How to read the first 4 bits of the byte?

[Petr]

Hello. As you've surely noticed, I'm not a big friend with bit logical operators AND, XOR and OR. But because I want to get on, I need to thoroughly understand how to get the first 4 bits, or just the last bit of the byte, because the conversion to the string is too slow. Moving back from binary form makes VAL, that's no problem.

[SMcNeill]

AND 15 is probably what you're looking for.

00001111 -- last 4 bits would be a total of 15 (decimal).

So let's tak a number like 34.... In binary it'd be: 00100010.

00100010
00001111    AND
-----------
00000010

Result would be 2 -- the last 4 bits of that byte.

************

First 4 would be AND &B11110000  (128 + 64 + 32 + 16..  240).  AND 240

If you're not good at converting, just us &B and type the values directly in binary.  In many cases, I find, it keeps it simple and help preserves the intent of the code nicely.

[Petr]

Exactly it is how to take (quick) the first 4 bits of one byte and the first 4 bits of the second byte, fold a new byte, and then write this byte. I use this to store bitmap in 2/16 colors in the following code, but it is ugly slow:

Code: QB64: [Select]

1. ima = _SCREENIMAGE
2.  
3.  
4. imb = _NEWIMAGE(2048, 1024, 256)
5. _DEST imb
6. CLS , 14
7. LINE (100, 100)-(1948, 924), 1, BF
8. CIRCLE (1024, 512), 150, 0
9. _DEST 0
10.  
11.  
12. Save_BMP imb, "test16.bmp", 2  : REM 0 = 32 bit, 1 = 8 bit, 2 = 4 bit, 3 = 1 bit
13.  
14.  
15.  
16.  
17.  
18.  
19.  
20.  
21. SUB Save_BMP (src AS LONG, file AS STRING, typ AS _UNSIGNED _BYTE) 'typ: 0 = 32 bit, 1 = 256 colors, 2 = 16 colors, 3 = 2 colors   PRO KONVERZI NEJPRVE DITHERINGEM UDELEJ 256 clr zdroj a ten uloz. NELZE ulozit primo 32 bit do 8 bit!
22.     'moje save formule
23.  
24.     TYPE BMP_H
25.         ID AS STRING * 2 'BM                                  a
26.         Size AS LONG 'celkova velikost souboru
27.         Reserved0 AS INTEGER '0                               a
28.         Reserved1 AS INTEGER '0                               a
29.         Data_Start AS LONG ' startovni oblast dat obrazu. U 32 bitu to je hned po hlave, u ostatnich az po 54 + oblast palety - protoze tahle hlava ma 14, nasleduje druha hlava, ktera ma 40 bytu
30.     END TYPE
31.  
32.     TYPE BMP_I
33.         Hlava_velikost AS LONG '40                            a
34.         width AS LONG
35.         height AS LONG
36.         planes AS INTEGER '1                                  a
37.         BPP AS INTEGER '1/4/8/24/32
38.         Compress AS LONG '0/1/2                               a
39.         Image_Size AS LONG ' dam nulu                         a
40.         Xpels AS LONG '0                                      a
41.         Ypels AS LONG '0                                      a
42.         Total_Colors AS LONG 'muze byt 0    (0, 256, 16, 2)
43.         Important_Colors AS LONG '0                           a
44.     END TYPE
45.  
46.     DIM H AS BMP_H
47.     DIM I AS BMP_I
48.  
49.     DIM v AS _UNSIGNED LONG, v2 AS _UNSIGNED _BYTE
50.  
51.     H.Size = (_WIDTH(src) * _HEIGHT(src) * 4) + 54: I.height = _HEIGHT(src): I.width = _WIDTH(src)
52.     SELECT CASE typ
53.  
54.         CASE 0: DIM IM(_WIDTH(src) * _HEIGHT(src) - 1) AS _UNSIGNED LONG
55.             I.BPP = 32: I.Total_Colors = 0: Depth = 4 '                        32  bit
56.  
57.  
58.         CASE 1: DIM IM2(_WIDTH(src) * _HEIGHT(src) - 1) AS _UNSIGNED _BYTE
59.             I.BPP = 8: I.Total_Colors = 0: Depth = 1 '                         256 clrs
60.  
61.  
62.  
63.         CASE 2: DIM IM3((_WIDTH(src) * _HEIGHT(src) - 1) / 2) AS _UNSIGNED _BYTE
64.             I.BPP = 4: I.Total_Colors = 0: Depth = 1 '                         16  clrs
65.  
66.         CASE 3: DIM IM4((_WIDTH(src) * _HEIGHT(src) - 1) / 8) AS _UNSIGNED _BYTE
67.             I.BPP = 1: I.Total_Colors = 0: Depth = 1 '                         2   clrs
68.  
69.  
70.     END SELECT
71.  
72.     H.ID = "BM": H.Reserved0 = 0: H.Reserved1 = 0: I.Hlava_velikost = 40: I.planes = 1: I.Compress = 0: I.Image_Size = 0: I.Xpels = 0: I.Ypels = 0: I.Important_Colors = 0
73.     DIM M AS _MEM, N AS _MEM
74.     M = _MEMIMAGE(src)
75.  
76.  
77.     N = _MEMNEW(I.width * I.height * Depth) 'oblast pameti, kde se bude otacet Y
78.  
79.     FOR y = (_HEIGHT(src)) - 1 TO 0 STEP -1
80.         FOR x = 0 TO (_WIDTH(src) - 1)
81.             SELECT CASE typ
82.                 CASE 0
83.                     _MEMGET M, M.OFFSET + o, v
84.                     _MEMPUT N, N.OFFSET + in(x, y, src&), v
85.                     o = o + 4
86.                 CASE 1
87.                     _MEMGET M, M.OFFSET + o, v2
88.                     _MEMPUT N, N.OFFSET + in(x, y, src&), v2
89.                     o = o + 1
90.                 CASE 2
91.                     _MEMGET M, M.OFFSET + o, v2
92.                     uk = uk + 1
93.                     binar$ = binar$ + RIGHT$(DECtoBIN$(v2), 4)
94.                     IF uk MOD 2 = 0 THEN
95.                         IM3(index) = BINtoDEC(binar$)
96.                         binar$ = ""
97.                         index = index + 1
98.                         uk = 0
99.                     END IF
100.                     o = o + 1
101.  
102.                 CASE 3
103.                     _MEMGET M, M.OFFSET + o, v2
104.                     uk = uk + 1
105.                     binar$ = binar$ + RIGHT$(DECtoBIN$(v2), 1)
106.                     IF uk MOD 8 = 0 THEN
107.                         IM4(index) = BINtoDEC(binar$)
108.                         binar$ = ""
109.                         index = index + 1
110.                         uk = 0
111.                     END IF
112.                     o = o + 1
113.             END SELECT
114.     NEXT x, y
115.  
116.  
117.  
118.  
119.     SELECT CASE typ
120.         CASE 0
121.             _MEMFREE M
122.             _MEMGET N, N.OFFSET, IM()
123.             _MEMFREE N
124.         CASE 1
125.             _MEMFREE M
126.             _MEMGET N, N.OFFSET, IM2()
127.             _MEMFREE N
128.         CASE 2, 3
129.             _MEMFREE M
130.             _MEMFREE N
131.     END SELECT
132.  
133.  
134.  
135.  
136.  
137.     ch = FREEFILE
138.     OPEN file FOR OUTPUT AS #ch: CLOSE #ch: OPEN file FOR BINARY AS #ch
139.     PUT #ch, , H
140.     PUT #ch, , I
141.     SELECT CASE typ
142.         CASE 0: PUT #ch, , IM()
143.         CASE 1:
144.             FOR Palete = 0 TO 255
145.                 v = _PALETTECOLOR(Palete, src&)
146.                 PUT #ch, , v
147.             NEXT
148.             PUT #ch, , IM2()
149.  
150.         CASE 2:
151.             FOR Palete = 0 TO 15
152.                 v = _PALETTECOLOR(Palete, src&)
153.                 PUT #ch, , v
154.             NEXT
155.             PUT #ch, , IM3()
156.  
157.  
158.         CASE 3:
159.             FOR Palete = 0 TO 1
160.                 v = _PALETTECOLOR(Palete, src&)
161.                 PUT #ch, , v
162.             NEXT
163.             PUT #ch, , IM4()
164.     END SELECT
165. END SUB
166.  
167.  
168. FUNCTION in& (x AS INTEGER, y AS INTEGER, src&)
169.     in& = _PIXELSIZE(src&) * (y * _WIDTH(src&) + x)
170.     ' in& = (y * _WIDTH(src&) + x)
171. END FUNCTION
172.  
173. FUNCTION DECtoBIN$ (vstup)
174.     FOR rj = 7 TO 0 STEP -1
175.         IF vstup AND 2 ^ rj THEN DECtoBIN$ = DECtoBIN$ + "1" ELSE DECtoBIN$ = DECtoBIN$ + "0"
176.     NEXT rj
177. END FUNCTION
178.  
179. FUNCTION BINtoDEC (b AS STRING)
180.     BINtoDEC = VAL("&B" + b$)
181. END FUNCTION
182.  

