Re: Matrix Digital Rain Effect

[Ashish]

Cool [banned user]! :D I like these matrix effect!
Here is my version which I have coded some years ago.

Code: QB64: [Select]

1. _TITLE "Matrix Rain Effect By Ashish"
2. SCREEN _NEWIMAGE(800, 600, 32)
3.  
4. TYPE matRain
5.     x AS INTEGER
6.     y AS INTEGER
7.     col AS INTEGER
8.     length AS INTEGER
9.     txt AS STRING * 32
10.     ys AS DOUBLE
11.     stp AS INTEGER
12.     fade AS DOUBLE
13.     u AS INTEGER
14.     f AS INTEGER
15. END TYPE
16. $RESIZE:SMOOTH
17. DIM SHARED Matrix(500) AS matRain
18.  
19. FOR i = 1 TO UBOUND(matrix)
20.     Matrix(i).x = RND * _WIDTH
21.     Matrix(i).y = -INT(RND * _HEIGHT * 2)
22.     Matrix(i).col = INT(RND * 100) + 1
23.     Matrix(i).ys = RND * 3
24.     Matrix(i).length = INT(RND * 31) + 1
25.     FOR o = 1 TO Matrix(i).length
26.         c$ = CHR$(RND * 40 + 65)
27.         cc$ = cc$ + c$
28.     NEXT
29.     Matrix(i).txt = cc$
30.     cc$ = ""
31.     Matrix(i).fade = RND * 2
32.     Matrix(i).stp = 1
33.     Matrix(i).u = INT(RND * 10)
34. NEXT
35. _PRINTMODE _KEEPBACKGROUND
36. width = _WIDTH
37. height = _HEIGHT
38. DO
39.     CLS
40.     'LINE (0, 0)-(width, height), _RGBA(0, 0, 0, 80), BF
41.     FOR i = 1 TO UBOUND(matrix)
42.         COLOR _RGB(0, (Matrix(i).col / 100 * 255), 0)
43.         q = 1
44.         FOR k = Matrix(i).y TO Matrix(i).y + Matrix(i).length * 10 STEP 12
45.             _PRINTSTRING (Matrix(i).x, k), MID$(Matrix(i).txt, q, 1)
46.             q = q + 1
47.         NEXT
48.         Matrix(i).y = Matrix(i).y + Matrix(i).ys
49.         Matrix(i).ys = Matrix(i).ys + .05
50.         tmp$ = ""
51.         IF Matrix(i).f > Matrix(i).u THEN
52.             Matrix(i).f = 0
53.             FOR o = 1 TO Matrix(i).length
54.                 tmp$ = MID$(Matrix(i).txt, o, 1)
55.                 tmp$ = CHR$(ASC(tmp$) + Matrix(i).stp)
56.                 IF ASC(tmp$) > 121 THEN Matrix(i).stp = -Matrix(i).stp
57.                 IF ASC(tmp$) < 66 THEN Matrix(i).stp = -Matrix(i).stp
58.                 ff$ = ff$ + tmp$
59.             NEXT
60.             Matrix(i).txt = ff$
61.             ff$ = ""
62.         END IF
63.         Matrix(i).f = Matrix(i).f + 1
64.         IF Matrix(i).y > _HEIGHT THEN
65.             Matrix(i).x = RND * width
66.             Matrix(i).y = -INT(RND * height)
67.             Matrix(i).col = INT(RND * 100) + 1
68.             Matrix(i).ys = RND * 3
69.             Matrix(i).length = INT(RND * 31) + 1
70.             FOR o = 1 TO Matrix(i).length
71.                 c$ = CHR$(RND * 40 + 65)
72.                 cc$ = cc$ + c$
73.             NEXT
74.             Matrix(i).txt = cc$
75.             cc$ = ""
76.             Matrix(i).stp = 1
77.             Matrix(i).u = INT(RND * 10)
78.         END IF
79.         Matrix(i).col = Matrix(i).col + Matrix(i).fade
80.         IF Matrix(i).col >= 100 OR Matrix(i).col <= 0 THEN Matrix(i).fade = -Matrix(i).fade
81.     NEXT
82.     _DISPLAY
83.     _LIMIT 40
84. LOOP UNTIL INKEY$ <> ""
85.  
86.  

[bplus]

I throw my hat into the ring:
 

[bplus]

A second effort to get the text to spin as drop descends down the string:
 

