Help with Starfield

[SierraKen]

SMcNeill, thanks for your math demonstration, I finally noticed it. Since there's no SQR command in the program, the programmer just decided to leave it out and have a GIGANTIC circle after all. LOL Still works though. :) Thanks, I'll keep your demonstration for future programs.

[SierraKen]

LOL Johno. Well you are right, usually... except for 2 episodes I can think of. There's the one where the weird mind alien takes Picard and his crew past the known universe. Then there's this Voyager episode, where they do go to warp 10... https://en.wikipedia.org/wiki/Threshold_(Star_Trek:_Voyager)

[OldMoses]

Um... According to Trek-lore* warp speed of 10 cannot be achieved. If it could, then you could occupy every location in the universe, at the same time.
I wonder how that could be represented using QB64's graphics commands.... Now THAT would be cool....

J

* "The Star Trek Encyclopedia - A Reference Guide to the Future" page 372

Some of the old canon lore had warp factors being a cube root of the apparent velocity of warp speed. Warp 1 being light speed, 2 being 8 x c, warp 3 being 27 x c, etc. Even at high warp the show played pretty fast and loose with travel times. Warp 1 wouldn't get you anywhere worth going in less than several years... at warp 6 Proxima Centauri is a week away.

Most of our star field programs are really bookin'.

UPDATE:
Instead of just appearing, stars now do an apparent magnitude 'fade in', and stars in the near field increase in size.

Fixed it, now it's fully bidirectional.

Code: QB64: [Select]

