IRC Chat Bot demo/beginning

[SMcNeill]

Code: QB64: [Select]

1. TITLE "Steve QB64-IRC Bot"
2.  
3. DIM SHARED Client AS LONG, Server AS STRING, Channel AS STRING
4. crlf$ = CHR$(13) + CHR$(10)
5. nick$ = "SqbBot"
6. pass$ = ""
7. Server = "irc.freenode.net"
8. Channel = "#qb64"
9.  
10. PRINT "Connecting to " + Server + "..."
11. Client = _OPENCLIENT("TCP/IP:6667:" + Server)
12. IF Client& = 0 THEN PRINT "Error: could not connect...": SLEEP: SYSTEM
13. IF pass$ > "" THEN SendInfo "PASS" + pass$
14. SendInfo "NICK " + nick$
15. SendInfo "USER " + nick$ + " 0 * :" + nick$
16. PRINT "Connected!"
17.  
18. SendInfo "JOIN " + Channel
19. SendInfo "TOPIC " + Channel
20. PRINT "Joined "; Channel
21.  
22. respond = 0
23. DO
24.     _LIMIT 1000
25.     GET #Client&, , In$
26.     IF LEFT$(In$, 4) = "PING" THEN
27.         'Respond with PONG
28.         res$ = "PONG" + MID$(In$, 5) + CHR$(13) + CHR$(10)
29.         PUT #Client, , res$
30.     END IF
31.  
32.     'IF In$ <> "" THEN PRINT LEFT$(In$, LEN(In$) - 2) 'Unremark this is we want to see what's being typed by everyone.
33.     IF In$ <> "" AND respond THEN ProcessInput In$
34.     IF INSTR(In$, "End of /NAMES list.") THEN respond = -1 'Don't start responding to the automatic server messages, like an idiot bot!
35. LOOP UNTIL INKEY$ = CHR$(32) 'Spacebar to quit
36.  
37.  
38. SUB SendInfo (text$)
39. text$ = text$ + CHR$(13) + CHR$(10)
40. PUT #Client&, , text$
41. END SUB
42.  
43. SUB SendReply (text$)
44. text$ = "PRIVMSG " + Channel$ + " :" + text$ + CHR$(13) + CHR$(10)
45. PUT #Client&, , text$
46. COLOR 14: PRINT text$
47. END SUB
48.  
49. SUB ProcessInput (text$)
50.  
51. Speaker$ = MID$(text$, 2, INSTR(text$, "!") - 2)
52. c$ = UCASE$(Channel) + " :"
53. In$ = UCASE$(LEFT$(text$, LEN(text$) - 2)) + " " ' Strip off the CRLF
54. eval$ = " " + MID$(In$, INSTR(In$, c$) + LEN(c$)) + " "
55.  
56. IF INSTR(eval$, " SQBBOT ") THEN
57.     'someone is talking directly to the bot or giving it a command
58.     IF INSTR(eval$, " QUIT ") THEN SYSTEM 'A means to automatically shut down the bot
59.     IF INSTR(eval$, " FINISH ") THEN SYSTEM 'A means to automatically shut down the bot
60.     IF INSTR(eval$, " DIE ") THEN SYSTEM 'A means to automatically shut down the bot
61.     IF INSTR(eval$, " SHUT DOWN ") THEN SYSTEM 'A means to automatically shut down the bot
62.     IF INSTR(eval$, " EXIT ") THEN SYSTEM 'A means to automatically shut down the bot
63.     IF INSTR(eval$, " END ") THEN SYSTEM 'A means to automatically shut down the bot
64.     IF INSTR(eval$, " TELL") THEN
65.         IF INSTR(eval$, "TIME") THEN Out$ = Out$ + "The TIME is " + TIME$ + ".  "
66.         IF INSTR(eval$, "DATE") THEN Out$ = Out$ + "The DATE is " + DATE$ + ".  "
67.     END IF
68.  
69.     IF INSTR(eval$, " HI ") THEN Out$ = "Hiyas, " + Speaker$ + ".  "
70.     IF INSTR(eval$, " HELLO ") THEN Out$ = "Hello to you too, " + Speaker$ + ".  "
71.     IF INSTR(eval$, " YO ") THEN Out$ = "Hola!  " + Speaker$ + "  How's it hanging?  "
72.     IF INSTR(eval$, " HOLA ") THEN Out$ = "What's happening, " + Speaker$ + "?  "
73. END IF
74.  
75. IF INSTR(In$, " JOIN ") AND (INSTR(eval$, "JOIN") = 0) THEN Out$ = "Welcome to QB64 Chat, " + Speaker$ + ".  "
76.  
77. IF Out$ <> "" THEN
78.     COLOR 15
79.     l = INSTR(In$, "PRIVMSG")
80.     PRINT Speaker$; " on "; MID$(In$, l + 8) 'I put a print here, so we can see what our bot is responding to, no matter what.
81.     SendReply Out$
82. END IF
83. END SUB

Another program from the depths of my hard drive — the start of an IRC chat bot.  I’m certain many of the old regulars will remember this guy popping up over and over in the IRC channel as folks tested it and then used it as a base to build their own custom bot, but we have a lot of new members around now, and I thought they too deserved the chance to drive us old QB64 chat channel lurkers crazy...

[SierraKen]

Awesome! One time I saw someone create an ALICE chat bot for IRC, decades ago. If anyone is interested in making one, there might be info online somewhere.

[STxAxTIC]

Lemme help reinforce Steve's point:

Real Qb64 coders hang out at in the #qb64 channel on irc.freenode.net. (I guess the yuppies use discord but I dont see the attraction.)

Steve's code has the ability to connect to the #qb64 room on IRC. A new name will pop up in the user list, and then you have 100% freedom to control what the bot does (minus heavy spam).

I used that ^ code to learn irc protocols and such. Twas pretty useful, so I think you all should try it. Dont be intimidated - Qb64 does all kinds of online stuff.