First Run at a virtual, customized keyboard routine

[SMcNeill]

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. _CONTROLCHR OFF
4. k = KB_Input(1, 30, 30, 100, 100)
5. PRINT k,
6. IF k > 0 AND k < 256 THEN PRINT CHR$(k)
7.  
8.  
9.  
10.  
11.  
12.  
13. FUNCTION KB_Input (KB, Xsize, Ysize, Xpos, Ypos)
14.  
15.     restart:
16.     IF keyboard_image THEN _FREEIMAGE keyboard_image
17.  
18.     SELECT CASE KB
19.         CASE 1 'starting, caps keyboard
    
20.             REDIM KB(0 TO 3) AS STRING
21.             KB(0) = "ABCDEFGH" + CHR$(0)
22.             KB(1) = "IJKLMNOP" + CHR$(0)
23.             KB(2) = "QRSTUVWX" + CHR$(0)
24.             KB(3) = "YZ" + CHR$(0)
25.         CASE 2 'lower case keyboard 
26.             REDIM KB(0 TO 3) AS STRING
27.             KB(0) = "abcdefgh" + CHR$(0)
28.             KB(1) = "ijklmnop" + CHR$(0)
29.             KB(2) = "qrstyvxx" + CHR$(0)
30.             KB(3) = "yz
    " + CHR$(0)
31.         CASE 3 'top row values
32.             REDIM KB(0 TO 3) AS STRING
33.             KB(0) = "12345678" + CHR$(0)
34.             KB(1) = "90!@#$%^" + CHR$(0)
35.             KB(2) = "&*()-=_+" + CHR$(0)
36.             KB(3) = "`~
    " + CHR$(0)
37.         CASE 4
38.             REDIM KB(0 TO 3) AS STRING
39.             KB(0) = "This" + CHR$(0)
40.             KB(1) = "does not" + CHR$(0)
41.             KB(2) = "yet work" + CHR$(0)
42.             KB(3) = "
    " + CHR$(0)
43.         CASE 5
44.             REDIM KB(0 TO 3) AS STRING
45.             KB(0) = "" + CHR$(0)
46.             KB(1) = "" + CHR$(0)
47.             KB(2) = "" + CHR$(0)
48.             KB(3) = "
    " + CHR$(0)
49.         CASE 6
50.             REDIM KB(0 TO 1) AS STRING
51.             KB(0) = "
    " + CHR$(0)
52.             KB(1) = "
    " + CHR$(0)
53.         CASE 7
54.             REDIM KB(0) AS STRING
55.             KB(0) = "
    " + CHR$(0)
56.     END SELECT
57.  
58.     l = LBOUND(KB): u = UBOUND(KB)
59.     FOR i = l TO u 'get longest line
60.         IF LEN(KB(i)) > LL THEN LL = LEN(KB(i))
61.     NEXT
62.     LL = LL + 1
63.     keyboard_image = _NEWIMAGE((Xsize + 2) * LL, (Ysize + 2) * (u - l + 1), 32)
64.     'now build the keyboard
65.     FOR i = l TO u
66.         top = (i - l) * Ysize + Ypos
67.         FOR j = 1 TO LEN(KB(i))
68.             left = (j - 1) * Xsize + Xpos
69.             LINE (left, top)-STEP(Xsize, Ysize), -1, B
70.             IF j < LEN(KB(i)) AND i < 3 THEN
71.                 c = ASC(KB(i), j)
72.                 IF c < 32 THEN out$ = "KB" + _TRIM$(STR$(c)) ELSE out$ = CHR$(c)
73.                 IF c = 0 THEN out$ = ""
74.             ELSE
75.                 IF j = LEN(KB(i)) THEN
76.                     SELECT CASE i
77.                         CASE 0: out$ = "BSP"
78.                         CASE 1: out$ = "DEL"
79.                         CASE 2: out$ = "RET"
80.                         CASE 3: out$ = "SPC"
81.                     END SELECT
82.                 ELSE
83.                     c = ASC(KB(i), j)
84.                     IF c < 32 THEN out$ = "KB" + _TRIM$(STR$(c)) ELSE out$ = CHR$(c)
85.                 END IF
86.             END IF
87.             _PRINTSTRING (left + (Xsize - _FONTWIDTH * LEN(out$)) / 2, top + (Ysize - _FONTHEIGHT) / 2), out$
88.         NEXT
89.     NEXT
90.     Hardware_Keyboard_Image = _COPYIMAGE(keyboard_image, 33)
91.     _FREEIMAGE keyboard_image
92.  
93.     oldmouse = -1
94.     DO
95.         _PUTIMAGE (Xpos, Ypos), Hardware_Keyboard_Image
96.         WHILE _MOUSEINPUT: WEND
97.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
98.  
99.         Xon = INT((mx - Xpos) / Xsize) + 1
100.         Yon = INT((my - Ypos) / Ysize) + l
101.         'LOCATE 1, 1: PRINT Xon, Yon
102.  
103.  
104.         IF mb AND NOT oldmouse THEN 'it's a click
105.             IF Yon >= l AND Yon <= u THEN
106.                 IF Xon > 0 AND Xon <= LEN(KB(Yon)) THEN
107.                     k = ASC(KB(Yon), Xon)
108.                     PCOPY 1, 0
109.                     SELECT CASE k
110.                         CASE 0 'we should only have a null value for the last row of special characters
111.                             SELECT CASE Yon
112.                                 CASE 0: KB_Input = 8: EXIT FUNCTION
113.                                 CASE 1: KB_Input = 21248: EXIT FUNCTION
114.                                 CASE 2: KB_Input = 13: EXIT FUNCTION
115.                                 CASE 3: KB_Input = 13: EXIT FUNCTION
116.                             END SELECT
117.                         CASE 1 TO 31: KB = k: GOTO restart
118.                         CASE ELSE
119.                             KB_Input = k: EXIT FUNCTION
120.                     END SELECT
121.  
122.                 END IF
123.             END IF
124.         END IF
125.         _LIMIT 30
126.         _DISPLAY
127.         oldmouse = mb
128.     LOOP
129. END FUNCTION

