« previous next »
Pages: [1]   Go Down

Author Topic: Playing 24bit WAV files (directly not supported)  (Read 5144 times)

0 Members and 1 Guest are viewing this topic.

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Playing 24bit WAV files (directly not supported)
« on: October 03, 2021, 09:19:49 am »
Hi people,

Still - and probably forever - I'm completely unable to remember working with AND due to bit operations. Therefore, I tried to rewrite my decoding functions, which used strings on the field principle. It work, but the speed is still desperate.

So, now about this thread. SNDOPEN cannot directly play WAV format 24bit. This format is used for various samples of musical instruments. I chose one of them for this program for a demonstration. It has been downloaded from the musicradar website, but it has been a long time. So here is a (slow) way to access and play this music format in QB64. End note - the variable n& on line 91 is estimated and may not give a completely accurate sound.

Try compare this output and your system media player output.

Code: QB64: [Select]
  1. 'how play 24bit wave?
  2. f$ = "24bit.wav"
  3. 'try standard method:
  4. PRINT "Opening "; f$
  5. sndf = _SNDOPEN(f$)
  6. PRINT "Playing "; f$
  8.  
  9.  
  10. PRINT "Nothing? Press any key..."
  12.  
  13. PRINT "Loading file to memory..."
  14. TYPE head24
  15.     chunk AS STRING * 4 '       4 bytes  (RIFF)
  16.     size AS LONG '              4 bytes  (file size)
  17.     fomat AS STRING * 4 '       4 bytes  (WAVE)
  18.     sub1 AS STRING * 4 '        4 bytes  (fmt )
  19.     subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  20.     format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  21.     channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  22.     rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  23.     ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  24.     Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  25.     Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  26.     subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  27.     lenght AS LONG '            4 bytes  Data block size
  28. END TYPE '                     44 bytes  total
  29. DIM H24 AS head24
  30.  
  31.  
  33. OPEN f$ FOR BINARY AS #ff
  34. GET #ff, , H24
  35.  
  36. 'PRINT H24.format
  37. 'PRINT H24.channels
  38. 'PRINT H24.rate
  39. 'PRINT H24.Block
  40. 'PRINT H24.Bits
  41. 'PRINT H24.lenght
  42.  
  44.  
  45. REDIM SHARED BinnaryL(0) AS _UNSIGNED _BYTE 'MUST BE 0
  46. REDIM SHARED BinnaryR(0) AS _UNSIGNED _BYTE 'MUST BE 0
  47. REDIM SHARED AS LONG FinalL(0), FinalR(0)
  48.  
  49.  
  50.  
  51. m = _MEMNEW(H24.lenght)
  52. f$ = SPACE$(H24.lenght)
  53.  
  54. GET #ff, , f$
  55. _MEMPUT m, m.OFFSET, f$
  57. f$ = ""
  58. PRINT "File loaded to memory, decoding it..."
  59.  
  60. DIM AS LONG L, R, D
  61. D& = 0
  62.  
  63. DO UNTIL D& = m.SIZE - 6
  64.  
  65.     FOR L = D& + 2 TO D& STEP -1
  66.         Vl = _MEMGET(m, m.OFFSET + L, _UNSIGNED _BYTE)
  67.         DecimalToBinary Vl, 1, BinnaryL()
  68.     NEXT L
  69.     '24 bites - left channel
  70.  
  71.     FOR R = D& + 5 TO D& + 3 STEP -1
  72.         Vr = _MEMGET(m, m.OFFSET + R, _UNSIGNED _BYTE)
  73.         DecimalToBinary Vr, 1, BinnaryR()
  74.     NEXT R
  75.     '24 bites - right channel
  76.  
  77.     Ul = UBOUND(FinalL)
  78.     REDIM _PRESERVE FinalL(Ul + 1) AS LONG 'higher type - 4-bytes than WAV used 3-bytes type
  79.     Ur = UBOUND(FinalR)
  80.     REDIM _PRESERVE FinalR(Ur + 1) AS LONG
  81.  
  82.     FinalL(Ul) = BinaryToDecimal(BinnaryL())
  83.     FinalR(Ur) = BinaryToDecimal(BinnaryR())
  84.  
  85.     REDIM BinnaryL(0) AS _UNSIGNED _BYTE 'erase binaries
  86.     REDIM BinnaryR(0) AS _UNSIGNED _BYTE
  87.     D& = D& + 6
  89. PRINT "Playing it..."
  90.  
  91. n& = 65535 * 128
  92.  
  93. FOR listen = 0 TO UBOUND(FinalL)
  94.     Ls = FinalL(listen) / n&
  95.     Rs = FinalR(listen) / n&
  96.     _SNDRAW Ls, Rs
  97.     DO UNTIL _SNDRAWLEN = 0: LOOP
  99. PRINT "Erasing memory..."
  101. PRINT "That's all"
  102.  
  103.  
  105.  
  106.  
  107.  
  108. SUB DecimalToBinary (v AS _UNSIGNED _BYTE, HowBytes, Binnary() AS _UNSIGNED _BYTE) 'vstup V prevede na pole o (8 * HowBytes) indexech (1 az HowBytes, nula se nepouziva) a vnich jsou ulozeny binarni hodnoty 0 nebo 1
  109.     u = UBOUND(binnary)
  110.     REDIM _PRESERVE Binnary(u + (8 * HowBytes)) AS _UNSIGNED _BYTE
  111.  
  112.     FOR rj = (8 * HowBytes) - 1 TO 0 STEP -1
  113.         u = u + 1
  114.         IF v AND 2 ^ rj THEN Binnary(u) = 1 ELSE Binnary(u) = 0
  115.     NEXT rj
  117.  
  118. FUNCTION BinaryToDecimal& (Binnary() AS _UNSIGNED _BYTE) ' pro cisla ktera jsou tvorena 3 bytes musi mit pole Binnary celkem 24 indexu (ubound = 24, index 0 se nepouziva)
  119.     DIM btd AS LONG, si AS LONG
  120.     u = UBOUND(binnary)
  121.     FOR si = 1 TO u
  122.         c = Binnary(si)
  123.         Sj = u - si
  124.         btd = btd + (c * 2 ^ Sj)
  125.     NEXT
  126.     BinaryToDecimal& = btd
  128.  

