qXed: fairly-polished text editor

[STxAxTIC]

Hello all,

Some of you remember the qXed project from almost a year ago, and real veterans know what the X stands for - but we aren't digging up ancient history here. I did a small bit of streamlining on the text editor I started, and figure there's no better time to familiarize everyone with its quirks and thereby trigger a crusade where bplus and/or Steve venture to code up a Notepad clone - but I digress. Really this post is to prototype a Samples entry for this code.

So I bring you qXed without any extras - you can open, edit and save text. Right now the file size limits to 128000 characters for no good reason. The code box below needs no extras, you just compile and run. Drag your own file onto the compiled exe if you don't want to read Terence Mckenna.

The controls are not precisely trivial, but a far easier learning curve than vim or emacs. So here goes... In alphabetical order...

Copy/Paste
Text that is highlighted by right-clicking (See Cursors) is copied to the clipboard. Clicking Mouse 3 will paste the clipboard contents into the text before Cursor 1. Press F3 to highlight and copy the row occupied by Cursor 1.

Cursors
A pair of "block" cursors are used to navigate and influence text. Left-clicking places Cursor 1 (teal), and right-clicking places Cursor 2 (brown). Cursor 2 is only visible and functional when placed after Cursor 1 (otherwise it vanishes). The text between Cursor 1 and Cursor 2 is considered highlighted. Cursor 2 does not move while editing text or scrolling, while Cursor 1 is the main "pointer" that stays in view at all times.

Cursor Overlap / Mode
When Cursor 1 and Cursor 2 highlight the same character, the color turns to violet, and the insert mode inverts. That is, new keyboard input will appear to the left of violet cursor(s), otherwise new input appears to the right. The Esc key moves Cursor 2 alternatively between the Cursor 1 position and the first character in the file, and thus acts as a "mode" key.

Formatting
There are no hidden or implied text formatting options or symbols: only alphanumeric characters and break returns are allowed. Tabs are translated into spaces. By toggling the F11 key, break returns and whitespace are shown using the tilde (~) and underscore (_) symbols, respectively.

Navigation
Cursors are confined to locate within the body of the text - only the mouse pointer can land in the meaningless black space where no text yet exists. Cursor 1 can be moved respectively using arrow keys to move through rows and columns. To scroll larger distances, the PgUp and PgDn keys bring Cursor 1 up/down several rows. In a given row, the Home and End keys move Cursor 1 to the beginning or end of a row, respectively. The mouse wheel is presently coded to imitate the up/down arrow keys. For unwrapped text with a horizontal span great than the screen width, the F1 ad F2 keys scroll left and right, respectively.

Save/Load
The F6 key saves the present text body to disk using a unique filename. A text file can be loaded by dragging it onto the compiled executable.

Scrollbars
The bottom- and right-edges of the window contain bookmarks that track Cursor 1 within the text body. The horizontal bookmark's position in the window is proportional to the Cursor's horizontal position in the present row. (I call it Zeno scrolling.)

Wrapping
There are three text wrapping modes: square, fluid, and none. Pressing F12 toggles between each mode.

Code: QB64: [Select]

