Pyramid with tile texture

[Ashish]

Hey everyone! I've a new opengl program for you!

Code: QB64: [Select]

1. _Title "Pyramid with tile texture"
2. 'Coded by Ashish
3. '26 march, 2021
4. Screen _NewImage(600, 600, 32)
5.  
6. Type vec3
7.     As Single x, y, z
8. End Type
9.  
10. Declare Library
11.     'for camera
12.     Sub gluLookAt (ByVal eyeX#, Byval eyeY#, Byval eyeZ#, Byval centerX#, Byval centerY#, Byval centerZ#, Byval upX#, Byval upY#, Byval upZ#)
13. End Declare
14.  
15.  
16. Dim Shared glAllow As _Byte
17. Dim Shared texture_data As Long, pyramid_coord(3) As vec3, texcoord(2) As vec3
18.  
19. 'coordinate data
20. pyramid_coord(0).x = 0: pyramid_coord(0).y = 2: pyramid_coord(0).z = 0
21. pyramid_coord(1).x = -2: pyramid_coord(1).y = -2: pyramid_coord(1).z = -2
22. pyramid_coord(2).x = 2: pyramid_coord(2).y = -2: pyramid_coord(2).z = -2
23. pyramid_coord(3).x = 0: pyramid_coord(3).y = -2: pyramid_coord(3).z = 2
24. texcoord(0).x = 0: texcoord(0).y = 0
25. texcoord(1).x = 0.5: texcoord(1).y = 1
26. texcoord(2).x = 1: texcoord(2).y = 0
27.  
28. texture_data = _NewImage(400, 400, 32)
29. texture_data_r = _CopyImage(texture_data)
30. glAllow = 1
31. 'set these shades values as per your requirement
32. shade1& = _RGB(15, 190, 200)
33. shade2& = _RGB(240, 10, 70)
34. Do
35.     _Dest texture_data_r
36.     Line (0, 0)-(_Width(texture_data_r), _Height(texture_data_r)), shade1&, BF
37.     i = 1
38.     For y = 0 To _Height(texture_data_r) Step 40
39.         i = i * -1
40.         For x = -40 + 20 * i To _Width(texture_data_r) + 40 Step 80
41.             CircleFill x + offx, y, 20, shade2&
42.         Next
43.     Next
44.     offx = offx + 3
45.     If offx > 80 Then offx = 0
46.     _Dest 0
47.     _PutImage , texture_data_r, texture_data
48.     Cls , shade1&
49.     For x = -100 To 700 Step 100
50.         Line (x + ax, 0)-(x + ax, 700), shade2&
51.         Line (x + ax + 50, 0)-(x + ax + 50, 700), shade2&
52.         Paint (x + ax + 49, 0), shade2&, shade2&
53.         Paint (x + ax + 1, 0), shade2&, shade2&
54.     Next
55.     If ax > 100 Then ax = 0
56.     ax = ax + 2
57.     _Limit 60
58.     _Display
59. Loop
60.  
61. Sub _GL ()
62.     If glAllow = 0 Then Exit Sub
63.     Static glInit, tex As Long, m As _MEM, t
64.     If glInit = 0 Then
65.         glInit = 1
66.         _glViewport 0, 0, _Width, _Height
67.         'texture
68.         _glGenTextures 1, _Offset(tex)
69.         m = _MemImage(texture_data)
70.  
71.     End If
72.  
73.     _glEnable _GL_TEXTURE_2D
74.     _glEnable _GL_DEPTH_TEST
75.     _glEnable _GL_BLEND
76.  
77.     'projection settings
78.     _glMatrixMode _GL_PROJECTION
79.     _gluPerspective 60, _Width / _Height, 0.1, 10
80.  
81.     _glMatrixMode _GL_MODELVIEW
82.     _glLoadIdentity
83.     gluLookAt 0, 0, 6, 0, 0, 0, 0, 1, 0
84.     _glRotatef t, 0, 1, 0.8
85.  
86.     'drawing pyramid
87.     _glBindTexture _GL_TEXTURE_2D, tex
88.     _glTexImage2D _GL_TEXTURE_2D, 0, _GL_RGB, _Width(texture_data), _Height(texture_data), 0, _GL_BGRA_EXT, _GL_UNSIGNED_BYTE, m.OFFSET
89.     _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_LINEAR
90.     _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_NEAREST
91.  
92.     For i = 0 To 3
93.         _glBegin _GL_TRIANGLES
94.         For j = i To i + 2
95.             _glTexCoord2f texcoord(j Mod 3).x, texcoord(j Mod 3).y
96.             _glVertex3f pyramid_coord(j Mod 4).x, pyramid_coord(j Mod 4).y, pyramid_coord(j Mod 4).z
97.         Next
98.         _glEnd
99.     Next
100.     t = t + 1
101. End Sub
102.  
103.  
104. Sub CircleFill (x As Long, y As Long, R As Long, C As _Unsigned Long)
105.     Dim x0 As Single, y0 As Single
106.     Dim e As Single
107.  
108.     x0 = R
109.     y0 = 0
110.     e = -R
111.     Do While y0 < x0
112.         If e <= 0 Then
113.             y0 = y0 + 1
114.             Line (x - x0, y + y0)-(x + x0, y + y0), C, BF
115.             Line (x - x0, y - y0)-(x + x0, y - y0), C, BF
116.             e = e + 2 * y0
117.         Else
118.             Line (x - y0, y - x0)-(x + y0, y - x0), C, BF
119.             Line (x - y0, y + x0)-(x + y0, y + x0), C, BF
120.             x0 = x0 - 1
121.             e = e - 2 * x0
122.         End If
123.     Loop
124.     Line (x - R, y)-(x + R, y), C, BF
125. End Sub
126.  
127.  
128.  

[SpriggsySpriggs]

Awesome program, Ashish!

[Pete]

Well it got me to download v1.5 to run it.

This stuff was cutting edge back in 1980's. Reminds me of something that could make a video game like Zaxxon. It was not something one could easily do in QBasic, so it's neat to see it working via OpenGL in QB64.

Pete

[johnno56]

That's pretty cool... Definitely a workout for the old optic nerves... Nicely done... Does it come in blue? lol

[Richard Frost]

[bplus]

This is nice, @Ashish.

I am wondering, this can be done without GL, I am fairly certain.

[Ashish]

Thanks @SpriggsySpriggs , @Pete, @johnno56, @Richard Frost and @bplus
@johnno56 , I have updated the code. You can change the shades color as per your requirement on line 32 and 33.

@bplus without _GL? are you going to make one? that would be awesome! :D

[TempodiBasic]

@Ashish
Cool !
Mmmmmh you have missed the right color, light blue and pink and not red!
:-)
Good job.