* 24bit.wav (Filesize: 1.23 MB, Downloads: 348)
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #1 on: October 03, 2021, 10:56:05 am »
Hi @Petr

If that is not a cymbal strike then my speaker or something is messed up, otherwise it seems to work.
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #2 on: October 03, 2021, 12:28:31 pm »
@bplus

Yes, it's a blow to cymbals. The whole composition can then be composed of these and similar individual samples.
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #3 on: October 05, 2021, 11:39:45 am »
Found bug in DecimalToBinary SUB, here is upgrade:

Code: QB64: [Select]
  1. 'how play 24bit wave?
  2. f$ = "24bit.wav"
  3. 'try standard method:
  4. PRINT "Opening "; f$
  5. sndf = _SNDOPEN(f$)
  6. PRINT "Playing "; f$
  8.  
  9.  
  10. PRINT "Nothing? Press any key..."
  12.  
  13. PRINT "Loading file to memory..."
  14. TYPE head24
  15.     chunk AS STRING * 4 '       4 bytes  (RIFF)
  16.     size AS LONG '              4 bytes  (file size)
  17.     fomat AS STRING * 4 '       4 bytes  (WAVE)
  18.     sub1 AS STRING * 4 '        4 bytes  (fmt )
  19.     subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  20.     format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  21.     channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  22.     rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  23.     ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  24.     Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  25.     Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  26.     subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  27.     lenght AS LONG '            4 bytes  Data block size
  28. END TYPE '                     44 bytes  total
  29. DIM H24 AS head24
  30.  
  31.  
  33. OPEN f$ FOR BINARY AS #ff
  34. GET #ff, , H24
  35.  
  36. 'PRINT H24.format
  37. 'PRINT H24.channels
  38. 'PRINT H24.rate
  39. 'PRINT H24.Block
  40. 'PRINT H24.Bits
  41. 'PRINT H24.lenght
  42.  
  44.  
  45. REDIM SHARED BinnaryL(0) AS _UNSIGNED _BYTE 'MUST BE 0
  46. REDIM SHARED BinnaryR(0) AS _UNSIGNED _BYTE 'MUST BE 0
  47. REDIM SHARED AS LONG FinalL(0), FinalR(0)
  48.  
  49.  
  50.  
  51. m = _MEMNEW(H24.lenght)
  52. f$ = SPACE$(H24.lenght)
  53.  
  54. GET #ff, , f$
  55. _MEMPUT m, m.OFFSET, f$
  57. f$ = ""
  58. PRINT "File loaded to memory, decoding it..."
  59.  
  60. DIM AS LONG L, R, D
  61. D& = 0
  62.  
  63. DO UNTIL D& = m.SIZE - 6&
  64.  
  65.     FOR L& = D& + 2& TO D& STEP -1&
  66.         Vl = _MEMGET(m, m.OFFSET + L&, _UNSIGNED _BYTE)
  67.         DecimalToBinary Vl, 1, BinnaryL()
  68.     NEXT L
  69.     '24 bites - left channel
  70.  
  71.     FOR R& = D& + 5& TO D& + 3& STEP -1
  72.         Vr = _MEMGET(m, m.OFFSET + R&, _UNSIGNED _BYTE)
  73.         DecimalToBinary Vr, 1, BinnaryR()
  74.     NEXT R
  75.     '24 bites - right channel
  76.  
  77.     Ul = UBOUND(FinalL)
  78.     REDIM _PRESERVE FinalL(Ul + 1) AS LONG 'higher type - 4-bytes than WAV used 3-bytes type
  79.     Ur = UBOUND(FinalR)
  80.     REDIM _PRESERVE FinalR(Ur + 1) AS LONG
  81.  
  82.     FinalL(Ul) = BinaryToDecimal(BinnaryL())
  83.     FinalR(Ur) = BinaryToDecimal(BinnaryR())
  84.  
  85.     REDIM BinnaryL(0) AS _UNSIGNED _BYTE 'erase binaries
  86.     REDIM BinnaryR(0) AS _UNSIGNED _BYTE
  87.     D& = D& + 6
  89. PRINT "Playing it..."
  90.  
  91. n& = 65535 * 127
  92.  
  93. FOR listen = 0 TO UBOUND(FinalL)
  94.     Ls = FinalL(listen) / n&
  95.     Rs = FinalR(listen) / n&
  96.     _SNDRAW Ls, Rs
  97.     DO UNTIL _SNDRAWLEN = 0: LOOP
  99. PRINT "Erasing memory..."
  101. PRINT "That's all"
  102.  
  103.  
  105.  
  106.  
  107.  
  108. SUB DecimalToBinary (v AS _UNSIGNED _BYTE, HowBytes, Binnary() AS _UNSIGNED _BYTE) 'vstup V prevede na pole o (8 * HowBytes) indexech (1 az HowBytes, nula se nepouziva) a vnich jsou ulozeny binarni hodnoty 0 nebo 1
  109.     DIM AS LONG u, rj
  110.     u = UBOUND(binnary)
  111.     REDIM _PRESERVE Binnary(u + (8 * HowBytes)) AS _UNSIGNED _BYTE
  112.     rj = (8 * HowBytes) - 1
  113.  
  114.     DO UNTIL rj = 0
  115.         IF v AND 2 ^ rj THEN Binnary(u) = 1 ELSE Binnary(u) = 0
  116.         u = u + 1
  117.         rj = rj - 1
  118.     LOOP
  120.  
  121. FUNCTION BinaryToDecimal& (Binnary() AS _UNSIGNED _BYTE) ' pro cisla ktera jsou tvorena 3 bytes musi mit pole Binnary celkem 24 indexu (ubound = 24, index 0 se nepouziva)
  122.     DIM btd AS LONG, si AS LONG, c AS LONG, sj AS LONG, u AS LONG
  123.     u = UBOUND(binnary)
  124.     si = 1
  125.     DO UNTIL si = u
  126.         c = Binnary(si)
  127.         sj = u - si
  128.         btd = btd + (c * 2 ^ sj)
  129.         si = si + 1
  130.     LOOP
  131.  
  132.     BinaryToDecimal& = btd
  134.  
