animation player

[mynameispaul]

This program is designed to create animation by playing a series of JPEG's in sequence.

Setup:

Unzip the contents of the ZIP file into your QB64 folder
* within the ZIP you should have:
- Animation2.bas
- Animation2.ini
- sub-folders 'AniFrames' and 'AniPlayer2wallpapers'
* ZIP file includes 1 animation series ('OptimusMegatron')

Create EXE for Animation2.bas

Run Animation2.exe

At the top of the window you should see a "button" for "Catagory 1"
Below that you should see an "icon" for 'OptimusMegatron'
Click the icon and the animation should start
. + (plus) to increase playback rate (speed up)
. - (minus) to decrease playback rate (slow down)
. TAB = change playback direction (forward/reverse)
. Backspace = go back to the Selection Screen (main menu)

Notes:

If the wallpaper name specified in the config file (Animation2.ini) is not found, the program will default to using the Width and Height (ScrnWidth and ScrnHeight) and colors (BGrd BGgr and BGbl) settings. (program will warn you that it cannot find the wallpaper)

Each catagory folder must have an "icon" .PNG file (30 pixels in height).

If you change the name of a catagory folder make sure you change its icon to the same name.

Each folder of JPG files (animation frames) must have a thumbnail JPG file named '$tn'.

Program assumes all images of a series are the same Width and Height. Screen/Window size is set using the first frame in the series.

As of this release the program allows for up to 5,000 frames per series. Of course you can change this in the source code.

* I have many more animation series i can share if anyone is interested. Most are TV intros of old shows.

Again, i hope i have supplied sufficient help and instructions so you can make this work. Please let me know if more help or instructions are needed.

PaulEL

[Pete]

This one looks interesting to me on a couple of levels. QB64 with _PUTIMAGE has made this a lot easier than it was in the past. I got a jpeg viewer in 2000 from Binary Mayhem that took 100s of lines to do what _PUTIMAGE routines do in just a few lines of code. Animation inside a QB64 app would be great, but until that happens, yes, this is the way to make a "taken apart" movie file run. But what would also be neat is a pic viewer. Windows 10 has a laggy one. Seven had a better one, but it got tossed.

Anyway, I downloaded it and I'm having a look. If you (Paul) are somewhat new to QB64, I will point out some helpful things when I come across them. I see you and I both use SHELL for directory info, but QB6 has added some commands to help there, too.

For instance, you could replace your getcurrentpath sub with...

path$ = _CWD$

An error I found: Change...

GetLabelValue "settings.ini", "CountPerSec", "", CountPerSec
to...
GetLabelValue "Animation2.ini", "CountPerSec", "", CountPerSec

To get the keys to work with a zero delay, I had to change the program flow in this part of the routine as follows...

Code: QB64: [Select]

1.     DO
2.  
3.         k$ = UCASE$(INKEY$)
4.         SELECT CASE k$
5.             CASE CHR$(27): EXIT SUB
6.             CASE CHR$(8): EXIT SUB 'back to main menu
7.             CASE "-"
8.                 IF AniDelay < MaxSlowDelay THEN
9.                     AniDelay = AniDelay + 1
10.                 END IF
11.             CASE "+"
12.                 AniDelay = AniDelay - 1
13.                 IF AniDelay < 1 THEN AniDelay = 1
14.             CASE CHR$(9) 'change playback direction
15.                 IF direction$ = "F" THEN
16.                     direction$ = "R"
17.                 ELSE
18.                     direction$ = "F"
19.                 END IF
20.                 EXIT DO
21.         END SELECT
22.  
23.         ''EXIT DO 'for testing
24.  
25.         dly = dly + 1
26.         CalcDelayValue delay
27.         ''LOCATE 1, 1: PRINT delay: END
28.         ''LOCATE 1, 1: PRINT delay; dly; AniDelay
29.         IF dly >= delay THEN EXIT DO
30.  
31.         ''LOCATE 1, 1: PRINT AniDelay
32.  
33.     LOOP
34.  

That's because if the delay check comes before the inkey input, it just exits the do loop without checking for a key press.


Also, you can use _HIDE with SHELL as in, SHELL _HIDE CMD$ to hide the console. _DONTWAIT can also be added if you don;t want the program to wit on the SHELL command. This is helpful in those NOTEPAD shells, you remarked out, because without _DONTWAIT, you have to close Notepad to return control to your program flow.

I'll muddle my way through more of your code throughout the day and let you know how it goes for me. BTW, welcome to the forum and thank you for posting some really interesting stuff  over the past couple of days. I would love to know if you started coding with QBasic and if so, how long ago? Also, I'm not saying you need to change anything, maybe you would rather use SHELL, but just in case you didn't know about the _CWD$ command, I wanted to point it out.

Pete

[Pete]

Wow, this was an absolute blast! I really need to make more time for hobby programming.

I did have some difficulty getting the delays to work, so I just redid that part of the program. My revisions keep the new delay times upon bksp or esc. I loved the green delay bar, so I made sure I kept that working in tandem with my new delay variable, "newdelay". I had to make a couple of the variables SHARED (path$, DelayFile$) and took out the previous delay subs. I consolidated the save delay part by adding sub savedelay (AniDelay). It worked perfectly for me with the demo jpegs.

I loved everything about this app. Super cool greyscale skin for starters. I loved the thumbnail menu. The reverse animation was a kick! I wish most video players had as good slow-mo capabilities.

Please if anyone tries my revision, let everyone know in this thread if there is an error in my coding that prevents the app from doing what Paul intended it to do.

Paul, again, very cool and thank you so much for coding this and posting it on the forum! The code was very easy to follow and understand. Great job!

Code: QB64: [Select]

