Help with Starfield

[johnno56]

Ya gotta love star fields - 'trig-less' or not - Very cool.

[SMcNeill]

And now with 10 warp speeds installed on our TrekDrive!

Code: QB64: [Select]

1. TYPE Dot_type
2.     x AS _FLOAT
3.     y AS _FLOAT
4.     movex AS _FLOAT
5.     movey AS _FLOAT
6.     color AS _FLOAT
7.     size AS _FLOAT
8. END TYPE
9. DIM dots(10000) AS Dot_type
10.  
11.  
12. SCREEN _NEWIMAGE(1024, 720, 32)
13. WINDOW (-1000, -1000)-(1000, 1000)
14. RANDOMIZE TIMER
15.  
16. dotsinplay = 1000
17. FOR i = 1 TO dotsinplay
18.     dots(i).x = RND * 100 - 50
19.     dots(i).y = RND * 100 - 50
20.     dots(i).movex = RND * 10 - 5
21.     dots(i).movey = RND * 10 - 5
22.     dots(i).color = &HFF000000 + INT(RND * &HFFFFFF) + 1
23.     dots(i).size = RND * 5
24. NEXT
25.  
26.  
27.  
28.  
29. warpspeed = 1
30. DO
31.     CLS
32.     i = 1
33.     DO 'move and replace dots which would go off screen
34.         dots(i).x = dots(i).x + dots(i).movex * warpspeed
35.         dots(i).y = dots(i).y + dots(i).movey * warpspeed
36.         IF dots(i).x < -1000 OR dots(i).x > 1000 or _
37.            dots(i).y < -1000 OR dots(i).y > 1000 THEN
38.             dots(i).x = RND * 100 - 50
39.             dots(i).y = RND * 100 - 50
40.             dots(i).movex = (RND * 10 - 5)
41.             dots(i).movey = (RND * 10 - 5)
42.             dots(i).color = &HFF000000 + INT(RND * &HFFFFFF) + 1
43.             dots(i).size = RND * 5
44.         END IF
45.         CircleFill dots(i).x, dots(i).y, dots(i).size, dots(i).color
46.         i = i + 1
47.     LOOP UNTIL i >= dotsinplay
48.     LOCATE 1, 1: PRINT "Warp Speed:"; warpspeed
49.  
50.     a$ = INKEY$
51.     SELECT CASE a$
52.         CASE "1" TO "9": warpspeed = VAL(a$)
53.         CASE "0"
54.             _AUTODISPLAY
55.             CLS
56.             PRINT "THE ENGINES CAN'T TAKE ANY MORE CAPT'N!"
57.             FOR i = 1 TO 5
58.                 _DELAY 1
59.                 FOR j = 1 TO i - 1:
60.                     PRINT ".";
61.                 NEXT
62.                 PRINT "."
63.             NEXT
64.             _DELAY 1
65.             PRINT "BOOOOOOOOOOOOOOMMMMMMM!!!!"
66.             BEEP
67.             BEEP
68.             SYSTEM
69.     END SELECT
70.     _DISPLAY
71. LOOP
72.  
73. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
74.     ' CX = center x coordinate
75.     ' CY = center y coordinate
76.     '  R = radius
77.     '  C = fill color
78.     DIM Radius AS INTEGER, RadiusError AS INTEGER
79.     DIM X AS INTEGER, Y AS INTEGER
80.     Radius = ABS(R)
81.     RadiusError = -Radius
82.     X = Radius
83.     Y = 0
84.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
85.     LINE (CX - X, CY)-(CX + X, CY), C, BF
86.     WHILE X > Y
87.         RadiusError = RadiusError + Y * 2 + 1
88.         IF RadiusError >= 0 THEN
89.             IF X <> Y + 1 THEN
90.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
91.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
92.             END IF
93.             X = X - 1
94.             RadiusError = RadiusError - X * 2
95.         END IF
96.         Y = Y + 1
97.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
98.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
99.     WEND
100. END SUB

[bplus]

Yeah Steve, I debated whether to use your "Gold Standard" CircleFill routine, the one tried and tested here and maybe  even at Walter's forum... and likely long before I came to [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there], but I figured Ken might be more inclined to buy a smaller more easy to understand SUB circleFill using PAINT??? Dang just get him to use a SUB properly to see the convenience!

In attempt to help Ken, I also dumped the use of TYPE which does keep all those arrays under one more manage-able name and index. I know others who avoid this structure form of data, it's easier to understand the tenancy to avoid that complexity.

