Scale-able Sprite from DATA

[Zeppelin]

Hey,
Here is a small program that makes sprites off the DATA command and multi-dimensional arrays, but also allows scaling of those sprites :)

Code: QB64: [Select]

1. DATA 0,15,0,15,0
2. DATA 15,0,15,0,15
3. DATA 15,0,15,0,15
4. DATA 0,15,0,15,0
5. DATA 15,0,0,0,15
6.  
7. SCREEN 13
8. DIM SHARED sprite(4, 4)
9.  
10. scale = 25 'Change me to scale your sprite
11.  
12. FOR y = 0 TO 4
13.     FOR x = 0 TO 4
14.         READ sprite(x, y) 'Read the data
15.     NEXT x
16. NEXT y
17.  
18. FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
19.     FOR x = 0 TO 4 * scale STEP scale
20.         LINE (x, y)-(x + scale, y + scale), sprite(x / scale, y / scale), BF 'Draw each pixel
21.     NEXT x
22. NEXT y

Zep

[bplus]

Hi Zeppelin,

I made a mod to generalize and demo loading and drawing a sprite any where at any scale:

Code: QB64: [Select]

1. 'DATA 0,15,0,15,0
2. 'DATA 15,0,15,0,15
3. 'DATA 15,0,15,0,15
4. 'DATA 0,15,0,15,0
5. 'DATA 15,0,0,0,15
6.  
7. DATA 0,0,0,0,0,0,0,0,0,0,0,0
8. DATA 1,1,1,1,0,0,0,0,1,0,0,0
9. DATA 1,0,0,0,1,0,0,0,1,0,0,0
10. DATA 1,0,0,0,1,0,0,0,1,0,0,0
11. DATA 1,1,1,1,0,0,1,1,1,1,1,0
12. DATA 1,0,0,0,1,0,0,0,1,0,0,0
13. DATA 1,0,0,0,1,0,0,0,1,0,0,0
14. DATA 1,1,1,1,0,0,0,0,1,0,0,0
15.  
16. SCREEN _NEWIMAGE(800, 600, 32)
17. COLOR _RGB32(0, 160, 0), _RGB32(0, 0, 0)
18. 'SCREEN 13
19. CONST spriteMaxX = 11
20. CONST spriteMaxY = 7
21. DIM SHARED sprite(spriteMaxX, spriteMaxY)
22.  
23. 'scale = 25 'Change me to scale your sprite
24.  
25. FOR y = 0 TO spriteMaxY
26.     FOR x = 0 TO spriteMaxX
27.         READ sprite(x, y) 'Read the data
28.     NEXT x
29. NEXT y
30.  
31. ds = 1
32. WHILE 1
33.     'up and down the scales
34.     scale = scale + ds
35.     IF scale > 35 THEN ds = -ds
36.     IF scale < 1 THEN scale = 1: ds = -ds
37.     CLS
38.     drawSprite 200 * RND, 100 * RND, scale
39.     _DISPLAY
40.     _LIMIT 3
41. WEND
42.  
43. SUB drawSprite (x, y, scale)
44.     FOR yy = 0 TO spriteMaxY
45.         FOR xx = 0 TO spriteMaxX
46.             'Factor in the scale
47.             IF sprite(xx, yy) THEN LINE (xx * scale + x, yy * scale + y)-STEP(scale, scale), , BF 'Draw each pixel
48.         NEXT
49.     NEXT
50. END SUB
51.  

This is only a beginning. We could create an array of spriteType and give the drawSprite sub an index to that array. Which means we could load and draw tons of sprites.

Also the data could have codes for different colors (which you might have started with the 15's). For setting that up, could use a sprite editor to create data statements for an app. Might be nice project.

[Petr]

What to say? :-D

Code: QB64: [Select]

1. REDIM SHARED Sprite(0, 0) AS _BYTE
2. REDIM SHARED Frame(0) AS LONG
3. CONST TimeDelay = 1 / 25
4. DIM SHARED OldTime
5.  
6.  
7. r:
8. DATA "/","|","\","-"
9. FOR V = 1 TO 4
10.     READ r$
11.     TextToArray (r$)
12.     AS_FRAME
13. NEXT V
14.  
15. T$ = "Nice!"
16. TextToArray (T$)
17.  
18. ds = 1
19. SCREEN _NEWIMAGE(800, 600, 32)
20. COLOR _RGB32(0, 160, 0), _RGB32(0, 0, 0)
21. 'SCREEN 13
22.  
23.  
24. DO UNTIL INKEY$ = CHR$(27)
25.     scale = scale + ds
26.     IF scale > 35 THEN ds = -ds
27.     IF scale < 1 THEN scale = 1: ds = -ds
28.     CLS
29.     drawSprite 200 * RND, 100 * RND, scale
30.     ViewFram 190, 190, scale * 10
31.     _DISPLAY
32.     _LIMIT 10
33. LOOP
34.  
35. SUB drawSprite (x, y, scale)
36.     FOR yy = 0 TO UBOUND(sprite, 2) - 1
37.         FOR xx = 0 TO UBOUND(sprite, 1) - 1
38.             'Factor in the scale
39.             IF Sprite(xx, yy) THEN LINE (xx * scale + x, yy * scale + y)-STEP(scale, scale), , BF 'Draw each pixel
40.         NEXT
41.     NEXT
42. END SUB
43.  
44.  
45.  
46. SUB TextToArray (text AS STRING)
47.     virtual& = _NEWIMAGE(1024, 50, 256)
48.     a = _DEST
49.     _DEST virtual&
50.     _FONT 8, virtual&
51.     PRINT text
52.     REDIM Sprite(_PRINTWIDTH(text, virtual&), 50) AS _BYTE
53.     FOR y = 1 TO 50
54.         FOR x = 1 TO _PRINTWIDTH(text, virtual&)
55.             _SOURCE virtual&
56.             IF POINT(x, y) THEN Sprite(x, y) = 1
57.     NEXT x, y
58.     _DEST a: _SOURCE a
59.     _FREEIMAGE virtual&
60. END SUB
61.  
62. SUB AS_FRAME
63.     REDIM _PRESERVE Frame(UBOUND(frame) + 1) AS LONG
64.     Frame(UBOUND(frame)) = _NEWIMAGE(50, 50, 256)
65.     a = _DEST
66.     _DEST Frame(UBOUND(frame))
67.     drawSprite 1, 1, 5
68.     _CLEARCOLOR 0, _DEST
69.     _DEST a
70. END SUB
71.  
72. SUB ViewFram (x, y, size)
73.     SHARED FrameNr
74.     IF OldTime + TimeDelay < TIMER THEN FrameNr = FrameNr + 1: OldTime = TIMER
75.     IF FrameNr > UBOUND(Frame) THEN FrameNr = LBOUND(Frame) + 1
76.     _PUTIMAGE (x, y)-(x + size, y + size), Frame(FrameNr), 0 :REM This is repaired
77. END SUB
78.  
79.  

[Jack002]

LOL.
Best reply ever.

[Zeppelin]

Petr: Nice! HAhahahahaha.
bplus: Nice ;) addition.

Zep