1. '/title Animations (version 2) using thumbs
2. '/type utility
3. '========================================================
4. ' Controls while playing animation
5. '..................................................
6. '          - = decrease animation speed
7. '         + = increase animation speed
8. '       TAB = change playback direction (forward/reverse)
9. ' Backspace = back to selection screen
10. '========================================================
11.  
12. _TITLE "Animations (version 2) using thumbs"
13.  
14. DIM SHARED UserWarned, newdelay, path$, DelayFile$
15. DIM SHARED MenuIconsPath$, reload, BGrd, BGgr, BGbl
16. path$ = _CWD$
17. DelayFile$ = path$ + "\delay.dat"
18. MenuIconsPath$ = path$ + "\AniFrames"
19. wallpaperPath$ = path$ + "\AniPlayer2wallpapers\"
20. DIM SHARED Catagory$(5), catagories, Cat#
21. DIM SHARED catX(10), catY(10), catW(10), catH(10)
22. GetCatagories
23. DIM SHARED iconX(50), iconY(50), iconW(50), iconH(50), icon#, icons
24. DIM SHARED IconName$(50)
25. DIM SHARED ScrnWidth: ScrnWidth = 600
26. DIM SHARED ScrnHeight: ScrnHeight = 300
27. DIM SHARED MaxFrames: MaxFrames = 5000
28. DIM SHARED FrameName$(MaxFrames), frames, direction$, AniDelay
29.  
30. ' value of 'MaxSlowDelay' is the largest value allowed to slow down
31. ' an animation. Could really be any number wanted.
32. DIM SHARED MaxSlowDelay: MaxSlowDelay = 200
33.  
34. DIM SHARED CountPerSec
35. GetLabelValue "Animation2.ini", "CountPerSec", "", CountPerSec
36.  
37. configfile$ = "Animation2.ini"
38. GetLabelValue configfile$, "BGrd", "", BGrd
39. GetLabelValue configfile$, "BGgr", "", BGgr
40. GetLabelValue configfile$, "BGbl", "", BGbl
41.  
42. SetTheScreen:
43.  
44. GetLabelValue configfile$, "ScrnWidth", "", ScrnWidth
45. GetLabelValue configfile$, "ScrnHeight", "", ScrnHeight
46.  
47. DIM SHARED wallpaper$
48. GetLabelValue configfile$, "wallpaper", wallpaper$, n
49. wallpaper$ = wallpaperPath$ + wallpaper$
50. CheckForFile wallpaper$, found
51. IF found = 0 THEN
52.     IF UserWarned = 0 THEN
53.         CLS
54.         PRINT "warning!   following wallpaper image not found..."
55.         PRINT wallpaper$
56.         PRINT "press any key.."
57.         DO UNTIL INKEY$ <> "": LOOP
58.         UserWarned = 1
59.     END IF
60.     wallpaper$ = ""
61.     GetLabelValue configfile$, "ScrnWidth", "", ScrnWidth
62.     GetLabelValue configfile$, "ScrnHeight", "", ScrnHeight
63.     SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, 32)
64. ELSE
65.     SCREEN _NEWIMAGE(150, 150, 32)
66.     image& = _LOADIMAGE(wallpaper$)
67.     imgW% = _WIDTH(image&) '  get image width
68.     imgH% = _HEIGHT(image&) ' get image height
69.     ScrnWidth = imgW%
70.     ScrnHeight = imgH%
71. END IF
72.  
73. CLS
74.  
75. IF wallpaper$ <> "" THEN
76.     SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, 32)
77.     _PUTIMAGE (0, 0), image&
78. ELSE
79.     BGrd = 10
80.     BGgr = 100
81.     BGbl = 20
82.     fill = 1
83.     DrawBox 0, 0, ScrnWidth, ScrnHeight, BGrd, BGgr, BGbl, fill
84. END IF
85.  
86. ShowCatagories
87. LaodIcons
88. DrawIconBoxes
89.  
90. reload = 0
91.  
92. DO
93.     DO WHILE _MOUSEINPUT ' get latest mouse information
94.     LOOP
95.  
96.     x% = _MOUSEX: mx = x%
97.     y% = _MOUSEY: my = y%
98.     LeftClick% = _MOUSEBUTTON(1) '                 retrieve left button status
99.     RightClick% = _MOUSEBUTTON(2) '                retrieve right button status
100.  
101.     IF LeftClick% = -1 THEN
102.         IF clkd = 0 THEN
103.             TestClickPos mx, my
104.             IF reload THEN GOTO SetTheScreen
105.             clkd = 1
106.         END IF
107.     ELSE
108.         clkd = 0
109.     END IF
110.  
111.     k$ = UCASE$(INKEY$)
112.  
113.     SELECT CASE k$
114.         CASE CHR$(27): CLS: SYSTEM
115.     END SELECT
116.  
117. LOOP
118.  
119. SUB TestClickPos (mx, my) '################################################
120.  
121. '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
122. '-- clicked on a icon?
123.  
124. FOR i = 1 TO icons
125.  
126.     x = iconX(i)
127.     y = iconY(i)
128.     w = iconW(i)
129.     h = iconH(i)
130.  
131.     IF my >= y AND my <= y + h - 1 THEN
132.         IF mx >= x AND mx <= x + w - 1 THEN
133.             IF icon# = i THEN
134.                 LoadAnimationFrames i
135.                 reload = 1
136.                 EXIT SUB
137.             END IF
138.             icon# = i
139.             DrawIconBoxes
140.             EXIT SUB
141.         END IF
142.     END IF
143.  
144. NEXT
145.  
146. '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
147. '--clicked on a catagory label ?
148.  
149. FOR i = 1 TO catagories
150.  
151.     x = catX(i)
152.     y = catY(i)
153.     w = catW(i)
154.     h = catH(i)
155.  
156.     IF my >= y AND my <= y + h - 1 THEN
157.         IF mx >= x AND mx <= x + w - 1 THEN
158.             IF Cat# <> i THEN
159.                 Cat# = i
160.                 reload = 1
161.                 EXIT SUB
162.                 ShowCatagories
163.             END IF
164.         END IF
165.     END IF
166.  
167. NEXT
168. END SUB
169.  
170. SUB DrawIconBoxes '########################################################
171.  
172. FOR i = 1 TO icons
173.  
174.     x = iconX(i)
175.     y = iconY(i)
176.     w = iconW(i)
177.     h = iconH(i)
178.  
179.     IF i = icon# THEN
180.         clr& = _RGB32(0, 200, 255)
181.     ELSE
182.         clr& = _RGB32(BGrd, BGgr, BGbl)
183.     END IF
184.  
185.     LINE (x - 2, y - 2)-(x + w + 1, y + h + 1), clr&, B
186.     LINE (x - 3, y - 3)-(x + w + 2, y + h + 2), clr&, B
187.  
188. NEXT
189.  
190. END SUB
191.  
192. SUB DrawBox (x, y, w, h, Rd, Gr, Bl, fill) '###########################################
193. clr& = _RGB32(Rd, Gr, Bl)
194. IF fill THEN
195.     LINE (x, y)-(x + w - 1, y + h - 1), clr&, BF
196. ELSE
197.     LINE (x, y)-(x + w - 1, y + h - 1), clr&, B
198. END IF
199. END SUB
200.  
201. SUB ShowCatagories '######################################################
202.  
203. x = 10
204. y = 10
205. h = 40
206.  
207. w = ScrnWidth / catagories
208.  
209. FOR c = 1 TO catagories
210.     img$ = MenuIconsPath$ + "\" + Catagory$(c) + ".png"
211.     image& = _LOADIMAGE(img$)
212.     w% = _WIDTH(image&) '                                get image width
213.     h% = _HEIGHT(image&) '                              get image height
214.     clr = 0
215.     IF c = Cat# THEN clr = 255
216.     DrawBox x - 3, y - 3, w% + 6, h% + 6, clr, clr, clr, 1
217.  
218.     catX(c) = x
219.     catY(c) = y
220.     catW(c) = w%
221.     catH(c) = h%
222.  
223.     _PUTIMAGE (x, y), image&
224.  
225.     x = x + w% + 10
226. NEXT
227.  
228. END SUB
229.  
230. SUB GetCatagories '######################################################
231.  
232. tf$ = "~cats.tmp"
233. q$ = CHR$(34)
234. cmd$ = "dir " + q$ + MenuIconsPath$ + q$ + " /b >" + tf$
235.  
236. SHELL _HIDE cmd$
237. ''SHELL _DONTWAIT "notepad ~cats.tmp": END
238. OPEN tf$ FOR INPUT AS #1
239.  
240. DO UNTIL EOF(1)
241.  
242.     LINE INPUT #1, cat$
243.  
244.     IF INSTR(cat$, ".") = 0 THEN
245.         i = i + 1
246.         PRINT i; cat$
247.         Catagory$(i) = cat$
248.     END IF
249.  
250. LOOP
251.  
252. CLOSE 1
253.  
254. catagories = i
255. Cat# = 1
256.  
257. END SUB
258.  
259. SUB LaodIcons '##########################################################
260.  
261. tf$ = "~SubCat.tmp"
262. path$ = MenuIconsPath$ + "\" + Catagory$(Cat#) + "\"
263. q$ = CHR$(34)
264. cmd$ = "dir " + q$ + path$ + "*" + q$ + " /b >" + tf$
265. SHELL _HIDE cmd$
266. ''SHELL "notepad.exe " + tf$: END
267.  
268. DIM image&
269. IconSqr = 50
270. y = 60
271. x1 = 5
272. x = x1
273.  
274. OPEN tf$ FOR INPUT AS #1
275.  
276. DO UNTIL EOF(1)
277.  
278.     LINE INPUT #1, fldr$
279.  
280.     IF 1 = 1 THEN
281.  
282.         img$ = path$ + fldr$ + "\$tn.jpg"
283.         ''PRINT img$; "<": END
284.         image& = _LOADIMAGE(img$)
285.         _PUTIMAGE (x, y), image&
286.         w% = _WIDTH(image&) '                                get image width
287.         h% = _HEIGHT(image&) '                              get image height
288.         IF h% > tallest THEN tallest = h%
289.         i = i + 1
290.         iconX(i) = x
291.         iconY(i) = y
292.         iconW(i) = w%
293.         iconH(i) = h%
294.         IconName$(i) = LEFT$(img$, LEN(img$) - 4) 'trim off .XXX
295.  
296.         x = x + w% + 10
297.         IF x + IconSqr >= ScrnWidth THEN
298.             y = y + tallest + 10
299.             x = x1
300.             tallest = 0
301.         END IF
302.     END IF
303.  
304. LOOP
305.  
306. CLOSE 1
307.  
308. icon# = 1
309. icons = i
310.  
311. END SUB
312.  
313. SUB GetLabelValue (lblfile$, lbl$, v$, n) '##################################
314.  
315. v$ = "": n = FREEFILE: OPEN lblfile$ FOR INPUT AS #n
316. DO UNTIL EOF(n)
317.     LINE INPUT #n, dta$: dta$ = RTRIM$(LTRIM$(dta$))
318.     IF LEFT$(dta$, 1) = "'" THEN dta$ = ""
319.     p = INSTR(dta$, "=")
320.     IF p THEN
321.         l$ = RTRIM$(LEFT$(dta$, p - 1))
322.         IF LCASE$(l$) = LCASE$(lbl$) THEN
323.             v$ = LTRIM$(RIGHT$(dta$, LEN(dta$) - p))
324.             EXIT DO
325.         END IF
326.     END IF
327. LOOP: CLOSE #n
328. n = VAL(v$)
329. END SUB
330.  
331. SUB LoadAnimationFrames (i) '#########################################################
332.  
333. ''CLS: PRINT IconName$(i): END
334. FOR p = LEN(IconName$(i)) TO 1 STEP -1
335.     IF MID$(IconName$(i), p, 1) = "\" THEN EXIT FOR
336. NEXT
337. path$ = LEFT$(IconName$(i), p - 1)
338. '--------------------------------------------------------------
339. FOR p = LEN(path$) TO 1 STEP -1
340.     IF MID$(path$, p, 1) = "\" THEN EXIT FOR
341. NEXT
342. folder$ = RIGHT$(path$, LEN(path$) - p)
343. '---------------------------------------------------------------
344. '' CLS: PRINT folder$; "<": END
345.  
346. _TITLE "Animation : " + folder$
347.  
348. ''path$ = StartPath$ + "\" + Catagory$(Cat#) + "\" + folder$(i)
349. tf$ = "~~animates.tmp"
350. q$ = CHR$(34)
351. cmd$ = "dir " + q$ + path$ + q$ + " /b >" + tf$
352.  
353. SHELL _HIDE cmd$
354. '' SHELL "notepad.exe " + tf$: END
355.  
356. CheckForFile DelayFile$, found
357. 'AniDelay is a percent of CountPerSec
358.  
359. IF found THEN
360.     OPEN DelayFile$ FOR INPUT AS #1
361.     INPUT #1, AniDelay
362.     INPUT #1, newdelay
363.     CLOSE 1
364. ELSE
365.     AniDelay = 1
366. END IF
367.  
368. COLOR 7, 0
369.  
370. OPEN tf$ FOR INPUT AS #1
371.  
372. i = 0
373.  
374. DO UNTIL EOF(1)
375.  
376.     LINE INPUT #1, f$
377.  
378.     IF LEFT$(LCASE$(f$), 4) = "$tn." THEN
379.         f$ = "" 'this is a thumbnail image
380.     END IF
381.  
382.     ft$ = LCASE$(RIGHT$(f$, 4))
383.  
384.     SELECT CASE ft$
385.  
386.         CASE ".jpg", ".png", ".bmp"
387.             i = i + 1
388.             FrameName$(i) = path$ + "\" + f$
389.             'CLS :
390.             PRINT i; FrameName$(i); "<"
391.             IF i = MaxFrames THEN EXIT DO
392.             'EXIT DO
393.  
394.     END SELECT
395.  
396. LOOP
397.  
398. CLOSE 1
399.  
400. frames = i
401.  
402. ScrnWidth = 600
403. ScrnHeight = 500
404. ScreenMode = 32
405.  
406. SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, ScreenMode)
407.  
408. img$ = FrameName$(1)
409. image& = _LOADIMAGE(img$)
410. w% = _WIDTH(image&)
411. h% = _HEIGHT(image&)
412. ScrnWidth = w%
413. ScrnHeight = h% + 15
414. SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, ScreenMode)
415. direction$ = "F"
416.  
417. DO
418.     PlayTheAnimation k$
419.     IF k$ = CHR$(8) THEN EXIT DO 'back to main menu
420.     IF k$ = CHR$(27) THEN EXIT DO
421. LOOP
422.  
423. CALL savedelay(AniDelay)
424.  
425. IF k$ = CHR$(27) THEN CLS: SYSTEM
426.  
427. END SUB
428.  
429. SUB CheckForFile (f$, found) '##############################################
430. found = 0
431. IF _FILEEXISTS(f$) THEN found = 1
432. END SUB
433.  
434. SUB PlayTheAnimation (k$) '################################################
435. ForStart = 1
436. ForStop = frames
437. ForStep = 1
438.  
439. IF direction$ = "R" THEN
440.     ForStart = frames
441.     ForStop = 1
442.     ForStep = -1
443. END IF
444.  
445. FOR i = ForStart TO ForStop STEP ForStep
446.  
447.     img$ = FrameName$(i)
448.     image& = _LOADIMAGE(img$)
449.     _PUTIMAGE (0, 0), image&
450.  
451.     ShowDelayBar
452.  
453.     DO
454.         k$ = UCASE$(INKEY$)
455.         SELECT CASE k$
456.             CASE CHR$(27)
457.                 ' Update delay file.
458.                 CALL savedelay(AniDelay)
459.                 EXIT SUB
460.             CASE CHR$(8)
461.                 ' Update delay file.
462.                 CALL savedelay(AniDelay)
463.                 EXIT SUB 'back to main menu
464.             CASE "-", "_"
465.                 IF newdelay < MaxSlowDelay THEN newdelay = newdelay + 1
466.                 IF AniDelay < MaxSlowDelay THEN
467.                     AniDelay = AniDelay + 1
468.                 END IF
469.             CASE "+", "="
470.                 AniDelay = AniDelay - 1
471.                 IF AniDelay < 1 THEN AniDelay = 1
472.                 IF newdelay > 0 THEN newdelay = newdelay - 1
473.             CASE CHR$(9) 'change playback direction
474.                 IF direction$ = "F" THEN
475.                     direction$ = "R"
476.                 ELSE
477.                     direction$ = "F"
478.                 END IF
479.                 EXIT DO
480.         END SELECT
481.         ''PRINT newdelay
482.         _DELAY newdelay / 5000: EXIT DO
483.     LOOP
484.  
485.     IF k$ = CHR$(9) THEN EXIT FOR
486.  
487.     per = i / frames
488.     ln = ScrnWidth * per
489.  
490.     x = 0
491.     y = ScrnHeight - 13
492.     h = 5
493.     fill = 1
494.  
495.     w = ScrnWidth
496.     Rd = 0 ' 255
497.     Gr = 0 ' 255
498.     Bl = 0 '' 255
499.     'black out the progress bar
500.     DrawBox x, y, w, h, Rd, Gr, Bl, fill
501.  
502.     w = ln
503.     Rd = 255
504.     Gr = 255
505.     Bl = 255
506.     'draw the progress bar
507.     DrawBox x, y, w, h, Rd, Gr, Bl, fill
508.  
509. NEXT
510.  
511. END SUB
512.  
513. SUB ShowDelayBar '##########################################################
514.  
515. x = 0
516. y = ScrnHeight - 5
517. h = 5
518. fill = 1
519.  
520. w = ScrnWidth
521. Rd = 0 ' 255
522. Gr = 0 ' 255
523. Bl = 0 '' 255
524. 'black out the delay value bar
525. DrawBox x, y, w, h, Rd, Gr, Bl, fill
526.  
527. per = (AniDelay / MaxSlowDelay) * 100
528. IF per >= 0 THEN 'fast
529.     Rd = 0: Gr = 255: Bl = 0
530. END IF
531. IF per >= 50 THEN 'medium
532.     Rd = 255: Gr = 255: Bl = 0
533. END IF
534. IF per >= 75 THEN 'slow
535.     Rd = 255: Gr = 0: Bl = 0
536. END IF
537.  
538. per = per / 100
539. w = ScrnWidth * per
540. 'draw the delay value bar
541. DrawBox x, y, w, h, Rd, Gr, Bl, fill
542.  
543. END SUB
544.  
545. SUB savedelay (AniDelay)
546. OPEN DelayFile$ FOR OUTPUT AS #1
547. WRITE #1, AniDelay
548. WRITE #1, newdelay
549. CLOSE 1
550.  
551. END SUB