1. _TITLE "OldMoses' 3D StarField (+ & - speed) (left/right arrows turn)"
2.  
3. a& = _NEWIMAGE(600, 600, 32)
4. SCREEN a&
5. DO: LOOP UNTIL _SCREENEXISTS
6. _SCREENMOVE 50, 50
7. TYPE star '                                                     define the star data type
8.     x AS INTEGER
9.     y AS INTEGER
10.     z AS INTEGER
11.     r AS INTEGER
12.     g AS INTEGER
13.     b AS INTEGER
14.     xa AS INTEGER
15.     ya AS INTEGER
16. END TYPE
17.  
18. DIM SHARED max AS INTEGER: max = 500
19. DIM SHARED vprt AS INTEGER: vprt = 600 '                        set the viewport setback from viewer's eye
20. DIM SHARED p(max) AS star '                                     dimension the star data array
21. DIM SHARED speed AS INTEGER: speed = 2 '                        warp factor
22. DIM SHARED xch AS _BYTE
23. DIM SHARED ych AS _BYTE
24.  
25. PopVoid '                                                       OldMoses said "Let there be light" and the universe was, is and ever shall be
26. WINDOW (-300, 300)-(300, -300) '                                create viewport window, Cap'n Kirk spends his days staring at this
27.  
28. DO '                                                            draw the stars
29.     x$ = INKEY$
30.     IF x$ = "" THEN
31.         xch = 0: ych = 0
32.     END IF
33.     IF x$ = CHR$(43) THEN speed = speed + 1
34.     IF x$ = CHR$(45) THEN speed = speed - 1
35.     IF x$ = CHR$(0) + CHR$(75) THEN xch = 1
36.     IF x$ = CHR$(0) + CHR$(77) THEN xch = -1
37.     'IF x$ = CHR$(0) + CHR$(72) THEN ych = 1
38.     'IF x$ = CHR$(0) + CHR$(80) THEN ych = -1
39.     CLS
40.     FOR x = 1 TO max '                                          iterate through all stars
41.         dst = Pythagorus(p(x)) '                                distance to star
42.         p(x).x = p(x).x + SinCalc(p(x).z, xch * 0.3)
43.         'p(x).y = p(x).y + CosCalc(p(x).z, ych * 0.3) '          <<<this just doesn't work
44.         p(x).xa = p(x).x / dst * vprt '                         get relative screen position from absolute position for x & y
45.         p(x).ya = p(x).y / dst * vprt
46.         IF ABS(p(x).xa) < 301 AND ABS(p(x).ya) < 301 THEN '     place the star if within the viewport
47.             fdf& = (dst - 12952) / 8
48.             IF fdf& < 0 THEN fdf& = 0
49.             SELECT CASE dst
50.                 CASE IS > 7500
51.                     PSET (p(x).xa, p(x).ya), _RGBA32(p(x).r, p(x).g, p(x).b, 255 - fdf&)
52.                 CASE ELSE
53.                     FCirc p(x).xa, p(x).ya, 1, _RGBA32(p(x).r, p(x).g, p(x).b, 255)
54.             END SELECT
55.         END IF
56.         p(x).z = p(x).z - speed '                               move the star closer to the viewer
57.         IF speed < 0 THEN
58.             IF p(x).z > 15000 THEN ReplaceStar x, 0
59.         ELSE
60.             IF p(x).z < 0 THEN ReplaceStar x, 15000 '                      add new stars as existing ones go behind the viewer
61.         END IF
62.     NEXT x
63.     _DISPLAY '                                                  eliminate screen flicker
64.     _LIMIT 500 '                                                smooth out the action
65. LOOP UNTIL _KEYDOWN(27)
66.  
67.  
68. SUB PopVoid '                                                   Do an initial population of stars
69.  
70.     FOR x = 1 TO max '                                          place a 'max' # of stars randomly in a 3D space
71.         RANDOMIZE TIMER
72.         p(x).x = INT(RND * 15000) - 7500
73.         p(x).y = INT(RND * 15000) - 7500
74.         p(x).z = INT(RND * 15000) + 1
75.         t% = INT(RND * 110) - 55
76.         ch = INT(RND * 6)
77.         IF ch < 4 THEN
78.             p(x).r = 200 + t%: p(x).b = 200 - t%
79.         ELSE
80.             p(x).r = 200 - t%: p(x).b = 200 + t%
81.         END IF
82.         p(x).g = 200
83.     NEXT x
84.  
85. END SUB 'PopVoid
86.  
87.  
88. FUNCTION Pythagorus (var1 AS star)
89.  
90.     horizontal = _HYPOT(ABS(var1.x), ABS(var1.y)) '             Use to find distance between star and origin (viewer)
91.     Pythagorus = _HYPOT(horizontal, ABS(var1.z))
92.  
93. END FUNCTION 'Pythagorus
94.  
95.  
96. SUB ReplaceStar (var AS INTEGER, insert AS INTEGER) '                              This replaces any star that goes behind the viewer
97.  
98.     RANDOMIZE TIMER
99.     p(var).x = INT(RND * 15000) - 7500 '                        New x,y,z but keep old color for simplicity sake
100.     p(var).y = INT(RND * 15000) - 7500
101.     p(var).z = insert
102.  
103. END SUB 'ReplaceStar
104.  
105. FUNCTION SinCalc (var1 AS _INTEGER64, var2 AS SINGLE)
106.  
107.     'Polar coordinate X finder
108.     'used to find X coordinate of a speed/distance (var1) and heading/azimuth (var2)
109.     SinCalc = var1 * SIN(_D2R(var2))
110.  
111. END FUNCTION 'SinCalc
112.  
113.  
114. FUNCTION CosCalc (var1 AS _INTEGER64, var2 AS SINGLE)
115.  
116.     'Polar coordinate Y finder
117.     'used to find Y coordinate of a speed/distance (var1) and heading/azimuth (var2)
118.     CosCalc = var1 * COS(_D2R(var2))
119.  
120. END FUNCTION 'CosCalc
121.  
122.  
123. SUB FCirc (CX AS INTEGER, CY AS INTEGER, RR AS INTEGER, C AS _UNSIGNED LONG)
124.     DIM R AS INTEGER, RError AS INTEGER
125.     DIM X AS INTEGER, Y AS INTEGER
126.  
127.     R = ABS(RR)
128.     RError = -R
129.     X = R
130.     Y = 0
131.     IF R = 0 THEN PSET (CX, CY), C: EXIT SUB
132.     LINE (CX - X, CY)-(CX + X, CY), C, BF
133.     WHILE X > Y
134.         RError = RError + Y * 2 + 1
135.         IF RError >= 0 THEN
136.             IF X <> Y + 1 THEN
137.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
138.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
139.             END IF
140.             X = X - 1
141.             RError = RError - X * 2
142.         END IF
143.         Y = Y + 1
144.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
145.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
146.     WEND
147. END SUB 'FCirc
148.  

[bplus]

Hi Andy,

That has very nice 3D look! You have (probably) seen what happens when press - too long? :)

[OldMoses]

Hi Andy,

That has very nice 3D look! You have (probably) seen what happens when press - too long? :)

Yep, it swallows my universe into oblivion and it doesn't come back. I may have to work on that one. ;)

