Getting coordinates from a WINDOW _PUTIMAGE w/ mouse

[OldMoses]

Is it possible to get relative coordinates with a mouse over from a smaller _putimage on a bigger screen?

I have a larger main display which I place a smaller view port on the right side which is created with VIEW and WINDOW and has coordinate system thus:   WINDOW (-1000, 1000)-(1000, -1000)  I'm looking to be able to get those coordinates when the mouse is over that viewport

The project in question is: https://www.qb64.org/forum/index.php?topic=1429.0

In searching the wiki and forum I came across PMAP, which seems to be the key, but the coordinates returned are only for the main screen and won't register the relative coordinates contained in the _PUTIMAGE. It works well only when working with the image in isolation, but not once it is put to the bigger display.

Is this even possible, and/or am I missing something....other than my marbles... ;)

[Petr]

Hi. Why not use directly _PUTIMAGE own? Something as this:

Code: QB64: [Select]

1. image = _NEWIMAGE(1024, 768, 256) 'create image
2. image2 = _NEWIMAGE(50, 50, 32)
3. _DEST image
4. CLS , 14
5. CIRCLE (512, 384), 300, 1
6. PAINT (512, 384), 1, 1
7. _DEST image2
8. CLS , &HFFFF0000
9. LINE (15, 15)-(35, 35), &HFF00FF00, BF
10. _DEST 0
11.  
12. SCREEN _NEWIMAGE(640, 480, 32) 'your screen
13. _PUTIMAGE (220, 140)-(420, 340), image 'insert image to position 220,140
14. PRINT "Bigger image than your screen is inserted. Press key..."
15. SLEEP
16.  
17. CLS
18. _PUTIMAGE (220, 140)-(420, 340), image2 'insert image to position 220,140
19. PRINT "Smaller image than your screen is inserted. Press key..."
20. SLEEP
21.  
22.  

[OldMoses]

Hi. Why not use directly _PUTIMAGE own? Something as this:

I'm looking to preserve the cartesian coordinate scheme in the graphics window to make the math simpler.

Now that you mention it, I suppose there's nothing preventing me from making the smaller view port 2000x2000, bypassing the whole WINDOW approach, and just using the _PUTIMAGE command to size it down to the main screen, but I assume that would still not address the mouseover issue.

[SMcNeill]

Sometimes you just have to do the math yourself.

Let’s say I’m running a program in a 1000x1000 window.  (Goofy size, but easy numbers.). Now, let’s say I designate the top right 250x250 area as a mini “preview” window of sorts, but I want to interact with it as a 1000x1000 coordinate window, as well...

The mouse position is relative to the main window, so if it’s halfway in that 250x250 area, it’d be at point (875,125).

To calculate relative position, I’d just:

WindowMouseX = (_MOUSEX - WindowLeftPosition) * (WindowCoordinateWidth/ ActualWindowWidth)
WindowMouseY = (_MOUSEY - WindowTopPosition) * (WindowCoordinateHeight / ActualWindowHeight)

So the WindowMouseX would be (875 - 750) * (1000 / 250) = (125) * (4) = 500
And WindowMouseY would be (125 - 0) * (1000 / 250) = (125) * (4) = 500

And, in the mini-window, point (500,500) is indeed the center of the designated 1000x1000 coordinate system, which overall would be at (875, 125) on the main screen.

Just don’t forget to error check...

IF WindowMouseX < 0 OR WindowMouseX > 1000 OR WindowMouseY < 0 OR WindowMouseY > 1000 THEN ‘Result is not inside preview window.  Skip any preview click results...

[Petr]

Hi. I look at it again, maybe this help you, it is the same as Steve wrote:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. LINE (100, 100)-(300, 300), , B
3. VIEW (100, 100)-(300, 300)
4. CIRCLE (100, 100), 100
5.  
6.  
7. DO
8.     WHILE _MOUSEINPUT: WEND
9.     WINDOW (100, 100)-(300, 300)
10.     LOCATE 1, 1,: PRINT _MOUSEX, _MOUSEY
11.     GET_Window_Coordinates 100, 300, 100, 300, Wx, Wy
12.     LOCATE 1, 1: PRINT "Absolute coordinates:"; _MOUSEX, _MOUSEY
13.     LOCATE 2, 1: PRINT "Realtive coordinates:"; Wx, Wy
14. LOOP
15.  
16. SUB GET_Window_Coordinates (xstart, xend, ystart, yend, getX, getY)
17.     getX = 0: getY = 0
18.     IF _MOUSEX >= xstart AND _MOUSEX <= xend THEN
19.         IF _MOUSEY >= ystart AND _MOUSEY <= yend THEN
20.             getX = _MOUSEX - xstart
21.             getY = _MOUSEY - ystart
22.         END IF
23.     END IF
24. END SUB
25.  

