Cube Wave

[Ashish]

Hello everyone! :D
Now the harmonic motion comes in 3D. :)
Enjoy the cube waves.

Code: QB64: [Select]

1. 'Coded by Ashish on 12 March, 2018
2. 'Originally By @BeesandBombs
3. '[youtube]https://youtu.be/H81Tdrmz2LA[/youtube]
4.  
5. _TITLE "Cube Wave"
6.  
7. SCREEN _NEWIMAGE(800, 600, 32)
8.  
9. TYPE vec4
10.     x AS SINGLE
11.     y AS SINGLE
12.     z AS SINGLE
13.     w AS SINGLE
14. END TYPE
15.  
16. TYPE vec3
17.     x AS SINGLE
18.     y AS SINGLE
19.     z AS SINGLE
20. END TYPE
21.  
22. DECLARE LIBRARY
23.     'for camera
24.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#)
25. END DECLARE
26.  
27. DIM SHARED glAllow AS _BYTE
28. DIM SHARED cubeSize
29. cubeSize = .2
30.  
31. _GLRENDER _BEHIND
32. glAllow = -1
33. DO
34.     _DISPLAY
35.     _LIMIT 40
36. LOOP
37.  
38.  
39.  
40. SUB _GL ()
41.     STATIC glInit, aspect#, clock#, angOff#
42.  
43.     DIM lightAmb AS vec3, lightDiff AS vec3, lightSpec AS vec3, lightPos AS vec4
44.     DIM matAmb AS vec3, matDiff AS vec3, matSpec AS vec3, matShin AS SINGLE
45.  
46.     'light color settings
47.     lightAmb.x = .2: lightDiff.x = .79: lightSpec.x = .99
48.     lightAmb.y = .2: lightDiff.y = .79: lightSpec.x = .99
49.     lightAmb.z = .2: lightDiff.z = .79: lightSpec.x = .99
50.     'light direction settings ,when w=0 it is directional light, when w =1, it is a point light
51.     lightPos.x = 0
52.     lightPos.y = 0
53.     lightPos.z = 1
54.     lightPos.w = 0
55.     'material settings
56.     'try to play with it! but the value of any of these must be between 0 and 1.
57.     matAmb.x = .4: matDiff.x = .7: matSpec.x = .999
58.     matAmb.y = .7: matDiff.y = 1: matSpec.y = .999
59.     matAmb.z = .7: matDiff.z = 1: matSpec.z = .999
60.     matShin = .6
61.     '
62.  
63.     IF NOT glAllow THEN EXIT SUB
64.  
65.     _glEnable _GL_DEPTH_TEST
66.  
67.     IF NOT glInit THEN
68.         glInit = -1
69.         aspect# = _WIDTH / _HEIGHT
70.         _glViewport 0, 0, _WIDTH, _HEIGHT
71.     END IF
72.  
73.     'setuping light
74.     _glEnable _GL_LIGHTING
75.     _glEnable _GL_LIGHT0
76.     addLight _GL_LIGHT0, lightAmb, lightSpec, lightDiff, lightPos
77.  
78.     _glMatrixMode _GL_PROJECTION
79.     _glLoadIdentity
80.     'we will be using orthographic projection
81.     _glOrtho -5, 5, -5, 5, -5, 5
82.  
83.     _glMatrixMode _GL_MODELVIEW
84.     _glLoadIdentity
85.  
86.     _glTranslatef 0, 0, 0
87.     _glRotatef 45, 0, 1, 0
88.     _glRotatef 23, 0, 0, 1
89.  
90.     'give our materials.
91.     setMaterial matAmb, matSpec, matDiff, matShin
92.  
93.     'draw our cubes
94.     FOR z = -3 TO 3 STEP cubeSize + cubeSize / 1.5
95.         FOR x = -3 TO 3 STEP cubeSize + cubeSize / 1.5
96.             d = dist(0, 0, x, z) 'angle will be shifted according to the distance from the center, i.e., (0,0,0)
97.             offset = map(d, 0, SQR(18), _PI, -_PI)
98.  
99.             s# = map(SIN(offset + angOff#), -1, 1, 1, 4)
100.  
101.             _glPushMatrix
102.  
103.             _glTranslatef x, 0, z
104.             drawBox cubeSize, s#, cubeSize
105.  
106.             _glPopMatrix
107.         NEXT x
108.     NEXT z
109.  
110.     _glFlush
111.     angOff# = angOff# + .07
112.     clock# = clock# + .01
113. END SUB
114.  
115.  
116. SUB addLight (light, ambient AS vec3, specular AS vec3, diffuse AS vec3, __pos AS vec4)
117.     _glLightfv light, _GL_AMBIENT, glVec3(ambient.x, ambient.y, ambient.z)
118.     _glLightfv light, _GL_SPECULAR, glVec3(specular.x, specular.y, specular.z)
119.     _glLightfv light, _GL_DIFFUSE, glVec3(diffuse.x, diffuse.y, diffuse.z)
120.     _glLightfv light, _GL_POSITION, glVec4(__pos.x, __pos.y, __pos.z, __pos.w)
121. END SUB
122.  
123. SUB setMaterial (ambient AS vec3, specular AS vec3, diffuse AS vec3, shineness AS SINGLE)
124.     _glMaterialfv _GL_FRONT, _GL_AMBIENT, glVec3(ambient.x, ambient.y, ambient.z)
125.     _glMaterialfv _GL_FRONT, _GL_DIFFUSE, glVec3(diffuse.x, diffuse.y, diffuse.z)
126.     _glMaterialfv _GL_FRONT, _GL_SPECULAR, glVec3(specular.x, specular.y, specular.z)
127.     _glMaterialfv _GL_FRONT, _GL_SHININESS, glVec3(128 * shineness, 0, 0)
128. END SUB
129.  
130. 'sub to draw a custom box with given width, height and depth.
131. SUB drawBox (w, h, d)
132.     _glPushMatrix
133.     _glBegin _GL_QUADS
134.     'front
135.     _glNormal3f 0, 0, 1
136.     _glVertex3f -w / 2, h / 2, d / 2
137.     _glVertex3f w / 2, h / 2, d / 2
138.     _glVertex3f w / 2, -h / 2, d / 2
139.     _glVertex3f -w / 2, -h / 2, d / 2
140.     'back
141.     _glNormal3f 0, 0, -1
142.     _glVertex3f -w / 2, h / 2, -d / 2
143.     _glVertex3f w / 2, h / 2, -d / 2
144.     _glVertex3f w / 2, -h / 2, -d / 2
145.     _glVertex3f -w / 2, -h / 2, -d / 2
146.     'right
147.     _glNormal3f 1, 0, 0
148.     _glVertex3f w / 2, h / 2, d / 2
149.     _glVertex3f w / 2, h / 2, -d / 2
150.     _glVertex3f w / 2, -h / 2, -d / 2
151.     _glVertex3f w / 2, -h / 2, d / 2
152.     'left
153.     _glNormal3f -1, 0, 0
154.     _glVertex3f -w / 2, h / 2, d / 2
155.     _glVertex3f -w / 2, h / 2, -d / 2
156.     _glVertex3f -w / 2, -h / 2, -d / 2
157.     _glVertex3f -w / 2, -h / 2, d / 2
158.     'top
159.     _glNormal3f 0, 1, 0
160.     _glVertex3f -w / 2, h / 2, d / 2
161.     _glVertex3f -w / 2, h / 2, -d / 2
162.     _glVertex3f w / 2, h / 2, -d / 2
163.     _glVertex3f w / 2, h / 2, d / 2
164.     'bottom
165.     _glNormal3f 0, -1, 0
166.     _glVertex3f -w / 2, -h / 2, d / 2
167.     _glVertex3f -w / 2, -h / 2, -d / 2
168.     _glVertex3f w / 2, -h / 2, -d / 2
169.     _glVertex3f w / 2, -h / 2, d / 2
170.  
171.     _glEnd
172.     _glPopMatrix
173. END SUB
174.  
175. 'used for passing pointers to the OpenGL.
176. FUNCTION glVec3%& (x, y, z)
177.     STATIC internal_vec3(2)
178.     internal_vec3(0) = x
179.     internal_vec3(1) = y
180.     internal_vec3(2) = z
181.     glVec3%& = _OFFSET(internal_vec3())
182. END FUNCTION
183.  
184. FUNCTION glVec4%& (x, y, z, w)
185.     STATIC internal_vec4(3)
186.     internal_vec4(0) = x
187.     internal_vec4(1) = y
188.     internal_vec4(2) = z
189.     internal_vec4(3) = w
190.     glVec4%& = _OFFSET(internal_vec4())
191. END FUNCTION
192.  
193. 'taken from p5js.bas
194. FUNCTION dist! (x1!, y1!, x2!, y2!)
195.     dist! = SQR((x2! - x1!) ^ 2 + (y2! - y1!) ^ 2)
196. END FUNCTION
197.  
198.  
199. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
200.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
201. END FUNCTION
202.  
203.  

