Ectoplasm

[STxAxTIC]

This part riiight here:

I don't think tables would be practical (800 * 600)^2 x1, y1, x2, y2 the distance from any point to any other = 2.304*10^11 values.

That's where interpolation comes in handy. The table need only contain crude known values, like 100, 105, 110, 120, etc. So that when a request for 103 comes in, it fakes the value by using its neighbors, 100 and 105. Same goes for a trig table, just wrap SIN() around each of the numbers I just used.

Not to mention the number of "values" might overcount. You want the number of pair-to-pair distances in a table? I think this is just a bunch of radii. Thats what I think i mean. Will have to look closer if not. Meh, take or leave this statement.

[bplus]

OK here is a nice set of settings, I added more colors to palette and stretched cells over 2 bands. SQR or no doesn't make a bunch of difference but stepper makes huge difference, recommend 2, 3 or 4 depending on your system:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "Plasmatic 5.1 Speed Tests" ' b+ 2020-01-26
3. ' Try no SQR for distance
4.  
5. CONST xxmax = 700, yymax = 500, xmax = 900, ymax = 740, xoff = (xmax - xxmax) \ 2, yoff = (ymax - yymax) \ 2
6. TYPE xy
7.     x AS SINGLE
8.     y AS SINGLE
9.     dx AS SINGLE
10.     dy AS SINGLE
11. END TYPE
12. SCREEN _NEWIMAGE(xmax, ymax, 32)
13. _SCREENMOVE 250, 0
14. RANDOMIZE TIMER
15. DIM c(1440) AS _UNSIGNED LONG, p(6) AS xy, f(6)
16. DIM i AS INTEGER, m AS INTEGER, n AS INTEGER, mode AS INTEGER, cnt AS INTEGER, k$, t, x, y, d, dx, dy, dist, s, stepper, tot
17. DIM r AS INTEGER, g AS INTEGER, b AS INTEGER, r1 AS INTEGER, g1 AS INTEGER, b1 AS INTEGER, r2 AS INTEGER, g2 AS INTEGER, b2 AS INTEGER
18.  
19. restart: 'select rgb1 and rgb2 based on mode of color mixing
20. IF mode = 0 THEN 'new plasma option ANY color for border and ANY color for middle
21.     r1 = RND * 255: g1 = RND * 255: b1 = RND * 255: r2 = RND * 255: g2 = RND * 255: b2 = RND * 255
22. ELSE ' traditional high contrast plasma black borders, white centers
23.     r1 = 0: g1 = 0: b1 = 0: r2 = 255: g2 = 255: b2 = 255 'regular Plasma
24. END IF
25.  
26. ' create 6 x 60 bands of color palette based on coloring mode (rgb1 set and rgb2 set)
27. FOR i = 0 TO 720
28.     IF i MOD 60 = 0 THEN r = RND * 255: g = RND * 255: b = RND * 255
29.     m = i MOD 60
30.     s = 1 - ((30 - m + .5) / 30) ^ 2
31.     SELECT CASE m
32.         CASE IS < 15: c(i) = midInk(s * r1, s * g1, s * b1, s * r, s * g, s * b, m / 15) '        1st stage increase rgb1 towards rgb color in 15 steps
33.         CASE IS < 30: c(i) = midInk(s * r, s * g, s * b, s * r2, s * g2, s * b2, (m - 15) / 15) ' 2nd stage increase rgb color towards rgb2 set in 15 steps
34.         CASE IS < 45: c(i) = midInk(s * r2, s * g2, s * b2, s * r, s * g, s * b, (m - 30) / 15) ' 3rd stage decrease rgb2 color back to rgb color in 15 steps
35.         CASE IS < 60: c(i) = midInk(s * r, s * g, s * b, s * r1, s * g1, s * b1, (m - 45) / 15) ' 4th and finally decrease rgb back to starting rgb1 set in 15 steps
36.     END SELECT
37. NEXT
38.  
39. ' behind the scenes variables for motion, weighting and shaping color mixing
40. FOR n = 0 TO 6
41.     p(n).x = RND * xmax: p(n).y = RND * yymax: p(n).dx = RND * 2 - 1: p(n).dy = RND * 2 - 1
42.     f(n) = .09 * RND
43. NEXT
44.  
45. 'screen labeling 3 lines for title above, 1 line instructions below
46. CLS
47. IF mode = 0 THEN
48.     yCP yoff - 60, "New Color Options for Plasma:"
49. ELSE
50.     yCP yoff - 60, "Traditional High Contrast Plasma: Black Borders and White Centers"
51. END IF
52. yCP yoff - 40, "Shaded Borders: RGB(" + TS$(r1 \ 1) + ", " + TS$(g1 \ 1) + ", " + TS$(b1 \ 1) + ")"
53. yCP yoff - 20, "Centers: RGB(" + TS$(r2 \ 1) + ", " + TS$(g2 \ 1) + ", " + TS$(b2 \ 1) + ")"
54. yCP yoff + yymax + 10, "Press t to toggle between Traditional and New Color Options Plasma"
55. yCP yoff + yymax + 30, "Press spacebar to get a new color set."
56.  
57. WHILE _KEYDOWN(27) = 0
58.     k$ = INKEY$
59.     IF k$ = " " THEN GOTO restart
60.     IF k$ = "t" THEN mode = 1 - mode: GOTO restart
61.     t = TIMER(.001)
62.     FOR i = 0 TO 6
63.         p(i).x = p(i).x + p(i).dx
64.         IF p(i).x > 2 * xxmax THEN p(i).dx = -p(i).dx: p(i).x = 2 * xxmax
65.         IF p(i).x < -xxmax THEN p(i).dx = -p(i).dx: p(i).x = -xxmax
66.         p(i).y = p(i).y + p(i).dy
67.         IF p(i).y > 2 * yymax THEN p(i).dy = -p(i).dy: p(i).y = 2 * yymax
68.         IF p(i).y < -yymax THEN p(i).dy = -p(i).dy: p(i).y = -yymax
69.     NEXT
70.     stepper = 3
71.     FOR y = 0 TO yymax - 1 STEP stepper
72.         FOR x = 0 TO xxmax - 1 STEP stepper
73.             d = 0
74.             FOR n = 0 TO 6
75.                 dx = x - p(n).x: dy = y - p(n).y
76.                 dist = .0005 * (dx * dx + dy * dy)
77.                 'dist = SQR(dx * dx + dy * dy)
78.                 'dist = _HYPOT(dx, dy)    'this may work faster on another system
79.                 d = d + (SIN(dist * f(n)) + 1) / 2
80.             NEXT n: d = d * 120
81.             LINE (x + xoff, y + yoff)-STEP(stepper, stepper), c(d), BF
82.         NEXT
83.     NEXT
84.     cnt = cnt + 1
85.     tot = tot + TIMER(.001) - t
86.     IF cnt = 100 THEN
87.         yCP yoff + yymax + 50, SPACE$(50)
88.         yCP yoff + yymax + 50, RIGHT$("   " + TS$(INT(1000 * tot / 100)), 4) + " ms per frame"
89.         cnt = 0: tot = 0
90.     END IF
91.     _DISPLAY
92. WEND
93.  
94. FUNCTION midInk~& (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
95.     midInk~& = _RGBA32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##, 255)
96. END FUNCTION
97.  
98. SUB yCP (y, s$) 'for xmax pixel wide graphics screen Center Print at pixel y row
99.     _PRINTSTRING ((_WIDTH - LEN(s$) * 8) / 2, y), s$
100. END SUB
101.  
102. FUNCTION TS$ (n AS INTEGER)
103.     TS$ = _TRIM$(STR$(n))
104. END FUNCTION
105.  
106.  

Plasma now gets holes in it, cool!

[johnno56]

Cool version. Runs much better than the previous... Averaging 13-14ms / frame...
Makes one nostalgic for the 70's... The decade that fashion forgot... lol

[bplus]

Update to the shell program:

Code: QB64: [Select]

1. _TITLE "Shell of another color 3" 'b+2020-01-25
2. 'inspired by "shell-like thing" by tsh73 Jan 2020 at JB
3. ' 2020-01-27 Shell of another color 3 adds more improvements
4.  
5. SCREEN _NEWIMAGE(660, 660, 32)
6. _SCREENMOVE 300, 40
7. DIM x(1600), y(1600), c AS _UNSIGNED LONG
8. cx = 340: cy = 390
9. FOR a = 0 TO _PI(8) STEP _PI(2 / 400) ' load x, y arrays
10.     x(i) = cx + ra * COS(a): y(i) = cy + ra * SIN(a)
11.     dr = dr + 1 / 1700: ra = ra + dr ^ 2: i = i + 1
12. NEXT
13. WHILE 1
14.     R = RND ^ 2: G = RND ^ 2: B = RND ^ 2: PN = 0: size = 1
15.     FOR i = 0 TO 1139
16.         dx = x(i + 400) - x(i): dy = y(i + 400) - y(i)
17.         dist = SQR(dx * dx + dy * dy): dx = dx / dist: dy = dy / dist: PN = PN + .73
18.         IF i > 820 THEN
19.             size = 3
20.         ELSEIF i > 380 THEN
21.             size = 2
22.         END IF
23.         FOR j = 0 TO dist
24.             shade = 1 - ((dist / 2 - j + 1 / 2) / (dist / 2)) ^ 2
25.             c = _RGB32(shade * INT(127 + 127 * SIN(R * PN)), shade * INT(127 + 127 * SIN(G * PN)), shade * INT(127 + 127 * SIN(B * PN)))
26.             fcirc x(i) + j * dx, y(i) + j * dy, size, c
27.         NEXT
28.     NEXT
29.     _DISPLAY
30.     _DELAY 2
31. WEND
32.  
33. 'from Steve Gold standard
34. SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
35.     DIM Radius AS INTEGER, RadiusError AS INTEGER
36.     DIM X AS INTEGER, Y AS INTEGER
37.     Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
38.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
39.     LINE (CX - X, CY)-(CX + X, CY), C, BF
40.     WHILE X > Y
41.         RadiusError = RadiusError + Y * 2 + 1
42.         IF RadiusError >= 0 THEN
43.             IF X <> Y + 1 THEN
44.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
45.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
46.             END IF
47.             X = X - 1
48.             RadiusError = RadiusError - X * 2
49.         END IF
50.         Y = Y + 1
51.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
52.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
53.     WEND
54. END SUB
55.  
56.