Analog Clock

[SierraKen]

Hi all,

I just made this analog clock today. I've wanted to make one for around 30 years and could never figure it out. So today I found an old QBasic version I had from probably the 1990's or so so I tried to research that a bit again. It was from a guy named Chris Procter who put it online back then. So I simplified the code a lot and updated it using the QB64 _DELAY command. Thank you Chris, wherever you are, for these math equations! I put it on my website, but here is the code below as well. If you wish to see other programs I've made, my website is here: http://ken.x10host.com/qb64/

So here it is, my brand new shiny analog clock that after 30 years I finally could make:

Code: QB64: [Select]

1. 'This is my first analog clock!
2. 'Thank you to someone named Chris Procter who put a QBasic clock online around 20 years ago or so.
3. 'I used some of his math to make this clock.
4. 'This clock was updated and simplified a lot using the QB64 _DELAY command.
5. 'This was made by Ken G. and is freeware.
6. _TITLE "Analog Clock"
7. SCREEN 12
8. CIRCLE (325, 225), 182, 15
9. go:
10. _LIMIT 500
11. _DELAY 1
12. hours = TIMER \ 3600
13. minutes = TIMER \ 60 - hours * 60
14. seconds = (TIMER - hours * 3600 - minutes * 60)
15. 'Seconds
16. s = (60 - seconds) * 6 + 180
17. LINE (325, 225)-(x, y), 0
18. x = INT(SIN(s / 180 * 3.141592) * 180) + 325
19. y = INT(COS(s / 180 * 3.141592) * 180) + 225
20. LINE (325, 225)-(x, y), 15
21. 'Minutes
22. m = 180 - minutes * 6
23. LINE (325, 225)-(xx, yy), 0
24. xx = INT(SIN(m / 180 * 3.141592) * 180) + 325
25. yy = INT(COS(m / 180 * 3.141592) * 180) + 225
26. LINE (325, 225)-(xx, yy), 15
27. 'Hours
28. h = 360 - hours * 30 + 180
29. LINE (325, 225)-(xxx, yyy), 0
30. xxx = INT(SIN(h / 180 * 3.141592) * 100) + 325
31. yyy = INT(COS(h / 180 * 3.141592) * 100) + 225
32. LINE (325, 225)-(xxx, yyy), 15
33. GOTO go:
34.  
35.  

[SMcNeill]

Here's the same clock as yours, Ken, except I've modified it to use a SUB to draw the hands for us.  I've noticed you don't make use of SUB/FUNCTIONs in your code much, so I thought I'd take a moment and help highlight the difference for you, so you can see how much more efficient your coding can become, once you get used to using them in your projects.

Code: QB64: [Select]

1. _TITLE "Analog Clock"
2. SCREEN 12
3.  
4. DO
5.     CLS
6.     CIRCLE (325, 225), 182, 15
7.     _LIMIT 1
8.     hours = TIMER \ 3600
9.     minutes = TIMER \ 60 - hours * 60
10.     seconds = (TIMER - hours * 3600 - minutes * 60)
11.     DrawHand (60 - seconds) * 6 + 180, 180 'Second hand
12.     DrawHand 180 - minutes * 6, 180 'Minute hand
13.     DrawHand 360 - hours * 30 + 180, 100 'Hour hand
14.     _DISPLAY
15. LOOP
16.  
17. SUB DrawHand (value, scale)
18.     X = INT(SIN(value / 180 * 3.141592) * scale) + 325
19.     Y = INT(COS(value / 180 * 3.141592) * scale) + 225
20.     LINE (325, 225)-(X, Y), 15
21. END SUB

[SierraKen]

Wow Ron that's incredible! I like how you did all the lines. I don't really understand the math part but I may update my clock someday.

[SierraKen]

