Pascal's Triangle Pinball Demo

[Qwerkey]

Pascal's Triangle is a construction to give the binomial coefficients.  Machines have been constructed to show a physical analogue of this (see en.wikipedia.org/wiki/Bean_machine for details of this).  This program is a simulation of a triangular pinball table which demonstrates (closely) the same thing.

Ball's fall through the pin board under a constant force (gravity) and bounce off the pins through the array and exit at the bottom.  The program uses full bouncing mechanics at each pin, with friction and non-ideal elastics collisions.  At each pin there is a 50% chance of the ball leaving to the left or right, which is the condition required to obtain the Pascal's Triangle numbers.

In the real constructed machines, a large number of balls simultaneously fall through the pin array and accumulate in columns at the bottom.  In this simulation, balls fall through one-at-a-time and are counted at the exits at the bottom.  The numbers through each exit are displayed in a histogram (Sorry, Fellippe, I couldn't do the ball columns!).  Beneath the histogram, figures are given in ratio to the expected binomial coefficients, scaled to the central column: if each pin collision were perfectly 50% left-right, each of the displayed figures would be exactly 1.

The balls are moving under constant force and (apart from the friction and inelastic collisions) would achieve high speeds, and consequently each ball experiences many collisions as it travels through the array.  This would have made the display very slow, and the program is adjusted to put an image to the screen at a fraction of the calculation cycle.  You may find that ball movement flicker is improved if you adjust line 4 of the code [FrameRate% = 60] to change the Constant FrameRate% to your monitor's refresh rate.

Because only one ball at a time travels through the pinboard, the histogram accumulation is rather slow and if you are interested to get to reasonable numbers, you'll have to allow the program to run for some time.

I had thought that I would need to place additional pins to the left and right of the triangle to prevent any ball exiting the triangle after an appropriate bounce.  However, I have never seen such a problem and the balls always stay within the triangle (it'll be interesting if anybody ever finds such an event - the program is likely to crash if this did happen).

You will need the whiteball and icon images and the cyberbit font file which comes with QB64.

Code: QB64: [Select]

1. 'Pascal's Triangle Simulation by QWERKEY 04/05/19
2.  
3. CONST True = -1, False = 0
4. CONST FrameRate% = 60, CalcRate% = 600
5. CONST BallDiam%% = 60, PinRad%% = 7, Separation%% = (BallDiam%% / 2) + PinRad%%, Spacing%% = BallDiam%% + (2 * PinRad%%) + 6
6. CONST H0! = SQR(0.75), H! = Spacing%% * H0!
7. CONST XScreen% = 980, YScreen% = 820, SmallBit! = 0.2, CornRad%% = 50, NoBallsLess1%% = 4
8. CONST A1%% = 16 + BallDiam%% + CornRad%%, A2%% = 8 + BallDiam%% / 2, A3%% = CornRad%% + 8 + BallDiam%% / 2
9. CONST A4%% = 16 + BallDiam%%, A5%% = 8 + BallDiam%%
10. CONST HistBase% = 380, HistHeight% = 340, HistWidth%% = 22, HistSepn%% = 5, HistBlock%% = 20
11. CONST G! = 0.2, F! = 0.97, W! = 0.8, Z! = 0.05, Bagatelle! = 0.8, Omega! = Bagatelle! / A3%%, SpeedLimit! = 3.5
12. DIM Pascal%(1, 8), Nos&(10), Pins!(1, 53), Vect!(NoBallsLess1%%, 4), DoPascal%%(NoBallsLess1%%, 6)
13.  
14. _TITLE "Pascal's Triangle"
15. $EXEICON:'.\blaise2.ico'
16. RANDOMIZE (TIMER)
17.  
18. DATA 1,8,28,56,70,56,28,8,1
19. FOR N%% = 0 TO 8
20.     READ Pascal%(0, N%%)
21. NEXT N%%
22. 'Images
23. TempImg& = _NEWIMAGE(BallDiam%%, BallDiam%%, 32)
24. _DEST TempImg&
25. _PUTIMAGE (0, 0)-(BallDiam%% - 1, BallDiam%% - 1), _LOADIMAGE("whiteball.png", 32)
26. Ball& = MakeHardware&(TempImg&)
27. Pin& = _NEWIMAGE(PinRad%% * 2 + 1, PinRad%% * 2 + 1, 32)
28. _DEST Pin&
29. FOR N%% = PinRad%% TO 1 STEP -1
30.     CIRCLE (PinRad%%, PinRad%%), N%%, _RGB32(CINT(181 * (N%% + 5) / (PinRad%% + 5)), CINT(166 * (N%% + 5) / (PinRad%% + 5)), CINT(66 * (N%% + 5) / (PinRad%% + 5)))
31.     PAINT (PinRad%%, PinRad%%), _RGB32(CINT(181 * (N%% + 5) / (PinRad%% + 5)), CINT(166 * (N%% + 5) / (PinRad%% + 5)), CINT(66 * (N%% + 5) / (PinRad%% + 5)))
32. NEXT N%%
33. B& = _NEWIMAGE(128, 128, 32)
34. _DEST B&
35. COLOR _RGB32(100, 100, 100), _RGB32(230, 230, 20)
36. CLS
37. Corn& = _NEWIMAGE(A1%%, A1%%, 32)
38. _DEST Corn&
39. COLOR _RGB32(229, 170, 112)
40. CIRCLE (0, 0), CornRad%%
41. CIRCLE (0, 0), A1%% - 1
42. PAINT (CornRad%% + 1, 1)
43. COLOR _RGB32(193, 117, 46)
44. CIRCLE (0, 0), CornRad%%
45. CIRCLE (0, 0), CornRad%% + 8
46. PAINT (CornRad%% + 1, 1)
47. CIRCLE (0, 0), A1%% - 1 - 8
48. CIRCLE (0, 0), A1%% - 1
49. PAINT (A1%% - 8, 1)
50. TempImg& = _NEWIMAGE(XScreen%, YScreen%, 32)
51. _DEST TempImg&
52. T% = 0
53. FOR N%% = 0 TO 8
54.     FOR M%% = -(N%% + 1) TO (N%% + 1) STEP 2
55.         _PUTIMAGE ((XScreen% / 2) + CINT(M%% * Spacing%% / 2) - PinRad%%, A1%% + 30 - PinRad%% + CINT(H! * N%%)), Pin&
56.         Pins!(0, T%) = (XScreen% / 2) + (M%% * Spacing%% / 2)
57.         Pins!(1, T%) = A1%% + 30 + (H! * N%%)
58.         T% = T% + 1
59.     NEXT M%%
60. NEXT N%%
61. L% = 700
62. T% = 130
63. _MAPTRIANGLE (0, 127)-(63, 127)-(63, 16), B& TO(L% + 0, T% + 127)-(L% + 63, T% + 127)-(L% + 63, T% + 16)
64. _MAPTRIANGLE (127, 127)-(63, 127)-(63, 16), B& TO(L% + 127, T% + 127)-(L% + 63, T% + 127)-(L% + 63, T% + 16)
65. COLOR _RGB32(0, 0, 0), _RGB32(230, 230, 20)
66. font& = _LOADFONT("cyberbit.ttf", 30, "bold")
67. _FONT font&
68. _PRINTSTRING (L% + 54, T% + 32), "P"
69. _PRINTSTRING (L% + 38, T% + 63), "A"
70. _PRINTSTRING (L% + 68, T% + 63), "S"
71. _PRINTSTRING (L% + 22, T% + 94), "C"
72. _PRINTSTRING (L% + 52, T% + 94), "A"
73. _PRINTSTRING (L% + 82, T% + 94), "L"
74. _FONT 16
75. _FREEFONT font&
76. LINE (90, YScreen% - 1)-(XScreen% - 1 - A1%%, YScreen% - 1 - A4%%), _RGB32(229, 170, 112), BF
77. LINE (90, YScreen% - 1)-(XScreen% - 1 - A1%%, YScreen% - 1 - 8), _RGB32(193, 117, 46), BF
78. LINE (90, YScreen% - 1 - A4%%)-(120, YScreen% - 1 - A5%%), _RGB32(193, 117, 46), BF
79. LINE (90, YScreen% - 1 - A4%%)-(98, YScreen% - 1), _RGB32(193, 117, 46), BF
80. LINE (121, YScreen% - 1 - A4%%)-(XScreen% - 1 - A1%%, YScreen% - 1 - A5%%), _RGBA32(193, 117, 46, 80), BF
81. LINE (XScreen% - 1 - A4%%, A1%%)-(XScreen% - 1, YScreen% - 1 - A1%%), _RGB32(229, 170, 112), BF
82. LINE (XScreen% - 1 - 8, A1%%)-(XScreen% - 1, YScreen% - 1 - A1%%), _RGB32(193, 117, 46), BF
83. LINE (XScreen% - 1 - A5%%, A1%%)-(XScreen% - 1 - A5%% - 8, YScreen% - 1 - A1%%), _RGB32(193, 117, 46), BF
84. LINE (XScreen% / 2 + BallDiam%% / 2 + CornRad%%, 0)-(XScreen% - 1 - A1%%, A4%%), _RGB32(229, 170, 112), BF
85. LINE (XScreen% / 2 + BallDiam%% / 2 + CornRad%%, 0)-(XScreen% - 1 - A1%%, 8), _RGB32(193, 117, 46), BF
86. LINE (XScreen% / 2 + BallDiam%% / 2 + CornRad%%, A4%% - 8)-(XScreen% - 1 - A1%%, A4%%), _RGB32(193, 117, 46), BF
87. _PUTIMAGE (XScreen% - 1 - A1%%, YScreen% - 1 - A1%%), Corn&
88. _MAPTRIANGLE (0, 0)-(A1%% - 1, 0)-(A1%% - 1, A1%% - 1), Corn& TO(XScreen% - 1 - A1%%, A1%%)-(XScreen% - 1 - A1%%, 0)-(XScreen% - 1, 0)
89. _MAPTRIANGLE (A1%% - 1, A1%% - 1)-(0, A1%% - 1)-(0, 0), Corn& TO(XScreen% - 1, 0)-(XScreen% - 1, A1%%)-(XScreen% - 1 - A1%%, A1%%)
90. _MAPTRIANGLE (0, 0)-(A1%% - 1, 0)-(A1%% - 1, A1%% - 1), Corn& TO(XScreen% / 2 + A3%%, A1%%)-(XScreen% / 2 - A2%%, A1%%)-(XScreen% / 2 - A2%%, 0)
91. _MAPTRIANGLE (A1%% - 1, A1%% - 1)-(0, A1%% - 1)-(0, 0), Corn& TO(XScreen% / 2 - A2%%, 0)-(XScreen% / 2 + A3%%, 0)-(XScreen% / 2 + A3%%, A1%%)
92. Background& = MakeHardware&(TempImg&)
93. _FREEIMAGE Pin&
94. _FREEIMAGE B&
95. _FREEIMAGE Corn&
96. TempImg& = _NEWIMAGE(20, 240, 32)
97. _DEST TempImg&
98. COLOR _RGB32(100, 100, 100), _RGB32(80, 240, 40)
99. CLS
100. Histo& = MakeHardware&(TempImg&)
101. FOR N%% = 0 TO 9
102.     No& = _NEWIMAGE(8, 14, 32)
103.     _DEST No&
104.     COLOR _RGB32(255, 30, 80)
105.     _PRINTSTRING (0, 0), LTRIM$(STR$(N%%))
106.     Nos&(N%%) = _NEWIMAGE(14, 8, 32)
107.     _DEST Nos&(N%%)
108.     _MAPTRIANGLE (0, 0)-(7, 0)-(0, 13), No& TO(13, 0)-(13, 7)-(0, 0)
109.     _MAPTRIANGLE (7, 13)-(0, 13)-(7, 0), No& TO(0, 7)-(0, 0)-(13, 7)
110.     _FREEIMAGE No&
111. NEXT N%%
112. No& = _NEWIMAGE(8, 14, 32)
113. _DEST No&
114. COLOR _RGB32(255, 30, 80)
115. _PRINTSTRING (0, 0), "."
116. Nos&(10) = _NEWIMAGE(14, 8, 32)
117. _DEST Nos&(10)
118. _MAPTRIANGLE (0, 0)-(7, 0)-(0, 13), No& TO(13, 0)-(13, 7)-(0, 0)
119. _MAPTRIANGLE (7, 13)-(0, 13)-(7, 0), No& TO(0, 7)-(0, 0)-(13, 7)
120. _FREEIMAGE No&
121. 'Initialise
122. MaxBar% = 0
123. C%% = False
124. DoPascal%%(0, 0) = True
125. DoPascal%%(0, 1) = False
126. DoPascal%%(0, 2) = False
127. DoPascal%%(0, 3) = False
128. DoPascal%%(0, 4) = False
129. DoPascal%%(0, 5) = False
130. DoPascal%%(0, 6) = False
131. Vect!(0, 0) = XScreen% / 2
132. Vect!(0, 1) = A1%% + 10
133. Vect!(0, 2) = Z! * (0.5 - RND)
134. Vect!(0, 3) = 0.3 + (0.2 * RND)
135. DoPascal%%(1, 0) = False
136. DoPascal%%(1, 1) = False
137. DoPascal%%(1, 2) = False
138. DoPascal%%(1, 3) = True
139. DoPascal%%(1, 4) = False
140. DoPascal%%(1, 5) = False
141. DoPascal%%(1, 6) = False
142. Vect!(1, 0) = XScreen% - A1%%
143. Vect!(1, 1) = A2%%
144. Vect!(1, 2) = -Bagatelle!
145. Vect!(1, 3) = 0
146. DoPascal%%(2, 0) = False
147. DoPascal%%(2, 1) = False
148. DoPascal%%(2, 2) = True
149. DoPascal%%(2, 3) = False
150. DoPascal%%(2, 4) = False
151. DoPascal%%(2, 5) = False
152. DoPascal%%(2, 6) = False
153. Vect!(2, 0) = XScreen% - A2%%
154. Vect!(2, 1) = A1%% + 10
155. Vect!(2, 2) = 0
156. Vect!(2, 3) = -Bagatelle!
157. DoPascal%%(3, 0) = False
158. DoPascal%%(3, 1) = False
159. DoPascal%%(3, 2) = True
160. DoPascal%%(3, 3) = False
161. DoPascal%%(3, 4) = False
162. DoPascal%%(3, 5) = False
163. DoPascal%%(3, 6) = False
164. Vect!(3, 0) = XScreen% - A2%%
165. Vect!(3, 1) = YScreen% - 1 - A1%% - 10
166. Vect!(3, 2) = 0
167. Vect!(3, 3) = -Bagatelle!
168. DoPascal%%(4, 0) = False
169. DoPascal%%(4, 1) = True
170. DoPascal%%(4, 2) = False
171. DoPascal%%(4, 3) = False
172. DoPascal%%(4, 4) = False
173. DoPascal%%(4, 5) = False
174. DoPascal%%(4, 6) = False
175. Vect!(4, 0) = XScreen% / 2
176. Vect!(4, 1) = YScreen% - A2%%
177. Vect!(4, 2) = 1.8 * Bagatelle!
178. Vect!(4, 3) = 0
179.  
180. SCREEN _NEWIMAGE(XScreen%, YScreen%, 32)
181. _SCREENMOVE 50, 0
182. _DEST 0
183. WHILE INKEY$ = ""
184.     _LIMIT CalcRate%
185.     DispCount% = DispCount% + 1
186.     'Display Images
187.     IF DispCount% = CINT(CalcRate% / FrameRate%) THEN
188.         'CLS
189.         _PUTIMAGE (0, 0), Background&
190.         FOR N%% = 0 TO NoBallsLess1%%
191.             _PUTIMAGE (CINT(Vect!(N%%, 0) - (BallDiam%% / 2)), CINT(Vect!(N%%, 1) - (BallDiam%% / 2))), Ball&
192.         NEXT N%%
193.         FOR N%% = 0 TO 8
194.             IF Pascal%(1, N%%) > MaxBar% THEN MaxBar% = Pascal%(1, N%%)
195.         NEXT N%%
196.         FOR N%% = 0 TO 8
197.             IF MaxBar% > HistBlock%% THEN
198.                 IF Pascal%(1, N%%) = 0 THEN
199.                     _PUTIMAGE (20 + (HistWidth%% + HistSepn%%) * N%%, HistBase%)-(20 + HistWidth%% + (HistWidth%% + HistSepn%%) * N%%, HistBase%), Histo&, , (0, 0)-(19, 0)
200.                 ELSE
201.                     _PUTIMAGE (20 + (HistWidth%% + HistSepn%%) * N%%, HistBase%)-(20 + HistWidth%% + (HistWidth%% + HistSepn%%) * N%%, HistBase% - CINT(Pascal%(1, N%%) * HistHeight% / MaxBar%)), Histo&, , (0, 0)-(19, CINT(Pascal%(1, N%%) * HistHeight% / MaxBar%) - 1)
202.                 END IF
203.             ELSE
204.                 IF Pascal%(1, N%%) = 0 THEN
205.                     _PUTIMAGE (20 + (HistWidth%% + HistSepn%%) * N%%, HistBase%)-(20 + HistWidth%% + (HistWidth%% + HistSepn%%) * N%%, HistBase%), Histo&, , (0, 0)-(19, 0)
206.                 ELSE
207.                     _PUTIMAGE (20 + (HistWidth%% + HistSepn%%) * N%%, HistBase%)-(20 + HistWidth%% + (HistWidth%% + HistSepn%%) * N%%, HistBase% - CINT(Pascal%(1, N%%) * HistHeight% / HistBlock%%)), Histo&, , (0, 0)-(19, CINT(Pascal%(1, N%%) * HistHeight% / MaxBar%) - 1)
208.                 END IF
209.             END IF
210.         NEXT N%%
211.         IF Pascal%(1, 4) > 0 THEN
212.             FOR N%% = 0 TO 8
213.                 S! = Pascal%(1, N%%) / (Pascal%(0, N%%) * (Pascal%(1, 4) / Pascal%(0, 4)))
214.                 IF S! > 9.99 THEN S! = 9.99
215.                 IF INT(S!) = S! THEN
216.                     _PUTIMAGE (24 + (HistWidth%% + HistSepn%%) * N%%, HistBase% + 10), Nos&(INT(S!))
217.                 ELSE
218.                     I1%% = INT(S!)
219.                     XS! = 10 * (S! - I1%%)
220.                     I3%% = INT(XS!)
221.                     XS! = 10 * (XS! - I3%%)
222.                     I4%% = INT(XS!)
223.                     XS! = 10 * (XS! - I4%%)
224.                     IF XS! >= 0.5 THEN I4%% = I4%% + 1
225.                     IF I4%% > 9 THEN
226.                         I3%% = I3%% + 1
227.                         I4%% = 0
228.                     END IF
229.                     IF I3%% > 9 THEN
230.                         I1%% = I1%% + 1
231.                         I3%% = 0
232.                     END IF
233.                     _PUTIMAGE (24 + (HistWidth%% + HistSepn%%) * N%%, HistBase% + 10 + 7), Nos&(10)
234.                     _PUTIMAGE (24 + (HistWidth%% + HistSepn%%) * N%%, HistBase% + 10), Nos&(I1%%)
235.                     _PUTIMAGE (24 + (HistWidth%% + HistSepn%%) * N%%, HistBase% + 10 + 16), Nos&(I3%%)
236.                     _PUTIMAGE (24 + (HistWidth%% + HistSepn%%) * N%%, HistBase% + 10 + 25), Nos&(I4%%)
237.                 END IF
238.             NEXT N%%
239.         END IF
240.         LOCATE 1, 1: PRINT Count&
241.         _DISPLAY
242.         DispCount% = 0
243.     END IF
244.     'Calculate
245.     FOR BallNo%% = 0 TO NoBallsLess1%%
246.         PreviousBall%% = BallNo%% - 1
247.         IF PreviousBall%% < 0 THEN PreviousBall%% = NoBallsLess1%%
248.         IF (Vect!(BallNo%%, 0) - Vect!(PreviousBall%%, 0)) * (Vect!(BallNo%%, 0) - Vect!(PreviousBall%%, 0)) + (Vect!(BallNo%%, 1) - Vect!(PreviousBall%%, 1)) * (Vect!(BallNo%%, 1) - Vect!(PreviousBall%%, 1)) > BallDiam%% * BallDiam%% THEN
249.             IF DoPascal%%(BallNo%%, 0) AND (Vect!(BallNo%%, 1) <= A1%% + 30 + 8 * H! OR NOT DoPascal%%(PreviousBall%%, 1)) THEN
250.                 Vect!(BallNo%%, 0) = Vect!(BallNo%%, 0) + Vect!(BallNo%%, 2)
251.                 Vect!(BallNo%%, 1) = Vect!(BallNo%%, 1) + Vect!(BallNo%%, 3)
252.                 Vect!(BallNo%%, 3) = (F! * Vect!(BallNo%%, 3)) + G!
253.                 Bounce%% = False
254.                 N%% = 0
255.                 WHILE NOT Bounce%% AND N%% <= 53 'FIO Doesn't seem to require external pins
256.                     IF SQR((Vect!(BallNo%%, 1) - Pins!(1, N%%)) * (Vect!(BallNo%%, 1) - Pins!(1, N%%)) + (Vect!(BallNo%%, 0) - Pins!(0, N%%)) * (Vect!(BallNo%%, 0) - Pins!(0, N%%))) < Separation%% THEN
257.                         Bounce%% = True
258.                         CALL Axes((Pins!(1, N%%)), Dum!, YPin1!, Dum1!)
259.                         CALL Axes(Vect!(BallNo%%, 1), Vect!(BallNo%%, 3), YPosn1!, YVel1!)
260.                         V! = SQR(Vect!(BallNo%%, 2) * Vect!(BallNo%%, 2) + YVel1! * YVel1!)
261.                         Theta! = _ATAN2(YVel1!, Vect!(BallNo%%, 2))
262.                         Beta! = _ATAN2(YPin1! - YPosn1!, Pins!(0, N%%) - Vect!(BallNo%%, 0))
263.                         Vect!(BallNo%%, 2) = -V! * COS(2 * Beta! - Theta!)
264.                         YVel1! = -V! * SIN(2 * Beta! - Theta!)
265.                         Vect!(BallNo%%, 0) = Pins!(0, N%%) - (Separation%% + SmallBit!) * COS(Beta!)
266.                         YPosn1! = YPin1! - (Separation%% + SmallBit!) * SIN(Beta!)
267.                         CALL Axes(YPosn1!, YVel1!, Vect!(BallNo%%, 1), Vect!(BallNo%%, 3))
268.                         Vect!(BallNo%%, 2) = W! * Vect!(BallNo%%, 2) + (0.5 - RND) * Z! 'FIO Not perfectly elastic (with some randomness) TBF
269.                         Vect!(BallNo%%, 3) = W! * Vect!(BallNo%%, 3)
270.                     END IF
271.                     N%% = N%% + 1
272.                 WEND
273.                 IF Vect!(BallNo%%, 3) < -SpeedLimit! THEN Vect!(BallNo%%, 3) = -SpeedLimit! 'FIO Gives reasonable coefficients with only -ve Vect!(BallNo%%, 3)
274.                 IF Vect!(BallNo%%, 1) > A1%% + 30 + 8 * H! AND NOT C%% THEN
275.                     Count& = Count& + 1
276.                     Slot%% = CINT(4 + (Vect!(BallNo%%, 0) - (XScreen% / 2)) / Spacing%%)
277.                     Vect!(BallNo%%, 2) = 0
278.                     Pascal%(1, Slot%%) = Pascal%(1, Slot%%) + 1
279.                     C%% = True
280.                 ELSEIF Vect!(BallNo%%, 1) >= YScreen% - 1 - 8 THEN
281.                     RANDOMIZE (TIMER)
282.                     Vect!(BallNo%%, 1) = YScreen% - 1 - A2%%
283.                     Vect!(BallNo%%, 2) = Bagatelle! * (1 + (8 - Slot%%) / 6)
284.                     Vect!(BallNo%%, 3) = 0
285.                     C%% = False
286.                     DoPascal%%(BallNo%%, 1) = True
287.                     DoPascal%%(BallNo%%, 0) = False
288.                 END IF
289.             ELSEIF DoPascal%%(BallNo%%, 1) OR DoPascal%%(BallNo%%, 2) OR DoPascal%%(BallNo%%, 3) THEN
290.                 Vect!(BallNo%%, 0) = Vect!(BallNo%%, 0) + Vect!(BallNo%%, 2)
291.                 Vect!(BallNo%%, 1) = Vect!(BallNo%%, 1) + Vect!(BallNo%%, 3)
292.                 IF DoPascal%%(BallNo%%, 1) THEN
293.                     IF Vect!(BallNo%%, 0) >= XScreen% - 1 - A1%% THEN
294.                         Vect!(BallNo%%, 0) = XScreen% - 1 - A1%%
295.                         DoPascal%%(BallNo%%, 1) = False
296.                         DoPascal%%(BallNo%%, 4) = True
297.                         Vect!(BallNo%%, 4) = 0
298.                     END IF
299.                 ELSEIF DoPascal%%(BallNo%%, 2) THEN
300.                     IF Vect!(BallNo%%, 1) < A1%% THEN
301.                         Vect!(BallNo%%, 0) = XScreen% - 1 - A2%%
302.                         Vect!(BallNo%%, 4) = 0
303.                         DoPascal%%(BallNo%%, 2) = False
304.                         DoPascal%%(BallNo%%, 5) = True
305.                     END IF
306.                 ELSE
307.                     IF Vect!(BallNo%%, 0) <= XScreen% / 2 + A3%% THEN
308.                         Vect!(BallNo%%, 0) = XScreen% / 2 + A3%%
309.                         Vect!(BallNo%%, 4) = 0
310.                         DoPascal%%(BallNo%%, 3) = False
311.                         DoPascal%%(BallNo%%, 6) = True
312.                     END IF
313.                 END IF
314.             ELSEIF DoPascal%%(BallNo%%, 4) OR DoPascal%%(BallNo%%, 5) OR DoPascal%%(BallNo%%, 6) THEN
315.                 IF DoPascal%%(BallNo%%, 4) THEN
316.                     Vect!(BallNo%%, 4) = Vect!(BallNo%%, 4) + Omega!
317.                     Vect!(BallNo%%, 0) = XScreen% - 1 - A1%% + (A3%% * SIN(Vect!(BallNo%%, 4)))
318.                     Vect!(BallNo%%, 1) = YScreen% - 1 - A1%% + (A3%% * COS(Vect!(BallNo%%, 4)))
319.                     IF Vect!(BallNo%%, 1) <= YScreen% - 1 - A1%% THEN
320.                         Vect!(BallNo%%, 0) = XScreen% - 1 - A2%%
321.                         Vect!(BallNo%%, 1) = YScreen% - 1 - A1%%
322.                         Vect!(BallNo%%, 2) = 0
323.                         Vect!(BallNo%%, 3) = -Bagatelle!
324.                         DoPascal%%(BallNo%%, 4) = False
325.                         DoPascal%%(BallNo%%, 2) = True
326.                     END IF
327.                 ELSEIF DoPascal%%(BallNo%%, 5) THEN
328.                     Vect!(BallNo%%, 4) = Vect!(BallNo%%, 4) + Omega!
329.                     Vect!(BallNo%%, 0) = XScreen% - 1 - A1%% + (A3%% * COS(Vect!(BallNo%%, 4)))
330.                     Vect!(BallNo%%, 1) = A1%% - (A3%% * SIN(Vect!(BallNo%%, 4)))
331.                     IF Vect!(BallNo%%, 0) < XScreen% - 1 - A1%% THEN
332.                         Vect!(BallNo%%, 0) = XScreen% - 1 - A1%%
333.                         Vect!(BallNo%%, 1) = A2%%
334.                         Vect!(BallNo%%, 2) = -Bagatelle!
335.                         Vect!(BallNo%%, 3) = 0
336.                         DoPascal%%(BallNo%%, 5) = False
337.                         DoPascal%%(BallNo%%, 3) = True
338.                     END IF
339.                 ELSE
340.                     IF Vect!(BallNo%%, 1) <= A1%% THEN
341.                         Vect!(BallNo%%, 4) = Vect!(BallNo%%, 4) + Omega!
342.                         Vect!(BallNo%%, 0) = XScreen% / 2 + A3%% - (A3%% * SIN(Vect!(BallNo%%, 4)))
343.                         Vect!(BallNo%%, 1) = A1%% - (A3%% * COS(Vect!(BallNo%%, 4)))
344.                     ELSEIF NOT DoPascal%%(PreviousBall%%, 0) THEN
345.                         Vect!(BallNo%%, 0) = XScreen% / 2
346.                         Vect!(BallNo%%, 1) = A1%%
347.                         Vect!(BallNo%%, 2) = Z! * (0.5 - RND)
348.                         Vect!(BallNo%%, 3) = 0.3 + (0.2 * RND)
349.                         DoPascal%%(BallNo%%, 6) = False
350.                         DoPascal%%(BallNo%%, 0) = True
351.                     END IF
352.                 END IF
353.             END IF
354.         END IF
355.     NEXT BallNo%%
356. WEND
357.  
358. SYSTEM
359.  
360. FUNCTION MakeHardware& (Img&)
361.     MakeHardware& = _COPYIMAGE(Img&, 33)
362.     _FREEIMAGE Img&
363. END FUNCTION
364.  
365. SUB Axes (YIn, VYIn, YOut, VYOut)
366.     YOut = -YIn
367.     VYOut = -VYIn
368. END SUB
369.  

[bplus]

Hi Qwerky,

Very impressive graphics! Getting that track drawn and the ball moving through it must of taken some effort.

(Would be nice to put all attachments in a zip file, so everything is in one folder, including font, to check out.)

I am also curious why you start a new thread with every update?
https://www.qb64.org/forum/index.php?topic=1310.0

[Qwerkey]

bplus, thanks.  I had imagined that you'd be one to appreciate this.

I do normally put everything in a zipped folder, but I thought that the attachments were so few that people would prefer the individual downloads.  I will stick to my usual method in future.

"Getting that track drawn and the ball moving through it must of taken some effort."

Well no, this is the beauty-beyond-measure of QB64.  With very little effort you can come up with graphics stuff this good (pardon my immodesty).

"Why start a new thread with every update?"

The previous thread was an "in preparation" topic.  In my mind, we've completely finished that.  Odin may give me a dressing-down for cluttering up the site.

Qwerkey.  To expropriate Miss Minnelli "That's Qwerkey with two E's"!

[bplus]

Qwerkey.  To expropriate Miss Minnelli "That's Qwerkey with two E's"!

Woops! sorry, I must have been miss appropriated by your avatar. :-))