Videos

[Prithak]

This might be a weird question. But is there anyway I can import videos in qb64? If it is not possible. Then I know how to do it with PNG sequence. But, I just wanted to ask if there is an easier way out of this...

[Dav]

Here a video player I made years ago using MCI commands, which means it's for Windows.  This is a VERY basic use of MCI, you can expand it by declaring types of files when opening the file, and add pause, resume, etc.  Lookup opening types of files with MCI for more info.  I'm not 100% sure I'm using MCI correctly here, but the video played for me at the time so I didn't mess with it anymore.

- Dav
 

Code: QB64: [Select]

1. '=============
2. 'QB64VIDEO.BAS
3. '=============
4. 'Plays a video file in QB64 via MCI commands (WINDOWS ONLY)
5. 'Coded by Dav, forgot what year...
6.  
7. 'NOTE: This demo plays a sample video name davpiano.wmv.
8.  
9. DECLARE DYNAMIC LIBRARY "WINMM"
10.     FUNCTION mciSendStringA% (lpstrCommand AS STRING, lpstrReturnString AS STRING, BYVAL uReturnLength AS INTEGER, BYVAL hwndCallback AS INTEGER)
11.     ' mciSendStringA function plays media files and returns the following:
12.     ' 0 = command sucessful
13.     ' - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
14.     ' lpstrCommand is the MCI command string (and optional flags) to send.
15.     ' lpstrReturnString is a string that holds any return information.
16.     ' uReturnLength is the length of the lpstrReturnString string passed.
17.     ' NOTE: If lpstrCommand given doesn't retun a value then lpstrReturnString
18.     '       can be empty and uReturnLength can be set to 0.
19.     ' hwndCallback contains a callback window handle (only if the Notify flag used in lpstrCommand)
20.     '====================================================================
21.     FUNCTION mciGetErrorStringA% (BYVAL dwError AS INTEGER, lpstrBuffer AS STRING, BYVAL uLength AS INTEGER)
22.     ' mciGetErrorStringA returns error info if the mciSendStringA failed.
23.     ' dwError is the return value from the mciSendString function.
24.     ' lpstrBuffer string holds the error information returned by the function.
25.     ' uLength is the length of the lpstrBuffer string buffer.
26.     '====================================================================
27. END DECLARE
28.  
29. DECLARE CUSTOMTYPE LIBRARY
30.     FUNCTION FindWindow& (BYVAL ClassName AS _OFFSET, WindowName$)
31. END DECLARE
32.  
33.  
34. filename$ = "davpiano.wmv" '<========== My video file to play
35.  
36. IF NOT _FILEEXISTS(filename$) THEN
37.     PRINT filename$ + " " + "not found."
38.     END
39. END IF
40.  
41. handle& = _NEWIMAGE(320, 240, 32) '<===== The x/y size of my video
42. SCREEN handle&
43.  
44. DO UNTIL _SCREENEXISTS: _LIMIT 30: LOOP 'be sure screen exists before using in this way
45.  
46. title$ = "QB64 Video Player - " + filename$
47. _TITLE title$
48.  
49. hwnd& = FindWindow(0, title$ + CHR$(0))
50.  
51. ReturnString$ = SPACE$(255): ErrorString$ = SPACE$(255)
52. a% = mciSendStringA%("open " + filename$ + " style popup", ReturnString$, LEN(ReturnString$), 0)
53.  
54. IF a% THEN
55.     x% = mciGetErrorStringA%(a%, ErrorString$, LEN(ErrorString$))
56.     PRINT ErrorString$
57.     END
58. ELSE
59.     a2% = mciSendStringA%("window " + filename$ + " handle " + STR$(hwnd&), ReturnString$, LEN(ReturnString$), 0)
60.     b% = mciSendStringA%("play " + filename$, "", 0, 0)
61.  
62.     '=== Play video...
63.     DO
64.         _LIMIT 30
65.  
66.         'you can add pause/resume routine here if you want...
67.  
68.     LOOP UNTIL INKEY$ <> ""
69.  
70.     x% = mciSendStringA%("stop " + filename$, "", 0, 0)
71.     x% = mciSendStringA%("close " + filename$, "", 0, 0)
72. END IF
73.  

[Pete]

Dav,

I tried it in Windows 10 and no luck. A .mov failed to initialize MCI and a .wmv gave me the specified device is not open or is not recognized my MCI. My hunch is ypu got this working in Windows 7?

Pete

[Cobalt]

I could get only audio myself, with several variations of the same video, mpg, wmv, avi, ect.
I could get choppy broken video with an uncompressed AVI but that was it. and that was on Vista.
wanted to use this with my battleship game.

[Pete]

I wonder what kind of setup Dav had? Well, this is what I thought might be the case. It would be nice to embed videos in QB64 apps.

Pete

[SMcNeill]

I could get only audio myself, with several variations of the same video, mpg, wmv, avi, ect.
I could get choppy broken video with an uncompressed AVI but that was it. and that was on Vista.
wanted to use this with my battleship game.

When I had those type issues with Vista, it was usually from hardware acceleration acting up.

Disable hardware acceleration. Open your computer's "Control Panel" and then click "Display." Select the "Settings" tab, click on "Advanced" and then click "Troubleshoot." Drag the hardware acceleration slider all the way to the left. This procedure can help reduce the strain on your processor, which can lead to choppy videos.

Give that a try and see if it helps.