Mighty Mouse?

[Pete]

I'll let you guys decide...

Code: QB64: [Select]

1. mydemo% = -1
2. DIM UI AS UserInput
3.  
4. TYPE UserInput
5.     KeyPress AS STRING
6.     KeyCombos AS INTEGER
7.     MbStatus AS INTEGER
8.     MbEnvoked AS INTEGER
9.     drag AS INTEGER
10.     DoubleClick AS INTEGER
11.     MbLeftx AS INTEGER
12.     MbLefty AS INTEGER
13.     mx AS INTEGER
14.     oldmx AS INTEGER
15.     my AS INTEGER
16.     oldmy AS INTEGER
17. END TYPE
18.  
19. PRINT "Press keys or use mouse for demo.";
20. DO
21.     CALL keyboard_mouse(UI, mydemo%)
22.     IF UI.MbStatus < 0 AND UI.MbEnvoked = 0 THEN
23.         SOUND 1000, .3: UI.MbEnvoked = -1
24.     END IF
25.     IF UI.KeyPress = CHR$(13) THEN BEEP: EXIT DO
26. LOOP
27.  
28. DO
29.     CALL keyboard_mouse(UI, mydemo%)
30.     IF UI.MbStatus > 0 AND UI.MbEnvoked = 0 THEN
31.         SOUND 300, .3: UI.MbEnvoked = 1
32.     END IF
33. LOOP
34.  
35. END
36.  
37. SUB keyboard_mouse (UI AS UserInput, mydemo%)
38.     STATIC z1, lclick
39.  
40.     _LIMIT 30
41.  
42.     DEF SEG = 0
43.     IF PEEK(1047) MOD 16 = 1 OR PEEK(1047) MOD 16 = 2 THEN
44.         UI.KeyCombos = 1 ' Shift  % = -1 ELSE shift% = 0
45.     ELSEIF PEEK(1047) MOD 16 = 3 OR PEEK(1047) MOD 16 = 4 THEN
46.         UI.KeyCombos = 2 ' Ctrl  % = -1 ELSE ctrl% = 0
47.     ELSEIF PEEK(1047) MOD 16 = 7 OR PEEK(1047) MOD 16 = 8 THEN
48.         UI.KeyCombos = 3 ' Alt  % = -1
49.     ELSEIF PEEK(1047) MOD 16 = 5 OR PEEK(1047) MOD 16 = 6 THEN
50.         UI.KeyCombos = 4 ' Ctrl+Shift  % = -1 ELSE ctrlshift% = 0
51.     ELSE
52.         UI.KeyCombos = 0
53.     END IF
54.     DEF SEG
55.  
56.     IF mydemo% THEN GOSUB check_UI.KeyCombos
57.  
58.     UI.KeyPress = INKEY$
59.     IF LEN(UI.KeyPress) THEN ' A key was pressed.
60.         UI.MbEnvoked = 0: UI.MbLeftx = 0
61.         SELECT CASE LEN(UI.KeyPress)
62.             CASE 1 ' 1-byte key A-Z, etc.
63.                 IF mydemo% THEN mydemo% = 1: GOSUB mydemo
64.                 SELECT CASE UI.KeyPress
65.                     ' Place key selection routine here...
66.                     CASE CHR$(27): SYSTEM
67.                 END SELECT
68.             CASE 2 '2-byte key F1-F12, etc.
69.                 IF mydemo% THEN mydemo% = 2: GOSUB mydemo
70.                 SELECT CASE RIGHT$(UI.KeyPress, 1)
71.                     ' Place key selection routine here...
72.                 END SELECT
73.         END SELECT
74.     ELSE ' Check for mouse input since no keyboard input was detected.
75.  
76.         IF lclick THEN ' Check timer for double-clicks.
77.             IF TIMER < z1 THEN z1 = z1 - 86400 ' Midnight adjustment.
78.             IF TIMER - z1 > .33 THEN lclick = 0 ' Too much time ellapsed for a double click.
79.         END IF
80.  
81.         WHILE _MOUSEINPUT
82.             mw = mw + _MOUSEWHEEL ' Check for mouse wheel use.
83.         WEND
84.  
85.         ' Get mouse status.
86.         UI.mx = _MOUSEX
87.         UI.my = _MOUSEY
88.         lb = _MOUSEBUTTON(1)
89.         rb = _MOUSEBUTTON(2)
90.         mb = _MOUSEBUTTON(3)
91.  
92.         SELECT CASE UI.MbEnvoked
93.             CASE 0
94.                 IF lb OR rb OR mb THEN
95.  
96.                 END IF
97.             CASE 1
98.                 IF lb OR rb OR mb THEN UI.MbEnvoked = 0
99.             CASE -1
100.                 IF lb = 0 AND rb = 0 AND mb = 0 THEN UI.MbEnvoked = 0
101.         END SELECT
102.  
103.         ' Check for mouse movement.
104.         IF UI.mx <> UI.oldmx OR UI.my <> UI.oldmy THEN
105.             oldcsrlin = CSRLIN: oldpos = POS(0)
106.             LOCATE 3, 1: PRINT "Mouse row/col ="; UI.my; UI.mx; "     ";: LOCATE oldcsrlin, oldpos
107.         END IF
108.  
109.         IF UI.MbStatus < 0 THEN ' Mouse button pressed. UI.MbStatus identity is by number. -1=left, -2=right, -3=middle.
110.             SELECT CASE UI.MbStatus
111.                 CASE -1 ' Left button was pressed.
112.                     IF lb = 0 THEN ' Left button released.
113.                         SELECT CASE lclick ' Single or double click analysis.
114.                             CASE 0
115.                                 IF mydemo% THEN mydemo% = 3: GOSUB mydemo
116.                                 lclick = lclick + 1
117.                             CASE ELSE ' Double click. Completed upon 2nd left button release.
118.                                 IF mydemo% THEN mydemo% = 11: GOSUB mydemo
119.                                 UI.DoubleClick = -1
120.                                 lclick = 0
121.                         END SELECT
122.                         UI.MbStatus = 1
123.  
124.                         IF UI.MbLeftx THEN
125.                             IF UI.mx <> UI.MbLeftx OR UI.my <> UI.MbLefty THEN UI.MbStatus = 0: lclick = 0
126.                             UI.MbLeftx = 0: UI.MbLefty = 0
127.                         END IF
128.  
129.                         IF UI.drag THEN UI.drag = 0
130.                     ELSE ' Left button is being held down. Check for UI.drag.
131.                         IF UI.mx <> UI.oldmx OR UI.my <> UI.oldmy THEN ' Mouse cursor has moved. UI.drag.
132.                             IF mydemo% THEN mydemo% = 12: GOSUB mydemo
133.                             UI.drag = -1
134.                         END IF
135.                     END IF
136.                 CASE -2 ' Right button was pressed.
137.                     IF rb = 0 THEN ' Right button was relased.
138.                         IF mydemo% THEN mydemo% = 4: GOSUB mydemo
139.                         UI.MbStatus = 2
140.                     END IF
141.                 CASE -3 ' Middle button was pressed
142.                     IF mb = 0 THEN ' Middle button was released.
143.                         IF mydemo% THEN mydemo% = 5: GOSUB mydemo
144.                         UI.MbStatus = 3
145.                     END IF
146.             END SELECT
147.         ELSE
148.             IF lb THEN ' Left button just pressed.
149.                 IF mydemo% THEN mydemo% = 6: GOSUB mydemo
150.                 UI.MbStatus = -1
151.                 IF UI.MbLeftx = 0 THEN UI.MbLeftx = UI.mx: UI.MbLefty = UI.my
152.                 z1 = TIMER
153.             ELSEIF rb THEN ' Right button just pressed.
154.                 IF mydemo% THEN mydemo% = 7: GOSUB mydemo
155.                 IF UI.MbLeftx = 0 THEN UI.MbLeftx = UI.mx: UI.MbLefty = UI.my
156.                 UI.MbStatus = -2
157.             ELSEIF mb THEN ' Middle button just pressed.
158.                 IF mydemo% THEN mydemo% = 8: GOSUB mydemo
159.                 IF UI.MbLeftx = 0 THEN UI.MbLeftx = UI.mx: UI.MbLefty = UI.my
160.                 UI.MbStatus = -3
161.             ELSEIF mw THEN ' Mouse wheel just moved.
162.                 SELECT CASE mw
163.                     CASE IS > 0 ' Scroll down.
164.                         IF mydemo% THEN mydemo% = 9: GOSUB mydemo
165.                     CASE IS < 0 ' Scroll up.
166.                         IF mydemo% THEN mydemo% = 10: GOSUB mydemo
167.                 END SELECT
168.             END IF
169.         END IF
170.  
171.         UI.oldmx = UI.mx: UI.oldmy = UI.my: mw = 0 ' Mouse position past and present.
172.     END IF
173.     EXIT SUB
174.  
175.     mydemo:
176.     LOCATE 1, 1: PRINT "Last User Status:                                    ";
177.     LOCATE , 19
178.     SELECT CASE mydemo%
179.         CASE 1
180.             PRINT "1-byte Key = "; UI.KeyPress
181.         CASE 2
182.             PRINT "2-byte Key = "; UI.KeyPress
183.         CASE 3
184.             PRINT "Left button released."
185.         CASE 4
186.             PRINT "Right button released."
187.         CASE 5
188.             PRINT "Middle button released."
189.         CASE 6
190.             PRINT "Left button down."
191.         CASE 7
192.             PRINT "Right button down."
193.         CASE 8
194.             PRINT "Middle button down."
195.         CASE 9
196.             PRINT "Wheel scroll down."
197.         CASE 10
198.             PRINT "Wheel scroll up."
199.         CASE 11
200.             PRINT "Left button double click."
201.         CASE 12
202.             PRINT "Drag..."
203.     END SELECT
204.     mydemo% = -1
205.     RETURN
206.  
207.     check_UI.KeyCombos:
208.     IF UI.KeyCombos THEN
209.         LOCATE 1, 50
210.         SELECT CASE UI.KeyCombos
211.             CASE 1
212.                 PRINT "Shift key down.        ";
213.             CASE 2
214.                 PRINT "Ctrl key down.         ";
215.             CASE 3
216.                 PRINT "Alt key down.          ";
217.             CASE 4
218.                 PRINT "Ctrl + Shift key down. ";
219.         END SELECT
220.     ELSE
221.         LOCATE 1, 50: PRINT SPACE$(29);
222.     END IF
223.     RETURN
224. END SUB

