System Precise Filetime, Unix Time and Elapsed Performance Counter Time

[EricE]

This is something I wrote today to compare the Windows System Precise Filetime with the Unix Time and the elapsed time computed by reading the Windows performance counter.

I welcome comments if there are alternative or better ways of getting time tags and elapsed times out of Windows.

Code: QB64: [Select]

1. ' FILETIME structure
2. ' This structure is a 64-bit value representing the number of 100-nanosecond intervals since January 1, 1601.
3. TYPE FILETIME
4.     dwLowDateTime AS _UNSIGNED LONG
5.     dwHighDateTime AS _UNSIGNED LONG
6. END TYPE
7.  
8. DECLARE DYNAMIC LIBRARY "kernel32"
9.     ' GetSystemTimePreciseAsFileTime function
10.     ' https://docs.microsoft.com/en-us/windows/win32/api/sysinfoapi/nf-sysinfoapi-getsystemtimepreciseasfiletime
11.     SUB GetSystemTimePreciseAsFileTime (BYVAL lpSystemTimeAsFileTime AS _UNSIGNED _OFFSET)
12.  
13.     ' Acquiring high-resolution time stamps
14.     ' https://docs.microsoft.com/en-us/windows/win32/sysinfo/acquiring-high-resolution-time-stamps
15.     SUB QueryPerformanceCounter (BYVAL lpPerformanceCount AS _UNSIGNED _OFFSET)
16.     SUB QueryPerformanceFrequency (BYVAL lpFrequency AS _UNSIGNED _OFFSET)
17. END DECLARE
18.  
19. DECLARE CUSTOMTYPE LIBRARY
20.     ' time_t time( time_t *destTime )
21.     ' Returns the time as seconds elapsed since midnight, January 1, 1970, or -1 in the case of an error.
22.     ' https://docs.microsoft.com/en-us/cpp/c-runtime-library/reference/time-time32-time64?view=vs-2019
23.     $IF 64BIT THEN
24.     ' 64-bit OS, time_t type is 8 byte _INTEGER64
25.     FUNCTION time&& (BYVAL TimerPtr AS _UNSIGNED _OFFSET)
26.     $ELSE
27.         ' 32-bit OS, time_t type is 4 byte INTEGER
28.         FUNCTION time& (BYVAL TimerPtr AS _UNSIGNED _OFFSET)
29.     $END IF
30. END DECLARE
31.  
32. DIM ft AS FILETIME
33. DIM time_now&
34. DIM qwResult AS _UNSIGNED _INTEGER64
35. DIM PerformanceCount AS _INTEGER64
36. DIM Frequency AS _INTEGER64
37. DIM StartingCount AS _INTEGER64
38. DIM dElapsedTime AS DOUBLE
39.  
40. PRINT " System Precise FILETIME,    UNIX TIME,   Elapsed Performance Counter"
41. QueryPerformanceFrequency (_OFFSET(Frequency))
42. QueryPerformanceCounter (_OFFSET(StartingCount))
43.  
44. FOR i% = 1 TO 10
45.     GetSystemTimePreciseAsFileTime (_OFFSET(ft))
46.  
47.     ' UNIX time
48.     time_now& = time(0)
49.  
50.     QueryPerformanceCounter (_OFFSET(PerformanceCount))
51.  
52.     ' Elasped Performace Count
53.     dElapsedTime = (CDBL(PerformanceCount - StartingCount)) / Frequency
54.  
55.     ' System Precise FileTime
56.     qwResult = ft.dwHighDateTime
57.     qwResult = qwResult * &H100000000
58.     qwResult = qwResult + ft.dwLowDateTime
59.  
60.     PRINT CDBL(qwResult) / 10000000.0 - 11644473600.0, time_now&, dElapsedTime
61.  
62.     _DELAY (1)
63. NEXT i%
64.  

[bplus]

Hi Eric,

Have you seen this?
https://www.qb64.org/forum/index.php?topic=1598.msg108135#msg108135

But yours looks like it's focused on a files utility.