JSON Reader

[Ashish]

Hello everyone!
I have coded a JSON reader. It can read a JSON string and it supports nested list, nested JSON objs and the mix of both
JSON obj and list.

Here is the code which contain JSON reader function -

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3. _Source _Console
4. Dim test$, l$
5.  
6. Open "test.json" For Binary As #1
7. test$ = Space$(LOF(1))
8. Get #1, , test$
9. Close #1
10.  
11. 'label$ is case-sensitive
12. Do
13.     Input "label : ", l$ 'try .server-name or .roles.special.devs or roles.common.regulars.[1]
14.     Print json$(test$, l$)
15. Loop
16.  
17. 'JSON Reader in QB64
18. 'By AshishKingdom
19. Function json$ (json_data_0$, l$)
20.     If Len(json_data_0$) = 0 Or Len(l$) = 0 Then Exit Function
21.     If _Trim$(l$) = "." Then json$ = json_data_0$: Exit Function
22.  
23.     Dim As Long startPos, endPos, label_pos1, label_pos2, num_of_br
24.     Dim As Long f0, f1, f2, f3, f4, f5, f6, list_obj_pos
25.     Dim As _Byte value_type, in_quote '1=object, 2=array, 0=string or number
26.     Dim As String sep_type, curr_label, ca, label, json_data, tmp_str
27.     Dim As Long list_pos1, list_pos2, list_index
28.  
29.     label$ = l$
30.     json_data$ = json_data_0$
31.  
32.     json_list_sec:
33.  
34.     label_pos1 = InStr(label$, ".")
35.     If label_pos1 = 0 Then json$ = json_data$: Exit Function
36.     label_pos2 = InStr(label_pos1 + 1, label$, ".")
37.  
38.  
39.     list_pos1 = InStr(label$, "[")
40.     If list_pos1 Then
41.         If label_pos2 = 0 Then
42.             list_pos2 = InStr(list_pos1 + 1, label$, "]")
43.  
44.             If list_pos1 < label_pos1 Then Print "json_parser_error: '.' inside [] ": Exit Function
45.             If list_pos2 = 0 Then Print "json_parser_error: missing ] in label": Exit Function
46.  
47.             list_index = Val(Mid$(label$, list_pos1 + 1, list_pos2 - list_pos1 - 1))
48.             tmp_str = _Trim$(json_list(json_data$, list_index))
49.             json_data$ = tmp_str
50.             label$ = Right$(label$, Len(label$) - list_pos2)
51.             GoTo json_list_sec 'for nested list (if present), it will keep on parsing it
52.         Else
53.             If list_pos1 > label_pos1 And list_pos1 < label_pos2 Then
54.                 'list index present
55.                 list_pos2 = InStr(list_pos1 + 1, label$, "]")
56.                 If list_pos2 = 0 Then Print "json_parser_error: missing ] in label": Exit Function
57.                 If list_pos2 > label_pos2 Then Print "json_parser_error: '.' inside [] ": Exit Function
58.                 list_index = Val(Mid$(label$, list_pos1 + 1, list_pos2 - list_pos1 - 1))
59.                 tmp_str = _Trim$(json_list(json_data$, list_index))
60.                 json_data$ = tmp_str
61.                 label$ = Right$(label$, Len(label$) - list_pos2)
62.                 GoTo json_list_sec 'for nested list (if present), it will keep on parsing it
63.             End If
64.         End If
65.     End If
66.  
67.     startPos = getAbsCharPos(json_data$, "{", 1)
68.     If startPos = 0 Then json$ = json_data$: Exit Function 'its not a json object then
69.     list_obj_pos = getAbsCharPos(json_data$, "[", 1)
70.     If startPos > list_obj_pos And list_obj_pos <> 0 Then Exit Function 'its probably a list
71.     endPos = charFind(json_data$, "}", 1, 1, 1)
72.     f0 = startPos + 1
73.     While 1
74.  
75.         f2 = getAbsCharPos(json_data$, ":", f0)
76.  
77.         If f2 = 0 Then Exit Function
78.         f1 = getAbsCharPos(json_data$, ",", f2 + 1)
79.  
80.         f5 = getAbsCharPos(json_data$, "[", f0)
81.         f6 = getAbsCharPos(json_data$, "{", f0)
82.         sep_type = ""
83.         If f5 = 0 And f6 = 0 Then
84.             f3 = 0
85.         ElseIf f5 = 0 And f6 > 0 Then
86.             f3 = f6
87.             sep_type = "}"
88.         ElseIf f6 = 0 And f5 > 0 Then
89.             f3 = f5
90.             sep_type = "]"
91.         ElseIf f5 < f6 And f5 <> 0 Then
92.             f3 = f5
93.             sep_type = "]"
94.         ElseIf f6 < f5 And f6 <> 0 Then
95.             f3 = f6
96.             sep_type = "}"
97.         End If
98.  
99.         If f3 = 0 Then
100.             value_type = 0
101.         Else
102.             'check if ',' was before [ or {
103.  
104.             If f1 < f3 And f1 <> 0 Then
105.                 ' comma present before [ or {
106.                 value_type = 0
107.             Else
108.                 'comma present after.. so it may be inside {}/[] or outside of it.
109.                 'finding end of position of json_obj/list present
110.                 num_of_br = 1
111.                 f4 = f3
112.                 in_quote = 1
113.                 While num_of_br > 0
114.                     f4 = f4 + 1
115.                     If f4 > endPos Then Print "json_parser_error: missing "; sep_type: Exit Function
116.  
117.                     ca = Mid$(json_data$, f4, 1)
118.                     If ca = Chr$(34) Then in_quote = in_quote * -1
119.                     If in_quote = 1 Then
120.                         If ca = "{" Or ca = "[" Then num_of_br = num_of_br + 1
121.                         If ca = "}" Or ca = "]" Then num_of_br = num_of_br - 1
122.                     End If
123.                 Wend
124.                 If sep_type = "}" Then value_type = 1 Else value_type = 2
125.             End If
126.         End If
127.  
128.  
129.         If f2 > f1 And f1 <> 0 Then
130.             Print "json_parser_error: ',' before ':'"
131.             Exit Function
132.         End If
133.         'Print value_type, f3, f4
134.         'Sleep
135.         If value_type = 0 Then
136.  
137.             If getData(Mid$(json_data$, f0, f2 - 1 - f0)) = Right$(label$, Len(label$) - 1) Then
138.                 If f1 = 0 Then
139.                     json$ = getData(Mid$(json_data$, f2 + 1, endPos - f2 - 1))
140.                 Else
141.                     json$ = getData(Mid$(json_data$, f2 + 1, f1 - f2 - 1))
142.                 End If
143.                 Exit Function
144.             Else
145.                 If f1 = 0 Then Exit Function Else f0 = f1 + 1
146.             End If
147.         Else
148.             If label_pos2 = 0 Then
149.                 curr_label = Right$(label$, Len(label$) - 1)
150.             Else
151.                 curr_label = Mid$(label$, label_pos1 + 1, label_pos2 - label_pos1 - 1)
152.             End If
153.             'Print curr_label, getData(Mid$(json_data$, f0, f2 - 1 - f0))
154.             'Sleep
155.             If getData(Mid$(json_data$, f0, f2 - 1 - f0)) = curr_label Then
156.                 If label_pos2 = 0 Then
157.                     json$ = Mid$(json_data$, f3, f4 - f3 + 1)
158.                     Exit Function
159.                 Else
160.                     'Print Mid$(json_data$, f3, f4 - f3 + 1)
161.                     'Print Right$(label$, Len(label$) - label_pos2 + 1)
162.                     json$ = json$(Mid$(json_data$, f3, f4 - f3 + 1), Right$(label$, Len(label$) - label_pos2 + 1))
163.                     Exit Function
164.                 End If
165.             Else
166.                 f1 = getAbsCharPos(json_data$, ",", f4 + 1)
167.                 If f1 = 0 Then f0 = f4 + 1 Else f0 = f1 + 1
168.                 'Print "hha ", f1, f0
169.             End If
170.         End If
171.     Wend
172. End Function
173.  
174. Function json_list$ (list_data$, index As _Unsigned Long)
175.     If list_data$ = "" Then Exit Function
176.  
177.     Dim As Long startPos, endPos, curr_index, json_obj_pos, value_type
178.     Dim As Long f0, f1, f2, f3, f4, f5, f6, i
179.     Dim As Long num_of_br
180.     Dim As String ca, sep_type
181.     Dim As _Byte element_present, in_quote
182.  
183.     startPos = InStr(list_data$, "[")
184.     endPos = charFind(list_data$, "]", 0, 1, 1)
185.     If startPos = 0 Then json_list$ = list_data$: Exit Function 'its not a list
186.     json_obj_pos = getAbsCharPos(list_data$, "{", 1)
187.     If startPos > json_obj_pos And json_obj_pos <> 0 Then Exit Function 'probably its a json object
188.  
189.     f0 = startPos + 1
190.     curr_index = 0
191.     While 1
192.         f1 = getAbsCharPos(list_data$, ",", f0)
193.         '  f2 = getAbsCharPos(list_data$, "[", f0)
194.         f5 = getAbsCharPos(list_data$, "[", f0)
195.         f6 = getAbsCharPos(list_data$, "{", f0)
196.         sep_type = ""
197.         If f5 = 0 And f6 = 0 Then
198.             f3 = 0
199.         ElseIf f5 = 0 And f6 > 0 Then
200.             f3 = f6
201.             sep_type = "}"
202.         ElseIf f6 = 0 And f5 > 0 Then
203.             f3 = f5
204.             sep_type = "]"
205.         ElseIf f5 < f6 And f5 <> 0 Then
206.             f3 = f5
207.             sep_type = "]"
208.         ElseIf f6 < f5 And f6 <> 0 Then
209.             f3 = f6
210.             sep_type = "}"
211.         End If
212.  
213.         If f3 = 0 Then
214.             value_type = 0
215.         Else
216.             'check if ',' was before [ or {
217.  
218.             If f1 < f3 And f1 <> 0 Then
219.                 ' comma present before [ or {
220.                 value_type = 0
221.             Else
222.                 'comma present after.. so it may be inside {}/[] or outside of it.
223.                 'finding end of position of json_obj/list present
224.                 num_of_br = 1
225.                 f4 = f3
226.                 in_quote = 1
227.                 While num_of_br > 0
228.                     f4 = f4 + 1
229.                     If f4 > endPos Then Print "json_parser_error: missing "; sep_type: Exit Function
230.  
231.                     ca = Mid$(list_data$, f4, 1)
232.                     If ca = Chr$(34) Then in_quote = in_quote * -1
233.                     If in_quote = 1 Then
234.                         If ca = "{" Or ca = "[" Then num_of_br = num_of_br + 1
235.                         If ca = "}" Or ca = "]" Then num_of_br = num_of_br - 1
236.                     End If
237.                 Wend
238.                 f1 = f4 + 1
239.                 If sep_type = "}" Then value_type = 1 Else value_type = 2
240.             End If
241.         End If
242.         'Print f0, f1, ca, curr_index, index
243.  
244.         If f1 = 0 Then
245.             'check if there's any value here
246.             If curr_index = index Then
247.                 element_present = 0
248.  
249.                 For i = f0 To endPos - 1
250.                     If Asc(Mid$(list_data$, i, 1)) <> 32 Then element_present = 1
251.                 Next
252.                 If element_present = 1 Then
253.                     If value_type = 0 Then
254.                         json_list$ = getData(Mid$(list_data$, f0, endPos - f0))
255.                     Else
256.                         json_list$ = Mid$(list_data$, f0, endPos - f0 + 1)
257.                     End If
258.                 End If
259.             End If
260.             Exit Function
261.         Else
262.             If curr_index = index Then
263.                 If value_type = 0 Then
264.                     json_list$ = getData(Mid$(list_data$, f0, f1 - f0))
265.                 Else
266.                     json_list$ = Mid$(list_data$, f0, f1 - f0)
267.                 End If
268.                 Exit Function
269.             Else
270.                 f0 = f1 + 1
271.             End If
272.         End If
273.         curr_index = curr_index + 1
274.     Wend
275. End Function
276.  
277. Function getAbsCharPos~& (main_str As String, char As String, s As _Unsigned Long) 'give position of char which is outside of quotes
278.     Dim As _Unsigned Long i, qp
279.     Dim ca$, q$
280.  
281.     qp = 1
282.     For i = s To Len(main_str)
283.         ca$ = Mid$(main_str, i, 1)
284.         If ca$ = Chr$(34) Then q$ = ca$: qp = qp * -1
285.         If ca$ = char And qp = 1 Then
286.             getAbsCharPos~& = i
287.             Exit Function
288.         End If
289.     Next
290. End Function
291. Function getData$ (main_str As String) 'quote_type=1("), 2=(')
292.     Dim quote$, i As _Unsigned Long, j As _Unsigned Long
293.     Dim c$
294.     If InStr(main_str, Chr$(34)) = 0 Then
295.         getData$ = _Trim$(main_str)
296.         'Print "yes"
297.         'Print main_str
298.         Exit Function
299.     End If
300.     For i = 1 To Len(main_str)
301.         c$ = Mid$(main_str, i, 1)
302.         If c$ = Chr$(34) Then
303.             quote$ = c$
304.             For j = i + 1 To Len(main_str)
305.                 c$ = Mid$(main_str, j, 1)
306.                 If c$ = quote$ Then Exit Function
307.                 getData$ = getData$ + c$
308.             Next
309.         End If
310.     Next
311. End Function
312. Function charFind~& (main_str As String, search As String, p As _Unsigned Long, fromEnd As _Byte, ignore_quote As _Byte)
313.     If Len(main_str) = 0 Or Len(search) = 0 Then Exit Function
314.     Dim i As _Unsigned Long
315.     If fromEnd Then
316.         Dim reversed$
317.         For i = Len(main_str) To 1 Step -1
318.             reversed$ = reversed$ + Mid$(main_str, i, 1)
319.         Next
320.         'Print reversed$
321.         If ignore_quote Then charFind~& = -getAbsCharPos(reversed$, search, p) + 1 + Len(main_str) Else charFind~& = -InStr(p, reversed$, search) + 1 + Len(main_str)
322.     Else
323.         If ignore_quote Then charFind~& = getAbsCharPos(main_str, search, p) Else charFind~& = InStr(p, main_str, search)
324.     End If
325. End Function
326.  

Here is the test.json file which you need. Save the below JSON string into a file named test.json

Code: Text: [Select]

1. {
2.     "server-name" : "QB64",
3.     "description" : "Server for qb64, qbasic and gw-basic fans.",
4.     "roles" : {
5.         "special": {
6.             "devs" : ["Fellippe", "Luke", "Spriggsy", "SteveMcNeill"],
7.             "Crew-Members" : ["Ashish", "Cobalt", "Qwerky", "STxAxTIC"]
8.         },
9.         "common" : {
10.             "regulars" : ["Shalin", "Monke", "ChiaPet", "onecoding", "garbage", "loudar"]
11.         }
12.     },
13.     "total-members" : 296
14. }
15.  

Use "." followed a by label to get value. Use "[ index ]" for a list to get a value.