Note: Anyone who downloads Paul's code with my revisons here will need to download Paul's original ZIO file to get the ini and folders with animation jpegs.

Pete

[mynameispaul]

OK...
First, the files 'CountPerSecUpdt.bas' and 'settings.ini' should have been supplied at the beginning.
The settings.ini file is a kinda of global settings file to be used by multiple programs. In this case the value for 'CountPerSec' is used by the animation program so that theoretically the animations should play at about the same speed even when run on a different pc with a different processing speed. This is done by running the CountPerSecUpdt program which basically just counts up as much as it can for 1 second (multiple times). Then the animation program get a specified percent of that Count Per Second value. Will count higher on a faster pc but count lower on a slower pc, but will always the same percent value for the program. Make sense?? (hopefully)
So anyways, copy the CountPerSecUpdt.bas to your QB64 folder and run it. Let it run a few times so it can get an average count per second. Then press any key to exit the program. It will save the average count per second to the settings.ini file.

Second, run the animation program (I have uploaded an updated version, using the _CWD$ command).

* each animation folder gets its own delay file after you run the animation and then go back to the selection screen.

[Pete]

Ah, some files were missing. Well Paul, what do you think about switching to _delay? From my understanding, it is a timer function, so it is independent of CPU speeds and should be the same on any system. If it works for you, that would simplify the app, which could be run with just the original files included in the original post.

