Stumped by a compiler error -fpermissive when calling windows api

[blametroi]

Hi. I'm trying to call the FindFileExA API and I can't figure out how to make my code compile cleanly in QB64. I'm sure the answer will be one of those "oh, duh" things, but I'm new to QB64 and I'm probably not reading all the code correctly. I started with one of the Windows API examples on the Wiki and started adding to it. The included code gets the following error on my system:

In file included from qbx.cpp:2171:0:
..\\temp\\main.txt: In function 'void QBMAIN(void*)':
..\\temp\\main.txt:151:146: error: invalid conversion from 'int' to 'FINDEX_INFO_LEVELS {aka _FINDEX_INFO_LEVELS}' [-fpermissive]
compilation terminated due to -Wfatal-errors.

And the code:

Code: QB64: [Select]

1. ' windows api testing, build a set of
2. ' useful routines
3. ' starting code is lifted from the qb64.org wiki to
4. ' bootstrap the effort, then i'll add my own stuff.
5. '
6. ' txb 27 December 2018
7.  
8. ' use a cmd console window instead of a screen
9. $CONSOLE:ONLY
10. _DEST _CONSOLE
11.  
12. ' Windows API constants
13. CONST MAX_PATH = 260
14.  
15. ' FINDEX_INFO_LEVELS
16. CONST FindExInfoStandard = 0&
17. CONST FindExInfoBasic = 1&
18.  
19. ' FINDEX_SEARCH_OPS
20. CONST FindExSearchNameMatch = 0&
21. CONST FindExSearchLimitToDirectories = 1&
22. CONST FindExSearchLimitToDevices = 2&
23.  
24. ' FILETIME
25. TYPE FileTime
26.     LowDateTime AS LONG
27.     HighDateTime AS LONG
28. END TYPE
29.  
30. ' WIN32_FIND_DATA
31. TYPE FindFileData
32.     FileAttributes AS LONG
33.     CreationTime AS FileTime
34.     LastAccessTime AS FileTime
35.     LastWriteTime AS FileTime
36.     FileSizeHigh AS LONG
37.     FileSizeLow AS LONG
38.     reserved0 AS LONG
39.     reserved1 AS LONG
40.     FileName AS STRING * MAX_PATH
41.     AlternateFileName AS STRING * 14
42.     FileType AS LONG
43.     CreatorType AS LONG
44.     FinderFlags AS INTEGER
45. END TYPE
46.  
47. DECLARE LIBRARY 'Directory Information using KERNEL32 provided by Dav
48.     FUNCTION WINDirectory ALIAS GetWindowsDirectoryA (lpBuffer AS STRING, BYVAL nSize AS LONG)
49.     FUNCTION SYSDirectory ALIAS GetSystemDirectoryA (lpBuffer AS STRING, BYVAL nSize AS LONG)
50.     FUNCTION CURDirectory ALIAS GetCurrentDirectoryA (BYVAL nBufferLen AS LONG, lpBuffer AS STRING)
51.     FUNCTION TempPath ALIAS GetTempPathA (BYVAL nBufferLen AS LONG, lpBuffer AS STRING)
52.     FUNCTION GetModuleFileNameA (BYVAL hModule AS LONG, lpFileName AS STRING, BYVAL nSize AS LONG)
53.     FUNCTION FindFirstFileEx ALIAS FindFirstFileExA (lpFileName AS STRING, BYVAL fInfoLevelId AS LONG, lpFindFileData AS FindFileData, BYVAL fSearchOp AS LONG, BYVAL aNull AS LONG, BYVAL AdditionalFlags AS LONG)
54.     FUNCTION FindClose (hFindFile AS LONG)
55. END DECLARE
56.  
57. '=== SHOW WINDOWS DIRECTORY
58. WinDir$ = SPACE$(144)
59. Result = WINDirectory(WinDir$, LEN(WinDir$))
60. IF Result THEN PRINT "WINDOWS DIRECTORY: "; LEFT$(WinDir$, Result)
61.  
62. '=== SHOW SYSTEM DIRECTORY
63. SysDir$ = SPACE$(144)
64. Result = SYSDirectory(SysDir$, LEN(SysDir$))
65. IF Result THEN PRINT "SYSTEM DIRECTORY: "; LEFT$(SysDir$, Result)
66.  
67. '=== SHOW CURRENT DIRECTORY
68. CurDir$ = SPACE$(255)
69. Result = CURDirectory(LEN(CurDir$), CurDir$)
70. IF Result THEN PRINT "CURRENT DIRECTORY: "; LEFT$(CurDir$, Result)
71.  
72. '=== SHOW TEMP DIRECTORY
73. TempDir$ = SPACE$(100)
74. Result = TempPath(LEN(TempDir$), TempDir$)
75. IF Result THEN PRINT "TEMP DIRECTORY: "; LEFT$(TempDir$, Result)
76.  
77. '=== SHOW CURRENT PROGRAM
78. FileName$ = SPACE$(256)
79. Result = GetModuleFileNameA(0, FileName$, LEN(FileName$))
80. IF Result THEN PRINT "CURRENT PROGRAM: "; LEFT$(FileName$, Result)
81.  
82. ' now try to find all the .bas files in this directory
83. DIM hfind AS LONG
84. DIM ffdata AS FindFileData
85. DIM searchString AS STRING * MAX_PATH
86. searchString = "*.bas"
87.  
88. hfind = FindFirstFileEx(searchString, FindExInfoStandard&, ffdata, 0, FindExSearchNameMatch, 0)
89. IF hfind < 0 THEN
90.     PRINT "find first failed"
91. ELSE
92.     PRINT "found ", ffdata.FileName
93.     Result = FindClose(hfind)
94. END IF
95.  
96. ' and done
97. SYSTEM 0 ' instead of END
98.  