SMcNeill, that is really amazing. I was never taught SUB's because I took the old BASIC programming classes in the 1980's and they didn't have those back then. That was back when each line was numbered as well lol. In 1995 some people on comp.lang.basic.misc newsgroup taught me the difference between those and QBasic and I took it from there. I've seen many SUB's over the years but I only vaguely understand them. I've always thought they were kinda like GOSUB/RETURN's or GOTO's. But just a tiny bit. Every time I program I work from top to bottom or in paths that the computer would read. That is why I never really got past BASIC languages, because they are not structured really in paths but more in "all of this happens at once" or something. lol But what I can tell about SUB's are that they are lines of code that can be called up in other places in the program when needed. I suppose that can be handy when a program needs the same code more than once and doesn't have to use IF/THEN's using variables to figure out when code is needed. I might learn it someday, thanks.

[SMcNeill]

Ken — you’ve been using SUBs and FUNCTIONs since the first time you started programming back in 95.  ;)

All a SUB is, is a basic routine which you decide you need to repeat multiple times in your code.

In your original, you use several in-built SUBs — CLS, CIRCLE, LINE, _LIMIT, _DELAY.

CLS is basically just a routine which clears the screen.  Circle just draws a circle where you specify.  You could write your own routines and do the exact same things, if you wanted to — and that’s all a SUB is.

For example:

Code: QB64: [Select]

1. FOR I = 1 TO 10
2. PRINT I
3. NEXT
4. SLEEP
5. CLS
6. SLEEP

And, to do the same with your own SUB:

Code: QB64: [Select]

1. FOR I = 1 TO 10
2. PRINT I
3. NEXT
4. SLEEP
5. ClearScreen
6. SLEEP
7.  
8. SUB ClearScreen
9. LOCATE 1,1 ‘start at the very top corner
10. FOR I = 1 TO 100
11. PRINT SPACE$(_WIDTH) ‘print enough blank lines to erase the screen
12. NEXT
13. LOCATE 1,1 ‘move the print position back to the top left corner
14. END SUB
15.  

SUBs basically just say, “Repeat this process when needed”, while allowing the programmer the flexibility to customize their own routines and easily move them into other programs as needed.

[SierraKen]

WOW that is so cool, thanks! I will try it soon.

I just improved the looks of my clock, I experimented with the math and made little circles all around the clock and also made it look better.

Code: QB64: [Select]

1. 'This is my first analog clock!
2. 'Thank you to someone named Chris Procter who put a QBasic clock online around 20 years ago or so.
3. 'I used some of his math to make this clock.
4. 'This clock was updated and simplified a lot using the QB64 _DELAY command.
5. 'This was made by Ken G. and is freeware.
6. _TITLE "Analog Clock"
7. SCREEN 12
8. CIRCLE (327, 225), 184, 15
9. CIRCLE (325, 225), 215, 15
10. LOCATE 2, 41: PRINT "12"
11. LOCATE 15, 16: PRINT "9"
12. LOCATE 15, 66: PRINT "3"
13. LOCATE 27, 41: PRINT "6"
14. go:
15. _LIMIT 500
16. _DELAY 1
17. FOR sc = 1 TO 60
18.     ss = (60 - sc) * 6 + 180
19.     x2 = INT(SIN(ss / 180 * 3.141592) * 180) + 5
20.     y2 = INT(COS(ss / 180 * 3.141592) * 180) + 5
21.     x2 = x2 + 323
22.     y2 = y2 + 220
23.     CIRCLE (x2, y2), 3, 15
24. NEXT sc
25. hours = TIMER \ 3600
26. minutes = TIMER \ 60 - hours * 60
27. seconds = (TIMER - hours * 3600 - minutes * 60)
28. 'Seconds
29. s = (60 - seconds) * 6 + 180
30. LINE (325, 225)-(x, y), 0
31. x = INT(SIN(s / 180 * 3.141592) * 180) + 325
32. y = INT(COS(s / 180 * 3.141592) * 180) + 225
33. LINE (325, 225)-(x, y), 15
34. 'Minutes
35. m = 180 - minutes * 6
36. LINE (325, 225)-(xx, yy), 0
37. xx = INT(SIN(m / 180 * 3.141592) * 180) + 325
38. yy = INT(COS(m / 180 * 3.141592) * 180) + 225
39. LINE (325, 225)-(xx, yy), 15
40. 'Hours
41. h = 360 - hours * 30 + 180
42. LINE (325, 225)-(xxx, yyy), 0
43. xxx = INT(SIN(h / 180 * 3.141592) * 100) + 325
44. yyy = INT(COS(h / 180 * 3.141592) * 100) + 225
45. LINE (325, 225)-(xxx, yyy), 15
46. GOTO go:
47.  

