Resizing Questions

[Qwerkey]

$RESIZE:ON and its associated code allows a user to resize the program window.  I am in the habit a writing graphics programs which use large screens, sometimes larger than members' monitors.  Fellippe has advised me to use the $RESIZE:ON method.

But when a user changes the program's window size, does everything inside the window scale?  I don't see why things such as _MOUSEX and graphics would scale inside the new window size.  Such parameters are defined as pixel distances from the window Top-Left and not as fractions of the window size.  Have the QB64 magicians been clever enough that all program "distances" scale with the $Resized window?  If not, of course, a mouse click will not necessarily work properly at appropriate places.

[Gets]

Have the QB64 magicians been clever enough that all program "distances" scale with the $Resized window?

Yes.

[Qwerkey]

I think that I have managed (at last) to answer my own question, with a little help from Fellippe.

The $RESIZE:ON and its associated code does NOT automatically scale everything inside the window.  The user must adjust all x- and y- distances with written code for scaling to the new _WIDTH and HEIGHT of the window (screen).

The first block of code demonstrates the usage of $RESIZE:ON and its associated _RESIZE code.  This allows the user to change the widow size, but the image and _PRINTSTRING text do no scale with the window size.  They stay at their fixed (x,y) positions and fixed sizes, and this is as we expect: those positions are defined as pixel distances from the top left.  The text figures given are: screen width, screen height, mousex and mousey.  Resize the window and see what happens.  Esc to quit.

Code: QB64: [Select]

1. '$Resize:ON only - image position & size does not change
2.  
3. $RESIZE:ON
4.  
5. TempImg& = _NEWIMAGE(100, 100, 32)
6. _DEST TempImg&
7. COLOR _RGB32(0, 0, 255), _RGB(80, 80, 80)
8. CLS
9. LINE (0, 0)-(19, 19), , BF
10. LINE (80, 80)-(99, 99), , BF
11. Block& = _COPYIMAGE(TempImg&, 33)
12. _FREEIMAGE TempImg&
13.  
14. s& = _NEWIMAGE(300, 300, 32)
15. SCREEN s&
16. _DEST 0
17. _DISPLAYORDER _SOFTWARE , _HARDWARE
18.  
19. DO
20.     _LIMIT 30
21.     IF _RESIZE THEN
22.         oldimage& = s&
23.         s& = _NEWIMAGE(_RESIZEWIDTH, _RESIZEHEIGHT, 32)
24.         SCREEN s&
25.         _DISPLAYORDER _SOFTWARE , _HARDWARE
26.         _FREEIMAGE oldimage&
27.     END IF
28.     WHILE _MOUSEINPUT: WEND
29.     _PUTIMAGE (100, 100), Block&
30.     _PRINTSTRING (200, 100), STR$(_WIDTH)
31.     _PRINTSTRING (200, 120), STR$(_HEIGHT)
32.     _PRINTSTRING (200, 140), STR$(_MOUSEX)
33.     _PRINTSTRING (200, 160), STR$(_MOUSEY)
34.  
35.     K$ = INKEY$
36.     IF K$ <> "" THEN
37.         IF ASC(K$) = 27 THEN SYSTEM
38.     END IF
39.     K$ = ""
40.  
41.     _DISPLAY
42. LOOP
43.  

If you want the image to scale with the window, then write code for the x- and y- positions scaled to the window size, as in the next code block (lines 31-38).  Now the image scales with screen size.  The size of the _PRINTSTRING text does not scale, of course.

Code: QB64: [Select]

