Pascal

[FellippeHeitor]

DIM JD, j, m, d AS LONG

is not the same as

DIM JD AS LONG, j AS LONG, m AS LONG, d AS LONG

Could that be it? Same for:

DIM y4, y1p, gam1, ksi1, mi1, ksi2, mi2, c41p, q, r, dz1, gam2, ksi3, c42p, c43p, dz2, gam3, mi3, z4, c, x3, x1 AS LONG

With that line, only x1 is a LONG. The rest are SINGLE.

[SMcNeill]

See if this doesn't work as intended:

Code: QB64: [Select]

1. ' program J2Jewish
2. DEFLNG A-Z
3. DIM JD, j, m, d AS LONG
4.  
5. PRINT " np. JD=2057986"
6. 'INPUT "JD = "; JD
7. JD = 2057986
8. JD2Jewish JD, j, m, d
9. PRINT j; " "; m; " "; d
10.  
11.  
12. FUNCTION c1 (x1 AS LONG)
13.     c1 = INT((235 * x1 + 1) / 19)
14. END FUNCTION
15.  
16. FUNCTION q1 (x1 AS LONG)
17.     q1 = INT(c1(x1) / 1095)
18. END FUNCTION
19.  
20. FUNCTION r1 (x1 AS LONG)
21.     r1 = c1(x1) MOD 1095
22. END FUNCTION
23.  
24. FUNCTION v1 (x1 AS LONG)
25.     v1 = 32336 * q1(x1) + INT((15 * q1(x1) + 765433 * r1(x1) + 12084) / 25920)
26. END FUNCTION
27.  
28. FUNCTION v2 (x1 AS LONG)
29.     v2 = v1(x1) + INT(6 * (v1(x1) / 7)) MOD 2
30. END FUNCTION
31.  
32. FUNCTION L2 (x1 AS LONG)
33.     L2 = v2(x1 + 1) - v2(x1)
34. END FUNCTION
35.  
36. FUNCTION c2 (x1 AS LONG)
37.     DIM v3, v4 AS LONG
38.     v3 = 2 * (INT((L2(x1) + 19) / 15) MOD 2)
39.     v4 = INT((L2(x1 - 1) + 7) / 15) MOD 2
40.     c2 = v2(x1) + v3 + v4
41. END FUNCTION
42.  
43. FUNCTION c4 (x1 AS LONG, x3 AS LONG)
44.     DIM L, c8, c9, c3 AS LONG
45.     L = c2(x1 + 1) - c2(x1)
46.     c8 = INT((L + 7) / 2) MOD 15
47.     c9 = -(INT((385 - L) / 2) MOD 15)
48.     c3 = INT((384 * x3 + 7) / 13) + c8 * INT((x3 + 4) / 12) + c9 * INT((x3 + 3) / 12)
49.     c4 = c2(x1) + c3
50. END FUNCTION
51.  
52. SUB JD2Jewish (JD AS LONG, j AS LONG, m AS LONG, d AS LONG)
53.  
54.     DIM y4, y1p, gam1, ksi1, mi1, ksi2, mi2, c41p, q, r, dz1, gam2, ksi3, c42p, c43p, dz2, gam3, mi3, z4, c, x3, x1 AS LONG
55.  
56.     y4 = JD - 347821
57.     q = INT(y4 / 1447)
58.     r = y4 MOD 1447
59.     y1p = 49 * q + INT((23 * q + 25920 * r + 13835) / 765433)
60.     gam1 = y1p + 1
61.     ksi1 = INT((19 * gam1 + 17) / 235)
62.     mi1 = gam1 - INT((235 * ksi1 + 1) / 19)
63.     c41p = c4(ksi1, mi1)
64.     dz1 = y4 - c41p
65.     gam2 = gam1 + INT(dz1 / 33)
66.     ksi2 = INT((19 * gam2 + 17) / 235)
67.     mi2 = gam2 - INT((235 * ksi2 + 1) / 19)
68.     c42p = c4(ksi2, mi2)
69.     dz2 = y4 - c42p
70.     gam3 = gam2 + INT(dz2 / 33)
71.     ksi3 = INT((19 * gam3 + 17) / 235)
72.     x1 = ksi3
73.     mi3 = gam3 - INT((235 * ksi3 + 1) / 19)
74.     x3 = mi3
75.     c43p = c4(ksi3, mi3)
76.     z4 = y4 - c43p
77.     c = INT((12 - x3) / 7)
78.     j = x1 + 1 - c
79.     m = x3 + 1
80.     d = z4 + 1
81. END SUB
82.  

Jack more or less had it translated.  The only issue with his program was variable types not matching and thus not passing back through the SUB/FUNCTION routines.

DIM JD, j, m, d AS LONG

vs..

SUB JD2Jewish (JD AS LONG, j AS LONG, m AS LONG, d AS LONG)

Since JD, j, m have no type associated with them, they're defined as SINGLE variables and won't pass values back and forth to the sub where the variables are LONG type.

A simple DEFLNG A-Z at the top of the program corrects most of the issues.  (Removing the % symbol makes certain all our variables are LONG and not INTEGER values which might overflow as well, so I stripped them out also.)

Except for those minor corrections, everything else is Jack's translation.  ;)

[Ryster]