[SierraKen]

Note: Anyone that got my Alarm Clock on the evening of Friday, June 22 or morning of June 23 please delete it. It had 1 error in it that set the alarm off at midnight LOL. I will paste the new one below, as well as another addition I added to it.

[bplus]

What another clock?!?!

Yeah, but this has an alarm and a little surprise... ;-))

Code: QB64: [Select]

1. OPTION _EXPLICIT 'B+ 2019-06-22
2. CONST RED = &HFFFF0000, GREEN = &HFF009000, BLUE = &HFF0000FF, WHITE = &HFFFFFFFF, CYAN = &HFF00A8A8
3. CONST BLACK = &HFF000000, YELLOW = &HFFFFFF00, PURPLE = &HFF800082, ORANGE = &HFFD26200
4. CONST xmax = 320, ymax = 320, x0 = xmax / 2, y0 = ymax / 2, p = 3.14159265, p2 = p * 2, pd2 = p / 2
5. DIM SHARED alarm$
6.  
7. SCREEN _NEWIMAGE(320, 320, 32)
8. _SCREENMOVE 300, 100
9. COLOR CYAN
10. WHILE 1
11.     outputClock
12.     IF UCASE$(INKEY$) = "A" THEN setAlarm
13.     _DISPLAY
14.     _LIMIT 60
15. WEND
16.  
17. SUB outputClock
18.     DIM i AS INTEGER, t, x, y, ha, ma, sa
19.     IF alarm$ = "" THEN _TITLE "<a> to Set Alarm Clock" ELSE _TITLE "Alarm Clock is Set"
20.     CLS
21.     FOR i = 0 TO 59
22.         x = x0 + .9 * y0 * COS(i / 60 * p2 - pd2)
23.         y = y0 + .9 * y0 * SIN(i / 60 * p2 - pd2)
24.         IF i MOD 5 = 0 THEN CIRCLE (x, y), 3, ORANGE ELSE CIRCLE (x, y), 2, PURPLE
25.     NEXT
26.     t = TIMER
27.     ha = (t / 3600) / 12 * p2 - pd2
28.     ma = (t / 60 - 60 * INT(ha)) / 60 * p2 - pd2
29.     sa = (t - INT(ha) * 3600 - INT(ma) * 60) / 60 * p2 - pd2
30.     arm y0 * .9, sa, GREEN: arm y0 * .85, ma, YELLOW: arm y0 * .65, ha, BLUE
31.     LOCATE 20, 1: PRINT TIME$;
32.     IF alarm$ <> "" THEN
33.         COLOR PURPLE: LOCATE 20, 34: PRINT "@";: COLOR RED: PRINT alarm$;: COLOR CYAN
34.         IF MID$(TIME$, 1, 5) = alarm$ THEN
35.             _TITLE "Press any to stop beeping..."
36.             _SCREENMOVE 300 + RND * 25, 100 + RND * 25: BEEP
37.         END IF
38.         IF LEN(INKEY$) THEN alarm$ = ""
39.     END IF
40. END SUB
41.  
42. SUB arm (radius AS INTEGER, radians AS SINGLE, colr AS _UNSIGNED LONG)
43.     LINE (x0, y0)-STEP(radius * COS(radians), radius * SIN(radians)), colr
44. END SUB
45.  
46. SUB setAlarm
47.     CLS: LOCATE 8, 2: PRINT "For time: hh = 00-23 : mm = 00-59"
48.     LOCATE 10, 2: INPUT "Enter hh:mm "; alarm$
49. END SUB
50.  