[bplus]

Once again I am inspired by Ashish example and attempt a similar thing from a different angle.

Here is Johnno's Gold Wave translated from SmallBASIC to QB64 in 2 ways:
1. First I tried the old fashioned way with line filled triangles.
2. Then I tried a very simple _MAPTRIANGLE method which turns out to be allot speedier if you remember _FREEIMAGE

Code: QB64: [Select]

1. _TITLE "Gold Wave bplus 2018-03-13"
2. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
3.  
4. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
5. CONST xmax = 600
6. CONST ymax = 480
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 360, 60
9. DIM ccc AS _UNSIGNED LONG
10.  
11.  
12. '                  compare fill triangle subs:  one uses very simple  _MAPTRIANGLE opt = 1
13. '                                               2nd uses primative line graphic0s  opt <> 1
14.  
15.  
16. opt = 1 ' << opt 1 uses _MAPTRIANGLE to fill triangles, any other uses line filled triangles
17. WHILE 1
18.     FOR t = 1 TO 60 STEP .1 '< changed
19.         CLS 'changed
20.         FOR y1 = 0 TO 24
21.             FOR x1 = 0 TO 24
22.                 x = (12 * (24 - x1)) + (12 * y1)
23.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
24.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
25.                 h = 60 * SIN(x1 / 4 + t) + 65
26.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
27.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
28.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
29.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
30.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
31.                 IF opt = 1 THEN
32.                     'TOP
33.                     ccc = _RGB32(242 + .1 * h, 242 + .1 * h, h)
34.                     filltri x, y - h, x + 10, y + 5 - h, x + 20, y - h, ccc
35.                     filltri x, y - h, x + 10, y - 5 - h, x + 20, y - h, ccc
36.                     'FRONT-LEFT
37.                     ccc = _RGB(255, 80, 0)
38.                     filltri x, y - h, x + 10, y + 5 - h, x + 10, y, ccc
39.                     filltri x, y - h, x, y - 5, x + 10, y, ccc
40.                     'FRONT-RIGHT
41.                     ccc = _RGB32(255, 150, 0)
42.                     filltri x + 10, y + 5 - h, x + 10, y, x + 20, y - 5, ccc
43.                     filltri x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5, ccc
44.                 ELSE
45.                     COLOR _RGB32(242 + .1 * h, 242 + .1 * h, h)
46.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 20, y - h
47.                     filltri2 x, y - h, x + 10, y - 5 - h, x + 20, y - h
48.                     'FRONT-LEFT
49.                     COLOR _RGB32(255, 80, 0)
50.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 10, y
51.                     filltri2 x, y - h, x, y - 5, x + 10, y
52.                     COLOR _RGB32(255, 150, 0)
53.                     filltri2 x + 10, y + 5 - h, x + 10, y, x + 20, y - 5
54.                     filltri2 x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5
55.                 END IF
56.  
57.                 IF INKEY$ = CHR$(27) THEN END
58.             NEXT
59.         NEXT
60.         _DISPLAY
61.         _LIMIT 200  'to compare speeds
62.     NEXT
63. WEND
64.  
65. 'Andy Amaya's modified FillTriangle
66. SUB filltri2 (xx1, yy1, xx2, yy2, xx3, yy3)
67.     'make copies before swapping
68.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2: x3 = xx3: y3 = yy3
69.     'thanks Andy Amaya!
70.     'triangle coordinates must be ordered: where x1 < x2 < x3
71.     IF x2 < x1 THEN SWAP x1, x2: SWAP y1, y2
72.     IF x3 < x1 THEN SWAP x1, x3: SWAP y1, y3
73.     IF x3 < x2 THEN SWAP x2, x3: SWAP y2, y3
74.     IF x1 <> x3 THEN slope1 = (y3 - y1) / (x3 - x1)
75.  
76.     'draw the first half of the triangle
77.     length = x2 - x1
78.     IF length <> 0 THEN
79.         slope2 = (y2 - y1) / (x2 - x1)
80.         FOR x = 0 TO length
81.             LINE (INT(x + x1), INT(x * slope1 + y1))-(INT(x + x1), INT(x * slope2 + y1))
82.             'lastx2% = lastx%
83.             lastx% = INT(x + x1)
84.         NEXT
85.     END IF
86.  
87.     'draw the second half of the triangle
88.     y = length * slope1 + y1: length = x3 - x2
89.     IF length <> 0 THEN
90.         slope3 = (y3 - y2) / (x3 - x2)
91.         FOR x = 0 TO length
92.             'IF INT(x + x2) <> lastx% AND INT(x + x2) <> lastx2% THEN  'works! but need 2nd? check
93.             IF INT(x + x2) <> lastx% THEN
94.                 LINE (INT(x + x2), INT(x * slope1 + y))-(INT(x + x2), INT(x * slope3 + y2))
95.             END IF
96.         NEXT
97.     END IF
98. END SUB
99.  
100. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
101. SUB filltri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
102.     a = _NEWIMAGE(1, 1, 32)
103.     _DEST a
104.     PSET (0, 0), K
105.     _DEST 0
106.     _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a TO(x1, y1)-(x2, y2)-(x3, y3)
107.     _FREEIMAGE a '<<< this is important!
108. END SUB
109.  
110.  