1. '$EXEICON:'qXedlogo.ico'
2. '$RESIZE:ON
3.  
4. 'REM $Include: 'sxmath.bi'
5. 'REM $Include: 'sxript.bi'
6.  
7. scrHand& = _NEWIMAGE(90, 30, 0)
8. SCREEN scrHand&
9. '_FREEIMAGE scrHand&
10.  
11. ' Define fundamental structures.
12. TYPE Vector
13.     X AS INTEGER
14.     Y AS INTEGER
15. END TYPE
16.  
17. TYPE Cell
18.     Identity AS LONG
19.     Pointer AS LONG
20.     Lagger AS LONG
21.     Content AS STRING * 1
22. END TYPE
23.  
24. DIM SHARED ChainLimit AS LONG
25. DIM SHARED BOC AS LONG ' Beginning of chain.
26. DIM SHARED EOC AS LONG ' End of chain.
27. ChainLimit = 128000
28. BOC = -1
29. EOC = ChainLimit
30.  
31. ' Define text window properties.
32. DIM SHARED WindowHeight
33. DIM SHARED WindowWidth
34. DIM SHARED VisibleLines
35. DIM SHARED TopIndent
36. DIM SHARED LeftIndent
37. DIM SHARED TextHeight
38. DIM SHARED TextWidth
39. DIM SHARED HScroll
40. DIM SHARED TextWrapping
41. DIM SHARED TextFormatting
42. DIM SHARED InsertKey
43. TopIndent = 1
44. LeftIndent = 1
45. WindowWidth = _WIDTH
46. WindowHeight = _HEIGHT
47. TextHeight = WindowHeight - 2 * TopIndent
48. TextWidth = WindowWidth - 2 * LeftIndent
49. HScroll = 1
50. TextWrapping = 1
51. TextFormatting = -1
52. InsertKey = -1
53.  
54. ' Initiate text inside window.
55. DIM SHARED StartIndex
56. DIM SHARED LineAsMapped(TextHeight) AS STRING
57. DIM SHARED Cursor1 AS Vector
58. DIM SHARED Cursor2 AS Vector
59. DIM SHARED ID1
60. DIM SHARED ID2
61.  
62. ' Auxiliary 2D text grid.
63. DIM SHARED GOLSwitch
64. DIM SHARED AuxGrid(TextWidth, TextHeight, 2) AS STRING
65. GOLSwitch = -1
66.  
67. ' Load text file into memory if applicable, use example string if not.
68. DIM SHARED FileName$
69. c$ = COMMAND$
70. IF (c$ <> "") THEN
71.     q$ = ""
72.     OPEN c$ FOR INPUT AS #1
73.     DO WHILE NOT EOF(1)
74.         LINE INPUT #1, r$
75.         q$ = q$ + r$ + CHR$(13)
76.     LOOP
77.     CLOSE #1
78.     i = INSTR(c$, ".")
79.     IF (i <> 0) THEN j = i - 1 ELSE j = LEN(c$)
80.     FileName$ = LEFT$(c$, j) + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
81.     _TITLE "qXed" + " (" + FileName$ + ")"
82. ELSE
83.     FileName$ = "Newfile" + "-" + DATE$ + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
84.     q$ = "I sank to the floor. I [experienced] this hallucination of tumbling forward into these fractal geometric spaces made of light and then I found myself in the equivalent of the Pope's private chapel and there were insect elf machines proffering strange little tablets with strange writing on them, and I was aghast, completely appalled, because [in] a matter of seconds . . . my entire expectation of the nature of the world was just being shredded in front of me. I've never actually gotten over it. These self-transforming machine elf creatures were speaking in a colored language which condensed into rotating machines that were like Faberge eggs but crafted out of luminescent superconducting ceramics and liquid crystal gels. All this stuff was just so weird and so alien and so un-English-able that it was a complete shock - I mean, the literal turning inside out of [my] intellectual universe!" + CHR$(13) + CHR$(13) + "This went on for two or three minutes, this situation of [discontinuous] orthogonal dimensions to reality just engulfing me. As I came out of it and the room reassembled itself, I said, " + CHR$(34) + "I can't believe it, it's impossible." + CHR$(34) + " To call that a drug is ridiculous; that just means that you just don't have a word for it and so you putter around and you come upon this sloppy concept [that] something goes into your body and there's a change. It's not like that; it's like being struck by noetic lightning. [Note: " + CHR$(34) + "Noetic" + CHR$(34) + " derives from the theologian Pierre Teilhard de Chardin's " + CHR$(34) + "noosphere" + CHR$(34) + " - the collective consciousness of humankind conceived of as a sort of philosophical virtuality.]" + CHR$(13) + CHR$(13) + "[What] astonished me was [that] . . . in the carpets of Central Asia, in the myths of the Maya, in the visions of an Arcimboldi or a Fra Angelico or a Bosch, there is not a hint, not a clue, not an atom of the presence of this thing, This was more [multiplex] than the universe that we share with each other. It was the victory of Neo-Platonic metaphysics; everything [was] made out of a fourth-dimensional mosaic of energy. I was knocked off my feet, and set myself the goal of understanding this. There was really no choice, you see."
85.     'q$ = " "
86.     _TITLE "qXed"
87. END IF
88.  
89. ' Create memory space for string.
90. DIM SHARED TheChain(ChainLimit) AS Cell
91.  
92. ' Create character list.
93. CALL Assimilate(q$)
94.  
95. ' Prime main loop.
96. CALL MapText
97. CALL CalibrateCursor(ID1)
98. CALL CalibrateCursor(ID2)
99. CALL PrintEverything
100.  
101. DIM SHARED DEBUG$
102.  
103. ' Main loop.
104. DO
105.     IF (StateChange = 1) THEN
106.         CALL PrintEverything
107.     END IF
108.  
109.     IF (GOLSwitch = 1) THEN
110.         CALL ConvertToGrid
111.         CALL GOL
112.         CALL ConvertFromGrid
113.         CALL MapText
114.         CALL PrintEverything
115.     END IF
116.  
117.     'IF _RESIZE = -1 THEN
118.     '    _DELAY .1
119.     '    oldimage& = scrHand&
120.     '    scrHand& = _NEWIMAGE(_RESIZEWIDTH / 8, _RESIZEHEIGHT / 16, 0)
121.     '    SCREEN scrHand&
122.     '    _FREEIMAGE oldimage&
123.     '    WindowWidth = INT(_RESIZEWIDTH / 8)
124.     '    WindowHeight = INT(_RESIZEHEIGHT / 16)
125.     '    TextHeight = WindowHeight - 2 * TopIndent
126.     '    TextWidth = WindowWidth - 2 * LeftIndent
127.     '    REDIM LineAsMapped(TextHeight)
128.     '    REDIM AuxGrid(TextWidth, TextHeight, 2)
129.     '    CALL MapText
130.     '    CALL CalibrateCursor(ID1)
131.     '    CALL CalibrateCursor(ID2)
132.     '    CALL PrintEverything
133.     'END IF
134.  
135.     _DISPLAY
136.     _LIMIT 120
137. LOOP
138. SYSTEM
139.  
140. SUB PrintEverything
141.     CLS
142.  
143.     ' Main text
144.     FOR i = 1 TO VisibleLines
145.         c$ = LineAsMapped(i)
146.         'IF ((TextFormatting = 1) AND (TextWrapping <> 2)) THEN
147.         IF (TextFormatting = 1) THEN
148.             FOR j = 1 TO TextWidth - LEN(c$)
149.                 c$ = c$ + "_"
150.             NEXT
151.         END IF
152.         d$ = MID$(c$, HScroll, TextWidth)
153.         CALL DisplayText(LeftIndent + 1, TopIndent + i, 7, 1, d$)
154.     NEXT
155.  
156.     ' Horizontal scrollbar
157.     p = LinearCount(NthP(StartIndex, FindID(LeftIndent + 1, Cursor1.Y)), ID1)
158.     q = LEN(LineAsMapped(Cursor1.Y - TopIndent))
159.     r = p / (q + 1)
160.     IF r > 1 THEN r = 1
161.     IF r < 0 THEN r = 0
162.     i = 2 + INT(r * (WindowWidth - 1))
163.     IF i < 1 THEN i = 1
164.     IF i >= WindowWidth THEN i = WindowWidth
165.     CALL DisplayText(i, WindowHeight - 1, 8, 7, "^")
166.  
167.     ' Vertical scrollbar
168.     p = LinearCount(ID1, NthP(ID1, ChainLimit + 1))
169.     q = LinearCount(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
170.     IF (q = 0) THEN r = 1 ELSE r = 1 - p / q
171.     CALL DisplayText(WindowWidth, 1 + INT(r * (WindowHeight - 1)), 8, 7, "<")
172.  
173.     ' Mouse pointer
174.     IF ((_MOUSEX >= 1) AND (_MOUSEX <= WindowWidth) AND (_MOUSEY >= 1) AND (_MOUSEY <= WindowHeight)) THEN
175.         a$ = CHR$(SCREEN(_MOUSEY, _MOUSEX))
176.         CALL DisplayText(_MOUSEX, _MOUSEY, 0, 15, a$)
177.     END IF
178.  
179.     ' Cursor2
180.     IF ((Cursor2.X > 0 AND Cursor2.X < WindowWidth) AND ((Cursor2.Y > 0) AND (Cursor2.Y < WindowHeight))) THEN
181.         p1 = LinearCount(StartIndex, ID1)
182.         p2 = LinearCount(StartIndex, ID2)
183.         pe = LinearCount(StartIndex, EOC)
184.         IF ((p2 > p1) AND (p2 < pe)) THEN
185.             c$ = TheChain(ID2).Content
186.             IF (c$ = " ") THEN c$ = "_"
187.             IF (c$ = CHR$(13)) THEN c$ = "~"
188.             CALL DisplayText(Cursor2.X, Cursor2.Y, 0, 6, c$)
189.         END IF
190.     END IF
191.  
192.     ' Cursor1
193.     IF ((Cursor1.X > 0 AND Cursor1.X < WindowWidth) AND ((Cursor1.Y > 0) AND (Cursor1.Y < WindowHeight))) THEN
194.         c$ = TheChain(ID1).Content
195.         IF (c$ = " ") THEN c$ = "_"
196.         IF (c$ = CHR$(13)) THEN c$ = "~"
197.         IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN
198.             a = 16: b = 5
199.         ELSE
200.             a = 16: b = 3
201.         END IF
202.         CALL DisplayText(Cursor1.X, Cursor1.Y, a, b, c$)
203.     END IF
204.  
205.     ' Guide
206.     SELECT CASE TextWrapping
207.         CASE 0: d$ = "Square"
208.         CASE 1: d$ = "Fluid"
209.         CASE 2: d$ = "None"
210.     END SELECT
211.     c$ = "[F3=Highlight Row] [F6=Save] [F11=Format] [F12=Wrap: " + d$ + "]"
212.     IF (TextWrapping = 2) THEN c$ = "[F1/2=HScroll] " + c$
213.     c$ = c$ + STR$(INT(100 * r)) + "%"
214.     IF (LEN(c$) >= TextWidth) THEN c$ = LEFT$(c$, TextWidth)
215.     CALL DisplayText(WindowWidth - LEN(c$), 1, 15, 0, c$)
216.     c$ = "[Esc=Mode] [M1=Cur1] [M2=Cur2/Copy] [M3=Paste] [Del=Erase Cur1-2]"
217.     IF (InsertKey = 1) THEN c$ = "[Ins] " + c$
218.     IF (LEN(c$) >= TextWidth) THEN c$ = LEFT$(c$, TextWidth)
219.     CALL DisplayText(WindowWidth - LEN(c$), WindowHeight, 15, 0, c$)
220.  
221.     ' Cursor status
222.     d$ = TheChain(ID1).Content
223.     e$ = TheChain(ID2).Content
224.     IF ((ASC(d$) = 10) OR (ASC(d$) = 13)) THEN d$ = "~"
225.     IF ((ASC(e$) = 10) OR (ASC(e$) = 13)) THEN e$ = "~"
226.     IF (ASC(d$) = 32) THEN d$ = "_"
227.     IF (ASC(e$) = 32) THEN e$ = "_"
228.  
229.     c$ = "(" + LTRIM$(RTRIM$(STR$(Cursor1.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor1.Y - TopIndent))) + ")" ':" + " " + LTRIM$(RTRIM$(d$)) + " " + LTRIM$(RTRIM$(STR$(ID1))) + ")"
230.     IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN
231.         CALL DisplayText(2, WindowHeight, 15, 5, c$)
232.         CALL DisplayText(3 + LEN(c$) + LEN(g$), WindowHeight, 15, 5, "<" + CHR$(177))
233.     ELSE
234.         CALL DisplayText(2, WindowHeight, 0, 3, c$)
235.         CALL DisplayText(3 + LEN(c$) + LEN(g$), WindowHeight, 0, 3, CHR$(177) + ">")
236.     END IF
237.     IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
238.         g$ = "(" + LTRIM$(RTRIM$(STR$(Cursor2.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor2.Y - TopIndent))) + ")" ':" + " " + LTRIM$(RTRIM$(e$)) + " " + LTRIM$(RTRIM$(STR$(ID2))) + ")"
239.         CALL DisplayText(6 + LEN(c$), WindowHeight, 0, 6, g$)
240.     END IF
241.  
242.     DEBUG$ = STR$(ID1) + STR$(ID2)
243.     c$ = "qXed" + " " + DEBUG$
244.     CALL DisplayText(1, 1, 11, 0, c$)
245.  
246.     COLOR 15, 0
247.  
248. END SUB
249.  
250. SUB Assimilate (a AS STRING)
251.     ' Load a string to initialize chain.
252.     FOR k = 1 TO ChainLimit
253.         TheChain(k).Identity = 0
254.     NEXT
255.     StartIndex = 1
256.     PreviousIdentity = BOC
257.     NextIdentity = NextOpenIdentity(StartIndex)
258.     FOR k = 1 TO LEN(a)
259.         j = NextIdentity
260.         TheChain(j).Identity = j
261.         TheChain(j).Content = ReFormat$(MID$(a, k, 1))
262.         TheChain(j).Lagger = PreviousIdentity
263.         PreviousIdentity = j
264.         IF (k < LEN(a)) THEN
265.             NextIdentity = NextOpenIdentity(j)
266.             TheChain(j).Pointer = NextIdentity
267.         ELSE
268.             TheChain(j).Pointer = EOC
269.         END IF
270.         PRINT TheChain(j).Content
271.     NEXT
272.     ID1 = StartIndex
273.     ID2 = ID1 'NthP(ID1, ChainLimit + 1)
274. END SUB
275.  
276. FUNCTION ReFormat$ (a AS STRING)
277.     c$ = a
278.     IF c$ = CHR$(10) THEN c$ = CHR$(13)
279.     IF c$ = CHR$(9) THEN c$ = "    "
280.     ReFormat = c$
281. END FUNCTION
282.  
283. FUNCTION NthP (a AS LONG, b AS LONG)
284.     ' Returns the address that is b jumps ahead of address a.
285.     i = a
286.     IF (i <> EOC) THEN
287.         k = 0
288.         j = 0
289.         DO WHILE (k < b)
290.             k = k + 1
291.             j = TheChain(i).Identity
292.             i = TheChain(j).Pointer
293.             IF (i = EOC) THEN EXIT DO
294.         LOOP
295.     END IF
296.     NthP = j
297. END FUNCTION
298.  
299. FUNCTION NthPC (a AS LONG, b AS STRING)
300.     ' Returns the address holding b first enLinearCountered from a.
301.     i = a
302.     DO
303.         j = TheChain(i).Identity
304.         i = TheChain(j).Pointer
305.         IF (TheChain(j).Content = b) THEN EXIT DO
306.         IF (i = EOC) THEN
307.             j = BOC
308.             EXIT DO
309.         END IF
310.     LOOP
311.     NthPC = j
312. END FUNCTION
313.  
314. FUNCTION NthL (a AS LONG, b AS LONG)
315.     ' Returns the address that is b jumps behind address a.
316.     i = a
317.     k = 0
318.     DO WHILE k < b
319.         k = k + 1
320.         j = TheChain(i).Identity
321.         i = TheChain(j).Lagger
322.         IF (i = BOC) THEN EXIT DO
323.     LOOP
324.     NthL = j
325. END FUNCTION
326.  
327. FUNCTION NextOpenIdentity (a AS LONG)
328.     ' Returns first nonzero identity.
329.     FOR j = a TO ChainLimit
330.         IF (TheChain(j).Identity = 0) THEN EXIT FOR
331.     NEXT
332.     IF (j > ChainLimit) THEN
333.         PRINT "Out of memory: "; ChainLimit
334.         SLEEP
335.         SYSTEM
336.     END IF
337.     NextOpenIdentity = j
338. END FUNCTION
339.  
340. FUNCTION BackBreak (a AS LONG)
341.     ' Function for scrolling up.
342.     j = a
343.     lastbreak = 0
344.     c$ = ""
345.     DO
346.         IF (j = BOC) THEN EXIT DO
347.         k = TheChain(j).Lagger
348.         IF (k = BOC) THEN
349.             lastbreak = j
350.             EXIT DO
351.         END IF
352.         j = k
353.         d$ = TheChain(j).Content
354.         c$ = d$ + c$
355.         IF ((TextWrapping = 1) AND (d$ = " ")) THEN lastbreak = j
356.         IF (TextWrapping <> 2) AND (LEN(c$) = TextWidth) THEN EXIT DO
357.         IF (d$ = CHR$(13)) THEN EXIT DO
358.     LOOP
359.     IF (lastbreak <> 0) THEN j = TheChain(lastbreak).Identity
360.     BackBreak = j
361. END FUNCTION
362.  
363. SUB InsertBefore (a AS LONG, b AS STRING)
364.     ' Inserts a single cell before address a in the chain.
365.     j = NextOpenIdentity(a)
366.     al = TheChain(a).Lagger
367.     TheChain(j).Identity = j
368.     TheChain(j).Pointer = a
369.     TheChain(j).Lagger = al
370.     TheChain(j).Content = ReFormat$(b)
371.     TheChain(a).Lagger = j
372.     IF (al = BOC) THEN StartIndex = j ELSE TheChain(al).Pointer = j
373. END SUB
374.  
375. SUB InsertAfter (a AS LONG, b AS STRING)
376.     ' Inserts a single cell after address a in the chain.
377.     j = NextOpenIdentity(a)
378.     ap = TheChain(a).Pointer
379.     TheChain(j).Identity = j
380.     TheChain(j).Pointer = ap
381.     TheChain(j).Lagger = a
382.     TheChain(j).Content = ReFormat$(b)
383.     TheChain(a).Pointer = j
384.     IF (ap <> EOC) THEN TheChain(ap).Lagger = j
385. END SUB
386.  
387. SUB InsertRange (a AS LONG, b AS STRING)
388.     ' Inserts a sub-chain anywhere.
389.     FOR k = 1 TO LEN(b)
390.         c$ = MID$(b, k, 1)
391.         CALL InsertBefore(a, c$)
392.     NEXT
393. END SUB
394.  
395. SUB UnlinkCell (a AS LONG)
396.     ' Remove single cell from chain and clear identity.
397.     ap = TheChain(a).Pointer
398.     al = TheChain(a).Lagger
399.     IF ((ap = EOC) AND (al = BOC)) THEN
400.         TheChain(a).Content = " "
401.         'ID1 = a
402.         'ID2 = ID1
403.     ELSE
404.         TheChain(a).Identity = 0
405.         IF ((ap <> EOC) AND (al <> BOC)) THEN
406.             TheChain(al).Pointer = ap
407.             TheChain(ap).Lagger = al
408.         END IF
409.         IF (ap = EOC) THEN TheChain(al).Pointer = EOC
410.         IF (al = BOC) THEN
411.             StartIndex = ap
412.             TheChain(ap).Lagger = BOC
413.         END IF
414.     END IF
415. END SUB
416.  
417. SUB UnlinkRange (a AS LONG, b AS LONG)
418.     ' Remove sub-chain and clear identity of each cell.
419.     bp = TheChain(b).Pointer
420.     al = TheChain(a).Lagger
421.     IF ((al = BOC) AND (bp = EOC)) THEN
422.         CALL UnlinkRange(NthP(a, 2), b)
423.         TheChain(a).Content = " "
424.         TheChain(a).Pointer = bp
425.     ELSE
426.         k = a
427.         DO WHILE ((k <> b) AND (k <> EOC))
428.             TheChain(k).Identity = 0
429.             k = TheChain(k).Pointer
430.         LOOP
431.         TheChain(b).Identity = 0
432.         TheChain(bp).Lagger = al
433.         IF (al = BOC) THEN StartIndex = bp ELSE TheChain(al).Pointer = bp
434.     END IF
435. END SUB
436.  
437. FUNCTION LinearCount (a AS LONG, b AS LONG)
438.     ' Returns number of links between two addresses.
439.     i = a
440.     k = 0
441.     DO WHILE (i <> b)
442.         k = k + 1
443.         j = TheChain(i).Identity
444.         i = TheChain(j).Pointer
445.         IF (i = EOC) THEN EXIT DO
446.     LOOP
447.     LinearCount = k
448. END FUNCTION
449.  
450. FUNCTION LinearCount2 (a AS LONG, b AS LONG, c AS LONG)
451.     ' Returns number of links between two addresses, with exit condition.
452.     i = a
453.     k = 0
454.     DO WHILE (i <> b)
455.         k = k + 1
456.         j = TheChain(i).Identity
457.         i = TheChain(j).Pointer
458.         IF (i = EOC) THEN EXIT DO
459.         IF (k = c) THEN EXIT DO
460.     LOOP
461.     LinearCount2 = k
462. END FUNCTION
463.  
464. FUNCTION Projection$ (a AS LONG, b AS LONG)
465.     ' Returns the linear content for all address between a and b, inclusive.
466.     DIM TheReturn AS STRING
467.     TheReturn = ""
468.     IF (a = b) THEN
469.         TheReturn = TheChain(a).Content
470.     ELSE
471.         j = a
472.         DO
473.             c$ = TheChain(j).Content
474.             TheReturn = TheReturn + c$
475.             k = TheChain(j).Pointer
476.             IF (j = b) THEN EXIT DO
477.             IF (k = EOC) THEN EXIT DO
478.             j = k
479.         LOOP
480.     END IF
481.     Projection$ = TheReturn
482. END SUB
483.  
484. SUB MapText
485.     IF (TextFormatting = 1) THEN br$ = "~" ELSE br$ = " "
486.     j = StartIndex
487.     i = 1
488.     q$ = ""
489.     d$ = ""
490.     DO ' Begin with any left-over text from previous iteration.
491.         q$ = d$
492.         d$ = ""
493.         r = TextWidth - LEN(q$)
494.         IF (TextWrapping <> 2) THEN k1 = NthP(j, r) ELSE k1 = EOC
495.         k2 = NthPC(j, CHR$(13))
496.         IF (TextWrapping <> 2) THEN c1 = LinearCount(j, k1) ELSE c1 = LinearCount2(j, k1, TextWidth * TextHeight)
497.         c2 = LinearCount(j, k2)
498.         IF (c2 = 0) THEN ' Line is blank-returned.
499.             k = k2
500.             q$ = q$ + br$
501.             j = NthP(k, 2)
502.         ELSE
503.             IF (c1 = c2) THEN ' Possible end of chain.
504.                 k = TheChain(k1).Lagger
505.                 q$ = q$ + Projection$(j, k)
506.                 j = NthP(k, 2)
507.             END IF
508.             IF (c1 < c2) THEN ' Width limit case (not always maximum).
509.                 k = k1
510.                 q$ = q$ + Projection$(j, k)
511.                 j = NthP(k, 2)
512.             END IF
513.             IF (c1 > c2) THEN ' Break return somewhere in line (not first).
514.                 k = k2
515.                 q$ = q$ + Projection$(j, TheChain(k).Lagger) + br$
516.                 n = TheChain(k).Pointer
517.                 IF (n <> EOC) THEN j = n
518.             END IF
519.         END IF
520.         IF (TextWrapping = 1) THEN ' Wrap text at first space from right, send remainder to next line.
521.             IF (LEN(q$) >= TextWidth) THEN
522.                 FOR m = LEN(q$) TO 1 STEP -1
523.                     c$ = MID$(q$, m, 1)
524.                     IF (c$ = " ") OR (c$ = "-") THEN
525.                         q$ = LEFT$(q$, m)
526.                         EXIT FOR
527.                     END IF
528.                     d$ = c$ + d$
529.                     IF (m = 1) THEN ' Line is too long for allowed space and contains no wrapping characters.
530.                         q$ = LEFT$(q$, TextWidth)
531.                         d$ = ""
532.                         EXIT FOR
533.                     END IF
534.                 NEXT
535.             END IF
536.         END IF
537.         LineAsMapped(i) = q$
538.         i = i + 1
539.         IF n = EOC THEN EXIT DO
540.         IF (i >= TextHeight) THEN EXIT DO
541.         IF (j = k) THEN EXIT DO
542.     LOOP
543.     VisibleLines = i - 1
544. END SUB
545.  
546. FUNCTION StateChange
547.     DIM TheReturn
548.     MH = 0
549.     MW = 0
550.     MT = 0
551.     DO WHILE _MOUSEINPUT
552.         MH1 = _MOUSEBUTTON(1)
553.         MH2 = _MOUSEBUTTON(2)
554.         MH3 = _MOUSEBUTTON(3)
555.         MW = _MOUSEWHEEL
556.         IF (MW <> 0) THEN MT = MW
557.     LOOP
558.     MW = MT
559.  
560.     IF (MH1 = -1) THEN
561.         ' Move Cursor1 among text.
562.         MH = 1
563.         IF ((_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight)) THEN
564.             Cursor1.X = _MOUSEX
565.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent)) - (HScroll - 1)
566.             IF (Cursor1.X > q) THEN
567.                 IF (q < 0) THEN
568.                     IF (LEN(LineAsMapped(_MOUSEY - TopIndent)) > TextWidth) THEN
569.                         HScroll = 1 + LEN(LineAsMapped(_MOUSEY - TopIndent)) - (Cursor1.X - LeftIndent)
570.                     ELSE
571.                         HScroll = 1
572.                         Cursor1.X = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
573.                     END IF
574.                 ELSE
575.                     Cursor1.X = q
576.                 END IF
577.             END IF
578.             Cursor1.Y = _MOUSEY
579.             CALL ReassignID1
580.         END IF
581.         ' Move by vertical scrollbar.
582.         IF (_MOUSEX = WindowWidth) THEN
583.             i = NthL(ID1, ChainLimit + 1)
584.             j = NthP(ID1, ChainLimit + 1)
585.             IF (_MOUSEY = WindowHeight) THEN i = j
586.             IF (_MOUSEY > 1) AND (_MOUSEY < WindowHeight) THEN
587.                 t = LinearCount(i, j)
588.                 f = _MOUSEY / WindowHeight
589.                 FOR k = 1 TO t
590.                     IF (k / t >= f) THEN EXIT FOR
591.                     i = TheChain(i).Pointer
592.                 NEXT
593.             END IF
594.             StartIndex = i
595.             ID1 = i
596.         END IF
597.         ' Move by horizontal scrollbar.
598.         IF (_MOUSEY = WindowHeight - 1) THEN
599.             j = ID1
600.             i = NthP(StartIndex, FindID(LeftIndent + 1, Cursor1.Y))
601.             IF (_MOUSEX > 1) AND (_MOUSEX < WindowWidth) THEN
602.                 t = LEN(LineAsMapped(Cursor1.Y - TopIndent))
603.                 f = _MOUSEX / WindowWidth
604.                 FOR k = 1 TO t
605.                     IF (k / t >= f) THEN EXIT FOR
606.                     i = TheChain(i).Pointer
607.                 NEXT
608.             END IF
609.             ID1 = i
610.             d = LinearCount(StartIndex, i) - LinearCount(StartIndex, j)
611.             IF (TextWrapping = 2) THEN HScroll = HScroll + d
612.             IF HScroll < 1 THEN HScroll = 1
613.         END IF
614.     END IF
615.     IF (MH2 = -1) THEN
616.         ' Move Cursor2 and copy anything between Cursor1 and Cursor2 to clipboard.
617.         MH = 1
618.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
619.             Cursor2.X = _MOUSEX
620.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent)) - (HScroll - 1)
621.             IF (Cursor2.X > q) THEN
622.                 IF (q < 0) THEN
623.                 ELSE
624.                     Cursor2.X = q
625.                 END IF
626.             END IF
627.             Cursor2.Y = _MOUSEY
628.             CALL ReassignID2
629.             IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN _CLIPBOARD$ = Projection$(ID1, ID2)
630.         END IF
631.     END IF
632.     IF (MH3 = -1) THEN
633.         ' Paste at Cursor1 position.
634.         MH = 1
635.         'IF (LinearCount(StartIndex, ID2) >= LinearCount(StartIndex, ID1)) THEN
636.         CALL InsertRange(ID1, _CLIPBOARD$)
637.     END IF
638.     IF (MW = -1) THEN
639.         ' Wheel up
640.         MH = 1
641.  
642.  
643.         'StartIndex = BackBreak(StartIndex)
644.         'CALL ReassignID1
645.  
646.         ' Borrowed from uparrow.
647.         IF (Cursor1.Y > TopIndent + 1) THEN
648.             Cursor1.Y = Cursor1.Y - 1
649.         ELSE
650.             StartIndex = BackBreak(StartIndex)
651.         END IF
652.         q = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (HScroll - 1)
653.         IF (Cursor1.X > q) THEN
654.             IF (q < 0) THEN
655.                 IF (LEN(LineAsMapped(Cursor1.Y - TopIndent)) > TextWidth) THEN
656.                     HScroll = 1 + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (Cursor1.X - LeftIndent)
657.                 ELSE
658.                     HScroll = 1
659.                     Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
660.                 END IF
661.             ELSE
662.                 Cursor1.X = q
663.             END IF
664.         END IF
665.         CALL ReassignID1
666.  
667.  
668.     END IF
669.     IF (MW = 1) THEN
670.         ' Wheel down
671.         MH = 1
672.  
673.         'IF (VisibleLines > 1) THEN
674.         '    StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
675.         '    CALL MapText
676.         'END IF
677.         'CALL ReassignID1
678.  
679.         ' Borrowed from downarrow.
680.         IF (Cursor1.Y = TopIndent + VisibleLines) THEN
681.             IF (VisibleLines > 1) THEN
682.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
683.                 CALL MapText
684.             END IF
685.         ELSE
686.             Cursor1.Y = Cursor1.Y + 1
687.         END IF
688.         q = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (HScroll - 1)
689.         IF (Cursor1.X > q) THEN
690.             IF (q < 0) THEN
691.                 IF (LEN(LineAsMapped(Cursor1.Y - TopIndent)) > TextWidth) THEN
692.                     HScroll = 1 + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (Cursor1.X - LeftIndent)
693.                 ELSE
694.                     HScroll = 1
695.                     Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
696.                 END IF
697.             ELSE
698.                 Cursor1.X = q
699.             END IF
700.         END IF
701.         CALL ReassignID1
702.  
703.     END IF
704.  
705.     KH = 0
706.     '''k$ = ""
707.     '''k$ = INKEY$
708.     '''IF k$ <> "" THEN KH = ASC(k$)
709.     KH = _KEYHIT
710.  
711.     ' Bksp
712.     IF (KH = 8) THEN
713.         IF ID1 = StartIndex THEN StartIndex = BackBreak(StartIndex) 'BEEP
714.         r = TheChain(ID1).Pointer
715.         q = TheChain(ID1).Lagger
716.         CALL UnlinkCell(ID1)
717.         IF ((r = EOC) AND (q = BOC)) THEN
718.             ' Never erase the last character.
719.         ELSE
720.             IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
721.             IF (r = EOC) THEN ID2 = ID1
722.         END IF
723.     END IF
724.     ' Tab
725.     IF (KH = 9) THEN CALL InsertRange(ID1, "    ")
726.     ' Esc
727.     IF (KH = 27) THEN
728.         IF (ID1 = StartIndex) AND (ID2 = StartIndex) THEN
729.             ID2 = TheChain(ID1).Pointer
730.         ELSE
731.             IF (ID2 <> ID1) THEN ID2 = ID1 ELSE ID2 = StartIndex
732.         END IF
733.     END IF
734.     ' Enter, Alphanumerics
735.     IF (KH = 13) OR ((KH >= 32) AND (KH <= 126)) THEN
736.         IF (InsertKey = -1) THEN
737.             IF (ID1 = ID2) THEN
738.                 CALL InsertBefore(ID1, LTRIM$(RTRIM$(CHR$(KH))))
739.             ELSE
740.                 CALL InsertAfter(ID1, LTRIM$(RTRIM$(CHR$(KH))))
741.                 ID1 = NthP(ID1, 2)
742.             END IF
743.         ELSE
744.             TheChain(ID1).Content = LTRIM$(RTRIM$(CHR$(KH)))
745.             IF (ID1 = ID2) THEN
746.                 ID1 = NthP(ID1, 2)
747.                 ID2 = ID1
748.             ELSE
749.                 ID1 = NthP(ID1, 2)
750.             END IF
751.         END IF
752.         IF ((TextWrapping = 2) AND (Cursor1.X - LeftIndent = TextWidth)) THEN HScroll = HScroll + 1
753.     END IF
754.     ' F1
755.     IF (KH = 15104) THEN
756.         IF (TextWrapping = 2) THEN
757.             HScroll = HScroll - 1
758.             IF (HScroll < 1) THEN HScroll = 1
759.             CALL ReassignID1
760.             CALL ReassignID2
761.         END IF
762.     END IF
763.     ' F2
764.     IF (KH = 15360) THEN
765.         IF (TextWrapping = 2) THEN
766.             HScroll = HScroll + 1
767.             CALL ReassignID1
768.             CALL ReassignID2
769.         END IF
770.     END IF
771.     ' F3
772.     IF (KH = 15616) THEN
773.         Cursor1.X = LeftIndent + 1
774.         CALL ReassignID1
775.         Cursor2.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
776.         Cursor2.Y = Cursor1.Y
777.         CALL ReassignID2
778.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN _CLIPBOARD$ = Projection$(ID1, ID2)
779.     END IF
780.     ' F5
781.     IF (KH = 16128) THEN
782.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
783.         Assimilate q$
784.     END IF
785.     ' F4
786.     'IF (KH = 15872) THEN
787.     '    'CALL InsertRange(NthP(ID2, 2), CHR$(10) + "=" + CoreProcess$(Projection(ID1, ID2)))
788.     '    CALL InsertRange(NthP(ID2, 2), CHR$(10) + "=" + SxriptEval$(Projection(ID1, ID2)))
789.     '    ID2 = StartIndex
790.     'END IF
791.     ' F6
792.     IF (KH = 16384) THEN
793.         OPEN FileName$ FOR OUTPUT AS #1
794.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
795.         PRINT #1, q$
796.         CLOSE #1
797.     END IF
798.     ' F7
799.     IF (KH = 16640) THEN
800.         GOLSwitch = -GOLSwitch
801.     END IF
802.     ' F8
803.     'IF (KH = 16896) THEN
804.     '    Cursor1.X = LeftIndent + 1
805.     '    CALL ReassignID1
806.     '    Cursor2.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
807.     '    Cursor2.Y = Cursor1.Y
808.     '    CALL ReassignID2
809.     'END IF
810.     ' Home
811.     IF (KH = 18176) THEN
812.         IF (TextWrapping = 2) THEN HScroll = 1
813.         Cursor1.X = LeftIndent + 1
814.         CALL ReassignID1
815.     END IF
816.     ' UpArrow
817.     IF (KH = 18432) THEN
818.         IF (Cursor1.Y > TopIndent + 1) THEN
819.             Cursor1.Y = Cursor1.Y - 1
820.         ELSE
821.             StartIndex = BackBreak(StartIndex)
822.         END IF
823.         q = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (HScroll - 1)
824.         IF (Cursor1.X > q) THEN
825.             IF (q < 0) THEN
826.                 IF (LEN(LineAsMapped(Cursor1.Y - TopIndent)) > TextWidth) THEN
827.                     HScroll = 1 + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (Cursor1.X - LeftIndent)
828.                 ELSE
829.                     HScroll = 1
830.                     Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
831.                 END IF
832.             ELSE
833.                 Cursor1.X = q
834.             END IF
835.         END IF
836.         CALL ReassignID1
837.     END IF
838.     ' PgUp
839.     IF (KH = 18688) THEN
840.         FOR k = 1 TO INT(TextHeight / 2)
841.             StartIndex = BackBreak(StartIndex)
842.         NEXT
843.         CALL ReassignID1
844.     END IF
845.     ' LeftArrow
846.     IF (KH = 19200) THEN
847.         ID1 = NthL(ID1, 2)
848.         IF (TextWrapping = 2) THEN
849.             IF (Cursor1.X = LeftIndent + 1) THEN
850.                 IF (HScroll > 1) THEN
851.                     HScroll = HScroll - 1
852.                 ELSE
853.                     j = Cursor1.Y - TopIndent - 1
854.                     IF (j >= 1) THEN
855.                         k = LEN(LineAsMapped(j)) - TextWidth + 1
856.                         IF (k >= 1) THEN
857.                             HScroll = k
858.                         END IF
859.                     END IF
860.                 END IF
861.             END IF
862.         ELSE
863.             IF ((Cursor1.X - LeftIndent = 1) AND Cursor1.Y - TopIndent = 1) THEN
864.                 StartIndex = BackBreak(StartIndex)
865.             END IF
866.         END IF
867.     END IF
868.     ' RightArrow
869.     IF (KH = 19712) THEN
870.         ID1 = NthP(ID1, 2)
871.         m = Cursor1.X - LeftIndent
872.         n = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - HScroll + 1
873.         IF (TextWrapping = 2) THEN
874.             IF (m >= TextWidth) THEN
875.                 HScroll = HScroll + 1
876.                 CALL ReassignID1
877.             END IF
878.             IF (m >= n) THEN
879.                 j = Cursor1.Y - TopIndent + 1
880.                 IF ((j <= TextHeight) AND (VisibleLines > 1)) THEN HScroll = 1
881.             END IF
882.         ELSE
883.             IF ((m >= n) AND (Cursor1.Y - TopIndent = VisibleLines)) THEN
884.                 IF (VisibleLines > 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
885.             END IF
886.         END IF
887.     END IF
888.     ' End
889.     IF (KH = 20224) THEN
890.         Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
891.         CALL ReassignID1
892.         IF (TextWrapping = 2) THEN
893.             q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - TextWidth + 1
894.             IF (q >= 1) THEN HScroll = q
895.         END IF
896.     END IF
897.     ' DownArrow
898.     IF (KH = 20480) THEN
899.         IF (Cursor1.Y = TopIndent + VisibleLines) THEN
900.             IF (VisibleLines > 1) THEN
901.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
902.                 CALL MapText
903.             END IF
904.         ELSE
905.             Cursor1.Y = Cursor1.Y + 1
906.         END IF
907.         q = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (HScroll - 1)
908.         IF (Cursor1.X > q) THEN
909.             IF (q < 0) THEN
910.                 IF (LEN(LineAsMapped(Cursor1.Y - TopIndent)) > TextWidth) THEN
911.                     HScroll = 1 + LEN(LineAsMapped(Cursor1.Y - TopIndent)) - (Cursor1.X - LeftIndent)
912.                 ELSE
913.                     HScroll = 1
914.                     Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
915.                 END IF
916.             ELSE
917.                 Cursor1.X = q
918.             END IF
919.         END IF
920.         CALL ReassignID1
921.     END IF
922.     ' PgDn
923.     IF (KH = 20736) THEN
924.         FOR k = 1 TO INT(TextHeight / 2)
925.             IF (VisibleLines > 1) THEN
926.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
927.                 CALL MapText
928.             END IF
929.         NEXT
930.         CALL ReassignID1
931.     END IF
932.     ' Insert
933.     IF (KH = 20992) THEN
934.         InsertKey = -InsertKey
935.     END IF
936.     ' Del
937.     IF (KH = 21248) THEN
938.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
939.             r = TheChain(ID2).Pointer
940.             q = TheChain(ID1).Lagger
941.             p = ID1
942.             CALL UnlinkRange(ID1, ID2)
943.             IF ((r = EOC) AND (q = BOC)) THEN
944.                 ID1 = p
945.                 ID2 = ID1
946.                 StartIndex = p
947.             ELSE
948.                 IF (q = BOC) THEN
949.                     ID1 = r
950.                 ELSE
951.                     ID1 = q
952.                     IF (p = StartIndex) THEN StartIndex = q
953.                 END IF
954.                 ID2 = NthP(ID1, 2)
955.             END IF
956.         END IF
957.     END IF
958.     ' F11
959.     IF (KH = 34048) THEN TextFormatting = -TextFormatting
960.     ' F12
961.     IF (KH = 34304) THEN
962.         TextWrapping = TextWrapping + 1
963.         IF (TextWrapping > 2) THEN TextWrapping = 0
964.         ID1 = StartIndex
965.         ID2 = ID1
966.         HScroll = 1
967.     END IF
968.     ' Exit sequence
969.     TheReturn = 0
970.     IF ((MH <> 0) OR (KH > 0)) THEN
971.         TheReturn = 1
972.         CALL MapText
973.         CALL CalibrateCursor(ID1)
974.         CALL CalibrateCursor(ID2)
975.         ' Cursor sync and autoscrolling.
976.         IF (Cursor1.Y > TopIndent + TextHeight - 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
977.     END IF
978.     _KEYCLEAR
979.     StateChange = TheReturn
980. END FUNCTION
981.  
982. SUB CalibrateCursor (a AS LONG)
983.     ' Place Cursor under ID on rendered line.
984.     s = StartIndex
985.     IF ((TextWrapping = 2) AND (HScroll > 1)) THEN s = NthP(s, HScroll)
986.     c = LinearCount(s, a)
987.     k = 0
988.     i = -1
989.     FOR j = 1 TO VisibleLines
990.         n = LEN(LineAsMapped(j))
991.         IF (k + n < c) THEN
992.             k = k + n
993.         ELSE
994.             i = c - k + 1
995.             EXIT FOR
996.         END IF
997.     NEXT
998.     IF (i >= LeftIndent + LEN(LineAsMapped(j))) THEN
999.         IF (j <= VisibleLines) THEN
1000.             i = 1
1001.             j = j + 1
1002.         END IF
1003.     END IF
1004.     IF (a = ID1) THEN
1005.         Cursor1.X = LeftIndent + i
1006.         Cursor1.Y = TopIndent + j
1007.     END IF
1008.     IF (a = ID2) THEN
1009.         Cursor2.X = LeftIndent + i
1010.         Cursor2.Y = TopIndent + j
1011.     END IF
1012. END SUB
1013.  
1014. FUNCTION FindID (a AS INTEGER, b AS LONG)
1015.     ' Find identity under a map location.
1016.     RelX = a - LeftIndent
1017.     RelY = b - TopIndent
1018.     FOR k = 1 TO RelY - 1
1019.         t = t + LEN(LineAsMapped(k))
1020.     NEXT
1021.     t = t + RelX
1022.     FindID = t
1023. END FUNCTION
1024.  
1025. SUB ReassignID1
1026.     ' Reassign identity under Cursor1.
1027.     ID1 = NthP(StartIndex, FindID(Cursor1.X, Cursor1.Y) + (HScroll - 1))
1028. END SUB
1029.  
1030. SUB ReassignID2
1031.     ' Reassign identity under Cursor2.
1032.     ID2 = NthP(StartIndex, FindID(Cursor2.X, Cursor2.Y) + (HScroll - 1))
1033. END SUB
1034.  
1035. SUB ConvertToGrid
1036.     FOR j = 1 TO VisibleLines
1037.         c$ = LineAsMapped(j)
1038.         FOR i = 1 TO LEN(c$) - 1 ' BR offset to exclude break return at line end.
1039.             AuxGrid(i, j, 1) = MID$(c$, i, 1)
1040.         NEXT
1041.     NEXT
1042. END SUB
1043.  
1044. SUB ConvertFromGrid
1045.     q$ = ""
1046.     FOR j = 1 TO VisibleLines
1047.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
1048.             q$ = q$ + AuxGrid(i, j, 1)
1049.         NEXT
1050.         q$ = q$ + CHR$(13) ' Undoes BR offset.
1051.     NEXT
1052.     Assimilate q$
1053. END SUB
1054.  
1055. SUB GOL
1056.     FOR j = 1 TO VisibleLines
1057.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
1058.             c$ = AuxGrid(i, j, 1)
1059.             IF (c$ = " ") THEN c$ = "0" ELSE c$ = "1"
1060.             AuxGrid(i, j, 1) = c$
1061.             AuxGrid(i, j, 2) = c$
1062.         NEXT
1063.     NEXT
1064.     FOR j = 2 TO VisibleLines - 2 ' BR offset.
1065.         FOR i = 2 TO LEN(LineAsMapped(j)) - 2 ' BR offset.
1066.             c$ = AuxGrid(i, j, 1)
1067.             a1 = VAL(AuxGrid(i - 1, j + 1, 1))
1068.             a2 = VAL(AuxGrid(i, j + 1, 1))
1069.             a3 = VAL(AuxGrid(i + 1, j + 1, 1))
1070.             a4 = VAL(AuxGrid(i - 1, j, 1))
1071.             a6 = VAL(AuxGrid(i + 1, j, 1))
1072.             a7 = VAL(AuxGrid(i - 1, j - 1, 1))
1073.             a8 = VAL(AuxGrid(i, j - 1, 1))
1074.             a9 = VAL(AuxGrid(i + 1, j - 1, 1))
1075.             t = a1 + a2 + a3 + a4 + a6 + a7 + a8 + a9
1076.             IF (c$ = "1") THEN
1077.                 SELECT CASE t
1078.                     CASE IS < 2
1079.                         AuxGrid(i, j, 2) = "0"
1080.                     CASE 2
1081.                         AuxGrid(i, j, 2) = "1"
1082.                     CASE 3
1083.                         AuxGrid(i, j, 2) = "1"
1084.                     CASE IS > 3
1085.                         AuxGrid(i, j, 2) = "0"
1086.                 END SELECT
1087.             ELSE
1088.                 IF (t = 3) THEN AuxGrid(i, j, 2) = "1"
1089.             END IF
1090.         NEXT
1091.     NEXT
1092.     FOR j = 1 TO VisibleLines
1093.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
1094.             c$ = AuxGrid(i, j, 2)
1095.             IF (c$ = "0") THEN c$ = " " ELSE c$ = CHR$(219)
1096.             AuxGrid(i, j, 1) = c$
1097.             AuxGrid(i, j, 2) = c$
1098.         NEXT
1099.     NEXT
1100. END SUB
1101.  
1102. SUB ThrowOutput
1103.     'i = NthP(ID1, ChainLimit + 1)
1104.     'FOR k = 1 TO LogTextCount
1105.     '    CALL InsertRange(i, LogText(k) + CHR$(13))
1106.     'NEXT
1107.     LogTextCount = 0
1108.     CALL MapText
1109.     ID1 = NthP(ID1, ChainLimit + 1)
1110.     CALL CalibrateCursor(ID1)
1111.     CALL CalibrateCursor(ID2)
1112.     DO WHILE (Cursor1.Y > TopIndent + TextHeight - 1)
1113.         StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
1114.         CALL MapText
1115.         CALL CalibrateCursor(ID1)
1116.         CALL CalibrateCursor(ID2)
1117.     LOOP
1118.     ID1 = NthP(ID1, ChainLimit + 1)
1119.     CALL PrintEverything
1120. END SUB
1121.  
1122. SUB DisplayText (Col AS INTEGER, Row AS INTEGER, Shade1 AS INTEGER, Shade2 AS INTEGER, Text AS STRING)
1123.     COLOR Shade1, Shade2: _PRINTSTRING (Col, Row), Text
1124. END SUB
1125.  
1126. 'REM $Include: 'sxmath.bm'
1127. 'REM $Include: 'sxript.bm'

[bplus]

:) For the record, why would I clone Notepad or any editor when I have it with one Shell line? (I wouldn't.)

Q: When I save to file, do file lines end with CHR$(10) or CHR$(13) + CHR$(10) or something eXotic?

Q2, 3, 4?: What is fluid wrapping? Can I assume with Square wrapping I can set line Width? or are we completely misaligned in our thinking?

[STxAxTIC]

Q: When I save to file, do file lines end with CHR$(10) or CHR$(13) + CHR$(10) or something eXotic?

Pretty sure I just use 13, but I haven't thought much about why or why not something else.

[bplus]

I ask, because I will likely want to open the file in QB64 code and work with text if it is saved like a .txt file.

[STxAxTIC]

If it gives you more courage, this thing never saves over any existing file. The saved filename includes a timestamp so you'd have to be(plus) unlucky as hell to lose anything.

[bplus]

Yeah, I see the timestamps after a test of F6 (no feedback if file saved, so I had to check directory.)

So far the only way to load a file is through command line?

update: Oh drag and drop too, nice!

[petoro]

If it gives you more courage, this thing never saves over any existing file. The saved filename includes a timestamp so you'd have to be(plus) unlucky as hell to lose anything.

I love that feature, and also the default text :)

[STxAxTIC]

Hey bplus,

Didn't see your other questions - so fluid wrapping is a way to not cut words at the right edge, so it breaks on returns, spaces, and hyphens. Square wrapping is automatically fit to the window, so the size for now is fixed. You can uncomment all the "resize" code to adjust that, but there is some (probably shallow) error that QB64 kicks up when resizing sometimes. I never really looked into it, but might...