Author Topic: Tag! 2.2 - the chasing game with network multiplayer for up to 8 players (Read 3968 times)

dajan · « **on:** April 30, 2019, 02:06:54 pm »

Hi everyone,

just posting a new enhanced version of Tag! game with LAN/internet multiplayer for max. 8 players added.

Previous version of this game is described in this older topic:
https://www.qb64.org/forum/index.php?topic=1161.0

Since I have never worked with network programming before, it ceratinly isn't coded as supposed to be. My main goal was to just get it work and it kind of is working. You just have to have ping from client to host under cca 50ms, otherwise the gameplay is bit jerky. However on LAN it is fluent and well playable.

To host an internet multiplayer game, it is required to have TCP port 7432 open and forwarded to the computer runnig the host game.

So here is the code:

Code: QB64: [Select]

'  .--------------------------------------------------------------------------------------------------.
'  |                                                                                                  |
'  |                                       Tag! v2                                                    |
'  |                                                                                                  |
'  |                                       daniel.janec@gmail.com                                     |
'  |                                                                                                  |
'  `--------------------------------------------------------------------------------------------------'
 
'--------constants----------------------------------------------------------------------------------------------------------------------------------
CONST MENU_BUILDSTR = "2.2.20.01.01"
CONST RES_X = 1280 'screen horizontal resolution, set to -1 to match the dsektop
CONST RES_Y = 720 'screen vertical resolution, set to -1 to match the dsektop
CONST FPS = 100 'set target frames per seconds to 100 for proper physicss speed
CONST DEBUGMODE = 0 'initial state of debug mode
CONST FULLSCREENMODE = 0 'set 1 for fullscreen on startup, other value to window mode
CONST RES_X_TARG = 1920 'world target horizontal resolution
CONST RES_Y_TARG = 1080 'world target vertical resolution
CONST MAX_COL = 247 'max. color number to use of 255
CONST PLAYER_COUNT_INI = 3 'Initial players count
CONST POCET_GUL_INI = 20 'Initial non player balls count
CONST PLAYER_COUNT_MAX = 32 'Maximum players count
CONST PLAYER_NET_MAX = 8 'Max. number of network players
CONST PLAYER_NET_MIN = 2 'First network control enabled player
CONST POCET_GUL_MAX = 32 'Maximum balls count
CONST STRAT_COUNT_MAX = 20 'Maximum players strategies
CONST PLAY_BALL_R = 20 'Players ball size
CONST V_MAX = 300 / FPS 'Max player ball velocity
CONST ACC_X = 10 / FPS 'Balls acceleration X
CONST ACC_Y = 10 / FPS 'Balls accelereation Y
CONST FRICTION = 0.998 'Space fricition coeffifcient
CONST ENERGY_ALL_MIN = 500 'min.starting energy of all players together
CONST ENERGY_PLAYER_MIN = 50 'min. player's starting energy
CONST ENERGY_PLAYER_MAX = 150 'max. player's starting energy
CONST ENERGY_DEC = 5 / FPS 'ball energy decrement
CONST REACTIME_AVG_NORMAL = 0 * FPS 'Average AI reaction time in sec*FPS
CONST CHYBASMERU_NORMAL = 0.0 'Improper reaction rate
CONST PRIESTOR_MIN = PLAY_BALL_R + 100
CONST DELAY_ROUNDSTART = 8 'delay in seconds after round end to accept resume
CONST DELAY_MATCHEND = 20 'delay in seconds after match end to accept resume
CONST FREEZE_TIME = 1.0 * FPS 'player freeze time after getting tag in seconds
CONST SCORE_POS_X = 50 'Score horizontal draw position
CONST SCORE_DELTA_Y = 13 'Score draw - vertictal offset from screen top
CONST SCORE_DELTA_X = 350 'Score draw - players score horizontal offset
CONST SCORE_NAME_LEN = 120 'Score draw - horizontal space for player name
CONST BOOST_V_KOEF = 3.0 'boost factor of extra maximum speed
CONST BOOST_TRVANIE = 1 * FPS 'boost duration
CONST BOOST_TIME = 1 * FPS 'min time between boosts in sec*fps
CONST MENUCURSOR_COLOR = 15 'Menu cursor color
CONST MENUITEM_COLOR = 7 'Menu cursor color
CONST MENU_PLAYERS_COUNT = 8 'Number of players in menu
CONST FONT_W = 8 'Font width in pixels
CONST FONT_H = 16 'Font height in pixels
CONST GAMESTICK_DEADZONE = 0.05 'gamepad stick axis maximum value considered as zero
CONST CPU_CONTROLID = PLAYER_NET_MAX + 1 'CPU controller id
CONST HOSTIP_DEFAULT = "" '"localhost" '
CONST HOSTPORT_DEFAULT = 7432
CONST GETITEM_SYNC = "SNC" 'network trasfer item code
CONST GETITEM_STAV = "SNS" 'network trasfer item code
CONST GETITEM_BAL = "SNB" 'network trasfer item code
CONST GETITEM_PBAL = "SNP" 'network trasfer item code
CONST GETITEM_KLAV = "SNK" 'network trasfer item code
CONST GETITEM_HRAC = "SNH" 'network trasfer item code
CONST GETITEM_MESG = "SNM" 'network trasfer item code
CONST GETITEM_STAT = "SNT" 'network trasfer item code
CONST NET_TIMEOUT_LIMIT = 10 'timeout to disconnect in seconds
CONST NET_TIMEOUT_SYNC = 0.01 'timeout to get synced in seconds
CONST MSG_COUNT_MAX = 20 'max. messages displayed
CONST MSG_LEN_MAX = 80 'max. length of message
CONST MSG_DUR_STD = 20 'message standard duration in seconds
CONST MSG_COL = 7 'message standard color
CONST UPDATE_PER_BAL = 0.1 'all balls network update period in seconds
CONST UPDATE_PER_PLBAL = 0.04 'player balls network update period in seconds
CONST UPDATE_PER_HRAC = 0.1 'players network update period in seconds
CONST UPDATE_PER_STAV = 0.04 'world state network update period in seconds
CONST AUTOSTART_SEC_MAX = 180 'max game autostart time
 
'--------type definitions----------------------------------------------------------------------------------------------------------------------------
TYPE vektor 'general 2D vector type
    x AS SINGLE
    y AS SINGLE
END TYPE
 
TYPE tstav 'game world state type  (cca 100B)
    minx AS INTEGER 'world - minimum x position
    maxx AS INTEGER 'world - maximum x position
    miny AS INTEGER 'world - minimum y position
    maxy AS INTEGER 'world - maximum y position
    vmax AS SINGLE 'maximum unboosted ball velocity
    maxcol AS INTEGER 'world - maximum of colors
    pocetgulzvoleny AS INTEGER 'number of balls desired
    pocetgul AS INTEGER 'number of balls actual
    pocetgulx AS INTEGER 'number of balls in bottom row
    pocetguly AS INTEGER 'number of balls in left column
    pocethracov AS INTEGER 'number of players
    energy_allmin AS SINGLE 'all players starting energy sum
    energy_playermin AS SINGLE 'minimum starting energy of player
    energy_playermax AS SINGLE 'maximum starting energy of player
    energy_player_start AS SINGLE 'player's starting energy
    energydec AS SINGLE 'energy decrease unit
    baljeto AS INTEGER 'actual tagged ball idx
    balbudeto AS INTEGER 'successor tagged ball idx
    vitaz AS INTEGER 'winner player idx
    koniec_kola AS _BYTE 'end of round flag (0=no end, 1=end of round, 2=end fo round and match)
    odpor AS SINGLE 'space friction
    massallowed AS _BYTE 'calculate balls with different masses
    pauza AS _BYTE 'game pause flag (0 or 1)
    gameplay AS _BYTE 'state of session: 0=menu, 1=gameplay
    fps AS SINGLE 'fps target set
    zacinabal AS INTEGER 'initially tagged ball idx
    boostallowed AS _BYTE 'player boost mode allowed (0 or 1)
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
    AIallowed AS _BYTE 'AI players in netgame allowed=1
    autostart_set AS INTEGER 'game autostart setting in seconds; 0=off
    autostart_timeleft AS SINGLE 'actual time to autostart the game in seconds
    winscore AS _BYTE 'score to win a match
END TYPE
 
TYPE gula 'ball  type  (cca 90B)
    i AS INTEGER 'balls id
    x AS SINGLE 'balls y position
    y AS SINGLE 'balls y position
    r AS SINGLE 'radius
    m AS SINGLE 'mass
    v AS vektor 'velocity
    vi AS vektor 'desired velocity
    a AS vektor 'acceleration
    col AS INTEGER 'balls color
    riadena AS INTEGER 'is actually player controllable (0 or 1)
    complayer AS INTEGER 'is computer player's ball (0 or 1)
    protivnik AS INTEGER 'actual ball's enemy ball id
    strat AS INTEGER 'balls behaviour strategy id
    energia AS SINGLE 'players energy
    freezedtime AS INTEGER 'actual time to unfreeze players control
    smer_odchyl AS SINGLE 'actual deviance from intended direction in radians
    klucka_time AS INTEGER 'actual time to start doging
    klucka_uhol AS SINGLE 'actual dodge angle
    klucka_trvanie AS INTEGER 'actual dodge duration
    klucka_pocet AS INTEGER 'actual dodge count
    boost_time AS INTEGER 'actual time to boost allowed again
    boost_trvanie AS INTEGER 'actual time to end boost
    reactdrop_time AS INTEGER 'actual time to start reaction drop in frames
    reactdrop_dur AS INTEGER 'actual time to stop reaction drop in frames
    boostintended AS INTEGER 'intention to boost or not (1, 0)
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
    hrac AS INTEGER 'ball player's id
END TYPE
 
TYPE tstrat 'balls behaviour strategy type
    okraj AS INTEGER 'distance from screen border to turn
    okraj_rot AS SINGLE 'distance from screen border to turn
    chybasmeru AS SINGLE 'percentage of deviance from desired direction -- not used currently
    react_lag AS INTEGER 'average reaction time in frames
    klucka_avgtm AS SINGLE 'average time between dodging in fps +-50%
    klucka_uhol AS SINGLE 'average dodge angle
    klucka_trvanie AS INTEGER 'average dodge time +-50%
    klucka_pocet AS INTEGER 'average dodge count
    klucka_uholodch AS SINGLE 'dodge angle deviation percentage
    detekcia_sin AS SINGLE 'sinus of frontal enemy detection angle
    detekcia_vzdfull AS SINGLE 'distance of frontal enemy full detection
    detekcia_vzdmin AS SINGLE 'distance of frontal enemy minimum detection
    detekcia_rot AS SINGLE 'amount of rotation on enemy detection in radians
    reactdrop_per AS INTEGER 'average reaction drop period in frames
    reactdrop_dur AS INTEGER 'average reaction drop duration in frames
    boost_rate AS SINGLE 'inclination to use boost in percent
    boost_dist AS SINGLE 'enemy distance activating boost deciding
    boost_chasesin AS SINGLE 'max. sinus of enemy to player velocity angle to apply chasing boost
    mate_cosenmax AS SINGLE 'max. cosinus of (player-enemy vector to player velocity) to rotate to mate
    mate_rot AS SINGLE 'amount of unit rotation towards nearest mate in rad per frame
    mate_en_distmin AS SINGLE 'min. distance from enemy to apply rotation towards mate
    mate_distmin AS SINGLE 'min. distance from mate to apply rotation towards mate
    adrenalin_rate AS SINGLE 'percentage of reaction time improved in adrenalin mode
    adrenalin_energy AS SINGLE 'energy level precentage starting adrenalin mode
END TYPE
 
TYPE thrac 'player type
    i AS INTEGER 'player index number
    meno AS STRING * 10 'players name
    skore AS _BYTE 'players score
    klavesy AS _BYTE 'players control keys set index
    bal AS INTEGER 'player driven ball idx
    col AS INTEGER 'player's choosed color
    clientid AS _BYTE 'index of hosted client, 0 if local player
    isready AS _BYTE '1=player is ready for game start
    syncstr AS STRING * 3
    synctime AS DOUBLE
END TYPE
 
TYPE tklavesy 'players controller type
    id AS INTEGER 'controllers id
    devid AS INTEGER 'controllers device id  (0=unused)
    typ AS _BYTE 'type of controller (0=unused, 1=keyboard, 2=mouse reserved, 3=gamepad, 4=AI, 5=network, 6=empty)
    nazov AS STRING * 25 'game controllers name
    up AS LONG 'key code for up
    down AS LONG 'keyp code for down
    right AS LONG 'key code for right
    left AS LONG 'key code for left
    shoota AS LONG 'keyborad key code or gamepad button id
    shootb AS LONG 'keyborad key code or gamepad button id
    xaxis AS _BYTE 'gamepad analog x-asis id
    yaxis AS _BYTE 'gamepad analog y-asis id
    dxaxis AS _BYTE 'gamepad digital x-asis id
    dyaxis AS _BYTE 'gamepad digital y-asis id
    isup AS _BYTE 'controllers actual state for up
    isdown AS _BYTE 'controllers actual state for down
    isright AS _BYTE 'controllers actual state for right
    isleft AS _BYTE 'controllers actual state for left
    isshoota AS _BYTE 'controllers actual state for fire 1
    isshootb AS _BYTE 'controllers actual state for fire 2
    gvektor AS vektor 'controllers actual x and y axis state
    buttonstate AS LONG 'all gamepads buttons cumulative state value
    buttonstatechanged AS _BYTE '0 if no button state change, 1 if any button state changed
    buttonstatetimer AS INTEGER
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
END TYPE
 
TYPE tmenu
    title AS STRING * 10 'menu title use for nothing
    items_count AS INTEGER 'menu items count
    item_active AS INTEGER 'active item index
    item_height AS INTEGER 'menu item height in pixels
    cursor_col AS INTEGER 'menu cursor color
    cursor_xpos AS INTEGER 'x position of cursors left side
    cursor_out AS INTEGER 'cursor bar outset
    ypos AS INTEGER 'y position of cursor
    cursor_width AS INTEGER 'cursor width in pixels
    menucode AS INTEGER 'stores code of selected action upon active menuitem
    playercode AS INTEGER 'stores  player id of active menuitem
END TYPE
 
TYPE tmessage
    clientid AS INTEGER 'client origin of message
    text AS STRING * MSG_LEN_MAX 'message text
    time_start AS DOUBLE 'message time
    time_dur AS SINGLE 'message duration
    col AS INTEGER 'message color
    distribute AS INTEGER 'message dsitribution status 1=distribute
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
END TYPE
 
TYPE tgamesession 'my game session properties
    maxx AS INTEGER 'my screen x resolution
    maxy AS INTEGER 'my screen y resolution
    isnetgame AS _BYTE 'network game flag; 1=network, 0=local
    hosth AS INTEGER 'my host handle
    clienth AS INTEGER 'my client handle
    clientid AS INTEGER 'my client's id registered at host
    host_ip AS STRING * 100 'host's ip to connect as a client
    host_port AS LONG 'host's port to connect as a client
    get_item AS STRING * 3 'actual item to get from host
    get_time AS DOUBLE 'time of last succesfull reading from host
    get_isdesync AS INTEGER 'net transfer is desynced=1
    fpsactual AS SINGLE 'fps achieved
    fpscoef AS SINGLE 'fps actual/target
    tstart AS DOUBLE 'timer start time
    tend AS DOUBLE 'timer end time
    pocetgamepadov AS INTEGER 'number of gamepads detected
    pocetkontrolerov AS INTEGER 'number of game controllers
    start AS INTEGER 'start game flag (0 or 1)
    exituj AS INTEGER 'exit game flag (0 or 1)
    printdebug AS INTEGER 'debug mode flag (0 or 1)
    msgcount AS INTEGER 'total number of actual messages
    msgwrite AS INTEGER 'message write mode=1
    newmsg AS INTEGER 'is new messages to distribute flag
    msgtext AS STRING * MSG_LEN_MAX 'message text being actually written
    autostart_time AS SINGLE 'local host time of game autostart
    timer_pballs AS SINGLE 'local time of last player balls update from host
    sync_stats AS _BYTE 'send statistics to clients flag
    show_stats AS _BYTE 'display match statistics
END TYPE
 
TYPE tclient 'hosted client type
    conn AS INTEGER 'connection handle of hosted client
    ip AS STRING * 100 'ip of hosted client
    get_item AS STRING * 3 'next item to get from client
    get_time AS DOUBLE 'time of last succesfull reading from client
    get_isdesync AS INTEGER 'net desynchronisation flag host cannot get from client
    isdesynced AS _BYTE 'client side is desynced - cannot get from host
    spectating AS _BYTE 'client player control enabled
END TYPE
 
TYPE tsyncvar
    syncstr AS STRING * 3 'sync string code
    synctime AS DOUBLE 'net synchronisation time stamp
    itemstr AS STRING * 3 'code of the next item to get
    isdesync AS _BYTE '1=the other side is desynced
    clientid AS INTEGER 'client id
END TYPE
 
'-----global variables-------------------------------------------------------------------------------------------------------------------------------
REDIM SHARED bal(1 TO POCET_GUL_MAX + PLAYER_COUNT_MAX) AS gula 'balls
DIM SHARED klav(1 TO PLAYER_COUNT_MAX) AS tklavesy 'keyboard control sets
DIM SHARED stav AS tstav 'game world state
DIM SHARED strat(1 TO STRAT_COUNT_MAX) AS tstrat 'computer players strategies
DIM SHARED hrac(1 TO PLAYER_COUNT_MAX) AS thrac 'players balls
DIM SHARED sync AS tsyncvar 'net sync variable
DIM SHARED stats(1 TO PLAYER_NET_MAX + 1, 1 TO PLAYER_NET_MAX) AS INTEGER 'players game statistics
 
REDIM SHARED ibal(1 TO POCET_GUL_MAX) AS gula 'nonplayer balls transfer array
REDIM SHARED ipbal(1 TO PLAYER_NET_MAX) AS gula 'players balls transfer array
DIM SHARED iklav(1 TO PLAYER_COUNT_MAX) AS tklavesy 'keyboard control sets transfer array
DIM SHARED istav AS tstav 'game world state transfer array
DIM SHARED ihrac(1 TO PLAYER_NET_MAX) AS thrac 'players balls transfer array
DIM SHARED isync AS tsyncvar 'net sync variable transfer array
DIM SHARED istats(1 TO PLAYER_NET_MAX + 1, 1 TO PLAYER_NET_MAX) AS INTEGER 'players game statistics transfer
 
DIM SHARED client(1 TO 8) AS tclient
DIM SHARED menu AS tmenu
DIM SHARED game AS tgamesession
DIM SHARED msg(1 TO MSG_COUNT_MAX) AS tmessage
DIM SHARED pi AS SINGLE
 
'----main program------------------------------------------------------------------------------------------------------------------------------------
SetGlobalParameters
SetUpControllers
IF game.pocetgamepadov > 0 THEN hrac(1).klavesy = game.pocetkontrolerov 'set gamepad as default controller for player1
 
SCREEN _NEWIMAGE(game.maxx, game.maxy, 256), , ,
_SCREENMOVE _MIDDLE
IF FULLSCREENMODE = 1 THEN _FULLSCREEN
AddMessage "Welcome in the Tag game.", MSG_COL, 5, 0
AddMessage "To display/hide match statistics press 'c' while gameplay.", MSG_COL, 8, 0
AddMessage "Default TCP port for the network game is 7432. ", MSG_COL, 11, 0
 