[Ashish]

This is really cool bplus! I like it a lot!

[FellippeHeitor]

Amazing results both with OpenGL and with pure QB64. Kudos to both of you guys. These are really cool.

[FellippeHeitor]

My mod to gold wave to turn it into "Trippy Bedsheet Swing With Morphing Colors":

Code: QB64: [Select]

1. _TITLE "Trippy Bedsheet Swing With Morphing Colors"
2. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
3. 'trippy bedsheet mod by fellippeheitor 2018-03-14
4.  
5. CONST xmax = 600
6. CONST ymax = 480
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 360, 60
9. DIM ccc AS _UNSIGNED LONG
10.  
11.  
12. '                  compare fill triangle subs:  one uses very simple  _MAPTRIANGLE opt = 1
13. '                                               2nd uses primative line graphic0s  opt <> 1
14.  
15.  
16. opt = 1 ' << opt 1 uses _MAPTRIANGLE to fill triangles, any other uses line filled triangles
17.  
18. DIM r AS _UNSIGNED _BYTE, g AS _UNSIGNED _BYTE, b AS _UNSIGNED _BYTE
19. r = 0
20. g = 65
21. b = 127
22. WHILE 1
23.     r = r + 15
24.     g = g + 15
25.     b = b + 15
26.     ccc = _RGB32(r, g, b)
27.     FOR t = 50.5 TO 56.6 STEP .1 '< changed
28.         CLS 'changed
29.         FOR y1 = 0 TO 24
30.             FOR x1 = 0 TO 24
31.                 x = (12 * (24 - x1)) + (12 * y1)
32.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
33.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
34.                 h = 60 * SIN(x1 / 4 + t) + 65
35.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
36.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
37.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
38.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
39.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
40.                 IF opt = 1 THEN
41.                     'TOP
42.                     filltri x, y - h, x + 10, y + 5 - h, x + 20, y - h, Shade(ccc, h)
43.                     filltri x, y - h, x + 10, y - 5 - h, x + 20, y - h, Shade(ccc, h)
44.                     ''FRONT-LEFT
45.                     'filltri x, y - h, x + 10, y + 5 - h, x + 10, y, Shade(ccc, 40)
46.                     'filltri x, y - h, x, y - 5, x + 10, y, Shade(ccc, 40)
47.                     ''FRONT-RIGHT
48.                     'filltri x + 10, y + 5 - h, x + 10, y, x + 20, y - 5, Shade(ccc, 120)
49.                     'filltri x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5, Shade(ccc, 120)
50.                 ELSE
51.                     COLOR _RGB32(242 + .1 * h, 242 + .1 * h, h)
52.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 20, y - h
53.                     filltri2 x, y - h, x + 10, y - 5 - h, x + 20, y - h
54.                     'FRONT-LEFT
55.                     COLOR _RGB32(255, 80, 0)
56.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 10, y
57.                     filltri2 x, y - h, x, y - 5, x + 10, y
58.                     COLOR _RGB32(255, 150, 0)
59.                     filltri2 x + 10, y + 5 - h, x + 10, y, x + 20, y - 5
60.                     filltri2 x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5
61.                 END IF
62.  
63.                 IF INKEY$ = CHR$(27) THEN END
64.             NEXT
65.         NEXT
66.         _DISPLAY
67.         _LIMIT 30 'to compare speeds
68.     NEXT
69. WEND
70.  
71. 'Andy Amaya's modified FillTriangle
72. SUB filltri2 (xx1, yy1, xx2, yy2, xx3, yy3)
73.     'make copies before swapping
74.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2: x3 = xx3: y3 = yy3
75.     'thanks Andy Amaya!
76.     'triangle coordinates must be ordered: where x1 < x2 < x3
77.     IF x2 < x1 THEN SWAP x1, x2: SWAP y1, y2
78.     IF x3 < x1 THEN SWAP x1, x3: SWAP y1, y3
79.     IF x3 < x2 THEN SWAP x2, x3: SWAP y2, y3
80.     IF x1 <> x3 THEN slope1 = (y3 - y1) / (x3 - x1)
81.  
82.     'draw the first half of the triangle
83.     length = x2 - x1
84.     IF length <> 0 THEN
85.         slope2 = (y2 - y1) / (x2 - x1)
86.         FOR x = 0 TO length
87.             LINE (INT(x + x1), INT(x * slope1 + y1))-(INT(x + x1), INT(x * slope2 + y1))
88.             'lastx2% = lastx%
89.             lastx% = INT(x + x1)
90.         NEXT
91.     END IF
92.  
93.     'draw the second half of the triangle
94.     y = length * slope1 + y1: length = x3 - x2
95.     IF length <> 0 THEN
96.         slope3 = (y3 - y2) / (x3 - x2)
97.         FOR x = 0 TO length
98.             'IF INT(x + x2) <> lastx% AND INT(x + x2) <> lastx2% THEN  'works! but need 2nd? check
99.             IF INT(x + x2) <> lastx% THEN
100.                 LINE (INT(x + x2), INT(x * slope1 + y))-(INT(x + x2), INT(x * slope3 + y2))
101.             END IF
102.         NEXT
103.     END IF
104. END SUB
105.  
106. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
107. SUB filltri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
108.     a = _NEWIMAGE(1, 1, 32)
109.     _DEST a
110.     PSET (0, 0), K
111.     _DEST 0
112.     _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a TO(x1, y1)-(x2, y2)-(x3, y3)
113.     _FREEIMAGE a '<<< this is important!
114. END SUB
115.  
116. FUNCTION Shade~& (WhichColor~&, ByHowMuch%)
117.     Shade~& = _RGB32(_RED32(WhichColor~&) * (ByHowMuch% / 100), _GREEN32(WhichColor~&) * (ByHowMuch% / 100), _BLUE32(WhichColor~&) * (ByHowMuch% / 100))
118. END FUNCTION
119.  