[TempodiBasic]

Hi Guys
here an example with PMAP, VIEW and WINDOW

Code: QB64: [Select]

1. CONST HScreen = 500, WScreen = 500
2. CONST T = 1, B = 100
3. SCREEN _NEWIMAGE(WScreen, HScreen, 32)
4. DIM k AS INTEGER, j AS INTEGER
5. ActiveMenu
6. ActiveMap
7.  
8. DO
9.     k = _KEYHIT
10.     DO WHILE _MOUSEINPUT: LOOP
11.     mX = _MOUSEX
12.     mY = _MOUSEY
13.     j = WhereIsMouse(mX, mY)
14.     showdata mX, mY, j
15.  
16.     _LIMIT 30
17. LOOP UNTIL k = 13 OR k = 27 ' enter or Esc to quit
18.  
19. SUB showdata (mX AS INTEGER, mY AS INTEGER, j AS INTEGER)
20.     IF j = 1 THEN
21.         ActiveMenu
22.         ' here you put all the instruction for manage Active menu
23.     ELSEIF j = 2 THEN
24.         ActiveMap
25.         ' here you put all the instruction for manage ActiveMaP
26.     ELSE
27.         VIEW
28.         ' here you put all the instruction for manage main view of the program
29.     END IF
30.     '    the functions PAMP work on the last view activated!
31.  
32.     LOCATE 1, 15
33.     PRINT "Viewport  MouseX MouseY  ViewMx ViewMy"
34.     LOCATE 2, 20
35.     PRINT SPACE$(40)
36.     LOCATE 2, 20
37.     PRINT j; "  "; mX; "  "; mY; "  "; PMAP(mX, 2); "  "; PMAP(mY, 3)
38.  
39.    ' restore main viewport    
40.     VIEW
41.     WINDOW
42. END SUB
43.  
44. FUNCTION WhereIsMouse (mx AS INTEGER, my AS INTEGER)
45.     IF mx > T AND mx < B THEN
46.         IF my > T AND my < B THEN
47.             WhereIsMouse = 1
48.             EXIT FUNCTION
49.         END IF
50.     END IF
51.     IF mx > WScreen - 200 AND mx < WScreen THEN
52.         IF my > HScreen - 200 AND my < HScreen THEN
53.             WhereIsMouse = 2
54.             EXIT FUNCTION
55.         END IF
56.     END IF
57.     WhereIsMouse = 3 ' value for main viewport
58. END FUNCTION
59.  
60. SUB ActiveMap
61.     ' view port map
62.     VIEW (HScreen - 200, WScreen - 200)-(HScreen - 2, WScreen - 2), _RGB32(200, 100, 200), _RGB32(220, 200, 50)
63.     WINDOW SCREEN(-500, -500)-(500, 500) ' personalized cohordinates
64. END SUB
65.  
66. SUB ActiveMenu
67.     ' view port menu
68.     VIEW (T, T)-(B, B), _RGB32(0, 100, 200), _RGB32(220, 200, 50)
69. END SUB

Thanks to read
Good Coding

[OldMoses]

Thanks guys, I figured that once I put the image in the main screen it was part of the main screen and would react with mainscreen coordinates. When I'm doing the display updates I'm working with the "sub image", but once it's put in the main display I've lost the option of direct mouse interaction. I'm always keen to avoid the math, but as Steve says, sometimes you just have to bite that bullet.

What I'm essentially flirting with is an AutoCAD like system that has WCS and UCS based references. I want to be able to go into the screen and click on a particular "radar blip" and have it come up as an active viewpoint. I'm also flirting with a way to do a "zoom extents" in the window. It's quite a hunk for someone at my level to be chewing on. Maybe it'll work, since with things like this I approach it with the attitude that I'm too stupid to realize I can't do it, and it often happens that I can after all...

[OldMoses]

Success! It's working as I envisioned it would. Steve's equations and a little patient tweaking did the trick.