DO
    '--------Main menu begin---------------------------------------------------------------------------------------------------------------------------------------------------------------------
    REDIM SHARED ibal(1 TO POCET_GUL_MAX) AS gula 'nonplayer balls transfer array
    REDIM SHARED ipbal(1 TO PLAYER_NET_MAX) AS gula 'players balls transfer array
    DIM playerst(1 TO 8) AS STRING * 30
    DIM hoststat AS STRING * 50
    DIM joinstat AS STRING * 50
    DIM autostart AS STRING
    DIM AIplayers AS STRING
    DIM newenergy AS STRING * 3
 
    stav.gameplay = 0
    vys = FONT_H
    sir = FONT_W
    menu.items_count = 27
 
    DO
        WINDOW (0, 0)-(game.maxx, game.maxy)
        IF game.hosth <> 0 THEN hoststat = "host started" ELSE hoststat = ""
        IF game.clienth <> 0 AND game.clientid = 0 THEN joinstat = "joining game...   "
        IF game.clienth <> 0 AND game.clientid <> 0 THEN joinstat = "connected to         " + LEFT$(game.host_ip, 30)
        IF game.clienth = 0 AND game.clientid = 0 THEN joinstat = ""
        ReadyPlayersCount = 0
        FOR i = 1 TO 8
            playerst(i) = ""
            IF game.isnetgame = 1 THEN
                IF hrac(i).clientid > 0 THEN playerst(i) = "  state: connected" ELSE playerst(i) = "  state: "
                IF klav(hrac(i).klavesy).typ <= 3 THEN playerst(i) = "  state: local player"
                IF hrac(i).isready = 1 AND hrac(i).clientid > 0 THEN playerst(i) = RTRIM$(playerst(i)) + " / ready!": ReadyPlayersCount = ReadyPlayersCount + 1
            END IF
        NEXT i
 
        IF stav.autostart_set = 0 THEN
            autostart = "Off"
        ELSE
            HumanPlayers = HumanPlayersCount
            IF game.autostart_time - stav.autostart_set > TIMER THEN game.autostart_time = game.autostart_time - 86399
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) THEN stav.autostart_timeleft = game.autostart_time - TIMER
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND game.autostart_time <= TIMER THEN
                IF stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayers >= 2) THEN
                    game.start = 1
                ELSE
                    game.autostart_time = TIMER + stav.autostart_set
                END IF
            END IF
            IF game.isnetgame = 1 AND game.hosth <> 0 AND ReadyPlayersCount = HumanPlayers AND ((stav.AIallowed = 1 AND HumanPlayers >= 1) OR (stav.AIallowed = 0 AND HumanPlayers >= 2)) THEN game.start = 1
            autostart = LTRIM$(STR$(stav.autostart_set)) + " sec               " + LTRIM$(STR$(INT(stav.autostart_timeleft))) + " left"
        END IF
 
        IF stav.AIallowed = 1 THEN AIplayers = "Yes" ELSE AIplayers = "No"
 
        CLS 1
        DisplayMessages
        PrintMenuItem -2, menu, 0, 0, 0, "Tag! v.2", 0, 0, -3, 13
        PrintMenuItem -1, menu, 0, 0, 0, "created in QuickBasic64 by Daniel Janec (2019) build " + MENU_BUILDSTR, 0, 0, -2, 20
        PrintMenuItem 1, menu, 6, 0, 0, "Play <Space>", 0, 0, 0, MENUITEM_COLOR
        PrintMenuItem 2, menu, 1, 0, 0, "Refresh gamepads detected: " + STR$(game.pocetgamepadov), 0, 0, 0, MENUITEM_COLOR
        PrintMenuItem 3, menu, 2, 1, 1, hrac(1).meno + " controls: " + klav(hrac(1).klavesy).nazov + RTRIM$(playerst(1)), 150, -10 * sir, 1, hrac(1).col
        PrintMenuItem 4, menu, 3, 1, 1, "              color:" + STR$(hrac(1).col), 150, -10 * sir, 1, hrac(1).col
        PrintMenuItem 5, menu, 2, 2, 1, hrac(2).meno + " controls: " + klav(hrac(2).klavesy).nazov + RTRIM$(playerst(2)), 150, -10 * sir, 1, hrac(2).col
        PrintMenuItem 6, menu, 3, 2, 1, "              color:" + STR$(hrac(2).col), 150, -10 * sir, 1, hrac(2).col
        PrintMenuItem 7, menu, 2, 3, 1, hrac(3).meno + " controls: " + klav(hrac(3).klavesy).nazov + RTRIM$(playerst(3)), 150, -10 * sir, 1, hrac(3).col
        PrintMenuItem 8, menu, 3, 3, 1, "              color:" + STR$(hrac(3).col), 150, -10 * sir, 1, hrac(3).col
        PrintMenuItem 9, menu, 2, 4, 1, hrac(4).meno + " controls: " + klav(hrac(4).klavesy).nazov + RTRIM$(playerst(4)), 150, -10 * sir, 1, hrac(4).col
        PrintMenuItem 10, menu, 3, 4, 1, "              color:" + STR$(hrac(4).col), 150, -10 * sir, 1, hrac(4).col
        PrintMenuItem 11, menu, 2, 5, 1, hrac(5).meno + " controls: " + klav(hrac(5).klavesy).nazov + RTRIM$(playerst(5)), 150, -10 * sir, 1, hrac(5).col
        PrintMenuItem 12, menu, 3, 5, 1, "              color:" + STR$(hrac(5).col), 150, -10 * sir, 1, hrac(5).col
        PrintMenuItem 13, menu, 2, 6, 1, hrac(6).meno + " controls: " + klav(hrac(6).klavesy).nazov + RTRIM$(playerst(6)), 150, -10 * sir, 1, hrac(6).col
        PrintMenuItem 14, menu, 3, 6, 1, "              color:" + STR$(hrac(6).col), 150, -10 * sir, 1, hrac(6).col
        PrintMenuItem 15, menu, 2, 7, 1, hrac(7).meno + " controls: " + klav(hrac(7).klavesy).nazov + RTRIM$(playerst(7)), 150, -10 * sir, 1, hrac(7).col
        PrintMenuItem 16, menu, 3, 7, 1, "              color:" + STR$(hrac(7).col), 150, -10 * sir, 1, hrac(7).col
        PrintMenuItem 17, menu, 2, 8, 1, hrac(8).meno + " controls: " + klav(hrac(8).klavesy).nazov + RTRIM$(playerst(8)), 150, -10 * sir, 1, hrac(8).col
        PrintMenuItem 18, menu, 3, 8, 1, "              color:" + STR$(hrac(8).col), 150, -10 * sir, 1, hrac(8).col
        PrintMenuItem 19, menu, 8, 0, 1, "Player starting energy: " + LTRIM$(STR$(stav.energy_player_start)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 20, menu, 4, 0, 1, "     Number of players: " + LTRIM$(STR$(stav.pocethracov)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 21, menu, 12, 0, 1, "   CPU players allowed: " + AIplayers, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 22, menu, 5, 0, 1, "           Balls count: " + LTRIM$(STR$(stav.pocetgulzvoleny)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 23, menu, 13, 0, 1, "   Match winning score: " + LTRIM$(STR$(stav.winscore)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 24, menu, 11, 0, 1, "        Game autostart: " + autostart, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 25, menu, 9, 0, 0, "             Host game: " + hoststat, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 26, menu, 10, 0, 0, "             Join game: " + joinstat, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 27, menu, 7, 0, 0, "Exit <Esc>", 0, 0, 2, MENUITEM_COLOR
        PrintMenuCursor menu
 
        k = _KEYHIT 'read menu action
        IF game.msgwrite = 1 AND game.isnetgame = 1 THEN WriteMessage k: k = 0
        IF game.msgwrite = 0 AND game.isnetgame = 1 THEN WriteMessage -1
 
        '---debug code begin---------------------------------------------
        IF k = 98 THEN game.printdebug = -(game.printdebug = 0)
        IF game.printdebug = 1 THEN DebugScreen k 'print debug info on screen
        '---debug code end-----------------------------------------------
 
        FOR i = 1 TO game.pocetkontrolerov
            IF klav(i).typ = 3 THEN
                ReadGamepad klav(i)
                IF klav(i).buttonstatechanged THEN
                    IF klav(i).isshoota THEN k = 13: klav(i).isshoota = 0
                    IF klav(i).isup THEN k = 18432: klav(i).isup = 0
                    IF klav(i).isdown THEN k = 20480: klav(i).isdown = 0
                    IF klav(i).isright THEN k = 19712: klav(i).isright = 0
                    IF klav(i).isleft THEN k = 19200: klav(i).isleft = 0
                END IF
            END IF
        NEXT i
 
        SELECT CASE k 'perform menu choice
            CASE 18432 'up
                IF menu.item_active > 1 THEN menu.item_active = menu.item_active - 1
            CASE 20480 'down
                IF menu.item_active < menu.items_count THEN menu.item_active = menu.item_active + 1
            CASE 19200 'left
                SELECT CASE menu.menucode
                    CASE 2 'players controller
                        i = menu.playercode
                        hrac(i).klavesy = hrac(i).klavesy - 1
                        IF hrac(i).klavesy < PLAYER_NET_MAX + 1 THEN hrac(i).klavesy = PLAYER_NET_MAX + 1
                    CASE 3 'players color
                        i = menu.playercode
                        hrac(i).col = hrac(i).col - 1
                        IF hrac(i).col < 1 THEN hrac(i).col = stav.maxcol
                    CASE 4 'players count
                        IF stav.pocethracov > 2 THEN
                            stav.pocethracov = stav.pocethracov - 1
                        END IF
                    CASE 5 'balls count
                        IF stav.pocetgulzvoleny > 0 THEN
                            stav.pocetgulzvoleny = stav.pocetgulzvoleny - 1
                        END IF
                    CASE 8 'starting energy
                        IF stav.energy_player_start > 10 THEN
                            stav.energy_player_start = stav.energy_player_start - 1
                        END IF
                    CASE 11 'game autostart
                        IF stav.autostart_set > 0 THEN
                            stav.autostart_set = stav.autostart_set - 10
                            game.autostart_time = TIMER + stav.autostart_set
                        END IF
                    CASE 12 'CPU players allowed
                        stav.AIallowed = 0
                    CASE 13 'Winning score
                        IF stav.winscore > 1 THEN stav.winscore = stav.winscore - 1
                END SELECT
            CASE 19712 'right
                SELECT CASE menu.menucode
                    CASE 2 'players controller
                        i = menu.playercode
                        hrac(i).klavesy = hrac(i).klavesy + 1
                        IF hrac(i).klavesy > game.pocetkontrolerov THEN hrac(i).klavesy = game.pocetkontrolerov
                    CASE 3 'players color
                        i = menu.playercode
                        hrac(i).col = hrac(i).col + 1
                        IF hrac(i).col > stav.maxcol THEN hrac(i).col = 1
                    CASE 4 'players count
                        IF stav.pocethracov < PLAYER_COUNT_MAX THEN
                            stav.pocethracov = stav.pocethracov + 1
                        END IF
                    CASE 5 'balls count
                        IF stav.pocetgulzvoleny < POCET_GUL_MAX THEN
                            stav.pocetgulzvoleny = stav.pocetgulzvoleny + 1
                        END IF
                    CASE 8 'starting energy
                        IF stav.energy_player_start < ENERGY_PLAYER_MAX THEN
                            stav.energy_player_start = stav.energy_player_start + 1
                        END IF
                    CASE 11 'game autostart
                        IF stav.autostart_set < AUTOSTART_SEC_MAX THEN
                            stav.autostart_set = stav.autostart_set + 10
                            game.autostart_time = TIMER + stav.autostart_set
                        END IF
                    CASE 12 'CPU players allowed
                        stav.AIallowed = 1
                    CASE 13 'Winning score
                        IF stav.winscore < 99 THEN stav.winscore = stav.winscore + 1
                END SELECT
            CASE 13 'enter
                SELECT CASE menu.menucode
                    CASE 1
                        SetUpControllers
                    CASE 8 'starting energy
                        newenergy = LTRIM$(STR$(stav.energy_player_start))
                        newenergy = InputText$(newenergy, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, MENUITEM_COLOR, 48, "<Type starting energy>", 0, 1)
                        IF LEFT$(newenergy$, 1) <> CHR$(27) AND LEN(RTRIM$(newenergy$)) > 0 THEN
                            energyval = VAL(newenergy)
                            IF energyval < 10 THEN energyval = 10
                            IF energyval > ENERGY_PLAYER_MAX THEN energyval = ENERGY_PLAYER_MAX
                            stav.energy_player_start = energyval
                        END IF
                    CASE 2 'set new name
                        novemeno$ = InputText$(hrac(menu.playercode).meno, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, hrac(menu.playercode).col, 14, "<Type name>", 0, 0)
                        IF novemeno$ <> CHR$(27) AND LEN(novemeno$) > 0 THEN hrac(menu.playercode).meno = novemeno$
                    CASE 9 'host game
                        HostGame
                    CASE 10 'join game
                        IF game.clienth = 0 THEN
                            gethostip$ = InputText$(game.host_ip, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, MENUITEM_COLOR, LEN(game.host_ip), "<Type IP address or host name>", 1, 0)
                            IF gethostip$ <> CHR$(27) THEN game.host_ip = gethostip$
                            IF gethostip$ <> CHR$(27) AND LEN(RTRIM$(game.host_ip)) > 0 THEN JoinGame
                        ELSE
                            ResetNetGame
                        END IF
                    CASE 6 'start game
                        IF game.clientid > 0 THEN hrac(game.clientid).isready = 1 - hrac(game.clientid).isready
                        IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND (stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayersCount >= 2)) THEN game.start = 1
                    CASE 7 'exit game
                        game.exituj = 1
                END SELECT
            CASE 116 'messaage write mode on
                IF game.isnetgame = 1 THEN
                    game.msgwrite = 1
                    k = 0
                END IF
            CASE 32 'start game
                IF game.clientid > 0 THEN hrac(game.clientid).isready = 1 - hrac(game.clientid).isready
                IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND (stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayersCount >= 2)) THEN game.start = 1
            CASE 27 'exit game
                game.exituj = 1
        END SELECT
 
        FOR i = 1 TO PLAYER_COUNT_MAX 'set AI controller type for computer players
            IF game.isnetgame = 1 AND game.clienth <> 0 AND game.clientid <> 0 AND klav(hrac(i).klavesy).typ = 4 THEN hrac(i).klavesy = hrac(i).klavesy + 1 'change AI controler on client to keyboard
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND klav(hrac(i).klavesy).typ = 4 THEN 'on host or singleplayer change AI controlled ball
                bal(hrac(i).bal).complayer = 1
            ELSE
                bal(hrac(i).bal).complayer = 0
            END IF
        NEXT i
 
        IF game.isnetgame AND stav.pocethracov > PLAYER_NET_MAX THEN stav.pocethracov = PLAYER_NET_MAX
        IF menu.menucode = 4 AND (k = 19712 OR k = 19200) THEN 'after changing players count
            stav.energy_player_start = INT(stav.energy_allmin / stav.pocethracov) 'calculate  players energy
            IF stav.energy_player_start < stav.energy_playermin THEN stav.energy_player_start = stav.energy_playermin
            IF stav.energy_player_start > stav.energy_playermax THEN stav.energy_player_start = stav.energy_playermax
        END IF
 
        IF game.isnetgame = 1 AND game.clienth <> 0 AND game.clientid > 0 AND stav.gameplay = 1 THEN game.start = 1
        IF game.isnetgame = 1 THEN SyncNetGameData
        _DISPLAY
        _LIMIT stav.fps
 
    LOOP UNTIL game.start = 1 OR game.exituj = 1
    game.start = 0
    IF game.clientid > 0 THEN hrac(game.clientid).isready = 0
    '--------end of main menu---------------------------------------------------------------------------------------------------------------------------------------------------------------------
 
    '----------------------------------new game start-------------------------------------------------------------------------------------------------
    WINDOW (0, 0)-(stav.maxx, stav.maxy)
    IF game.exituj <> 1 THEN 'new game starts here
        '----------------------------------set the world on the new game start-------------------------------
        IF game.hosth <> 0 THEN AddMessage "The match has been started by the host. Whoever scores" + RTRIM$(STR$(stav.winscore)) + " times wins.", MSG_COL, MSG_DUR_STD, 1
 
        FOR i = 1 TO PLAYER_NET_MAX
            FOR j = 1 TO PLAYER_NET_MAX
                stats(i, j) = 0
            NEXT j
        NEXT i
 
        stav.gameplay = 1
        stav.pocetgul = stav.pocetgulzvoleny + stav.pocethracov
        stav.pocetgulx = MATHROUND(SQR(4 / 3 * stav.pocetgul))
        IF stav.pocetgulx < stav.pocethracov THEN stav.pocetgulx = stav.pocethracov
        stav.pocetguly = _CEIL(stav.pocetgul / stav.pocetgulx)
 
        IF stav.pocethracov < 2 THEN stav.pocethracov = 2
        FOR i = 1 TO stav.pocethracov
            hrac(i).skore = 0
        NEXT i
 
        FOR n = 1 TO stav.pocethracov: bal(n).syncstr = GETITEM_PBAL: bal(n).synctime = 0: NEXT n
        FOR n = stav.pocethracov + 1 TO UBOUND(bal): bal(n).syncstr = GETITEM_BAL: bal(n).synctime = 0: NEXT n
 
        stav.zacinabal = hrac(INT(RND * stav.pocethracov + 1)).bal
 
        DO 'new round starts here
            '-------------------------------set the world on the new round start---------------------------
            stav.koniec_kola = 0
            stav.pauza = 0
            stav.vitaz = 0
            game.exituj = 0
            stav.baljeto = 0
 
            IF game.isnetgame = 1 AND game.hosth <> 0 THEN 'engage new spectating players
                FOR i = 2 TO stav.pocethracov
                    IF client(i).spectating = 1 THEN
                        hrac(i).skore = 0
                        bal(hrac(i).bal).hrac = i
                        bal(hrac(i).bal).complayer = 0
                        bal(hrac(i).bal).riadena = 1
                        client(i).spectating = 0
                        bal(i).vi.x = 0: bal(i).vi.y = 0
                        FOR j = 1 TO PLAYER_NET_MAX
                            stats(i, j) = 0
                            stats(j, i) = 0
                        NEXT j
                    END IF
                NEXT i
            END IF
 
            RANDOMIZE TIMER
            coloffset = 104 + INT(RND * 10)
            colcoef = (1 + INT(RND * (246 - coloffset))) / stav.pocetgulx
            FOR i = 1 TO stav.pocetguly + 1 'set all balls
                FOR j = 1 TO stav.pocetgulx
                    n = (i - 1) * stav.pocetgulx + j:
                    IF n <= stav.pocetgul THEN
                        ry = 20 + RND * INT(((stav.maxy - 100) / (stav.pocetguly + 1) - 25) / 2)
                        rx = 10 + RND * INT(((stav.maxx - 100) / (stav.pocetgulx + 1) - 25) / 2)
                        bcol = coloffset + j * colcoef
                        bal(n).i = n
                        bal(n).col = bcol
                        bal(n).x = 100 + j * INT((stav.maxx - 100) / (stav.pocetgulx + 1))
                        bal(n).y = 100 + i * INT((stav.maxy - 100) / (stav.pocetguly + 1))
                        bal(n).r = rx * -(rx < ry) + ry * -(ry < rx)
                        bal(n).m = 4 / 4 * pi * bal(n).r ^ 2
                        bal(n).v.x = -10 / FPS: bal(n).v.y = -30 / FPS
                        bal(n).a.x = ACC_X * stav.maxx / RES_X_TARG
                        bal(n).a.y = ACC_Y * stav.maxx / RES_X_TARG
                        bal(n).vi.x = -(bal(n).complayer = 1) * RND * stav.vmax - stav.vmax / 2
                        bal(n).vi.y = -(bal(n).complayer = 1) * RND * stav.vmax - stav.vmax / 2
                        bal(n).riadena = 0
                        bal(n).energia = stav.energy_player_start
                        bal(n).freezedtime = 0: bal(n).klucka_time = 0: bal(n).klucka_pocet = 0
                        bal(n).klucka_trvanie = 0: bal(n).klucka_uhol = 0
                        bal(n).boost_time = 0: bal(n).boost_trvanie = 0
                        bal(n).synctime = 0
                    END IF
                NEXT j
            NEXT i
 
            '---set players balls default atributtes--------------------------------------------------------
            FOR i = 1 TO stav.pocethracov
                hrac(i).bal = i
                bal(hrac(i).bal).hrac = i
                bal(hrac(i).bal).riadena = 1
                IF stav.AIallowed = 0 AND klav(hrac(i).klavesy).typ = 4 THEN
                    bal(hrac(i).bal).energia = 0
                    bal(hrac(i).bal).riadena = 0
                ELSE
                    bal(hrac(i).bal).r = PLAY_BALL_R * stav.maxx / RES_X_TARG
                    bal(hrac(i).bal).m = 4 / 4 * pi * PLAY_BALL_R ^ 2 / 2 'Players have only half density
                    bal(hrac(i).bal).col = hrac(i).col
                    bal(hrac(i).bal).strat = 3
                END IF
            NEXT i
 
            '---decide initially tagged player-------------------------------------------------------------
            zacinalNaposledyBal = stav.zacinabal
            stav.balbudeto = stav.zacinabal
            DO
                stav.zacinabal = stav.zacinabal + 1
                IF stav.zacinabal > stav.pocetgulx THEN stav.zacinabal = 1
            LOOP UNTIL bal(stav.zacinabal).riadena = 1
            stav.baljeto = stav.zacinabal
 
            FOR b = 1 TO stav.pocethracov
                bal(hrac(b).bal).protivnik = stav.baljeto * -(hrac(b).bal <> stav.baljeto)
            NEXT b
            bal(stav.zacinabal).protivnik = zacinalNaposledyBal
 
            '----------------------------------game action loop--------------------------------------------
            DO
                game.tstart = TIMER(.001)
                _LIMIT stav.fps
                CLS 1
                k = _KEYHIT
                IF k = 116 AND game.clientid > 0 AND game.msgwrite = 0 THEN game.msgwrite = 1: k = 0 'message writing mode
                IF game.msgwrite = 1 THEN WriteMessage k: k = 0
                IF NOT (game.isnetgame = 1 AND game.clienth <> 0) AND (k = 112 OR k = 102) THEN stav.pauza = 1 - stav.pauza
 
                DrawScore 'Draw players score on screen
                DisplayMessages 'Draw messages
 
                '---debug code begin---------------------------------------------
                IF k = 98 THEN game.printdebug = -(game.printdebug = 0)
                IF game.printdebug = 1 THEN DebugScreen k 'display debug info on screen
                '---debug code end-----------------------------------------------
 
                IF k = 99 THEN game.show_stats = -(game.show_stats = 0)
                IF game.show_stats = 1 THEN DisplayStatistics 'display match statistics
 
                IF stav.pauza = 0 THEN
                    FOR i = 1 TO stav.pocethracov
                        ResolvePlayerControl bal(hrac(i).bal), klav(hrac(i).klavesy) 'resolve players control
                        IF bal(hrac(i).bal).riadena = 1 THEN
                            CalculatePlayerState bal(hrac(i).bal) 'calculate player status
                        END IF
                    NEXT i
 
                    FOR n = 1 TO stav.pocetgul
                        PerformMovement bal(n) 'do ball movement
                    NEXT n
 
                    FOR i = 1 TO stav.pocetgul
                        FOR j = i + 1 TO stav.pocetgul
                            BounceTest bal(i), bal(j) 'Test balls bounce
                        NEXT j
                    NEXT i
                ELSE
                    PauseGame
                END IF
 
                IF game.isnetgame = 1 THEN SyncNetGameData
 
                FOR n = 1 TO stav.pocetgul
                    DrawBall bal(n) 'draw ball
                NEXT n
 
                IF stav.vitaz <> 0 THEN DrawWinScreen
 
                IF NOT (game.isnetgame = 1 AND game.clienth <> 0) AND (k = 102) THEN stav.pauza = 1
                IF k = 27 AND game.isnetgame = 1 THEN AddMessage "To quit network game press 't' and type '/q'", MSG_COL, MSG_DUR_STD, 0: k = 0
                IF k = 27 AND game.isnetgame = 0 THEN stav.koniec_kola = 2
 
                _DISPLAY 'Turn video page over
                game.tend = TIMER(.001)
                CalculateFps
            LOOP UNTIL stav.koniec_kola >= 1
            '---------------------------end of game action loop---------------------------------------------
 
            IF stav.vitaz <> 0 THEN k = 0
            anyHumanPlayer = HumanPlayersCount
            resumegame = 0
            DO 'wait for resume if not net game
                _LIMIT stav.fps
                IF k = 27 AND game.hosth = 0 THEN stav.koniec_kola = 2
                FOR i = 1 TO stav.pocethracov
                    IF klav(hrac(i).klavesy).typ = 3 THEN ReadGamepad klav(hrac(i).klavesy)
                    IF klav(hrac(i).klavesy).isshoota THEN resumegame = 1
                    IF klav(hrac(i).klavesy).isshootb THEN stav.koniec_kola = 2
                    IF klav(hrac(i).klavesy).typ = 1 THEN IF _KEYDOWN(klav(hrac(i).klavesy).shoota) THEN resumegame = 1
                NEXT i
                k = _KEYHIT
            LOOP UNTIL (resumegame = 1) OR (anyHumanPlayer = 0) OR (stav.koniec_kola = 2) OR (game.isnetgame = 1)
            '---------------------------end of round-----------------------------------------------------------
        LOOP UNTIL stav.koniec_kola = 2 OR (stav.AIallowed = 0 AND anyHumanPlayer < 2)
        IF (stav.AIallowed = 0 AND anyHumanPlayer < 2) THEN AddMessage "Match was ended for less than 2 players left", MSG_COL, MSG_DUR_STD, 0
    END IF
    '---------------------------end of game------------------------------------------------------------
    game.autostart_time = TIMER + stav.autostart_set
LOOP UNTIL game.exituj = 1
CLS 1
'---------------------------end of program------------------------------------------------------------
 
'////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawWinScreen
    DIM statstab(1 TO PLAYER_NET_MAX) AS STRING
    IF stav.vitaz > 0 THEN
        IF hrac(stav.vitaz).skore >= stav.winscore THEN windelay = DELAY_MATCHEND ELSE windelay = DELAY_ROUNDSTART
        IF game.autostart_time - windelay > TIMER THEN game.autostart_time = game.autostart_time - 86399
        IF (game.autostart_time <= TIMER) AND (game.isnetgame = 0 OR game.hosth <> 0) THEN
            stav.koniec_kola = 1 'end of round
            IF hrac(stav.vitaz).skore >= stav.winscore THEN stav.koniec_kola = 2 'end of match either
        END IF
        IF (game.isnetgame = 0 OR game.hosth <> 0) THEN stav.autostart_timeleft = game.autostart_time - TIMER
        IF INT(stav.autostart_timeleft) >= 0 THEN timeleft$ = "  (" + LTRIM$(STR$(INT(stav.autostart_timeleft))) + ")" ELSE timeleft$ = ""
        IF hrac(stav.vitaz).skore < stav.winscore THEN
            winstr1$ = "....and the winner of this round is... " + RTRIM$(hrac(stav.vitaz).meno) + timeleft$
            winstr2$ = "Press <fire> for the next round"
        ELSE
            winstr1$ = "...>>> " + RTRIM$(hrac(stav.vitaz).meno) + " <<<.... scores " + LTRIM$(STR$(stav.winscore)) + " and becomes the MATCH WINNER!" + timeleft$
            winstr2$ = "Press <fire> to return to the menu"
            DisplayStatistics
        END IF
        COLOR bal(hrac(stav.vitaz).bal).col
        _PRINTSTRING ((game.maxx - LEN(winstr1$) * 10) / 2, (game.maxy - 50) / 2), winstr1$
        IF stav.koniec_kola > 0 THEN _PRINTSTRING ((game.maxx - LEN(winstr2$) * 10) / 2, (game.maxy - 50) / 2 + 50), winstr2$
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DisplayStatistics
    IF stav.pocethracov <= PLAYER_NET_MAX THEN playercount = stav.pocethracov ELSE playercount = PLAYER_NET_MAX
    row = INT((game.maxy - (playercount + 4) * _FONTHEIGHT) / _FONTHEIGHT)
    col = INT((game.maxx - ((playercount + 2) * 11 * _FONTWIDTH)) / 2 / _FONTWIDTH)
    IF row < 1 THEN row = 1
    IF col < 1 THEN col = 1
    COLOR MSG_COL
    LOCATE row, col
    PRINT "Match statistics - tags given by player"
    LOCATE row + 1, col
    PRINT STRING$((playercount + 2) * 11, "-"),
    LOCATE row + 2, col
    PRINT "Player"
    FOR i = 1 TO playercount
        COLOR hrac(i).col
        LOCATE row + 2, col + i * 11
        PRINT RTRIM$(hrac(i).meno)
    NEXT i
    COLOR MSG_COL
    LOCATE row + 2, col + i * 11
    PRINT "Tags given"
    FOR i = 1 TO playercount
        tagsum = 0
        LOCATE row + 2 + i, col
        COLOR hrac(i).col
        PRINT RTRIM$(hrac(i).meno)
        FOR j = 1 TO playercount
            LOCATE row + 2 + i, col + j * 11
            IF stats(i, j) > 0 THEN PRINT STR$(stats(i, j))
            tagsum = tagsum + stats(i, j)
        NEXT j
        LOCATE row + 2 + i, col + j * 11
        PRINT STR$(tagsum)
    NEXT i
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION HumanPlayersCount 'set pre-game parameters
    HumanPlayersCount = 0
    FOR i = 1 TO stav.pocethracov
        IF bal(hrac(i).bal).complayer = 0 THEN HumanPlayersCount = HumanPlayersCount + 1
    NEXT i
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SetGlobalParameters 'set pre-game parameters
    '-------------------------------set game session parameters----------------------------------------------------------------------------------------
    game.fpsactual = FPS
    game.isnetgame = 0
    game.clienth = 0
    game.clientid = 0
    game.hosth = 0
    game.host_port = HOSTPORT_DEFAULT
    game.host_ip = HOSTIP_DEFAULT
    game.printdebug = DEBUGMODE
    game.exituj = 0
    game.start = 0
    game.newmsg = 0
    IF RES_X = -1 THEN game.maxx = _DESKTOPWIDTH ELSE game.maxx = RES_X
    IF RES_Y = -1 THEN game.maxy = _DESKTOPHEIGHT ELSE game.maxy = RES_Y
    game.msgcount = 0
    game.msgwrite = 0
    game.msgtext = ""
    game.show_stats = 0
    sync.syncstr = GETITEM_SYNC
    sync.synctime = 0
 
    '-------------------------------set game world parameters----------------------------------------------------------------------------------------
    pi = _PI
    stav.syncstr = GETITEM_STAV
    stav.synctime = 0
    stav.pauza = 0
    stav.gameplay = 0
    stav.fps = FPS
    stav.pocethracov = PLAYER_COUNT_INI
    stav.pocetgulzvoleny = POCET_GUL_INI
    stav.pocetgul = POCET_GUL_INI
    stav.energy_allmin = ENERGY_ALL_MIN
    stav.energy_playermin = ENERGY_PLAYER_MIN
    stav.energy_playermax = ENERGY_PLAYER_MAX
    stav.energydec = ENERGY_DEC
    stav.odpor = FRICTION
    stav.minx = 0
    stav.miny = 0
    stav.maxx = RES_X_TARG
    stav.maxy = RES_Y_TARG
    stav.vmax = V_MAX * stav.maxx / RES_X_TARG
    stav.maxcol = MAX_COL
    stav.boostallowed = 1
    stav.massallowed = 0 'sticky balls problem if mass allowed unsolved yet
    stav.autostart_set = 0
    game.autostart_time = 0
    stav.AIallowed = 1
    stav.winscore = 3
    stav.energy_player_start = (stav.energy_allmin / stav.pocethracov) 'calculate  players energy
    IF stav.energy_player_start < stav.energy_playermin THEN stav.energy_player_start = stav.energy_playermin
    IF stav.energy_player_start > stav.energy_playermax THEN stav.energy_player_start = stav.energy_playermax
 
    stats(PLAYER_NET_MAX + 1, 1) = ASC(GETITEM_STAT, 1)
    stats(PLAYER_NET_MAX + 1, 2) = ASC(GETITEM_STAT, 2)
    stats(PLAYER_NET_MAX + 1, 3) = ASC(GETITEM_STAT, 3)
 
    '-------------------------------set game controllers---------------------------------------------------------------------------------------------
    FOR i = 1 TO UBOUND(klav) 'set all the other game controllers as unused, few reserved for net players
        IF i <= PLAYER_NET_MAX THEN
            klav(i).typ = 5
            klav(i).nazov = "NetControl" + LTRIM$(STR$(i))
        ELSE
            klav(i).typ = 0
        END IF
        klav(i).devid = 0
        klav(i).syncstr = GETITEM_KLAV
        klav(i).synctime = 0
    NEXT i
 
    'set default controllers
    kid = PLAYER_NET_MAX + 1 'CPU void controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<CPU>": klav(kid).typ = 4
 
    kid = PLAYER_NET_MAX + 2 'keyboard set 1 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<Arrow keys + LShift>": klav(kid).typ = 1
    klav(kid).up = 18432: klav(kid).down = 20480: klav(kid).left = 19200: klav(kid).right = 19712
    klav(kid).shoota = 100304: klav(kid).shootb = 100306
 
    kid = PLAYER_NET_MAX + 3 'keyboard set 2 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<W,A,S,D + RShift>": klav(kid).typ = 1
    klav(kid).up = 119: klav(kid).down = 115: klav(kid).left = 97: klav(kid).right = 100
    klav(kid).shoota = 100303: klav(kid).shootb = 100305
 
    kid = PLAYER_NET_MAX + 4 'keyboard set 3 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<I,J,K,L + Enter>": klav(kid).typ = 1
    klav(kid).up = 105: klav(kid).down = 107: klav(kid).left = 106: klav(kid).right = 108
    klav(kid).shoota = 13: klav(kid).shootb = 21248
 
    '-------------------------------set players------------------------------------------------------------------------------------------------------
    FOR i = 1 TO UBOUND(hrac) 'initial setting for all players
        hrac(i).bal = i
        hrac(i).meno = "Player" + LTRIM$(STR$(i))
        hrac(i).skore = 0
        hrac(i).klavesy = CPU_CONTROLID
        hrac(i).col = 32 + i * 3
        hrac(i).clientid = 0
        bal(hrac(i).bal).complayer = 1
        hrac(i).syncstr = GETITEM_HRAC
        hrac(i).synctime = 0
    NEXT i
 
    'personalize some players initially
    bal(hrac(1).bal).complayer = 0
    hrac(1).klavesy = PLAYER_NET_MAX + 2
    hrac(1).meno = "Chuck"
    hrac(2).meno = "Arnold"
    hrac(3).meno = "Jean"
    hrac(4).meno = "Bruce"
    hrac(5).meno = "Dolph"
    hrac(6).meno = "Sylvester"
    hrac(7).meno = "Jet"
    hrac(8).meno = "Dwayne"
 
    '-------------------------------set behaviour strategies------------------------------------------------------------------------------------------
    'some void strategy
    strat(1).okraj = PRIESTOR_MIN:
    strat(1).okraj_rot = 0.1
    strat(1).chybasmeru = 0.00:
    strat(1).klucka_avgtm = 1 * FPS: strat(1).klucka_pocet = 5
    strat(1).klucka_trvanie = 0.25 * FPS: strat(1).klucka_uhol = pi / 2: strat(1).klucka_uholodch = 0.2
    strat(1).detekcia_sin = SIN(pi / 4): strat(1).detekcia_vzdfull = 500: strat(1).detekcia_vzdmin = 1000: strat(1).detekcia_rot = 0.5
    strat(1).boost_dist = 200
    strat(1).boost_chasesin = SIN(pi / 8)
    strat(1).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(1).mate_rot = 0.1 ' 3*pi /FPS
    strat(1).mate_en_distmin = 5 * PLAY_BALL_R
    strat(1).mate_distmin = 4 * PLAY_BALL_R
 
    'non dodging strategy
    strat(2).okraj = PRIESTOR_MIN + 10
    strat(2).okraj_rot = 0.1
    strat(2).chybasmeru = 0.00
    strat(2).reactdrop_per = 0 * FPS
    strat(2).reactdrop_dur = 0 * FPS
    strat(2).klucka_avgtm = 10 * FPS
    strat(2).klucka_pocet = 0
    strat(2).klucka_trvanie = 0 * FPS
    strat(2).klucka_uhol = 0 * pi / 3
    strat(2).klucka_uholodch = 0.2
    strat(2).detekcia_sin = SIN(pi / 6)
    strat(2).detekcia_vzdfull = 500
    strat(2).detekcia_vzdmin = 1000
    strat(2).detekcia_rot = 0.5
    strat(2).boost_dist = 200
    strat(2).boost_chasesin = SIN(pi / 8)
    strat(2).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(2).mate_rot = 0.1 ' 3*pi /FPS
    strat(2).mate_en_distmin = 5 * PLAY_BALL_R
    strat(2).mate_distmin = 4 * PLAY_BALL_R
 
    'dodging strategy - currently used for all AI players
    strat(3).okraj = PRIESTOR_MIN + 10
    strat(3).okraj_rot = 0.1
    strat(3).chybasmeru = 0.30
    strat(3).reactdrop_per = 0.8 * FPS
    strat(3).reactdrop_dur = 0.4 * FPS
    strat(3).klucka_avgtm = 5 * FPS
    strat(3).klucka_pocet = 3
    strat(3).klucka_trvanie = 2 * FPS
    strat(3).klucka_uhol = pi * 2 / 3
    strat(3).klucka_uholodch = 0.2
    strat(3).detekcia_sin = SIN(pi / 6)
    strat(3).detekcia_vzdfull = 300
    strat(3).detekcia_vzdmin = 1500
    strat(3).detekcia_rot = 0.5 '10 * pi / FPS
    strat(3).boost_dist = 200
    strat(3).boost_chasesin = SIN(pi / 8)
    strat(3).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(3).mate_rot = 0.1 ' 3*pi /FPS
    strat(3).mate_en_distmin = 8 * PLAY_BALL_R
    strat(3).mate_distmin = 4 * PLAY_BALL_R
    strat(3).adrenalin_rate = 0.90
    strat(3).adrenalin_energy = 0.30
 
    '-------------------------------set main menu-----------------------------------------------------------------------------------------------------
    menu.item_active = 1
    menu.items_count = 22
    menu.cursor_col = 15
    menu.cursor_width = 400
    menu.item_height = FONT_H + 4
    menu.cursor_xpos = INT((game.maxx - menu.cursor_width) / 2)
    menu.ypos = INT((game.maxy - menu.items_count * menu.item_height) / 2)
    menu.cursor_out = 5
    '-------------------------------set balls---------------------------------------------------------------------------------------------------------
    FOR n = 1 TO stav.pocethracov: bal(n).syncstr = GETITEM_PBAL: bal(n).synctime = 0: NEXT n
    FOR n = stav.pocethracov + 1 TO UBOUND(bal): bal(n).syncstr = GETITEM_BAL: bal(n).synctime = 0: NEXT n
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB WriteMessage (k AS INTEGER)
    DIM tmptext AS STRING
    IF game.clientid > 0 THEN
        msginput_x = 10
        msginput_y = RES_Y - 20
 
        tmptext = LEFT$(game.msgtext, LEN(RTRIM$(game.msgtext)) - 1)
        IF k >= 32 AND k <= 126 AND LEN(tmptext) < MSG_LEN_MAX THEN tmptext = tmptext + CHR$(k)
        IF k = 8 AND LEN(tmptext) > 0 THEN tmptext = LEFT$(tmptext, LEN(tmptext) - 1)
        IF k = 27 THEN game.msgwrite = 0
 
        COLOR MSG_COL
        _PRINTSTRING (msginput_x, msginput_y), "Type message>>  " + tmptext
        IF k = -1 AND game.msgwrite = 0 THEN _PRINTSTRING (msginput_x, msginput_y), "Press 't' to writte text message to other players" + tmptext
 
 
        IF k = 13 THEN
            IF LEFT$(tmptext, 1) = "/" THEN
                AddMessage tmptext, MSG_COL, MSG_DUR_STD, 0
            ELSE
                AddMessage RTRIM$(hrac(game.clientid).meno) + "> " + tmptext, hrac(game.clientid).col, MSG_DUR_STD, 1
            END IF
            game.msgtext = CHR$(92)
            game.msgwrite = 0
        ELSE
            game.msgtext = tmptext + CHR$(92)
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SetUpControllers 'detect gamepads and set them as game controllers
    DIM klav_volne AS INTEGER, devices AS INTEGER
    DIM dev AS STRING
 
    FOR i = 1 TO UBOUND(klav) 'dispose all gamepad constrollers
        IF klav(i).typ = 3 THEN
            klav(i).typ = 0
            klav(i).devid = 0
        END IF
    NEXT i
    klav_volne = 1
    game.pocetgamepadov = 0
    DO
        klav_volne = klav_volne + 1
    LOOP UNTIL klav(klav_volne).typ = 0 OR klav_volne = UBOUND(klav)
    klav_used = klav_volne - 1
    devices = _DEVICES 'must be read prior to other device functions usage
    FOR i = 1 TO devices
        dev = _DEVICE$(i)
        IF INSTR(dev, "[CONTROLLER]") > 0 AND INSTR(dev, "[AXIS]") > 0 AND klav_volne <= UBOUND(klav) THEN 'set new controller if gamepad
            klav(klav_volne).id = klav_volne
            klav(klav_volne).devid = i
            klav(klav_volne).typ = 3
            klav(klav_volne).nazov = "<Gamepad" + LTRIM$(STR$(klav_volne - klav_used)) + ">"
            klav(klav_volne).xaxis = 1
            klav(klav_volne).yaxis = 2
            klav(klav_volne).dxaxis = _LASTAXIS(i) - 1
            klav(klav_volne).dyaxis = _LASTAXIS(i)
            klav(klav_volne).shoota = 1
            klav(klav_volne).shootb = 8
            klav_volne = klav_volne + 1
            game.pocetgamepadov = game.pocetgamepadov + 1
        END IF
    NEXT i
    game.pocetkontrolerov = klav_volne - 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB MainMenuScreen 'perform choises in main menu
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SyncNetGameData
    DIM i AS INTEGER, isync AS tsyncvar, clklav AS tklavesy, clhrac AS thrac, imsg AS tmessage
    DIM sync_stav AS INTEGER, sync_pbal AS INTEGER, sync_bal AS INTEGER, sync_hrac AS INTEGER
    IF game.isnetgame = 1 THEN
        '--------------------------host side---------------------------------------------------------------------------------------------------------
        IF game.hosth <> 0 THEN 'sync host data
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'for each client try to connect
                IF client(i).conn = 0 AND i <= stav.pocethracov THEN
                    client(i).conn = _OPENCONNECTION(game.hosth) 'try to open connection if not open
                    client(i).get_item = GETITEM_SYNC
                    client(i).get_isdesync = 0
                    client(i).get_time = TIMER(.001)
                    IF client(i).conn <> 0 THEN 'if connection opened
                        client(i).ip = _CONNECTIONADDRESS(client(i).conn)
                        PLAY "MBL64O2CEG>C"
                        IF stav.gameplay = 1 THEN
                            client(i).spectating = 1
                            game.sync_stats = 1
                            msgtext$ = " joins the game from the next round"
                        ELSE
                            client(i).spectating = 0
                            msgtext$ = " has joined the game"
                        END IF
                        AddMessage "Player " + RTRIM$(hrac(i).meno) + msgtext$, MSG_COL, MSG_DUR_STD, 1
                    END IF
                END IF
                IF (TIMER(.001) - client(i).get_time) > NET_TIMEOUT_LIMIT AND client(i).conn <> 0 THEN CloseClientConn (i)
            NEXT i
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'sync data with each client
                sync.clientid = i
                IF client(i).conn <> 0 THEN
                    DO
                        IF client(i).get_isdesync = 1 THEN 'flush acquired data if desynced
                            GET #client(i).conn, , flush$
                            client(i).get_isdesync = 0
                            client(i).get_item = GETITEM_SYNC
                        END IF
 
                        IF client(i).get_item = GETITEM_SYNC THEN 'first get sync info on what item to get next
                            GET #client(i).conn, , isync
                            IF NOT EOF(client(i).conn) THEN
                                IF isync.syncstr = GETITEM_SYNC THEN
                                    client(i).get_item = isync.itemstr
                                    client(i).get_time = TIMER(.001)
                                    client(i).isdesynced = isync.isdesync
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_KLAV THEN 'get controller state from client
                            GET #client(i).conn, , clklav
                            IF NOT EOF(client(i).conn) THEN
                                IF clklav.syncstr = GETITEM_KLAV THEN
                                    klav(hrac(i).klavesy).isup = clklav.isup
                                    klav(hrac(i).klavesy).isdown = clklav.isdown
                                    klav(hrac(i).klavesy).isright = clklav.isright
                                    klav(hrac(i).klavesy).isleft = clklav.isleft
                                    klav(hrac(i).klavesy).isshoota = clklav.isshoota
                                    klav(hrac(i).klavesy).isshootb = clklav.isshootb
                                    klav(hrac(i).klavesy).gvektor = clklav.gvektor
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_HRAC THEN 'get client's player
                            GET #client(i).conn, , clhrac
                            IF NOT EOF(client(i).conn) THEN
                                IF clhrac.syncstr = GETITEM_HRAC THEN
                                    clhrac.skore = hrac(i).skore 'keep players socre
                                    hrac(i) = clhrac 'get player data from client
                                    hrac(i).klavesy = i 'set player net controlled
                                    hrac(i).clientid = i 'set player's clientid
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_MESG THEN 'get message from client
                            GET #client(i).conn, , imsg
                            IF NOT EOF(client(i).conn) THEN
                                IF imsg.syncstr = GETITEM_MESG THEN
                                    AddMessage imsg.text, imsg.col, imsg.time_dur, 1
                                    msg(game.msgcount).clientid = imsg.clientid
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                    LOOP UNTIL EOF(client(i).conn)
                END IF
            NEXT i
 
            IF TIMER(.001) - stav.synctime > UPDATE_PER_STAV THEN 'check if update time
                sync_stav = 1
            ELSE sync_stav = 0
            END IF
            IF TIMER(.001) - bal(1).synctime > UPDATE_PER_PLBAL THEN
                FOR j = 1 TO stav.pocethracov: ipbal(j) = bal(j): NEXT j 'fill transfer array
                sync_pbal = 1
            ELSE sync_pbal = 0
            END IF
            IF TIMER(.001) - bal(stav.pocethracov + 1).synctime > UPDATE_PER_BAL THEN
                FOR j = 1 TO stav.pocetgulzvoleny: ibal(j) = bal(j + stav.pocethracov): NEXT j 'fill transfer array
                sync_bal = 1
            ELSE sync_bal = 0
            END IF
            IF TIMER(.001) - hrac(1).synctime > UPDATE_PER_HRAC THEN
                sync_hrac = 1
            ELSE sync_hrac = 0
            END IF
 
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'send host data to each client
                IF client(i).conn <> 0 THEN
                    sync.clientid = i
 
                    IF client(i).isdesynced = 1 THEN 'send sync var if client desynced
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_SYNC
                        PUT #client(i).conn, , sync
                        'PRINT "Resyncing client "; i 'TEMP DEBUG line
                    END IF
 
                    IF sync_stav = 1 AND client(i).isdesynced = 0 THEN 'send world state
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_STAV
                        PUT #client(i).conn, , sync
                        stav.synctime = TIMER(.001)
                        PUT #client(i).conn, , stav
                    END IF
 
                    IF sync_pbal = 1 AND client(i).isdesynced = 0 THEN 'send player balls
                        sync.synctime = TIMER(.001):
                        sync.itemstr = GETITEM_PBAL
                        PUT #client(i).conn, , sync
                        bal(1).synctime = TIMER(.001)
                        PUT #client(i).conn, , ipbal()
                    END IF
 
                    IF sync_bal = 1 AND client(i).isdesynced = 0 THEN 'send nonplayer balls
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_BAL
                        bal(stav.pocethracov + 1).synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        PUT #client(i).conn, , ibal()
                    END IF
 
                    IF sync_hrac = 1 AND client(i).isdesynced = 0 THEN 'IF stav.gameplay = 0 OR stav.vitaz <> 0 THEN 'send players
                        FOR j = 1 TO PLAYER_NET_MAX: ihrac(j) = hrac(j): NEXT j 'fill transfer array
                        sync.itemstr = GETITEM_HRAC
                        sync.synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        hrac(1).synctime = TIMER(.001)
                        PUT #client(i).conn, , ihrac()
                    END IF
 
                    IF game.sync_stats = 1 AND client(i).isdesynced = 0 THEN 'send match statistics
                        sync.itemstr = GETITEM_STAT
                        sync.synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        PUT #client(i).conn, , stats()
                    END IF
 
                    IF game.newmsg = 1 AND client(i).isdesynced = 0 THEN 'send new messages
                        FOR j = 1 TO game.msgcount
                            IF msg(j).distribute = 1 AND msg(j).clientid <> i THEN
                                sync.itemstr = GETITEM_MESG:
                                sync.synctime = TIMER(.001):
                                PUT #client(i).conn, , sync
                                msg(j).synctime = TIMER(.001):
                                PUT #client(i).conn, , msg(j)
                            END IF
                        NEXT j
                    END IF
 
                END IF
            NEXT i
            game.sync_stats = 0 'clear send statistics flag
            game.newmsg = 0 'clear messages distributed flags
            FOR j = 1 TO game.msgcount
                msg(j).distribute = 0
            NEXT j
        END IF
 
        '-------------------client side-------------------------------------------------------------------------------
        IF game.clienth <> 0 THEN 'client getting data from host
            DO
                IF game.get_isdesync = 1 THEN 'flush acquired data if desynced
                    'PRINT "Resyncing... "; game.get_item 'TEMP debug line
                    DO
                        GET #game.clienth, , isync
                    LOOP UNTIL (NOT EOF(game.clienth) AND isync.syncstr = GETITEM_SYNC) OR (TIMER(.001) - game.get_time) > NET_TIMEOUT_SYNC
 
                    'GET #game.clienth, , flush$
 
                    IF NOT EOF(game.clienth) AND isync.syncstr = GETITEM_SYNC THEN
                        'PRINT "==================RESYNCED================ "; game.get_item; "-"; isync.itemstr 'TEMP debug line
                        game.get_item = isync.itemstr
                        game.get_isdesync = 0
                    ELSE
                        'PRINT "Desynced!!!!!!!!!!!!! "; game.get_item 'TEMP debug line
                    END IF
                END IF
 
                IF game.get_item = GETITEM_SYNC THEN 'first get sync info on what item to get next
                    GET #game.clienth, , isync
                    IF NOT EOF(game.clienth) THEN
                        IF isync.syncstr = GETITEM_SYNC THEN
                            game.clientid = isync.clientid
                            game.get_item = isync.itemstr
                            game.get_time = TIMER(.001)
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                    END IF
                END IF
 
                IF game.get_item = GETITEM_STAV THEN 'get world state
                    GET #game.clienth, , istav
                    IF NOT EOF(game.clienth) THEN
                        IF istav.syncstr = GETITEM_STAV THEN
                            IF istav.synctime > stav.synctime THEN
                                stav = istav
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_PBAL THEN 'get player balls data
                    GET #game.clienth, , ipbal()
                    IF NOT EOF(game.clienth) THEN
                        IF (ipbal(1).syncstr = GETITEM_PBAL) THEN
                            IF (ipbal(1).synctime > bal(1).synctime) THEN 'AND (TIMER(.001) - game.timer_pballs) < (ipbal(1).synctime - bal(1).synctime + 0.05) THEN
                                FOR i = 1 TO stav.pocethracov
                                    bal(i) = ipbal(i)
                                NEXT i
                            END IF
                            game.timer_pballs = TIMER(.001)
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_BAL THEN 'get nonplayer balls data
                    GET #game.clienth, , ibal()
                    IF NOT EOF(game.clienth) THEN
                        IF (ibal(1).syncstr = GETITEM_BAL) THEN
                            IF (ibal(1).synctime > bal(stav.pocethracov + 1).synctime) THEN
                                FOR i = 1 TO stav.pocetgulzvoleny
                                    bal(stav.pocethracov + i) = ibal(i)
                                NEXT i
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_MESG THEN 'get message
                    GET #game.clienth, , imsg
                    IF NOT EOF(game.clienth) THEN
                        IF (imsg.syncstr = GETITEM_MESG) THEN
                            AddMessage imsg.text, imsg.col, imsg.time_dur, 0
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_HRAC THEN 'get players data
                    GET #game.clienth, , ihrac()
                    IF NOT EOF(game.clienth) THEN
                        IF ihrac(1).syncstr = GETITEM_HRAC THEN
                            IF ihrac(1).synctime > hrac(1).synctime THEN
                                FOR i = 1 TO PLAYER_NET_MAX
                                    IF i <> game.clientid AND game.clientid > 0 THEN 'if another client's player
                                        hrac(i) = ihrac(i) 'get player data from host
                                        hrac(i).klavesy = i 'set player net controlled
                                    ELSE 'if my client player
                                        hrac(i).skore = ihrac(i).skore
                                        hrac(i).bal = ihrac(i).bal
                                        hrac(i).clientid = ihrac(i).clientid
                                    END IF
                                NEXT i
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_STAT THEN 'get match statistics
                    GET #game.clienth, , istats()
                    IF NOT EOF(game.clienth) THEN
                        IF (istats(PLAYER_NET_MAX + 1, 1) + istats(PLAYER_NET_MAX + 1, 2) + istats(PLAYER_NET_MAX + 1, 3)) = (ASC(GETITEM_STAT, 1) + ASC(GETITEM_STAT, 2) + ASC(GETITEM_STAT, 3)) THEN
                            FOR i = 1 TO UBOUND(stats, 1)
                                FOR j = 1 TO UBOUND(stats, 2)
                                    stats(i, j) = istats(i, j)
                                NEXT j
                            NEXT i
                            game.sync_stats = 0
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
            LOOP UNTIL EOF(game.clienth)
 
            IF game.clientid > 0 THEN 'send clients data to host
                sync.synctime = TIMER(.001)
 
                'IF stav.gameplay = 1 THEN 'send client controller to host
                sync.itemstr = GETITEM_KLAV
                sync.synctime = TIMER(.001)
                sync.isdesync = game.get_isdesync
                PUT #game.clienth, , sync
                PUT #game.clienth, , klav(hrac(game.clientid).klavesy)
                'END IF
 
                'IF stav.gameplay = 0 THEN 'send client player to host
                sync.itemstr = GETITEM_HRAC
                sync.synctime = TIMER(.001)
                PUT #game.clienth, , sync
                PUT #game.clienth, , hrac(game.clientid)
                'END IF
 
                IF game.newmsg = 1 AND game.msgcount > 0 THEN 'send client player to host
                    IF msg(game.msgcount).distribute = 1 THEN
                        sync.itemstr = GETITEM_MESG
                        sync.synctime = TIMER(.001)
                        PUT #game.clienth, , sync
                        PUT #game.clienth, , msg(game.msgcount)
                        msg(game.msgcount).distribute = 0
                    END IF
                    game.newmsg = 0
                END IF
            END IF
 
            IF (TIMER(.001) - game.get_time) > NET_TIMEOUT_LIMIT THEN ResetNetGame
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CloseClientConn (clidx AS INTEGER)
    IF client(clidx).conn <> 0 THEN
        CLOSE client(clidx).conn
        client(clidx).conn = 0
    END IF
    hrac(clidx).clientid = 0
    hrac(clidx).klavesy = CPU_CONTROLID
    hrac(clidx).isready = 0
    bal(hrac(clidx).bal).complayer = 1
    IF stav.AIallowed = 0 AND klav(hrac(clidx).klavesy).typ = 4 THEN
        bal(hrac(clidx).bal).energia = 0
        CalculatePlayerState bal(hrac(clidx).bal)
    END IF
    AddMessage "Player " + RTRIM$(hrac(clidx).meno) + " was disconnected", MSG_COL, MSG_DUR_STD, 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ResetNetGame
    IF game.clienth <> 0 THEN 'try to close client connection
        CLOSE game.clienth
        game.clienth = 0
        game.clientid = 0
        stav.autostart_set = 0
        AddMessage "You have been disconnected from the host", MSG_COL, MSG_DUR_STD, 0
    END IF
    IF game.hosth <> 0 THEN 'try to close host service
        CLOSE game.hosth
        game.hosth = 0
        game.clientid = 0
        hrac(1).clientid = 0
        AddMessage "Game hosting ended", MSG_COL, MSG_DUR_STD, 0
    END IF
    game.isnetgame = 0
    FOR i = 1 TO PLAYER_COUNT_MAX
        hrac(i).clientid = 0
        IF (klav(hrac(i).klavesy).typ = 5) OR (i > PLAYER_NET_MAX AND klav(hrac(i).klavesy).typ <> 4) THEN
            hrac(i).klavesy = CPU_CONTROLID
            bal(hrac(i).bal).complayer = 1
        END IF
    NEXT i
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB HostGame
    IF game.clienth <> 0 THEN ResetNetGame
    IF game.hosth = 0 THEN
        game.hosth = _OPENHOST("TCP/IP:" + STR$(game.host_port))
        IF game.hosth <> 0 THEN
            game.isnetgame = 1
            game.clientid = 1
            hrac(1).clientid = 1
            AddMessage "Game hosting started", MSG_COL, MSG_DUR_STD, 0
        ELSE
            game.isnetgame = 0
        END IF
    ELSE
        ResetNetGame
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB JoinGame
    IF game.hosth <> 0 THEN ResetNetGame
    IF game.clienth = 0 THEN
        AddMessage "Connecting to" + RTRIM$(STR$(game.host_port)) + ":" + RTRIM$(game.host_ip) + "...", MSG_COL, MSG_DUR_STD, 0
        DisplayMessages
        _DISPLAY
        game.clienth = _OPENCLIENT("TCP/IP:" + STR$(game.host_port) + ":" + RTRIM$(game.host_ip))
        IF game.clienth <> 0 THEN
            game.isnetgame = 1
            game.get_item = GETITEM_SYNC
            game.get_isdesync = 0
            game.get_time = TIMER(.001)
            game.timer_pballs = TIMER(.001)
            AddMessage "Connection opened, joining the game...", MSG_COL, MSG_DUR_STD, 0
        ELSE
            game.isnetgame = 0
        END IF
    ELSE
        CLOSE game.clienth
        ResetNetGame
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION InputText$ (meno AS STRING, xpos AS INTEGER, ypos AS INTEGER, col AS INTEGER, inputwidth AS _BYTE, hint AS STRING, initval AS _BYTE, digitonly AS _BYTE) 'get text input from keyboard input
    clrstr$ = ""
    tmpstr$ = ""
    IF initval = 1 THEN res$ = RTRIM$(meno) ELSE res$ = ""
    FOR i = 1 TO inputwidth: clrstr$ = clrstr$ + " ": NEXT i
    COLOR col
    DO
        DO
            _LIMIT FPS
            k = _KEYHIT
        LOOP UNTIL k <> 0
        IF ((digitonly = 0 AND k >= 33 AND k <= 126) OR (digitonly = 1 AND k >= 48 AND k <= 57)) AND LEN(res$) < LEN(meno) THEN res$ = res$ + CHR$(k)
        IF k = 8 AND LEN(res$) > 0 THEN res$ = LEFT$(res$, LEN(res$) - 1)
        IF res$ = "" THEN tmpstr$ = hint ELSE tmpstr$ = res$
        _PRINTSTRING (xpos, ypos), clrstr$
        _PRINTSTRING (xpos, ypos), tmpstr$
        _DISPLAY
    LOOP UNTIL k = 13 OR k = 27
    IF k = 13 THEN InputText$ = res$
    IF k = 27 THEN InputText$ = CHR$(27)
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PrintMenuItem (id AS INTEGER, amenu AS tmenu, menucode AS INTEGER, playercode AS INTEGER, rollable AS INTEGER, s AS STRING, fixedwidth AS INTEGER, deltax AS INTEGER, lineoff AS INTEGER, col AS INTEGER) 'print horizontaly centered text at line y
    slen = LEN(RTRIM$(s)) * FONT_W
    IF fixedwidth > 0 THEN slen = fixedwidth
    px = INT((game.maxx - slen) / 2) + deltax
    py = amenu.ypos + (id - 1) * amenu.item_height
    COLOR col
    _PRINTSTRING (px, py), s
    IF id = amenu.item_active THEN
        IF rollable = 1 THEN
            COLOR amenu.cursor_col
            _PRINTSTRING (amenu.cursor_xpos - 10 - FONT_W, py), "<"
            _PRINTSTRING (amenu.cursor_xpos + amenu.cursor_width + 10, py), ">"
        END IF
        amenu.menucode = menucode
        amenu.playercode = playercode
    END IF
END SUB
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PrintMenuCursor (amenu AS tmenu) 'print menu cursor
    py = amenu.ypos + (amenu.item_active - 1) * amenu.item_height
    COLOR amenu.cursor_col
    LINE (amenu.cursor_xpos - amenu.cursor_out, game.maxy - (py - amenu.cursor_out))-(amenu.cursor_xpos + amenu.cursor_out + amenu.cursor_width, game.maxy - (py + FONT_H) - amenu.cursor_out), amenu.cursor_col, B
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PauseGame 'pause gameplay
    winstr$ = "-> Game paused <-"
    COLOR MSG_COL
    _PRINTSTRING ((game.maxx - LEN(winstr$) * 10) / 2, (game.maxy - 50) / 2), winstr$
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawBall (baln AS gula) 'draw ball
    CONST BSEGM = 10
    koef = (10 + 90 * game.printdebug) * FPS / 100
    bcol = baln.col
    IF baln.freezedtime > 0 THEN bcol = 27
    IF baln.riadena = 1 THEN
        CIRCLE (baln.x, baln.y), baln.r - 1, baln.col
        CIRCLE (baln.x, baln.y), baln.r + 1, baln.col
        FOR i = 1 TO BSEGM
            CIRCLE (baln.x, baln.y), i * (baln.r / 2 - 2) / BSEGM, bcol, 0, baln.energia / stav.energy_player_start * _PI * 2
        NEXT i
        LINE (baln.x, baln.y)-(baln.x + baln.v.x * koef, baln.y + baln.v.y * koef), baln.col 'draw actual velocity
        IF game.printdebug = 1 THEN LINE (baln.x, baln.y)-(baln.x + baln.vi.x * koef, baln.y + baln.vi.y * koef), bal(baln.protivnik).col 'draw intended velocity
    END IF
    IF baln.i = stav.baljeto THEN
        CIRCLE (baln.x, baln.y), baln.r * 2 / 3, 15
    END IF
    IF baln.i > stav.pocethracov THEN
        reflectfrom = ATN((1.25 * stav.maxy - baln.y) / (1.25 * stav.maxx - baln.x))
        CIRCLE (baln.x, baln.y), baln.r - 5, 28, reflectfrom, reflectfrom + _PI / 8
        CIRCLE (baln.x, baln.y), baln.r - 5, 28, reflectfrom + _PI / 8 + _PI / 32, reflectfrom + _PI / 4
        CIRCLE (baln.x, baln.y), baln.r - 10, 28, reflectfrom, reflectfrom + _PI / 8
        CIRCLE (baln.x, baln.y), baln.r - 10, 28, reflectfrom + _PI / 8 + _PI / 32, reflectfrom + _PI / 4
    END IF
 
    CIRCLE (baln.x, baln.y), baln.r, baln.col
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawScore 'Draw player score
    WINDOW (0, 0)-(game.maxx, game.maxy)
    FOR i = 1 TO stav.pocethracov
        scxl = SCORE_DELTA_X * -(game.maxx >= 4 * SCORE_DELTA_X) + game.maxx / 4 * -(game.maxx < 4 * SCORE_DELTA_X)
        dx = (game.maxx - 4 * scxl) / 2
        scx = dx + scxl * ((i - 4 * INT((i - 1) / 4)) - 1)
        scty = SCORE_DELTA_Y + 15 * INT((i - 1) / 4)
        scly = game.maxy - SCORE_DELTA_Y - 15 * INT((i - 1) / 4)
        COLOR bal(hrac(i).bal).col
        _PRINTSTRING (scx + (LEN(hrac(i).meno) - LEN(RTRIM$(hrac(i).meno))) * 8, scty - 10), RTRIM$(hrac(i).meno) + " -" + STR$(hrac(i).skore)
        LINE (scx + SCORE_NAME_LEN, scly)-(scx + SCORE_NAME_LEN + bal(hrac(i).bal).energia, scly + 7), bal(hrac(i).bal).col, BF
        IF bal(hrac(i).bal).energia <= 0 THEN
            _PRINTSTRING (scx + SCORE_NAME_LEN, scty - 10), "OUT"
        END IF
    NEXT i
    WINDOW (0, 0)-(stav.maxx, stav.maxy)
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CalculatePlayerState (baln AS gula) 'calculate players states
    DIM od AS SINGLE
    '-----------------------energy decreasing-------------------------------------
    IF baln.freezedtime > 0 THEN
        baln.freezedtime = baln.freezedtime - 1
    ELSE
        baln.energia = baln.energia - (stav.energydec * -(stav.baljeto = baln.i)) * game.fpscoef
    END IF
    IF baln.energia <= 0 THEN
        baln.riadena = 0
        pocetriadenych = 0
        FOR i = 1 TO stav.pocethracov
            IF bal(hrac(i).bal).riadena = 1 THEN
                pocetriadenych = pocetriadenych + 1
                priebeznyvitaz = i
            END IF
        NEXT i
        IF pocetriadenych > 1 THEN
            stav.baljeto = stav.balbudeto
            stav.balbudeto = nearestPlayer(bal(stav.baljeto), 0, 0)
            FOR i = 1 TO stav.pocetgulx
                IF bal(i).i <> stav.baljeto AND bal(i).riadena = 1 THEN bal(i).protivnik = stav.baljeto
            NEXT i
        END IF
        IF pocetriadenych = 1 THEN
            stav.vitaz = priebeznyvitaz
            hrac(stav.vitaz).skore = hrac(stav.vitaz).skore + 1
            IF hrac(stav.vitaz).skore >= stav.winscore THEN game.autostart_time = TIMER + DELAY_MATCHEND ELSE game.autostart_time = TIMER + DELAY_ROUNDSTART
            DrawScore
        END IF
    END IF
    '-----------------------dodging time-----------------------------------------
    IF baln.klucka_time = 0 AND baln.klucka_trvanie = 0 AND baln.klucka_pocet = 0 THEN
        baln.klucka_time = INT(RND * strat(baln.strat).klucka_avgtm + strat(baln.strat).klucka_avgtm / 2) / game.fpscoef
        baln.klucka_pocet = strat(baln.strat).klucka_pocet
    END IF
    IF baln.klucka_time > 0 THEN
        baln.klucka_time = baln.klucka_time - 1
    END IF
    IF baln.klucka_time = 0 AND baln.klucka_trvanie > 0 THEN
        baln.klucka_trvanie = baln.klucka_trvanie - 1
    END IF
    IF baln.klucka_time = 0 AND baln.klucka_trvanie = 0 AND baln.klucka_pocet > 0 THEN
        baln.klucka_pocet = baln.klucka_pocet - 1
        baln.klucka_trvanie = INT(RND * strat(baln.strat).klucka_trvanie + strat(baln.strat).klucka_trvanie / 2) / game.fpscoef
        baln.klucka_uhol = RND * strat(baln.strat).klucka_uhol * (2 * strat(baln.strat).klucka_uholodch) + strat(baln.strat).klucka_uhol * (1 - strat(baln.strat).klucka_uholodch) * (3 - INT(RND * 2 + 1) * 2)
    END IF
    '-----------------------choose nearest enemy if tagged-----------------------
    IF stav.baljeto = baln.i THEN
        novyprotivnik = nearestPlayer(baln, 0, -(baln.energia > (stav.energy_player_start * strat(baln.strat).adrenalin_energy)))
        IF novyprotivnik <> 0 THEN baln.protivnik = novyprotivnik
        stav.balbudeto = nearestPlayer(baln, 0, 0)
    END IF
    '-----------------------boosting time----------------------------------------
    IF baln.boost_time > 0 AND baln.boost_trvanie = 0 THEN baln.boost_time = baln.boost_time - 1
    IF baln.boost_trvanie > 0 THEN baln.boost_trvanie = baln.boost_trvanie - 1
 
    '-----------------------reaction drop time-----------------------------------
    IF baln.reactdrop_time > 0 THEN baln.reactdrop_time = baln.reactdrop_time - 1
    IF baln.reactdrop_time <= 0 AND baln.reactdrop_dur > 0 THEN baln.reactdrop_dur = baln.reactdrop_dur - 1
    IF baln.reactdrop_time <= 0 AND baln.reactdrop_dur <= 0 THEN
        IF baln.energia < (stav.energy_player_start * strat(baln.strat).adrenalin_energy) THEN reactkoef = (1 - strat(baln.strat).adrenalin_rate) ELSE reactkoef = 1
        baln.reactdrop_time = INT((RND * strat(baln.strat).reactdrop_per * reactkoef + strat(baln.strat).reactdrop_per * reactkoef / 2) / game.fpscoef)
        baln.reactdrop_dur = INT((RND * strat(baln.strat).reactdrop_dur * reactkoef + strat(baln.strat).reactdrop_dur * reactkoef / 2) / game.fpscoef)
        baln.smer_odchyl = (RND * strat(baln.strat).chybasmeru - strat(baln.strat).chybasmeru / 2) * pi 'apply random radian deviance from intended direction
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION nearestPlayer (baln AS gula, mateonly AS _BYTE, weighted AS _BYTE) 'returns nearest opponent idx
    CONST NEAREST_WEIGHTCOEF = 10.0 'coeficient for energy inclusion into weight
    DIM weight, vzd, vzdakt, vzdakt_winner AS SINGLE
    DIM nearest_winner AS INTEGER
    vzdakt = 0
    nearestPlayer = 0
    vzdakt_winner = 0
    nearest_winner = 0
    FOR i = 1 TO stav.pocetgulx
        IF bal(i).i <> baln.i AND bal(i).riadena = 1 AND (mateonly = 1 IMP i <> stav.baljeto) THEN
            weight = weighted * (stav.energy_player_start - bal(i).energia) * NEAREST_WEIGHTCOEF
            vzd = SQR((baln.x - bal(i).x) ^ 2 + (baln.y - bal(i).y) ^ 2) + weight
            IF nearestPlayer = 0 OR vzd < vzdakt THEN
                nearestPlayer = i
                vzdakt = vzd
            END IF
            IF hrac(bal(i).hrac).skore = stav.winscore - 1 AND (vzd < vzdakt_winner OR nearest_winner = 0) THEN
                nearest_winner = i
                vzdakt_winner = vzd
            END IF
        END IF
    NEXT i
    IF weighted = 1 AND nearest_winner > 0 THEN nearestPlayer = nearest_winner
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB GenerateAIControl (baln AS gula) 'Decide computer player's control keys hits
    DIM dd AS SINGLE, vid AS SINGLE, vd AS SINGLE, eid AS SINGLE, vnd AS SINGLE, ved AS SINGLE, did AS SINGLE, thit AS SINGLE
    DIM rot_klucka AS SINGLE, rot_border AS SINGLE, rot_enemy AS SINGLE, rot_mate AS SINGLE
    DIM siner AS SINGLE, coser AS SINGLE, sineri AS SINGLE, coseri AS SINGLE
    DIM sinevr AS SINGLE, cosevr AS SINGLE, sinmt AS SINGLE, cosnmt AS SINGLE
    DIM okrajrot AS SINGLE, enemy_dist_factor AS SINGLE, smerdookraju AS INTEGER, nearmate AS INTEGER
    DIM d AS vektor, vi AS vektor, ei AS vektor, ve AS vektor, di AS vektor, dm AS vektor
 
    vi = baln.vi 'player's intended speed vector copy
    vid = SQR(vi.x ^ 2 + vi.y ^ 2)
    vi.x = vi.x / vid * stav.vmax
    vi.y = vi.y / vid * stav.vmax
    vd = SQR(baln.v.x ^ 2 + baln.v.y ^ 2)
    ve = bal(baln.protivnik).v 'enemy speed vector copy
    ved = SQR(ve.x ^ 2 + ve.y ^ 2)
 
    d.x = bal(baln.protivnik).x - baln.x 'player to enemy postition vector
    d.y = bal(baln.protivnik).y - baln.y
    dd = SQR(d.x ^ 2 + d.y ^ 2)
    coser = (d.x * baln.v.x + d.y * baln.v.y) / (dd * vd)
    siner = (d.x * baln.v.y - d.y * baln.v.x) / (dd * vd)
    cosevr = (ve.x * baln.v.x + ve.y * baln.v.y) / (ved * vd)
    sinevr = (ve.x * baln.v.y - ve.y * baln.v.x) / (ved * vd)
 
    '!EXPERIMENTAL CODE! - try more exact enemy future position vector, but  does not work so well as used approximation
    'di.x = d.x + ve.x * d.x / ((((d.x / dd) + (ve.x / ved)) * stav.vmax) - ve.x) 'new intended direction to enemy
    'di.y = d.y + ve.y * d.y / ((((d.y / dd) + (ve.y / ved)) * stav.vmax) - ve.y) 'new intended direction to enemy
    '!EXPERIMENTAL CODE! end
 
    di.x = d.x + ve.x * dd / vd * ABS(siner) 'player to enemy approximate future position vector, future enemy position more relevant when enemy closer
    di.y = d.y + ve.y * dd / vd * ABS(siner)
    did = SQR(di.x ^ 2 + di.y ^ 2)
    coseri = (di.x * baln.v.x + di.y * baln.v.y) / (did * vd)
    sineri = (di.x * baln.v.y - di.y * baln.v.x) / (did * vd)
 
    rot_enemy = 0 'rotation away from enemy in rad
    rot_border = 0 'rotation away from border in rad
    rot_mate = 0 'rotation towards nearest mate in rad
    rot_odchyl = 0 'baln.smer_odchyl * -(baln.reactdrop_dur = 1) 'apply direction error if react time
    smerdookraju = 0 'is players direction to border
 
    IF NOT (stav.baljeto = baln.i) THEN 'decide flee action
        enemy_dist_factor = 1 * -(dd <= strat(baln.strat).detekcia_vzdfull) + (1 - (dd - strat(baln.strat).detekcia_vzdfull) / _
          (strat(baln.strat).detekcia_vzdmin - strat(baln.strat).detekcia_vzdfull)) * -(dd > strat(baln.strat).detekcia_vzdfull AND dd <= strat(baln.strat).detekcia_vzdmin)' factor=1 if enemy distance within treshold, then decreasing
 
        IF enemy_dist_factor > 0 THEN 'if enemy in detection distance, rotate away
            rot_enemy = -(coseri > 0) * -(ABS(sineri) <= strat(baln.strat).detekcia_sin) * (-(sineri > 0) + (sineri < 0)) * strat(baln.strat).detekcia_rot * enemy_dist_factor * game.fpscoef
 
            '!EXPERIMENTAL CODE! - try better rotation from enemy
            'strat(baln.strat).detekcia_rot = 10 * pi / FPS 'TEMPORARY MODIFICATION
            'cosevi = (di.x * vi.x + di.y * vi.y) / (did * vid)
            'sinevi = (di.x * vi.y - di.y * vi.x) / (did * vid)
            'cosvvi = (v.x * vi.x + v.y * vi.y) / (vd * vid)
            'sinvvi = (v.x * vi.y - v.y * vi.x) / (vd * vid)
            'IF (coseri > 0) AND (ABS(sineri) <= strat(baln.strat).detekcia_sin) THEN
            '    rot_dir = -(sineri > 0) + (sineri < 0)
            '    IF NOT ((cosevi > 0 AND (ABS(sinevi) <= strat(baln.strat).detekcia_sin)) AND NOT (rot_dir = (-(sinevi > 0) + (sinevi < 0)))) THEN
            '        rot_enemy = rot_dir * strat(baln.strat).detekcia_rot * enemy_dist_factor * game.fpscoef
            '    END IF
            'END IF
            '!EXPERIMENTAL CODE! end
 
        END IF
 
        okrajrot = strat(baln.strat).okraj_rot 'border unit rotation in rad
        IF baln.x < strat(baln.strat).okraj AND vi.x < 0 THEN
            rot_border = (okrajrot * (vi.y >= 0) + okrajrot * -(vi.y < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.x > stav.maxx - strat(baln.strat).okraj AND vi.x > 0 THEN
            rot_border = (okrajrot * -(vi.y >= 0) + okrajrot * (vi.y < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.y < strat(baln.strat).okraj AND vi.y < 0 THEN
            rot_border = (okrajrot * (vi.x >= 0) + okrajrot * (vi.x < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.y > stav.maxy - strat(baln.strat).okraj AND vi.y > 0 THEN
            rot_border = (okrajrot * (vi.x >= 0) + okrajrot * -(vi.x < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
    END IF
 
    rot_klucka = baln.klucka_uhol * -(baln.klucka_time = 0) * -(baln.klucka_trvanie = 1) * -(stav.baljeto <> baln.i) * _
      (dd > strat(baln.strat).mate_distmin OR (coseri < 0 AND sineri >= 0 AND baln.klucka_uhol > 0 AND baln.klucka_uhol < pi) OR (coseri < 0 AND sineri <= 0 AND baln.klucka_uhol < 0 AND baln.klucka_uhol > -pi)) 'apply dodge if dodging time - TEMPORARY DISABLED!!!
 
 
    IF baln.i = bal(stav.baljeto).protivnik THEN 'if ball being chased
        nearmate = nearestPlayer(baln, 1, -(baln.energia > (stav.energy_player_start * strat(baln.strat).adrenalin_energy)))
        IF nearmate > 0 THEN
            dm.x = bal(nearmate).x - baln.x
            dm.y = bal(nearmate).y - baln.y
            dmd = SQR(dm.x ^ 2 + dm.y ^ 2)
            cosnm = (dm.x * baln.v.x + dm.y * baln.v.y) / (dmd * vd)
            sinnm = (dm.x * baln.v.y - dm.y * baln.v.x) / (dmd * vd)
            IF (rot_border = 0) AND (dmd > strat(baln.strat).mate_distmin) AND (((coseri < strat(baln.strat).mate_cosenmax) AND (dd < strat(baln.strat).mate_en_distmin)) OR ((coseri < 0) AND (dd > strat(baln.strat).mate_en_distmin))) THEN
                rot_mate = ((sinnm > 0) * strat(baln.strat).mate_rot * game.fpscoef - (sinnm <= 0) * strat(baln.strat).mate_rot * game.fpscoef) 'rotate towards mate
            END IF
        END IF
    END IF
 
    RotateVector vi, rot_border + rot_klucka + rot_odchyl + rot_enemy + rot_mate 'aplly all calculated rotations to intended velocity
 
    IF stav.baljeto = baln.i THEN 'chasing direction intended
        IF baln.reactdrop_time > 0 THEN 'if time is up for reaction
            baln.boostintended = -(-(coser > 0) AND -(cosevr > 0) AND -(ABS(sinevr) < strat(baln.strat).boost_chasesin) AND baln.boost_time = 0 AND smerdookraju = 0)
            baln.vi.x = stav.vmax * di.x / did
            baln.vi.y = stav.vmax * di.y / did
        END IF
    ELSE 'flee direction intended
        baln.boostintended = -(-(coser < 0) AND baln.boost_time = 0 AND dd < (RND * strat(baln.strat).boost_dist + 2 * PLAY_BALL_R) AND smerdookraju = 0)
        baln.vi.x = vi.x
        baln.vi.y = vi.y
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ReadGamepad (klavn AS tklavesy) 'read state of gamepad
    di = _DEVICEINPUT(klavn.devid)
    IF klavn.typ = 3 THEN
        klavn.gvektor.x = _AXIS(klavn.xaxis)
        klavn.gvektor.y = -_AXIS(klavn.yaxis)
        klavn.isshoota = _BUTTON(klavn.shoota)
        klavn.isshootb = _BUTTON(klavn.shootb)
        klavn.isup = (_AXIS(klavn.dyaxis) = -1)
        klavn.isdown = (_AXIS(klavn.dyaxis) = 1)
        klavn.isleft = (_AXIS(klavn.dxaxis) = -1)
        klavn.isright = (_AXIS(klavn.dxaxis) = 1)
        IF klavn.gvektor.x > 0.5 THEN klavn.isright = -1
        IF klavn.gvektor.x < -0.5 THEN klavn.isleft = -1
        IF klavn.gvektor.y > 0.5 THEN klavn.isup = -1
        IF klavn.gvektor.y < -0.5 THEN klavn.isdown = -1
 
        IF klavn.buttonstate <> (klavn.isshoota + klavn.isshootb * 2 + klavn.isup * 4 + klavn.isdown * 8 + klavn.isright * 16 + klavn.isleft * 32) THEN
            klavn.buttonstatechanged = -1
            klavn.buttonstatetimer = 50
        ELSE
            klavn.buttonstatechanged = 0
        END IF
        klavn.buttonstate = (klavn.isshoota + klavn.isshootb * 2 + klavn.isup * 4 + klavn.isdown * 8 + klavn.isright * 16 + klavn.isleft * 32)
    END IF
    IF klavn.buttonstatetimer > 0 THEN klavn.buttonstatetimer = klavn.buttonstatetimer - 1
    IF klavn.buttonstatetimer = 0 THEN klavn.buttonstatechanged = -1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ResolvePlayerControl (baln AS gula, klavn AS tklavesy) 'perform players control keys actions
    DIM vn AS vektor, gvector AS vektor
 
    IF baln.complayer = 0 THEN 'read human player controls
        IF klavn.typ = 1 THEN 'read keyboard control
            klavn.isright = _KEYDOWN(klavn.right)
            klavn.isleft = _KEYDOWN(klavn.left)
            klavn.isdown = _KEYDOWN(klavn.down)
            klavn.isup = _KEYDOWN(klavn.up)
            klavn.isshoota = _KEYDOWN(klavn.shoota)
            klavn.isshootb = _KEYDOWN(klavn.shootb)
            baln.vi.x = baln.v.x
            baln.vi.y = baln.v.y
        END IF
 
        IF klavn.typ = 3 THEN 'read gamepad control
            baln.vi.x = 0
            baln.vi.y = 0
            ReadGamepad klavn
            baln.vi.x = klavn.gvektor.x * stav.vmax
            baln.vi.y = klavn.gvektor.y * stav.vmax
            IF ABS(klavn.gvektor.x) > GAMESTICK_DEADZONE OR ABS(klavn.gvektor.y) > GAMESTICK_DEADZONE THEN
                klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
                klavn.isleft = (baln.v.x > baln.vi.x)
                klavn.isup = (baln.v.y < baln.vi.y)
                klavn.isdown = (baln.v.y > baln.vi.y)
            END IF
            IF klavn.isshootb AND game.isnetgame = 0 THEN stav.koniec_kola = 2
        END IF
 
        IF klavn.typ = 5 AND game.isnetgame = 1 THEN
            IF game.clienth <> 0 THEN ' reset network controller state on client
                klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
                klavn.isleft = (baln.v.x > baln.vi.x)
                klavn.isup = (baln.v.y < baln.vi.y)
                klavn.isdown = (baln.v.y > baln.vi.y)
                'klavn.isright = 0
                'klavn.isleft = 0
                'klavn.isup = 0
                'klavn.isdown = 0
                klavn.isshoota = 0
            END IF
            baln.vi.x = baln.v.x
            baln.vi.y = baln.v.y
        END IF
 
    ELSE 'get controls of computer player
        IF baln.riadena = 1 THEN GenerateAIControl baln
        klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
        klavn.isleft = (baln.v.x > baln.vi.x)
        klavn.isup = (baln.v.y < baln.vi.y)
        klavn.isdown = (baln.v.y > baln.vi.y)
        klavn.isshoota = -baln.boostintended
    END IF
 
    IF baln.freezedtime <= 0 AND baln.riadena = 1 THEN 'apply acquired controls to player movement
        vn.x = baln.v.x
        vn.y = baln.v.y
 
        game.fpscoef = stav.fps / game.fpsactual
        IF klavn.isright THEN vn.x = vn.x + baln.a.x * game.fpscoef 'accelerate player according to control keys states
        IF klavn.isleft THEN vn.x = vn.x - baln.a.x * game.fpscoef
        IF klavn.isdown THEN vn.y = vn.y - baln.a.y * game.fpscoef
        IF klavn.isup THEN vn.y = vn.y + baln.a.x * game.fpscoef
        IF klavn.isshoota AND baln.boost_time = 0 AND stav.boostallowed = 1 THEN 'set boost state
            baln.boost_trvanie = BOOST_TRVANIE / game.fpscoef
            baln.boost_time = BOOST_TIME / game.fpscoef
        END IF
        vnd = SQR(vn.x ^ 2 + vn.y ^ 2) 'limit actual velocity to max. velocity
        IF vnd > stav.vmax THEN
            vn.x = vn.x * stav.vmax / vnd
            vn.y = vn.y * stav.vmax / vnd
        END IF
 
        IF baln.boost_trvanie > 0 THEN 'add some extra speed if boosted
            vn.x = vn.x + stav.vmax * BOOST_V_KOEF * (baln.boost_trvanie / BOOST_TRVANIE) * game.fpscoef * vn.x / vnd
            vn.y = vn.y + stav.vmax * BOOST_V_KOEF * (baln.boost_trvanie / BOOST_TRVANIE) * game.fpscoef * vn.y / vnd
        END IF
 
        baln.v.x = vn.x 'apply controler modified velocity
        baln.v.y = vn.y
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PerformMovement (baln AS gula) 'Calculate ball movement
    baln.x = baln.x + baln.v.x * game.fpscoef
    baln.y = baln.y + baln.v.y * game.fpscoef
    baln.v.x = baln.v.x * stav.odpor ^ game.fpscoef
    baln.v.y = baln.v.y * stav.odpor ^ game.fpscoef
    IF (baln.x + baln.r > stav.maxx) THEN
        baln.v.x = -baln.v.x
        baln.x = stav.maxx - baln.r
    END IF
    IF (baln.x - baln.r < stav.minx) THEN
        baln.v.x = -baln.v.x
        baln.x = stav.minx + baln.r
    END IF
    IF (baln.y + baln.r > stav.maxy) THEN
        baln.v.y = -baln.v.y
        baln.y = stav.maxy - baln.r
    END IF
    IF (baln.y - baln.r < stav.miny) THEN
        baln.v.y = -baln.v.y
        baln.y = stav.miny + baln.r
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB BounceTest (bala AS gula, balb AS gula) 'Balls bounce test
    IF (bala.x - balb.x) * (bala.x - balb.x) + (bala.y - balb.y) * (bala.y - balb.y) <= (bala.r + balb.r + 0) * (bala.r + balb.r + 0) THEN
        PerformBounce bala, balb
        IF bala.riadena AND balb.riadena AND bala.freezedtime <= 0 AND balb.freezedtime <= 0 AND (stav.baljeto = bala.i OR stav.baljeto = balb.i) THEN 'balb.col = bal(bala.protivnik).col
            newjeto = bala.i * -(stav.baljeto <> bala.i) + balb.i * -(stav.baljeto <> balb.i)
            IF stav.baljeto <= PLAYER_NET_MAX AND newjeto <= PLAYER_NET_MAX AND (game.isnetgame = 0 OR game.hosth <> 0) THEN
                stats(stav.baljeto, newjeto) = stats(stav.baljeto, newjeto) + 1
                game.sync_stats = 1
            END IF
            stav.baljeto = newjeto
            bala.freezedtime = -(stav.baljeto = bala.i) * FREEZE_TIME / game.fpscoef
            balb.freezedtime = -(stav.baljeto = balb.i) * FREEZE_TIME / game.fpscoef
            bala.protivnik = balb.i
            balb.protivnik = bala.i
            FOR i = 1 TO stav.pocetgulx
                IF bal(i).i <> stav.baljeto AND bal(i).riadena = 1 THEN bal(i).protivnik = bal(stav.baljeto).i
            NEXT i
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PerformBounce (bala AS gula, balb AS gula) 'Calculate balls bounce
    DIM dx AS SINGLE, dy AS SINGLE, d AS SINGLE
    DIM l AS SINGLE, l1 AS SINGLE, l2 AS SINGLE
    DIM k AS SINGLE, k1 AS SINGLE, k2 AS SINGLE
    DIM m AS SINGLE, m1 AS SINGLE, m2 AS SINGLE
    DIM n AS SINGLE, n1 AS SINGLE, n2 AS SINGLE
    DIM cosa AS SINGLE, cosb AS SINGLE, p AS SINGLE
    DIM ma AS SINGLE, mb AS SINGLE
 
    IF stav.massallowed = 1 THEN
        ma = bala.m
        mb = balb.m
    ELSE
        ma = 1
        mb = 1
    END IF
 
    dx = balb.x - bala.x
    dy = balb.y - bala.y
    d = SQR(dx ^ 2 + dy ^ 2)
 
    p = bala.r + balb.r - d 'Move overlapping balls away from each other
    IF p >= 0 THEN
        bala.x = bala.x - dx * p / d / 2 * 2
        bala.y = bala.y - dy * p / d / 2 * 2
        balb.x = balb.x + dx * p / d / 2 * 2
        balb.y = balb.y + dy * p / d / 2 * 2
 
        dx = balb.x - bala.x
        dy = balb.y - bala.y
        d = SQR(dx ^ 2 + dy ^ 2)
    END IF
 
    cosa = dy / d
    cosb = -cosa
 
    l = (dx * bala.v.x * ma + dy * bala.v.y * ma) / d
    l2 = l * cosa
    k = (dy * bala.v.x * ma - dx * bala.v.y * ma) / d
    k1 = k * cosa
    l1 = bala.v.x * ma - k1
    k2 = bala.v.y * ma - l2
 
    n = (-dx * balb.v.x * mb - dy * balb.v.y * mb) / d
    n2 = n * cosb
    m = (-dy * balb.v.x * mb + dx * balb.v.y * mb) / d
    m1 = m * cosb
    n1 = balb.v.x * mb - m1
    m2 = balb.v.y * mb - n2
 
    bala.v.x = (k1 + n1) / ma
    bala.v.y = (k2 + n2) / ma
    balb.v.x = (m1 + l1) / mb
    balb.v.y = (m2 + l2) / mb
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION MATHROUND (n)
    MATHROUND = FIX(n + 0.5 * SGN(n))
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB RotateVector (vn AS vektor, b AS SINGLE)
    DIM vt AS vektor
    sinb = SIN(b): cosb = COS(b)
    vt.x = vn.x * cosb - vn.y * sinb
    vt.y = vn.y * cosb + vn.x * sinb
    vn = vt
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CalculateFps 'calculate actual fps coeficient for correct timig
    IF game.tend = game.tstart THEN
        game.fpsactual = stav.fps
    ELSE
        game.fpsactual = ((1 / (game.tend - game.tstart)) * 1 + game.fpsactual * 99) / 100
    END IF
    game.tstart = game.tend
    game.fpscoef = stav.fps / game.fpsactual
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DisplayMessages
    IF game.msgcount > 0 THEN 'refresh messages validity
        FOR i = 1 TO game.msgcount
            IF ((TIMER(.001) - msg(i).time_start) > msg(i).time_dur) AND msg(i).time_dur > 0 THEN DeleteMessage (i)
        NEXT i
    END IF
    LOCATE 3, 1
    IF game.msgcount > 0 THEN 'print messages
        FOR i = 1 TO game.msgcount
            COLOR msg(i).col
            PRINT RTRIM$(msg(i).text)
        NEXT i
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB AddMessage (mtext AS STRING, mcol AS INTEGER, mdur AS SINGLE, mdist AS INTEGER)
    IF LEFT$(mtext, 1) = "/" THEN
        TextCommand mtext
    ELSE
        IF mdur <> 0 THEN
            IF game.msgcount >= MSG_COUNT_MAX THEN DeleteMessage (1) 'delete last message if full
            game.msgcount = game.msgcount + 1
            msg(game.msgcount).clientid = game.clientid
            msg(game.msgcount).text = mtext
            msg(game.msgcount).col = mcol
            msg(game.msgcount).time_dur = mdur
            msg(game.msgcount).time_start = TIMER(.001)
            msg(game.msgcount).syncstr = "SNM"
            msg(game.msgcount).synctime = 0
            msg(game.msgcount).distribute = mdist
            IF mdist = 1 THEN game.newmsg = 1
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DeleteMessage (mid AS INTEGER)
    IF mid < game.msgcount AND mid > 0 THEN
        FOR i = mid TO game.msgcount - 1
            msg(i) = msg(i + 1)
        NEXT i
    END IF
    game.msgcount = game.msgcount - 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB TextCommand (ctext AS STRING)
    SELECT CASE LEFT$(RTRIM$(ctext), 2)
        CASE "/q" 'end network game
            IF game.hosth <> 0 AND stav.gameplay = 1 THEN
                stav.koniec_kola = 2
                AddMessage "The match has been ended by the host", MSG_COL, MSG_DUR_STD, 1
            END IF
            IF game.clienth <> 0 AND stav.gameplay = 1 THEN
                stav.koniec_kola = 2
                ResetNetGame
            END IF
        CASE "/d" 'disconnet client clidx
            clidx = VAL(MID$(RTRIM$(ctext), 3, LEN(RTRIM$(ctext)) - 2))
            IF game.hosth <> 0 AND clidx > 1 AND clidx <= PLAYER_NET_MAX THEN
                IF client(clidx).conn <> 0 THEN
                    CloseClientConn clidx
                    AddMessage "Player " + RTRIM$(hrac(clidx).meno) + " was disconnected by host", MSG_COL, MSG_DUR_STD, 1
                END IF
            END IF
    END SELECT
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DebugScreen (K AS INTEGER) 'print debyg information on screen in runtime
    COLOR 7
    LOCATE INT((stav.pocethracov - 0.5) / 4) + 2, 1
    PRINT "FPS:   "; game.fpsactual
 
    IF K = 101 THEN stav.energydec = -(stav.energydec = 0) * ENERGY_DEC
    IF K = 113 THEN
        bal(hrac(2).bal).strat = bal(hrac(2).bal).strat + 1
        IF bal(hrac(2).bal).strat > UBOUND(strat) THEN
            bal(hrac(2).bal).strat = 1
        END IF
    END IF
    COLOR 13
    PRINT "hrac(n)..isleft   "; klav(hrac(1).klavesy).isleft; klav(hrac(2).klavesy).isleft; klav(hrac(3).klavesy).isleft; klav(hrac(4).klavesy).isleft
    PRINT "hrac(n)..isright  "; klav(hrac(1).klavesy).isright; klav(hrac(2).klavesy).isright; klav(hrac(3).klavesy).isright; klav(hrac(4).klavesy).isright
    PRINT "hrac(n)..isdown   "; klav(hrac(1).klavesy).isdown; klav(hrac(2).klavesy).isdown; klav(hrac(3).klavesy).isdown; klav(hrac(4).klavesy).isdown
    PRINT "hrac(n)..isup     "; klav(hrac(1).klavesy).isup; klav(hrac(2).klavesy).isup; klav(hrac(3).klavesy).isup; klav(hrac(4).klavesy).isup
    PRINT "bal(2).vi        "; bal(hrac(2).bal).vi.x; bal(hrac(2).bal).vi.y
    PRINT "bal(3).vi        "; bal(hrac(3).bal).vi.x; bal(hrac(3).bal).vi.y
    PRINT "bal(4).vi        "; bal(hrac(4).bal).vi.x; bal(hrac(4).bal).vi.y
    PRINT "bal(2).strat     "; bal(2).strat
    PRINT "bal(2).klucka_time    "; bal(hrac(2).bal).klucka_time
    PRINT "bal(2).klucka_pocet   "; bal(hrac(2).bal).klucka_pocet
    PRINT "bal(2).klucka_trvanie "; bal(hrac(2).bal).klucka_trvanie
    PRINT "bal(2).klucka_uhol    "; bal(hrac(2).bal).klucka_uhol
    PRINT "bal(n).protivnik      "; bal(1).protivnik; bal(2).protivnik; bal(3).protivnik
    PRINT "bal(n).complayer      "; bal(1).protivnik; bal(2).protivnik; bal(3).protivnik
    PRINT "stav.baljeto          "; stav.baljeto
    PRINT "stav.koniec_kola      "; stav.koniec_kola
    PRINT "nearestPlayer(1)      "; nearestPlayer(bal(1), 0, 1)
    PRINT "bal(n).reactdrop_time _dur "; bal(2).reactdrop_time; bal(2).reactdrop_dur
    PRINT "bal(1).v              "; bal(1).v.x; bal(1).v.y
    PRINT "bal(1).a              "; bal(1).a.x; bal(1).a.y
    PRINT "bal(2).boostintended  "; bal(2).boostintended
    PRINT "bal(2).boost_time     "; bal(1).boost_time
    PRINT "bal(2).boost_trvanie  "; bal(1).boost_trvanie
    PRINT "bal(n).hrac           "; bal(1).hrac; bal(2).hrac; bal(3).hrac; bal(4).hrac
    PRINT "bal(1).syncstr        "; bal(1).syncstr
    PRINT "game.autostart_time   "; game.autostart_time
    PRINT "stav.autostart_set    "; stav.autostart_set
    PRINT "TIMER                 "; TIMER
    PRINT "client(n).conn"; client(1).conn; client(2).conn; client(3).conn; client(4).conn
    PRINT "hrac(n).klavesy"; hrac(1).klavesy; hrac(2).klavesy; hrac(3).klavesy; hrac(4).klavesy; hrac(10).klavesy
    PRINT "klav(hrac(n)klavesy).typ"; klav(hrac(1).klavesy).typ; klav(hrac(2).klavesy).typ; klav(hrac(3).klavesy).typ; klav(hrac(4).klavesy).typ; klav(hrac(10).klavesy).typ
    PRINT "game.sync_stats         "; game.sync_stats
 
 
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
 
 

Edit:

28.5.2019 update: fixed error while using older gamepads with less than 8 axis

25.1.2020 version 2.2

dajan · « **Reply #1 on:** April 30, 2019, 02:16:07 pm »

If you want to help me to test, there is currently a game hosted on dajan.no-ip.biz

dajan · « **Reply #2 on:** January 25, 2020, 04:10:25 pm »

I have done some improvements to this simple chasing game in the version 2.2 of it:

- graphics polished slightly
- added energy indicator on player
- increased the player boost speed to 5 times of the normal speed (much more fun)
- AI chooses a victim to chase more carefuly now. Unless being in low energy/panic mode, it chooses to eliminate the player closest to the victory. Therefore, it is really hard to win the match to zero. Analog gamepad is strongly recommended for the best control experience.

Code: QB64: [Select]

'--------constants----------------------------------------------------------------------------------------------------------------------------------
CONST MENU_BUILDSTR = "2.2.20.01.01"
CONST RES_X = 1280 'screen horizontal resolution, set to -1 to match the dsektop
CONST RES_Y = 720 'screen vertical resolution, set to -1 to match the dsektop
CONST FPS = 100 'set target frames per seconds to 100 for proper physicss speed
CONST DEBUGMODE = 0 'initial state of debug mode
CONST FULLSCREENMODE = 0 'set 1 for fullscreen on startup, other value to window mode
CONST RES_X_TARG = 1920 'world target horizontal resolution
CONST RES_Y_TARG = 1080 'world target vertical resolution
CONST MAX_COL = 247 'max. color number to use of 255
CONST PLAYER_COUNT_INI = 3 'Initial players count
CONST POCET_GUL_INI = 20 'Initial non player balls count
CONST PLAYER_COUNT_MAX = 32 'Maximum players count
CONST PLAYER_NET_MAX = 8 'Max. number of network players
CONST PLAYER_NET_MIN = 2 'First network control enabled player
CONST POCET_GUL_MAX = 32 'Maximum balls count
CONST STRAT_COUNT_MAX = 20 'Maximum players strategies
CONST PLAY_BALL_R = 20 'Players ball size
CONST V_MAX = 300 / FPS 'Max player ball velocity
CONST ACC_X = 10 / FPS 'Balls acceleration X
CONST ACC_Y = 10 / FPS 'Balls accelereation Y
CONST FRICTION = 0.998 'Space fricition coeffifcient
CONST ENERGY_ALL_MIN = 500 'min.starting energy of all players together
CONST ENERGY_PLAYER_MIN = 50 'min. player's starting energy
CONST ENERGY_PLAYER_MAX = 150 'max. player's starting energy
CONST ENERGY_DEC = 5 / FPS 'ball energy decrement
CONST REACTIME_AVG_NORMAL = 0 * FPS 'Average AI reaction time in sec*FPS
CONST CHYBASMERU_NORMAL = 0.0 'Improper reaction rate
CONST PRIESTOR_MIN = PLAY_BALL_R + 100
CONST DELAY_ROUNDSTART = 8 'delay in seconds after round end to accept resume
CONST DELAY_MATCHEND = 20 'delay in seconds after match end to accept resume
CONST FREEZE_TIME = 1.0 * FPS 'player freeze time after getting tag in seconds
CONST SCORE_POS_X = 50 'Score horizontal draw position
CONST SCORE_DELTA_Y = 13 'Score draw - vertictal offset from screen top
CONST SCORE_DELTA_X = 350 'Score draw - players score horizontal offset
CONST SCORE_NAME_LEN = 120 'Score draw - horizontal space for player name
CONST BOOST_V_KOEF = 3.0 'boost factor of extra maximum speed
CONST BOOST_TRVANIE = 1 * FPS 'boost duration
CONST BOOST_TIME = 1 * FPS 'min time between boosts in sec*fps
CONST MENUCURSOR_COLOR = 15 'Menu cursor color
CONST MENUITEM_COLOR = 7 'Menu cursor color
CONST MENU_PLAYERS_COUNT = 8 'Number of players in menu
CONST FONT_W = 8 'Font width in pixels
CONST FONT_H = 16 'Font height in pixels
CONST GAMESTICK_DEADZONE = 0.05 'gamepad stick axis maximum value considered as zero
CONST CPU_CONTROLID = PLAYER_NET_MAX + 1 'CPU controller id
CONST HOSTIP_DEFAULT = "" '"localhost" '
CONST HOSTPORT_DEFAULT = 7432
CONST GETITEM_SYNC = "SNC" 'network trasfer item code
CONST GETITEM_STAV = "SNS" 'network trasfer item code
CONST GETITEM_BAL = "SNB" 'network trasfer item code
CONST GETITEM_PBAL = "SNP" 'network trasfer item code
CONST GETITEM_KLAV = "SNK" 'network trasfer item code
CONST GETITEM_HRAC = "SNH" 'network trasfer item code
CONST GETITEM_MESG = "SNM" 'network trasfer item code
CONST GETITEM_STAT = "SNT" 'network trasfer item code
CONST NET_TIMEOUT_LIMIT = 10 'timeout to disconnect in seconds
CONST NET_TIMEOUT_SYNC = 0.01 'timeout to get synced in seconds
CONST MSG_COUNT_MAX = 20 'max. messages displayed
CONST MSG_LEN_MAX = 80 'max. length of message
CONST MSG_DUR_STD = 20 'message standard duration in seconds
CONST MSG_COL = 7 'message standard color
CONST UPDATE_PER_BAL = 0.1 'all balls network update period in seconds
CONST UPDATE_PER_PLBAL = 0.04 'player balls network update period in seconds
CONST UPDATE_PER_HRAC = 0.1 'players network update period in seconds
CONST UPDATE_PER_STAV = 0.04 'world state network update period in seconds
CONST AUTOSTART_SEC_MAX = 180 'max game autostart time
 
'--------type definitions----------------------------------------------------------------------------------------------------------------------------
TYPE vektor 'general 2D vector type
    x AS SINGLE
    y AS SINGLE
END TYPE
 
TYPE tstav 'game world state type  (cca 100B)
    minx AS INTEGER 'world - minimum x position
    maxx AS INTEGER 'world - maximum x position
    miny AS INTEGER 'world - minimum y position
    maxy AS INTEGER 'world - maximum y position
    vmax AS SINGLE 'maximum unboosted ball velocity
    maxcol AS INTEGER 'world - maximum of colors
    pocetgulzvoleny AS INTEGER 'number of balls desired
    pocetgul AS INTEGER 'number of balls actual
    pocetgulx AS INTEGER 'number of balls in bottom row
    pocetguly AS INTEGER 'number of balls in left column
    pocethracov AS INTEGER 'number of players
    energy_allmin AS SINGLE 'all players starting energy sum
    energy_playermin AS SINGLE 'minimum starting energy of player
    energy_playermax AS SINGLE 'maximum starting energy of player
    energy_player_start AS SINGLE 'player's starting energy
    energydec AS SINGLE 'energy decrease unit
    baljeto AS INTEGER 'actual tagged ball idx
    balbudeto AS INTEGER 'successor tagged ball idx
    vitaz AS INTEGER 'winner player idx
    koniec_kola AS _BYTE 'end of round flag (0=no end, 1=end of round, 2=end fo round and match)
    odpor AS SINGLE 'space friction
    massallowed AS _BYTE 'calculate balls with different masses
    pauza AS _BYTE 'game pause flag (0 or 1)
    gameplay AS _BYTE 'state of session: 0=menu, 1=gameplay
    fps AS SINGLE 'fps target set
    zacinabal AS INTEGER 'initially tagged ball idx
    boostallowed AS _BYTE 'player boost mode allowed (0 or 1)
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
    AIallowed AS _BYTE 'AI players in netgame allowed=1
    autostart_set AS INTEGER 'game autostart setting in seconds; 0=off
    autostart_timeleft AS SINGLE 'actual time to autostart the game in seconds
    winscore AS _BYTE 'score to win a match
END TYPE
 
TYPE gula 'ball  type  (cca 90B)
    i AS INTEGER 'balls id
    x AS SINGLE 'balls y position
    y AS SINGLE 'balls y position
    r AS SINGLE 'radius
    m AS SINGLE 'mass
    v AS vektor 'velocity
    vi AS vektor 'desired velocity
    a AS vektor 'acceleration
    col AS INTEGER 'balls color
    riadena AS INTEGER 'is actually player controllable (0 or 1)
    complayer AS INTEGER 'is computer player's ball (0 or 1)
    protivnik AS INTEGER 'actual ball's enemy ball id
    strat AS INTEGER 'balls behaviour strategy id
    energia AS SINGLE 'players energy
    freezedtime AS INTEGER 'actual time to unfreeze players control
    smer_odchyl AS SINGLE 'actual deviance from intended direction in radians
    klucka_time AS INTEGER 'actual time to start doging
    klucka_uhol AS SINGLE 'actual dodge angle
    klucka_trvanie AS INTEGER 'actual dodge duration
    klucka_pocet AS INTEGER 'actual dodge count
    boost_time AS INTEGER 'actual time to boost allowed again
    boost_trvanie AS INTEGER 'actual time to end boost
    reactdrop_time AS INTEGER 'actual time to start reaction drop in frames
    reactdrop_dur AS INTEGER 'actual time to stop reaction drop in frames
    boostintended AS INTEGER 'intention to boost or not (1, 0)
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
    hrac AS INTEGER 'ball player's id
END TYPE
 
TYPE tstrat 'balls behaviour strategy type
    okraj AS INTEGER 'distance from screen border to turn
    okraj_rot AS SINGLE 'distance from screen border to turn
    chybasmeru AS SINGLE 'percentage of deviance from desired direction -- not used currently
    react_lag AS INTEGER 'average reaction time in frames
    klucka_avgtm AS SINGLE 'average time between dodging in fps +-50%
    klucka_uhol AS SINGLE 'average dodge angle
    klucka_trvanie AS INTEGER 'average dodge time +-50%
    klucka_pocet AS INTEGER 'average dodge count
    klucka_uholodch AS SINGLE 'dodge angle deviation percentage
    detekcia_sin AS SINGLE 'sinus of frontal enemy detection angle
    detekcia_vzdfull AS SINGLE 'distance of frontal enemy full detection
    detekcia_vzdmin AS SINGLE 'distance of frontal enemy minimum detection
    detekcia_rot AS SINGLE 'amount of rotation on enemy detection in radians
    reactdrop_per AS INTEGER 'average reaction drop period in frames
    reactdrop_dur AS INTEGER 'average reaction drop duration in frames
    boost_rate AS SINGLE 'inclination to use boost in percent
    boost_dist AS SINGLE 'enemy distance activating boost deciding
    boost_chasesin AS SINGLE 'max. sinus of enemy to player velocity angle to apply chasing boost
    mate_cosenmax AS SINGLE 'max. cosinus of (player-enemy vector to player velocity) to rotate to mate
    mate_rot AS SINGLE 'amount of unit rotation towards nearest mate in rad per frame
    mate_en_distmin AS SINGLE 'min. distance from enemy to apply rotation towards mate
    mate_distmin AS SINGLE 'min. distance from mate to apply rotation towards mate
    adrenalin_rate AS SINGLE 'percentage of reaction time improved in adrenalin mode
    adrenalin_energy AS SINGLE 'energy level precentage starting adrenalin mode
END TYPE
 
TYPE thrac 'player type
    i AS INTEGER 'player index number
    meno AS STRING * 10 'players name
    skore AS _BYTE 'players score
    klavesy AS _BYTE 'players control keys set index
    bal AS INTEGER 'player driven ball idx
    col AS INTEGER 'player's choosed color
    clientid AS _BYTE 'index of hosted client, 0 if local player
    isready AS _BYTE '1=player is ready for game start
    syncstr AS STRING * 3
    synctime AS DOUBLE
END TYPE
 
TYPE tklavesy 'players controller type
    id AS INTEGER 'controllers id
    devid AS INTEGER 'controllers device id  (0=unused)
    typ AS _BYTE 'type of controller (0=unused, 1=keyboard, 2=mouse reserved, 3=gamepad, 4=AI, 5=network, 6=empty)
    nazov AS STRING * 25 'game controllers name
    up AS LONG 'key code for up
    down AS LONG 'keyp code for down
    right AS LONG 'key code for right
    left AS LONG 'key code for left
    shoota AS LONG 'keyborad key code or gamepad button id
    shootb AS LONG 'keyborad key code or gamepad button id
    xaxis AS _BYTE 'gamepad analog x-asis id
    yaxis AS _BYTE 'gamepad analog y-asis id
    dxaxis AS _BYTE 'gamepad digital x-asis id
    dyaxis AS _BYTE 'gamepad digital y-asis id
    isup AS _BYTE 'controllers actual state for up
    isdown AS _BYTE 'controllers actual state for down
    isright AS _BYTE 'controllers actual state for right
    isleft AS _BYTE 'controllers actual state for left
    isshoota AS _BYTE 'controllers actual state for fire 1
    isshootb AS _BYTE 'controllers actual state for fire 2
    gvektor AS vektor 'controllers actual x and y axis state
    buttonstate AS LONG 'all gamepads buttons cumulative state value
    buttonstatechanged AS _BYTE '0 if no button state change, 1 if any button state changed
    buttonstatetimer AS INTEGER
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
END TYPE
 
TYPE tmenu
    title AS STRING * 10 'menu title use for nothing
    items_count AS INTEGER 'menu items count
    item_active AS INTEGER 'active item index
    item_height AS INTEGER 'menu item height in pixels
    cursor_col AS INTEGER 'menu cursor color
    cursor_xpos AS INTEGER 'x position of cursors left side
    cursor_out AS INTEGER 'cursor bar outset
    ypos AS INTEGER 'y position of cursor
    cursor_width AS INTEGER 'cursor width in pixels
    menucode AS INTEGER 'stores code of selected action upon active menuitem
    playercode AS INTEGER 'stores  player id of active menuitem
END TYPE
 
TYPE tmessage
    clientid AS INTEGER 'client origin of message
    text AS STRING * MSG_LEN_MAX 'message text
    time_start AS DOUBLE 'message time
    time_dur AS SINGLE 'message duration
    col AS INTEGER 'message color
    distribute AS INTEGER 'message dsitribution status 1=distribute
    syncstr AS STRING * 3 'net synchronisation string code
    synctime AS DOUBLE 'net synchronisation time stamp
END TYPE
 
TYPE tgamesession 'my game session properties
    maxx AS INTEGER 'my screen x resolution
    maxy AS INTEGER 'my screen y resolution
    isnetgame AS _BYTE 'network game flag; 1=network, 0=local
    hosth AS INTEGER 'my host handle
    clienth AS INTEGER 'my client handle
    clientid AS INTEGER 'my client's id registered at host
    host_ip AS STRING * 100 'host's ip to connect as a client
    host_port AS LONG 'host's port to connect as a client
    get_item AS STRING * 3 'actual item to get from host
    get_time AS DOUBLE 'time of last succesfull reading from host
    get_isdesync AS INTEGER 'net transfer is desynced=1
    fpsactual AS SINGLE 'fps achieved
    fpscoef AS SINGLE 'fps actual/target
    tstart AS DOUBLE 'timer start time
    tend AS DOUBLE 'timer end time
    pocetgamepadov AS INTEGER 'number of gamepads detected
    pocetkontrolerov AS INTEGER 'number of game controllers
    start AS INTEGER 'start game flag (0 or 1)
    exituj AS INTEGER 'exit game flag (0 or 1)
    printdebug AS INTEGER 'debug mode flag (0 or 1)
    msgcount AS INTEGER 'total number of actual messages
    msgwrite AS INTEGER 'message write mode=1
    newmsg AS INTEGER 'is new messages to distribute flag
    msgtext AS STRING * MSG_LEN_MAX 'message text being actually written
    autostart_time AS SINGLE 'local host time of game autostart
    timer_pballs AS SINGLE 'local time of last player balls update from host
    sync_stats AS _BYTE 'send statistics to clients flag
    show_stats AS _BYTE 'display match statistics
END TYPE
 
TYPE tclient 'hosted client type
    conn AS INTEGER 'connection handle of hosted client
    ip AS STRING * 100 'ip of hosted client
    get_item AS STRING * 3 'next item to get from client
    get_time AS DOUBLE 'time of last succesfull reading from client
    get_isdesync AS INTEGER 'net desynchronisation flag host cannot get from client
    isdesynced AS _BYTE 'client side is desynced - cannot get from host
    spectating AS _BYTE 'client player control enabled
END TYPE
 
TYPE tsyncvar
    syncstr AS STRING * 3 'sync string code
    synctime AS DOUBLE 'net synchronisation time stamp
    itemstr AS STRING * 3 'code of the next item to get
    isdesync AS _BYTE '1=the other side is desynced
    clientid AS INTEGER 'client id
END TYPE
 
'-----global variables-------------------------------------------------------------------------------------------------------------------------------
REDIM SHARED bal(1 TO POCET_GUL_MAX + PLAYER_COUNT_MAX) AS gula 'balls
DIM SHARED klav(1 TO PLAYER_COUNT_MAX) AS tklavesy 'keyboard control sets
DIM SHARED stav AS tstav 'game world state
DIM SHARED strat(1 TO STRAT_COUNT_MAX) AS tstrat 'computer players strategies
DIM SHARED hrac(1 TO PLAYER_COUNT_MAX) AS thrac 'players balls
DIM SHARED sync AS tsyncvar 'net sync variable
DIM SHARED stats(1 TO PLAYER_NET_MAX + 1, 1 TO PLAYER_NET_MAX) AS INTEGER 'players game statistics
 
REDIM SHARED ibal(1 TO POCET_GUL_MAX) AS gula 'nonplayer balls transfer array
REDIM SHARED ipbal(1 TO PLAYER_NET_MAX) AS gula 'players balls transfer array
DIM SHARED iklav(1 TO PLAYER_COUNT_MAX) AS tklavesy 'keyboard control sets transfer array
DIM SHARED istav AS tstav 'game world state transfer array
DIM SHARED ihrac(1 TO PLAYER_NET_MAX) AS thrac 'players balls transfer array
DIM SHARED isync AS tsyncvar 'net sync variable transfer array
DIM SHARED istats(1 TO PLAYER_NET_MAX + 1, 1 TO PLAYER_NET_MAX) AS INTEGER 'players game statistics transfer
 
DIM SHARED client(1 TO 8) AS tclient
DIM SHARED menu AS tmenu
DIM SHARED game AS tgamesession
DIM SHARED msg(1 TO MSG_COUNT_MAX) AS tmessage
DIM SHARED pi AS SINGLE
 
'----main program------------------------------------------------------------------------------------------------------------------------------------
SetGlobalParameters
SetUpControllers
IF game.pocetgamepadov > 0 THEN hrac(1).klavesy = game.pocetkontrolerov 'set gamepad as default controller for player1
 
SCREEN _NEWIMAGE(game.maxx, game.maxy, 256), , ,
_SCREENMOVE _MIDDLE
IF FULLSCREENMODE = 1 THEN _FULLSCREEN
AddMessage "Welcome in the Tag game.", MSG_COL, 5, 0
AddMessage "To display/hide match statistics press 'c' while gameplay.", MSG_COL, 8, 0
AddMessage "Default TCP port for the network game is 7432. ", MSG_COL, 11, 0
 
DO
    '--------Main menu begin---------------------------------------------------------------------------------------------------------------------------------------------------------------------
    REDIM SHARED ibal(1 TO POCET_GUL_MAX) AS gula 'nonplayer balls transfer array
    REDIM SHARED ipbal(1 TO PLAYER_NET_MAX) AS gula 'players balls transfer array
    DIM playerst(1 TO 8) AS STRING * 30
    DIM hoststat AS STRING * 50
    DIM joinstat AS STRING * 50
    DIM autostart AS STRING
    DIM AIplayers AS STRING
    DIM newenergy AS STRING * 3
 
    stav.gameplay = 0
    vys = FONT_H
    sir = FONT_W
    menu.items_count = 27
 
    DO
        WINDOW (0, 0)-(game.maxx, game.maxy)
        IF game.hosth <> 0 THEN hoststat = "host started" ELSE hoststat = ""
        IF game.clienth <> 0 AND game.clientid = 0 THEN joinstat = "joining game...   "
        IF game.clienth <> 0 AND game.clientid <> 0 THEN joinstat = "connected to         " + LEFT$(game.host_ip, 30)
        IF game.clienth = 0 AND game.clientid = 0 THEN joinstat = ""
        ReadyPlayersCount = 0
        FOR i = 1 TO 8
            playerst(i) = ""
            IF game.isnetgame = 1 THEN
                IF hrac(i).clientid > 0 THEN playerst(i) = "  state: connected" ELSE playerst(i) = "  state: "
                IF klav(hrac(i).klavesy).typ <= 3 THEN playerst(i) = "  state: local player"
                IF hrac(i).isready = 1 AND hrac(i).clientid > 0 THEN playerst(i) = RTRIM$(playerst(i)) + " / ready!": ReadyPlayersCount = ReadyPlayersCount + 1
            END IF
        NEXT i
 
        IF stav.autostart_set = 0 THEN
            autostart = "Off"
        ELSE
            HumanPlayers = HumanPlayersCount
            IF game.autostart_time - stav.autostart_set > TIMER THEN game.autostart_time = game.autostart_time - 86399
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) THEN stav.autostart_timeleft = game.autostart_time - TIMER
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND game.autostart_time <= TIMER THEN
                IF stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayers >= 2) THEN
                    game.start = 1
                ELSE
                    game.autostart_time = TIMER + stav.autostart_set
                END IF
            END IF
            IF game.isnetgame = 1 AND game.hosth <> 0 AND ReadyPlayersCount = HumanPlayers AND ((stav.AIallowed = 1 AND HumanPlayers >= 1) OR (stav.AIallowed = 0 AND HumanPlayers >= 2)) THEN game.start = 1
            autostart = LTRIM$(STR$(stav.autostart_set)) + " sec               " + LTRIM$(STR$(INT(stav.autostart_timeleft))) + " left"
        END IF
 
        IF stav.AIallowed = 1 THEN AIplayers = "Yes" ELSE AIplayers = "No"
 
        CLS 1
        DisplayMessages
        PrintMenuItem -2, menu, 0, 0, 0, "Tag! v.2", 0, 0, -3, 13
        PrintMenuItem -1, menu, 0, 0, 0, "created in QuickBasic64 by Daniel Janec (2019) build " + MENU_BUILDSTR, 0, 0, -2, 20
        PrintMenuItem 1, menu, 6, 0, 0, "Play <Space>", 0, 0, 0, MENUITEM_COLOR
        PrintMenuItem 2, menu, 1, 0, 0, "Refresh gamepads detected: " + STR$(game.pocetgamepadov), 0, 0, 0, MENUITEM_COLOR
        PrintMenuItem 3, menu, 2, 1, 1, hrac(1).meno + " controls: " + klav(hrac(1).klavesy).nazov + RTRIM$(playerst(1)), 150, -10 * sir, 1, hrac(1).col
        PrintMenuItem 4, menu, 3, 1, 1, "              color:" + STR$(hrac(1).col), 150, -10 * sir, 1, hrac(1).col
        PrintMenuItem 5, menu, 2, 2, 1, hrac(2).meno + " controls: " + klav(hrac(2).klavesy).nazov + RTRIM$(playerst(2)), 150, -10 * sir, 1, hrac(2).col
        PrintMenuItem 6, menu, 3, 2, 1, "              color:" + STR$(hrac(2).col), 150, -10 * sir, 1, hrac(2).col
        PrintMenuItem 7, menu, 2, 3, 1, hrac(3).meno + " controls: " + klav(hrac(3).klavesy).nazov + RTRIM$(playerst(3)), 150, -10 * sir, 1, hrac(3).col
        PrintMenuItem 8, menu, 3, 3, 1, "              color:" + STR$(hrac(3).col), 150, -10 * sir, 1, hrac(3).col
        PrintMenuItem 9, menu, 2, 4, 1, hrac(4).meno + " controls: " + klav(hrac(4).klavesy).nazov + RTRIM$(playerst(4)), 150, -10 * sir, 1, hrac(4).col
        PrintMenuItem 10, menu, 3, 4, 1, "              color:" + STR$(hrac(4).col), 150, -10 * sir, 1, hrac(4).col
        PrintMenuItem 11, menu, 2, 5, 1, hrac(5).meno + " controls: " + klav(hrac(5).klavesy).nazov + RTRIM$(playerst(5)), 150, -10 * sir, 1, hrac(5).col
        PrintMenuItem 12, menu, 3, 5, 1, "              color:" + STR$(hrac(5).col), 150, -10 * sir, 1, hrac(5).col
        PrintMenuItem 13, menu, 2, 6, 1, hrac(6).meno + " controls: " + klav(hrac(6).klavesy).nazov + RTRIM$(playerst(6)), 150, -10 * sir, 1, hrac(6).col
        PrintMenuItem 14, menu, 3, 6, 1, "              color:" + STR$(hrac(6).col), 150, -10 * sir, 1, hrac(6).col
        PrintMenuItem 15, menu, 2, 7, 1, hrac(7).meno + " controls: " + klav(hrac(7).klavesy).nazov + RTRIM$(playerst(7)), 150, -10 * sir, 1, hrac(7).col
        PrintMenuItem 16, menu, 3, 7, 1, "              color:" + STR$(hrac(7).col), 150, -10 * sir, 1, hrac(7).col
        PrintMenuItem 17, menu, 2, 8, 1, hrac(8).meno + " controls: " + klav(hrac(8).klavesy).nazov + RTRIM$(playerst(8)), 150, -10 * sir, 1, hrac(8).col
        PrintMenuItem 18, menu, 3, 8, 1, "              color:" + STR$(hrac(8).col), 150, -10 * sir, 1, hrac(8).col
        PrintMenuItem 19, menu, 8, 0, 1, "Player starting energy: " + LTRIM$(STR$(stav.energy_player_start)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 20, menu, 4, 0, 1, "     Number of players: " + LTRIM$(STR$(stav.pocethracov)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 21, menu, 12, 0, 1, "   CPU players allowed: " + AIplayers, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 22, menu, 5, 0, 1, "           Balls count: " + LTRIM$(STR$(stav.pocetgulzvoleny)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 23, menu, 13, 0, 1, "   Match winning score: " + LTRIM$(STR$(stav.winscore)), 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 24, menu, 11, 0, 1, "        Game autostart: " + autostart, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 25, menu, 9, 0, 0, "             Host game: " + hoststat, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 26, menu, 10, 0, 0, "             Join game: " + joinstat, 100, -10 * sir, 2, MENUITEM_COLOR
        PrintMenuItem 27, menu, 7, 0, 0, "Exit <Esc>", 0, 0, 2, MENUITEM_COLOR
        PrintMenuCursor menu
 
        k = _KEYHIT 'read menu action
        IF game.msgwrite = 1 AND game.isnetgame = 1 THEN WriteMessage k: k = 0
        IF game.msgwrite = 0 AND game.isnetgame = 1 THEN WriteMessage -1
 
        '---debug code begin---------------------------------------------
        IF k = 98 THEN game.printdebug = -(game.printdebug = 0)
        IF game.printdebug = 1 THEN DebugScreen k 'print debug info on screen
        '---debug code end-----------------------------------------------
 
        FOR i = 1 TO game.pocetkontrolerov
            IF klav(i).typ = 3 THEN
                ReadGamepad klav(i)
                IF klav(i).buttonstatechanged THEN
                    IF klav(i).isshoota THEN k = 13: klav(i).isshoota = 0
                    IF klav(i).isup THEN k = 18432: klav(i).isup = 0
                    IF klav(i).isdown THEN k = 20480: klav(i).isdown = 0
                    IF klav(i).isright THEN k = 19712: klav(i).isright = 0
                    IF klav(i).isleft THEN k = 19200: klav(i).isleft = 0
                END IF
            END IF
        NEXT i
 
        SELECT CASE k 'perform menu choice
            CASE 18432 'up
                IF menu.item_active > 1 THEN menu.item_active = menu.item_active - 1
            CASE 20480 'down
                IF menu.item_active < menu.items_count THEN menu.item_active = menu.item_active + 1
            CASE 19200 'left
                SELECT CASE menu.menucode
                    CASE 2 'players controller
                        i = menu.playercode
                        hrac(i).klavesy = hrac(i).klavesy - 1
                        IF hrac(i).klavesy < PLAYER_NET_MAX + 1 THEN hrac(i).klavesy = PLAYER_NET_MAX + 1
                    CASE 3 'players color
                        i = menu.playercode
                        hrac(i).col = hrac(i).col - 1
                        IF hrac(i).col < 1 THEN hrac(i).col = stav.maxcol
                    CASE 4 'players count
                        IF stav.pocethracov > 2 THEN
                            stav.pocethracov = stav.pocethracov - 1
                        END IF
                    CASE 5 'balls count
                        IF stav.pocetgulzvoleny > 0 THEN
                            stav.pocetgulzvoleny = stav.pocetgulzvoleny - 1
                        END IF
                    CASE 8 'starting energy
                        IF stav.energy_player_start > 10 THEN
                            stav.energy_player_start = stav.energy_player_start - 1
                        END IF
                    CASE 11 'game autostart
                        IF stav.autostart_set > 0 THEN
                            stav.autostart_set = stav.autostart_set - 10
                            game.autostart_time = TIMER + stav.autostart_set
                        END IF
                    CASE 12 'CPU players allowed
                        stav.AIallowed = 0
                    CASE 13 'Winning score
                        IF stav.winscore > 1 THEN stav.winscore = stav.winscore - 1
                END SELECT
            CASE 19712 'right
                SELECT CASE menu.menucode
                    CASE 2 'players controller
                        i = menu.playercode
                        hrac(i).klavesy = hrac(i).klavesy + 1
                        IF hrac(i).klavesy > game.pocetkontrolerov THEN hrac(i).klavesy = game.pocetkontrolerov
                    CASE 3 'players color
                        i = menu.playercode
                        hrac(i).col = hrac(i).col + 1
                        IF hrac(i).col > stav.maxcol THEN hrac(i).col = 1
                    CASE 4 'players count
                        IF stav.pocethracov < PLAYER_COUNT_MAX THEN
                            stav.pocethracov = stav.pocethracov + 1
                        END IF
                    CASE 5 'balls count
                        IF stav.pocetgulzvoleny < POCET_GUL_MAX THEN
                            stav.pocetgulzvoleny = stav.pocetgulzvoleny + 1
                        END IF
                    CASE 8 'starting energy
                        IF stav.energy_player_start < ENERGY_PLAYER_MAX THEN
                            stav.energy_player_start = stav.energy_player_start + 1
                        END IF
                    CASE 11 'game autostart
                        IF stav.autostart_set < AUTOSTART_SEC_MAX THEN
                            stav.autostart_set = stav.autostart_set + 10
                            game.autostart_time = TIMER + stav.autostart_set
                        END IF
                    CASE 12 'CPU players allowed
                        stav.AIallowed = 1
                    CASE 13 'Winning score
                        IF stav.winscore < 99 THEN stav.winscore = stav.winscore + 1
                END SELECT
            CASE 13 'enter
                SELECT CASE menu.menucode
                    CASE 1
                        SetUpControllers
                    CASE 8 'starting energy
                        newenergy = LTRIM$(STR$(stav.energy_player_start))
                        newenergy = InputText$(newenergy, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, MENUITEM_COLOR, 48, "<Type starting energy>", 0, 1)
                        IF LEFT$(newenergy$, 1) <> CHR$(27) AND LEN(RTRIM$(newenergy$)) > 0 THEN
                            energyval = VAL(newenergy)
                            IF energyval < 10 THEN energyval = 10
                            IF energyval > ENERGY_PLAYER_MAX THEN energyval = ENERGY_PLAYER_MAX
                            stav.energy_player_start = energyval
                        END IF
                    CASE 2 'set new name
                        novemeno$ = InputText$(hrac(menu.playercode).meno, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, hrac(menu.playercode).col, 14, "<Type name>", 0, 0)
                        IF novemeno$ <> CHR$(27) AND LEN(novemeno$) > 0 THEN hrac(menu.playercode).meno = novemeno$
                    CASE 9 'host game
                        HostGame
                    CASE 10 'join game
                        IF game.clienth = 0 THEN
                            gethostip$ = InputText$(game.host_ip, menu.cursor_xpos + 2 * sir, menu.ypos + (menu.item_active - 1) * menu.item_height, MENUITEM_COLOR, LEN(game.host_ip), "<Type IP address or host name>", 1, 0)
                            IF gethostip$ <> CHR$(27) THEN game.host_ip = gethostip$
                            IF gethostip$ <> CHR$(27) AND LEN(RTRIM$(game.host_ip)) > 0 THEN JoinGame
                        ELSE
                            ResetNetGame
                        END IF
                    CASE 6 'start game
                        IF game.clientid > 0 THEN hrac(game.clientid).isready = 1 - hrac(game.clientid).isready
                        IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND (stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayersCount >= 2)) THEN game.start = 1
                    CASE 7 'exit game
                        game.exituj = 1
                END SELECT
            CASE 116 'messaage write mode on
                IF game.isnetgame = 1 THEN
                    game.msgwrite = 1
                    k = 0
                END IF
            CASE 32 'start game
                IF game.clientid > 0 THEN hrac(game.clientid).isready = 1 - hrac(game.clientid).isready
                IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND (stav.AIallowed = 1 OR (stav.AIallowed = 0 AND HumanPlayersCount >= 2)) THEN game.start = 1
            CASE 27 'exit game
                game.exituj = 1
        END SELECT
 
        FOR i = 1 TO PLAYER_COUNT_MAX 'set AI controller type for computer players
            IF game.isnetgame = 1 AND game.clienth <> 0 AND game.clientid <> 0 AND klav(hrac(i).klavesy).typ = 4 THEN hrac(i).klavesy = hrac(i).klavesy + 1 'change AI controler on client to keyboard
            IF (game.isnetgame = 0 OR (game.isnetgame = 1 AND game.hosth <> 0)) AND klav(hrac(i).klavesy).typ = 4 THEN 'on host or singleplayer change AI controlled ball
                bal(hrac(i).bal).complayer = 1
            ELSE
                bal(hrac(i).bal).complayer = 0
            END IF
        NEXT i
 
        IF game.isnetgame AND stav.pocethracov > PLAYER_NET_MAX THEN stav.pocethracov = PLAYER_NET_MAX
        IF menu.menucode = 4 AND (k = 19712 OR k = 19200) THEN 'after changing players count
            stav.energy_player_start = INT(stav.energy_allmin / stav.pocethracov) 'calculate  players energy
            IF stav.energy_player_start < stav.energy_playermin THEN stav.energy_player_start = stav.energy_playermin
            IF stav.energy_player_start > stav.energy_playermax THEN stav.energy_player_start = stav.energy_playermax
        END IF
 
        IF game.isnetgame = 1 AND game.clienth <> 0 AND game.clientid > 0 AND stav.gameplay = 1 THEN game.start = 1
        IF game.isnetgame = 1 THEN SyncNetGameData
        _DISPLAY
        _LIMIT stav.fps
 
    LOOP UNTIL game.start = 1 OR game.exituj = 1
    game.start = 0
    IF game.clientid > 0 THEN hrac(game.clientid).isready = 0
    '--------end of main menu---------------------------------------------------------------------------------------------------------------------------------------------------------------------
 
    '----------------------------------new game start-------------------------------------------------------------------------------------------------
    WINDOW (0, 0)-(stav.maxx, stav.maxy)
    IF game.exituj <> 1 THEN 'new game starts here
        '----------------------------------set the world on the new game start-------------------------------
        IF game.hosth <> 0 THEN AddMessage "The match has been started by the host. Whoever scores" + RTRIM$(STR$(stav.winscore)) + " times wins.", MSG_COL, MSG_DUR_STD, 1
 
        FOR i = 1 TO PLAYER_NET_MAX
            FOR j = 1 TO PLAYER_NET_MAX
                stats(i, j) = 0
            NEXT j
        NEXT i
 
        stav.gameplay = 1
        stav.pocetgul = stav.pocetgulzvoleny + stav.pocethracov
        stav.pocetgulx = MATHROUND(SQR(4 / 3 * stav.pocetgul))
        IF stav.pocetgulx < stav.pocethracov THEN stav.pocetgulx = stav.pocethracov
        stav.pocetguly = _CEIL(stav.pocetgul / stav.pocetgulx)
 
        IF stav.pocethracov < 2 THEN stav.pocethracov = 2
        FOR i = 1 TO stav.pocethracov
            hrac(i).skore = 0
        NEXT i
 
        FOR n = 1 TO stav.pocethracov: bal(n).syncstr = GETITEM_PBAL: bal(n).synctime = 0: NEXT n
        FOR n = stav.pocethracov + 1 TO UBOUND(bal): bal(n).syncstr = GETITEM_BAL: bal(n).synctime = 0: NEXT n
 
        stav.zacinabal = hrac(INT(RND * stav.pocethracov + 1)).bal
 
        DO 'new round starts here
            '-------------------------------set the world on the new round start---------------------------
            stav.koniec_kola = 0
            stav.pauza = 0
            stav.vitaz = 0
            game.exituj = 0
            stav.baljeto = 0
 
            IF game.isnetgame = 1 AND game.hosth <> 0 THEN 'engage new spectating players
                FOR i = 2 TO stav.pocethracov
                    IF client(i).spectating = 1 THEN
                        hrac(i).skore = 0
                        bal(hrac(i).bal).hrac = i
                        bal(hrac(i).bal).complayer = 0
                        bal(hrac(i).bal).riadena = 1
                        client(i).spectating = 0
                        bal(i).vi.x = 0: bal(i).vi.y = 0
                        FOR j = 1 TO PLAYER_NET_MAX
                            stats(i, j) = 0
                            stats(j, i) = 0
                        NEXT j
                    END IF
                NEXT i
            END IF
 
            RANDOMIZE TIMER
            coloffset = 104 + INT(RND * 10)
            colcoef = (1 + INT(RND * (246 - coloffset))) / stav.pocetgulx
            FOR i = 1 TO stav.pocetguly + 1 'set all balls
                FOR j = 1 TO stav.pocetgulx
                    n = (i - 1) * stav.pocetgulx + j:
                    IF n <= stav.pocetgul THEN
                        ry = 20 + RND * INT(((stav.maxy - 100) / (stav.pocetguly + 1) - 25) / 2)
                        rx = 10 + RND * INT(((stav.maxx - 100) / (stav.pocetgulx + 1) - 25) / 2)
                        bcol = coloffset + j * colcoef
                        bal(n).i = n
                        bal(n).col = bcol
                        bal(n).x = 100 + j * INT((stav.maxx - 100) / (stav.pocetgulx + 1))
                        bal(n).y = 100 + i * INT((stav.maxy - 100) / (stav.pocetguly + 1))
                        bal(n).r = rx * -(rx < ry) + ry * -(ry < rx)
                        bal(n).m = 4 / 4 * pi * bal(n).r ^ 2
                        bal(n).v.x = -10 / FPS: bal(n).v.y = -30 / FPS
                        bal(n).a.x = ACC_X * stav.maxx / RES_X_TARG
                        bal(n).a.y = ACC_Y * stav.maxx / RES_X_TARG
                        bal(n).vi.x = -(bal(n).complayer = 1) * RND * stav.vmax - stav.vmax / 2
                        bal(n).vi.y = -(bal(n).complayer = 1) * RND * stav.vmax - stav.vmax / 2
                        bal(n).riadena = 0
                        bal(n).energia = stav.energy_player_start
                        bal(n).freezedtime = 0: bal(n).klucka_time = 0: bal(n).klucka_pocet = 0
                        bal(n).klucka_trvanie = 0: bal(n).klucka_uhol = 0
                        bal(n).boost_time = 0: bal(n).boost_trvanie = 0
                        bal(n).synctime = 0
                    END IF
                NEXT j
            NEXT i
 
            '---set players balls default atributtes--------------------------------------------------------
            FOR i = 1 TO stav.pocethracov
                hrac(i).bal = i
                bal(hrac(i).bal).hrac = i
                bal(hrac(i).bal).riadena = 1
                IF stav.AIallowed = 0 AND klav(hrac(i).klavesy).typ = 4 THEN
                    bal(hrac(i).bal).energia = 0
                    bal(hrac(i).bal).riadena = 0
                ELSE
                    bal(hrac(i).bal).r = PLAY_BALL_R * stav.maxx / RES_X_TARG
                    bal(hrac(i).bal).m = 4 / 4 * pi * PLAY_BALL_R ^ 2 / 2 'Players have only half density
                    bal(hrac(i).bal).col = hrac(i).col
                    bal(hrac(i).bal).strat = 3
                END IF
            NEXT i
 
            '---decide initially tagged player-------------------------------------------------------------
            zacinalNaposledyBal = stav.zacinabal
            stav.balbudeto = stav.zacinabal
            DO
                stav.zacinabal = stav.zacinabal + 1
                IF stav.zacinabal > stav.pocetgulx THEN stav.zacinabal = 1
            LOOP UNTIL bal(stav.zacinabal).riadena = 1
            stav.baljeto = stav.zacinabal
 
            FOR b = 1 TO stav.pocethracov
                bal(hrac(b).bal).protivnik = stav.baljeto * -(hrac(b).bal <> stav.baljeto)
            NEXT b
            bal(stav.zacinabal).protivnik = zacinalNaposledyBal
 
            '----------------------------------game action loop--------------------------------------------
            DO
                game.tstart = TIMER(.001)
                _LIMIT stav.fps
                CLS 1
                k = _KEYHIT
                IF k = 116 AND game.clientid > 0 AND game.msgwrite = 0 THEN game.msgwrite = 1: k = 0 'message writing mode
                IF game.msgwrite = 1 THEN WriteMessage k: k = 0
                IF NOT (game.isnetgame = 1 AND game.clienth <> 0) AND (k = 112 OR k = 102) THEN stav.pauza = 1 - stav.pauza
 
                DrawScore 'Draw players score on screen
                DisplayMessages 'Draw messages
 
                '---debug code begin---------------------------------------------
                IF k = 98 THEN game.printdebug = -(game.printdebug = 0)
                IF game.printdebug = 1 THEN DebugScreen k 'display debug info on screen
                '---debug code end-----------------------------------------------
 
                IF k = 99 THEN game.show_stats = -(game.show_stats = 0)
                IF game.show_stats = 1 THEN DisplayStatistics 'display match statistics
 
                IF stav.pauza = 0 THEN
                    FOR i = 1 TO stav.pocethracov
                        ResolvePlayerControl bal(hrac(i).bal), klav(hrac(i).klavesy) 'resolve players control
                        IF bal(hrac(i).bal).riadena = 1 THEN
                            CalculatePlayerState bal(hrac(i).bal) 'calculate player status
                        END IF
                    NEXT i
 
                    FOR n = 1 TO stav.pocetgul
                        PerformMovement bal(n) 'do ball movement
                    NEXT n
 
                    FOR i = 1 TO stav.pocetgul
                        FOR j = i + 1 TO stav.pocetgul
                            BounceTest bal(i), bal(j) 'Test balls bounce
                        NEXT j
                    NEXT i
                ELSE
                    PauseGame
                END IF
 
                IF game.isnetgame = 1 THEN SyncNetGameData
 
                FOR n = 1 TO stav.pocetgul
                    DrawBall bal(n) 'draw ball
                NEXT n
 
                IF stav.vitaz <> 0 THEN DrawWinScreen
 
                IF NOT (game.isnetgame = 1 AND game.clienth <> 0) AND (k = 102) THEN stav.pauza = 1
                IF k = 27 AND game.isnetgame = 1 THEN AddMessage "To quit network game press 't' and type '/q'", MSG_COL, MSG_DUR_STD, 0: k = 0
                IF k = 27 AND game.isnetgame = 0 THEN stav.koniec_kola = 2
 
                _DISPLAY 'Turn video page over
                game.tend = TIMER(.001)
                CalculateFps
            LOOP UNTIL stav.koniec_kola >= 1
            '---------------------------end of game action loop---------------------------------------------
 
            IF stav.vitaz <> 0 THEN k = 0
            anyHumanPlayer = HumanPlayersCount
            resumegame = 0
            DO 'wait for resume if not net game
                _LIMIT stav.fps
                IF k = 27 AND game.hosth = 0 THEN stav.koniec_kola = 2
                FOR i = 1 TO stav.pocethracov
                    IF klav(hrac(i).klavesy).typ = 3 THEN ReadGamepad klav(hrac(i).klavesy)
                    IF klav(hrac(i).klavesy).isshoota THEN resumegame = 1
                    IF klav(hrac(i).klavesy).isshootb THEN stav.koniec_kola = 2
                    IF klav(hrac(i).klavesy).typ = 1 THEN IF _KEYDOWN(klav(hrac(i).klavesy).shoota) THEN resumegame = 1
                NEXT i
                k = _KEYHIT
            LOOP UNTIL (resumegame = 1) OR (anyHumanPlayer = 0) OR (stav.koniec_kola = 2) OR (game.isnetgame = 1)
            '---------------------------end of round-----------------------------------------------------------
        LOOP UNTIL stav.koniec_kola = 2 OR (stav.AIallowed = 0 AND anyHumanPlayer < 2)
        IF (stav.AIallowed = 0 AND anyHumanPlayer < 2) THEN AddMessage "Match was ended for less than 2 players left", MSG_COL, MSG_DUR_STD, 0
    END IF
    '---------------------------end of game------------------------------------------------------------
    game.autostart_time = TIMER + stav.autostart_set
LOOP UNTIL game.exituj = 1
CLS 1
'---------------------------end of program------------------------------------------------------------
 
'////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawWinScreen
    DIM statstab(1 TO PLAYER_NET_MAX) AS STRING
    IF stav.vitaz > 0 THEN
        IF hrac(stav.vitaz).skore >= stav.winscore THEN windelay = DELAY_MATCHEND ELSE windelay = DELAY_ROUNDSTART
        IF game.autostart_time - windelay > TIMER THEN game.autostart_time = game.autostart_time - 86399
        IF (game.autostart_time <= TIMER) AND (game.isnetgame = 0 OR game.hosth <> 0) THEN
            stav.koniec_kola = 1 'end of round
            IF hrac(stav.vitaz).skore >= stav.winscore THEN stav.koniec_kola = 2 'end of match either
        END IF
        IF (game.isnetgame = 0 OR game.hosth <> 0) THEN stav.autostart_timeleft = game.autostart_time - TIMER
        IF INT(stav.autostart_timeleft) >= 0 THEN timeleft$ = "  (" + LTRIM$(STR$(INT(stav.autostart_timeleft))) + ")" ELSE timeleft$ = ""
        IF hrac(stav.vitaz).skore < stav.winscore THEN
            winstr1$ = "....and the winner of this round is... " + RTRIM$(hrac(stav.vitaz).meno) + timeleft$
            winstr2$ = "Press <fire> for the next round"
        ELSE
            winstr1$ = "...>>> " + RTRIM$(hrac(stav.vitaz).meno) + " <<<.... scores " + LTRIM$(STR$(stav.winscore)) + " and becomes the MATCH WINNER!" + timeleft$
            winstr2$ = "Press <fire> to return to the menu"
            DisplayStatistics
        END IF
        COLOR bal(hrac(stav.vitaz).bal).col
        _PRINTSTRING ((game.maxx - LEN(winstr1$) * 10) / 2, (game.maxy - 50) / 2), winstr1$
        IF stav.koniec_kola > 0 THEN _PRINTSTRING ((game.maxx - LEN(winstr2$) * 10) / 2, (game.maxy - 50) / 2 + 50), winstr2$
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DisplayStatistics
    IF stav.pocethracov <= PLAYER_NET_MAX THEN playercount = stav.pocethracov ELSE playercount = PLAYER_NET_MAX
    row = INT((game.maxy - (playercount + 4) * _FONTHEIGHT) / _FONTHEIGHT)
    col = INT((game.maxx - ((playercount + 2) * 11 * _FONTWIDTH)) / 2 / _FONTWIDTH)
    IF row < 1 THEN row = 1
    IF col < 1 THEN col = 1
    COLOR MSG_COL
    LOCATE row, col
    PRINT "Match statistics - tags given by player"
    LOCATE row + 1, col
    PRINT STRING$((playercount + 2) * 11, "-"),
    LOCATE row + 2, col
    PRINT "Player"
    FOR i = 1 TO playercount
        COLOR hrac(i).col
        LOCATE row + 2, col + i * 11
        PRINT RTRIM$(hrac(i).meno)
    NEXT i
    COLOR MSG_COL
    LOCATE row + 2, col + i * 11
    PRINT "Tags given"
    FOR i = 1 TO playercount
        tagsum = 0
        LOCATE row + 2 + i, col
        COLOR hrac(i).col
        PRINT RTRIM$(hrac(i).meno)
        FOR j = 1 TO playercount
            LOCATE row + 2 + i, col + j * 11
            IF stats(i, j) > 0 THEN PRINT STR$(stats(i, j))
            tagsum = tagsum + stats(i, j)
        NEXT j
        LOCATE row + 2 + i, col + j * 11
        PRINT STR$(tagsum)
    NEXT i
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION HumanPlayersCount 'set pre-game parameters
    HumanPlayersCount = 0
    FOR i = 1 TO stav.pocethracov
        IF bal(hrac(i).bal).complayer = 0 THEN HumanPlayersCount = HumanPlayersCount + 1
    NEXT i
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SetGlobalParameters 'set pre-game parameters
    '-------------------------------set game session parameters----------------------------------------------------------------------------------------
    game.fpsactual = FPS
    game.isnetgame = 0
    game.clienth = 0
    game.clientid = 0
    game.hosth = 0
    game.host_port = HOSTPORT_DEFAULT
    game.host_ip = HOSTIP_DEFAULT
    game.printdebug = DEBUGMODE
    game.exituj = 0
    game.start = 0
    game.newmsg = 0
    IF RES_X = -1 THEN game.maxx = _DESKTOPWIDTH ELSE game.maxx = RES_X
    IF RES_Y = -1 THEN game.maxy = _DESKTOPHEIGHT ELSE game.maxy = RES_Y
    game.msgcount = 0
    game.msgwrite = 0
    game.msgtext = ""
    game.show_stats = 0
    sync.syncstr = GETITEM_SYNC
    sync.synctime = 0
 
    '-------------------------------set game world parameters----------------------------------------------------------------------------------------
    pi = _PI
    stav.syncstr = GETITEM_STAV
    stav.synctime = 0
    stav.pauza = 0
    stav.gameplay = 0
    stav.fps = FPS
    stav.pocethracov = PLAYER_COUNT_INI
    stav.pocetgulzvoleny = POCET_GUL_INI
    stav.pocetgul = POCET_GUL_INI
    stav.energy_allmin = ENERGY_ALL_MIN
    stav.energy_playermin = ENERGY_PLAYER_MIN
    stav.energy_playermax = ENERGY_PLAYER_MAX
    stav.energydec = ENERGY_DEC
    stav.odpor = FRICTION
    stav.minx = 0
    stav.miny = 0
    stav.maxx = RES_X_TARG
    stav.maxy = RES_Y_TARG
    stav.vmax = V_MAX * stav.maxx / RES_X_TARG
    stav.maxcol = MAX_COL
    stav.boostallowed = 1
    stav.massallowed = 0 'sticky balls problem if mass allowed unsolved yet
    stav.autostart_set = 0
    game.autostart_time = 0
    stav.AIallowed = 1
    stav.winscore = 3
    stav.energy_player_start = (stav.energy_allmin / stav.pocethracov) 'calculate  players energy
    IF stav.energy_player_start < stav.energy_playermin THEN stav.energy_player_start = stav.energy_playermin
    IF stav.energy_player_start > stav.energy_playermax THEN stav.energy_player_start = stav.energy_playermax
 
    stats(PLAYER_NET_MAX + 1, 1) = ASC(GETITEM_STAT, 1)
    stats(PLAYER_NET_MAX + 1, 2) = ASC(GETITEM_STAT, 2)
    stats(PLAYER_NET_MAX + 1, 3) = ASC(GETITEM_STAT, 3)
 
    '-------------------------------set game controllers---------------------------------------------------------------------------------------------
    FOR i = 1 TO UBOUND(klav) 'set all the other game controllers as unused, few reserved for net players
        IF i <= PLAYER_NET_MAX THEN
            klav(i).typ = 5
            klav(i).nazov = "NetControl" + LTRIM$(STR$(i))
        ELSE
            klav(i).typ = 0
        END IF
        klav(i).devid = 0
        klav(i).syncstr = GETITEM_KLAV
        klav(i).synctime = 0
    NEXT i
 
    'set default controllers
    kid = PLAYER_NET_MAX + 1 'CPU void controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<CPU>": klav(kid).typ = 4
 
    kid = PLAYER_NET_MAX + 2 'keyboard set 1 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<Arrow keys + LShift>": klav(kid).typ = 1
    klav(kid).up = 18432: klav(kid).down = 20480: klav(kid).left = 19200: klav(kid).right = 19712
    klav(kid).shoota = 100304: klav(kid).shootb = 100306
 
    kid = PLAYER_NET_MAX + 3 'keyboard set 2 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<W,A,S,D + RShift>": klav(kid).typ = 1
    klav(kid).up = 119: klav(kid).down = 115: klav(kid).left = 97: klav(kid).right = 100
    klav(kid).shoota = 100303: klav(kid).shootb = 100305
 
    kid = PLAYER_NET_MAX + 4 'keyboard set 3 controller
    klav(kid).id = kid: klav(kid).devid = 1: klav(kid).nazov = "<I,J,K,L + Enter>": klav(kid).typ = 1
    klav(kid).up = 105: klav(kid).down = 107: klav(kid).left = 106: klav(kid).right = 108
    klav(kid).shoota = 13: klav(kid).shootb = 21248
 
    '-------------------------------set players------------------------------------------------------------------------------------------------------
    FOR i = 1 TO UBOUND(hrac) 'initial setting for all players
        hrac(i).bal = i
        hrac(i).meno = "Player" + LTRIM$(STR$(i))
        hrac(i).skore = 0
        hrac(i).klavesy = CPU_CONTROLID
        hrac(i).col = 32 + i * 3
        hrac(i).clientid = 0
        bal(hrac(i).bal).complayer = 1
        hrac(i).syncstr = GETITEM_HRAC
        hrac(i).synctime = 0
    NEXT i
 
    'personalize some players initially
    bal(hrac(1).bal).complayer = 0
    hrac(1).klavesy = PLAYER_NET_MAX + 2
    hrac(1).meno = "Chuck"
    hrac(2).meno = "Arnold"
    hrac(3).meno = "Jean"
    hrac(4).meno = "Bruce"
    hrac(5).meno = "Dolph"
    hrac(6).meno = "Sylvester"
    hrac(7).meno = "Jet"
    hrac(8).meno = "Dwayne"
 
    '-------------------------------set behaviour strategies------------------------------------------------------------------------------------------
    'some void strategy
    strat(1).okraj = PRIESTOR_MIN:
    strat(1).okraj_rot = 0.1
    strat(1).chybasmeru = 0.00:
    strat(1).klucka_avgtm = 1 * FPS: strat(1).klucka_pocet = 5
    strat(1).klucka_trvanie = 0.25 * FPS: strat(1).klucka_uhol = pi / 2: strat(1).klucka_uholodch = 0.2
    strat(1).detekcia_sin = SIN(pi / 4): strat(1).detekcia_vzdfull = 500: strat(1).detekcia_vzdmin = 1000: strat(1).detekcia_rot = 0.5
    strat(1).boost_dist = 200
    strat(1).boost_chasesin = SIN(pi / 8)
    strat(1).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(1).mate_rot = 0.1 ' 3*pi /FPS
    strat(1).mate_en_distmin = 5 * PLAY_BALL_R
    strat(1).mate_distmin = 4 * PLAY_BALL_R
 
    'non dodging strategy
    strat(2).okraj = PRIESTOR_MIN + 10
    strat(2).okraj_rot = 0.1
    strat(2).chybasmeru = 0.00
    strat(2).reactdrop_per = 0 * FPS
    strat(2).reactdrop_dur = 0 * FPS
    strat(2).klucka_avgtm = 10 * FPS
    strat(2).klucka_pocet = 0
    strat(2).klucka_trvanie = 0 * FPS
    strat(2).klucka_uhol = 0 * pi / 3
    strat(2).klucka_uholodch = 0.2
    strat(2).detekcia_sin = SIN(pi / 6)
    strat(2).detekcia_vzdfull = 500
    strat(2).detekcia_vzdmin = 1000
    strat(2).detekcia_rot = 0.5
    strat(2).boost_dist = 200
    strat(2).boost_chasesin = SIN(pi / 8)
    strat(2).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(2).mate_rot = 0.1 ' 3*pi /FPS
    strat(2).mate_en_distmin = 5 * PLAY_BALL_R
    strat(2).mate_distmin = 4 * PLAY_BALL_R
 
    'dodging strategy - currently used for all AI players
    strat(3).okraj = PRIESTOR_MIN + 10
    strat(3).okraj_rot = 0.1
    strat(3).chybasmeru = 0.30
    strat(3).reactdrop_per = 0.8 * FPS
    strat(3).reactdrop_dur = 0.4 * FPS
    strat(3).klucka_avgtm = 5 * FPS
    strat(3).klucka_pocet = 3
    strat(3).klucka_trvanie = 2 * FPS
    strat(3).klucka_uhol = pi * 2 / 3
    strat(3).klucka_uholodch = 0.2
    strat(3).detekcia_sin = SIN(pi / 6)
    strat(3).detekcia_vzdfull = 300
    strat(3).detekcia_vzdmin = 1500
    strat(3).detekcia_rot = 0.5 '10 * pi / FPS
    strat(3).boost_dist = 200
    strat(3).boost_chasesin = SIN(pi / 8)
    strat(3).mate_cosenmax = -0.8 'cos(140/180*pi)
    strat(3).mate_rot = 0.1 ' 3*pi /FPS
    strat(3).mate_en_distmin = 8 * PLAY_BALL_R
    strat(3).mate_distmin = 4 * PLAY_BALL_R
    strat(3).adrenalin_rate = 0.90
    strat(3).adrenalin_energy = 0.30
 
    '-------------------------------set main menu-----------------------------------------------------------------------------------------------------
    menu.item_active = 1
    menu.items_count = 22
    menu.cursor_col = 15
    menu.cursor_width = 400
    menu.item_height = FONT_H + 4
    menu.cursor_xpos = INT((game.maxx - menu.cursor_width) / 2)
    menu.ypos = INT((game.maxy - menu.items_count * menu.item_height) / 2)
    menu.cursor_out = 5
    '-------------------------------set balls---------------------------------------------------------------------------------------------------------
    FOR n = 1 TO stav.pocethracov: bal(n).syncstr = GETITEM_PBAL: bal(n).synctime = 0: NEXT n
    FOR n = stav.pocethracov + 1 TO UBOUND(bal): bal(n).syncstr = GETITEM_BAL: bal(n).synctime = 0: NEXT n
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB WriteMessage (k AS INTEGER)
    DIM tmptext AS STRING
    IF game.clientid > 0 THEN
        msginput_x = 10
        msginput_y = RES_Y - 20
 
        tmptext = LEFT$(game.msgtext, LEN(RTRIM$(game.msgtext)) - 1)
        IF k >= 32 AND k <= 126 AND LEN(tmptext) < MSG_LEN_MAX THEN tmptext = tmptext + CHR$(k)
        IF k = 8 AND LEN(tmptext) > 0 THEN tmptext = LEFT$(tmptext, LEN(tmptext) - 1)
        IF k = 27 THEN game.msgwrite = 0
 
        COLOR MSG_COL
        _PRINTSTRING (msginput_x, msginput_y), "Type message>>  " + tmptext
        IF k = -1 AND game.msgwrite = 0 THEN _PRINTSTRING (msginput_x, msginput_y), "Press 't' to writte text message to other players" + tmptext
 
 
        IF k = 13 THEN
            IF LEFT$(tmptext, 1) = "/" THEN
                AddMessage tmptext, MSG_COL, MSG_DUR_STD, 0
            ELSE
                AddMessage RTRIM$(hrac(game.clientid).meno) + "> " + tmptext, hrac(game.clientid).col, MSG_DUR_STD, 1
            END IF
            game.msgtext = CHR$(92)
            game.msgwrite = 0
        ELSE
            game.msgtext = tmptext + CHR$(92)
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SetUpControllers 'detect gamepads and set them as game controllers
    DIM klav_volne AS INTEGER, devices AS INTEGER
    DIM dev AS STRING
 
    FOR i = 1 TO UBOUND(klav) 'dispose all gamepad constrollers
        IF klav(i).typ = 3 THEN
            klav(i).typ = 0
            klav(i).devid = 0
        END IF
    NEXT i
    klav_volne = 1
    game.pocetgamepadov = 0
    DO
        klav_volne = klav_volne + 1
    LOOP UNTIL klav(klav_volne).typ = 0 OR klav_volne = UBOUND(klav)
    klav_used = klav_volne - 1
    devices = _DEVICES 'must be read prior to other device functions usage
    FOR i = 1 TO devices
        dev = _DEVICE$(i)
        IF INSTR(dev, "[CONTROLLER]") > 0 AND INSTR(dev, "[AXIS]") > 0 AND klav_volne <= UBOUND(klav) THEN 'set new controller if gamepad
            klav(klav_volne).id = klav_volne
            klav(klav_volne).devid = i
            klav(klav_volne).typ = 3
            klav(klav_volne).nazov = "<Gamepad" + LTRIM$(STR$(klav_volne - klav_used)) + ">"
            klav(klav_volne).xaxis = 1
            klav(klav_volne).yaxis = 2
            klav(klav_volne).dxaxis = _LASTAXIS(i) - 1
            klav(klav_volne).dyaxis = _LASTAXIS(i)
            klav(klav_volne).shoota = 1
            klav(klav_volne).shootb = 8
            klav_volne = klav_volne + 1
            game.pocetgamepadov = game.pocetgamepadov + 1
        END IF
    NEXT i
    game.pocetkontrolerov = klav_volne - 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB MainMenuScreen 'perform choises in main menu
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB SyncNetGameData
    DIM i AS INTEGER, isync AS tsyncvar, clklav AS tklavesy, clhrac AS thrac, imsg AS tmessage
    DIM sync_stav AS INTEGER, sync_pbal AS INTEGER, sync_bal AS INTEGER, sync_hrac AS INTEGER
    IF game.isnetgame = 1 THEN
        '--------------------------host side---------------------------------------------------------------------------------------------------------
        IF game.hosth <> 0 THEN 'sync host data
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'for each client try to connect
                IF client(i).conn = 0 AND i <= stav.pocethracov THEN
                    client(i).conn = _OPENCONNECTION(game.hosth) 'try to open connection if not open
                    client(i).get_item = GETITEM_SYNC
                    client(i).get_isdesync = 0
                    client(i).get_time = TIMER(.001)
                    IF client(i).conn <> 0 THEN 'if connection opened
                        client(i).ip = _CONNECTIONADDRESS(client(i).conn)
                        PLAY "MBL64O2CEG>C"
                        IF stav.gameplay = 1 THEN
                            client(i).spectating = 1
                            game.sync_stats = 1
                            msgtext$ = " joins the game from the next round"
                        ELSE
                            client(i).spectating = 0
                            msgtext$ = " has joined the game"
                        END IF
                        AddMessage "Player " + RTRIM$(hrac(i).meno) + msgtext$, MSG_COL, MSG_DUR_STD, 1
                    END IF
                END IF
                IF (TIMER(.001) - client(i).get_time) > NET_TIMEOUT_LIMIT AND client(i).conn <> 0 THEN CloseClientConn (i)
            NEXT i
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'sync data with each client
                sync.clientid = i
                IF client(i).conn <> 0 THEN
                    DO
                        IF client(i).get_isdesync = 1 THEN 'flush acquired data if desynced
                            GET #client(i).conn, , flush$
                            client(i).get_isdesync = 0
                            client(i).get_item = GETITEM_SYNC
                        END IF
 
                        IF client(i).get_item = GETITEM_SYNC THEN 'first get sync info on what item to get next
                            GET #client(i).conn, , isync
                            IF NOT EOF(client(i).conn) THEN
                                IF isync.syncstr = GETITEM_SYNC THEN
                                    client(i).get_item = isync.itemstr
                                    client(i).get_time = TIMER(.001)
                                    client(i).isdesynced = isync.isdesync
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_KLAV THEN 'get controller state from client
                            GET #client(i).conn, , clklav
                            IF NOT EOF(client(i).conn) THEN
                                IF clklav.syncstr = GETITEM_KLAV THEN
                                    klav(hrac(i).klavesy).isup = clklav.isup
                                    klav(hrac(i).klavesy).isdown = clklav.isdown
                                    klav(hrac(i).klavesy).isright = clklav.isright
                                    klav(hrac(i).klavesy).isleft = clklav.isleft
                                    klav(hrac(i).klavesy).isshoota = clklav.isshoota
                                    klav(hrac(i).klavesy).isshootb = clklav.isshootb
                                    klav(hrac(i).klavesy).gvektor = clklav.gvektor
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_HRAC THEN 'get client's player
                            GET #client(i).conn, , clhrac
                            IF NOT EOF(client(i).conn) THEN
                                IF clhrac.syncstr = GETITEM_HRAC THEN
                                    clhrac.skore = hrac(i).skore 'keep players socre
                                    hrac(i) = clhrac 'get player data from client
                                    hrac(i).klavesy = i 'set player net controlled
                                    hrac(i).clientid = i 'set player's clientid
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                        IF client(i).get_item = GETITEM_MESG THEN 'get message from client
                            GET #client(i).conn, , imsg
                            IF NOT EOF(client(i).conn) THEN
                                IF imsg.syncstr = GETITEM_MESG THEN
                                    AddMessage imsg.text, imsg.col, imsg.time_dur, 1
                                    msg(game.msgcount).clientid = imsg.clientid
                                    client(i).get_time = TIMER(.001)
                                ELSE
                                    client(i).get_isdesync = 1
                                END IF
                                client(i).get_item = GETITEM_SYNC
                            END IF
                        END IF
 
                    LOOP UNTIL EOF(client(i).conn)
                END IF
            NEXT i
 
            IF TIMER(.001) - stav.synctime > UPDATE_PER_STAV THEN 'check if update time
                sync_stav = 1
            ELSE sync_stav = 0
            END IF
            IF TIMER(.001) - bal(1).synctime > UPDATE_PER_PLBAL THEN
                FOR j = 1 TO stav.pocethracov: ipbal(j) = bal(j): NEXT j 'fill transfer array
                sync_pbal = 1
            ELSE sync_pbal = 0
            END IF
            IF TIMER(.001) - bal(stav.pocethracov + 1).synctime > UPDATE_PER_BAL THEN
                FOR j = 1 TO stav.pocetgulzvoleny: ibal(j) = bal(j + stav.pocethracov): NEXT j 'fill transfer array
                sync_bal = 1
            ELSE sync_bal = 0
            END IF
            IF TIMER(.001) - hrac(1).synctime > UPDATE_PER_HRAC THEN
                sync_hrac = 1
            ELSE sync_hrac = 0
            END IF
 
            FOR i = PLAYER_NET_MIN TO PLAYER_NET_MAX 'send host data to each client
                IF client(i).conn <> 0 THEN
                    sync.clientid = i
 
                    IF client(i).isdesynced = 1 THEN 'send sync var if client desynced
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_SYNC
                        PUT #client(i).conn, , sync
                        'PRINT "Resyncing client "; i 'TEMP DEBUG line
                    END IF
 
                    IF sync_stav = 1 AND client(i).isdesynced = 0 THEN 'send world state
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_STAV
                        PUT #client(i).conn, , sync
                        stav.synctime = TIMER(.001)
                        PUT #client(i).conn, , stav
                    END IF
 
                    IF sync_pbal = 1 AND client(i).isdesynced = 0 THEN 'send player balls
                        sync.synctime = TIMER(.001):
                        sync.itemstr = GETITEM_PBAL
                        PUT #client(i).conn, , sync
                        bal(1).synctime = TIMER(.001)
                        PUT #client(i).conn, , ipbal()
                    END IF
 
                    IF sync_bal = 1 AND client(i).isdesynced = 0 THEN 'send nonplayer balls
                        sync.synctime = TIMER(.001)
                        sync.itemstr = GETITEM_BAL
                        bal(stav.pocethracov + 1).synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        PUT #client(i).conn, , ibal()
                    END IF
 
                    IF sync_hrac = 1 AND client(i).isdesynced = 0 THEN 'IF stav.gameplay = 0 OR stav.vitaz <> 0 THEN 'send players
                        FOR j = 1 TO PLAYER_NET_MAX: ihrac(j) = hrac(j): NEXT j 'fill transfer array
                        sync.itemstr = GETITEM_HRAC
                        sync.synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        hrac(1).synctime = TIMER(.001)
                        PUT #client(i).conn, , ihrac()
                    END IF
 
                    IF game.sync_stats = 1 AND client(i).isdesynced = 0 THEN 'send match statistics
                        sync.itemstr = GETITEM_STAT
                        sync.synctime = TIMER(.001)
                        PUT #client(i).conn, , sync
                        PUT #client(i).conn, , stats()
                    END IF
 
                    IF game.newmsg = 1 AND client(i).isdesynced = 0 THEN 'send new messages
                        FOR j = 1 TO game.msgcount
                            IF msg(j).distribute = 1 AND msg(j).clientid <> i THEN
                                sync.itemstr = GETITEM_MESG:
                                sync.synctime = TIMER(.001):
                                PUT #client(i).conn, , sync
                                msg(j).synctime = TIMER(.001):
                                PUT #client(i).conn, , msg(j)
                            END IF
                        NEXT j
                    END IF
 
                END IF
            NEXT i
            game.sync_stats = 0 'clear send statistics flag
            game.newmsg = 0 'clear messages distributed flags
            FOR j = 1 TO game.msgcount
                msg(j).distribute = 0
            NEXT j
        END IF
 
        '-------------------client side-------------------------------------------------------------------------------
        IF game.clienth <> 0 THEN 'client getting data from host
            DO
                IF game.get_isdesync = 1 THEN 'flush acquired data if desynced
                    'PRINT "Resyncing... "; game.get_item 'TEMP debug line
                    DO
                        GET #game.clienth, , isync
                    LOOP UNTIL (NOT EOF(game.clienth) AND isync.syncstr = GETITEM_SYNC) OR (TIMER(.001) - game.get_time) > NET_TIMEOUT_SYNC
 
                    'GET #game.clienth, , flush$
 
                    IF NOT EOF(game.clienth) AND isync.syncstr = GETITEM_SYNC THEN
                        'PRINT "==================RESYNCED================ "; game.get_item; "-"; isync.itemstr 'TEMP debug line
                        game.get_item = isync.itemstr
                        game.get_isdesync = 0
                    ELSE
                        'PRINT "Desynced!!!!!!!!!!!!! "; game.get_item 'TEMP debug line
                    END IF
                END IF
 
                IF game.get_item = GETITEM_SYNC THEN 'first get sync info on what item to get next
                    GET #game.clienth, , isync
                    IF NOT EOF(game.clienth) THEN
                        IF isync.syncstr = GETITEM_SYNC THEN
                            game.clientid = isync.clientid
                            game.get_item = isync.itemstr
                            game.get_time = TIMER(.001)
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                    END IF
                END IF
 
                IF game.get_item = GETITEM_STAV THEN 'get world state
                    GET #game.clienth, , istav
                    IF NOT EOF(game.clienth) THEN
                        IF istav.syncstr = GETITEM_STAV THEN
                            IF istav.synctime > stav.synctime THEN
                                stav = istav
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_PBAL THEN 'get player balls data
                    GET #game.clienth, , ipbal()
                    IF NOT EOF(game.clienth) THEN
                        IF (ipbal(1).syncstr = GETITEM_PBAL) THEN
                            IF (ipbal(1).synctime > bal(1).synctime) THEN 'AND (TIMER(.001) - game.timer_pballs) < (ipbal(1).synctime - bal(1).synctime + 0.05) THEN
                                FOR i = 1 TO stav.pocethracov
                                    bal(i) = ipbal(i)
                                NEXT i
                            END IF
                            game.timer_pballs = TIMER(.001)
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_BAL THEN 'get nonplayer balls data
                    GET #game.clienth, , ibal()
                    IF NOT EOF(game.clienth) THEN
                        IF (ibal(1).syncstr = GETITEM_BAL) THEN
                            IF (ibal(1).synctime > bal(stav.pocethracov + 1).synctime) THEN
                                FOR i = 1 TO stav.pocetgulzvoleny
                                    bal(stav.pocethracov + i) = ibal(i)
                                NEXT i
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_MESG THEN 'get message
                    GET #game.clienth, , imsg
                    IF NOT EOF(game.clienth) THEN
                        IF (imsg.syncstr = GETITEM_MESG) THEN
                            AddMessage imsg.text, imsg.col, imsg.time_dur, 0
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_HRAC THEN 'get players data
                    GET #game.clienth, , ihrac()
                    IF NOT EOF(game.clienth) THEN
                        IF ihrac(1).syncstr = GETITEM_HRAC THEN
                            IF ihrac(1).synctime > hrac(1).synctime THEN
                                FOR i = 1 TO PLAYER_NET_MAX
                                    IF i <> game.clientid AND game.clientid > 0 THEN 'if another client's player
                                        hrac(i) = ihrac(i) 'get player data from host
                                        hrac(i).klavesy = i 'set player net controlled
                                    ELSE 'if my client player
                                        hrac(i).skore = ihrac(i).skore
                                        hrac(i).bal = ihrac(i).bal
                                        hrac(i).clientid = ihrac(i).clientid
                                    END IF
                                NEXT i
                            END IF
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
                IF game.get_item = GETITEM_STAT THEN 'get match statistics
                    GET #game.clienth, , istats()
                    IF NOT EOF(game.clienth) THEN
                        IF (istats(PLAYER_NET_MAX + 1, 1) + istats(PLAYER_NET_MAX + 1, 2) + istats(PLAYER_NET_MAX + 1, 3)) = (ASC(GETITEM_STAT, 1) + ASC(GETITEM_STAT, 2) + ASC(GETITEM_STAT, 3)) THEN
                            FOR i = 1 TO UBOUND(stats, 1)
                                FOR j = 1 TO UBOUND(stats, 2)
                                    stats(i, j) = istats(i, j)
                                NEXT j
                            NEXT i
                            game.sync_stats = 0
                            'PRINT "Synced"; isync.itemstr 'TEMP debug line
                        ELSE
                            game.get_isdesync = 1
                        END IF
                        game.get_item = GETITEM_SYNC
                    END IF
                END IF
 
            LOOP UNTIL EOF(game.clienth)
 
            IF game.clientid > 0 THEN 'send clients data to host
                sync.synctime = TIMER(.001)
 
                'IF stav.gameplay = 1 THEN 'send client controller to host
                sync.itemstr = GETITEM_KLAV
                sync.synctime = TIMER(.001)
                sync.isdesync = game.get_isdesync
                PUT #game.clienth, , sync
                PUT #game.clienth, , klav(hrac(game.clientid).klavesy)
                'END IF
 
                'IF stav.gameplay = 0 THEN 'send client player to host
                sync.itemstr = GETITEM_HRAC
                sync.synctime = TIMER(.001)
                PUT #game.clienth, , sync
                PUT #game.clienth, , hrac(game.clientid)
                'END IF
 
                IF game.newmsg = 1 AND game.msgcount > 0 THEN 'send client player to host
                    IF msg(game.msgcount).distribute = 1 THEN
                        sync.itemstr = GETITEM_MESG
                        sync.synctime = TIMER(.001)
                        PUT #game.clienth, , sync
                        PUT #game.clienth, , msg(game.msgcount)
                        msg(game.msgcount).distribute = 0
                    END IF
                    game.newmsg = 0
                END IF
            END IF
 
            IF (TIMER(.001) - game.get_time) > NET_TIMEOUT_LIMIT THEN ResetNetGame
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CloseClientConn (clidx AS INTEGER)
    IF client(clidx).conn <> 0 THEN
        CLOSE client(clidx).conn
        client(clidx).conn = 0
    END IF
    hrac(clidx).clientid = 0
    hrac(clidx).klavesy = CPU_CONTROLID
    hrac(clidx).isready = 0
    bal(hrac(clidx).bal).complayer = 1
    IF stav.AIallowed = 0 AND klav(hrac(clidx).klavesy).typ = 4 THEN
        bal(hrac(clidx).bal).energia = 0
        CalculatePlayerState bal(hrac(clidx).bal)
    END IF
    AddMessage "Player " + RTRIM$(hrac(clidx).meno) + " was disconnected", MSG_COL, MSG_DUR_STD, 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ResetNetGame
    IF game.clienth <> 0 THEN 'try to close client connection
        CLOSE game.clienth
        game.clienth = 0
        game.clientid = 0
        stav.autostart_set = 0
        AddMessage "You have been disconnected from the host", MSG_COL, MSG_DUR_STD, 0
    END IF
    IF game.hosth <> 0 THEN 'try to close host service
        CLOSE game.hosth
        game.hosth = 0
        game.clientid = 0
        hrac(1).clientid = 0
        AddMessage "Game hosting ended", MSG_COL, MSG_DUR_STD, 0
    END IF
    game.isnetgame = 0
    FOR i = 1 TO PLAYER_COUNT_MAX
        hrac(i).clientid = 0
        IF (klav(hrac(i).klavesy).typ = 5) OR (i > PLAYER_NET_MAX AND klav(hrac(i).klavesy).typ <> 4) THEN
            hrac(i).klavesy = CPU_CONTROLID
            bal(hrac(i).bal).complayer = 1
        END IF
    NEXT i
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB HostGame
    IF game.clienth <> 0 THEN ResetNetGame
    IF game.hosth = 0 THEN
        game.hosth = _OPENHOST("TCP/IP:" + STR$(game.host_port))
        IF game.hosth <> 0 THEN
            game.isnetgame = 1
            game.clientid = 1
            hrac(1).clientid = 1
            AddMessage "Game hosting started", MSG_COL, MSG_DUR_STD, 0
        ELSE
            game.isnetgame = 0
        END IF
    ELSE
        ResetNetGame
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB JoinGame
    IF game.hosth <> 0 THEN ResetNetGame
    IF game.clienth = 0 THEN
        AddMessage "Connecting to" + RTRIM$(STR$(game.host_port)) + ":" + RTRIM$(game.host_ip) + "...", MSG_COL, MSG_DUR_STD, 0
        DisplayMessages
        _DISPLAY
        game.clienth = _OPENCLIENT("TCP/IP:" + STR$(game.host_port) + ":" + RTRIM$(game.host_ip))
        IF game.clienth <> 0 THEN
            game.isnetgame = 1
            game.get_item = GETITEM_SYNC
            game.get_isdesync = 0
            game.get_time = TIMER(.001)
            game.timer_pballs = TIMER(.001)
            AddMessage "Connection opened, joining the game...", MSG_COL, MSG_DUR_STD, 0
        ELSE
            game.isnetgame = 0
        END IF
    ELSE
        CLOSE game.clienth
        ResetNetGame
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION InputText$ (meno AS STRING, xpos AS INTEGER, ypos AS INTEGER, col AS INTEGER, inputwidth AS _BYTE, hint AS STRING, initval AS _BYTE, digitonly AS _BYTE) 'get text input from keyboard input
    clrstr$ = ""
    tmpstr$ = ""
    IF initval = 1 THEN res$ = RTRIM$(meno) ELSE res$ = ""
    FOR i = 1 TO inputwidth: clrstr$ = clrstr$ + " ": NEXT i
    COLOR col
    DO
        DO
            _LIMIT FPS
            k = _KEYHIT
        LOOP UNTIL k <> 0
        IF ((digitonly = 0 AND k >= 33 AND k <= 126) OR (digitonly = 1 AND k >= 48 AND k <= 57)) AND LEN(res$) < LEN(meno) THEN res$ = res$ + CHR$(k)
        IF k = 8 AND LEN(res$) > 0 THEN res$ = LEFT$(res$, LEN(res$) - 1)
        IF res$ = "" THEN tmpstr$ = hint ELSE tmpstr$ = res$
        _PRINTSTRING (xpos, ypos), clrstr$
        _PRINTSTRING (xpos, ypos), tmpstr$
        _DISPLAY
    LOOP UNTIL k = 13 OR k = 27
    IF k = 13 THEN InputText$ = res$
    IF k = 27 THEN InputText$ = CHR$(27)
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PrintMenuItem (id AS INTEGER, amenu AS tmenu, menucode AS INTEGER, playercode AS INTEGER, rollable AS INTEGER, s AS STRING, fixedwidth AS INTEGER, deltax AS INTEGER, lineoff AS INTEGER, col AS INTEGER) 'print horizontaly centered text at line y
    slen = LEN(RTRIM$(s)) * FONT_W
    IF fixedwidth > 0 THEN slen = fixedwidth
    px = INT((game.maxx - slen) / 2) + deltax
    py = amenu.ypos + (id - 1) * amenu.item_height
    COLOR col
    _PRINTSTRING (px, py), s
    IF id = amenu.item_active THEN
        IF rollable = 1 THEN
            COLOR amenu.cursor_col
            _PRINTSTRING (amenu.cursor_xpos - 10 - FONT_W, py), "<"
            _PRINTSTRING (amenu.cursor_xpos + amenu.cursor_width + 10, py), ">"
        END IF
        amenu.menucode = menucode
        amenu.playercode = playercode
    END IF
END SUB
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PrintMenuCursor (amenu AS tmenu) 'print menu cursor
    py = amenu.ypos + (amenu.item_active - 1) * amenu.item_height
    COLOR amenu.cursor_col
    LINE (amenu.cursor_xpos - amenu.cursor_out, game.maxy - (py - amenu.cursor_out))-(amenu.cursor_xpos + amenu.cursor_out + amenu.cursor_width, game.maxy - (py + FONT_H) - amenu.cursor_out), amenu.cursor_col, B
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PauseGame 'pause gameplay
    winstr$ = "-> Game paused <-"
    COLOR MSG_COL
    _PRINTSTRING ((game.maxx - LEN(winstr$) * 10) / 2, (game.maxy - 50) / 2), winstr$
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawBall (baln AS gula) 'draw ball
    CONST BSEGM = 10
    koef = (10 + 90 * game.printdebug) * FPS / 100
    bcol = baln.col
    IF baln.freezedtime > 0 THEN bcol = 27
    IF baln.riadena = 1 THEN
        CIRCLE (baln.x, baln.y), baln.r - 1, baln.col
        CIRCLE (baln.x, baln.y), baln.r + 1, baln.col
        FOR i = 1 TO BSEGM
            CIRCLE (baln.x, baln.y), i * (baln.r / 2 - 2) / BSEGM, bcol, 0, baln.energia / stav.energy_player_start * _PI * 2
        NEXT i
        LINE (baln.x, baln.y)-(baln.x + baln.v.x * koef, baln.y + baln.v.y * koef), baln.col 'draw actual velocity
        IF game.printdebug = 1 THEN LINE (baln.x, baln.y)-(baln.x + baln.vi.x * koef, baln.y + baln.vi.y * koef), bal(baln.protivnik).col 'draw intended velocity
    END IF
    IF baln.i = stav.baljeto THEN
        CIRCLE (baln.x, baln.y), baln.r * 2 / 3, 15
    END IF
    IF baln.i > stav.pocethracov THEN
        reflectfrom = ATN((1.25 * stav.maxy - baln.y) / (1.25 * stav.maxx - baln.x))
        CIRCLE (baln.x, baln.y), baln.r - 5, 28, reflectfrom, reflectfrom + _PI / 8
        CIRCLE (baln.x, baln.y), baln.r - 5, 28, reflectfrom + _PI / 8 + _PI / 32, reflectfrom + _PI / 4
        CIRCLE (baln.x, baln.y), baln.r - 10, 28, reflectfrom, reflectfrom + _PI / 8
        CIRCLE (baln.x, baln.y), baln.r - 10, 28, reflectfrom + _PI / 8 + _PI / 32, reflectfrom + _PI / 4
    END IF
 
    CIRCLE (baln.x, baln.y), baln.r, baln.col
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DrawScore 'Draw player score
    WINDOW (0, 0)-(game.maxx, game.maxy)
    FOR i = 1 TO stav.pocethracov
        scxl = SCORE_DELTA_X * -(game.maxx >= 4 * SCORE_DELTA_X) + game.maxx / 4 * -(game.maxx < 4 * SCORE_DELTA_X)
        dx = (game.maxx - 4 * scxl) / 2
        scx = dx + scxl * ((i - 4 * INT((i - 1) / 4)) - 1)
        scty = SCORE_DELTA_Y + 15 * INT((i - 1) / 4)
        scly = game.maxy - SCORE_DELTA_Y - 15 * INT((i - 1) / 4)
        COLOR bal(hrac(i).bal).col
        _PRINTSTRING (scx + (LEN(hrac(i).meno) - LEN(RTRIM$(hrac(i).meno))) * 8, scty - 10), RTRIM$(hrac(i).meno) + " -" + STR$(hrac(i).skore)
        LINE (scx + SCORE_NAME_LEN, scly)-(scx + SCORE_NAME_LEN + bal(hrac(i).bal).energia, scly + 7), bal(hrac(i).bal).col, BF
        IF bal(hrac(i).bal).energia <= 0 THEN
            _PRINTSTRING (scx + SCORE_NAME_LEN, scty - 10), "OUT"
        END IF
    NEXT i
    WINDOW (0, 0)-(stav.maxx, stav.maxy)
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CalculatePlayerState (baln AS gula) 'calculate players states
    DIM od AS SINGLE
    '-----------------------energy decreasing-------------------------------------
    IF baln.freezedtime > 0 THEN
        baln.freezedtime = baln.freezedtime - 1
    ELSE
        baln.energia = baln.energia - (stav.energydec * -(stav.baljeto = baln.i)) * game.fpscoef
    END IF
    IF baln.energia <= 0 THEN
        baln.riadena = 0
        pocetriadenych = 0
        FOR i = 1 TO stav.pocethracov
            IF bal(hrac(i).bal).riadena = 1 THEN
                pocetriadenych = pocetriadenych + 1
                priebeznyvitaz = i
            END IF
        NEXT i
        IF pocetriadenych > 1 THEN
            stav.baljeto = stav.balbudeto
            stav.balbudeto = nearestPlayer(bal(stav.baljeto), 0, 0)
            FOR i = 1 TO stav.pocetgulx
                IF bal(i).i <> stav.baljeto AND bal(i).riadena = 1 THEN bal(i).protivnik = stav.baljeto
            NEXT i
        END IF
        IF pocetriadenych = 1 THEN
            stav.vitaz = priebeznyvitaz
            hrac(stav.vitaz).skore = hrac(stav.vitaz).skore + 1
            IF hrac(stav.vitaz).skore >= stav.winscore THEN game.autostart_time = TIMER + DELAY_MATCHEND ELSE game.autostart_time = TIMER + DELAY_ROUNDSTART
            DrawScore
        END IF
    END IF
    '-----------------------dodging time-----------------------------------------
    IF baln.klucka_time = 0 AND baln.klucka_trvanie = 0 AND baln.klucka_pocet = 0 THEN
        baln.klucka_time = INT(RND * strat(baln.strat).klucka_avgtm + strat(baln.strat).klucka_avgtm / 2) / game.fpscoef
        baln.klucka_pocet = strat(baln.strat).klucka_pocet
    END IF
    IF baln.klucka_time > 0 THEN
        baln.klucka_time = baln.klucka_time - 1
    END IF
    IF baln.klucka_time = 0 AND baln.klucka_trvanie > 0 THEN
        baln.klucka_trvanie = baln.klucka_trvanie - 1
    END IF
    IF baln.klucka_time = 0 AND baln.klucka_trvanie = 0 AND baln.klucka_pocet > 0 THEN
        baln.klucka_pocet = baln.klucka_pocet - 1
        baln.klucka_trvanie = INT(RND * strat(baln.strat).klucka_trvanie + strat(baln.strat).klucka_trvanie / 2) / game.fpscoef
        baln.klucka_uhol = RND * strat(baln.strat).klucka_uhol * (2 * strat(baln.strat).klucka_uholodch) + strat(baln.strat).klucka_uhol * (1 - strat(baln.strat).klucka_uholodch) * (3 - INT(RND * 2 + 1) * 2)
    END IF
    '-----------------------choose nearest enemy if tagged-----------------------
    IF stav.baljeto = baln.i THEN
        novyprotivnik = nearestPlayer(baln, 0, -(baln.energia > (stav.energy_player_start * strat(baln.strat).adrenalin_energy)))
        IF novyprotivnik <> 0 THEN baln.protivnik = novyprotivnik
        stav.balbudeto = nearestPlayer(baln, 0, 0)
    END IF
    '-----------------------boosting time----------------------------------------
    IF baln.boost_time > 0 AND baln.boost_trvanie = 0 THEN baln.boost_time = baln.boost_time - 1
    IF baln.boost_trvanie > 0 THEN baln.boost_trvanie = baln.boost_trvanie - 1
 
    '-----------------------reaction drop time-----------------------------------
    IF baln.reactdrop_time > 0 THEN baln.reactdrop_time = baln.reactdrop_time - 1
    IF baln.reactdrop_time <= 0 AND baln.reactdrop_dur > 0 THEN baln.reactdrop_dur = baln.reactdrop_dur - 1
    IF baln.reactdrop_time <= 0 AND baln.reactdrop_dur <= 0 THEN
        IF baln.energia < (stav.energy_player_start * strat(baln.strat).adrenalin_energy) THEN reactkoef = (1 - strat(baln.strat).adrenalin_rate) ELSE reactkoef = 1
        baln.reactdrop_time = INT((RND * strat(baln.strat).reactdrop_per * reactkoef + strat(baln.strat).reactdrop_per * reactkoef / 2) / game.fpscoef)
        baln.reactdrop_dur = INT((RND * strat(baln.strat).reactdrop_dur * reactkoef + strat(baln.strat).reactdrop_dur * reactkoef / 2) / game.fpscoef)
        baln.smer_odchyl = (RND * strat(baln.strat).chybasmeru - strat(baln.strat).chybasmeru / 2) * pi 'apply random radian deviance from intended direction
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION nearestPlayer (baln AS gula, mateonly AS _BYTE, weighted AS _BYTE) 'returns nearest opponent idx
    CONST NEAREST_WEIGHTCOEF = 10.0 'coeficient for energy inclusion into weight
    DIM weight, vzd, vzdakt, vzdakt_winner AS SINGLE
    DIM nearest_winner AS INTEGER
    vzdakt = 0
    nearestPlayer = 0
    vzdakt_winner = 0
    nearest_winner = 0
    FOR i = 1 TO stav.pocetgulx
        IF bal(i).i <> baln.i AND bal(i).riadena = 1 AND (mateonly = 1 IMP i <> stav.baljeto) THEN
            weight = weighted * (stav.energy_player_start - bal(i).energia) * NEAREST_WEIGHTCOEF
            vzd = SQR((baln.x - bal(i).x) ^ 2 + (baln.y - bal(i).y) ^ 2) + weight
            IF nearestPlayer = 0 OR vzd < vzdakt THEN
                nearestPlayer = i
                vzdakt = vzd
            END IF
            IF hrac(bal(i).hrac).skore = stav.winscore - 1 AND (vzd < vzdakt_winner OR nearest_winner = 0) THEN
                nearest_winner = i
                vzdakt_winner = vzd
            END IF
        END IF
    NEXT i
    IF weighted = 1 AND nearest_winner > 0 THEN nearestPlayer = nearest_winner
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB GenerateAIControl (baln AS gula) 'Decide computer player's control keys hits
    DIM dd AS SINGLE, vid AS SINGLE, vd AS SINGLE, eid AS SINGLE, vnd AS SINGLE, ved AS SINGLE, did AS SINGLE, thit AS SINGLE
    DIM rot_klucka AS SINGLE, rot_border AS SINGLE, rot_enemy AS SINGLE, rot_mate AS SINGLE
    DIM siner AS SINGLE, coser AS SINGLE, sineri AS SINGLE, coseri AS SINGLE
    DIM sinevr AS SINGLE, cosevr AS SINGLE, sinmt AS SINGLE, cosnmt AS SINGLE
    DIM okrajrot AS SINGLE, enemy_dist_factor AS SINGLE, smerdookraju AS INTEGER, nearmate AS INTEGER
    DIM d AS vektor, vi AS vektor, ei AS vektor, ve AS vektor, di AS vektor, dm AS vektor
 
    vi = baln.vi 'player's intended speed vector copy
    vid = SQR(vi.x ^ 2 + vi.y ^ 2)
    vi.x = vi.x / vid * stav.vmax
    vi.y = vi.y / vid * stav.vmax
    vd = SQR(baln.v.x ^ 2 + baln.v.y ^ 2)
    ve = bal(baln.protivnik).v 'enemy speed vector copy
    ved = SQR(ve.x ^ 2 + ve.y ^ 2)
 
    d.x = bal(baln.protivnik).x - baln.x 'player to enemy postition vector
    d.y = bal(baln.protivnik).y - baln.y
    dd = SQR(d.x ^ 2 + d.y ^ 2)
    coser = (d.x * baln.v.x + d.y * baln.v.y) / (dd * vd)
    siner = (d.x * baln.v.y - d.y * baln.v.x) / (dd * vd)
    cosevr = (ve.x * baln.v.x + ve.y * baln.v.y) / (ved * vd)
    sinevr = (ve.x * baln.v.y - ve.y * baln.v.x) / (ved * vd)
 
    '!EXPERIMENTAL CODE! - try more exact enemy future position vector, but  does not work so well as used approximation
    'di.x = d.x + ve.x * d.x / ((((d.x / dd) + (ve.x / ved)) * stav.vmax) - ve.x) 'new intended direction to enemy
    'di.y = d.y + ve.y * d.y / ((((d.y / dd) + (ve.y / ved)) * stav.vmax) - ve.y) 'new intended direction to enemy
    '!EXPERIMENTAL CODE! end
 
    di.x = d.x + ve.x * dd / vd * ABS(siner) 'player to enemy approximate future position vector, future enemy position more relevant when enemy closer
    di.y = d.y + ve.y * dd / vd * ABS(siner)
    did = SQR(di.x ^ 2 + di.y ^ 2)
    coseri = (di.x * baln.v.x + di.y * baln.v.y) / (did * vd)
    sineri = (di.x * baln.v.y - di.y * baln.v.x) / (did * vd)
 
    rot_enemy = 0 'rotation away from enemy in rad
    rot_border = 0 'rotation away from border in rad
    rot_mate = 0 'rotation towards nearest mate in rad
    rot_odchyl = 0 'baln.smer_odchyl * -(baln.reactdrop_dur = 1) 'apply direction error if react time
    smerdookraju = 0 'is players direction to border
 
    IF NOT (stav.baljeto = baln.i) THEN 'decide flee action
        enemy_dist_factor = 1 * -(dd <= strat(baln.strat).detekcia_vzdfull) + (1 - (dd - strat(baln.strat).detekcia_vzdfull) / _
          (strat(baln.strat).detekcia_vzdmin - strat(baln.strat).detekcia_vzdfull)) * -(dd > strat(baln.strat).detekcia_vzdfull AND dd <= strat(baln.strat).detekcia_vzdmin)' factor=1 if enemy distance within treshold, then decreasing
 
        IF enemy_dist_factor > 0 THEN 'if enemy in detection distance, rotate away
            rot_enemy = -(coseri > 0) * -(ABS(sineri) <= strat(baln.strat).detekcia_sin) * (-(sineri > 0) + (sineri < 0)) * strat(baln.strat).detekcia_rot * enemy_dist_factor * game.fpscoef
 
            '!EXPERIMENTAL CODE! - try better rotation from enemy
            'strat(baln.strat).detekcia_rot = 10 * pi / FPS 'TEMPORARY MODIFICATION
            'cosevi = (di.x * vi.x + di.y * vi.y) / (did * vid)
            'sinevi = (di.x * vi.y - di.y * vi.x) / (did * vid)
            'cosvvi = (v.x * vi.x + v.y * vi.y) / (vd * vid)
            'sinvvi = (v.x * vi.y - v.y * vi.x) / (vd * vid)
            'IF (coseri > 0) AND (ABS(sineri) <= strat(baln.strat).detekcia_sin) THEN
            '    rot_dir = -(sineri > 0) + (sineri < 0)
            '    IF NOT ((cosevi > 0 AND (ABS(sinevi) <= strat(baln.strat).detekcia_sin)) AND NOT (rot_dir = (-(sinevi > 0) + (sinevi < 0)))) THEN
            '        rot_enemy = rot_dir * strat(baln.strat).detekcia_rot * enemy_dist_factor * game.fpscoef
            '    END IF
            'END IF
            '!EXPERIMENTAL CODE! end
 
        END IF
 
        okrajrot = strat(baln.strat).okraj_rot 'border unit rotation in rad
        IF baln.x < strat(baln.strat).okraj AND vi.x < 0 THEN
            rot_border = (okrajrot * (vi.y >= 0) + okrajrot * -(vi.y < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.x > stav.maxx - strat(baln.strat).okraj AND vi.x > 0 THEN
            rot_border = (okrajrot * -(vi.y >= 0) + okrajrot * (vi.y < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.y < strat(baln.strat).okraj AND vi.y < 0 THEN
            rot_border = (okrajrot * (vi.x >= 0) + okrajrot * (vi.x < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
        IF baln.y > stav.maxy - strat(baln.strat).okraj AND vi.y > 0 THEN
            rot_border = (okrajrot * (vi.x >= 0) + okrajrot * -(vi.x < 0)) '* (1 - enemy_dist_factor)
            smerdookraju = 1
        END IF
    END IF
 
    rot_klucka = baln.klucka_uhol * -(baln.klucka_time = 0) * -(baln.klucka_trvanie = 1) * -(stav.baljeto <> baln.i) * _
      (dd > strat(baln.strat).mate_distmin OR (coseri < 0 AND sineri >= 0 AND baln.klucka_uhol > 0 AND baln.klucka_uhol < pi) OR (coseri < 0 AND sineri <= 0 AND baln.klucka_uhol < 0 AND baln.klucka_uhol > -pi)) 'apply dodge if dodging time - TEMPORARY DISABLED!!!
 
 
    IF baln.i = bal(stav.baljeto).protivnik THEN 'if ball being chased
        nearmate = nearestPlayer(baln, 1, -(baln.energia > (stav.energy_player_start * strat(baln.strat).adrenalin_energy)))
        IF nearmate > 0 THEN
            dm.x = bal(nearmate).x - baln.x
            dm.y = bal(nearmate).y - baln.y
            dmd = SQR(dm.x ^ 2 + dm.y ^ 2)
            cosnm = (dm.x * baln.v.x + dm.y * baln.v.y) / (dmd * vd)
            sinnm = (dm.x * baln.v.y - dm.y * baln.v.x) / (dmd * vd)
            IF (rot_border = 0) AND (dmd > strat(baln.strat).mate_distmin) AND (((coseri < strat(baln.strat).mate_cosenmax) AND (dd < strat(baln.strat).mate_en_distmin)) OR ((coseri < 0) AND (dd > strat(baln.strat).mate_en_distmin))) THEN
                rot_mate = ((sinnm > 0) * strat(baln.strat).mate_rot * game.fpscoef - (sinnm <= 0) * strat(baln.strat).mate_rot * game.fpscoef) 'rotate towards mate
            END IF
        END IF
    END IF
 
    RotateVector vi, rot_border + rot_klucka + rot_odchyl + rot_enemy + rot_mate 'aplly all calculated rotations to intended velocity
 
    IF stav.baljeto = baln.i THEN 'chasing direction intended
        IF baln.reactdrop_time > 0 THEN 'if time is up for reaction
            baln.boostintended = -(-(coser > 0) AND -(cosevr > 0) AND -(ABS(sinevr) < strat(baln.strat).boost_chasesin) AND baln.boost_time = 0 AND smerdookraju = 0)
            baln.vi.x = stav.vmax * di.x / did
            baln.vi.y = stav.vmax * di.y / did
        END IF
    ELSE 'flee direction intended
        baln.boostintended = -(-(coser < 0) AND baln.boost_time = 0 AND dd < (RND * strat(baln.strat).boost_dist + 2 * PLAY_BALL_R) AND smerdookraju = 0)
        baln.vi.x = vi.x
        baln.vi.y = vi.y
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ReadGamepad (klavn AS tklavesy) 'read state of gamepad
    di = _DEVICEINPUT(klavn.devid)
    IF klavn.typ = 3 THEN
        klavn.gvektor.x = _AXIS(klavn.xaxis)
        klavn.gvektor.y = -_AXIS(klavn.yaxis)
        klavn.isshoota = _BUTTON(klavn.shoota)
        klavn.isshootb = _BUTTON(klavn.shootb)
        klavn.isup = (_AXIS(klavn.dyaxis) = -1)
        klavn.isdown = (_AXIS(klavn.dyaxis) = 1)
        klavn.isleft = (_AXIS(klavn.dxaxis) = -1)
        klavn.isright = (_AXIS(klavn.dxaxis) = 1)
        IF klavn.gvektor.x > 0.5 THEN klavn.isright = -1
        IF klavn.gvektor.x < -0.5 THEN klavn.isleft = -1
        IF klavn.gvektor.y > 0.5 THEN klavn.isup = -1
        IF klavn.gvektor.y < -0.5 THEN klavn.isdown = -1
 
        IF klavn.buttonstate <> (klavn.isshoota + klavn.isshootb * 2 + klavn.isup * 4 + klavn.isdown * 8 + klavn.isright * 16 + klavn.isleft * 32) THEN
            klavn.buttonstatechanged = -1
            klavn.buttonstatetimer = 50
        ELSE
            klavn.buttonstatechanged = 0
        END IF
        klavn.buttonstate = (klavn.isshoota + klavn.isshootb * 2 + klavn.isup * 4 + klavn.isdown * 8 + klavn.isright * 16 + klavn.isleft * 32)
    END IF
    IF klavn.buttonstatetimer > 0 THEN klavn.buttonstatetimer = klavn.buttonstatetimer - 1
    IF klavn.buttonstatetimer = 0 THEN klavn.buttonstatechanged = -1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB ResolvePlayerControl (baln AS gula, klavn AS tklavesy) 'perform players control keys actions
    DIM vn AS vektor, gvector AS vektor
 
    IF baln.complayer = 0 THEN 'read human player controls
        IF klavn.typ = 1 THEN 'read keyboard control
            klavn.isright = _KEYDOWN(klavn.right)
            klavn.isleft = _KEYDOWN(klavn.left)
            klavn.isdown = _KEYDOWN(klavn.down)
            klavn.isup = _KEYDOWN(klavn.up)
            klavn.isshoota = _KEYDOWN(klavn.shoota)
            klavn.isshootb = _KEYDOWN(klavn.shootb)
            baln.vi.x = baln.v.x
            baln.vi.y = baln.v.y
        END IF
 
        IF klavn.typ = 3 THEN 'read gamepad control
            baln.vi.x = 0
            baln.vi.y = 0
            ReadGamepad klavn
            baln.vi.x = klavn.gvektor.x * stav.vmax
            baln.vi.y = klavn.gvektor.y * stav.vmax
            IF ABS(klavn.gvektor.x) > GAMESTICK_DEADZONE OR ABS(klavn.gvektor.y) > GAMESTICK_DEADZONE THEN
                klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
                klavn.isleft = (baln.v.x > baln.vi.x)
                klavn.isup = (baln.v.y < baln.vi.y)
                klavn.isdown = (baln.v.y > baln.vi.y)
            END IF
            IF klavn.isshootb AND game.isnetgame = 0 THEN stav.koniec_kola = 2
        END IF
 
        IF klavn.typ = 5 AND game.isnetgame = 1 THEN
            IF game.clienth <> 0 THEN ' reset network controller state on client
                klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
                klavn.isleft = (baln.v.x > baln.vi.x)
                klavn.isup = (baln.v.y < baln.vi.y)
                klavn.isdown = (baln.v.y > baln.vi.y)
                'klavn.isright = 0
                'klavn.isleft = 0
                'klavn.isup = 0
                'klavn.isdown = 0
                klavn.isshoota = 0
            END IF
            baln.vi.x = baln.v.x
            baln.vi.y = baln.v.y
        END IF
 
    ELSE 'get controls of computer player
        IF baln.riadena = 1 THEN GenerateAIControl baln
        klavn.isright = (baln.v.x < baln.vi.x) 'set control keys status for desired direction
        klavn.isleft = (baln.v.x > baln.vi.x)
        klavn.isup = (baln.v.y < baln.vi.y)
        klavn.isdown = (baln.v.y > baln.vi.y)
        klavn.isshoota = -baln.boostintended
    END IF
 
    IF baln.freezedtime <= 0 AND baln.riadena = 1 THEN 'apply acquired controls to player movement
        vn.x = baln.v.x
        vn.y = baln.v.y
 
        game.fpscoef = stav.fps / game.fpsactual
        IF klavn.isright THEN vn.x = vn.x + baln.a.x * game.fpscoef 'accelerate player according to control keys states
        IF klavn.isleft THEN vn.x = vn.x - baln.a.x * game.fpscoef
        IF klavn.isdown THEN vn.y = vn.y - baln.a.y * game.fpscoef
        IF klavn.isup THEN vn.y = vn.y + baln.a.x * game.fpscoef
        IF klavn.isshoota AND baln.boost_time = 0 AND stav.boostallowed = 1 THEN 'set boost state
            baln.boost_trvanie = BOOST_TRVANIE / game.fpscoef
            baln.boost_time = BOOST_TIME / game.fpscoef
        END IF
        vnd = SQR(vn.x ^ 2 + vn.y ^ 2) 'limit actual velocity to max. velocity
        IF vnd > stav.vmax THEN
            vn.x = vn.x * stav.vmax / vnd
            vn.y = vn.y * stav.vmax / vnd
        END IF
 
        IF baln.boost_trvanie > 0 THEN 'add some extra speed if boosted
            vn.x = vn.x + stav.vmax * BOOST_V_KOEF * (baln.boost_trvanie / BOOST_TRVANIE) * game.fpscoef * vn.x / vnd
            vn.y = vn.y + stav.vmax * BOOST_V_KOEF * (baln.boost_trvanie / BOOST_TRVANIE) * game.fpscoef * vn.y / vnd
        END IF
 
        baln.v.x = vn.x 'apply controler modified velocity
        baln.v.y = vn.y
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PerformMovement (baln AS gula) 'Calculate ball movement
    baln.x = baln.x + baln.v.x * game.fpscoef
    baln.y = baln.y + baln.v.y * game.fpscoef
    baln.v.x = baln.v.x * stav.odpor ^ game.fpscoef
    baln.v.y = baln.v.y * stav.odpor ^ game.fpscoef
    IF (baln.x + baln.r > stav.maxx) THEN
        baln.v.x = -baln.v.x
        baln.x = stav.maxx - baln.r
    END IF
    IF (baln.x - baln.r < stav.minx) THEN
        baln.v.x = -baln.v.x
        baln.x = stav.minx + baln.r
    END IF
    IF (baln.y + baln.r > stav.maxy) THEN
        baln.v.y = -baln.v.y
        baln.y = stav.maxy - baln.r
    END IF
    IF (baln.y - baln.r < stav.miny) THEN
        baln.v.y = -baln.v.y
        baln.y = stav.miny + baln.r
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB BounceTest (bala AS gula, balb AS gula) 'Balls bounce test
    IF (bala.x - balb.x) * (bala.x - balb.x) + (bala.y - balb.y) * (bala.y - balb.y) <= (bala.r + balb.r + 0) * (bala.r + balb.r + 0) THEN
        PerformBounce bala, balb
        IF bala.riadena AND balb.riadena AND bala.freezedtime <= 0 AND balb.freezedtime <= 0 AND (stav.baljeto = bala.i OR stav.baljeto = balb.i) THEN 'balb.col = bal(bala.protivnik).col
            newjeto = bala.i * -(stav.baljeto <> bala.i) + balb.i * -(stav.baljeto <> balb.i)
            IF stav.baljeto <= PLAYER_NET_MAX AND newjeto <= PLAYER_NET_MAX AND (game.isnetgame = 0 OR game.hosth <> 0) THEN
                stats(stav.baljeto, newjeto) = stats(stav.baljeto, newjeto) + 1
                game.sync_stats = 1
            END IF
            stav.baljeto = newjeto
            bala.freezedtime = -(stav.baljeto = bala.i) * FREEZE_TIME / game.fpscoef
            balb.freezedtime = -(stav.baljeto = balb.i) * FREEZE_TIME / game.fpscoef
            bala.protivnik = balb.i
            balb.protivnik = bala.i
            FOR i = 1 TO stav.pocetgulx
                IF bal(i).i <> stav.baljeto AND bal(i).riadena = 1 THEN bal(i).protivnik = bal(stav.baljeto).i
            NEXT i
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB PerformBounce (bala AS gula, balb AS gula) 'Calculate balls bounce
    DIM dx AS SINGLE, dy AS SINGLE, d AS SINGLE
    DIM l AS SINGLE, l1 AS SINGLE, l2 AS SINGLE
    DIM k AS SINGLE, k1 AS SINGLE, k2 AS SINGLE
    DIM m AS SINGLE, m1 AS SINGLE, m2 AS SINGLE
    DIM n AS SINGLE, n1 AS SINGLE, n2 AS SINGLE
    DIM cosa AS SINGLE, cosb AS SINGLE, p AS SINGLE
    DIM ma AS SINGLE, mb AS SINGLE
 
    IF stav.massallowed = 1 THEN
        ma = bala.m
        mb = balb.m
    ELSE
        ma = 1
        mb = 1
    END IF
 
    dx = balb.x - bala.x
    dy = balb.y - bala.y
    d = SQR(dx ^ 2 + dy ^ 2)
 
    p = bala.r + balb.r - d 'Move overlapping balls away from each other
    IF p >= 0 THEN
        bala.x = bala.x - dx * p / d / 2 * 2
        bala.y = bala.y - dy * p / d / 2 * 2
        balb.x = balb.x + dx * p / d / 2 * 2
        balb.y = balb.y + dy * p / d / 2 * 2
 
        dx = balb.x - bala.x
        dy = balb.y - bala.y
        d = SQR(dx ^ 2 + dy ^ 2)
    END IF
 
    cosa = dy / d
    cosb = -cosa
 
    l = (dx * bala.v.x * ma + dy * bala.v.y * ma) / d
    l2 = l * cosa
    k = (dy * bala.v.x * ma - dx * bala.v.y * ma) / d
    k1 = k * cosa
    l1 = bala.v.x * ma - k1
    k2 = bala.v.y * ma - l2
 
    n = (-dx * balb.v.x * mb - dy * balb.v.y * mb) / d
    n2 = n * cosb
    m = (-dy * balb.v.x * mb + dx * balb.v.y * mb) / d
    m1 = m * cosb
    n1 = balb.v.x * mb - m1
    m2 = balb.v.y * mb - n2
 
    bala.v.x = (k1 + n1) / ma
    bala.v.y = (k2 + n2) / ma
    balb.v.x = (m1 + l1) / mb
    balb.v.y = (m2 + l2) / mb
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
FUNCTION MATHROUND (n)
    MATHROUND = FIX(n + 0.5 * SGN(n))
END FUNCTION
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB RotateVector (vn AS vektor, b AS SINGLE)
    DIM vt AS vektor
    sinb = SIN(b): cosb = COS(b)
    vt.x = vn.x * cosb - vn.y * sinb
    vt.y = vn.y * cosb + vn.x * sinb
    vn = vt
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB CalculateFps 'calculate actual fps coeficient for correct timig
    IF game.tend = game.tstart THEN
        game.fpsactual = stav.fps
    ELSE
        game.fpsactual = ((1 / (game.tend - game.tstart)) * 1 + game.fpsactual * 99) / 100
    END IF
    game.tstart = game.tend
    game.fpscoef = stav.fps / game.fpsactual
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DisplayMessages
    IF game.msgcount > 0 THEN 'refresh messages validity
        FOR i = 1 TO game.msgcount
            IF ((TIMER(.001) - msg(i).time_start) > msg(i).time_dur) AND msg(i).time_dur > 0 THEN DeleteMessage (i)
        NEXT i
    END IF
    LOCATE 3, 1
    IF game.msgcount > 0 THEN 'print messages
        FOR i = 1 TO game.msgcount
            COLOR msg(i).col
            PRINT RTRIM$(msg(i).text)
        NEXT i
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB AddMessage (mtext AS STRING, mcol AS INTEGER, mdur AS SINGLE, mdist AS INTEGER)
    IF LEFT$(mtext, 1) = "/" THEN
        TextCommand mtext
    ELSE
        IF mdur <> 0 THEN
            IF game.msgcount >= MSG_COUNT_MAX THEN DeleteMessage (1) 'delete last message if full
            game.msgcount = game.msgcount + 1
            msg(game.msgcount).clientid = game.clientid
            msg(game.msgcount).text = mtext
            msg(game.msgcount).col = mcol
            msg(game.msgcount).time_dur = mdur
            msg(game.msgcount).time_start = TIMER(.001)
            msg(game.msgcount).syncstr = "SNM"
            msg(game.msgcount).synctime = 0
            msg(game.msgcount).distribute = mdist
            IF mdist = 1 THEN game.newmsg = 1
        END IF
    END IF
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DeleteMessage (mid AS INTEGER)
    IF mid < game.msgcount AND mid > 0 THEN
        FOR i = mid TO game.msgcount - 1
            msg(i) = msg(i + 1)
        NEXT i
    END IF
    game.msgcount = game.msgcount - 1
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB TextCommand (ctext AS STRING)
    SELECT CASE LEFT$(RTRIM$(ctext), 2)
        CASE "/q" 'end network game
            IF game.hosth <> 0 AND stav.gameplay = 1 THEN
                stav.koniec_kola = 2
                AddMessage "The match has been ended by the host", MSG_COL, MSG_DUR_STD, 1
            END IF
            IF game.clienth <> 0 AND stav.gameplay = 1 THEN
                stav.koniec_kola = 2
                ResetNetGame
            END IF
        CASE "/d" 'disconnet client clidx
            clidx = VAL(MID$(RTRIM$(ctext), 3, LEN(RTRIM$(ctext)) - 2))
            IF game.hosth <> 0 AND clidx > 1 AND clidx <= PLAYER_NET_MAX THEN
                IF client(clidx).conn <> 0 THEN
                    CloseClientConn clidx
                    AddMessage "Player " + RTRIM$(hrac(clidx).meno) + " was disconnected by host", MSG_COL, MSG_DUR_STD, 1
                END IF
            END IF
    END SELECT
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
SUB DebugScreen (K AS INTEGER) 'print debyg information on screen in runtime
    COLOR 7
    LOCATE INT((stav.pocethracov - 0.5) / 4) + 2, 1
    PRINT "FPS:   "; game.fpsactual
 
    IF K = 101 THEN stav.energydec = -(stav.energydec = 0) * ENERGY_DEC
    IF K = 113 THEN
        bal(hrac(2).bal).strat = bal(hrac(2).bal).strat + 1
        IF bal(hrac(2).bal).strat > UBOUND(strat) THEN
            bal(hrac(2).bal).strat = 1
        END IF
    END IF
    COLOR 13
    PRINT "hrac(n)..isleft   "; klav(hrac(1).klavesy).isleft; klav(hrac(2).klavesy).isleft; klav(hrac(3).klavesy).isleft; klav(hrac(4).klavesy).isleft
    PRINT "hrac(n)..isright  "; klav(hrac(1).klavesy).isright; klav(hrac(2).klavesy).isright; klav(hrac(3).klavesy).isright; klav(hrac(4).klavesy).isright
    PRINT "hrac(n)..isdown   "; klav(hrac(1).klavesy).isdown; klav(hrac(2).klavesy).isdown; klav(hrac(3).klavesy).isdown; klav(hrac(4).klavesy).isdown
    PRINT "hrac(n)..isup     "; klav(hrac(1).klavesy).isup; klav(hrac(2).klavesy).isup; klav(hrac(3).klavesy).isup; klav(hrac(4).klavesy).isup
    PRINT "bal(2).vi        "; bal(hrac(2).bal).vi.x; bal(hrac(2).bal).vi.y
    PRINT "bal(3).vi        "; bal(hrac(3).bal).vi.x; bal(hrac(3).bal).vi.y
    PRINT "bal(4).vi        "; bal(hrac(4).bal).vi.x; bal(hrac(4).bal).vi.y
    PRINT "bal(2).strat     "; bal(2).strat
    PRINT "bal(2).klucka_time    "; bal(hrac(2).bal).klucka_time
    PRINT "bal(2).klucka_pocet   "; bal(hrac(2).bal).klucka_pocet
    PRINT "bal(2).klucka_trvanie "; bal(hrac(2).bal).klucka_trvanie
    PRINT "bal(2).klucka_uhol    "; bal(hrac(2).bal).klucka_uhol
    PRINT "bal(n).protivnik      "; bal(1).protivnik; bal(2).protivnik; bal(3).protivnik
    PRINT "bal(n).complayer      "; bal(1).protivnik; bal(2).protivnik; bal(3).protivnik
    PRINT "stav.baljeto          "; stav.baljeto
    PRINT "stav.koniec_kola      "; stav.koniec_kola
    PRINT "nearestPlayer(1)      "; nearestPlayer(bal(1), 0, 1)
    PRINT "bal(n).reactdrop_time _dur "; bal(2).reactdrop_time; bal(2).reactdrop_dur
    PRINT "bal(1).v              "; bal(1).v.x; bal(1).v.y
    PRINT "bal(1).a              "; bal(1).a.x; bal(1).a.y
    PRINT "bal(2).boostintended  "; bal(2).boostintended
    PRINT "bal(2).boost_time     "; bal(1).boost_time
    PRINT "bal(2).boost_trvanie  "; bal(1).boost_trvanie
    PRINT "bal(n).hrac           "; bal(1).hrac; bal(2).hrac; bal(3).hrac; bal(4).hrac
    PRINT "bal(1).syncstr        "; bal(1).syncstr
    PRINT "game.autostart_time   "; game.autostart_time
    PRINT "stav.autostart_set    "; stav.autostart_set
    PRINT "TIMER                 "; TIMER
    PRINT "client(n).conn"; client(1).conn; client(2).conn; client(3).conn; client(4).conn
    PRINT "hrac(n).klavesy"; hrac(1).klavesy; hrac(2).klavesy; hrac(3).klavesy; hrac(4).klavesy; hrac(10).klavesy
    PRINT "klav(hrac(n)klavesy).typ"; klav(hrac(1).klavesy).typ; klav(hrac(2).klavesy).typ; klav(hrac(3).klavesy).typ; klav(hrac(4).klavesy).typ; klav(hrac(10).klavesy).typ
    PRINT "game.sync_stats         "; game.sync_stats
END SUB
 
'----------------------------------------------------------------------------------------------------------------------------------------------------
 
 

Game description:
The aim is simple - do not allow to get tagged. Tagged player loses energy. If you get tagged, tag someone else as quickly as possible. When you are out of energy, you are out of the game round. Win 3 rounds to win the whole match.

Network game:
Host player chooses "Host game" from the main menu. Other players launch the game on their computers, choose "Join game" from main menu and input the IP address (or URL) of the computer with the host game running.
Player 1 is allways assigned to the host. Other players can be joined client players, other local players on host computer or AI players.

Control keys during the match:
P - pause the game
B - enter debug mode
E - enable/disable energy decreasing (only in debug mode)
<Esc> - quit the game (only if not in network game mode)
T - write text message to other players (only while hosting or joining a network session)
T/q - quit the game (only if hosting or joining a network session)
T/d2 - disconnect player 2 from session (only if hosting a network session)

News:

Author Topic: Tag! 2.2 - the chasing game with network multiplayer for up to 8 players (Read 3968 times)

dajan

Tag! 2.2 - the chasing game with network multiplayer for up to 8 players

dajan

Re: Tag! 2.1 game with LAN/internet multiplayer for max. 8 players

dajan

Re: Tag! 2.2 - the chasing game with network multiplayer for up to 8 players