I am afraid Ken is very into his way of doing things like drawing and the blacking out moving figures rather than simple CLS and redraw everything like he is back in 80's when that sort of thing took too much time (ha! or using JB). And why RANDOMIZE TIMER before every use of RND???

I am sorry to see all the folks encouraging the non use of trig, all these people who do know how to use trig. I don't get it, sure Star fields can be done easily without SIN and COS but it seems an ideal time for some SIN COS practice. Does doing Star Fields without trig help Ken?  Oh sure, it helps him avoid SIN and COS that much longer :D

Can anyone do regular polygons without SIN and COS? Probably, but who wants to try?

[SMcNeill]

Can anyone do regular polygons without SIN and COS? Probably, but who wants to try?

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 256)
2.  
3. FOR i = 3 TO 10
4.     CLS
5.     angle = 360 / i
6.     a$ = _TRIM$(STR$(angle))
7.     d$ = "U100"
8.     PSET (500, 300)
9.     n = 0
10.     d$ = "U100"
11.     FOR j = 1 TO i
12.         n = n + angle
13.         a$ = _TRIM$(STR$(n))
14.         d$ = d$ + " TA" + a$ + " U100"
15.     NEXT
16.     DRAW d$
17.     SLEEP
18. NEXT

;D

[bplus]

Oh yeah draw strings, OK! :)

[OldMoses]

Being an inveterate tweaker, I've been messing with this star field thing. While I didn't use SIN & COS in the original code, I reasoned that I could use it to add some navigational fun. SIN will slew the stars left and right with the use of the left and right arrow keys, and plus and minus keys will speed and slow the action.

Well then I thought, hell, use COS to pitch up and down as well. Except that approaching that in the same manner makes the display go batty. Uncomment line 35 to see the effect. I'm not sure why it dislikes one and not the other...

Code: QB64: [Select]

1. a& = _NEWIMAGE(600, 600, 32)
2. SCREEN a&
3. TYPE star '                                                     define the star data type
4.     x AS INTEGER
5.     y AS INTEGER
6.     z AS INTEGER
7.     xa AS INTEGER
8.     ya AS INTEGER
9. END TYPE
10.  
11. DIM SHARED max AS INTEGER: max = 500
12. DIM SHARED vprt AS INTEGER: vprt = 600 '                        set the viewport setback from viewer's eye
13. DIM SHARED p(max) AS star '                                     dimension the star data array
14. DIM SHARED speed AS INTEGER: speed = 2 '                        warp factor
15. DIM SHARED xch AS _BYTE
16. DIM SHARED ych AS _BYTE
17.  
18. PopVoid '                                                       OldMoses said "Let there be light" and the universe was, is and ever shall be
19. WINDOW (-300, 300)-(300, -300) '                                create viewport window, Cap'n Kirk spends his days staring at this
20.  
21. DO '                                                            draw the stars
22.     x$ = INKEY$
23.     IF x$ = "" THEN
24.         xch = 0: ych = 0
25.     END IF
26.     IF x$ = CHR$(43) THEN speed = speed + 1
27.     IF x$ = CHR$(45) THEN speed = speed - 1
28.     IF x$ = CHR$(0) + CHR$(75) THEN xch = 1 '      steering left/right
29.     IF x$ = CHR$(0) + CHR$(77) THEN xch = -1
30.     IF x$ = CHR$(0) + CHR$(72) THEN ych = 1 '      pitching up/down
31.     IF x$ = CHR$(0) + CHR$(80) THEN ych = -1
32.     CLS
33.     FOR x = 1 TO max '                                          iterate through all stars
34.         p(x).x = p(x).x + SinCalc(p(x).z, xch * 0.3)
35.         'p(x).y = p(x).y + CosCalc(p(x).z, ych * 0.3)
36.         p(x).xa = p(x).x / Pythagorus(p(x)) * vprt '            get relative screen position from absolute position for x & y
37.         p(x).ya = p(x).y / Pythagorus(p(x)) * vprt
38.         IF ABS(p(x).xa) < 301 AND ABS(p(x).ya) < 301 THEN '     place the star if within the viewport
39.             PSET (p(x).xa, p(x).ya)
40.         END IF
41.         p(x).z = p(x).z - speed '                               move the star closer to the viewer
42.         IF p(x).z < 0 THEN ReplaceStar x '                      add new stars as existing ones go behind the viewer
43.     NEXT x
44.     _DISPLAY '                                                  eliminate screen flicker
45.     _LIMIT 500 '                                                smooth out the action
46. LOOP UNTIL _KEYDOWN(27)
47.  
48.  
49. SUB PopVoid '                                                   Do an initial population of stars
50.  
51.     FOR x = 1 TO max '                                          place a 'max' # of stars randomly in a 3D space
52.         RANDOMIZE TIMER
53.         p(x).x = INT(RND * 15000) - 7500
54.         p(x).y = INT(RND * 15000) - 7500
55.         p(x).z = INT(RND * 15000) + 1
56.     NEXT x
57.  
58. END SUB 'PopVoid
59.  
60.  
61. FUNCTION Pythagorus (var1 AS star)
62.  
63.     'Use to find distance between two 3D points
64.  
65.     horizontal = _HYPOT(ABS(var1.x), ABS(var1.y))
66.     Pythagorus = _HYPOT(horizontal, ABS(var1.z))
67.  
68. END FUNCTION 'Pythagorus
69.  
70.  
71. SUB ReplaceStar (var AS INTEGER) '                              This replaces any star that goes behind the viewer
72.  
73.     RANDOMIZE TIMER
74.     p(var).x = INT(RND * 15000) - 7500
75.     p(var).y = INT(RND * 15000) - 7500
76.     p(var).z = 15000
77.  
78. END SUB 'ReplaceStar
79.  
80. FUNCTION SinCalc (var1 AS _INTEGER64, var2 AS SINGLE)
81.  
82.     'Polar coordinate X finder
83.     'used to find X coordinate of a speed/distance (var1) and heading/azimuth (var2)
84.     SinCalc = var1 * SIN(_D2R(var2))
85.  
86. END FUNCTION 'SinCalc
87.  
88.  
89. FUNCTION CosCalc (var1 AS _INTEGER64, var2 AS SINGLE)
90.  
91.     'Polar coordinate Y finder
92.     'used to find Y coordinate of a speed/distance (var1) and heading/azimuth (var2)
93.     CosCalc = var1 * COS(_D2R(var2))
94.  
95. END FUNCTION 'CosCalc
96.  
97.  