Logged

Offline RhoSigma

  • QB64 Developer
  • Forum Resident
  • Posts: 565
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #4 on: October 05, 2021, 07:58:51 pm »
Hi @Petr,

according to your question in the Bin$ thread about omitting leading zeros and possible complications for reversing the values back to decimal I see no problem here. Your BinaryToDecimal&() function should perfectly handle it, given the Binnary() array is setup correctly with the valid bits in the right array indexes.

However, although your way was interresting to study, I've never seen a more complicated way of an arbitrary bitsize little to big endian data converter, so I couldn't resist to cut your code down to the essential loop part, no MEM stuff, no arrays.

The bad sound quality of your converter is not related to the bitwise approach you chose or any arithmetic complicatons because of bit errors. It's simply because you don't make a proper sign extension from 24bit to the 32bit LONGs, hence you only produce positive sample values between 0.0 and 1.0

Code: QB64: [Select]
  1. 'how play 24bit wave?
  2. f$ = "24bit.wav"
  3. 'try standard method:
  4. PRINT "Opening "; f$
  5. sndf = _SNDOPEN(f$)
  6. PRINT "Playing "; f$
  8.  
  9.  
  10. PRINT "Nothing? Press any key...": PRINT
  12.  
  13. PRINT "Loading file..."
  14. TYPE head24
  15.     chunk AS STRING * 4 '       4 bytes  (RIFF)
  16.     size AS LONG '              4 bytes  (file size)
  17.     fomat AS STRING * 4 '       4 bytes  (WAVE)
  18.     sub1 AS STRING * 4 '        4 bytes  (fmt )
  19.     subchunksize AS LONG '      4 bytes  (lo / hi), $00000010 for PCM audio
  20.     format AS INTEGER '         2 bytes  (0001 = standard PCM, 0101 = IBM mu-law, 0102 = IBM a-law, 0103 = IBM AVC ADPCM)
  21.     channels AS INTEGER '       2 bytes  (1 = mono, 2 = stereo)
  22.     rate AS LONG '              4 bytes  (sample rate, standard is 44100)
  23.     ByteRate AS LONG '          4 bytes  (= sample rate * number of channels * (bits per channel /8))
  24.     Block AS INTEGER '          2 bytes  (block align = number of channels * bits per sample /8)
  25.     Bits AS INTEGER '           2 bytes  (bits per sample. 8 = 8, 16 = 16)
  26.     subchunk2 AS STRING * 4 '   4 bytes  ("data")  contains begin audio samples
  27.     lenght AS LONG '            4 bytes  Data block size
  28. END TYPE '                     44 bytes  total
  29. DIM H24 AS head24
  30.  
  31.  
  33. OPEN f$ FOR BINARY AS #ff
  34. GET #ff, , H24
  35. f$ = SPACE$(H24.lenght)
  36. GET #ff, , f$
  38.  
  39. PRINT "File loaded, decoding and playing it..."
  40.  
  41. FOR samp& = 0 TO (LEN(f$) / 6) - 1 'lenght / block align - 1
  42.     Ls& = 0: Rs& = 0 'clear samples
  43.     FOR i% = 3 TO 1 STEP -1
  44.         'loop trough little endian file data to build samples
  45.         Ls& = (Ls& * 256) + ASC(f$, (samp& * 6) + i%) 'shift current value 8 bits left and add next byte
  46.         Rs& = (Rs& * 256) + ASC(f$, (samp& * 6) + i% + 3)
  47.     NEXT i%
  48.     'if MSB (bit 23) is set (negative sample) then sign extend to LONG
  49.     IF (Ls& AND &H800000) THEN Ls& = (Ls& OR &HFF000000)
  50.     IF (Rs& AND &H800000) THEN Rs& = (Rs& OR &HFF000000)
  51.     'play normalized samples in range -1.0 to +1.0
  52.     _SNDRAW Ls& / 8388608#, Rs& / 8388608#
  53. NEXT samp&
  55.  
  56. PRINT "That's all"
  57.  
  59.  
  60.  