[Ashish]

@Fellippe
Very nice mod! Amazing effect with shading colors.

[FellippeHeitor]

Modded once again (my last, I promisse) to use HSB color space and provide smooth color transition.

Code: QB64: [Select]

1. _TITLE "Trippy Bedsheet Swing With Morphing Colors"
2. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
3. 'trippy bedsheet mod by fellippeheitor 2018-03-14
4.  
5. CONST xmax = 600
6. CONST ymax = 480
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 360, 60
9. DIM ccc AS _UNSIGNED LONG
10. '_FULLSCREEN _SQUAREPIXELS , _SMOOTH
11.  
12. '                  compare fill triangle subs:  one uses very simple  _MAPTRIANGLE opt = 1
13. '                                               2nd uses primative line graphic0s  opt <> 1
14.  
15.  
16. opt = 1 ' << opt 1 uses _MAPTRIANGLE to fill triangles, any other uses line filled triangles
17.  
18. DIM angle
19. WHILE 1
20.     ccc = hsb(angle, 127, 127, 255)
21.     angle = angle + 10
22.     FOR t = 50.5 TO 56.7 STEP .1 '< changed
23.         CLS 'changed
24.         FOR y1 = 0 TO 24
25.             FOR x1 = 0 TO 24
26.                 x = (12 * (24 - x1)) + (12 * y1)
27.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
28.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
29.                 h = 60 * SIN(x1 / 4 + t) + 65
30.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
31.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
32.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
33.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
34.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
35.                 IF opt = 1 THEN
36.                     'TOP
37.                     filltri x, y - h, x + 10, y + 5 - h, x + 20, y - h, Shade(ccc, h)
38.                     filltri x, y - h, x + 10, y - 5 - h, x + 20, y - h, Shade(ccc, h)
39.                     ''FRONT-LEFT
40.                     'filltri x, y - h, x + 10, y + 5 - h, x + 10, y, Shade(ccc, h * .4)
41.                     'filltri x, y - h, x, y - 5, x + 10, y, Shade(ccc, h * .4)
42.                     ''FRONT-RIGHT
43.                     'filltri x + 10, y + 5 - h, x + 10, y, x + 20, y - 5, Shade(ccc, h * 1.2)
44.                     'filltri x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5, Shade(ccc, h * 1.2)
45.                 ELSE
46.                     COLOR _RGB32(242 + .1 * h, 242 + .1 * h, h)
47.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 20, y - h
48.                     filltri2 x, y - h, x + 10, y - 5 - h, x + 20, y - h
49.                     'FRONT-LEFT
50.                     COLOR _RGB32(255, 80, 0)
51.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 10, y
52.                     filltri2 x, y - h, x, y - 5, x + 10, y
53.                     COLOR _RGB32(255, 150, 0)
54.                     filltri2 x + 10, y + 5 - h, x + 10, y, x + 20, y - 5
55.                     filltri2 x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5
56.                 END IF
57.  
58.                 IF INKEY$ = CHR$(27) THEN SYSTEM
59.             NEXT
60.         NEXT
61.         _DISPLAY
62.         IF iconSetup = 0 THEN iconSetup = -1: _ICON _DEST
63.         _LIMIT 24 'to compare speeds
64.     NEXT
65. WEND
66.  
67. 'Andy Amaya's modified FillTriangle
68. SUB filltri2 (xx1, yy1, xx2, yy2, xx3, yy3)
69.     'make copies before swapping
70.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2: x3 = xx3: y3 = yy3
71.     'thanks Andy Amaya!
72.     'triangle coordinates must be ordered: where x1 < x2 < x3
73.     IF x2 < x1 THEN SWAP x1, x2: SWAP y1, y2
74.     IF x3 < x1 THEN SWAP x1, x3: SWAP y1, y3
75.     IF x3 < x2 THEN SWAP x2, x3: SWAP y2, y3
76.     IF x1 <> x3 THEN slope1 = (y3 - y1) / (x3 - x1)
77.  
78.     'draw the first half of the triangle
79.     length = x2 - x1
80.     IF length <> 0 THEN
81.         slope2 = (y2 - y1) / (x2 - x1)
82.         FOR x = 0 TO length
83.             LINE (INT(x + x1), INT(x * slope1 + y1))-(INT(x + x1), INT(x * slope2 + y1))
84.             'lastx2% = lastx%
85.             lastx% = INT(x + x1)
86.         NEXT
87.     END IF
88.  
89.     'draw the second half of the triangle
90.     y = length * slope1 + y1: length = x3 - x2
91.     IF length <> 0 THEN
92.         slope3 = (y3 - y2) / (x3 - x2)
93.         FOR x = 0 TO length
94.             'IF INT(x + x2) <> lastx% AND INT(x + x2) <> lastx2% THEN  'works! but need 2nd? check
95.             IF INT(x + x2) <> lastx% THEN
96.                 LINE (INT(x + x2), INT(x * slope1 + y))-(INT(x + x2), INT(x * slope3 + y2))
97.             END IF
98.         NEXT
99.     END IF
100. END SUB
101.  
102. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
103. SUB filltri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
104.     a = _NEWIMAGE(1, 1, 32)
105.     _DEST a
106.     PSET (0, 0), K
107.     _DEST 0
108.     _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a TO(x1, y1)-(x2, y2)-(x3, y3)
109.     _FREEIMAGE a '<<< this is important!
110. END SUB
111.  
112. FUNCTION Shade~& (WhichColor~&, ByHowMuch%)
113.     Shade~& = _RGB32(_RED32(WhichColor~&) * (ByHowMuch% / 100), _GREEN32(WhichColor~&) * (ByHowMuch% / 100), _BLUE32(WhichColor~&) * (ByHowMuch% / 100))
114. END FUNCTION
115.  
116. 'Functions below come from p5js.bas
117. FUNCTION hsb~& (__H AS _FLOAT, __S AS _FLOAT, __B AS _FLOAT, A AS _FLOAT)
118.     DIM H AS _FLOAT, S AS _FLOAT, B AS _FLOAT
119.  
120.     H = map(__H, 0, 255, 0, 360)
121.     S = map(__S, 0, 255, 0, 1)
122.     B = map(__B, 0, 255, 0, 1)
123.  
124.     IF S = 0 THEN
125.         hsb~& = _RGBA32(B * 255, B * 255, B * 255, A)
126.         EXIT FUNCTION
127.     END IF
128.  
129.     DIM fmx AS _FLOAT, fmn AS _FLOAT
130.     DIM fmd AS _FLOAT, iSextant AS INTEGER
131.     DIM imx AS INTEGER, imd AS INTEGER, imn AS INTEGER
132.  
133.     IF B > .5 THEN
134.         fmx = B - (B * S) + S
135.         fmn = B + (B * S) - S
136.     ELSE
137.         fmx = B + (B * S)
138.         fmn = B - (B * S)
139.     END IF
140.  
141.     iSextant = INT(H / 60)
142.  
143.     IF H >= 300 THEN
144.         H = H - 360
145.     END IF
146.  
147.     H = H / 60
148.     H = H - (2 * INT(((iSextant + 1) MOD 6) / 2))
149.  
150.     IF iSextant MOD 2 = 0 THEN
151.         fmd = (H * (fmx - fmn)) + fmn
152.     ELSE
153.         fmd = fmn - (H * (fmx - fmn))
154.     END IF
155.  
156.     imx = _ROUND(fmx * 255)
157.     imd = _ROUND(fmd * 255)
158.     imn = _ROUND(fmn * 255)
159.  
160.     SELECT CASE INT(iSextant)
161.         CASE 1
162.             hsb~& = _RGBA32(imd, imx, imn, A)
163.         CASE 2
164.             hsb~& = _RGBA32(imn, imx, imd, A)
165.         CASE 3
166.             hsb~& = _RGBA32(imn, imd, imx, A)
167.         CASE 4
168.             hsb~& = _RGBA32(imd, imn, imx, A)
169.         CASE 5
170.             hsb~& = _RGBA32(imx, imn, imd, A)
171.         CASE ELSE
172.             hsb~& = _RGBA32(imx, imd, imn, A)
173.     END SELECT
174.  
175. END FUNCTION
176.  
177. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
178.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
179. END FUNCTION
180.  

