Dalota language program

[Larryrl]

I have a program to help me edit and upkeep my Dalota conlang. The file loading routine is like this

Code: QB64: [Select]

1. DIM language$(20000, 2)
2.  
3. OPEN "f:\dalota\dalota wordlist.dalwd" FOR INPUT AS #1
4.  
5. x = 0
6. WHILE NOT EOF(1)
7.     x = x + 1
8.     LINE INPUT #1, language$(x, 1)
9.     LINE INPUT #1, language$(x, 2)
10. WEND
11.  
12. CLOSE #1
13.  
14. total = x
15.  
16.  

From there it displays the array elements to the screen with column 1 on the left, and column 2 on the right. What I am needing now, is a way to possibly use a loop to go through the data, and change the color of my highlight bar if a word is shown to be a duplicate of another entry. In Excel, they call that cell highlighting. I would love to be able to have duplicates in column a, highlighted and also the dupes in column B. Duplicates across columns is ok.
 

[Pete]

Something like this?

Code: QB64: [Select]

1. DIM x$(6)
2. x$(1) = "turtle"
3. x$(2) = "cat"
4. x$(3) = "dog"
5. x$(4) = "cat"
6. x$(5) = "Rabbit"
7. x$(6) = "frog"
8.  
9. CLS
10. FOR i = 1 TO 6
11.     PRINT x$(i)
12. NEXT
13. LOCATE 1, 1
14. GOSUB display_routine
15. DO
16.     DO
17.         _LIMIT 30
18.         b$ = INKEY$
19.         IF b$ = CHR$(0) + "H" AND CSRLIN > 1 THEN PRINT x$(CSRLIN);: LOCATE CSRLIN - 1, 1: EXIT DO ' Arrow key up.
20.         IF b$ = CHR$(0) + "P" AND CSRLIN < 6 THEN PRINT x$(CSRLIN);: LOCATE CSRLIN + 1, 1: EXIT DO ' Arrow key down.
21.         IF b$ = CHR$(27) THEN END
22.     LOOP
23.     GOSUB display_routine
24. LOOP
25. END
26.  
27. display_routine:
28. j = 0
29. FOR k = 1 TO 6
30.     IF x$(CSRLIN) = x$(k) THEN j = j + 1
31.     IF j = 2 THEN EXIT FOR
32. NEXT
33. IF j = 2 THEN COLOR 14, 4 ELSE COLOR 15, 1
34. PRINT x$(CSRLIN);
35. LOCATE , 1
36. COLOR 7, 0
37. RETURN
38.  

Use arrow up and down to highlight text. Blue is single occurrence. Red is two or more.

Let me know if you don't understand what's happening in the code.

Oh, if you are familiar with INSTR, you could concatenate all of those arrays and do something a little faster than looping...

Code: QB64: [Select]

1. DIM x$(6)
2. x$(1) = "turtle"
3. x$(2) = "cat"
4. x$(3) = "dog"
5. x$(4) = "cat"
6. x$(5) = "Rabbit"
7. x$(6) = "frog"
8.  
9. CLS
10. concat_x$ = "|"
11. FOR i = 1 TO 6
12.     PRINT x$(i)
13.     concat_x$ = concat_x$ + x$(i) + "|"
14. NEXT
15. LOCATE 1, 1
16. GOSUB display_routine
17. DO
18.     DO
19.         _LIMIT 30
20.         b$ = INKEY$
21.         IF b$ = CHR$(0) + "H" AND CSRLIN > 1 THEN PRINT x$(CSRLIN);: LOCATE CSRLIN - 1, 1: EXIT DO ' Arrow key up.
22.         IF b$ = CHR$(0) + "P" AND CSRLIN < 6 THEN PRINT x$(CSRLIN);: LOCATE CSRLIN + 1, 1: EXIT DO ' Arrow key down.
23.         IF b$ = CHR$(27) THEN END
24.     LOOP
25.     GOSUB display_routine
26. LOOP
27. END
28.  
29. display_routine:
30. j = 0
31. x$ = "|" + x$(CSRLIN) + "|"
32. IF INSTR(INSTR(concat_x$, x$) + LEN(x$), concat_x$, x$) THEN COLOR 14, 4 ELSE COLOR 15, 1
33. PRINT x$(CSRLIN);
34. LOCATE , 1
35. COLOR 7, 0
36. RETURN
37.  

Pete

[Larryrl]

Thanks a lot, that looks awesome. Either one is fast on my machine.

However, I have two versions of this program, one in qb64 and the other in Liberty basic. If I can take this code and modify it to fit the program coded in Liberty basic, that will be good. Not the color part, just the dupes part. I have two arrays ldup$ for the language words and edup$ for the English words. It should check for duplicates on both columns of the array. I need to know if there are two English words thesame, and aso if two langiage words are the same. If language duplicates are found they get added to ldup$ array, if English duplicates are found, they get added to edup$ array. In the Liberty version of the program, I just dump the two dup arrays ldup$ and edup$ into a textbox and can go through them at my leisure. Yes, please explain how this works. I think I know, bit but at the same time I am not totally sure. Also, rather my original request to change the highlight bar, it should color the dupes, in the list to show at all times and I can recheck as needed when I delete some of the dups.