Artillery Wanted

[SierraKen]

Awesome thanks again! I used your suggestions and added what you said about the cannon angle. I also changed the window size to 1200 x 700. Plus I changed the sound to a bit deeper sound so it's not an irritating one lol. But it took about an hour to figure out what variables to use and how to do the equations you told me about. It's just 2 lines I needed, which are these, which are down below as the last lines before "RETURN".

Code: QB64: [Select]

1. cmx = cbx + (100 * COS(_D2R(a)))
2. cmy = cby + (100 * SIN(_D2R(a)))
3.  

That wraps it up for tonight on my programming, I never program late anymore like I did in the 90's. I hope to work on it more this coming week and will post my progress. :)

[johnno56]

I couldn't resist... Sorry.  A few minor tweaks. May not be the right way to do it but it seems to work.

J

Code: QB64: [Select]

1. 'Thank you to B+ for posting much of this code on the QB64.org Forum!
2.  
3. _TITLE "Ken's Artillery"
4. SCREEN _NEWIMAGE(1600, 800, 32)
5. ground = 590 'up is negative in direction
6.  
7. cbx = 10 '              cannon butt end x, y
8. cby = ground - 10
9. cmx = 50 '              cannon mouth end
10. cmy = ground - 70
11.  
12.  
13. g = .15 '       with air resistance
14. airX = -.005 '         wind blows against direction of shot
15. COLOR , _RGB32(156, 210, 237)
16. CLS ' sky
17. LINE (0, ground)-(1600, 800), _RGB32(74, 86, 58), BF 'ground
18. LINE (cbx, cby)-(cmx, cmy), _RGB32(150, 50, 0) 'cannon line
19.  
20. GOSUB coords:
21.  
22. again:
23. 'initialize
24. bx = cmx 'ball x, y same as cannon mouth at start of shot
25. by = cmy
26.  
27.  
28. dx = vel * COS(ca) 'start at cannon mouth
29. dy = vel * SIN(ca)
30.  
31. 'shot
32. DO
33.     CLS
34.     a$ = INKEY$
35.     IF a$ = CHR$(27) THEN END
36.     LINE (0, ground)-(1600, 800), _RGB32(74, 86, 58), BF 'ground
37.     LINE (cbx, cby)-(cmx, cmy), _RGB32(150, 50, 0) 'cannon line
38.     CIRCLE (bx, by), 5, _RGB32(0, 0, 0)
39.     PAINT (bx, by), _RGB32(0, 0, 0), _RGB32(0, 0, 0)
40.     dx = dx + airX
41.     dy = dy + g
42.     bx = bx + dx
43.     by = by + dy
44.     _DISPLAY
45.     _LIMIT 30
46.     IF by > ground THEN
47.         FOR explosion = 10 TO 50 STEP 0.5
48.             CIRCLE (bx, by), explosion, _RGB32(156, 210, 237)
49.             SOUND 150 + (explosion * 5), 0.07
50.         NEXT explosion
51.         FOR i = 0 TO 10 STEP 0.5
52.             CIRCLE (bx, by), i, _RGB(156, 210, 237)
53.         NEXT
54.     END IF
55. LOOP UNTIL bx > 1600 OR by > ground OR bx < 0
56. GOSUB coords:
57. GOTO again:
58. END
59. coords:
60. COLOR _RGB(0, 0, 0)
61. LOCATE 1, 1: INPUT "Power (0-80):", vel
62. LOCATE 2, 1: INPUT "Angle (0-360): ", a
63. going:
64. vel = INT(vel / 4)
65. IF a > 360 THEN a = 360
66. IF a < 0 THEN a = 0
67. IF vel < 0 THEN vel = 0
68. IF vel > 80 THEN vel = 80
69. a = 360 - a
70. ca = _D2R(a)
71. RETURN
72.  

[bplus]

Here is what I came up with after stuck with messing around with moving target in afternoon.

I went with number key press for speed setting.

So look at the Moon, set your speed number, move mouse so arrow is the angle you want to try and click the mouse to shoot.