Pete

[mynameispaul]

I will give it a try and report back.

[mynameispaul]

OK, updated Animation2.bas with option to use the old delay process (using CountPerSec) or using the _DELAY function.
Add the following lines of code to Animation2.ini

'If you want the program to use the CountPerSec field value from settings.ini
'  set the following field value to 1
'Else
'  set it to 0 (program will use the _DELAY function)
'  program acts a little different when using this option
UseCountPerSec = 1

I personally prefer to the CountPerSec process. the _Delay function is ok. But what I don't like about it is that the _DELAY function basically pauses the entire program..while its paused the program from runnin, the program is not acting on any input from the user. Does not look like it to me anyways. I use the delay loop (which uses the CountPerSec) so that while the program is 'paused' showing a frame its also monitoring for input from the user.
So anyway, I've modified the program so its up to the user to decide which way they prefer.
...or modify the program however you want...doesn't really matter to me.

[bplus]

Pete's code worked, is there only one animation? (I haven't tried latest.)

[mynameispaul]

If his works then use his.

[bplus]

The reason I ask if there was another animation is that I see stuff being setup for cat. So I was expecting something with a cat. Maybe Pete snuck that in?

[Pete]

Mark: I presume Cat is short for category. Paul put that in there.

Paul: I agree that programs are better if they always keep the flow going. I had a clock in all my office software, and all user input passed through the clock sub, without delays. Timers were fluid. Now for this application the delays are so minimal I really don't think it matters, but with some adjustments, the timer function can be use. I included two in this rendition, along with the _delay. To anyone who tries it, just change the remarks to the one you want to use.