Update: simple fix, now it goes both ways.

[SierraKen]

That's really cool looking OldMoses!

[OldMoses]

That's really cool looking OldMoses!

Thanks, when I wrote it, I was shocked at how simple the math was. It's basically a star "wind tunnel", where the stars stay locked in the x & y position and only their z axis position is advanced toward the viewer. Their actual x & y are translated to an apparent x & y that is plotted on a virtual viewport at z=600, while the stars themselves go as far out as z=15,000. It's the ratio of the distance to the star and the distance to the viewport that gives the "parallax" effect of nearer stars moving faster, when in fact they are all advancing at the same speed. I learned that trick of perspective while researching ray tracing algorithms recently.

[SierraKen]

Amazing OldMoses.

Well, for the fun of it and the Star Trek geek I am, I added the mouse to mine where you can move the mouse left or right and see what the stars look like flying by on the side of you. Like when it shows the Star Trek people looking out a side window and the stars fly by. I had to add some numbers for the stars to last longer, but it was pretty easy.
Check it out:

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2.  
3. _TITLE "Warp Speed  - Use Up and Down Arrow Keys"
4. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
5.  
6. SCREEN _NEWIMAGE(800, 800, 32)
7.  
8. 'Set the default speed, amount of stars, and then make the first stars.
9. speed = .001
10. amount = 200
11. xx = 0
12. FOR stars = 1 TO amount
13.     GOSUB make:
14. NEXT stars
15.  
16. DO
17.     _LIMIT 1000
18.     FOR stars = 1 TO amount
19.         a$ = INKEY$
20.         IF a$ = CHR$(27) THEN END
21.         DO WHILE _MOUSEINPUT
22.             mouseX = _MOUSEX
23.             mouseY = _MOUSEY
24.             mouseLeftButton = _MOUSEBUTTON(1)
25.             mouseRightButton = _MOUSEBUTTON(2)
26.             mouseMiddleButton = _MOUSEBUTTON(3)
27.             mouseWheel = mouseWheel + _MOUSEWHEEL
28.         LOOP
29.         xx = (mouseX - 400) * 8
30.         xx = xx * -1
31.         'Detect the arrow keys to make it go faster or slower.
32.         IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
33.         IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
34.         IF warp < .002 THEN warp = 0
35.         IF warp > 10 THEN warp = 10
36.         IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
37.         IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
38.         IF speed < .001 THEN speed = .001
39.         IF speed > .01 THEN speed = .01
40.  
41.         'Move the stars.
42.         x(stars) = x(stars) + dx(stars) * speed
43.         y(stars) = y(stars) + dy(stars) * speed
44.  
45.         'Get a new star if one goes off the screen.
46.         IF x(stars) < -6400 OR x(stars) > 6400 OR y(stars) < -400 OR y(stars) > 400 THEN GOSUB make:
47.  
48.         'Draw the stars, c(stars) is the choice of color.
49.         IF sz(stars) > 2 THEN sz(stars) = 2
50.         IF c(stars) < 65 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
51.         IF c(stars) > 64 AND c(stars) < 85 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
52.         IF c(stars) > 84 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
53.  
54.         'If the size of the star is less than 1, skip paint.
55.         IF sz(stars) < 1 THEN GOTO nopaint:
56.  
57.         'Paint the stars.
58.         IF c(stars) < 65 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
59.         IF c(stars) > 64 AND c(stars) < 85 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
60.         IF c(stars) > 84 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
61.         nopaint:
62.     NEXT stars
63.  
64.     'This stops flickering.
65.     _DISPLAY
66.  
67.     'Erase the stars for motion but keep a transparent black for the trails.
68.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
69. LOOP
70.  
71. make:
72. RANDOMIZE TIMER
73.  
74. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
75.  
76. x(stars) = (RND - .5) * _WIDTH
77.  
78. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
79.  
80. y(stars) = (RND - .5) * _HEIGHT
81.  
82. 'Get a random star size between .25 and 2.
83.  
84. sz(stars) = (RND * 2) + .25
85.  
86. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
87.  
88. c(stars) = INT(RND * 100) + 1
89.  
90. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
91.  
92. v = 5 + RND * 5
93. dx(stars) = x(stars) * v
94. dy(stars) = y(stars) * v
95.  
96. RETURN
97.  
98.  

[TempodiBasic]

Hi SierraKen

fine and with a speedy change of direction by mouse!