Here is "Shoot'n for the Moon":

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Shoot'n for the Moon" 'B+ started 2019-06-23
3. RANDOMIZE TIMER
4. CONST xmax = 1200, ymax = 700, pi = 3.14159265
5.  
6. SCREEN _NEWIMAGE(xmax, ymax, 32)
7. _SCREENMOVE 100, 20
8.  
9. CONST gravity = .035
10. CONST airResistance = .01
11. CONST nStars = 127
12. CONST lnth = 100
13. CONST wallx1 = .5 * xmax - 20
14. CONST wallx2 = .5 * xmax
15.  
16. TYPE XYR
17.     x AS INTEGER
18.     y AS INTEGER
19.     r AS INTEGER
20. END TYPE
21.  
22. TYPE projectile
23.     x AS INTEGER
24.     y AS INTEGER
25.     dx AS SINGLE
26.     dy AS SINGLE
27.     a AS SINGLE 'radian angle
28.     speed AS SINGLE
29.     active AS INTEGER
30. END TYPE
31. DIM SHARED level, p AS projectile, t AS XYR, wallY, stars(1 TO nStars) AS XYR
32.  
33. 'set up stars
34. DIM i, r
35. FOR i = 1 TO 127
36.     stars(i).x = xmax * RND
37.     stars(i).y = ymax * RND
38.     r = RND
39.     SELECT CASE r
40.         CASE IS < .5: stars(i).r = 0
41.         CASE IS < .75: stars(i).r = 1
42.         CASE IS < .875: stars(i).r = 2
43.         CASE IS < .9375: stars(i).r = 3
44.         CASE ELSE: stars(i).r = 1
45.     END SELECT
46. NEXT
47.  
48. level = 1
49. COLOR , &H0 'clear background for printing on various shades of blue
50. DO
51.     DrawSpace
52.     InitTarget
53.     Target
54.     InitProjectile
55.     WHILE p.active
56.         DrawSpace 'cls
57.         Arrow
58.         Target
59.         p.dy = p.dy + gravity
60.         p.dx = p.dx + airResistance
61.         p.x = p.x + p.dx
62.         p.y = p.y + p.dy
63.         p.a = _ATAN2(p.dy, p.dx) 'reset arrow angle
64.         'IF p.a < 0 THEN p.a = p.a + 2 * pi
65.         IF ((p.x - t.x) ^ 2 + (p.y - t.y) ^ 2) ^ .5 < t.r THEN
66.             p.active = 0: BEEP ' here a beep is a good thing!
67.         ELSEIF p.x < 0 OR p.x > xmax OR p.y > ymax THEN
68.             p.active = 0
69.         ELSEIF p.x > wallx1 AND p.x < wallx2 AND p.y > wallY THEN
70.             p.active = 0
71.         END IF
72.         LOCATE 1, 1: PRINT "("; _TRIM$(STR$(p.x)); ", "; _TRIM$(STR$(p.y)); ")";
73.         _DISPLAY
74.         _LIMIT 60
75.     WEND
76.     _DELAY 3
77. LOOP
78.  
79. SUB InitProjectile
80.     DIM kh&, mx, my, mb
81.     _TITLE "Use numbers 1 to 9, 0 for 10 for speed, click mouse when arrow at fire angle to fire."
82.     p.x = 100
83.     p.y = ymax - 100
84.     p.active = 0
85.     p.speed = 0
86.     WHILE p.active = 0
87.         DrawSpace 'CLS
88.         Target
89.         Arrow
90.         kh& = _KEYHIT
91.         IF kh& >= 48 AND kh& <= 57 THEN
92.             IF kh& = 48 THEN p.speed = 10 ELSE p.speed = kh& - 48
93.         END IF
94.         WHILE _MOUSEINPUT: WEND
95.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
96.         p.a = _ATAN2(my - p.y, mx - p.x)
97.         IF p.a < 0 THEN p.a = p.a + 2 * pi
98.         p.dx = p.speed * COS(p.a): p.dy = p.speed * SIN(p.a)
99.         IF mb THEN
100.             IF p.speed THEN p.active = -1 ELSE BEEP ' <<< you forgot to set a speed!
101.         END IF
102.         LOCATE 1, 1: PRINT "Angle:"; INT(360 - _R2D(p.a));
103.         LOCATE 2, 1: PRINT "Speed:"; p.speed
104.         _DISPLAY
105.         _LIMIT 60
106.     WEND
107. END SUB
108.  
109. SUB InitTarget
110.     t.r = 55 - 5 * level
111.     wallY = RND * ymax * .5 + .25 * ymax
112.     t.x = RND * (.25 * xmax - t.r) + .75 * xmax: t.y = RND * (ymax - 2 * t.r) + t.r
113. END SUB
114.  
115. SUB DrawSpace
116.     DIM y AS INTEGER
117.     FOR y = 0 TO ymax
118.         LINE (0, y)-STEP(xmax, 0), _RGB32(35, 0, 55 * y / ymax + 10), BF
119.     NEXT
120.     FOR y = 1 TO nStars
121.         fcirc stars(y).x, stars(y).y, stars(y).r, &HFFDDEEFF
122.     NEXT
123. END SUB
124.  
125. SUB Target
126.     fcirc t.x, t.y, t.r, &HFFCFCEA3
127.     'draw wall blocking
128.     LINE (wallx1, wallY)-(wallx2, ymax), &HFFAA6600, BF
129. END SUB
130.  
131. SUB Arrow '  save these for other (x0, y0, rAngle, lngth)
132.     DIM x0, y0, x1, y1, x2, y2, rAngle, lngth, i AS INTEGER
133.     x0 = p.x: y0 = p.y: rAngle = p.a: lngth = lnth
134.     x2 = x0 - lngth * COS(rAngle)
135.     y2 = y0 - lngth * SIN(rAngle)
136.     drawLink x0, y0, .001 * lngth, x2, y2, .01 * lngth, &HFFFFFFFF
137.     LINE (x0, y0)-(x2, y2), &HFFFFFFFF
138.     x2 = x0 - .1 * lngth * COS(rAngle - .2 * pi)
139.     y2 = y0 - .1 * lngth * SIN(rAngle - .2 * pi)
140.     x1 = x0 - .1 * lngth * COS(rAngle + .2 * pi)
141.     y1 = y0 - .1 * lngth * SIN(rAngle + .2 * pi)
142.     ftri x0, y0, x1, y1, x2, y2, &HFFFF0000
143.     FOR i = .8 * lngth TO lngth STEP 3
144.         x1 = x0 - i * COS(rAngle)
145.         y1 = y0 - i * SIN(rAngle)
146.         x2 = x1 - .1 * lngth * COS(rAngle - .25 * pi)
147.         y2 = y1 - .1 * lngth * SIN(rAngle - .25 * pi)
148.         LINE (x1, y1)-(x2, y2), &HFF0000FF
149.         x2 = x1 - .1 * lngth * COS(rAngle + .25 * pi)
150.         y2 = y1 - .1 * lngth * SIN(rAngle + .25 * pi)
151.         LINE (x1, y1)-(x2, y2), &HFF0000FF
152.     NEXT
153. END SUB
154.  
155. SUB drawLink (x1, y1, r1, x2, y2, r2, c AS _UNSIGNED LONG)
156.     DIM a, a1, a2, x3, x4, x5, x6, y3, y4, y5, y6
157.     a = _ATAN2(y2 - y1, x2 - x1)
158.     a1 = a + _PI(1 / 2)
159.     a2 = a - _PI(1 / 2)
160.     x3 = x1 + r1 * COS(a1): y3 = y1 + r1 * SIN(a1)
161.     x4 = x1 + r1 * COS(a2): y4 = y1 + r1 * SIN(a2)
162.     x5 = x2 + r2 * COS(a1): y5 = y2 + r2 * SIN(a1)
163.     x6 = x2 + r2 * COS(a2): y6 = y2 + r2 * SIN(a2)
164.     fquad x3, y3, x4, y4, x5, y5, x6, y6, c
165. END SUB
166.  
167. 'need 4 non linear points (not all on 1 line) list them clockwise so x2, y2 is opposite of x4, y4
168. SUB fquad (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER, x3 AS INTEGER, y3 AS INTEGER, x4 AS INTEGER, y4 AS INTEGER, c AS _UNSIGNED LONG)
169.     ftri x1, y1, x2, y2, x4, y4, c
170.     ftri x3, y3, x4, y4, x1, y1, c
171. END SUB
172.  
173. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
174.     DIM a&
175.     a& = _NEWIMAGE(1, 1, 32)
176.     _DEST a&
177.     PSET (0, 0), K
178.     _DEST 0
179.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
180.     _FREEIMAGE a& '<<< this is important!
181. END SUB
182.  
183. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
184.     DIM Radius AS INTEGER, RadiusError AS INTEGER
185.     DIM X AS INTEGER, Y AS INTEGER
186.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
187.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
188.     LINE (CX - X, CY)-(CX + X, CY), C, BF
189.     WHILE X > Y
190.         RadiusError = RadiusError + Y * 2 + 1
191.         IF RadiusError >= 0 THEN
192.             IF X <> Y + 1 THEN
193.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
194.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
195.             END IF
196.             X = X - 1
197.             RadiusError = RadiusError - X * 2
198.         END IF
199.         Y = Y + 1
200.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
201.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
202.     WEND
203. END SUB
204.  