1. '$Resize:ON with scaled dimensions - sizes do change
2.  
3. $RESIZE:ON
4.  
5. TempImg& = _NEWIMAGE(100, 100, 32)
6. _DEST TempImg&
7. COLOR _RGB32(0, 0, 255), _RGB(80, 80, 80)
8. CLS
9. LINE (0, 0)-(19, 19), , BF
10. LINE (80, 80)-(99, 99), , BF
11. Block& = _COPYIMAGE(TempImg&, 33)
12. _FREEIMAGE TempImg&
13.  
14. s& = _NEWIMAGE(300, 300, 32)
15. SCREEN s&
16. _DEST 0
17. _DISPLAYORDER _SOFTWARE , _HARDWARE
18.  
19. DO
20.     _LIMIT 30
21.     IF _RESIZE THEN
22.         oldimage& = s&
23.         s& = _NEWIMAGE(_RESIZEWIDTH, _RESIZEHEIGHT, 32)
24.         SCREEN s&
25.         _DISPLAYORDER _SOFTWARE , _HARDWARE
26.         _FREEIMAGE oldimage&
27.     END IF
28.     WHILE _MOUSEINPUT: WEND
29.  
30.     'Code to change size of image scaled with window sizes
31.     X1% = CINT(100 * _WIDTH / 300)
32.     X2% = CINT(199 * _WIDTH / 300)
33.     X3% = CINT(200 * _WIDTH / 300)
34.     Y1% = CINT(100 * _HEIGHT / 300)
35.     Y2% = CINT(199 * _HEIGHT / 300)
36.     Y3% = CINT(120 * _HEIGHT / 300)
37.     Y4% = CINT(140 * _HEIGHT / 300)
38.     Y5% = CINT(160 * _HEIGHT / 300)
39.     _PUTIMAGE (X1%, Y1%)-(X2%, Y2%), Block&
40.     _PRINTSTRING (X3%, Y1%), STR$(_WIDTH)
41.     _PRINTSTRING (X3%, Y3%), STR$(_HEIGHT)
42.     _PRINTSTRING (X3%, Y4%), STR$(_MOUSEX)
43.     _PRINTSTRING (X3%, Y5%), STR$(_MOUSEY)
44.  
45.     K$ = INKEY$
46.     IF K$ <> "" THEN
47.         IF ASC(K$) = 27 THEN SYSTEM
48.     END IF
49.     K$ = ""
50.  
51.     _DISPLAY
52. LOOP
53.  

[FellippeHeitor]

Don't forget about $RESIZE:SMOOTH and $RESIZE:STRETCH, which don't require polling _RESIZEWIDTH or _RESIZEHEIGHT or creating a new screen, as they just stretch the screen to the new resized dimensions and automatically adjust mouse clicks.

[Qwerkey]

Oh, Pardom me.  I had not understood from the wiki that $RESIZE:SMOOTH and $RESIZE:STRETCH don't require polling, _RESIZEWIDTH, _RESIZEHEIGHT or creating a new screen.

When I tried $RESIZE:SMOOTH and $RESIZE:STRETCH with the first code (and with previous efforts of mine), nothing much seemed to happen.

$RESIZE:SMOOTH and $RESIZE:STRETCH do automatically scale everything with the window size with just the one command.

Perhaps the wiki is not as clear as it might be for us dopeyer members.

[FellippeHeitor]

Code: QB64: [Select]

1. $RESIZE:SMOOTH
2.  
3. CONST true = -1, false = 0
4.  
5. DO
6.     WHILE _MOUSEINPUT: WEND
7.  
8.     CLS
9.     COLOR 7, 0
10.     PRINT "_MOUSEX:"; _MOUSEX; ", _MOUSEY:"; _MOUSEY
11.  
12.     COLOR 15
13.     PRINT "Resize me."
14.     PRINT
15.     PRINT "Click exactly here: ";
16.  
17.     hovering = false
18.     IF _MOUSEX >= POS(1) AND _MOUSEX <= POS(1) + 9 AND _MOUSEY >= CSRLIN AND _MOUSEY <= CSRLIN + 4 THEN
19.         hovering = true
20.         COLOR 2
21.     END IF
22.  
23.     col = POS(1)
24.     FOR i = CSRLIN TO CSRLIN + 4
25.         LOCATE i, col
26.         PRINT STRING$(10, 219);
27.     NEXT
28.  
29.     IF _MOUSEBUTTON(1) THEN
30.         IF mouseDown = false THEN
31.             clicked = false
32.             mouseDown = true
33.         END IF
34.     ELSE
35.         IF mouseDown THEN
36.             mouseDown = false
37.             IF hovering THEN
38.                 clicked = true
39.             END IF
40.         END IF
41.     END IF
42.  
43.     IF clicked THEN COLOR 2: PRINT: PRINT "That's it."
44.  
45.     _DISPLAY
46.     _LIMIT 30
47. LOOP

[Qwerkey]

Would I be right in thinking that $RESIZE:STRETCH (or $RESIZE:SMOOTH) can only feature once (at the beginning of the code) in a program?

I've tried a conditional $RESIZE:STRETCH mid code, just before a SCREEN statement, so that you can resize a large screen (should it need it), but not a smaller one (which doesn't need it).  It appeared that you can only have Resize either on or off permanently (this was for a non-Inform project).

Having the $RESIZE:OFF function available implies that you can turn on/off resizing at will.  But this does not seem to be the case, although I must say that I am still in wonder that this auto-scaled resizing has been achieved.

[FellippeHeitor]

Set $RESIZE once (it's a precompiler switch), then use

Code: QB64: [Select]

1. _RESIZE OFF 'or back ON

To toggle during execution.