Anyway, this is just something I threw together for another member to consider. I usually write these routines from scratch each time I need one, but for fun, I thought I take a shot at one I could save as a library and use as a universal routine for future apps. I need to add some more stuff from my other routines, like my PEEK / POKE routine for detecting Shift + arrow keys, alt, ctrl, etc. I also want to add another variable to let the user decide if the mouse action should take place upon button press or release. I'll probably update this post, occasionally, if and when I make these additions. Fun stuff.

Pete

Edited: Worked in V 1.3, but not the more recent versions. Reason was as bplus pointed out, I had two IF THEN statements following a SELECT CASE statement. Both statements were moved one line up, and now work in the later versions. Thanks for catching that, Mark!

Edited: Added a method and demo for mouse action either on button press or release. The first loop signals a high tone when a mouse click is made with button down. It then shuts off more mouse input until the button is released. Press [ENTER] to exit to the next loop, which issues a low tone when a depressed mouse button is released. Now the user can decide on each mouse event if the program should respond upon mouse button press or release.

Edited: Added my PEEK / POKE routine to detect Shift, Ctrl, Alt, and Ctrl+Shift.

Editd: Added a prevent click initiation on button release if mouse cursor is moved while button is held down. So if the user decides to use the activate mouse command on button release option, this addition allows the user to abort the click, by moving the mouse cursor before the button is released.