[johnno56]

More misses than hits... But that's normal for me... lol

But, I did notice the subtle absence of aliens and or asteroids....

[SierraKen]

Thanks for the idea Johno56. I added that to mine and also made it so the holes stay as you keep firing. Also last night I added random wind speed and it displays the amount up on top of the screen so you can try to calculate how to go with or against the wind.

[SierraKen]

LOL B+ that kicks butt! That's professional right there. :) I got the Moon once. :) Good job!

[bplus]

Thanks Ken, Johnno I find it more difficult than expected myself, the aliens are coming soon enough ;-))

Keep the holes! Great idea! Now maybe the moon wont be so full :D

I am working on a slider for speed settings so it's all mouse work: click, spin, click and we're off to the moon.

Maybe a cartoon rocket and moon would be good images. What should it sound like when you hit..., wait.. let's plant flags on the moon, wait... no wind ;-))

[SierraKen]

I'm getting closer and closer to finishing it. :) You can play the computer now and the wind speed and direction shows up on top. Plus I made a little base on each side so you can see what you are actually blowing up. lol You win or the computer wins when you blow up the other person 5 times. Am still tweaking it some so it might be a couple days until I release it. Tomorrow I will be busy all day doing other things.

[SierraKen]

I'm done with version 1. But first I'm trying to see if I can make a mountain or not, might take awhile if I can do it. lol