It works brilliantly. There is one problem; Well, after the ending line, the code: END SU is the rest of the program, namely:
LOCATE 17, 5
PRINT "Julian Calendar"
e.t.c.
On each of these lines shows an error. It can be eliminated.

[jack]

this version gives the same answer as that of the pascal version, but am not sure it's correct however.

Code: QB64: [Select]

1. ' program J2Jewish
2. DEFINT A-Z
3.  
4. DIM JD, j, m, d
5.  
6. PRINT " np. JD=2057986"
7. 'NPUT "JD = "; JD
8. JD = 2057986
9. JD2Jewish JD, j, m, d
10. PRINT j; " "; m; " "; d
11.  
12.  
13. FUNCTION c1% (x1)
14.     c1% = INT((235 * x1 + 1) / 19)
15. END FUNCTION
16.  
17. FUNCTION q1% (x1)
18.     q1% = INT(c1%(x1) / 1095)
19. END FUNCTION
20.  
21. FUNCTION r1% (x1)
22.     r1% = c1%(x1) MOD 1095
23. END FUNCTION
24.  
25. FUNCTION v1% (x1)
26.     v1% = 32336 * q1%(x1) + INT((15 * q1%(x1) + 765433 * r1%(x1) + 12084) / 25920)
27. END FUNCTION
28.  
29. FUNCTION v2% (x1)
30.     v2% = v1%(x1) + INT(6 * (v1%(x1) / 7)) MOD 2
31. END FUNCTION
32.  
33. FUNCTION L2% (x1)
34.     L2% = v2%(x1 + 1) - v2(x1)
35. END FUNCTION
36.  
37. FUNCTION c2% (x1)
38.     DIM v3, v4
39.     v3 = 2 * (INT((L2%(x1) + 19) / 15) MOD 2)
40.     v4 = INT((L2%(x1 - 1) + 7) / 15) MOD 2
41.     c2 = v2%(x1) + v3 + v4
42. END FUNCTION
43.  
44. FUNCTION c4% (x1, x3)
45.     DIM L, c8, c9, c3
46.     L = c2%(x1 + 1) - c2%(x1)
47.     c8 = INT((L + 7) / 2) MOD 15
48.     c9 = -(INT((385 - L) / 2) MOD 15)
49.     c3 = INT((384 * x3 + 7) / 13) + c8 * INT((x3 + 4) / 12) + c9 * INT((x3 + 3) / 12)
50.     c4 = c2%(x1) + c3
51. END FUNCTION
52.  
53. SUB JD2Jewish (JD, j, m, d)
54.  
55.     DIM y4, y1p, gam1, ksi1
56.     DIM mi1, ksi2, mi2, c41p
57.     DIM q, r, dz1, gam2, ksi3
58.     DIM c42p, c43p, dz2, gam3
59.     DIM mi3, z4, c, x3, x1
60.  
61.     y4 = JD - 347821
62.     q = INT(y4 / 1447)
63.     r = y4 MOD 1447
64.     y1p = 49 * q + INT((23 * q + 25920 * r + 13835) / 765433)
65.     gam1 = y1p + 1
66.     ksi1 = INT((19 * gam1 + 17) / 235)
67.     mi1 = gam1 - INT((235 * ksi1 + 1) / 19)
68.     c41p = c4(ksi1, mi1)
69.     dz1 = y4 - c41p
70.     gam2 = gam1 + INT(dz1 / 33)
71.     ksi2 = INT((19 * gam2 + 17) / 235)
72.     mi2 = gam2 - INT((235 * ksi2 + 1) / 19)
73.     c42p = c4(ksi2, mi2)
74.     dz2 = y4 - c42p
75.     gam3 = gam2 + INT(dz2 / 33)
76.     ksi3 = INT((19 * gam3 + 17) / 235)
77.     x1 = ksi3
78.     mi3 = gam3 - INT((235 * ksi3 + 1) / 19)
79.     x3 = mi3
80.     c43p = c4(ksi3, mi3)
81.     z4 = y4 - c43p
82.     c = INT((12 - x3) / 7)
83.     j = x1 + 1 - c
84.     m = x3 + 1
85.     d = z4 + 1
86. END SUB
87.  

[Ryster]

A request to change the code.
The code works properly, but not completely according to my plan. In the current code, JD is given numerically. In my program, JD is calculated by another code placed earlier. So I want it to be automatically downloaded by the Hebrew code.

[TempodiBasic]

Hi Ryster

piece by piece the project comes out!
JD is the result of another piece (block) of code... a Function? A Sub?
it is easy...in pseudocode...

FUNCTION HebrewCode AS LONG
calculations
calculations
calculations
END FUNCTION

' program J2Jewish
DEFLNG A-Z

DIM JD, j, m, d

'PRINT " np. JD=2057986"
'INPUT "JD = "; JD
JD = HebrewCode    '2057986
JD2Jewish JD, j, m, d

this can be useful!....
or you must post the other piece of code if you are not so able to translate it into QB64/BASIC.
;-)

[Ryster]

JD is calculated from the usual formula. In addition, what I wrote in an earlier post (no answer) about the fact that after the Hebrew code whatever is there displays error in the first line. This is how you have to finish the Hebrew code so that you can write next instructions not related to Hebrew. So only these two problems remain to be solved and everything will be ok. Thank you for your willingness to help.