Edited: Did some renaming and changed variables to TYPE variables.

Edited: Added mouse row and column indicator.

[bplus]

What the heck? I am getting error on line 16:

Code: QB64: [Select]

1. IF mydemo%  THEN mydemo% = 1: GOSUB mydemo  
2.  

@Pete is this working OK for you or you making a point in that funny way of yours?

[bplus]

I think both Terry Richie and Steve have made similar do all mouse reporting, probably others too.

But I agree, more fun reinventing the wheel sometimes.

[bplus]

What the heck? I am getting error on line 16:

Code: QB64: [Select]

1. IF mydemo%  THEN mydemo% = 1: GOSUB mydemo  
2.  

@Pete is this working OK for you or you making a point in that funny way of yours?

Ohhh! You're trying an IF THEN right after Select Case, IDE is expecting a Case line. What version QB64 are you running Pete?

[Pete]

THANKS MARK!

I coded this one on V 1.3. It compiled and worked just fine. I just did a post edit to correct the problem, and tested it on V1.5.

Pete

[Pete]

I think I just made my last edit / addition to the code for today, unless someone finds a goof, then I'll go back and fix it. This is why I love having the edit post ability extended. Thanks, Fell.

Pete

[bplus]

@Pete

Instead of Peek and Poke to check Shift, Ctrl, Alt have you considered _KeyDown(keyInQuestion)?

[FellippeHeitor]

I think I just made my last edit / addition to the code for today, unless someone finds a goof, then I'll go back and fix it. This is why I love having the edit post ability extended. Thanks, Fell.

Pete

Stop rubbing it in, will ya.

[Pete]

I know, I feel like such a heel!

Pete

[Pete]

@bplus Yes, I actually have one very extensive keyboard input routine I wrote with the newer QB64 key keywords. It works, but because I did not use CONSTANTS, just numeric values, I discovered it was just too unfamiliar to be comfortable. I'm not sure if I'm recalling correctly now, but I also thought mixing INKEY$ and _KEYDOWN was a big mistake, whereas the PEEK / POKE marriage works perfectly. If I were to do another _KEYDOWN routine, I'd do like I do with SENDKEY, and make CONSTANTS to replace the numeric entries.

Now I have a reached a bit of a difficulty with my posted routine. I need to work out an elegant way to cancel a mouse cycle if the mouse is moved. I was just thinkjng a few minutes ago that I have a couple of routines I designed to do exactly that. So if you slide off a mouse hot spot, and release the button, the click will not take action. It is a neat way of changing your mind in the middle of a selection process.

Pete

[Pete]

I made one more edit to use TYPE variables, easier to pass in subs without the need to to DIM SHARED. Also, I improved some of the variable names.

At some point I might start to analyze the code for debugging and modifying improvements. It would be neat to come back to a coding project after a couple of years, and be able to read it like a book. Easy to search and simple to modify. Ah well, I can dream...

Pete