[SierraKen]

Post erased by original poster.

[johnno56]

Cool...  I particularly like the way the wind speed and direction changes for each shot... Do you have any plans for further development?

[SierraKen]

Thanks Johno56. At this moment I don't although later on I might think of something to add to it. I will post this to my website after B+ checks it out and I will put both names on the site. Actually 1 thing I will add is saying "5 Points Wins" somewhere so people know how long the game is. I think I'm going to make a splash screen (welcome screen) with the basic instructions with B+ and your name on it. I'll add the code in a few minutes to this forum.

[johnno56]

Thank you. But credit is not necessary. In the meantime, I will keep my eye open for upgrades... lol (No pressure, right?)

[SierraKen]

LOL thanks Johnno56. Well, I did find some problems with the last one, for example, there wasn't explosions on the normal ground below older explosions, so I fixed that and a couple other things. I also added the welcome screen. Here is (possibly) the final version. I'll erase the code on my last post.
B+ what do you think of it? :) You helped me with most of the math code so I put your name on it.

Edit: Finding more problems.. will look this over more and then post. Sorry for any problems this caused.

[bplus]

Hi Ken,

I wrote some code for making very very simple mountains:

Code: QB64: [Select]

1. _TITLE " by bplus"
2. 'QB64 v1.3
3. CONST xmax = 1200
4. CONST ymax = 700
5. SCREEN _NEWIMAGE(xmax, ymax, 32)
6. _SCREENMOVE (1280 - xmax) / 2 + 30, (760 - ymax) / 2
7. RANDOMIZE TIMER
8. COLOR , _RGB32(110, 110, 255)
9. WHILE _KEYHIT <> 32
10.     CLS
11.     MakeMountain xmax / 2, (ymax - 100) * .8, ymax - 100
12.     _DELAY 2
13. WEND
14.  
15. SUB MakeMountain (xcenter, maxHeight, mountainbaseY)
16.     centerDist = 15 * RND + 15
17.     FOR i = 1 TO 5
18.         IF RND < .5 THEN dir = -1 ELSE dir = 1
19.         xc = xcenter + dir * centerDist
20.         yc = maxHeight - centerDist - RND * 25
21.         xl = xc - rrnd(1.25 * yc, yc)
22.         xr = xc + rrnd(1.25 * yc, yc)
23.         IF mountainbaseY - yc < mountainbaseY THEN
24.             ftri xl, mountainbaseY, xc, mountainbaseY - yc, xr, mountainbaseY, _RGB32(110 - i * 4, RND * 20 + 100 - i * 2, 100 - i * 8)
25.         ELSE
26.             EXIT FOR
27.         END IF
28.         centerDist = centerDist + 40 * RND + 30
29.     NEXT
30. END SUB
31.  
32. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
33.     a& = _NEWIMAGE(1, 1, 32)
34.     _DEST a&
35.     PSET (0, 0), K
36.     _DEST 0
37.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
38.     _FREEIMAGE a& '<<< this is important!
39. END SUB
40. FUNCTION rrnd (n1, n2) 'return real number (_single, double, _float depending on default / define setup)
41.     rrnd = (n2 - n1) * RND + n1
42. END FUNCTION
43.  

I tried to install it into your game and ran into one thing after another so I am trying to overhaul it so I can understand it and not ruin that great AI shooter you have going!