Logged
My Projects:   https://qb64forum.alephc.xyz/index.php?topic=809
GuiTools - A graphic UI framework (can do multiple UI forms/windows in one program)
Libraries - ImageProcess, StringBuffers (virt. files), MD5/SHA2-Hash, LZW etc.
Bonus - Blankers, QB64/Notepad++ setup pack

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #5 on: October 06, 2021, 01:33:44 pm »
@RhoSigma

Hi,

I will say it quite openly. I am amazed by the simplicity and efficiency of your version. The reason why mine was complicated there has one main and essential reason and another irrelevant reason.

The main reason is that I'm not very familiar with these bit operations, and your way of writing a program is simply beyond my knowledge.

The irrelevant one is that I will continue to use the samples in another program, so I needed to store them in memory.

When I think about it in retrospect, I'm surprised that it didn't hit me in the eye and ear right away. I assumed the correct samples would play with (255 ^ 3/2) but it didn't work properly. So I was expecting _SNDRAW number 8290688, but it's not there. There is 8388608. I'll try to find out the reason.

I'll put it this way. Many thanks for looking at it and showing me this solution. Lines 45, 46, 49, 50 would not occur to me in any way to solve in this way, it is definitely exactly what I can't do. Yet.
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #6 on: October 06, 2021, 02:46:01 pm »
So I figured it out. I forgot zero again. Zero is also a value. Therefore it is of course correct: 256 ^ 3 / 2 = 8 388 608.
Logged