[SierraKen]

Well, I finally made it! Well, actually I tried to make it with my own code but ended up using just about all of B+'s example. It sure is teaching me a lot though and I thank you to all of you guys for your example codes. I won't be able to remember the math involved (I know it's simple math), unless someday I use this many times to make things with (because of my memory problems). But I did add to it some things that B+ didn't have, like 3 different colored stars, white, red, and blue (for white, Red Giants, and Blue Giants), and different sizes of stars using CIRCLE and PAINT. I also used an example I found on this thread to use keys to speed up and slow down, which are the up and down arrow keys. Instead of Impulse Speed I use "Cruise Speed" and then Warp 1-10. If you guys, especially B+, don't want this on my website I won't put it on. But I did add credits to the top of the code that you can read below. Thank you again for the help. I might use this in other games or programs (unless you don't want me to). Oh also, I finally know why I couldn't make my own originally, I was very close though, but didn't make just 1 star at a time like this does (except for the first stars).  I know this line must delete all the stars to add motion to them all at once, but does it also make the star tails? I need to experiment with this type of stuff later. :)
 LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF

Here it is, I added lots of remarks to remember the reasons later and for others.

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2.  
3. _TITLE "Warp Speed  - Use Up and Down Arrow Keys"
4. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
5.  
6. SCREEN _NEWIMAGE(800, 800, 32)
7.  
8. 'Set the default speed, amount of stars, and then make the first stars.
9. speed = .001
10. amount = 750
11. FOR stars = 1 TO amount
12.     GOSUB make:
13. NEXT stars
14.  
15. DO
16.     _LIMIT 500
17.     FOR stars = 1 TO amount
18.         a$ = INKEY$
19.         IF a$ = CHR$(27) THEN END
20.  
21.         'Detect the arrow keys to make it go faster or slower.
22.         IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
23.         IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
24.         IF warp < .0003 THEN warp = 0
25.         IF warp > 10 THEN warp = 10
26.         IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
27.         IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
28.         IF speed < .001 THEN speed = .001
29.         IF speed > .01 THEN speed = .01
30.  
31.         'Move the stars.
32.         x(stars) = x(stars) + dx(stars) * speed
33.         y(stars) = y(stars) + dy(stars) * speed
34.  
35.         'See how many stars are on screen, if there's a certain amount, GOSUB to make: to make a new star.
36.         r = x(stars) * x(stars) + y(stars) * y(stars)
37.         IF (r > 600 ^ 2) THEN GOSUB make:
38.  
39.         'Draw the stars, c(stars) is the choice of color.
40.         IF c(stars) < 75 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
41.         IF c(stars) > 74 AND c(stars) < 85 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
42.         IF c(stars) > 84 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
43.  
44.         'If the size of the star is less than 1, skip paint.
45.         IF sz(stars) < 1 THEN GOTO nopaint:
46.  
47.         'Paint the stars.
48.         IF c(stars) < 75 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
49.         IF c(stars) > 74 AND c(stars) < 85 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
50.         IF c(stars) > 84 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
51.         nopaint:
52.     NEXT stars
53.  
54.     _DISPLAY
55.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
56.  
57. LOOP
58.  
59. make:
60. RANDOMIZE TIMER
61.  
62. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
63.  
64. x(stars) = (RND - .5) * _WIDTH
65.  
66. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
67.  
68. y(stars) = (RND - .5) * _HEIGHT
69.  
70. 'Get a random star size between .25 and 2.
71.  
72. sz(stars) = (RND * 2) + .25
73.  
74. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
75.  
76. c(stars) = INT(RND * 100) + 1
77.  
78. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
79.  
80. v = 5 + RND * 5
81. dx(stars) = x(stars) * v
82. dy(stars) = y(stars) * v
83.  
84. RETURN
85.  

[bplus]

Yeah, this line:
 LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
layers the star field with coats of transparent black, the oldest on screen eventually get covered over, this creates the tail effect, thanks Fellippe, from whom I learned that trick.

Looks pretty good Ken :)

I have this strange urge to stand up and salute your stars!

Update: this is looking like my translation of STxAxTIC's code the locating of stars is signature STxAxTIC.

These lines:

Code: QB64: [Select]

1.   'See how many stars are on screen, if there's a certain amount, GOSUB to make: to make a new star.
2.         r = x(stars) * x(stars) + y(stars) * y(stars)
3.         IF (r > 600 ^ 2) THEN GOSUB make:
4.  

are measuring the distance of x, y from the center of the screen. A new star is made when the distance is beyond borders of screen.

[SierraKen]

Thanks B+!  LOL I thought the same thing, red, white, and blue.

[SierraKen]

This is just directly from your example. Wow it is measurement from the center I think. It's not adding stars, I'll change the remark, thank you.

Edit: B+ the more I think about this line, the more confusing it is to me. And I have no idea why it works. I tried using my program without these 2 lines and it only did the first stars and wouldn't make any more, so I put it back. It's confusing because 600 to the second power equals 360,000 which has nothing to do with X * X plus Y * Y.  For example, if a star made it to X=10, Y=10, then 10 * 10 = 100 and again 10 * 10 = 100 so 100 + 100 = 200, nowhere neat 600 to the second power. What am I missing?

Edit again: And I know its 360000 because I took out the equation and just put in 360000 and the program runs fine, but HOW can r get up that high of a number?? lol

Yeah, this line:
 LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
layers the star field with coats of transparent black, the oldest on screen eventually get covered over, this creates the tail effect, thanks Fellippe, from whom I learned that trick.

Looks pretty good Ken :)