[Petr]

All this code are nice.

[bplus]

Did someone say "Trippy":

Code: QB64: [Select]

1. _TITLE "Trippy Wave bplus 2018-03-14"
2. ' mod Gold Wave
3. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
4.  
5. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
6. CONST xmax = 600
7. CONST ymax = 480
8. SCREEN _NEWIMAGE(xmax, ymax, 32)
9. _SCREENMOVE 360, 60
10. DIM SHARED cN, pR, pG, pB
11. DIM ccc AS _UNSIGNED LONG
12. RANDOMIZE TIMER
13.  
14. WHILE 1
15.     resetPlasma
16.     FOR t = 1 TO 60 STEP .1 '< changed
17.         toggle = (toggle + 1) MOD 16
18.         IF toggle MOD 16 = 0 THEN CLS
19.         CLS 'changed
20.         FOR y1 = 0 TO 24
21.             FOR x1 = 0 TO 24
22.                 x = (12 * (24 - x1)) + (12 * y1)
23.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
24.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
25.                 h = 60 * SIN(x1 / 4 + t) + 65
26.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
27.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
28.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
29.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
30.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
31.                 'TOP
32.                 ccc&& = changePlasma
33.                 filltri x, y - h, x + 10, y + 5 - h, x + 20, y - h, ccc&&
34.                 filltri x, y - h, x + 10, y - 5 - h, x + 20, y - h, ccc&&
35.                 'FRONT-LEFT
36.                 ccc = _RGBA32(200, 200, 200, 80)
37.                 filltri x, y - h, x + 10, y + 5 - h, x + 10, y, ccc
38.                 filltri x, y - h, x, y - 5, x + 10, y, ccc
39.                 'FRONT-RIGHT
40.                 ccc = _RGBA32(155, 155, 155, 80)
41.                 filltri x + 10, y + 5 - h, x + 10, y, x + 20, y - 5, ccc
42.                 filltri x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5, ccc
43.                 IF INKEY$ = CHR$(27) THEN END
44.             NEXT
45.         NEXT
46.         _DISPLAY
47.         _LIMIT 20
48.     NEXT
49. WEND
50.  
51. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
52. SUB filltri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
53.     a& = _NEWIMAGE(1, 1, 32)
54.     _DEST a&
55.     PSET (0, 0), K
56.     _DEST 0
57.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
58.     _FREEIMAGE a& '<<< this is important!
59. END SUB
60.  
61. FUNCTION changePlasma&& ()
62.     cN = cN + 1
63.     changePlasma&& = _RGB32(127 + 127 * SIN(pR * cN), 127 + 127 * SIN(pG * cN), 127 + 127 * SIN(pB * cN))
64. END SUB
65.  
66. SUB resetPlasma ()
67.     pR = .1 * RND ^ 2: pG = .1 * RND ^ 2: pB = .1 * RND ^ 2
68. END SUB
69.  