[SierraKen]

Here is my newest update. I apologize for the last Alarm Clock, it accidentally set the alarm off at midnight lol. Here is the fixed version as well as a new addition to it which plays the hour chimes every hour on top of the hour. I found this QB64 code on the Wiki page for chimes. :))) Thank you!

Code: QB64: [Select]

1. 'This is my first analog clock!
2. 'Thank you to someone named Chris Procter who put a QBasic clock online around 20 years ago or so.
3. 'I used some of his math to make this clock.
4. 'This clock was updated and simplified a lot using the QB64 _DELAY command.
5. 'This was made by Ken G. and is freeware.
6. _TITLE "Analog Alarm Clock"
7. SCREEN 12
8. CLS
9. PRINT "                              Analog Alarm Clock"
10. PRINT: PRINT: PRINT
11. PRINT "                                  By Ken G."
12. PRINT: PRINT: PRINT
13. PRINT "                To set alarm, start clock and then press 'A' to set."
14. PRINT "                    Hours must be set to a 24 hour scale (0-23)."
15. PRINT "             The clock will chime the hours every hour on top of the hour."
16. PRINT "   To shut off clock, press 'Q' or click the X button on the upper right corner."
17. PRINT: PRINT: PRINT
18. PRINT "                         Press any key to start clock.",
19. gggo:
20. _LIMIT 500
21. st$ = INKEY$
22. IF st$ = CHR$(27) THEN END
23. IF st$ <> "" THEN CLS: GOTO drawing:
24. GOTO gggo:
25. drawing:
26. COLOR 15, 0
27. CIRCLE (327, 225), 184, 15
28. CIRCLE (325, 225), 215, 15
29. LOCATE 2, 41: PRINT "12"
30. LOCATE 15, 16: PRINT "9"
31. LOCATE 15, 66: PRINT "3"
32. LOCATE 27, 41: PRINT "6"
33. IF set = 1 THEN
34.     LOCATE 24, 63: PRINT "Alarm Set At:"
35.     LOCATE 25, 63: PRINT "Hour:"; hr
36.     LOCATE 26, 63: PRINT "Minute:"; mn
37.     LOCATE 27, 63: PRINT "Second:"; se
38. END IF
39. go:
40. a$ = INKEY$
41. IF a$ = "q" OR a$ = "Q" THEN END
42. IF a$ = "a" OR a$ = "A" THEN
43.     CLS
44.     PRINT "                           Set Alarm"
45.     PRINT: PRINT: PRINT
46.     hourset:
47.     INPUT "Hour (24 Hour Format 0-23): ", hr
48.     IF hr < 0 OR hr > 23 THEN GOTO hourset:
49.     IF hr <> INT(hr) THEN GOTO hourset:
50.     PRINT
51.     minuteset:
52.     INPUT "Minute: ", mn
53.     IF mn < 0 OR mn > 59 THEN GOTO minuteset:
54.     IF mn <> INT(mn) THEN GOTO minuteset:
55.     PRINT
56.     secondset:
57.     INPUT "Second: ", se
58.     IF se < 0 OR se > 59 THEN GOTO secondset:
59.     IF se <> INT(se) THEN GOTO secondset:
60.     set = 1
61.     CLS
62.     GOTO drawing:
63. END IF
64. _LIMIT 500
65. _DELAY 1
66. FOR sc = 1 TO 60
67.     ss = (60 - sc) * 6 + 180
68.     x2 = INT(SIN(ss / 180 * 3.141592) * 180) + 5
69.     y2 = INT(COS(ss / 180 * 3.141592) * 180) + 5
70.     x2 = x2 + 323
71.     y2 = y2 + 220
72.     CIRCLE (x2, y2), 3, 15
73. NEXT sc
74. hours = TIMER \ 3600
75. minutes = TIMER \ 60 - hours * 60
76. seconds = (TIMER - hours * 3600 - minutes * 60)
77. 'Check For Alarm
78. t$ = TIME$
79. LOCATE 1, 1: PRINT t$
80. ho$ = LEFT$(TIME$, 2): hou = VAL(ho$)
81. min$ = MID$(TIME$, 4, 2): minu = VAL(min$)
82. seco$ = RIGHT$(TIME$, 2): secon = VAL(seco$)
83. IF hou = hr AND minu = mn AND secon = se AND set = 1 THEN
84.     sounds:
85.     _DELAY .05
86.     alarm = alarm + 50
87.     IF alarm = 800 THEN alarm = 100
88.     SOUND alarm, .5
89.     clr = clr + 1: IF clr = 15 THEN clr = 1
90.     COLOR clr, 0
91.     LOCATE 1, 20: PRINT "ALARM IS GOING OFF! - Press Space Bar to stop."
92.     al$ = INKEY$
93.     IF al$ = " " OR al$ = CHR$(27) THEN
94.         CLS
95.         set = 0
96.         alarm = 0: clr = 0: hr = 0: mn = 0: se = 0
97.         a$ = "": al$ = ""
98.         _DELAY 1
99.         GOTO drawing:
100.     END IF
101.     GOTO sounds:
102. END IF
103. 'Seconds
104. s = (60 - seconds) * 6 + 180
105. LINE (325, 225)-(x, y), 0
106. x = INT(SIN(s / 180 * 3.141592) * 180) + 325
107. y = INT(COS(s / 180 * 3.141592) * 180) + 225
108. LINE (325, 225)-(x, y), 15
109. 'Minutes
110. m = 180 - minutes * 6
111. LINE (325, 225)-(xx, yy), 0
112. xx = INT(SIN(m / 180 * 3.141592) * 180) + 325
113. yy = INT(COS(m / 180 * 3.141592) * 180) + 225
114. LINE (325, 225)-(xx, yy), 15
115. 'Hours
116. h = 360 - hours * 30 + 180
117. LINE (325, 225)-(xxx, yyy), 0
118. xxx = INT(SIN(h / 180 * 3.141592) * 100) + 325
119. yyy = INT(COS(h / 180 * 3.141592) * 100) + 225
120. LINE (325, 225)-(xxx, yyy), 15
121. 'Chimes
122. IF minu = 0 AND secon = 0 AND alarm = 0 THEN
123.     hour2 = hou
124.     IF hour2 > 12 THEN hour2 = hour2 - 12
125.     IF hour2 = 0 THEN hour2 = 12
126.     FOR chimes = 1 TO hour2
127.         ttt = 0
128.         DO
129.             'queue some sound
130.             DO WHILE _SNDRAWLEN < 0.1 'you may wish to adjust this
131.                 sample = SIN(ttt * 340 * ATN(1) * 8) '340Hz sine wave (ttt * 440 * 2p)
132.                 sample = sample * EXP(-ttt * 3) 'fade out eliminates clicks after sound
133.                 _SNDRAW sample
134.                 ttt = ttt + 1 / _SNDRATE 'sound card sample frequency determines time
135.             LOOP
136.             'do other stuff, but it may interrupt sound
137.         LOOP WHILE ttt < 2 'play for 2 seconds
138.         DO WHILE _SNDRAWLEN > 0 'Finish any left over queued sound!
139.         LOOP
140.     NEXT chimes
141. END IF
142. GOTO go:
143.  

[SierraKen]

LOL bplus, that's hilarious. :). The window bounces around lol. Good job.

[bplus]

Hey Kennith, those chimes sound pretty good!

[SierraKen]

Thanks B+! I think I got the code from the QB64 wiki page. :)