I also changed the name of one sub, because it was a typo; so LaodIcons is now properly named LoadIcons. I could have left it alone... but then the twitch wouldn't have abated without considerable doses of several psychogenic medications.

Oh, I also added _EXIT so a user can click the "X" and still save the last delay.

What I need to do next is study and learn some stuff from the animation code to make a photo viewer app inside an app. Not bad for a SCREEN 0 junkie like me!

Pete

Code: QB64: [Select]

1. '/title Animations (version 2) using thumbs
2. '/type utility
3. '========================================================
4. ' Controls while playing animation
5. '..................................................
6. '          - = decrease animation speed
7. '         + = increase animation speed
8. '       TAB = change playback direction (forward/reverse)
9. ' Backspace = back to selection screen
10. '========================================================
11.  
12. _TITLE "Animations (version 2) using thumbs"
13.  
14. DIM SHARED UserWarned, newdelay%, newdelay!, t#, path$, DelayFile$
15. DIM SHARED MenuIconsPath$, reload, BGrd, BGgr, BGbl
16. path$ = _CWD$
17. DelayFile$ = path$ + "\delay.dat"
18. MenuIconsPath$ = path$ + "\AniFrames"
19. wallpaperPath$ = path$ + "\AniPlayer2wallpapers\"
20. DIM SHARED Catagory$(5), catagories, Cat#
21. DIM SHARED catX(10), catY(10), catW(10), catH(10)
22. GetCatagories
23. DIM SHARED iconX(50), iconY(50), iconW(50), iconH(50), icon#, icons
24. DIM SHARED IconName$(50)
25. DIM SHARED ScrnWidth: ScrnWidth = 600
26. DIM SHARED ScrnHeight: ScrnHeight = 300
27. DIM SHARED MaxFrames: MaxFrames = 5000
28. DIM SHARED FrameName$(MaxFrames), frames, direction$, AniDelay
29.  
30. ' value of 'MaxSlowDelay' is the largest value allowed to slow down
31. ' an animation. Could really be any number wanted.
32. DIM SHARED MaxSlowDelay: MaxSlowDelay = 200
33.  
34. DIM SHARED CountPerSec
35. GetLabelValue "Animation2.ini", "CountPerSec", "", CountPerSec
36.  
37. configfile$ = "Animation2.ini"
38. GetLabelValue configfile$, "BGrd", "", BGrd
39. GetLabelValue configfile$, "BGgr", "", BGgr
40. GetLabelValue configfile$, "BGbl", "", BGbl
41.  
42. SetTheScreen:
43.  
44. GetLabelValue configfile$, "ScrnWidth", "", ScrnWidth
45. GetLabelValue configfile$, "ScrnHeight", "", ScrnHeight
46.  
47. DIM SHARED wallpaper$
48. GetLabelValue configfile$, "wallpaper", wallpaper$, n
49. wallpaper$ = wallpaperPath$ + wallpaper$
50. CheckForFile wallpaper$, found
51. IF found = 0 THEN
52.     IF UserWarned = 0 THEN
53.         CLS
54.         PRINT "warning!   following wallpaper image not found..."
55.         PRINT wallpaper$
56.         PRINT "press any key.."
57.         DO UNTIL INKEY$ <> "": LOOP
58.         UserWarned = 1
59.     END IF
60.     wallpaper$ = ""
61.     GetLabelValue configfile$, "ScrnWidth", "", ScrnWidth
62.     GetLabelValue configfile$, "ScrnHeight", "", ScrnHeight
63.     SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, 32)
64. ELSE
65.     SCREEN _NEWIMAGE(150, 150, 32)
66.     image& = _LOADIMAGE(wallpaper$)
67.     imgW% = _WIDTH(image&) '  get image width
68.     imgH% = _HEIGHT(image&) ' get image height
69.     ScrnWidth = imgW%
70.     ScrnHeight = imgH%
71. END IF
72.  
73. CLS
74.  
75. IF wallpaper$ <> "" THEN
76.     SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, 32)
77.     _PUTIMAGE (0, 0), image&
78. ELSE
79.     BGrd = 10
80.     BGgr = 100
81.     BGbl = 20
82.     fill = 1
83.     DrawBox 0, 0, ScrnWidth, ScrnHeight, BGrd, BGgr, BGbl, fill
84. END IF
85.  
86. ShowCatagories
87. LoadIcons
88. DrawIconBoxes
89.  
90. reload = 0
91.  
92. DO
93.     DO WHILE _MOUSEINPUT ' get latest mouse information
94.     LOOP
95.  
96.     x% = _MOUSEX: mx = x%
97.     y% = _MOUSEY: my = y%
98.     LeftClick% = _MOUSEBUTTON(1) '                 retrieve left button status
99.     RightClick% = _MOUSEBUTTON(2) '                retrieve right button status
100.  
101.     IF LeftClick% = -1 THEN
102.         IF clkd = 0 THEN
103.             TestClickPos mx, my
104.             IF reload THEN GOTO SetTheScreen
105.             clkd = 1
106.         END IF
107.     ELSE
108.         clkd = 0
109.     END IF
110.  
111.     k$ = UCASE$(INKEY$)
112.  
113.     SELECT CASE k$
114.         CASE CHR$(27): CLS: SYSTEM
115.     END SELECT
116.  
117. LOOP
118.  
119. SUB TestClickPos (mx, my) '################################################
120.  
121. '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
122. '-- clicked on a icon?
123.  
124. FOR i = 1 TO icons
125.  
126.     x = iconX(i)
127.     y = iconY(i)
128.     w = iconW(i)
129.     h = iconH(i)
130.  
131.     IF my >= y AND my <= y + h - 1 THEN
132.         IF mx >= x AND mx <= x + w - 1 THEN
133.             IF icon# = i THEN
134.                 LoadAnimationFrames i
135.                 reload = 1
136.                 EXIT SUB
137.             END IF
138.             icon# = i
139.             DrawIconBoxes
140.             EXIT SUB
141.         END IF
142.     END IF
143.  
144. NEXT
145.  
146. '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
147. '--clicked on a catagory label ?
148.  
149. FOR i = 1 TO catagories
150.  
151.     x = catX(i)
152.     y = catY(i)
153.     w = catW(i)
154.     h = catH(i)
155.  
156.     IF my >= y AND my <= y + h - 1 THEN
157.         IF mx >= x AND mx <= x + w - 1 THEN
158.             IF Cat# <> i THEN
159.                 Cat# = i
160.                 reload = 1
161.                 EXIT SUB
162.                 ShowCatagories
163.             END IF
164.         END IF
165.     END IF
166.  
167. NEXT
168. END SUB
169.  
170. SUB DrawIconBoxes '########################################################
171.  
172. FOR i = 1 TO icons
173.  
174.     x = iconX(i)
175.     y = iconY(i)
176.     w = iconW(i)
177.     h = iconH(i)
178.  
179.     IF i = icon# THEN
180.         clr& = _RGB32(0, 200, 255)
181.     ELSE
182.         clr& = _RGB32(BGrd, BGgr, BGbl)
183.     END IF
184.  
185.     LINE (x - 2, y - 2)-(x + w + 1, y + h + 1), clr&, B
186.     LINE (x - 3, y - 3)-(x + w + 2, y + h + 2), clr&, B
187.  
188. NEXT
189.  
190. END SUB
191.  
192. SUB DrawBox (x, y, w, h, Rd, Gr, Bl, fill) '###########################################
193. clr& = _RGB32(Rd, Gr, Bl)
194. IF fill THEN
195.     LINE (x, y)-(x + w - 1, y + h - 1), clr&, BF
196. ELSE
197.     LINE (x, y)-(x + w - 1, y + h - 1), clr&, B
198. END IF
199. END SUB
200.  
201. SUB ShowCatagories '######################################################
202.  
203. x = 10
204. y = 10
205. h = 40
206.  
207. w = ScrnWidth / catagories
208.  
209. FOR c = 1 TO catagories
210.     img$ = MenuIconsPath$ + "\" + Catagory$(c) + ".png"
211.     image& = _LOADIMAGE(img$)
212.     w% = _WIDTH(image&) '                                get image width
213.     h% = _HEIGHT(image&) '                              get image height
214.     clr = 0
215.     IF c = Cat# THEN clr = 255
216.     DrawBox x - 3, y - 3, w% + 6, h% + 6, clr, clr, clr, 1
217.  
218.     catX(c) = x
219.     catY(c) = y
220.     catW(c) = w%
221.     catH(c) = h%
222.  
223.     _PUTIMAGE (x, y), image&
224.  
225.     x = x + w% + 10
226. NEXT
227.  
228. END SUB
229.  
230. SUB GetCatagories '######################################################
231.  
232. tf$ = "~cats.tmp"
233. q$ = CHR$(34)
234. cmd$ = "dir " + q$ + MenuIconsPath$ + q$ + " /b >" + tf$
235.  
236. SHELL _HIDE cmd$
237. ''SHELL _DONTWAIT "notepad ~cats.tmp": END
238. OPEN tf$ FOR INPUT AS #1
239.  
240. DO UNTIL EOF(1)
241.  
242.     LINE INPUT #1, cat$
243.  
244.     IF INSTR(cat$, ".") = 0 THEN
245.         i = i + 1
246.         PRINT i; cat$
247.         Catagory$(i) = cat$
248.     END IF
249.  
250. LOOP
251.  
252. CLOSE 1
253.  
254. catagories = i
255. Cat# = 1
256.  
257. END SUB
258.  
259. SUB LoadIcons '##########################################################
260.  
261. tf$ = "~SubCat.tmp"
262. path$ = MenuIconsPath$ + "\" + Catagory$(Cat#) + "\"
263. q$ = CHR$(34)
264. cmd$ = "dir " + q$ + path$ + "*" + q$ + " /b >" + tf$
265. SHELL _HIDE cmd$
266. ''SHELL "notepad.exe " + tf$: END
267.  
268. DIM image&
269. IconSqr = 50
270. y = 60
271. x1 = 5
272. x = x1
273.  
274. OPEN tf$ FOR INPUT AS #1
275.  
276. DO UNTIL EOF(1)
277.  
278.     LINE INPUT #1, fldr$
279.  
280.     IF 1 = 1 THEN
281.  
282.         img$ = path$ + fldr$ + "\$tn.jpg"
283.         ''PRINT img$; "<": END
284.         image& = _LOADIMAGE(img$)
285.         _PUTIMAGE (x, y), image&
286.         w% = _WIDTH(image&) '                                get image width
287.         h% = _HEIGHT(image&) '                              get image height
288.         IF h% > tallest THEN tallest = h%
289.         i = i + 1
290.         iconX(i) = x
291.         iconY(i) = y
292.         iconW(i) = w%
293.         iconH(i) = h%
294.         IconName$(i) = LEFT$(img$, LEN(img$) - 4) 'trim off .XXX
295.  
296.         x = x + w% + 10
297.         IF x + IconSqr >= ScrnWidth THEN
298.             y = y + tallest + 10
299.             x = x1
300.             tallest = 0
301.         END IF
302.     END IF
303.  
304. LOOP
305.  
306. CLOSE 1
307.  
308. icon# = 1
309. icons = i
310.  
311. END SUB
312.  
313. SUB GetLabelValue (lblfile$, lbl$, v$, n) '##################################
314.  
315. v$ = "": n = FREEFILE: OPEN lblfile$ FOR INPUT AS #n
316. DO UNTIL EOF(n)
317.     LINE INPUT #n, dta$: dta$ = RTRIM$(LTRIM$(dta$))
318.     IF LEFT$(dta$, 1) = "'" THEN dta$ = ""
319.     p = INSTR(dta$, "=")
320.     IF p THEN
321.         l$ = RTRIM$(LEFT$(dta$, p - 1))
322.         IF LCASE$(l$) = LCASE$(lbl$) THEN
323.             v$ = LTRIM$(RIGHT$(dta$, LEN(dta$) - p))
324.             EXIT DO
325.         END IF
326.     END IF
327. LOOP: CLOSE #n
328. n = VAL(v$)
329. END SUB
330.  
331. SUB LoadAnimationFrames (i) '#########################################################
332. ''CLS: PRINT IconName$(i): END
333. FOR p = LEN(IconName$(i)) TO 1 STEP -1
334.     IF MID$(IconName$(i), p, 1) = "\" THEN EXIT FOR
335. NEXT
336. path$ = LEFT$(IconName$(i), p - 1)
337. '--------------------------------------------------------------
338. FOR p = LEN(path$) TO 1 STEP -1
339.     IF MID$(path$, p, 1) = "\" THEN EXIT FOR
340. NEXT
341. folder$ = RIGHT$(path$, LEN(path$) - p)
342. '---------------------------------------------------------------
343. '' CLS: PRINT folder$; "<": END
344.  
345. _TITLE "Animation : " + folder$
346.  
347. ''path$ = StartPath$ + "\" + Catagory$(Cat#) + "\" + folder$(i)
348. tf$ = "~~animates.tmp"
349. q$ = CHR$(34)
350. cmd$ = "dir " + q$ + path$ + q$ + " /b >" + tf$
351.  
352. SHELL _HIDE cmd$
353. '' SHELL "notepad.exe " + tf$: END
354.  
355. CheckForFile DelayFile$, found
356. 'AniDelay is a percent of CountPerSec
357.  
358. IF found THEN
359.     OPEN DelayFile$ FOR INPUT AS #1
360.     INPUT #1, AniDelay
361.     INPUT #1, newdelay%
362.     newdelay! = newdelay% / 1000
363.     CLOSE 1
364. ELSE
365.     AniDelay = 1
366. END IF
367.  
368. COLOR 7, 0
369.  
370. OPEN tf$ FOR INPUT AS #1
371.  
372. i = 0
373.  
374. DO UNTIL EOF(1)
375.  
376.     LINE INPUT #1, f$
377.  
378.     IF LEFT$(LCASE$(f$), 4) = "$tn." THEN
379.         f$ = "" 'this is a thumbnail image
380.     END IF
381.  
382.     ft$ = LCASE$(RIGHT$(f$, 4))
383.  
384.     SELECT CASE ft$
385.  
386.         CASE ".jpg", ".png", ".bmp"
387.             i = i + 1
388.             FrameName$(i) = path$ + "\" + f$
389.             'CLS :
390.             PRINT i; FrameName$(i); "<"
391.             IF i = MaxFrames THEN EXIT DO
392.             'EXIT DO
393.  
394.     END SELECT
395.  
396. LOOP
397.  
398. CLOSE 1
399.  
400. frames = i
401.  
402. ScrnWidth = 600
403. ScrnHeight = 500
404. ScreenMode = 32
405.  
406. SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, ScreenMode)
407.  
408. img$ = FrameName$(1)
409. image& = _LOADIMAGE(img$)
410. w% = _WIDTH(image&)
411. h% = _HEIGHT(image&)
412. ScrnWidth = w%
413. ScrnHeight = h% + 15
414. SCREEN _NEWIMAGE(ScrnWidth, ScrnHeight, ScreenMode)
415. direction$ = "F"
416.  
417. DO
418.     PlayTheAnimation k$
419.     IF k$ = CHR$(8) THEN EXIT DO 'back to main menu
420.     IF k$ = CHR$(27) THEN EXIT DO
421. LOOP
422.  
423. CALL savedelay(AniDelay)
424.  
425. IF k$ = CHR$(27) THEN CLS: SYSTEM
426.  
427. END SUB
428.  
429. SUB CheckForFile (f$, found) '##############################################
430. found = 0
431. IF _FILEEXISTS(f$) THEN found = 1
432. END SUB
433.  
434. SUB PlayTheAnimation (k$) '################################################
435. ForStart = 1
436. ForStop = frames
437. ForStep = 1
438.  
439. IF direction$ = "R" THEN
440.     ForStart = frames
441.     ForStop = 1
442.     ForStep = -1
443. END IF
444.  
445. FOR i = ForStart TO ForStop STEP ForStep
446.  
447.     img$ = FrameName$(i)
448.     image& = _LOADIMAGE(img$)
449.     _PUTIMAGE (0, 0), image&
450.  
451.     ShowDelayBar
452.     t# = TIMER
453.     DO
454.         quit = _EXIT
455.         IF quit THEN
456.             CALL savedelay(AniDelay)
457.             SYSTEM
458.         END IF
459.  
460.         k$ = INKEY$
461.  
462.         SELECT CASE k$
463.             CASE CHR$(27)
464.                 ' Update delay file.
465.                 CALL savedelay(AniDelay)
466.                 EXIT SUB
467.             CASE CHR$(8)
468.                 ' Update delay file.
469.                 CALL savedelay(AniDelay)
470.                 EXIT SUB 'back to main menu
471.             CASE "-", "_"
472.                 IF newdelay% < MaxSlowDelay THEN
473.                     newdelay% = newdelay% + 1
474.                     newdelay! = newdelay% / 1000
475.                 END IF
476.                 IF AniDelay < MaxSlowDelay THEN
477.                     AniDelay = AniDelay + 1
478.                 END IF
479.             CASE "+", "="
480.                 AniDelay = AniDelay - 1
481.                 IF AniDelay < 1 THEN AniDelay = 1
482.                 IF newdelay% > 0 THEN
483.                     newdelay% = newdelay% - 1
484.                     newdelay! = newdelay% / 1000
485.                 END IF
486.             CASE CHR$(9) 'change playback direction
487.                 IF direction$ = "F" THEN
488.                     direction$ = "R"
489.                 ELSE
490.                     direction$ = "F"
491.                 END IF
492.                 EXIT DO
493.         END SELECT
494.  
495.         ' Three delay options.
496.         ''_DELAY newdelay% / 5000
497.         ''IF ABS(TIMER - t#) > newdelay! THEN EXIT DO ' (Can be Substituted for the call sub below if a midnite delay is not a big deal.)
498.         CALL timerdelay(flag%): IF flag% THEN flag% = 0: EXIT DO
499.     LOOP
500.  
501.     IF k$ = CHR$(9) THEN EXIT FOR
502.  
503.     per = i / frames
504.     ln = ScrnWidth * per
505.  
506.     x = 0
507.     y = ScrnHeight - 13
508.     h = 5
509.     fill = 1
510.  
511.     w = ScrnWidth
512.     Rd = 0 ' 255
513.     Gr = 0 ' 255
514.     Bl = 0 '' 255
515.     'black out the progress bar
516.     DrawBox x, y, w, h, Rd, Gr, Bl, fill
517.  
518.     w = ln
519.     Rd = 255
520.     Gr = 255
521.     Bl = 255
522.     'draw the progress bar
523.     DrawBox x, y, w, h, Rd, Gr, Bl, fill
524.  
525. NEXT
526.  
527. END SUB
528.  
529. SUB ShowDelayBar '##########################################################
530.  
531. x = 0
532. y = ScrnHeight - 5
533. h = 5
534. fill = 1
535.  
536. w = ScrnWidth
537. Rd = 0 ' 255
538. Gr = 0 ' 255
539. Bl = 0 '' 255
540. 'black out the delay value bar
541. DrawBox x, y, w, h, Rd, Gr, Bl, fill
542.  
543. per = (AniDelay / MaxSlowDelay) * 100
544. IF per >= 0 THEN 'fast
545.     Rd = 0: Gr = 255: Bl = 0
546. END IF
547. IF per >= 50 THEN 'medium
548.     Rd = 255: Gr = 255: Bl = 0
549. END IF
550. IF per >= 75 THEN 'slow
551.     Rd = 255: Gr = 0: Bl = 0
552. END IF
553.  
554. per = per / 100
555. w = ScrnWidth * per
556. 'draw the delay value bar
557. DrawBox x, y, w, h, Rd, Gr, Bl, fill
558.  
559. END SUB
560.  
561. SUB savedelay (AniDelay)
562. OPEN DelayFile$ FOR OUTPUT AS #1
563. WRITE #1, AniDelay
564. WRITE #1, newdelay%
565. CLOSE 1
566.  
567. END SUB
568.  
569. SUB timerdelay (flag%)
570. IF TIMER < t# THEN
571.     t# = t# - 86400 'Midnite adjustment
572. ELSE
573.     IF TIMER - t# > newdelay! THEN flag% = -1
574. END IF
575. END SUB

[bplus]

Mark: I presume Cat is short for category. Paul put that in there.

LOL well yes that explains that!

[Pete]

There are some similarities. Take for instance a Cat 5 hurricane. Similar, but everyone knows 5 cats do a lot more damage to your home than a 180 mile an hour wind.

Pete