[SMcNeill]

I just ran into the same error the other day.  My issue was trying to assign a LONG value to a 64-bit hwnd handle.  64-bit offsets are 8-bytes, and need to be defined as _INTEGER64 or else they overflow and don’t point to the proper place in memory.

You may try changing your  variable types and see if that corrects the issue for you.  (I’m not current at the PC and can’t test the theory.)

[FellippeHeitor]

Instead of DECLARE LIBRARY try DECLARE CUSTOMTYPE LIBRARY.

[blametroi]

Thanks guys.

Fillippe's suggestion gets me compiling and running. No intelligible output yet, but there's a start.

Steve, aren't my programs 32-bit when compiled? Why would I need an 8 byte handle?

EDIT: Using CustomType and changing the search string to include a trailing chr$(0) gets me results!

In testing I saw that only the FindFirstFileExA and FindClose need to be defined as CustomType. Indeed, using CustomType on the original calls broke that code and nothing intelligible was returned.

So, thanks again and I'm moving forward. Fun times.

[TempodiBasic]

Yeah a good land to explore...

A first philosophycal thinking:
It may be useful a tutorial both for Windows API both OtherOses API (Linux/MacOs)
or is the project that only Windows coder can do something more with QB64?

What experience and knowledge is needed to do this?

[blametroi]

A first philosophycal thinking:
It may be useful a tutorial both for Windows API both OtherOses API (Linux/MacOs)
or is the project that only Windows coder can do something more with QB64?

What experience and knowledge is needed to do this?

When getting into a new language/environment I have a few things I like to do. Hex dumps, directory lists, file copies, etc. I document my code along the way (see access violation calling FindNextFileA) so it might be useful as a tutorial or sample code at some point.

I know I could have called the shell to get a directory list as a text file, but I'm philosophically opposed to doing so :)

I only run in Windows these days, but I imagine the concepts will apply to Linux or OS X.

As far as experience/knowledge, someone needs to be able to understand a C header file and have a clear understanding of the difference between BY VALUE vs BY REFERENCE.