[FellippeHeitor]

Where's your seizure warning, man?

[FellippeHeitor]

Smoother color morphing.

Code: QB64: [Select]

1. _TITLE "Trippy Bedsheet Swing With Morphing Colors"
2. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
3. 'trippy bedsheet mod by fellippeheitor 2018-03-14
4.  
5. CONST xmax = 600
6. CONST ymax = 480
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 360, 60
9. DIM ccc AS _UNSIGNED LONG
10. '_FULLSCREEN _SQUAREPIXELS , _SMOOTH
11.  
12. '                  compare fill triangle subs:  one uses very simple  _MAPTRIANGLE opt = 1
13. '                                               2nd uses primative line graphic0s  opt <> 1
14.  
15.  
16. opt = 1 ' << opt 1 uses _MAPTRIANGLE to fill triangles, any other uses line filled triangles
17.  
18. DIM angle
19. WHILE 1
20.     FOR t = 50.5 TO 56.7 STEP .01 '< changed
21.         CLS 'changed
22.         ccc = hsb(angle, 127, 127, 255)
23.         angle = angle + .1
24.         IF angle > 359 THEN angle = 0
25.         FOR y1 = 0 TO 24
26.             FOR x1 = 0 TO 24
27.                 x = (12 * (24 - x1)) + (12 * y1)
28.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
29.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
30.                 h = 60 * SIN(x1 / 4 + t) + 65
31.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
32.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
33.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
34.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
35.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
36.                 IF opt = 1 THEN
37.                     'TOP
38.                     filltri x, y - h, x + 10, y + 5 - h, x + 20, y - h, Shade(ccc, h)
39.                     filltri x, y - h, x + 10, y - 5 - h, x + 20, y - h, Shade(ccc, h)
40.                     ''FRONT-LEFT
41.                     'filltri x, y - h, x + 10, y + 5 - h, x + 10, y, Shade(ccc, h * .4)
42.                     'filltri x, y - h, x, y - 5, x + 10, y, Shade(ccc, h * .4)
43.                     ''FRONT-RIGHT
44.                     'filltri x + 10, y + 5 - h, x + 10, y, x + 20, y - 5, Shade(ccc, h * 1.2)
45.                     'filltri x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5, Shade(ccc, h * 1.2)
46.                 ELSE
47.                     COLOR _RGB32(242 + .1 * h, 242 + .1 * h, h)
48.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 20, y - h
49.                     filltri2 x, y - h, x + 10, y - 5 - h, x + 20, y - h
50.                     'FRONT-LEFT
51.                     COLOR _RGB32(255, 80, 0)
52.                     filltri2 x, y - h, x + 10, y + 5 - h, x + 10, y
53.                     filltri2 x, y - h, x, y - 5, x + 10, y
54.                     COLOR _RGB32(255, 150, 0)
55.                     filltri2 x + 10, y + 5 - h, x + 10, y, x + 20, y - 5
56.                     filltri2 x + 10, y + 5 - h, x + 20, y - h, x + 20, y - 5
57.                 END IF
58.  
59.                 IF INKEY$ = CHR$(27) THEN SYSTEM
60.             NEXT
61.         NEXT
62.         _DISPLAY
63.         IF iconSetup = 0 THEN iconSetup = -1: _ICON _DEST
64.         _LIMIT 60 'to compare speeds
65.     NEXT
66. WEND
67.  
68. 'Andy Amaya's modified FillTriangle
69. SUB filltri2 (xx1, yy1, xx2, yy2, xx3, yy3)
70.     'make copies before swapping
71.     x1 = xx1: y1 = yy1: x2 = xx2: y2 = yy2: x3 = xx3: y3 = yy3
72.     'thanks Andy Amaya!
73.     'triangle coordinates must be ordered: where x1 < x2 < x3
74.     IF x2 < x1 THEN SWAP x1, x2: SWAP y1, y2
75.     IF x3 < x1 THEN SWAP x1, x3: SWAP y1, y3
76.     IF x3 < x2 THEN SWAP x2, x3: SWAP y2, y3
77.     IF x1 <> x3 THEN slope1 = (y3 - y1) / (x3 - x1)
78.  
79.     'draw the first half of the triangle
80.     length = x2 - x1
81.     IF length <> 0 THEN
82.         slope2 = (y2 - y1) / (x2 - x1)
83.         FOR x = 0 TO length
84.             LINE (INT(x + x1), INT(x * slope1 + y1))-(INT(x + x1), INT(x * slope2 + y1))
85.             'lastx2% = lastx%
86.             lastx% = INT(x + x1)
87.         NEXT
88.     END IF
89.  
90.     'draw the second half of the triangle
91.     y = length * slope1 + y1: length = x3 - x2
92.     IF length <> 0 THEN
93.         slope3 = (y3 - y2) / (x3 - x2)
94.         FOR x = 0 TO length
95.             'IF INT(x + x2) <> lastx% AND INT(x + x2) <> lastx2% THEN  'works! but need 2nd? check
96.             IF INT(x + x2) <> lastx% THEN
97.                 LINE (INT(x + x2), INT(x * slope1 + y))-(INT(x + x2), INT(x * slope3 + y2))
98.             END IF
99.         NEXT
100.     END IF
101. END SUB
102.  
103. ' found at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]:    http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=14425.0
104. SUB filltri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
105.     a = _NEWIMAGE(1, 1, 32)
106.     _DEST a
107.     PSET (0, 0), K
108.     _DEST 0
109.     _MAPTRIANGLE (0, 0)-(0, 0)-(0, 0), a TO(x1, y1)-(x2, y2)-(x3, y3)
110.     _FREEIMAGE a '<<< this is important!
111. END SUB
112.  
113. FUNCTION Shade~& (WhichColor~&, ByHowMuch%)
114.     Shade~& = _RGB32(_RED32(WhichColor~&) * (ByHowMuch% / 100), _GREEN32(WhichColor~&) * (ByHowMuch% / 100), _BLUE32(WhichColor~&) * (ByHowMuch% / 100))
115. END FUNCTION
116.  
117. FUNCTION hsb~& (__H AS _FLOAT, __S AS _FLOAT, __B AS _FLOAT, A AS _FLOAT)
118.     DIM H AS _FLOAT, S AS _FLOAT, B AS _FLOAT
119.  
120.     H = map(__H, 0, 255, 0, 360)
121.     S = map(__S, 0, 255, 0, 1)
122.     B = map(__B, 0, 255, 0, 1)
123.  
124.     IF S = 0 THEN
125.         hsb~& = _RGBA32(B * 255, B * 255, B * 255, A)
126.         EXIT FUNCTION
127.     END IF
128.  
129.     DIM fmx AS _FLOAT, fmn AS _FLOAT
130.     DIM fmd AS _FLOAT, iSextant AS INTEGER
131.     DIM imx AS INTEGER, imd AS INTEGER, imn AS INTEGER
132.  
133.     IF B > .5 THEN
134.         fmx = B - (B * S) + S
135.         fmn = B + (B * S) - S
136.     ELSE
137.         fmx = B + (B * S)
138.         fmn = B - (B * S)
139.     END IF
140.  
141.     iSextant = INT(H / 60)
142.  
143.     IF H >= 300 THEN
144.         H = H - 360
145.     END IF
146.  
147.     H = H / 60
148.     H = H - (2 * INT(((iSextant + 1) MOD 6) / 2))
149.  
150.     IF iSextant MOD 2 = 0 THEN
151.         fmd = (H * (fmx - fmn)) + fmn
152.     ELSE
153.         fmd = fmn - (H * (fmx - fmn))
154.     END IF
155.  
156.     imx = _ROUND(fmx * 255)
157.     imd = _ROUND(fmd * 255)
158.     imn = _ROUND(fmn * 255)
159.  
160.     SELECT CASE INT(iSextant)
161.         CASE 1
162.             hsb~& = _RGBA32(imd, imx, imn, A)
163.         CASE 2
164.             hsb~& = _RGBA32(imn, imx, imd, A)
165.         CASE 3
166.             hsb~& = _RGBA32(imn, imd, imx, A)
167.         CASE 4
168.             hsb~& = _RGBA32(imd, imn, imx, A)
169.         CASE 5
170.             hsb~& = _RGBA32(imx, imn, imd, A)
171.         CASE ELSE
172.             hsb~& = _RGBA32(imx, imd, imn, A)
173.     END SELECT
174.  
175. END FUNCTION
176.  
177. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
178.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
179. END FUNCTION
180.  

