Spell It Aloud (Help Requested)

[SMcNeill]

This easy and very stupid code show, what i mean, if i say, that ON TIMER get out in middle in the loop:

Code: QB64: [Select]

1. DIM f AS LONG
2. ON TIMER(1) GOSUB timerdone
3. TIMER ON
4. DO
5.     FOR f = 1 TO 500000
6.     NEXT f
7. LOOP
8.  
9. timerdone: PRINT "For next loop value is:"; f
10. RETURN
11.  

Sometimes, you want to be able to pop in and out of the middle of a loop.

Code: [Select]

DIM f AS LONG
ON TIMER(.1) GOSUB timerdone
TIMER ON
DO
    c = (c + 1) MOD 16
    COLOR c
    PRINT "COLOR "; c,
    _LIMIT 10 'no need to use a lot of CPU; we're going to handle things VIA the timed routine
LOOP

timerdone:
IF NOT paused THEN
    f = f + 1
    PRINT "For next loop value is:"; f
END IF
k = _KEYHIT
IF k = 32 THEN GOSUB pausetimer

RETURN

pausetimer:
paused = NOT paused
RETURN
The above is a very simple demo of how things might interact so that we do one thing (the main process), while still using ON TIMER as a means to handle control of other processes.

In the Spell It code I posted above, the SUB UserInput reads mouse/keystrokes via an ON TIMER routine, and by utilizing its ability to jump out of the middle of loops/subs, we can use it as a ready means to set control flags so we can stop the sound playing at any point in the process.

Code: [Select]

        _SNDPLAY AlphaSound(a)
        WHILE _SNDPLAYING(AlphaSound(a)) 'wait for sound to finish before playing again
            _LIMIT 10 'play nice with CPU during wait
            IF ControlVariable1 THEN _SNDSTOP (AlphaSound(a))
        WEND

ControlVariable1 can be set in the ON TIMER routine, and when set, we stop the sound and simply wait for the next process to be initiated by the user.  (play, next, quit, ect...)

[Petr]

 Steve.... i am very curious. How is this possible?

I am on the end in your source code in new compiled IDE with support for your new metacommand $color and give this screen.... Line 579 not exists, maximal row value in source code is 501...



if i comment your new metacommand, i find next bug - you use none LOF(1) control in SUB ChangeSearchTags, so, if is user idiot, so as me, and copy your Spell source code to new installation dir without needed subdirectories, so it generate Input past end of file on row 309 :)


image with your source code so, as it, with missing subdirectories for Spell program:

 

[Petr]

Thank you for your ON Timer example!

[SMcNeill]

Steve.... i am very curious. How is this possible?

It's actually a glitch which I didn't notice in the last BAS file I posted earlier.

If you open QB64.bas (which you downloaded from earlier), do a quick search for $COLOR32.  At line 2981, you'll see where there's:

Code: [Select]

        IF a3u$ = "$COLOR32" THEN
            ColorHack = -1
This is where QB64 is now parsing the metacommand for $COLOR32.  What it's doing is very simple -- it's actually just injecting those lines into your code (much like a native $INCLUDE statement would), and adding them to your available CONST list...

The glitch is rather simple:  I didn't bother to parse those statements and add the values manually to the CONST list (it's a bunch of different TYPE values which we use to track them), since QB64 already parses and deals with them for us, as it reads our code.  The glitch is that each time it processes them, it adds to the linecount for them -- all 200+ times!

Fix is really simple:

Add a line for:             oldlinenumber = linenumber to the start of that IF block, and then             linenumber = oldlinenumber to the end of that IF block (right before the GOTO which continues processing the rest of our code.

So that error you're getting isn't past the end of the file; your internal line counter is just off, until that one little glitch is corrected.

(There's always something simple like this, which is overlooked when making changes, which is why we have a development build for people to test these things, and a stable build so they don't have to worry about them.)  ;D

[Petr]

So rewrited, QB64 recompiled, re-tested and now it is ok. Please add to your Speel program to row 307 something as this:

Code: QB64: [Select]

1.   IF LOF(1) = 0 THEN PRINT "Missing program directories!": SLEEP 3: SYSTEM
2.  

We are going to have lunch, I will work with it again later.

[FellippeHeitor]

It's actually a glitch which I didn't notice in the last BAS file I posted earlier.

If you open QB64.bas (which you downloaded from earlier), do a quick search for $COLOR32.  At line 2981, you'll see where there's:

Code: [Select]

        IF a3u$ = "$COLOR32" THEN
            ColorHack = -1
This is where QB64 is now parsing the metacommand for $COLOR32.  What it's doing is very simple -- it's actually just injecting those lines into your code (much like a native $INCLUDE statement would), and adding them to your available CONST list...

The glitch is rather simple:  I didn't bother to parse those statements and add the values manually to the CONST list (it's a bunch of different TYPE values which we use to track them), since QB64 already parses and deals with them for us, as it reads our code.  The glitch is that each time it processes them, it adds to the linecount for them -- all 200+ times!

Fix is really simple:

Add a line for:             oldlinenumber = linenumber to the start of that IF block, and then             linenumber = oldlinenumber to the end of that IF block (right before the GOTO which continues processing the rest of our code.

So that error you're getting isn't past the end of the file; your internal line counter is just off, until that one little glitch is corrected.

(There's always something simple like this, which is overlooked when making changes, which is why we have a development build for people to test these things, and a stable build so they don't have to worry about them.)  ;D

Might also be a good idea to only inject the CONST declarations if ColorHack = 0.

[Petr]

Steve, this is another suggestion to change your function so that the input can be end by next click anywhere you want. (so you can not using enter only)

Code: QB64: [Select]

1. FUNCTION ChangeValue$ (x, y, word$, limit)
2.     TIMER(Timer1) OFF
3.     S = SaveState
4.     _FONT 16
5.     temp$ = CHR$(179)
6.     _KEYCLEAR
7.     DO UNTIL state = 2
8.         Box x, y, 100, 20, 1, Black, Gold
9.         CenterText x, y, x + 100, y + 20, temp$
10.         WHILE _MOUSEINPUT: WEND
11.         IF _MOUSEBUTTON(1) THEN
12.             state = state + 1
13.             DO UNTIL _MOUSEBUTTON(1) = 0
14.                 WHILE _MOUSEINPUT: WEND
15.             LOOP
16.         END IF
17.  
18.         k = _KEYHIT
19.         SELECT CASE k
20.             CASE 8
21.                 word$ = LEFT$(word$, LEN(word$) - 1)
22.             CASE 13
23.                 EXIT DO
24.             CASE 48 TO 57 'We'll always accept numeric input
25.                 word$ = word$ + CHR$(k)
26.             CASE 65 TO 90, 97 TO 122 'A-Z (a-z) only when we're dealing with a string
27.                 IF NOT limit THEN word$ = word$ + CHR$(k)
28.         END SELECT
29.         temp$ = word$ + CHR$(179)
30.         _LIMIT 10
31.     LOOP
32.     ChangeValue$ = word$
33.     RestoreState S
34.     DisplayTags 575, 150, "Search Tags (" + _TRIM$(STR$(PhotoCount)) + ")", LimitTag
35.     DisplayTags 575, 300, "Photo Tags", PhotoTag
36.  
37.     TIMER(Timer1) ON
38. END FUNCTION
39.  

I must upgrading my version in own way, because in your new source is too many news.

[Petr]

Steve, I removed DELAY 1 on SUB PlayLetters and added mouse input control  when is playback, and I have the same speed  without TIMER. Is the intention that the first and third blocks in PlayLetters for playback are the same?

[SMcNeill]

Here's a different version for you, Petr, without the ON TIMER routines to handle input:

Code: QB64: [Select]

1. $COLOR32
2.  
3. TYPE TagType
4.     Year AS INTEGER
5.     Week AS INTEGER
6.     Sound AS STRING
7.     Theme AS STRING
8. END TYPE
9.  
10. SCREEN _NEWIMAGE(800, 600, 32)
11. _TITLE "Spell It Aloud"
12. RANDOMIZE TIMER
13.  
14. CONST ImageDir$ = ".\Images\"
15. CONST SoundDir$ = ".\Alphabet Sounds\"
16. CONST TagDir$ = ".\Image Tags\"
17. CONST WordSoundDir$ = ".\Word Sounds\"
18.  
19. DIM SHARED PhotoTag AS TagType
20. DIM SHARED LimitTag AS TagType
21.  
22. DIM SHARED AlphaSound(65 TO 90)
23. REDIM SHARED PhotoList(100000) AS STRING
24. REDIM SHARED WordList(0) AS LONG
25. DIM SHARED PhotoCount AS LONG
26. DIM SHARED PhotoChosen AS LONG
27. DIM SHARED f AS LONG, f1 AS LONG
28. DIM SHARED IsHowYouSpell AS LONG
29. DIM SHARED ControlVariable1 AS LONG
30. DIM SHARED ShowNext AS LONG
31.  
32.  
33. 'load our fonts
34. f = _LOADFONT("courbd.ttf", 84, "MONOSPACE")
35. f1 = _LOADFONT("courbd.ttf", 48, "MONOSPACE")
36. _FONT f
37. fw = _FONTWIDTH: fh = _FONTHEIGHT
38.  
39.  
40. 'Load the alphabet sound library
41. FOR i = 65 TO 90
42.     temp$ = SoundDir$ + CHR$(i) + ".ogg"
43.     AlphaSound(i) = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")
44. NEXT
45. temp$ = WordSoundDir$ + "is how you spell.ogg"
46. IsHowYouSpell = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")
47.  
48. _FONT f
49.  
50. _DELAY 1 'Give everything a moment to initialize and get started for us.
51. WordList(0) = 3 'three times repeating the list, as default
52. ChangeSearchTags
53. ShowNext = -1
54.  
55. DO
56.     ControlVariable = 0
57.     MB = mouseclick
58.     Mx = _MOUSEX: My = _MOUSEY
59.     IF MB THEN
60.         IF Mx >= 650 AND Mx <= 750 THEN 'the mouse is in the correct X area for input
61.             SELECT CASE My
62.                 CASE 171 TO 190
63.                     temp$ = ChangeValue(650, 171, STR$(LimitTag.Year), -1)
64.                     LimitTag.Year = VAL(temp$)
65.                     ChangeSearchTags
66.                     ShowNext = -1
67.                 CASE 191 TO 210
68.                     temp$ = ChangeValue(650, 191, STR$(LimitTag.Week), -1)
69.                     LimitTag.Week = VAL(temp$)
70.                     ChangeSearchTags
71.                     ShowNext = -1
72.                 CASE 211 TO 230
73.                     temp$ = ChangeValue(650, 211, LimitTag.Sound, 0)
74.                     LimitTag.Sound = temp$
75.                     ChangeSearchTags
76.                     ShowNext = -1
77.                 CASE 231 TO 250
78.                     temp$ = ChangeValue(650, 231, LimitTag.Theme, 0)
79.                     LimitTag.Theme = temp$
80.                     ChangeSearchTags
81.                     ShowNext = -1
82.                 CASE 324 TO 340
83.                     PhotoTag.Year = VAL(ChangeValue(650, 324, STR$(PhotoTag.Year), -1))
84.                     ChangePhotoTags word$
85.                     ShowNext = -1: ControlVariable1 = -1
86.                 CASE 341 TO 360
87.                     PhotoTag.Week = VAL(ChangeValue(650, 341, STR$(PhotoTag.Week), -1))
88.                     ChangePhotoTags word$
89.                     ShowNext = -1: ControlVariable1 = -1
90.                 CASE 361 TO 380
91.                     PhotoTag.Sound = ChangeValue(650, 361, PhotoTag.Sound, 0)
92.                     ChangePhotoTags word$
93.                     ShowNext = -1: ControlVariable1 = -1
94.                 CASE 381 TO 400
95.                     PhotoTag.Theme = ChangeValue(650, 381, PhotoTag.Theme, 0)
96.                     ChangePhotoTags word$
97.                     ShowNext = -1: ControlVariable1 = -1
98.             END SELECT
99.         END IF
100.         IF _MOUSEY > 450 AND _MOUSEY < 470 THEN 'it's the right Y pos for the top control buttons
101.             SELECT CASE _MOUSEX
102.                 CASE 575 TO 640 'Last
103.                     PhotoChosen = PhotoChosen - 1
104.                     IF PhotoChosen < 1 THEN PhotoChosen = UBOUND(WordList)
105.                     ShowNext = -1
106.                 CASE 641 TO 705 'Play
107.                     ShowNext = -1
108.                 CASE 706 TO 770 'Next
109.                     PhotoChosen = PhotoChosen + 1
110.                     IF PhotoChosen > UBOUND(WordList) THEN PhotoChosen = 1
111.                     ShowNext = -1
112.             END SELECT
113.         ELSEIF _MOUSEY > 471 AND _MOUSEY < 491 THEN 'it's the right Y pos for the 2nd row of control buttons
114.             SELECT CASE _MOUSEX
115.                 CASE 575 TO 640 'Vol not yet implemented
116.                 CASE 641 TO 705 'Stop now handled via the sound sub
117.                 CASE 706 TO 770: SYSTEM 'Quit
118.             END SELECT
119.         END IF
120.     END IF
121.  
122.     k = _KEYHIT
123.     SELECT CASE k
124.         CASE 32 'space for next picture
125.             PhotoChosen = PhotoChosen + 1
126.             IF PhotoChosen > WordList(0) THEN PhotoChosen = 1
127.             ShowNext = -1
128.         CASE 27 'escape
129.             SYSTEM 'quit
130.     END SELECT
131.  
132.     IF ShowNext THEN
133.         ShowNext = 0
134.         IF PhotoChosen THEN
135.             temp$ = PhotoList(WordList(PhotoChosen))
136.             word$ = MID$(temp$, _INSTRREV(temp$, "\") + 1)
137.             word$ = LEFT$(word$, INSTR(word$, ".") - 1)
138.  
139.             IF tempimage <> 0 THEN _FREEIMAGE tempimage 'free the old image
140.             tempimage = _LOADIMAGE(temp$, 32) 'get the new image
141.  
142.             CLS
143.             _FONT f1: CenterText 0, 0, 800, 50, "Spell It Aloud": _FONT f
144.  
145.             'program photo area is 500 x 450 pixels. So:
146.             GetNewWH 500, 450, tempimage, nW, nH
147.             _PUTIMAGE (300 - (nW / 2), 300 - (nH / 2) - 25)-STEP(nW, nH), tempimage
148.  
149.             LoadPhotoTags word$
150.             temp$ = "Search Tags (" + _TRIM$(STR$(PhotoChosen)) + " of " + _TRIM$(STR$(UBOUND(WordList))) + ")"
151.             DisplayTags 575, 150, temp$, LimitTag
152.             DisplayTags 575, 300, "Photo Tags", PhotoTag
153.             DrawCommandBoxes
154.             IF ControlVariable1 = 0 THEN PlayLetters word$
155.         ELSE
156.             DrawNoMatches
157.         END IF
158.         ControlVariable1 = 0
159.     END IF
160.     _LIMIT 10
161.     _DISPLAY
162. LOOP
163.  
164. SUB DrawCommandBoxes
165.     s = SaveState
166.     _FONT 16
167.     COLOR Black, 0
168.     BoxTitle 575, 450, 640, 470, 2, BlueGray, Gold, "LAST"
169.     BoxTitle 641, 450, 705, 470, 2, BlueGray, Gold, "PLAY"
170.     BoxTitle 706, 450, 770, 470, 2, BlueGray, Gold, "NEXT"
171.     BoxTitle 575, 471, 640, 490, 2, BlueGray, Gold, "VOL"
172.     COLOR Maroon
173.     BoxTitle 641, 471, 705, 490, 2, BlueGray, Gold, "STOP"
174.     COLOR Yellow
175.     BoxTitle 706, 471, 770, 490, 2, BlueGray, Gold, "QUIT"
176.  
177.     RestoreState s
178. END SUB
179.  
180. SUB BoxTitle (x1, y1, x2, y2, thick, fg AS _UNSIGNED LONG, bg AS _UNSIGNED LONG, title$)
181.     Box x1, y1, x2 - x1 + 1, y2 - y1 + 1, thick, fg, bg
182.     CenterText x1, y1 + thick, x2, y2 + thick, title$
183. END SUB
184.  
185. SUB DrawNoMatches
186.     S = SaveState
187.     CLS
188.     _FONT f1
189.     Box 50, 50, 500, 500, 5, Silver, Gold
190.     CenterText 0, 0, 800, 50, "Spell It Aloud"
191.     FOR i = 1 TO 10 STEP .5
192.         CIRCLE (300, 300), 200 - i, BrickRed
193.         LINE (300 + SIN(_D2R(-45)) * 198 + i, 300 + COS(_D2R(-45)) * 198 + i)-(300 + SIN(_D2R(135)) * 198 + i, 300 + COS(_D2R(135)) * 198 + i), BrickRed
194.     NEXT
195.     COLOR Yellow, 0
196.     CenterText 50, 50, 550, 550, "No Matches"
197.     PhotoTag.Year = 0
198.     PhotoTag.Week = 0
199.     PhotoTag.Sound = ""
200.     PhotoTag.Theme = ""
201.     DisplayTags 575, 150, "Search Tags (0)", LimitTag
202.     DisplayTags 575, 300, "Photo Tags", PhotoTag
203.     RestoreState S
204. END SUB
205.  
206.  
207.  
208. SUB PlayLetters (word$)
209.     'Put the letters to the screen one by one
210.     ControlVariable1 = 0
211.     pw = _PRINTWIDTH(word$): StartX = (600 - pw) \ 2 'center position
212.  
213.     FOR i = 1 TO LEN(word$)
214.         a = ASC(word$, i) AND NOT 32 'play lowercase letters as uppercase sounds
215.         _PRINTSTRING (StartX + (i - 1) * _FONTWIDTH, 510), CHR$(a)
216.         _DISPLAY
217.         IF a < 65 OR a > 90 THEN _CONTINUE 'ignore non-letters in the file name
218.         _SNDPLAY AlphaSound(a)
219.         WHILE _SNDPLAYING(AlphaSound(a)) 'wait for sound to finish before playing again
220.             _LIMIT 10 'play nice with CPU during wait
221.             GOSUB checkstop
222.             IF ControlVariable1 THEN _SNDSTOP (AlphaSound(a))
223.         WEND
224.     NEXT
225.     IF ContolVariable1 = 0 THEN
226.         temp$ = WordSoundDir$ + word$ + ".ogg"
227.         IF _FILEEXISTS(temp$) THEN
228.             _SNDVOL IsHowYouSpell, .5
229.             _SNDPLAY IsHowYouSpell
230.             WHILE _SNDPLAYING(IsHowYouSpell) 'wait for sound to finish before playing again
231.                 _LIMIT 10 'play nice with CPU during wait
232.                 GOSUB checkstop
233.                 IF ControlVariable1 THEN _SNDSTOP (IsHowYouSpell): EXIT SUB
234.             WEND
235.  
236.             temp = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")
237.             _SNDPLAY temp
238.             WHILE _SNDPLAYING(temp) 'wait for sound to finish before playing again
239.                 _LIMIT 10 'play nice with CPU during wait
240.                 GOSUB checkstop
241.                 IF ControlVariable1 THEN _SNDCLOSE temp: EXIT SUB
242.             WEND
243.             _SNDCLOSE temp
244.  
245.             FOR i = 1 TO LEN(word$)
246.                 a = ASC(word$, i) AND NOT 32 'play lowercase letters as uppercase sounds
247.                 _PRINTSTRING (StartX + (i - 1) * _FONTWIDTH, 510), CHR$(a)
248.                 IF a < 65 OR a > 90 THEN _CONTINUE 'ignore non-letters in the file name
249.                 _SNDPLAY AlphaSound(a)
250.                 WHILE _SNDPLAYING(AlphaSound(a)) 'wait for sound to finish before playing again
251.                     _LIMIT 10 'play nice with CPU during wait
252.                     GOSUB checkstop
253.                     IF ControlVariable1 THEN EXIT SUB
254.                 WEND
255.             NEXT
256.         END IF
257.     END IF
258.  
259.     EXIT SUB
260.  
261.     checkstop:
262.     WHILE _MOUSEINPUT: WEND
263.     IF _MOUSEBUTTON(1) THEN
264.         IF _MOUSEY > 451 AND _MOUSEY < 491 THEN
265.             IF _MOUSEX > 575 AND _MOUSEX < 770 THEN 'stop
266.                 ControlVariable1 = -1 'Stop Command for playing the word
267.             END IF
268.         END IF
269.     END IF
270.     RETURN
271. END SUB
272.  
273.  
274. SUB ChangePhotoTags (word$)
275.     'Get a listing of the files
276.     file$ = TagDir$ + word$ + ".txt"
277.     OPEN file$ FOR OUTPUT AS #1
278.     PRINT #1, PhotoTag.Year
279.     PRINT #1, PhotoTag.Week
280.     PRINT #1, PhotoTag.Sound
281.     PRINT #1, PhotoTag.Theme
282.     CLOSE
283. END SUB
284.  
285. SUB LoadPhotoTags (word$)
286.     file$ = TagDir$ + word$ + ".txt"
287.     IF _FILEEXISTS(file$) THEN
288.         OPEN file$ FOR INPUT AS #1
289.         INPUT #1, PhotoTag.Year
290.         INPUT #1, PhotoTag.Week
291.         INPUT #1, PhotoTag.Sound
292.         INPUT #1, PhotoTag.Theme
293.         CLOSE
294.     ELSE
295.         PhotoTag.Year = 0
296.         PhotoTag.Week = 0
297.         PhotoTag.Sound = ""
298.         PhotoTag.Theme = ""
299.         IF word$ <> "" THEN ChangePhotoTags word$
300.     END IF
301. END SUB
302.  
303.  
304. SUB ChangeSearchTags
305.     'Get a listing of the files
306.     PhotoList$ = ImageDir$ + "*.bmp " + ImageDir$ + "*.jpg " + ImageDir$ + "*.png " + ImageDir$ + "*.gif "
307.     SHELL _HIDE "DIR " + PhotoList$ + "/b /s /a-d >PhotoList.txt"
308.  
309.     REDIM _PRESERVE PhotoList(100000)
310.     'Load those names into a file.
311.     OPEN "Photolist.txt" FOR BINARY AS #1
312.     PhotoCount = 0
313.     DO UNTIL EOF(1)
314.         LINE INPUT #1, fullpath$
315.         word$ = MID$(fullpath$, _INSTRREV(fullpath$, "\") + 1)
316.         word$ = LEFT$(word$, INSTR(word$, ".") - 1)
317.  
318.         file$ = TagDir$ + word$ + ".txt"
319.         IF _FILEEXISTS(file$) THEN
320.             OPEN file$ FOR INPUT AS #2
321.             INPUT #2, PhotoTag.Year
322.             INPUT #2, PhotoTag.Week
323.             INPUT #2, PhotoTag.Sound
324.             INPUT #2, PhotoTag.Theme
325.         ELSE
326.             OPEN file$ FOR OUTPUT AS #2
327.             PRINT #2, 0
328.             PRINT #2, 0
329.             PRINT #2, ""
330.             PRINT #2, ""
331.         END IF
332.         CLOSE #2
333.         good = -1
334.         IF LimitTag.Year <> 0 AND LimitTag.Year <> PhotoTag.Year THEN good = 0
335.         IF LimitTag.Week <> 0 AND LimitTag.Week <> PhotoTag.Week THEN good = 0
336.  
337.         IF LimitTag.Sound <> "" AND LimitTag.Sound <> PhotoTag.Sound THEN good = 0
338.         IF LimitTag.Theme <> "" AND LimitTag.Theme <> PhotoTag.Theme THEN good = 0
339.         IF good THEN
340.             PhotoCount = PhotoCount + 1
341.             PhotoList(PhotoCount) = fullpath$
342.         END IF
343.     LOOP
344.     REDIM _PRESERVE PhotoList(PhotoCount)
345.     CLOSE
346.     MakeList
347. END SUB
348.  
349. SUB MakeList
350.     RepeatCount = WordList(0)
351.     REDIM WordList(PhotoCount * RepeatCount) AS LONG
352.     WordList(0) = RepeatCount
353.     IF UBOUND(wordlist) > 0 THEN
354.         PhotoChosen = 1
355.     ELSE
356.         PhotoChosen = 0
357.         EXIT SUB
358.     END IF
359.     DIM TempList(PhotoCount) AS LONG
360.     FOR i = 1 TO PhotoCount
361.         TempList(i) = i
362.     NEXT
363.     FOR i = 1 TO RepeatCount
364.         FOR j = 1 TO PhotoCount
365.             r = INT(RND * PhotoCount) + 1
366.             SWAP TempList(j), TempList(r)
367.         NEXT
368.         FOR j = 1 TO PhotoCount
369.             Count = Count + 1
370.             WordList(Count) = TempList(j)
371.         NEXT
372.     NEXT
373. END SUB
374.  
375. FUNCTION ChangeValue$ (x, y, tword$, limit)
376.     S = SaveState
377.     _FONT 16
378.     temp$ = CHR$(179)
379.     _KEYCLEAR
380.     _AUTODISPLAY
381.     DO
382.         Box x, y, 100, 20, 1, Black, Gold
383.         CenterText x, y, x + 100, y + 20, temp$
384.         k = _KEYHIT
385.         SELECT CASE k
386.             CASE 8
387.                 tword$ = LEFT$(tword$, LEN(tword$) - 1)
388.             CASE 13
389.                 EXIT DO
390.             CASE 48 TO 57 'We'll always accept numeric input
391.                 tword$ = tword$ + CHR$(k)
392.             CASE 65 TO 90, 97 TO 122 'A-Z (a-z) only when we're dealing with a string
393.                 IF NOT limit THEN tword$ = tword$ + CHR$(k)
394.         END SELECT
395.         temp$ = tword$ + CHR$(179)
396.         _LIMIT 10
397.         DisplayTags 575, 150, "Search Tags (" + _TRIM$(STR$(PhotoCount)) + ")", LimitTag
398.         DisplayTags 575, 300, "Photo Tags", PhotoTag
399.     LOOP
400.     ChangeValue$ = tword$
401.     RestoreState S
402. END SUB
403.  
404. SUB DisplayTags (x, y, Title AS STRING, DisplayTag AS TagType)
405.     S = SaveState
406.     _FONT 16
407.     W = 200: h = 106
408.     Box x, y, W, h, 2, BlueGray, Gold
409.     COLOR Gold, 0
410.     CenterText x, y + 2, x + 200, y + 20, Title
411.     LINE (x + 1, y + 19)-STEP(W - 2, 0), Gold
412.     COLOR White, 0
413.     xs = x + 24: ys = y + 24 'x/y start after the box offset
414.     _PRINTSTRING (xs, ys), "Year :"
415.     _PRINTSTRING (xs, ys + 20), "Week :"
416.     _PRINTSTRING (xs, ys + 40), "Sound:"
417.     _PRINTSTRING (xs, ys + 60), "Theme:"
418.     bxs = xs + 50: bys = ys - 2 'x/y start for the display boxes
419.     FOR i = 0 TO 3
420.         Box bxs, bys + i * 20, 100, 20, 1, Black, Gold
421.     NEXT
422.     CenterValue bxs, bys, bxs + 100, bys + 20, DisplayTag.Year
423.     CenterValue bxs, bys + 20, bxs + 100, bys + 40, DisplayTag.Week
424.     CenterText bxs, bys + 40, bxs + 100, bys + 60, DisplayTag.Sound
425.     CenterText bxs, bys + 60, bxs + 100, bys + 80, DisplayTag.Theme
426.     RestoreState S
427. END SUB
428.  
429. SUB Box (x, y, wide, high, thick, Kolor AS _UNSIGNED LONG, Trim AS _UNSIGNED LONG)
430.     LINE (x, y)-STEP(wide, high), Kolor, BF
431.     FOR i = 0 TO thick - 1
432.         LINE (x + i, y + i)-STEP(wide - 2 * i, high - 2 * i), Trim, B
433.     NEXT
434. END SUB
435.  
436.  
437. SUB CenterText (x1, y1, x2, y2, text$)
438.     text$ = _TRIM$(text$)
439.     xmax = x2 - x1: ymax = y2 - y1
440.     textlength = _PRINTWIDTH(text$)
441.     xpos = (xmax - textlength) / 2
442.     ypos = (ymax - _FONTHEIGHT) / 2
443.     _PRINTSTRING (x1 + xpos, y1 + ypos), text$
444. END SUB
445.  
446. SUB CenterValue (x1, y1, x2, y2, value AS LONG)
447.     text$ = _TRIM$(STR$(value))
448.     CenterText x1, y1, x2, y2, text$
449. END SUB
450.  
451. FUNCTION SaveState
452.     TYPE SaveStateType
453.         InUse AS INTEGER
454.         DC AS INTEGER
455.         BG AS INTEGER
456.         F AS INTEGER
457.         D AS INTEGER
458.         S AS INTEGER
459.         Disp AS INTEGER
460.         CurX AS INTEGER
461.         CurY AS INTEGER
462.     END TYPE
463.     DIM SS AS SaveStateType, Temp AS SaveStateType
464.     SHARED NSS AS LONG 'Number of Saved States
465.     SHARED SaveMem AS _MEM
466.     IF NOT _MEMEXISTS(SaveMem) THEN
467.         SaveMem = _MEMNEW(LEN(SS) * 255) 'Save up to 255 save states; More than 255 and we toss an error
468.         $CHECKING:OFF
469.         _MEMFILL SaveMem, SaveMem.OFFSET, SaveMem.SIZE, 0 AS _UNSIGNED _BYTE
470.         $CHECKING:ON
471.     END IF
472.  
473.     'Data to Save
474.     SS.InUse = -1
475.     SS.F = _FONT
476.     SS.DC = _DEFAULTCOLOR
477.     SS.BG = _BACKGROUNDCOLOR
478.     SS.D = _DEST
479.     SS.S = _SOURCE
480.     SS.Disp = _AUTODISPLAY
481.     SS.CurX = POS(0)
482.     SS.CurY = CSRLIN
483.     $CHECKING:OFF
484.     FOR i = 1 TO NSS
485.         o = (i - 1) * LEN(SS)
486.         _MEMGET SaveMem, SaveMem.OFFSET + o, Temp
487.         IF Temp.InUse = 0 THEN
488.             _MEMPUT SaveMem, SaveMem.OFFSET + o, SS
489.             SaveState = i
490.             EXIT FUNCTION
491.         END IF
492.     NEXT
493.     _MEMPUT SaveMem, SaveMem.OFFSET + NSS * LEN(SS), SS
494.     $CHECKING:ON
495.     NSS = NSS + 1
496.     SaveState = NSS
497. END SUB
498.  
499. SUB RestoreState (WhichOne AS LONG)
500.     DIM SS AS SaveStateType
501.     SHARED NSS AS LONG 'Number of Saved States
502.     SHARED SaveMem AS _MEM
503.     _MEMGET SaveMem, SaveMem.OFFSET + (WhichOne - 1) * LEN(SS), SS
504.     $CHECKING:ON
505.     IF SS.InUse THEN
506.         SS.InUse = 0 'Let the routine know that we're no longer in use for this handle
507.         $CHECKING:OFF
508.         _MEMPUT SaveMem, SaveMem.OFFSET + (WhichOne - 1) * LEN(SS), SS
509.         $CHECKING:ON
510.         _FONT SS.F
511.         COLOR SS.DC, SS.BG
512.         _DEST SS.D
513.         _SOURCE SS.S
514.         IF SS.Disp THEN _AUTODISPLAY ELSE _DISPLAY
515.         LOCATE SS.CurY, SS.CurX
516.     END IF
517. END SUB
518.  
519. SUB GetNewWH (destWidth, destHeight, handle AS LONG, NewWidth, NewHeight) 'Sub return in variables NewWidth and NewHeight new image Width and image Height with the same ratio for optimal picture to set area width and height with [destWidth, destHeight]
520.     W = _WIDTH(handle)
521.     H = _HEIGHT(handle)
522.     Pw = W / destWidth
523.     Ph = H / destHeight
524.     IF W > H THEN P = Pw ELSE P = Ph
525.     NewWidth = W / P
526.     NewHeight = H / P
527. END SUB
528.  
529. FUNCTION mouseclick%
530.     DO WHILE _MOUSEINPUT 'check mouse status
531.         lb% = _MOUSEBUTTON(1)
532.     LOOP
533.  
534.     DO WHILE lb% 'check for leftbutton release
535.         i% = _MOUSEINPUT
536.         lb% = _MOUSEBUTTON(1)
537.         mouseclick% = -1
538.     LOOP
539. END FUNCTION
540.  

It's now making the review lists (I still need to quick code in the buttons to change how many times we review our words, as of now, they're stuck at 3 times each), and I think I've sorted out the glitches so that we no longer require the ON TIMER method of handling things.  All GOTO statements are now removed as well, since many folks find them completely distasteful, and all that's left at this point is to:

1) Add the 5 quick select buttons for the numbers of times to review the material chosen.
2) To add in the quiz routine at the end of the review process.

And then it's just add pictures and words, and tag them so they can be reviewed as wanted.

[Petr]

Hi Steve. I tried with my "English" to say those few words .... the result is - useless. Check your email (@QB64.ORG), have fun and delete it. I never learned English (I learned German, because I live near the German border) and my English pronunciation is disastrous. But - again - I tried it, unlike English-speaking colleagues here on the forum. English speaking gentlemen programmers could think about each other :-D

Yeah, I have a provocative day today. Steve, because I don't have enough imagination, I ask you to elaborate on the idea. Five buttons. Good. Specifically, what to this 5 buttons have to do. Thanks for your patience.

[SMcNeill]

Steve, because I don't have enough imagination, I ask you to elaborate on the idea. Five buttons. Good. Specifically, what to this 5 buttons have to do. Thanks for your patience.

They're now in there.  All that's left now is for the QUIZ portion of the program!  ;D

Code: [Select]

$COLOR:32

TYPE TagType
    Year AS INTEGER
    Week AS INTEGER
    Sound AS STRING
    Theme AS STRING
END TYPE

SCREEN _NEWIMAGE(800, 600, 32)
_TITLE "Spell It Aloud"
RANDOMIZE TIMER

$IF WIN THEN
    temp$ = MID$(_CWD$, _INSTRREV(_CWD$, "\") + 1)
$ELSE
    temp$ = MID$(_CWD$, _INSTRREV(_CWD$, "/") + 1)
$END IF

IF temp$ <> "Spell It Aloud" THEN
    PRINT "ERROR -- Program not in proper directory."
    PRINT "Stopping execution..."
    PRINT
    PRINT "Please don't be a dufus, and fix it!"
END IF

CONST ImageDir$ = ".\Images\"
CONST SoundDir$ = ".\Alphabet Sounds\"
CONST TagDir$ = ".\Image Tags\"
CONST WordSoundDir$ = ".\Word Sounds\"


DIM SHARED PhotoTag AS TagType
DIM SHARED LimitTag AS TagType

DIM SHARED AlphaSound(65 TO 90)
REDIM SHARED PhotoList(100000) AS STRING
REDIM SHARED WordList(0) AS LONG
DIM SHARED PhotoCount AS LONG
DIM SHARED PhotoChosen AS LONG
DIM SHARED f AS LONG, f1 AS LONG
DIM SHARED IsHowYouSpell AS LONG
DIM SHARED ControlVariable1 AS LONG
DIM SHARED ShowNext AS LONG


'load our fonts
f = _LOADFONT("courbd.ttf", 84, "MONOSPACE")
f1 = _LOADFONT("courbd.ttf", 48, "MONOSPACE")
_FONT f
fw = _FONTWIDTH: fh = _FONTHEIGHT


'Load the alphabet sound library
FOR i = 65 TO 90
    temp$ = SoundDir$ + CHR$(i) + ".ogg"
    AlphaSound(i) = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")
NEXT
temp$ = WordSoundDir$ + "is how you spell.ogg"
IsHowYouSpell = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")

_FONT f

_DELAY 1 'Give everything a moment to initialize and get started for us.
WordList(0) = 3 'three times repeating the list, as default
ChangeSearchTags
ShowNext = -1

DO
    ControlVariable = 0
    WHILE _MOUSEINPUT: WEND

    MB = _MOUSEBUTTON(1)
    Mx = _MOUSEX: My = _MOUSEY
    IF MB AND NOT oldmouse THEN
        IF Mx >= 650 AND Mx <= 750 THEN 'the mouse is in the correct X area for input
            SELECT CASE My
                CASE 171 TO 190
                    temp$ = ChangeValue(650, 171, STR$(LimitTag.Year), -1)
                    LimitTag.Year = VAL(temp$)
                    ChangeSearchTags
                    ShowNext = -1
                CASE 191 TO 210
                    temp$ = ChangeValue(650, 191, STR$(LimitTag.Week), -1)
                    LimitTag.Week = VAL(temp$)
                    ChangeSearchTags
                    ShowNext = -1
                CASE 211 TO 230
                    temp$ = ChangeValue(650, 211, LimitTag.Sound, 0)
                    LimitTag.Sound = temp$
                    ChangeSearchTags
                    ShowNext = -1
                CASE 231 TO 250
                    temp$ = ChangeValue(650, 231, LimitTag.Theme, 0)
                    LimitTag.Theme = temp$
                    ChangeSearchTags
                    ShowNext = -1
                CASE 324 TO 340
                    PhotoTag.Year = VAL(ChangeValue(650, 324, STR$(PhotoTag.Year), -1))
                    ChangePhotoTags word$
                    ShowNext = -1: ControlVariable1 = -1
                CASE 341 TO 360
                    PhotoTag.Week = VAL(ChangeValue(650, 341, STR$(PhotoTag.Week), -1))
                    ChangePhotoTags word$
                    ShowNext = -1: ControlVariable1 = -1
                CASE 361 TO 380
                    PhotoTag.Sound = ChangeValue(650, 361, PhotoTag.Sound, 0)
                    ChangePhotoTags word$
                    ShowNext = -1: ControlVariable1 = -1
                CASE 381 TO 400
                    PhotoTag.Theme = ChangeValue(650, 381, PhotoTag.Theme, 0)
                    ChangePhotoTags word$
                    ShowNext = -1: ControlVariable1 = -1
            END SELECT
        END IF
        IF _MOUSEY > 450 AND _MOUSEY < 470 THEN 'it's the right Y pos for the top control buttons
            SELECT CASE _MOUSEX
                CASE 575 TO 640 'Last
                    PhotoChosen = PhotoChosen - 1
                    IF PhotoChosen < 1 THEN PhotoChosen = 1
                    ShowNext = -1
                CASE 641 TO 705 'Play
                    ShowNext = -1
                CASE 706 TO 770 'Next
                    PhotoChosen = PhotoChosen + 1
                    IF PhotoChosen > UBOUND(WordList) THEN PhotoChosen = 1
                    ShowNext = -1
            END SELECT
        ELSEIF _MOUSEY > 471 AND _MOUSEY < 491 THEN 'it's the right Y pos for the 2nd row of control buttons
            SELECT CASE _MOUSEX
                CASE 575 TO 640 'Vol not yet implemented
                CASE 641 TO 705 'Stop now handled via the sound sub
                CASE 706 TO 770: SYSTEM 'Quit
            END SELECT
        ELSEIF _MOUSEY > 495 AND _MOUSEY < 515 THEN 'it's in the review column
            oldR = WordList(0)
            R = (_MOUSEX - 641) / 26
            IF R <> oldR THEN
                IF R > 0 AND R < 5 THEN WordList(0) = INT(R + 1)
                MakeList
                ShowNext = -1
            END IF
        END IF
    END IF

    k = _KEYHIT
    SELECT CASE k
        CASE 32 'space for next picture
            PhotoChosen = PhotoChosen + 1
            IF PhotoChosen > WordList(0) THEN PhotoChosen = 1
            ShowNext = -1
        CASE 27 'escape
            SYSTEM 'quit
    END SELECT

    IF ShowNext THEN
        ShowNext = 0
        IF PhotoChosen THEN
            temp$ = PhotoList(WordList(PhotoChosen))
            word$ = MID$(temp$, _INSTRREV(temp$, "\") + 1)
            word$ = LEFT$(word$, INSTR(word$, ".") - 1)

            IF tempimage <> 0 THEN _FREEIMAGE tempimage 'free the old image
            tempimage = _LOADIMAGE(temp$, 32) 'get the new image

            CLS
            _FONT f1: CenterText 0, 0, 800, 50, "Spell It Aloud": _FONT f

            'program photo area is 500 x 450 pixels. So:
            GetNewWH 500, 450, tempimage, nW, nH
            _PUTIMAGE (300 - (nW / 2), 300 - (nH / 2) - 25)-STEP(nW, nH), tempimage

            LoadPhotoTags word$
            temp$ = "Search Tags (" + _TRIM$(STR$(PhotoChosen)) + " of " + _TRIM$(STR$(UBOUND(wordlist))) + ")"
            DisplayTags 575, 150, temp$, LimitTag
            DisplayTags 575, 300, "Photo Tags", PhotoTag
            DrawCommandBoxes
            IF ControlVariable1 = 0 THEN PlayLetters word$
        ELSE
            DrawNoMatches
        END IF
        ControlVariable1 = 0
    END IF
    _LIMIT 10
    _DISPLAY
    oldmouse = MB
LOOP

SUB DrawCommandBoxes
    s = SaveState
    _FONT 16
    COLOR Black, 0
    BoxTitle 575, 450, 640, 470, 2, BlueGray, Gold, "LAST"
    BoxTitle 641, 450, 705, 470, 2, BlueGray, Gold, "PLAY"
    BoxTitle 706, 450, 770, 470, 2, BlueGray, Gold, "NEXT"
    BoxTitle 575, 471, 640, 490, 2, BlueGray, Gold, "VOL"
    COLOR Maroon
    BoxTitle 641, 471, 705, 490, 2, BlueGray, Gold, "STOP"
    COLOR Yellow
    BoxTitle 706, 471, 770, 490, 2, BlueGray, Gold, "QUIT"
    COLOR Black
    BoxTitle 575, 495, 640, 515, 2, BlueGray, Gold, "REVIEW:"
    R = WordList(0) '3
    FOR i = 1 TO 5
        IF i <> R THEN
            COLOR LightGray
            BoxTitle 641 + (i - 1) * 26, 495, 641 + i * 26, 515, 1, Black, Gold, STR$(i)
        ELSE
            COLOR White
            BoxTitle 641 + (i - 1) * 26, 495, 641 + i * 26, 515, 1, BlueGray, Gold, STR$(i)
        END IF
    NEXT
    RestoreState s
END SUB

SUB BoxTitle (x1, y1, x2, y2, thick, fg AS _UNSIGNED LONG, bg AS _UNSIGNED LONG, title$)
    Box x1, y1, x2 - x1 + 1, y2 - y1 + 1, thick, fg, bg
    CenterText x1, y1 + thick, x2, y2 + thick, title$
END SUB

SUB DrawNoMatches
    S = SaveState
    CLS
    _FONT f1
    Box 50, 50, 500, 500, 5, Silver, Gold
    CenterText 0, 0, 800, 50, "Spell It Aloud"
    FOR i = 1 TO 10 STEP .5
        CIRCLE (300, 300), 200 - i, BrickRed
        LINE (300 + SIN(_D2R(-45)) * 198 + i, 300 + COS(_D2R(-45)) * 198 + i)-(300 + SIN(_D2R(135)) * 198 + i, 300 + COS(_D2R(135)) * 198 + i), BrickRed
    NEXT
    COLOR Yellow, 0
    CenterText 50, 50, 550, 550, "No Matches"
    PhotoTag.Year = 0
    PhotoTag.Week = 0
    PhotoTag.Sound = ""
    PhotoTag.Theme = ""
    DisplayTags 575, 150, "Search Tags (0)", LimitTag
    DisplayTags 575, 300, "Photo Tags", PhotoTag
    RestoreState S
END SUB



SUB PlayLetters (word$)
    'Put the letters to the screen one by one
    ControlVariable1 = 0
    pw = _PRINTWIDTH(word$): StartX = (600 - pw) \ 2 'center position

    FOR i = 1 TO LEN(word$)
        a = ASC(word$, i) AND NOT 32 'play lowercase letters as uppercase sounds
        _PRINTSTRING (StartX + (i - 1) * _FONTWIDTH, 510), CHR$(a)
        _DISPLAY
        IF a < 65 OR a > 90 THEN _CONTINUE 'ignore non-letters in the file name
        _SNDPLAY AlphaSound(a)
        WHILE _SNDPLAYING(AlphaSound(a)) 'wait for sound to finish before playing again
            _LIMIT 10 'play nice with CPU during wait
            GOSUB checkstop
            IF ControlVariable1 THEN _SNDSTOP (AlphaSound(a))
        WEND
    NEXT
    IF ContolVariable1 = 0 THEN
        temp$ = WordSoundDir$ + word$ + ".ogg"
        IF _FILEEXISTS(temp$) THEN
            _SNDVOL IsHowYouSpell, .5
            _SNDPLAY IsHowYouSpell
            WHILE _SNDPLAYING(IsHowYouSpell) 'wait for sound to finish before playing again
                _LIMIT 10 'play nice with CPU during wait
                GOSUB checkstop
                IF ControlVariable1 THEN _SNDSTOP (IsHowYouSpell): EXIT SUB
            WEND

            temp = _SNDOPEN(temp$, "VOL,SYNC,LEN,PAUSE")
            _SNDPLAY temp
            WHILE _SNDPLAYING(temp) 'wait for sound to finish before playing again
                _LIMIT 10 'play nice with CPU during wait
                GOSUB checkstop
                IF ControlVariable1 THEN _SNDCLOSE temp: EXIT SUB
            WEND
            _SNDCLOSE temp

            FOR i = 1 TO LEN(word$)
                a = ASC(word$, i) AND NOT 32 'play lowercase letters as uppercase sounds
                _PRINTSTRING (StartX + (i - 1) * _FONTWIDTH, 510), CHR$(a)
                IF a < 65 OR a > 90 THEN _CONTINUE 'ignore non-letters in the file name
                _SNDPLAY AlphaSound(a)
                WHILE _SNDPLAYING(AlphaSound(a)) 'wait for sound to finish before playing again
                    _LIMIT 10 'play nice with CPU during wait
                    GOSUB checkstop
                    IF ControlVariable1 THEN EXIT SUB
                WEND
            NEXT
        END IF
    END IF

    EXIT SUB

    checkstop:
    WHILE _MOUSEINPUT: WEND
    IF _MOUSEBUTTON(1) THEN
        IF _MOUSEY > 451 AND _MOUSEY < 491 THEN
            IF _MOUSEX > 575 AND _MOUSEX < 770 THEN 'stop
                ControlVariable1 = -1 'Stop Command for playing the word
            END IF
        END IF
    END IF
    RETURN
END SUB


SUB ChangePhotoTags (word$)
    'Get a listing of the files
    file$ = TagDir$ + word$ + ".txt"
    OPEN file$ FOR OUTPUT AS #1
    PRINT #1, PhotoTag.Year
    PRINT #1, PhotoTag.Week
    PRINT #1, PhotoTag.Sound
    PRINT #1, PhotoTag.Theme
    CLOSE
END SUB

SUB LoadPhotoTags (word$)
    file$ = TagDir$ + word$ + ".txt"
    IF _FILEEXISTS(file$) THEN
        OPEN file$ FOR INPUT AS #1
        INPUT #1, PhotoTag.Year
        INPUT #1, PhotoTag.Week
        INPUT #1, PhotoTag.Sound
        INPUT #1, PhotoTag.Theme
        CLOSE
    ELSE
        PhotoTag.Year = 0
        PhotoTag.Week = 0
        PhotoTag.Sound = ""
        PhotoTag.Theme = ""
        IF word$ <> "" THEN ChangePhotoTags word$
    END IF
END SUB


SUB ChangeSearchTags
    'Get a listing of the files
    PhotoList$ = ImageDir$ + "*.bmp " + ImageDir$ + "*.jpg " + ImageDir$ + "*.png " + ImageDir$ + "*.gif "
    SHELL _HIDE "DIR " + PhotoList$ + "/b /s /a-d >PhotoList.txt"

    REDIM _PRESERVE PhotoList(100000)
    'Load those names into a file.
    OPEN "Photolist.txt" FOR BINARY AS #1
    PhotoCount = 0
    DO UNTIL EOF(1)
        LINE INPUT #1, fullpath$
        word$ = MID$(fullpath$, _INSTRREV(fullpath$, "\") + 1)
        word$ = LEFT$(word$, INSTR(word$, ".") - 1)

        file$ = TagDir$ + word$ + ".txt"
        IF _FILEEXISTS(file$) THEN
            OPEN file$ FOR INPUT AS #2
            INPUT #2, PhotoTag.Year
            INPUT #2, PhotoTag.Week
            INPUT #2, PhotoTag.Sound
            INPUT #2, PhotoTag.Theme
        ELSE
            OPEN file$ FOR OUTPUT AS #2
            PRINT #2, 0
            PRINT #2, 0
            PRINT #2, ""
            PRINT #2, ""
        END IF
        CLOSE #2
        good = -1
        IF LimitTag.Year <> 0 AND LimitTag.Year <> PhotoTag.Year THEN good = 0
        IF LimitTag.Week <> 0 AND LimitTag.Week <> PhotoTag.Week THEN good = 0

        IF LimitTag.Sound <> "" AND LimitTag.Sound <> PhotoTag.Sound THEN good = 0
        IF LimitTag.Theme <> "" AND LimitTag.Theme <> PhotoTag.Theme THEN good = 0
        IF good THEN
            PhotoCount = PhotoCount + 1
            PhotoList(PhotoCount) = fullpath$
        END IF
    LOOP
    REDIM _PRESERVE PhotoList(PhotoCount)
    CLOSE
    MakeList
END SUB

SUB MakeList
    RepeatCount = WordList(0)
    REDIM WordList(PhotoCount * RepeatCount) AS LONG
    WordList(0) = RepeatCount
    IF UBOUND(wordlist) > 0 THEN
        PhotoChosen = 1
    ELSE
        PhotoChosen = 0
        EXIT SUB
    END IF
    DIM TempList(PhotoCount) AS LONG
    FOR i = 1 TO PhotoCount
        TempList(i) = i
    NEXT
    FOR i = 1 TO RepeatCount
        FOR j = 1 TO PhotoCount
            r = INT(RND * PhotoCount) + 1
            SWAP TempList(j), TempList(r)
        NEXT
        FOR j = 1 TO PhotoCount
            Count = Count + 1
            WordList(Count) = TempList(j)
        NEXT
    NEXT
END SUB

FUNCTION ChangeValue$ (x, y, tword$, limit)
    S = SaveState
    _FONT 16
    temp$ = CHR$(179)
    _KEYCLEAR
    _AUTODISPLAY
    DO
        Box x, y, 100, 20, 1, Black, Gold
        CenterText x, y, x + 100, y + 20, temp$
        k = _KEYHIT
        SELECT CASE k
            CASE 8
                tword$ = LEFT$(tword$, LEN(tword$) - 1)
            CASE 13
                EXIT DO
            CASE 48 TO 57 'We'll always accept numeric input
                tword$ = tword$ + CHR$(k)
            CASE 65 TO 90, 97 TO 122 'A-Z (a-z) only when we're dealing with a string
                IF NOT limit THEN tword$ = tword$ + CHR$(k)
        END SELECT
        temp$ = tword$ + CHR$(179)
        _LIMIT 10
        DisplayTags 575, 150, "Search Tags (" + _TRIM$(STR$(PhotoCount)) + ")", LimitTag
        DisplayTags 575, 300, "Photo Tags", PhotoTag
    LOOP
    ChangeValue$ = tword$
    RestoreState S
END SUB

SUB DisplayTags (x, y, Title AS STRING, DisplayTag AS TagType)
    S = SaveState
    _FONT 16
    W = 200: h = 106
    Box x, y, W, h, 2, BlueGray, Gold
    COLOR Gold, 0
    CenterText x, y + 2, x + 200, y + 20, Title
    LINE (x + 1, y + 19)-STEP(W - 2, 0), Gold
    COLOR White, 0
    xs = x + 24: ys = y + 24 'x/y start after the box offset
    _PRINTSTRING (xs, ys), "Year :"
    _PRINTSTRING (xs, ys + 20), "Week :"
    _PRINTSTRING (xs, ys + 40), "Sound:"
    _PRINTSTRING (xs, ys + 60), "Theme:"
    bxs = xs + 50: bys = ys - 2 'x/y start for the display boxes
    FOR i = 0 TO 3
        Box bxs, bys + i * 20, 100, 20, 1, Black, Gold
    NEXT
    CenterValue bxs, bys, bxs + 100, bys + 20, DisplayTag.Year
    CenterValue bxs, bys + 20, bxs + 100, bys + 40, DisplayTag.Week
    CenterText bxs, bys + 40, bxs + 100, bys + 60, DisplayTag.Sound
    CenterText bxs, bys + 60, bxs + 100, bys + 80, DisplayTag.Theme
    RestoreState S
END SUB

SUB Box (x, y, wide, high, thick, Kolor AS _UNSIGNED LONG, Trim AS _UNSIGNED LONG)
    LINE (x, y)-STEP(wide, high), Kolor, BF
    FOR i = 0 TO thick - 1
        LINE (x + i, y + i)-STEP(wide - 2 * i, high - 2 * i), Trim, B
    NEXT
END SUB


SUB CenterText (x1, y1, x2, y2, text$)
    text$ = _TRIM$(text$)
    xmax = x2 - x1: ymax = y2 - y1
    textlength = _PRINTWIDTH(text$)
    xpos = (xmax - textlength) / 2
    ypos = (ymax - _FONTHEIGHT) / 2
    _PRINTSTRING (x1 + xpos, y1 + ypos), text$
END SUB

SUB CenterValue (x1, y1, x2, y2, value AS LONG)
    text$ = _TRIM$(STR$(value))
    CenterText x1, y1, x2, y2, text$
END SUB

FUNCTION SaveState
    TYPE SaveStateType
        InUse AS INTEGER
        DC AS INTEGER
        BG AS INTEGER
        F AS INTEGER
        D AS INTEGER
        S AS INTEGER
        Disp AS INTEGER
        CurX AS INTEGER
        CurY AS INTEGER
    END TYPE
    DIM SS AS SaveStateType, Temp AS SaveStateType
    SHARED NSS AS LONG 'Number of Saved States
    SHARED SaveMem AS _MEM
    IF NOT _MEMEXISTS(SaveMem) THEN
        SaveMem = _MEMNEW(LEN(SS) * 255) 'Save up to 255 save states; More than 255 and we toss an error
        $CHECKING:OFF
        _MEMFILL SaveMem, SaveMem.OFFSET, SaveMem.SIZE, 0 AS _UNSIGNED _BYTE
        $CHECKING:ON
    END IF

    'Data to Save
    SS.InUse = -1
    SS.F = _FONT
    SS.DC = _DEFAULTCOLOR
    SS.BG = _BACKGROUNDCOLOR
    SS.D = _DEST
    SS.S = _SOURCE
    SS.Disp = _AUTODISPLAY
    SS.CurX = POS(0)
    SS.CurY = CSRLIN
    $CHECKING:OFF
    FOR i = 1 TO NSS
        o = (i - 1) * LEN(SS)
        _MEMGET SaveMem, SaveMem.OFFSET + o, Temp
        IF Temp.InUse = 0 THEN
            _MEMPUT SaveMem, SaveMem.OFFSET + o, SS
            SaveState = i
            EXIT FUNCTION
        END IF
    NEXT
    _MEMPUT SaveMem, SaveMem.OFFSET + NSS * LEN(SS), SS
    $CHECKING:ON
    NSS = NSS + 1
    SaveState = NSS
END SUB

SUB RestoreState (WhichOne AS LONG)
    DIM SS AS SaveStateType
    SHARED NSS AS LONG 'Number of Saved States
    SHARED SaveMem AS _MEM
    _MEMGET SaveMem, SaveMem.OFFSET + (WhichOne - 1) * LEN(SS), SS
    $CHECKING:ON
    IF SS.InUse THEN
        SS.InUse = 0 'Let the routine know that we're no longer in use for this handle
        $CHECKING:OFF
        _MEMPUT SaveMem, SaveMem.OFFSET + (WhichOne - 1) * LEN(SS), SS
        $CHECKING:ON
        _FONT SS.F
        COLOR SS.DC, SS.BG
        _DEST SS.D
        _SOURCE SS.S
        IF SS.Disp THEN _AUTODISPLAY ELSE _DISPLAY
        LOCATE SS.CurY, SS.CurX
    END IF
END SUB

SUB GetNewWH (destWidth, destHeight, handle AS LONG, NewWidth, NewHeight) 'Sub return in variables NewWidth and NewHeight new image Width and image Height with the same ratio for optimal picture to set area width and height with [destWidth, destHeight]
    W = _WIDTH(handle)
    H = _HEIGHT(handle)
    Pw = W / destWidth
    Ph = H / destHeight
    IF W > H THEN P = Pw ELSE P = Ph
    NewWidth = W / P
    NewHeight = H / P
END SUB
What the review buttons does is choose how many times we review the material at hand, before we finish and take our (not yet implemented) quiz.

For example, we narrow down our list of words to "Petr, Pete, Peter".

If the Review number is one, our review list might be:  "Pete, Petr, Peter"
If the Review number is two, our review list might be:  "Pete, Petr, Peter, Petr, Peter, Pete".

It's just the number of times (from 1 to 5) which we want to set to review the material, before taking a test on it. 


Not related to this, but related to QB64 development:

If you notice, the syntax on $COLOR32 has changed a little in my version; it's now $COLOR:32.  (See that : in there?)

This is because $COLOR now has 2 modes which we can get names from -- $COLOR:32 for 32-bit color names, and $COLOR:0 for screen 0 color names. 

It's a slight change, but it makes my current version of QB64 slightly incompatible with yours, at the moment.

When this little project is finished, I'll probably just put the CONST values in an $INCLUDE file for now, so that it'll be usable for everyone -- those that keep up with the latest development builds, and those who prefer the stable 1.3 version instead.  ;)

[Petr]

Yeah, so there is a nice buzz at the beginning, with the wrong directory, but SOMEONE who entered it also for Linux no longer added support for Linux when loading the contents of the directory (ls for Linux, DIR for Windows) :-D
So i am tryed it and have query. If selecting 3 images, in Photo tags saving for this 3 photos the same flags to theme and then select review - let say to 3x. Then if i press space or next button, are this 3 photos playing (if i set this theme to search tag). So after then, when are this selected images all played, in current version starting again, but final version then start quiz. Its so correct?

[SMcNeill]

Here's a prototype of the finished product.  ;)

Things still needed:

It needs some layout work to center things better to make the screen prettier.
A prettier QUIZ results page, with pauses in case the user has a quiz with more words than can appear on a single display page.
Hard/Easy mode to be implemented for the spelling quiz --
      At the moment, all we're having is the HARD mode implemented.  (Enter the word, with no help whatsoever.)
      For easy mode, I picture it to limit word input to the proper number of letters, and to display a placeholder on the screen for the letters.  Such as for "cat", the screen will offer a prompt of three stars ("***") as placeholders to help indicate how many letters belong in the word. 

But, more or less, our little spelling training program is workable the way it already exists!  ;D

[Petr]

Nice Work, Steve. There is one very small bug - try to search tags writing "animals", not "Animals", then is none match. LCASE$ can reapir it.  Next - :) - in begin - if is program not in correct directory, yet continue.

This is big and nice work, Steve.

[SW]

congratz, Steve!

I mind its good to add multi lingual support by adding ".\en\Alphabet Sounds\" and "".\en\Word Sounds\". So you can add other pronounces(languages) for same images.