Offline RhoSigma

  • QB64 Developer
  • Forum Resident
  • Posts: 565
    • View Profile
Re: Playing 24bit WAV files (directly not supported)
« Reply #7 on: October 06, 2021, 02:50:15 pm »
Hi @Petr,

Quote
The main reason is that I'm not very familiar with these bit operations, and your way of writing a program is simply beyond my knowledge.
Maybe a good topic for a tutorial, how to accomplish bit shifts by multiply/divide operations with powers of 2 and how to use AND/OR etc. to check for certain bit states and masking in/out certain bits.

Quote
I assumed the correct samples would play with (255 ^ 3/2) but it didn't work properly. So I was expecting _SNDRAW number 8290688, but it's not there. There is 8388608. I'll try to find out the reason.
Quote
So I figured it out. I forgot zero again. Zero is also a value. Therefore it is of course correct: 256 ^ 3 / 2 = 8 388 608.
Even more simple, it's a 24bit WAV, samples can be positive or negative to the same value, hence (2^24)/2 = 8388608.

Quote
I'll put it this way. Many thanks for looking at it and showing me this solution. Lines 45, 46, 49, 50 would not occur to me in any way to solve in this way, it is definitely exactly what I can't do. Yet.
That's why we are here, to share knowledge and to help others getting better.

Logged
My Projects:   https://qb64forum.alephc.xyz/index.php?topic=809
GuiTools - A graphic UI framework (can do multiple UI forms/windows in one program)
Libraries - ImageProcess, StringBuffers (virt. files), MD5/SHA2-Hash, LZW etc.
Bonus - Blankers, QB64/Notepad++ setup pack
Pages: [1]   Go Up
« previous next »