[Ashish]

Nice Fellippe!

[bplus]

It's nice but I don't see anybody being awoken by it.

Now a ball might be something!

Where is Pete?

[bplus]

Trippy Wave Ball Mod:

Code: QB64: [Select]

1. _TITLE "Trippy Wave Ball Mod bplus 2018-03-20"
2. '2018-03-20 just screwing around more with Ball stuff
3. ' mod Gold Wave
4. 'translated from SmallBASIC: Goldwave by johnno copied and mod by bplus 2018-01-28
5.  
6. 'QB64 version 2017 1106/82 (the day before they switched to version 1.2)
7. CONST xmax = 600
8. CONST ymax = 480
9. SCREEN _NEWIMAGE(xmax, ymax, 32)
10. _SCREENMOVE 360, 60
11. DIM SHARED cN, pR, pG, pB
12. DIM ccc AS _UNSIGNED LONG
13. RANDOMIZE TIMER
14.  
15. WHILE 1
16.     resetPlasma
17.     FOR t = 1 TO 60 STEP .1 '< changed
18.         toggle = (toggle + 1) MOD 16
19.         IF toggle MOD 16 = 0 THEN CLS
20.         CLS 'changed
21.         FOR y1 = 0 TO 24
22.             FOR x1 = 0 TO 24
23.                 x = (12 * (24 - x1)) + (12 * y1)
24.                 y = (-6 * (24 - x1)) + (6 * y1) + 300
25.                 d = ((10 - x1) ^ 2 + (10 - y1) ^ 2) ^ .5
26.                 h = 60 * SIN(x1 / 4 + t) + 65
27.                 IF t > 10 AND t < 20 THEN h = 60 * SIN(y1 / 4 + t) + 65
28.                 IF t > 20 AND t < 30 THEN h = 60 * SIN((x1 - y1) / 4 + t) + 65
29.                 IF t > 30 AND t < 40 THEN h = 30 * SIN(x1 / 2 + t) + 30 * SIN(y1 / 2 + t) + 65
30.                 IF t > 40 AND t < 50 THEN h = 60 * SIN((x1 + y1) / 4 + t) + 65
31.                 IF t > 50 AND t < 60 THEN h = 60 * SIN(d * .3 + t) + 65
32.                 'TOP
33.                 FOR r = 20 TO 1 STEP -4
34.                     ccc&& = changePlasma
35.                     fcirc x + 10, y - h, r
36.                 NEXT
37.                 IF INKEY$ = CHR$(27) THEN END
38.             NEXT
39.         NEXT
40.         _DISPLAY
41.         _LIMIT 20
42.     NEXT
43. WEND
44.  
45. FUNCTION changePlasma&& ()
46.     cN = cN + .05
47.     COLOR _RGB32(127 + 127 * SIN(pR * cN), 127 + 127 * SIN(pG * cN), 127 + 127 * SIN(pB * cN))
48. END SUB
49.  
50. SUB resetPlasma ()
51.     pR = .1 * RND ^ 2: pG = .1 * RND ^ 2: pB = .1 * RND ^ 2
52. END SUB
53.  
54. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
55. SUB fcirc (CX AS LONG, CY AS LONG, R AS LONG)
56.     DIM subRadius AS LONG, RadiusError AS LONG
57.     DIM X AS LONG, Y AS LONG
58.  
59.     subRadius = ABS(R)
60.     RadiusError = -subRadius
61.     X = subRadius
62.     Y = 0
63.  
64.     IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
65.  
66.     ' Draw the middle span here so we don't draw it twice in the main loop,
67.     ' which would be a problem with blending turned on.
68.     LINE (CX - X, CY)-(CX + X, CY), , BF
69.  
70.     WHILE X > Y
71.         RadiusError = RadiusError + Y * 2 + 1
72.         IF RadiusError >= 0 THEN
73.             IF X <> Y + 1 THEN
74.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
75.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
76.             END IF
77.             X = X - 1
78.             RadiusError = RadiusError - X * 2
79.         END IF
80.         Y = Y + 1
81.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
82.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
83.     WEND
84. END SUB
85.