Much like Pete, I tend to sit down and just start coding, without really much thought  going into anything before I start working on it.  Unlike Pete, I try to make my code as modular as possible, and to only focus on one little thing at a time...

This is my first attempt at a virtual, customizable, pop-up keyboard.  At first, I was thinking that I might not need certain keys (and I won't, for all inputs, such as having a customer only enter a numeric entry for their phone number), but I still need to come up with some easy way to represent them, in case they are wanted (such as enter, space, and so on).

I want to keep the syntax simple enough that a new user could basically just sit down and write out what keys go where, like I've done above, but I need something a little more flexible and powerful as well.  For now, and for ease of testing/swapping, I'm using low ASCII codes as control characters to designate different keyboards, but I'll need to do them a little different as well...

Drawing the keyboard, making it a hardware image,  and reading it isn't really that hard to do.  Sorting out the proper data format in this case is a real head scratcher!!

Anyone with a good idea for a simple way to implement a string layout for a keyboard?

Right now, my thoughts are thinking of using CHR$(0) as a "Special character" and wrapping it around keys.  As far as I know, there's no easy/native way to insert a CHR$(0) character into the QB64 IDE (the ASCII chart doesn't insert 0 and neither does ALT-0 with the number keys, and you won't find a key on any keyboard for it), so it'd have to be manually placed and used, keeping if from being something that might accidently pop-up in a string, and if a person wants to print it, all they'd have to print is a normal CHR$(32) space...

So the next layout would tentatively look like:

KB(0) = "`1234567890-=" + CHR$(0) + "BSP" + CHR$(0)
KB(1) = CHR$(0) + "TAB" + CHR$(0) + "QWERTYUIOP[]\"

The bottom row would look like:
KB(5) = CHR$(0) + "CTR" + CHR$(0) + CHR$(0) + "WIN" + CHR$(0) + CHR$(0) + "ALT" + CHR$(0) + CHR$(0) + " " + ... (you get the point)

Which still seems relatively simple to me, and easy enough for others to learn...   Unless somebody has an idea for a better schematic?  I'm all ears, and willing to listen to all ideas and opinions.  :)

[SMcNeill]

Maybe CHR$(0) + “(the ASCII code)”  + CHR$(0)

So Enter would be CHR$(0) + “13” + CHR$(0)... 

Then all I have to do is return that value back to the user, and have a set of labels to automagically go with them.

Edit:

Maybe a hybrid approach: Value + comma + Display

Example for enter: CHR$(0) + “13, RET” + CHR$(0)

Returns code 13, displays RET if you’re making a compact keyboard.

[SMcNeill]

So here's what my a new, full-sized, virtual keyboard might look like under my new system:

Code: QB64: [Select]

1. DIM My_Keyboard(5) AS STRING
2. My_Keyboard(0) = CHR$(0) + "27,ESC" + STRING$(2,0) + "15104,F1" + STRING$(2,0) + "15360,F2" + _
3.     STRING$(2,0) + "15616,F3" + STRING$(2,0) + "15872,F4" + STRING$(2,0) + "16128,F5" + _
4.     STRING$(2,0) + "16384,F6" + STRING$(2,0) + "16640,F7" + STRING$(2,0) + "16896,F8" + _
5.     STRING$(2,0) + "17152,F9" + STRING$(2,0) + "17408,F10" + STRING$(2,0) + "34048,F11" + _
6.     STRING$(2,0) + "34304,F12" + CHR$(0)
7. My_Keyboard(1) = "`1234567890-=" + CHR$(0) + "19200,BKSP" + CHR$(0)
8. My_Keyboard(2) = CHR$(0) + "9,TAB" + CHR$(0) + "QWERTYUIOP[]\"
9. My_Keyboard(3) = CHR$(0) + "100301,CAPS" + CHR$(0) + "ASDFGHJKL;'" + CHR$(0) + "13,ENTER" + CHR$(0)
10. My_Keyboard(4) = CHR$(0) + "100304,SHIFT" + CHR$(0) + "ZXCVBNM,./" + CHR$(0) + "100303,SHIFT" + CHR$(0)
11. My_Keyboard(5) = CHR$(0) + "100306,CTRL" + STRING$(2,0) + "0,WIN" + STRING$(2,0) + "100308,ALT" + _
12.     STRING$(2,0) + "32,SPACE" + STRING$(2,0) + "100307,ALT" + STRING$(2,0) + "0,WIN" + STRING$(2,0) + "0,MENU" + _
13.     STRING$(2,0) + "100305,CTRL" +  CHR$(0)
14.  
15. SCREEN _NEWIMAGE(800, 600, 32)
16. _CONTROLCHR OFF
17.  
18. k = KB_Input(My_Keyboard(), 50, 30, 50, 100)
19. PRINT k
20.  
21.  
22. FUNCTION KB_Input (KB() AS STRING, Xsize, Ysize, Xpos, Ypos)
23.  
24.     l = LBOUND(KB): u = UBOUND(KB)
25.     DIM Keyboard_Values(l TO u, 0 TO 256)
26.     FOR i = l TO u 'get longest line
27.         IF LEN(KB(i)) > LL THEN LL = LEN(KB(i))
28.     NEXT
29.     LL = LL + 1
30.     keyboard_image = _NEWIMAGE((Xsize + 2) * LL, (Ysize + 2) * (u - l + 1), 32)
31.     'now build the keyboard
32.     FOR i = l TO u
33.         top = (i - l) * Ysize + Ypos
34.         count = 0
35.         FOR j = 1 TO LEN(KB(i))
36.             left = (count) * Xsize + Xpos
37.             count = count + 1
38.             repeat = 1
39.             c = ASC(KB(i), j): out$ = ""
40.             IF c = 0 THEN
41.                 'look for the comma
42.                 comma_position = INSTR(j, KB(i), ",")
43.                 IF comma_position THEN 'we have a value, label
44.                     value$ = MID$(KB(i), j + 1, comma_position - j - 1)
45.                     c = VAL(value$)
46.                     j = comma_position + 1
47.                 ELSE 'cry loud and hard so we can sort it out while programming our keyboard layout
48.                     scream_and_die:
49.                     SLEEP
50.                     CLS
51.                     PRINT "You have an invalid keyboard layout!"
52.                     END
53.                 END IF
54.  
55.                 end_position = INSTR(j, KB(i), CHR$(0))
56.                 IF end_position THEN 'we're extracting the label
57.                     out$ = MID$(KB(i), j, end_position - j)
58.                     repeat = ASC(out$, LEN(out$))
59.                     IF repeat > 0 AND repeat < 9 THEN
60.                         out$ = LEFT$(out$, LEN(out$) - 1)
61.                     ELSE
62.                         repeat = 1
63.                     END IF
64.                     j = end_position
65.                 ELSE
66.                     GOTO scream_and_die
67.                 END IF
68.             END IF
69.             LINE (left, top)-STEP(Xsize * repeat, Ysize), -1, B
70.             DO UNTIL repeat = 1
71.                 Keyboard_Values(i, count) = c
72.                 count = count + 1
73.                 repeat = repeat - 1
74.             LOOP
75.             Keyboard_Values(i, count) = c
76.             IF c < 256 AND out$ = "" THEN out$ = CHR$(c)
77.             _PRINTSTRING (left + (Xsize - _FONTWIDTH * LEN(out$)) / 2, top + (Ysize - _FONTHEIGHT) / 2), out$
78.         NEXT
79.     NEXT
80.     Hardware_Keyboard_Image = _COPYIMAGE(keyboard_image, 33)
81.     _FREEIMAGE keyboard_image
82.  
83.     oldmouse = -1
84.     DO
85.         _PUTIMAGE (Xpos, Ypos), Hardware_Keyboard_Image
86.         WHILE _MOUSEINPUT: WEND
87.         mb = _MOUSEBUTTON(1): mx = _MOUSEX: my = _MOUSEY
88.  
89.         Xon = INT((mx - Xpos) / Xsize) + 1
90.         Yon = INT((my - Ypos) / Ysize) + l
91.         'LOCATE 1, 1: PRINT Xon, Yon
92.  
93.  
94.         _LIMIT 30
95.         _DISPLAY
96.         oldmouse = mb
97.     LOOP
98. END FUNCTION

  [ You are not allowed to view this attachment ]  

That's actually not looking so bad, if I do say so myself!

And the whole thing builds itself from scratch, once you give it your chosen layout.  The one which made the keyboard in the screen shot is this one:

DIM My_Keyboard(5) AS STRING
My_Keyboard(0) = CHR$(0) + "27,ESC" + STRING$(2,0) + "15104,F1" + STRING$(2,0) + "15360,F2" + _
    STRING$(2,0) + "15616,F3" + STRING$(2,0) + "15872,F4" + STRING$(2,0) + "16128,F5" + _
    STRING$(2,0) + "16384,F6" + STRING$(2,0) + "16640,F7" + STRING$(2,0) + "16896,F8" + _
    STRING$(2,0) + "17152,F9" + STRING$(2,0) + "17408,F10" + STRING$(2,0) + "34048,F11" + _
    STRING$(2,0) + "34304,F12" + CHR$(0)
My_Keyboard(1) = "`1234567890-=" + CHR$(0) + "19200,BKSP" + CHR$(0)
My_Keyboard(2) = CHR$(0) + "9,TAB" + CHR$(0) + "QWERTYUIOP[]\"
My_Keyboard(3) = CHR$(0) + "100301,CAPS" + CHR$(0) + "ASDFGHJKL;'" + CHR$(0) + "13,ENTER" + CHR$(0)
My_Keyboard(4) = CHR$(0) + "100304,SHIFT" + CHR$(0) + "ZXCVBNM,./" + CHR$(0) + "100303,SHIFT" + CHR$(0)
My_Keyboard(5) = CHR$(0) + "100306,CTRL" + STRING$(2,0) + "0,WIN" + STRING$(2,0) + "100308,ALT" + _
    STRING$(2,0) + "32,SPACE" + STRING$(2,0) + "100307,ALT" + STRING$(2,0) + "0,WIN" + STRING$(2,0) + "0,MENU" + _
    STRING$(2,0) + "100305,CTRL" +  CHR$(0)


It looks a little complicated when you first take a glance at it, but it's not.  It's basically using the syntax which I was talking about above.
For normal keys, you just put them in quotes.  "QWERTYUIOP[]\"
For any special keys, you identify them with CHR$(0) + "code_value,LABEL" + CHR$(0).
So the TAB key, for instance is: CHR$(0) + "9,TAB" + CHR$(0).

So that whole row becomes CHR$(0) + "9,TAB" + CHR$(0) + "QWERTYUIOP[]\"

And with that, you can build a keyboard of any layout which you might want for your programs, and then use the mouse to interact with it.  (Or a touchscreen.)

[bplus]

Yes that looks better than my Keyboard!

For comparison on a HP laptop Keyboard several years out, I have a fn key and my Windows Logo key on Left of Spacebar: ctrl fn Logo alt.  On right of spacebar it's: alt  ctrl 4 arrow keys in the space of 3 buttons, the Up and Down arrows split a normal sized key space into 2, really bad for gaming.

Probably doesn't mean a hill of beans but I like to b...

Come to think, way, way, way back to VB 2, I made a graphic keyboard so when mousing inputs I didn't have move my hands off to type something like a single letter and then go back to mouse. Ergonomically that's huge savings.