if you like starfield and 4 direction of navigation take a look at this my code porting in QB64 a Java demo

Code: QB64: [Select]

1. 'starfield in processing
2. TYPE Star
3.     x AS DOUBLE
4.     y AS DOUBLE
5.     z AS DOUBLE
6. END TYPE
7. CONST True = -1, False = NOT True, radStar = 4, countStar = 800, HScreen = 500, WScreen = 800
8. DIM SHARED a AS LONG, b AS LONG, Zvel AS INTEGER, WarpVel AS INTEGER, Yvel AS INTEGER, Xvel AS INTEGER
9. DIM Stars(1 TO countStar) AS Star
10.  
11.  
12.  
13. RANDOMIZE TIMER
14. ' we need two surface to avoid flickering that rises up painting directly on the screen
15. a = _NEWIMAGE(WScreen, HScreen, 32) 'main screen
16. b = _NEWIMAGE(WScreen, HScreen, 32) ' panel to draw screen before displaying it
17.  
18. _DEST b
19. WINDOW SCREEN(-WScreen / 2, -HScreen / 2)-(WScreen / 2, HScreen / 2)
20.  
21. SCREEN a
22. InitStar Stars()
23. Zvel = 1
24. Xvel = 0
25. Yvel = 0
26. WarpVel = 1
27. t# = TIMER
28. DO
29.     _LIMIT 120
30.     DrawStars Stars()
31.     UpDate Stars()
32.  
33.     ' Enter key = reset Key
34.     IF _KEYDOWN(13) THEN
35.         Xvel = 0
36.         Yvel = 0
37.         Zvel = 5
38.         WarpVel = 1
39.     END IF
40.  
41.     '19200
42.     ' Left arrow
43.     IF _KEYDOWN(19200) AND ABS(TIMER - t#) > .1 AND Xvel > -15 THEN
44.         Xvel = Xvel - 1
45.         t# = TIMER
46.     END IF
47.  
48.     '19712
49.     ' Right arrow
50.     IF _KEYDOWN(19712) AND ABS(TIMER - t#) > .1 AND Xvel < 15 THEN
51.         Xvel = Xvel + 1
52.         t# = TIMER
53.     END IF
54.  
55.  
56.     '20480
57.     ' Down arrow
58.     IF _KEYDOWN(20480) AND ABS(TIMER - t#) > .1 AND Yvel < 15 THEN
59.         Yvel = Yvel + 1
60.         t# = TIMER
61.     END IF
62.  
63.  
64.     '18432
65.     ' Up arrow
66.     IF _KEYDOWN(18432) AND ABS(TIMER - t#) > .1 AND Yvel > -15 THEN
67.         Yvel = Yvel - 1
68.         t# = TIMER
69.     END IF
70.  
71.     '+
72.     IF _KEYDOWN(43) AND ABS(TIMER - t#) > .1 AND Zvel < 15 THEN
73.         Zvel = Zvel + 1
74.         t# = TIMER
75.     END IF
76.  
77.  
78.     '-
79.     IF _KEYDOWN(45) AND ABS(TIMER - t#) > .1 AND Zvel > 0 THEN
80.         Zvel = Zvel - 1
81.         t# = TIMER
82.     END IF
83.  
84.     ' WarpVel activate/deactivate the wake effect
85.     ' w W
86.     IF _KEYDOWN(87) OR _KEYDOWN(119) THEN
87.         IF ABS(TIMER - t#) > .1 THEN
88.             WarpVel = WarpVel * -1
89.             t# = TIMER
90.         END IF
91.     END IF
92.  
93.     ' Zvel is min when _mouseX is min on the left and is max when _mouseX is max on the right
94.     WHILE _MOUSEINPUT = -1
95.         IF ABS(TIMER - t#) > .1 THEN
96.             Zvel = map(_MOUSEX, 0, WScreen, 0, 15)
97.             t# = TIMER
98.         END IF
99.     WEND
100. LOOP UNTIL _KEYHIT = 32 ' stop pressing spacebar
101. END
102.  
103. SUB UpDate (starField() AS Star)
104.     DIM i AS INTEGER
105.  
106.     FOR i = 1 TO countStar
107.         starField(i).x = starField(i).x + Xvel
108.         starField(i).y = starField(i).y + Yvel
109.         starField(i).z = starField(i).z - Zvel
110.         IF starField(i).z < 1 OR starField(i).y > HScreen OR starField(i).x > WScreen THEN
111.             starField(i).z = WScreen
112.             starField(i).x = MinMax(-WScreen, WScreen) ' new position x
113.             starField(i).y = MinMax(-HScreen, HScreen) ' new position y
114.         END IF
115.     NEXT
116. END SUB
117.  
118. SUB InitStar (starField() AS Star)
119.     DIM i AS INTEGER
120.  
121.     FOR i = 1 TO countStar
122.         starField(i).x = MinMax(-WScreen, WScreen)
123.         starField(i).y = MinMax(-HScreen, HScreen)
124.         starField(i).z = INT(RND * WScreen) + 1
125.     NEXT
126. END SUB
127.  
128. SUB DrawStars (starField() AS Star)
129.     DIM i AS INTEGER
130.     DIM sx AS DOUBLE, sy AS DOUBLE, sr AS DOUBLE, px AS DOUBLE, py AS DOUBLE
131.     _DEST b
132.     CLS
133.     FOR i = 1 TO countStar
134.         ' the ratio x/z is min when x is min and is max when x is max
135.         sx = map(starField(i).x / starField(i).z, 0, 1, 0, WScreen)
136.         ' the ratio y/z is min when y is min and is max when y is max
137.         sy = map(starField(i).y / starField(i).z, 0, 1, 0, HScreen)
138.         ' radius in warp speed is a point of 1 pixel
139.         IF WarpVel = True THEN
140.             sr = 1
141.         ELSE
142.             ' radius of circle is max when z is near 0 and min when z is max
143.             sr = map(starField(i).z, 0, WScreen, radStar, 0)
144.         END IF
145.  
146.         CIRCLE (sx, sy), sr, _RGB(255, 255, 255)
147.         ' if radius of circle is more than 1 you can fill it else no
148.         IF sr > 1 THEN PAINT STEP(0, 0), _RGB(255, 255, 255), _RGB(255, 255, 255)
149.  
150.         ' if we want draw the wake of the stars when we travel in warp speed
151.         IF WarpVel = True THEN
152.             px = map(starField(i).x / (starField(i).z + 25), 0, 1, 0, WScreen)
153.             py = map(starField(i).y / (starField(i).z + 25), 0, 1, 0, HScreen)
154.             LINE (sx, sy)-(px, py), _RGB(255, 255, 255)
155.         END IF
156.     NEXT
157.     info
158.     _DEST a
159.     _SOURCE b
160.     _PUTIMAGE
161. END SUB
162.  
163. FUNCTION MinMax (Max%, Min%)
164.     IF Max% < Min% THEN SWAP Max%, Min%
165.     MinMax = INT(RND * (Max% - Min% + 1)) + Min%
166. END FUNCTION
167.  
168. ' p5.js Functions
169. FUNCTION map! (value!, mianRange!, maxRange!, newMinRange!, newMaxRange!)
170.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
171. END FUNCTION
172.  
173. SUB info
174.     LOCATE 1, 1: PRINT "Stop";
175.     LOCATE 1, 98: PRINT "Run";
176.  
177.     LOCATE 2, 1: PRINT "Speed:"; Zvel;
178.     IF WarpVel = True THEN PRINT "Mode Warp ON" ELSE PRINT "Mode Warp OFF"
179.     LOCATE 2, 91: PRINT "Yvel "; Yvel;
180.     LOCATE 2, 82: PRINT "Xvel "; Xvel;
181.     LOCATE 30, 1: PRINT " Help: Spacebar = quit, Enter = reset, + = vel up , - = vel down, Arrows= directions, W = warp mode";
182. END SUB
183.  
184.  

Thanks to share your code

PS is color of star random (with not specific meaning)?

[OldMoses]

Pretty cool use of the mouse. It took me a minute figure out that it was working with the width of screen, but after that there was no issues controlling it.

[SierraKen]

Thanks OldMoses.

TempoidBasic, that's a really cool example! I am working on something similar but not that advanced. I'm going to change from the mouse to the arrow keys if I can figure it out. The mouse is just too touchy and is hard to get back to center, for the general public anyway.

[SierraKen]

I changed mine to use the arrow keys inside. Arrow keys make it easier to control. Also I made it so the Space Bar puts it back to center. :) One interesting thing I found out is that the xx variable I use to add or subtract from the center, can make it do weird things if it's in the negative lol. Like if you make xx negative, it will show the stars coming from each side of the screen instead and overlapping. lol I removed that part because it just didn't look right. LOL

This version is on my website now along with thanks to B+ and the guys on this forum, as well as a link to this forum. http://www.KensPrograms.com/

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2.  
3. _TITLE "Warp Speed  - Use Up and Down Arrow Key for speed and Right and Left Arrows to view sides and Space Bar to center."
4. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
5.  
6. SCREEN _NEWIMAGE(800, 800, 32)
7.  
8. 'Set the default speed, amount of stars, and then make the first stars.
9. speed = .001
10. amount = 200
11. xx = 0
12. FOR stars = 1 TO amount
13.     GOSUB make:
14. NEXT stars
15.  
16. DO
17.     _LIMIT 1000
18.     FOR stars = 1 TO amount
19.         a$ = INKEY$
20.         IF a$ = CHR$(27) THEN END
21.         IF a$ = CHR$(0) + CHR$(77) THEN xx = xx + 50
22.         IF a$ = CHR$(0) + CHR$(75) THEN xx = xx - 50
23.         IF a$ = " " THEN xx = 0
24.  
25.         IF xx > 1200 THEN xx = 1200
26.         IF xx < -1200 THEN xx = -1200
27.  
28.         'Detect the arrow keys to make it go faster or slower.
29.         IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
30.         IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
31.         IF warp < .002 THEN warp = 0
32.         IF warp > 10 THEN warp = 10
33.         IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
34.         IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
35.         IF speed < .001 THEN speed = .001
36.         IF speed > .01 THEN speed = .01
37.  
38.         'Move the stars.
39.         x(stars) = x(stars) + dx(stars) * speed
40.         y(stars) = y(stars) + dy(stars) * speed
41.  
42.         'Get a new star if one goes off the screen.
43.         IF x(stars) < -6400 OR x(stars) > 6400 OR y(stars) < -400 OR y(stars) > 400 THEN GOSUB make:
44.  
45.         'Draw the stars, c(stars) is the choice of color.
46.         IF sz(stars) > 2 THEN sz(stars) = 2
47.         IF c(stars) < 65 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
48.         IF c(stars) > 64 AND c(stars) < 85 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
49.         IF c(stars) > 84 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
50.  
51.         'If the size of the star is less than 1, skip paint.
52.         IF sz(stars) < 1 THEN GOTO nopaint:
53.  
54.         'Paint the stars.
55.         IF c(stars) < 65 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
56.         IF c(stars) > 64 AND c(stars) < 85 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
57.         IF c(stars) > 84 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
58.         nopaint:
59.     NEXT stars
60.  
61.     'This stops flickering.
62.     _DISPLAY
63.  
64.     'Erase the stars for motion but keep a transparent black for the trails.
65.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
66. LOOP
67.  
68. make:
69. RANDOMIZE TIMER
70.  
71. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
72.  
73. x(stars) = (RND - .5) * _WIDTH
74.  
75. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
76.  
77. y(stars) = (RND - .5) * _HEIGHT
78.  
79. 'Get a random star size between .25 and 2.
80.  
81. sz(stars) = (RND * 2) + .25
82.  
83. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
84.  
85. c(stars) = INT(RND * 100) + 1
86.  
87. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
88.  
89. v = 5 + RND * 5
90. dx(stars) = x(stars) * v
91. dy(stars) = y(stars) * v
92.  
93. RETURN
94.  

[TempodiBasic]

Sierraken
good and cool!

Well done.

[TempodiBasic]

Hi SierraKen

please read this second my feedback only if you want go further to the development of your creature otherwise go on another topic.
And thanks to let me read and try your code.

I can pass you some tips that at its time I got from Qb64 masters...

1.  smoother keyboard input with new QB64 function than Inkey$

see a mod of your program

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2. '2019-08-12 TDB mod introducing _keyhit and _Keyclear to a   smoother response to keyboard
3.  
4. _TITLE "Warp Speed  - Use Up and Down Arrow Key for speed and Right and Left Arrows to view sides and Space Bar to center."
5. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
6.  
7. SCREEN _NEWIMAGE(800, 800, 32)
8.  
9. 'Set the default speed, amount of stars, and then make the first stars.
10. speed = .001
11. amount = 200
12. xx = 0
13. FOR stars = 1 TO amount
14.     GOSUB make:
15. NEXT stars
16.  
17. DO
18.     _LIMIT 30 ' <---- it seems enough in respect of 1000
19.     FOR stars = 1 TO amount
20.         ' a$ = INKEY$
21.  
22.         u = 0 ' a tricky way to reset the variable of input
23.         u = _KEYHIT
24.         IF u = 27 THEN END
25.         IF u = 19200 THEN xx = xx - 50
26.         IF u = 19712 THEN xx = xx + 50
27.         IF u = 32 THEN xx = 0
28.         ' IF a$ = CHR$(27) THEN END
29.         ' IF a$ = CHR$(0) + CHR$(77) THEN xx = xx + 50
30.         ' IF a$ = CHR$(0) + CHR$(75) THEN xx = xx - 50
31.         ' IF a$ = " " THEN xx = 0
32.  
33.         IF xx > 1200 THEN xx = 1200
34.         IF xx < -1200 THEN xx = -1200
35.  
36.         'Detect the arrow keys to make it go faster or slower.
37.         IF u = 18432 THEN speed = speed + .001: warp = warp + 1
38.         IF u = 20480 THEN speed = speed - .001: warp = warp - 1
39.         REM _KEYCLEAR  '<---- you can get the same effect REMming u = 0 and activating this statement here
40.  
41.         'IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
42.         'IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
43.  
44.         IF warp < .002 THEN warp = 0
45.         IF warp > 10 THEN warp = 10
46.         IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
47.         IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
48.         IF speed < .001 THEN speed = .001
49.         IF speed > .01 THEN speed = .01
50.  
51.         'Move the stars.
52.         x(stars) = x(stars) + dx(stars) * speed
53.         y(stars) = y(stars) + dy(stars) * speed
54.  
55.         'Get a new star if one goes off the screen.
56.         IF x(stars) < -6400 OR x(stars) > 6400 OR y(stars) < -400 OR y(stars) > 400 THEN GOSUB make:
57.  
58.         'Draw the stars, c(stars) is the choice of color.
59.         IF sz(stars) > 2 THEN sz(stars) = 2
60.         IF c(stars) < 65 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
61.         IF c(stars) > 64 AND c(stars) < 85 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
62.         IF c(stars) > 84 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
63.  
64.         'If the size of the star is less than 1, skip paint.
65.         IF sz(stars) < 1 THEN GOTO nopaint:
66.  
67.         'Paint the stars.
68.         IF c(stars) < 65 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
69.         IF c(stars) > 64 AND c(stars) < 85 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
70.         IF c(stars) > 84 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
71.         nopaint:
72.     NEXT stars
73.  
74.     'This stops flickering.
75.     _DISPLAY
76.  
77.     'Erase the stars for motion but keep a transparent black for the trails.
78.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
79. LOOP
80.  
81. make:
82. RANDOMIZE TIMER
83.  
84. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
85.  
86. x(stars) = (RND - .5) * _WIDTH
87.  
88. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
89.  
90. y(stars) = (RND - .5) * _HEIGHT
91.  
92. 'Get a random star size between .25 and 2.
93.  
94. sz(stars) = (RND * 2) + .25
95.  
96. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
97.  
98. c(stars) = INT(RND * 100) + 1
99.  
100. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
101.  
102. v = 5 + RND * 5
103. dx(stars) = x(stars) * v
104. dy(stars) = y(stars) * v
105.  
106. RETURN
107.  

2. less flickering or blinking of screen   (also with Inkey$ if you move fast to right or to left you got the stars jumping on the screen)
  2.1 an alternative (long?) way to manage output to screen with 2 panel for images
  2.2 an adjust of _limit value
  2.3 an adjust of how to move in the select direction the stars (50 is high, 20 seems better)

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2. '2019-08-12 TDB mod introducing _keyhit and _Keyclear to a smoother response to keyboard
3. '2019-08-12 TDB mod introducing the 2 panel tecnique for animation to avoid flickering and loose of images
4. _TITLE "Warp Speed  - Use Up and Down Arrow Key for speed and Right and Left Arrows to view sides and Space Bar to center."
5. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
6.  
7. SCREEN _NEWIMAGE(800, 800, 32)
8.  
9. ' another way to avoid flickering is to use 2 panel 1st for screen output and 2nd for drawing
10. ' so you draw on 2nd and copy to 1st to show
11. Bpanel& = _NEWIMAGE(800, 800, 32)
12.  
13.  
14. 'Set the default speed, amount of stars, and then make the first stars.
15. speed = .001
16. amount = 200
17. xx = 0
18. FOR stars = 1 TO amount
19.     GOSUB make:
20. NEXT stars
21.  
22. DO
23.     _LIMIT 30 ' <---- it seems enough in respect of 1000
24.     FOR stars = 1 TO amount
25.         ' a$ = INKEY$
26.  
27.         u = 0 ' a tricky way to reset the variable of input
28.         u = _KEYHIT
29.         IF u = 27 THEN END
30.         IF u = 19200 THEN xx = xx - 20 ' left key
31.         IF u = 19712 THEN xx = xx + 20 ' right key
32.         IF u = 32 THEN xx = 0
33.         ' IF a$ = CHR$(27) THEN END
34.         ' IF a$ = CHR$(0) + CHR$(77) THEN xx = xx + 50
35.         ' IF a$ = CHR$(0) + CHR$(75) THEN xx = xx - 50
36.         ' IF a$ = " " THEN xx = 0
37.  
38.         IF xx > 1200 THEN xx = 1200
39.         IF xx < -1200 THEN xx = -1200
40.  
41.         'Detect the arrow keys to make it go faster or slower.
42.         IF u = 18432 THEN speed = speed + .001: warp = warp + 1 ' up key
43.         IF u = 20480 THEN speed = speed - .001: warp = warp - 1 ' down key
44.         REM _KEYCLEAR  '<---- you can get the same effect REMming u = 0 and activating this statement here
45.  
46.         'IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
47.         'IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
48.  
49.         IF warp < .002 THEN warp = 0
50.         IF warp > 10 THEN warp = 10
51.         'Why do you write on the screen 200 times the same text?
52.         ' I  move the PRINT instruction in the area of output to screen one time out of for..next
53.  
54.         IF speed < .001 THEN speed = .001
55.         IF speed > .01 THEN speed = .01
56.  
57.         'Move the stars.
58.         x(stars) = x(stars) + dx(stars) * speed
59.         y(stars) = y(stars) + dy(stars) * speed
60.  
61.         'Get a new star if one goes off the screen.
62.         IF x(stars) < -6400 OR x(stars) > 6400 OR y(stars) < -400 OR y(stars) > 400 THEN GOSUB make:
63.  
64.  
65.         _DEST Bpanel&
66.         'Draw the stars, c(stars) is the choice of color.
67.         IF sz(stars) > 2 THEN sz(stars) = 2
68.         IF c(stars) < 65 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
69.         IF c(stars) > 64 AND c(stars) < 85 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
70.         IF c(stars) > 84 THEN CIRCLE ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
71.  
72.         'If the size of the star is less than 1, skip paint.
73.         IF sz(stars) < 1 THEN GOTO nopaint:
74.  
75.         'Paint the stars.
76.         IF c(stars) < 65 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
77.         IF c(stars) > 64 AND c(stars) < 85 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
78.         IF c(stars) > 84 THEN PAINT ((x(stars) + _WIDTH / 2) + xx, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
79.         nopaint:
80.     NEXT stars
81.     ' here print one time info in text format on the screen
82.     IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
83.     IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
84.     _SOURCE Bpanel&: _DEST 0
85.     _PUTIMAGE
86.  
87.     'This stops flickering.
88.     '   _DISPLAY              <--- the quick method
89.  
90.  
91.     _DEST Bpanel&
92.     'Erase the stars for motion but keep a transparent black for the trails.
93.     CLS , _RGBA32(0, 0, 0, 30)
94.     '    LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
95. LOOP
96.  
97. make:
98. RANDOMIZE TIMER
99.  
100. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
101.  
102. x(stars) = (RND - .5) * _WIDTH
103.  
104. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
105.  
106. y(stars) = (RND - .5) * _HEIGHT
107.  
108. 'Get a random star size between .25 and 2.
109.  
110. sz(stars) = (RND * 2) + .25
111.  
112. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
113.  
114. c(stars) = INT(RND * 100) + 1
115.  
116. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
117.  
118. v = 5 + RND * 5
119. dx(stars) = x(stars) * v
120. dy(stars) = y(stars) * v
121.  
122. RETURN
123.  
124.  

and two glitches...
1 moving to the leftest position or the rightest position you get stars moving in the opposite extreme direction
2 moving fastly to left or to right from initial position you get some various movements of stars
 

Thanks to read