I have this strange urge to stand up and salute your stars!

Update: this is looking like my translation of STxAxTIC's code the locating of stars is signature STxAxTIC.

Code: QB64: [Select]

1.  
2. These lines:
3.   'See how many stars are on screen, if there's a certain amount, GOSUB to make: to make a new star.
4.         r = x(stars) * x(stars) + y(stars) * y(stars)
5.         IF (r > 600 ^ 2) THEN GOSUB make:
6.  

are measuring the distance of x, y from the center of the screen. A new star is made when the distance is beyond borders of screen.

[OldMoses]

Nicely done Ken, I've been intrigued by the alpha overlay tip too, makes a nice comet trail effect. Kind of hoping I'll think of a project I can use it in myself.

[SierraKen]

Thanks OldMoses, this is almost all B+'s example code, so I am grateful to learn from that.

[SMcNeill]

It’s a simple version of Pytagorean’s Theorem.  When it comes to a right triangle, the hypotenuse is twice the sum of the squares of the other 2 sides....

Simply put, in a circle, r ^ 2 = x ^ 2 + y ^ 2


Run the tutorial in reply #4 here, and see if it helps you understand it: https://www.qb64.org/forum/index.php?topic=1583.msg108049#msg108049

[SierraKen]

A-HA! I found the reason B+! Those 2 lines just detect to see if any star goes past 600, either vertically or horizontally. It's just a trick to see how far the farthest stars have gone in that 1 direction. And since all of the directions move the same speed and length, only 1 direction is needed. If any of them passed up 600, it would make another new star in make: Knowing this, I changed the 600 to 800 because I had changed the screen size to 800 x 800 when I made the program. And now the stars even look better!!! Here is a better version:

