Solar System (Kinda)

[Prithak]

Yay! I made a solar system!
Not the best way to do it but still, it's really cool.

Try clicking somewhere and see what happens :P

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. x = _WIDTH / 2
3. y = _HEIGHT / 2
4. y1 = y - 100
5. mx = x
6. my = y
7. DIM SHARED r, g, b
8. CLS
9. DO
10.     FOR i = 0 TO 360
11.         WHILE _MOUSEINPUT: WEND
12.         mb = _MOUSEBUTTON(1)
13.         IF mb THEN
14.             mx = _MOUSEX: my = _MOUSEY
15.         END IF
16.         r = 135: g = 135: b = 79
17.         rotate x, y, i, 50
18.         r = 135: g = 79: b = 79
19.         rotate x, y, i, 100
20.         r = 100: g = 150: b = 255
21.         rotate x, y, i, 150
22.         r = 109: g = 43: b = 43
23.         CIRCLE (x, y), 20, _RGB32(255, 150, 100)
24.         IF mx < x THEN
25.             x = x - 1
26.         ELSEIF mx > x THEN
27.             x = x + 1
28.         END IF
29.         IF my < y THEN
30.             y = y - 1
31.         ELSEIF my > y THEN
32.             y = y + 1
33.         END IF
34.  
35.         _DISPLAY
36.         CLS
37.     NEXT i
38. LOOP
39.  
40. SUB rotate (X, y, i, l)
41.     x2 = X + COS(_D2R(i)) * l
42.     y2 = y + SIN(_D2R(i)) * l / 2
43.     CIRCLE (x2, y2), 10, _RGB32(r, g, b)
44. END SUB

[Pete]

Nice! You turned the mouse into God's U-Haul.

Pete

[bplus]

Hi Prithak,

Nice playing God! I mod your Solar System with stuff learned with david_uwi :
https://www.qb64.org/forum/index.php?topic=1184.0

Code: QB64: [Select]

1. _TITLE "Prithak's Solor Mouse mod B+"
2. SCREEN _NEWIMAGE(700, 700, 32)
3. _SCREENMOVE 300, 20
4.  
5. TYPE planetType 'all info needed to draw a planet
6.     pName AS STRING
7.     distanceFromSun AS SINGLE
8.     radius AS SINGLE
9.     oneDayAngleChange AS SINGLE
10.     kolor AS _UNSIGNED LONG
11. END TYPE
12.  
13. 'setup solar center
14. DIM SHARED sunX, sunY
15. sunX = _WIDTH / 2
16. sunY = _HEIGHT / 2
17.  
18. 'setup planets  array
19. DIM SHARED planets(4) AS planetType
20.  
21. 'load the planets array data
22. '' newPlanet (index, planetName$, distFromSun,  radius, Kolr AS _UNSIGNED LONG)
23. newPlanet 0, "Sun", 0, 43, 1, _RGB32(255, 255, 160)
24. newPlanet 1, "Mercury", 57.9, 2, 87.97, _RGB32(255, 120, 150)
25. newPlanet 2, "Venus", 108.2, 4, 224.7, _RGB32(0, 200, 255)
26. newPlanet 3, "Earth", 149.6, 4, 365.26, _RGB32(0, 50, 180)
27. newPlanet 4, "Mars", 227.9, 2, 686.98, _RGB32(200, 0, 0)
28. 'DATA "Mercury",57.9,87.97 radius   1.5+   thousands of miles
29. 'DATA "Venus",108.2,224.7           3.7
30. 'DATA "Earth",149.6,365.26          3.9
31. 'DATA "Mars",227.9,686.98           2.1
32. '                                    432 sun  so take 10 x's less
33.  
34. 'see SUB planetXY for locating the planet and SUB drawPlanet
35.  
36.  
37. 'y1 = y - 100 'not used
38. mx = sunX
39. my = sunY
40. 'DIM SHARED r, g, b
41. 'CLS
42. DIM SHARED days
43. DO
44.     days = days + 1
45.     'FOR degreeAngle = 0 TO 360
46.     WHILE _MOUSEINPUT: WEND
47.     mb = _MOUSEBUTTON(1)
48.     IF mb THEN
49.         mx = _MOUSEX: my = _MOUSEY
50.     END IF
51.     'r = 135: g = 135: b = 79
52.     'rotate x, y, i, 50
53.     'r = 135: g = 79: b = 79
54.     'rotate x, y, i, 100
55.     'r = 100: g = 150: b = 255
56.     'rotate x, y, i, 150
57.     'r = 109: g = 43: b = 43
58.     'CIRCLE (x, y), 20, _RGB32(255, 150, 100)
59.     FOR i = 0 TO 4
60.         drawPlanet i
61.     NEXT
62.     IF mx < sunX THEN
63.         sunX = sunX - 1
64.     ELSEIF mx > sunX THEN
65.         sunX = sunX + 1
66.     END IF
67.     IF my < sunY THEN
68.         sunY = sunY - 1
69.     ELSEIF my > sunY THEN
70.         sunY = sunY + 1
71.     END IF
72.  
73.     _DISPLAY
74.     _LIMIT 20
75.     CLS
76.     'NEXT
77. LOOP
78.  
79. 'SUB rotate (X, y, i, l)
80. '    x2 = X + COS(_D2R(i)) * l
81. '    y2 = y + SIN(_D2R(i)) * l / 2
82. '    CIRCLE (x2, y2), 10, _RGB32(r, g, b)
83. 'END SUB
84.  
85. SUB drawPlanet (planetIndex)
86.     planetXY planetIndex, setX, setY
87.     CIRCLE (setX, setY), planets(planetIndex).radius, planets(planetIndex).kolor
88.     PAINT (setX, setY), planets(planetIndex).kolor, planets(planetIndex).kolor
89. END SUB
90.  
91. 'load a planet's data in a single call
92. SUB newPlanet (index, planetName$, distFromSun, radius, oneYearInEarthDays, Kolr AS _UNSIGNED LONG) 'all info needed to draw a planet
93.     planets(index).pName = planetName$
94.     planets(index).distanceFromSun = distFromSun
95.     planets(index).radius = radius
96.     planets(index).oneDayAngleChange = _PI(2) / oneYearInEarthDays
97.     planets(index).kolor = Kolr
98. END SUB
99.  
100. ' locate the planets current position in relation to sun center
101. SUB planetXY (planetIndex, pX, pY)
102.     pX = sunX + planets(planetIndex).distanceFromSun * COS(days * planets(planetIndex).oneDayAngleChange)
103.     pY = sunY + planets(planetIndex).distanceFromSun * SIN(days * planets(planetIndex).oneDayAngleChange)
104. END SUB
105.  
106.  

EDIT: did not need the inner FOR loop for degreeAngle but then had to reset _LIMIT 20 for main loop.