EDIT: Dah! Don't need the Character Set.DAT file, and so don't need to send this in a .zip package.

Code: QB64: [Select]

1. _TITLE "Matrix Rain 2" 'B+ started 2019-03-15
2. ' from Matrix Rain 2019-03-14
3. ' or QB64 Purple Rain!
4.  
5. '>>>>>>>>>>>>>>>> Save this file as: Matrix Rain 2.bas, so the program can load the strings from it.  <<<<<<<<<<<<<<<<<
6.  
7. '2019-03-15 This will attempt to spin the drops as they fall
8. '2019-03-16  Don't need no damn Character Set.DAT file!!!
9.  
10. RANDOMIZE TIMER
11. CONST xmax = 1280
12. CONST ymax = 740
13. CONST maxChars = ymax \ 16
14. CONST nDrops = 60
15. TYPE dropType
16.     x AS SINGLE
17.     sz AS SINGLE
18.     curY AS INTEGER
19.     xscale AS SINGLE
20.     dxscale AS SINGLE
21. END TYPE
22.  
23. SCREEN _NEWIMAGE(xmax, ymax, 32)
24. _SCREENMOVE 80, 20
25. DIM SHARED fileString$
26.  
27. 'use big string from this file for drop text
28. OPEN "Matrix Rain 2.bas" FOR INPUT AS #1
29. WHILE NOT EOF(1)
30.     INPUT #1, s$
31.     fileString$ = fileString$ + "B+" + s$
32. WEND
33. CLOSE #1
34.  
35. 'setup drops
36. DIM SHARED drop(nDrops) AS dropType
37. DIM SHARED text(nDrops) AS STRING
38. FOR i = 0 TO nDrops
39.     newDrop i, 1
40. NEXT
41.  
42. WHILE _KEYDOWN(27) = 0
43.     CLS
44.     FOR i = 0 TO nDrops
45.         drawDrop (i)
46.         drop(i).curY = drop(i).curY + 1
47.         IF drop(i).curY > LEN(text(i)) THEN newDrop i, 0
48.     NEXT
49.     _DISPLAY
50.     _LIMIT 8
51. WEND
52.  
53. SUB drawDrop (i)
54.     FOR j = 1 TO drop(i).curY
55.         d = drop(i).curY - j
56.         IF d = 0 THEN
57.             c~& = _RGBA32(255, 100, 255, 255)
58.         ELSEIF d = 1 THEN
59.             c~& = _RGBA32(255, 50, 255, 215)
60.         ELSEIF d = 2 THEN
61.             c~& = _RGBA32(255, 10, 255, 180)
62.         ELSEIF d = 3 THEN
63.             c~& = _RGBA32(255, 0, 255, 150)
64.         ELSEIF d = 4 THEN
65.             c~& = _RGBA32(255, 0, 255, 125)
66.         ELSEIF d = 5 THEN
67.             c~& = _RGBA32(255, 0, 255, 105)
68.         ELSEIF d = 6 THEN
69.             c~& = _RGBA32(255, 0, 255, 90)
70.         ELSEIF d = 7 THEN
71.             c~& = _RGBA32(255, 0, 255, 80)
72.         ELSEIF d = 8 THEN
73.             c~& = _RGBA32(255, 0, 255, 70)
74.         ELSEIF d = 9 THEN
75.             c~& = _RGBA32(255, 0, 255, 60)
76.         ELSEIF d = 10 THEN
77.             c~& = _RGBA32(255, 0, 255, 50)
78.         ELSE
79.             c~& = _RGBA32(255, 0, 255, 0)
80.         END IF
81.         rot = drop(i).xscale: dir = 1
82.         FOR k = 1 TO j
83.             rot = rot + drop(i).dxscale * dir
84.             IF rot > 1 THEN rot = 1: dir = -1 * dir
85.             IF rot < -1 THEN rot = -1: dir = dir * -1
86.         NEXT
87.         drwChar MID$(text(i), j, 1), c~&, drop(i).x + 4 * drop(i).sz, drop(i).sz * 16 * (j - 1) + 8 * sz, rot * drop(i).sz, drop(i).sz, 0
88.     NEXT
89. END SUB
90.  
91. SUB newDrop (i, start)
92.     drop(i).x = RND * xmax
93.     drop(i).sz = RND * 4 + 1
94.     IF start <> 0 THEN drop(i).curY = INT(RND * (maxChars \ drop(i).sz + 1)) + 1 ELSE drop(i).curY = 1
95.     text(i) = MID$(fileString$, INT(RND * (LEN(fileString$) - maxChars \ drop(i).sz + 1)), maxChars \ drop(i).sz + 1)
96.     drop(i).xscale = RND
97.     r = RND
98.     IF r < .5 THEN drop(i).dxscale = -.3 * r - .1 ELSE drop(i).dxscale = .3 * r + .1
99. END SUB
100.  
101. SUB drwChar (char$, c AS _UNSIGNED LONG, midX, midY, xScale, yScale, Rotation) 'what ever the present color is set at
102.     I& = _NEWIMAGE(8, 16, 32)
103.     _DEST I&
104.     COLOR c
105.     _PRINTSTRING (0, 0), char$
106.     _DEST 0
107.     RotoZoom2 midX, midY, I&, xScale, yScale, Rotation
108.     _FREEIMAGE I&
109. END SUB
110.  
111. SUB RotoZoom2 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale AS SINGLE, Rotation AS SINGLE)
112.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
113.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
114.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
115.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
116.     sinr! = SIN(-Rotation): cosr! = COS(-Rotation)
117.     FOR i& = 0 TO 3
118.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * xScale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * yScale + Y
119.         px(i&) = x2&: py(i&) = y2&
120.     NEXT
121.     _MAPTRIANGLE (0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
122.     _MAPTRIANGLE (0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
123. END SUB
124.  
125.  

Do need to save this file as "Matrix Rain 2.bas" so the program can use strings from the file.

[bplus]

Ah finally, I have text strings / drops spinning as originally imagined.

Code: QB64: [Select]

1. _TITLE "Matrix Rain 3" 'B+ started 2019-03-16
2. ' from Matrix Rain 2019-03-14
3. ' or QB64 Purple Rain!
4.  
5. '>>> Save this file as: Matrix Rain 3.bas, so the program can load the strings from it.  <<<
6.  
7. '2019-03-15 This will attempt to spin the drops as they fall
8. '2019-03-16  Don't need no damn Character Set.DAT file!!!
9. '2019-03-16 Ijust want to see the vertical code strings dangle and twist.
10.  
11. RANDOMIZE TIMER
12. CONST xmax = 1280
13. CONST ymax = 740
14. CONST nDrops = 100
15. TYPE dropType
16.     x AS SINGLE
17.     sz AS SINGLE
18.     curY AS INTEGER
19.     dxs AS SINGLE 'direction and change of spin some small fraction of 1, +-1/3, +-1/4, +-1/5...
20. END TYPE
21.  
22. SCREEN _NEWIMAGE(xmax, ymax, 32)
23. _SCREENMOVE 80, 0 'for snap shot
24. '_FULLSCREEN    'as screen saver
25.  
26. REDIM SHARED fileStrings$(1000) 'container for these program lines that will be dangling
27. OPEN "Matrix Rain 3.bas" FOR INPUT AS #1
28. WHILE NOT EOF(1)
29.     LINE INPUT #1, fs$
30.     IF LEN(LTRIM$(fs$)) <> 0 THEN 'less empty spaces
31.         fileStrings$(i) = LTRIM$(fs$)
32.         i = i + 1
33.     END IF
34. WEND
35. CLOSE #1
36. REDIM _PRESERVE fileStrings$(i - 1)
37. ' check loading
38. 'FOR i = 0 TO UBOUND(fileStrings$)
39. '    PRINT i, fileStrings$(i)
40. 'NEXT
41. 'END
42.  
43. 'setup drops
44. DIM SHARED drop(nDrops) AS dropType
45. DIM SHARED s$(nDrops)
46.  
47. FOR i = 0 TO nDrops
48.     newDrop i, 1
49. NEXT
50.  
51. WHILE _KEYDOWN(27) = 0
52.     CLS
53.     FOR i = 0 TO nDrops
54.         drawDrop (i)
55.         drop(i).curY = drop(i).curY + 1
56.         IF drop(i).curY > LEN(s$(i)) THEN newDrop i, 0
57.     NEXT
58.     _DISPLAY
59.     _LIMIT 4
60. WEND
61.  
62. SUB newDrop (i, start)
63.     drop(i).x = RND * xmax 'set location
64.     drop(i).sz = RND * 4 + .3 'set size
65.     'length of text string can fit on screen
66.     charLength = ymax \ (drop(i).sz * 16) + 1 'from size determine how many chars fit on screen
67.     randLine = INT(RND * UBOUND(fileStrings$)) 'pick a random program line
68.     s$(i) = MID$(fileStrings$(randLine), 1, charLength) 'here is text string to dangle
69.     WHILE LEN(s$(i)) < charLength
70.         IF randLine + 1 > UBOUND(fileStrings$) THEN randLine = 0 ELSE randLine = randLine + 1
71.         s$(i) = MID$(s$(i) + " : " + fileStrings$(randLine), 1, charLength)
72.     WEND
73.     IF start <> 0 THEN drop(i).curY = INT(RND * (charLength)) + 1 ELSE drop(i).curY = 1 'flat and readable at curY
74.     drop(i).dxs = 1 / (INT(RND * 7) + 3) 'change of spin rate +-1/3, +-1/4, ... +-1/9
75.     IF RND < .5 THEN drop(i).dxs = -drop(i).dxs
76. END SUB
77.  
78. SUB drawDrop (i)
79.     FOR j = 1 TO drop(i).curY
80.         d = drop(i).curY - j
81.         IF d = 0 THEN
82.             c~& = _RGBA32(255, 100, 255, 225)
83.         ELSEIF d = 1 THEN
84.             c~& = _RGBA32(255, 50, 255, 205)
85.         ELSEIF d = 2 THEN
86.             c~& = _RGBA32(255, 25, 255, 180)
87.         ELSEIF d >= 3 THEN
88.             c~& = _RGBA32(255, 0, 255, 190 - d * 5)
89.         END IF
90.         rot = 1: dir = -1
91.         FOR k = 0 TO d
92.             rot = rot + drop(i).dxs * dir
93.             IF rot > 1 THEN dir = -1 * dir: rot = 1 + drop(i).dxs * dir
94.             IF rot < -1 THEN dir = dir * -1: rot = -1 + drop(i).dxs * dir
95.         NEXT
96.         drwChar MID$(s$(i), j, 1), c~&, drop(i).x + 4 * drop(i).sz, drop(i).sz * 16 * (j - 1) + 8 * drop(i).sz, rot * drop(i).sz, drop(i).sz, 0
97.     NEXT
98. END SUB
99.  
100. SUB drwChar (char$, c AS _UNSIGNED LONG, midX, midY, xScale, yScale, Rotation) 'what ever the present color is set at
101.     I& = _NEWIMAGE(8, 16, 32)
102.     _DEST I&
103.     COLOR c
104.     _PRINTSTRING (0, 0), char$
105.     _DEST 0
106.     RotoZoom2 midX, midY, I&, xScale, yScale, Rotation
107.     _FREEIMAGE I&
108. END SUB
109.  
110. SUB RotoZoom2 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale AS SINGLE, Rotation AS SINGLE)
111.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
112.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
113.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
114.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
115.     sinr! = SIN(-Rotation): cosr! = COS(-Rotation)
116.     FOR i& = 0 TO 3
117.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * xScale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * yScale + Y
118.         px(i&) = x2&: py(i&) = y2&
119.     NEXT
120.     _MAPTRIANGLE (0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
121.     _MAPTRIANGLE (0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
122. END SUB
123.  

 

[Ashish]

Cool bplus! :D

[Zeppelin]

bplus.
Love the effect.
Is it possible to achieve scalable text without using map-triangle?

[bplus]

bplus.
Love the effect.
Is it possible to achieve scalable text without using map-triangle?

Yes draw text in isolation capture image and use stretch/shrink powers of _PUTIMAGE

Code: QB64: [Select]

1. _TITLE "Text sub tests" 'B+ started 2019-03-25
2.  
3. RANDOMIZE TIMER
4. CONST xmax = 1200
5. CONST ymax = 700
6.  
7. SCREEN _NEWIMAGE(xmax, ymax, 32)
8. _SCREENMOVE 100, 40
9. COLOR _RGB32(0, 0, 255)
10. PRINT "Hello World"
11. 'test& = _NEWIMAGE(xmax, ymax, 32)
12. 'DEST test&
13. y = ymax
14. FOR i = 1 TO 60 STEP .5
15.     CLS
16.     y = y - 60 / i
17.     cText xmax / 2, y, 240 / i, _RGB32(255, 0, 0), "So how is this looking?"
18.     _DISPLAY
19.     _LIMIT 30
20. NEXT
21. '_DEST 0
22. '_PUTIMAGE , test&, 0
23. PRINT "OK, blue?"
24.  
25. SUB Text (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
26.     fg = _DEFAULTCOLOR
27.     'screen snapshot
28.     cur& = _DEST
29.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
30.     _DEST I&
31.     COLOR K, _RGBA32(0, 0, 0, 0)
32.     _PRINTSTRING (0, 0), txt$
33.     mult = textHeight / 16
34.     xlen = LEN(txt$) * 8 * mult
35.     _PUTIMAGE (x, y)-STEP(xlen, textHeight), I&, cur&
36.     COLOR fg
37.     _FREEIMAGE I&
38. END SUB
39.  
40. SUB cText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
41.     fg = _DEFAULTCOLOR
42.     'screen snapshot
43.     cur& = _DEST
44.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
45.     _DEST I&
46.     COLOR K, _RGBA32(0, 0, 0, 0)
47.     _PRINTSTRING (0, 0), txt$
48.     mult = textHeight / 16
49.     xlen = LEN(txt$) * 8 * mult
50.     _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
51.     COLOR fg
52.     _FREEIMAGE I&
53. END SUB
54.  
55.  

[bplus]

I see I hadn't posted my final rain, it has better 3D effect because of ratio small drops to large:

Code: QB64: [Select]

1. _TITLE "Matrix Rain 4" 'B+ started 2019-03-16
2. ' from Matrix Rain 2019-03-14
3. ' or QB64 Purple Rain!
4.  
5. '>>> Save this file as: Matrix Rain 4.bas, so the program can load the strings from it.  <<<
6.  
7. '2019-03-15 This will attempt to spin the drops as they fall
8. '2019-03-16  Don't need no damn Character Set.DAT file!!!
9. '2019-03-16 Ijust want to see the vertical code strings dangle and twist.
10.  
11. '2019-03-19 Matrix Rain 4
12. ' + added randWeight to weight the random sizes chosen so many more on small side than large
13. ' + draw letters on a transparent background so the background of the letter does not cover
14. '   the drops behind it.
15.  
16.  
17. RANDOMIZE TIMER
18. CONST xmax = 1280
19. CONST ymax = 740
20. CONST nDrops = 500
21. TYPE dropType
22.     x AS SINGLE
23.     sz AS SINGLE
24.     curY AS INTEGER
25.     dxs AS SINGLE 'direction and change of spin some small fraction of 1, +-1/3, +-1/4, +-1/5...
26. END TYPE
27.  
28. SCREEN _NEWIMAGE(xmax, ymax, 32)
29. _SCREENMOVE 80, 0 'for snap shot
30. '_FULLSCREEN 'as screen saver
31.  
32. REDIM SHARED fileStrings$(1000) 'container for these program lines that will be dangling
33. OPEN "Matrix Rain 4.bas" FOR INPUT AS #1
34. WHILE NOT EOF(1)
35.     LINE INPUT #1, fs$
36.     IF LEN(LTRIM$(fs$)) <> 0 THEN 'less empty spaces
37.         fileStrings$(i) = LTRIM$(fs$)
38.         i = i + 1
39.     END IF
40. WEND
41. CLOSE #1
42. REDIM _PRESERVE fileStrings$(i - 1)
43. ' check loading
44. 'FOR i = 0 TO UBOUND(fileStrings$)
45. '    PRINT i, fileStrings$(i)
46. 'NEXT
47. 'END
48.  
49. 'setup drops
50. DIM SHARED drop(nDrops) AS dropType
51. DIM SHARED s$(nDrops)
52.  
53. FOR i = 0 TO nDrops
54.     newDrop i, 1
55. NEXT
56.  
57. WHILE _KEYDOWN(27) = 0
58.     CLS
59.     FOR i = 0 TO nDrops
60.         drawDrop (i)
61.         drop(i).curY = drop(i).curY + 1
62.         IF drop(i).curY > LEN(s$(i)) THEN newDrop i, 0
63.     NEXT
64.     _DISPLAY
65.     _LIMIT 25
66. WEND
67.  
68. SUB newDrop (i, start)
69.     drop(i).x = RND * xmax 'set location
70.     drop(i).sz = randWeight(.3, 5, 3) 'set size  weighted on small sizes
71.     'length of text string can fit on screen
72.     charLength = ymax \ (drop(i).sz * 16) + 1 'from size determine how many chars fit on screen
73.     randLine = INT(RND * UBOUND(fileStrings$)) 'pick a random program line
74.     s$(i) = MID$(fileStrings$(randLine), 1, charLength) 'here is text string to dangle
75.     WHILE LEN(s$(i)) < charLength
76.         IF randLine + 1 > UBOUND(fileStrings$) THEN randLine = 0 ELSE randLine = randLine + 1
77.         s$(i) = MID$(s$(i) + " : " + fileStrings$(randLine), 1, charLength)
78.     WEND
79.     IF start <> 0 THEN drop(i).curY = INT(RND * (charLength)) + 1 ELSE drop(i).curY = 1 'flat and readable at curY
80.     drop(i).dxs = 1 / (INT(RND * 7) + 3) 'change of spin rate +-1/3, +-1/4, ... +-1/9
81.     IF RND < .5 THEN drop(i).dxs = -drop(i).dxs
82. END SUB
83.  
84. SUB drawDrop (i)
85.     FOR j = 1 TO drop(i).curY
86.         d = drop(i).curY - j
87.         IF d = 0 THEN
88.             c~& = _RGBA32(255, 100, 255, 225)
89.         ELSEIF d = 1 THEN
90.             c~& = _RGBA32(255, 50, 255, 205)
91.         ELSEIF d = 2 THEN
92.             c~& = _RGBA32(255, 25, 255, 180)
93.         ELSEIF d >= 3 THEN
94.             c~& = _RGBA32(255, 0, 255, 190 - d * 5)
95.         END IF
96.         rot = 1: dir = -1
97.         FOR k = 0 TO d
98.             rot = rot + drop(i).dxs * dir
99.             IF rot > 1 THEN dir = -1 * dir: rot = 1 + drop(i).dxs * dir
100.             IF rot < -1 THEN dir = dir * -1: rot = -1 + drop(i).dxs * dir
101.         NEXT
102.         drwChar MID$(s$(i), j, 1), c~&, drop(i).x + 4 * drop(i).sz, drop(i).sz * 16 * (j - 1) + 8 * drop(i).sz, rot * drop(i).sz, drop(i).sz, 0
103.     NEXT
104. END SUB
105.  
106. SUB drwChar (char$, c AS _UNSIGNED LONG, midX, midY, xScale, yScale, Rotation) 'what ever the present color is set at
107.     I& = _NEWIMAGE(8, 16, 32)
108.     _DEST I&
109.     COLOR c, _RGBA32(0, 0, 0, 0)
110.     _PRINTSTRING (0, 0), char$
111.     _DEST 0
112.     RotoZoom2 midX, midY, I&, xScale, yScale, Rotation
113.     _FREEIMAGE I&
114. END SUB
115.  
116. SUB RotoZoom2 (X AS LONG, Y AS LONG, Image AS LONG, xScale AS SINGLE, yScale AS SINGLE, Rotation AS SINGLE)
117.     DIM px(3) AS SINGLE: DIM py(3) AS SINGLE
118.     W& = _WIDTH(Image&): H& = _HEIGHT(Image&)
119.     px(0) = -W& / 2: py(0) = -H& / 2: px(1) = -W& / 2: py(1) = H& / 2
120.     px(2) = W& / 2: py(2) = H& / 2: px(3) = W& / 2: py(3) = -H& / 2
121.     sinr! = SIN(-Rotation): cosr! = COS(-Rotation)
122.     FOR i& = 0 TO 3
123.         x2& = (px(i&) * cosr! + sinr! * py(i&)) * xScale + X: y2& = (py(i&) * cosr! - px(i&) * sinr!) * yScale + Y
124.         px(i&) = x2&: py(i&) = y2&
125.     NEXT
126.     _MAPTRIANGLE (0, 0)-(0, H& - 1)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
127.     _MAPTRIANGLE (0, 0)-(W& - 1, 0)-(W& - 1, H& - 1), Image& TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
128. END SUB
129.  
130. FUNCTION randWeight (manyValue, fewValue, power)
131.     randWeight = manyValue + RND ^ power * (fewValue - manyValue)
132. END FUNCTION
133.  
134.