Newbie question about 8-bit screen in new QB64

[venex]

I have a simple program, which works fine with QB64 SDL in Windows 10:

Code: QB64: [Select]

1. SCREEN 13
2. i = _LOADIMAGE("sample.png")
3. _PUTIMAGE , i
4.  

The sample.png is an 8-bit 320x200 image.

The code compiles with the latest QB64 without errors, but when I try to run the executable I'm getting the following runtime error:

Line: 3 (in main module)
Illegal function call
Continue?

The same thing happens when the first line of the program is

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(320, 200, 256)
2.  

but when I change it to

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(320, 200, 32)
2.  

it works and displays the image.

Problem is that many tutorials, examples and games I found online use SCREEN 13 and other 8-bit modes. How can I run them with the latest QB64? Many times simply changing to 32-bit mode does not help, because a program manipulates the color palette with _COPYPALETTE, or uses LOCATE to display text, which also seems not to work in 32-bit screen modes.

[bplus]

Are you looking for modern interpretations? QB64 can run SCREEN 13.

If so some small sample?

Maybe this?
http://www.qb64.org/wiki/A_Small_Game_Tutorial

[venex]

Thanks for the tutorial link. However, the problem I have is not with drawing, but with loading images. One example of a game which has this problem is Barbarian 1987 from http://barbarian.1987.free.fr/download/download.htm written in QB64 SDL. You can compile it with QB64 v1.4, but it will crash at runtime, because it has problems loading 8-bit image assets. This does not happen when the game is compiled with QB64 SDL. I would like to know if it’s a bug with _PUTIMAGE or maybe something else.

[Dav]

Hi @venex.  Here's a thread that may shed some light on what's happening:
https://www.qb64.org/forum/index.php?topic=1252.0

- Dav

[bplus]

edit

[FellippeHeitor]

8bit mode image loading has been disabled for a while now. You should always check that loaded image handles are <= -1 first (-1 signals the image failed to load):

Code: QB64: [Select]

1. SCREEN 13
2. i = _LOADIMAGE("sample.png")
3. IF i <= -1 THEN _PUTIMAGE , i ELSE PRINT "Load failed."

[SMcNeill]

_LOADIMAGE in the GL version (from 1.0 onwards), auto-converts images to 32-bits.  If you want to use it with 256 color screens (8-bit), then you’ll need to first load them as 32-bits, and then convert/dither them back down to 256 colors.  RhoSigma’s libraries can handle the task, as can routines in my SaveImage libraries, along with examples by Petr, here on the forum, along with several others that I’m probably just not thinking of at the moment.

Here’s a link to one such discussion for you: https://www.qb64.org/forum/index.php?topic=2701.msg119104#msg119104

[Petr]

Hi. This is function for DIRECT inserting 8 bit image to 8 bit screen. This screen palette is always changed so, as it is used in image!

Code: QB64: [Select]

1. 'LOADIMAGE256 experimental
2.  
3. '1] Load image as 32 bit image
4. '2] find how much colors image contains. If 256 and less, continue. If more than 256, return -1 as error message. (can be solved with  RhoSigma's ditherring which is a part of SaveImage)
5. '3] create 8 bit image and color palette
6.  
7. '4] BIG ASK IS: If is this image inserted to 8 bit screen, copy image palette to this screen? OR try to do the same palette for both images?
8.  
9.  
10. SCREEN _NEWIMAGE(1700, 800, 256)
11. img8 = LOADIMAGE256("anim1.png")
12. _COPYPALETTE img8, _DEST
13. _PUTIMAGE (0, 0), img8
14.  
15.  
16.  
17.  
18. FUNCTION LOADIMAGE256 (img$)
19.     DEFLNG A-Z
20.     image = _LOADIMAGE(img$, 32)
21.     DIM m AS _MEM, clr8(255) AS _UNSIGNED LONG, Clr32 AS _UNSIGNED LONG, test AS LONG, s AS LONG
22.     FOR s = 0 TO 255
23.         clr8(s) = 99999
24.     NEXT s
25.     m = _MEMIMAGE(image)
26.     DO UNTIL p& = m.SIZE
27.         _MEMGET m, m.OFFSET + p&, Clr32~&
28.         test = 0
29.         'this block prevent for writing the same color more than 1x to palette array
30.         DO UNTIL test = 255
31.             IF clr8(test) = Clr32~& THEN GOTO NextColor
32.             IF clr8(test) = 99999 THEN EXIT DO
33.             test = test + 1
34.         LOOP
35.         'if is empty place in palette, save this color as next palette color
36.         IF test > 255 THEN PRINT "Image contains more than 256 colors, can not be directly copyed as 8 bit image": END
37.         clr8(test) = Clr32
38.         'color is saved as palette for 8 bit image
39.         NextColor: p& = p& + 4
40.     LOOP
41.     image8 = _NEWIMAGE(_WIDTH(image), _HEIGHT(image), 256)
42.     'set palette
43.     DIM N AS _MEM, C AS _UNSIGNED _BYTE
44.     N = _MEMIMAGE(image8)
45.     FOR palett = 0 TO 255
46.         _PALETTECOLOR palett, clr8(palett), image8
47.     NEXT
48.     'create 8 bit mask (set colors 0 to 255 to 8 bit image)
49.     FOR C = 255 TO 0 STEP -1
50.         clr~& = clr8(C)
51.         R& = 0
52.         R8& = 0
53.         DO UNTIL R& = m.SIZE
54.             _MEMGET m, m.OFFSET + R&, Clr32
55.             IF Clr32 = clr~& THEN _MEMPUT N, N.OFFSET + R8&, C
56.             R& = R& + 4
57.             R8& = R8& + 1
58.         LOOP
59.     NEXT C
60.     LOADIMAGE256 = _COPYIMAGE(image8, 256)
61.     _MEMFREE m
62.     _MEMFREE N
63.     _FREEIMAGE image
64.     _FREEIMAGE image8
65. END FUNCTION
66.  

Of course, you can work with multiple 8-bit images with different palettes at the same time. You just place them on a 32-bit screen. You can make changes using 8-bit colors on 8-bit images in the background. To do this, you need knowledge of the _SOURCE, _DEST and _PALETTECOLOR statements.

[venex]

Thank you very much guys for your help!

I read the materials you linked and also had a quick look at the QB64 source code of internal/c/parts/video/image/src.c and I think I understand a little bit better now how it works.

@Petr your code rocks! I changed my initial program from:

Code: QB64: [Select]

1. SCREEN 13
2. i = _LOADIMAGE("sample.png")
3. _PUTIMAGE , i
4.  

into:

Code: QB64: [Select]

1. SCREEN 13
2. i = LOADIMAGE256("sample.png")
3. _COPYPALETTE i, _DEST
4. _PUTIMAGE , i
5.  

and now everything works like a charm :) Thank you!