Code: QB64: [Select]

1. 'Thank you to B+ and other guys from the QB64.org forum for their code examples to make this program!
2.  
3. _TITLE "Warp Speed  - Use Up and Down Arrow Keys"
4. DIM x(800), y(800), dx(800), dy(800), sz(800), c(800)
5.  
6. SCREEN _NEWIMAGE(800, 800, 32)
7.  
8. 'Set the default speed, amount of stars, and then make the first stars.
9. speed = .001
10. amount = 750
11. FOR stars = 1 TO amount
12.     GOSUB make:
13. NEXT stars
14.  
15. DO
16.     _LIMIT 500
17.     FOR stars = 1 TO amount
18.         a$ = INKEY$
19.         IF a$ = CHR$(27) THEN END
20.  
21.         'Detect the arrow keys to make it go faster or slower.
22.         IF a$ = CHR$(0) + CHR$(72) THEN speed = speed + .001: warp = warp + 1
23.         IF a$ = CHR$(0) + CHR$(80) THEN speed = speed - .001: warp = warp - 1
24.         IF warp < .0003 THEN warp = 0
25.         IF warp > 10 THEN warp = 10
26.         IF warp > 0 THEN LOCATE 1, 1: PRINT "Warp: "; warp
27.         IF warp = 0 THEN LOCATE 1, 1: PRINT "Cruise Speed"
28.         IF speed < .001 THEN speed = .001
29.         IF speed > .01 THEN speed = .01
30.  
31.         'Move the stars.
32.         x(stars) = x(stars) + dx(stars) * speed
33.         y(stars) = y(stars) + dy(stars) * speed
34.  
35.         'Detect to see if any star goes past the screen 800 x 800, if so, GOSUB make: to make a new star.
36.         r = x(stars) * x(stars) + y(stars) * y(stars)
37.         IF (r > 800 ^ 2) THEN GOSUB make:
38.  
39.         'Draw the stars, c(stars) is the choice of color.
40.         IF c(stars) < 75 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(255, 255, 255)
41.         IF c(stars) > 74 AND c(stars) < 85 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(100, 10, 10)
42.         IF c(stars) > 84 THEN CIRCLE (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), sz(stars), _RGB32(10, 10, 200)
43.  
44.         'If the size of the star is less than 1, skip paint.
45.         IF sz(stars) < 1 THEN GOTO nopaint:
46.  
47.         'Paint the stars.
48.         IF c(stars) < 75 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(255, 255, 255)
49.         IF c(stars) > 74 AND c(stars) < 85 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(100, 10, 10)
50.         IF c(stars) > 84 THEN PAINT (x(stars) + _WIDTH / 2, -y(stars) + _HEIGHT / 2), _RGB32(10, 10, 200)
51.         nopaint:
52.     NEXT stars
53.  
54.     'This stops flickering.
55.     _DISPLAY
56.  
57.     'Erase the stars for motion but keep a transparent black for the trails.
58.     LINE (0, 0)-(_WIDTH, _HEIGHT), _RGBA32(0, 0, 0, 30), BF
59.  
60. LOOP
61.  
62. make:
63. RANDOMIZE TIMER
64.  
65. 'Get a random X number using 2 decimal points - RND and .5 and times it by the width of the screen.
66.  
67. x(stars) = (RND - .5) * _WIDTH
68.  
69. 'Get a random Y number using 2 decimal points - RND and .5 and times it by the height of the screen.
70.  
71. y(stars) = (RND - .5) * _HEIGHT
72.  
73. 'Get a random star size between .25 and 2.
74.  
75. sz(stars) = (RND * 2) + .25
76.  
77. 'Get a random number between 1 and 100 to pick 1 of 3 different star colors in the main loop.
78.  
79. c(stars) = INT(RND * 100) + 1
80.  
81. 'Get any random number between 5 and 10, used for both X and Y, to use in the star movement in the main loop.
82.  
83. v = 5 + RND * 5
84. dx(stars) = x(stars) * v
85. dy(stars) = y(stars) * v
86.  
87. RETURN
88.  
89.  

[SierraKen]

True SMcNeill, but it's still only moving right or moving down because if a star went to the left or up, that equation wouldn't work.