[SMcNeill]

Color compression, I take it?

Bear with me, as I'm still waking up, and let's see if I understand the need.

To get a compressed 8-bit value back into 2 4-bit values, you'd;

LeftHalf = CompressedBit AND 240
RightHalf = CompressedBit AND 15

To put those 2 halves back together into a full 8-bit value, you'd:

CompressedBit = 16 * LeftHalf + RightHalf   (LeftHalf needs to shift 4 places, while the right half stays the same.)

[Petr]

Yes, this is it. I was able to make a write for 16 colors using this logical operator, it's much faster. The solution was AND 15 for the first pass and the same (but without re-reading the first value) for the second pass. Now I'm banging my head and trying the same thing for a two-color record. Thank You Steve.

[SMcNeill]

2 color, as in black and white?

Each bit would represent a pixel.

Take a compressed byte (CB) and just AND (2 ^ pixel) for the value.

CB AND 1 = pixel 0
CB AND 2 = pixel 1
CB AND 4 = pixel 2
CB AND 8
CB AND 16
CB AND 32
CB AND 64
CB AND 128

To go the other direction:

CB = pixel 7 * 128 + pixel 6 * 64 + pixel 5 * 32 + ......  + pixel 1 * 2 + pixel 0

[Petr]

Perfect. Thanks a lot. In fact, even two-color BMPs contain 2 pallet records, so they do not always have to be a black-and-white picture. Only Windows painting does not accept this (while the photo viewer will display it correctly).