« previous next »
Pages: [1]   Go Down

Author Topic: Sanctum: major overhaul to particle world  (Read 3659 times)

0 Members and 1 Guest are viewing this topic.

Offline STxAxTIC

  • Library Staff
  • Forum Resident
  • Posts: 1091
  • he lives
    • View Profile
Sanctum: major overhaul to particle world
« on: October 04, 2020, 05:32:29 pm »
All you do is discover stuff. Everything should be obvious:

Code: QB64: [Select]
  1. ' Version 2020-10-04
  2.  
  3. ' Meta
  6. _TITLE "Sanctum"
  7. _DELAY .25
  8.  
  9. ' Hardware.
  10. 'SCREEN _NEWIMAGE(640, 480, 32)
  11. SCREEN _NEWIMAGE(800, 600, 32)
  12. 'SCREEN _NEWIMAGE(1024, 768, 32)
  15.  
  16. ' Color constants.
  17. CONST Aquamarine = _RGB32(127, 255, 212)
  18. CONST Black = _RGB32(0, 0, 0)
  19. CONST Blue = _RGB32(0, 0, 255)
  20. CONST BlueViolet = _RGB32(138, 43, 226)
  21. CONST Chocolate = _RGB32(210, 105, 30)
  22. CONST Cyan = _RGB32(0, 255, 255)
  23. CONST DarkBlue = _RGB32(0, 0, 139)
  24. CONST DarkGoldenRod = _RGB32(184, 134, 11)
  25. CONST DarkGray = _RGB32(169, 169, 169)
  26. CONST DarkKhaki = _RGB32(189, 183, 107)
  27. CONST DeepPink = _RGB32(255, 20, 147)
  28. CONST DodgerBlue = _RGB32(30, 144, 255)
  29. CONST ForestGreen = _RGB32(34, 139, 34)
  30. CONST Gray = _RGB32(128, 128, 128)
  31. CONST Green = _RGB32(0, 128, 0)
  32. CONST Indigo = _RGB32(75, 0, 130)
  33. CONST Ivory = _RGB32(255, 255, 240)
  34. CONST LightSeaGreen = _RGB32(32, 178, 170)
  35. CONST Lime = _RGB32(0, 255, 0)
  36. CONST LimeGreen = _RGB32(50, 205, 50)
  37. CONST Magenta = _RGB32(255, 0, 255)
  38. CONST PaleGoldenRod = _RGB32(238, 232, 170)
  39. CONST Purple = _RGB32(128, 0, 128)
  40. CONST Red = _RGB32(255, 0, 0)
  41. CONST RoyalBlue = _RGB32(65, 105, 225)
  42. CONST SaddleBrown = _RGB32(139, 69, 19)
  43. CONST Sienna = _RGB32(160, 82, 45)
  44. CONST SlateGray = _RGB32(112, 128, 144)
  45. CONST Snow = _RGB32(255, 250, 250)
  46. CONST Sunglow = _RGB32(255, 207, 72)
  47. CONST SunsetOrange = _RGB32(253, 94, 83)
  48. CONST Teal = _RGB32(0, 128, 128)
  49. CONST White = _RGB32(255, 255, 255)
  50. CONST Yellow = _RGB32(255, 255, 0)
  51.  
  52. ' Mathematical constants.
  53. CONST pi = 4 * ATN(1)
  54. CONST ee = EXP(1)
  55.  
  56. ' Types.
  57.  
  58. TYPE Vector
  59.     x AS DOUBLE
  60.     y AS DOUBLE
  61.     z AS DOUBLE
  63.  
  64. TYPE ShadeMix
  65.     ShadeA AS _UNSIGNED LONG
  66.     ShadeB AS _UNSIGNED LONG
  67.     ShadeC AS _UNSIGNED LONG
  69.  
  70. TYPE Camera
  71.     Position AS Vector
  72.     Velocity AS Vector
  73.     Shade AS _UNSIGNED LONG
  75.  
  76. TYPE ClusterElement
  77.     Index AS LONG
  78.     FirstGroup AS LONG
  79.     LastGroup AS LONG
  80.     Centroid AS Vector
  81.     Velocity AS Vector
  82.     Visible AS INTEGER
  83.     MotionType AS INTEGER
  85.  
  86. TYPE GroupElement
  87.     Identity AS LONG
  88.     GroupName AS STRING
  89.     Pointer AS LONG
  90.     Lagger AS LONG
  91.     Volume AS Vector
  92.     FirstVector AS LONG
  93.     LastVector AS LONG
  94.     Centroid AS Vector
  95.     Velocity AS Vector
  96.     Visible AS INTEGER
  97.     Distance2 AS DOUBLE
  99.  
  100. TYPE MissionGroup
  101.     Label AS STRING
  102.     Discovered AS INTEGER
  104.  
  105. ' Scale.
  106. DIM SHARED bignumber AS LONG
  107. bignumber = 6000000
  108.  
  109. ' Cluster setup.
  110. DIM SHARED ClusterIndexTicker AS LONG
  111. DIM SHARED ClusterFillCounter AS INTEGER
  112. DIM SHARED Cluster(bignumber / 100) AS ClusterElement
  113. ClusterIndexTicker = 0
  114. ClusterFillCounter = 0
  115.  
  116. ' Group linked list setup.
  117. DIM SHARED Group(bignumber / 10) AS GroupElement
  118. DIM SHARED GroupIdTicker AS LONG
  119. GroupIdTicker = 0
  120.  
  121. ' Path
  122. DIM SHARED FixedPath(25, 86400) AS Vector
  123. DIM SHARED PathIndexTicker AS LONG
  124. PathIndexTicker = 0
  125.  
  126. ' Basis vectors defined in three-space.
  127. DIM SHARED xhat(3), yhat(3), zhat(3)
  128. xhat(1) = 1: xhat(2) = 0: xhat(3) = 0
  129. yhat(1) = 0: yhat(2) = 1: yhat(3) = 0
  130. zhat(1) = 0: zhat(2) = 0: zhat(3) = 1
  131.  
  132. ' Camera orientation vectors.
  133. DIM SHARED uhat(3), vhat(3), nhat(3)
  134.  
  135. ' Camera position.
  136. DIM SHARED PlayerCamera AS Camera
  137.  
  138. ' Field-of-view distance.
  139. DIM SHARED fovd
  140. fovd = -192
  141.  
  142. ' Clipping planes.
  143. DIM SHARED nearplane(4), farplane(4), rightplane(4), leftplane(4), topplane(4), bottomplane(4)
  144. nearplane(4) = 1
  145. farplane(4) = -180
  146. rightplane(4) = -17 ' (10 looks better than 1.)
  147. leftplane(4) = -17
  148. topplane(4) = -17
  149. bottomplane(4) = -17
  150.  
  151. ' World vectors.
  152. DIM SHARED vec(bignumber, 3) ' Relative Position
  153. DIM SHARED vec3Dpos(bignumber, 3) ' Position
  154. DIM SHARED vec3Dvel(bignumber, 3) ' Linear velocity
  155. DIM SHARED vec3Dvis(bignumber) ' Visible toggle
  156. DIM SHARED vec2D(bignumber, 2) ' Projection onto 2D plane
  157. DIM SHARED vec3Dcolor(bignumber) AS LONG ' Original color
  158. DIM SHARED vec2Dcolor(bignumber) AS LONG ' Projected color
  159.  
  160. ' Mission.
  161. DIM SHARED MissionTicker AS INTEGER
  162. DIM SHARED Mission(20) AS MissionGroup
  163.  
  164. ' Interface.
  165. DIM SHARED ToggleHUD AS INTEGER
  166. DIM SHARED ToggleAnimate AS INTEGER
  167. DIM SHARED FPSReport AS INTEGER
  168. DIM SHARED NumClusterVisible AS LONG
  169. DIM SHARED NumVectorVisible AS LONG
  170. DIM SHARED NumGroupVisible AS LONG
  171. DIM SHARED ClosestGroup AS LONG
  172.  
  173. ' Initialize.
  174. ToggleAnimate = 1
  175. ToggleHUD = 1
  176. PlayerCamera.Position.x = -40
  177. PlayerCamera.Position.y = 30
  178. PlayerCamera.Position.z = 40
  179. uhat(1) = -.2078192: uhat(2) = -.9781672: uhat(3) = 0
  180. vhat(1) = 0: vhat(2) = 0: vhat(3) = 1
  181. CALL CalculateScreenVectors
  182.  
  183. ' Prime main loop.
  184. CALL CreateLevel
  185. CALL CreateMission(10)
  186.  
  187. ' Start main loop.
  188. CALL MainLoop
  189.  
  190. ' Subs and Functions
  191.  
  192. SUB CreateMission (ListSize AS INTEGER)
  193.     DIM k AS INTEGER
  194.     DIM a AS STRING
  195.     DIM b AS STRING
  196.     a = ""
  197.     b = ""
  198.     REDIM MissionPool(0) AS STRING
  199.  
  200.     '''
  201.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Atmospheric dust"
  202.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Black hole"
  203.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Cloudy sky"
  204.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 1"
  205.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 2"
  206.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Comet 3"
  207.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Demon orb"
  208.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Dirt and sand"
  209.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Grave"
  210.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Hell sparks"
  211.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Laser"
  212.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Lush terrain"
  213.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 1"
  214.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 2"
  215.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 3"
  216.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Tornado 4"
  217.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet center"
  218.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet column"
  219.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Planet interior"
  220.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Plasma core"
  221.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Pyramid"
  222.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Rain"
  223.     REDIM _PRESERVE MissionPool(UBOUND(MissionPool) + 1): MissionPool(UBOUND(MissionPool)) = "Singularity"
  224.     '''
  225.  
  226.     MissionTicker = 0
  227.     DO
  228.         k = 1 + INT(RND * UBOUND(MissionPool))
  229.         a = MissionPool(k)
  230.         IF (INSTR(b, a) = 0) THEN
  231.             b = b + a
  232.             MissionTicker = MissionTicker + 1
  233.             Mission(MissionTicker).Label = a
  234.             Mission(MissionTicker).Discovered = 0
  235.         END IF
  236.     LOOP UNTIL (MissionTicker = ListSize)
  238.  
  239. SUB CreateLevel
  240.     DIM gtmp AS LONG
  241.     DIM p AS LONG
  242.     DIM n AS DOUBLE
  243.     DIM i, j, k AS DOUBLE
  244.     DIM u, v, w AS DOUBLE
  245.     DIM x0, y0, z0 AS DOUBLE
  246.  
  247.     ' Initialize linked list.
  248.     gtmp = CreateNewGroup&(0, 0, 0, 0, 0, 1)
  249.  
  250.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  251.  
  252.     ' Atmospheric dust
  253.     FOR u = -1400 TO 1400 - 350 STEP 350
  254.         FOR v = -1400 TO 1400 - 350 STEP 350
  255.             FOR i = u TO u + 350 STEP 35
  256.                 FOR j = v TO v + 350 STEP 35
  257.                     FOR w = (100 + 35 / 2) TO (800 - 35 + 35 / 2) STEP 35
  258.                         gtmp = NewCube&(gtmp, "Atmospheric dust", 5 * (1 - w / 800), i, j, w, 35, 35, 35, DarkGray, White, Snow, -1)
  259.                     NEXT
  260.                 NEXT
  261.             NEXT
  262.             CALL ClusterPinch(gtmp)
  263.         NEXT
  264.     NEXT
  265.     CALL ClusterPinch(gtmp)
  266.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  267.  
  268.     'Black hole
  269.     k = RND * 2 * pi
  270.     x0 = 1000 * COS(k)
  271.     y0 = 1000 * SIN(k)
  272.     z0 = 300
  273.     i = 100
  274.     j = 25
  275.     FOR u = -i TO i STEP j
  276.         FOR v = -i TO i STEP j
  277.             FOR w = -i TO i STEP j
  278.                 k = SQR(u * u + v * v + w * w)
  279.                 IF k <= i AND k >= i - j THEN
  280.                     gtmp = NewCube&(gtmp, "Black hole", j, x0 + u, y0 + v, z0 + w, j, j, j, DarkGray, White, Snow, -1)
  281.                     CALL SetParticleVelocity(gtmp, -.25 * u / k, -.25 * v / k, -.25 * w / k)
  282.                 END IF
  283.             NEXT
  284.         NEXT
  285.     NEXT
  286.     gtmp = NewShell&("Singularity", 10, x0, y0, z0, Black, Black, Black, 2, 5, -1)
  287.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  288.  
  289.     ' Comet
  290.     FOR n = 1 TO 3
  291.         u = RND * 2 * pi
  292.         PathIndexTicker = PathIndexTicker + 1
  293.         FOR p = 1 TO 86400
  294.             FixedPath(PathIndexTicker, p).x = .25 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  295.             FixedPath(PathIndexTicker, p).y = .25 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  296.             FixedPath(PathIndexTicker, p).z = .15 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  297.         NEXT
  298.         x0 = 150 + (RND - .5) * 2 * 550
  299.         y0 = 150 + (RND - .5) * 2 * 550
  300.         z0 = 200 + RND * 100
  301.         gtmp = NewCube&(gtmp, "Comet" + STR$(n), 300, x0, y0, z0, 25, 25, 25, Teal, Cyan, DodgerBlue, PathIndexTicker)
  302.         FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
  303.             vec3Dvel(k, 1) = (RND - .5) * .20
  304.             vec3Dvel(k, 2) = (RND - .5) * .20
  305.             vec3Dvel(k, 3) = (RND - .5) * .20
  306.         NEXT
  307.         gtmp = NewShell&("Comet" + STR$(n), 15, x0, y0, z0, Teal, Cyan, DodgerBlue, 1, 80, PathIndexTicker)
  308.         CALL ClusterPinch(gtmp)
  309.     NEXT
  310.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  311.  
  312.     ' Demon orb
  313.     FOR n = 1 TO 6
  314.         u = RND * 2 * pi
  315.         PathIndexTicker = PathIndexTicker + 1
  316.         FOR p = 1 TO 86400
  317.             FixedPath(PathIndexTicker, p).x = .25 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  318.             FixedPath(PathIndexTicker, p).y = .25 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  319.             FixedPath(PathIndexTicker, p).z = .15 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  320.         NEXT
  321.         x0 = (RND - .5) * 2 * 1000
  322.         y0 = (RND - .5) * 2 * 1000
  323.         z0 = -700 - RND * 100
  324.         gtmp = NewCube&(gtmp, "Demon orb", 300, x0, y0, z0, 25, 25, 25, Red, SunsetOrange, Sunglow, PathIndexTicker)
  325.         FOR k = Group(gtmp).FirstVector TO Group(gtmp).LastVector
  326.             vec3Dvel(k, 1) = (RND - .5) * .20
  327.             vec3Dvel(k, 2) = (RND - .5) * .20
  328.             vec3Dvel(k, 3) = (RND - .5) * .20
  329.         NEXT
  330.         gtmp = NewShell&("Demon orb", 15, x0, y0, z0, Red, SunsetOrange, Sunglow, 1, 80, PathIndexTicker)
  331.         CALL ClusterPinch(gtmp)
  332.     NEXT
  333.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  334.  
  335.     ' Death Star
  336.     PathIndexTicker = PathIndexTicker + 1
  337.     FOR p = 1 TO 86400
  338.         FixedPath(PathIndexTicker, p).x = -.1 * COS(2 * pi * (24 * 60) * (p - 1) / 86400)
  339.         FixedPath(PathIndexTicker, p).y = -.1 * SIN(2 * pi * (24 * 60) * (p - 1) / 86400)
  340.         FixedPath(PathIndexTicker, p).z = 0
  341.     NEXT
  342.     x0 = 100 + (RND - .5) * 2 * 250
  343.     y0 = 100 + (RND - .5) * 2 * 250
  344.     gtmp = NewShell&("Death Star", 75, x0, y0, 400, Gray, DarkGray, White, 0, 0, PathIndexTicker)
  345.     gtmp = NewShell&("Death Star reactor", 15, x0, y0, 400, Cyan, Teal, Blue, 1, 20, PathIndexTicker)
  346.     gtmp = NewCube&(gtmp, "Plasma core", 300, x0, y0, 400, 25, 25, 25, Cyan, Teal, Blue, PathIndexTicker)
  347.     FOR p = Group(gtmp).FirstVector TO Group(gtmp).LastVector
  348.         vec3Dvel(p, 1) = (RND - .5) * .20
  349.         vec3Dvel(p, 2) = (RND - .5) * .20
  350.         vec3Dvel(p, 3) = (RND - .5) * .20
  351.     NEXT
  352.     FOR n = 10 TO 1 STEP -.5
  353.         gtmp = NewCube&(gtmp, "Laser", 300, x0 + 75 / SQR(2) + (n - 1) * 25, y0 + .5 * n * 25, 400 + 75 / SQR(2) + .5 * (n - 1) * 25, 25, 25, 25, Lime, Green, White, PathIndexTicker)
  354.         FOR p = Group(gtmp).FirstVector TO Group(gtmp).LastVector
  355.             vec3Dvel(p, 1) = (RND - .5) * .50
  356.             vec3Dvel(p, 2) = (RND - .5) * .50
  357.             vec3Dvel(p, 3) = (RND - .5) * .50
  358.         NEXT
  359.     NEXT
  360.     CALL ClusterPinch(gtmp)
  361.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  362.  
  363.     ' Dirt and sand
  364.     FOR u = -1400 TO 1400 - 350 STEP 350
  365.         FOR v = -1400 TO 1400 - 350 STEP 350
  366.             FOR i = u TO u + 350 STEP 35
  367.                 FOR j = v TO v + 350 STEP 35
  368.                     FOR w = 0 - 35 / 2 TO -770 - 35 / 2 STEP -35
  369.                         gtmp = NewCube&(gtmp, "Dirt and sand", 5, i, j, w, 35, 35, 35, SaddleBrown, DarkKhaki, Sienna, -1)
  370.                     NEXT
  371.                 NEXT
  372.             NEXT
  373.             CALL ClusterPinch(gtmp)
  374.         NEXT
  375.     NEXT
  376.     CALL ClusterPinch(gtmp)
  377.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  378.  
  379.     ' Grave and Pyramid (1/2)
  380.     k = RND * 2 * pi
  381.     x0 = 1000 * COS(k)
  382.     y0 = 1000 * SIN(k)
  383.     FOR u = x0 - 160 TO x0 + 160 STEP 80
  384.         FOR v = y0 - 160 TO y0 + 160 STEP 80
  385.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (1) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  386.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (2) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  387.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (3) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  388.             gtmp = NewCube&(gtmp, "Grave", 200, u - 10, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  389.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  390.             gtmp = NewCube&(gtmp, "Grave", 200, u + 10, v, (4) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  391.             gtmp = NewCube&(gtmp, "Grave", 200, u, v, (5) * 10 - 10 / 2, 10, 10, 10, Gray, SlateGray, DarkGray, -1)
  392.         NEXT
  393.     NEXT
  394.     CALL ClusterPinch(gtmp)
  395.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  396.  
  397.     ' Grave and Pyramid (2/2)
  398.     k = k + pi
  399.     x0 = 1000 * COS(k)
  400.     y0 = 1000 * SIN(k)
  401.     FOR w = 0 TO 75 STEP 15
  402.         FOR u = -75 + w TO 75 - w STEP 15
  403.             FOR v = -75 + w TO 75 - w STEP 15
  404.                 gtmp = NewCube&(gtmp, "Pyramid", 35, x0 + u, y0 + v, w, 13, 13, 13, DarkKhaki, SunsetOrange, DarkGoldenRod, -1)
  405.             NEXT
  406.         NEXT
  407.     NEXT
  408.     CALL ClusterPinch(gtmp)
  409.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  410.  
  411.     ' Hell Sparks
  412.     FOR u = -1400 TO 1400 - 350 STEP 350
  413.         FOR v = -1400 TO 1400 - 350 STEP 350
  414.             FOR i = u TO u + 350 STEP 35
  415.                 FOR j = v TO v + 350 STEP 35
  416.                     gtmp = NewCube&(gtmp, "Hell sparks", 15, i, j, -850, 35, 35, 100, Red, SunsetOrange, Sunglow, -1)
  417.                     CALL SetParticleVelocity(gtmp, 0, 0, .75 + RND * .25)
  418.                 NEXT
  419.             NEXT
  420.         NEXT
  421.     NEXT
  422.     CALL ClusterPinch(gtmp)
  423.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  424.  
  425.     ' Lake of Fire
  426.     gtmp = NewTerrain&("Lake of Fire", 2800, 2800, 35, 0, 0, -900, Red, SunsetOrange, Sunglow, 4, 30)
  427.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  428.  
  429.     ' Planet
  430.     PathIndexTicker = PathIndexTicker + 1
  431.     FOR p = 1 TO 86400
  432.         FixedPath(PathIndexTicker, p).x = .1 * COS(2 * pi * (24 * 60) * (p - 1) / 86400)
  433.         FixedPath(PathIndexTicker, p).y = .1 * SIN(2 * pi * (24 * 60) * (p - 1) / 86400)
  434.         FixedPath(PathIndexTicker, p).z = 0
  435.     NEXT
  436.     x0 = 100 + (RND - .5) * 2 * 250
  437.     y0 = 100 + (RND - .5) * 2 * 250
  438.     gtmp = NewPlanet&(350, 35, x0, y0, 900, PathIndexTicker)
  439.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  440.  
  441.     ' Rain
  442.     FOR u = -350 TO 350 STEP 35
  443.         FOR v = -350 TO 350 STEP 35
  444.             IF (u * u + v * v <= 350 ^ 2) THEN
  445.                 gtmp = NewCube&(gtmp, "Rain", 15, u, v, 50, 35, 35, 100, Blue, DodgerBlue, Blue, -1)
  446.                 CALL SetParticleVelocity(gtmp, 0, 0, -.75 - RND * .25)
  447.             END IF
  448.         NEXT
  449.     NEXT
  450.     CALL ClusterPinch(gtmp)
  451.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  452.  
  453.     ' Realm of Heaven
  454.     gtmp = NewTerrain&("Realm of Heaven", 2800, 2800, 35, 0, 0, 1400, BlueViolet, Cyan, White, 4, 30)
  455.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  456.  
  457.     ' Sky and Terrain
  458.     gtmp = NewTerrain&("Cloudy sky", 1400, 1400, 35, 0, 0, 100, RoyalBlue, DarkGray, Snow, 4, 30)
  459.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  460.     gtmp = NewTerrain&("Lush terrain", 1400, 1400, 35, 0, 0, 0, Green, LightSeaGreen, Blue, 4, 30)
  461.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  462.     gtmp = NewTerrain&("Northern desert sand", 2100, 700, 35, 350, 700 + 350 + 35, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
  463.     gtmp = NewTerrain&("Northern desert sky", 2100, 700, 35, 350, 700 + 350 + 35, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
  464.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  465.     gtmp = NewTerrain&("Southern desert sand", 2100, 700, 35, -350, -700 - 350 - 35, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
  466.     gtmp = NewTerrain&("Southern desert sky", 2100, 700, 35, -350, -700 - 350 - 35, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
  467.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  468.     gtmp = NewTerrain&("Eastern desert sand", 700, 2100, 35, 700 + 350 + 35, -350, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
  469.     gtmp = NewTerrain&("Eastern desert sky", 700, 2100, 35, 700 + 350 + 35, -350, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
  470.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  471.     gtmp = NewTerrain&("Western desert sand", 700, 2100, 35, -700 - 350 - 35, 350, 0, DarkKhaki, PaleGoldenRod, Sunglow, 4, 30)
  472.     gtmp = NewTerrain&("Western desert sky", 700, 2100, 35, -700 - 350 - 35, 350, 100, RoyalBlue, DarkGray, Indigo, 4, 30)
  473.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  474.  
  475.     ' Tornado
  476.     FOR n = 1 TO 4
  477.         u = RND * 2 * pi
  478.         PathIndexTicker = PathIndexTicker + 1
  479.         FOR p = 1 TO 86400
  480.             FixedPath(PathIndexTicker, p).x = 1 * COS(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  481.             FixedPath(PathIndexTicker, p).y = 1 * SIN(u + 2 * pi * (24 * 60) * (p - 1) / 86400)
  482.             FixedPath(PathIndexTicker, p).z = 0
  483.         NEXT
  484.         x0 = (RND - .5) * 2 * 750
  485.         y0 = (RND - .5) * 2 * 750
  486.         FOR k = 1 TO 30
  487.             u = RND * 100
  488.             v = RND * u / 3
  489.             w = RND * 2 * pi
  490.             gtmp = NewCube&(gtmp, "Tornado" + STR$(n), 35, x0 + v * COS(w), y0 + v * SIN(w), u, 15, 15, 15, DarkGray, SunsetOrange, DarkGoldenRod, PathIndexTicker)
  491.             CALL SetParticleVelocity(gtmp, -SIN(w), COS(w), 0)
  492.         NEXT
  493.         CALL ClusterPinch(gtmp)
  494.     NEXT
  495.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  496.  
  497.     ' Stellar dust
  498.     FOR u = -1400 TO 1400 - 350 STEP 350
  499.         FOR v = -1400 TO 1400 - 350 STEP 350
  500.             FOR i = u TO u + 350 STEP 35
  501.                 FOR j = v TO v + 350 STEP 35
  502.                     gtmp = NewCube&(gtmp, "Stellar dust", 15, i, j, 1350, 35, 35, 100, BlueViolet, Cyan, White, -1)
  503.                     CALL SetParticleVelocity(gtmp, 0, 0, -.75 - RND * .25)
  504.                 NEXT
  505.             NEXT
  506.         NEXT
  507.     NEXT
  508.     CALL ClusterPinch(gtmp)
  509.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  510.  
  511.     ''' Rocket
  512.     gtmp = NewCube&(gtmp, "Rocket", 200, 0, 0, 0, 15, 15, 35, Green, Green, Green, 0)
  513.     gtmp = NewCube&(gtmp, "Rocket", 200, 0, 0, 0, 15, 15, 15, Red, Red, Red, 0)
  514.     Cluster(ClusterIndexTicker).Velocity.x = 0
  515.     Cluster(ClusterIndexTicker).Velocity.y = 0
  516.     Cluster(ClusterIndexTicker).Velocity.z = 1
  517.     CALL ClusterPinch(gtmp)
  518.     LOCATE 1, 1: PRINT "Loading..." + STR$(INT(100 * Group(gtmp).LastVector / bignumber)) + "%": _DISPLAY
  519.  
  520.     'PRINT
  521.     'PRINT "Total clusters:  " + STR$(ClusterIndexTicker)
  522.     'PRINT "Total groups:    " + STR$(GroupIdTicker)
  523.     'PRINT "Total particles: " + STR$(Group(gtmp).LastVector)
  524.     '_DISPLAY
  525.     'SLEEP 5
  526.  
  528.  
  529. SUB MainLoop
  530.     DIM fps AS INTEGER
  531.     DIM fpstimer AS INTEGER
  532.     DIM tt AS INTEGER
  533.     fps = 0
  534.     fpstimer = INT(TIMER)
  535.     CALL CalculateScreenVectors
  536.     DO
  537.         CALL PlayerDynamics
  538.         CALL ComputeVisibleScene
  539.         CALL PlotWorld
  540.         CALL DisplayHUD
  541.         CALL KeyProcess
  542.  
  543.         fps = fps + 1
  544.         tt = INT(TIMER)
  545.         IF (tt = fpstimer + 1) THEN
  546.             fpstimer = tt
  547.             FPSReport = fps
  548.             fps = 0
  549.         END IF
  550.  
  551.         _DISPLAY
  552.         _LIMIT 30
  553.     LOOP
  555.  
  556. ' Elevated-order primitive group.
  557.  
  558. FUNCTION NewPlanet& (TheRadius AS DOUBLE, ChunkSize AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, TheDynamic AS INTEGER)
  559.     DIM ShadeA AS _UNSIGNED LONG
  560.     DIM ShadeB AS _UNSIGNED LONG
  561.     DIM ShadeC AS _UNSIGNED LONG
  562.     DIM gtmp AS LONG
  563.     DIM rtemp AS DOUBLE
  564.     DIM u AS DOUBLE
  565.     DIM v AS DOUBLE
  566.     DIM w AS DOUBLE
  567.     DIM r AS DOUBLE
  568.     FOR rtemp = ChunkSize TO TheRadius STEP ChunkSize
  569.         FOR u = -rtemp TO rtemp STEP ChunkSize
  570.             FOR v = -rtemp TO rtemp STEP ChunkSize
  571.                 FOR w = -rtemp TO rtemp STEP ChunkSize
  572.                     r = SQR(u * u + v * v + w * w)
  573.                     IF r <= rtemp AND r >= rtemp - ChunkSize THEN
  574.                         ShadeA = Gradient~&(Red, SaddleBrown, r / TheRadius)
  575.                         ShadeB = Gradient~&(SunsetOrange, DarkKhaki, r / TheRadius)
  576.                         ShadeC = DarkKhaki
  577.                         gtmp = NewCube&(1, "Planet Interior", ChunkSize, PosX + u, PosY + v, PosZ + w, ChunkSize, ChunkSize, ChunkSize, ShadeA, ShadeB, ShadeC, TheDynamic)
  578.                         IF (r < TheRadius / 2.5) THEN
  579.                             Group(gtmp).GroupName = "Planet center"
  580.                             CALL SetParticleVelocity(gtmp, .25 * u / r, .25 * v / r, .25 * w / r)
  581.                         END IF
  582.                     END IF
  583.                 NEXT
  584.             NEXT
  585.         NEXT
  586.         CALL ClusterPinch(gtmp)
  587.     NEXT
  588.     CALL ClusterPinch(gtmp)
  589.     gtmp = NewShell&("Planet surface", TheRadius, PosX, PosY, PosZ, Green, DarkKhaki, DodgerBlue, 2, 20, TheDynamic)
  590.     gtmp = NewShell&("Planet core", TheRadius / 10, PosX, PosY, PosZ, Red, Yellow, DarkGoldenRod, 2, 5, TheDynamic)
  591.     FOR w = 0 + ChunkSize / 4 TO PosZ - TheRadius - ChunkSize / 4 STEP ChunkSize / 2
  592.         gtmp = NewCube&(1, "Planet column", 2 * ChunkSize, PosX, PosY, w, ChunkSize / 2, ChunkSize / 2, ChunkSize / 2, Cyan, Teal, Blue, TheDynamic)
  593.         CALL SetParticleVelocity(gtmp, .15 * (RND - .5), .15 * (RND - .5), .25 * RND)
  594.     NEXT
  595.     CALL ClusterPinch(gtmp)
  596.     NewPlanet& = gtmp
  598.  
  599. ' Medium-order primitive group(s).
  600.  
  601. FUNCTION NewTerrain& (TheName AS STRING, SizeX AS DOUBLE, SizeY AS DOUBLE, TheResolution AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, BumpFactor AS DOUBLE, SmoothFactor AS INTEGER)
  602.     DIM g AS LONG
  603.     DIM q AS LONG
  604.     DIM vindex AS LONG
  605.     DIM k AS INTEGER
  606.     DIM factor1 AS DOUBLE
  607.     DIM factor2 AS DOUBLE
  608.     DIM a AS DOUBLE
  609.     DIM b AS DOUBLE
  610.     DIM i AS DOUBLE
  611.     DIM j AS DOUBLE
  612.     DIM u AS DOUBLE
  613.     DIM v AS DOUBLE
  614.     DIM w AS DOUBLE
  615.     DIM ia AS DOUBLE
  616.     DIM jb AS DOUBLE
  617.     DIM rr AS DOUBLE
  618.     DIM wi AS INTEGER
  619.     DIM wj AS INTEGER
  620.     DIM wa AS INTEGER
  621.     DIM wb AS INTEGER
  622.     DIM ci AS INTEGER
  623.     DIM cj AS INTEGER
  624.     DIM ca AS INTEGER
  625.     DIM cb AS INTEGER
  626.  
  627.     factor1 = TheResolution
  628.     factor2 = factor1 / 10
  629.     wi = 0
  630.     wj = 0
  631.     wa = 0
  632.     wb = 0
  633.     FOR i = -SizeX / 2 TO SizeX / 2 STEP factor1
  634.         wi = wi + 1
  635.     NEXT
  636.     FOR j = -SizeY / 2 TO SizeY / 2 STEP factor1
  637.         wj = wj + 1
  638.     NEXT
  639.     FOR a = 0 TO factor1 STEP factor2
  640.         wa = wa + 1
  641.     NEXT
  642.     FOR b = 0 TO factor1 STEP factor2
  643.         wb = wb + 1
  644.     NEXT
  645.  
  646.     DIM vgrid(wi * wa, wj * wb, 2) AS DOUBLE
  647.     DIM vgrid2(wi * wa, wj * wb) AS DOUBLE
  648.     FOR ia = 1 TO wi * wa
  649.         FOR jb = 1 TO wj * wb
  650.             SELECT CASE (RND)
  651.                 CASE IS < .005
  652.                     vgrid(ia, jb, 1) = factor1 * RND
  653.                     vgrid(ia, jb, 2) = 1
  654.                 CASE IS > 1 - .005
  655.                     vgrid(ia, jb, 1) = -factor1 * RND / 2
  656.                     vgrid(ia, jb, 2) = 1
  657.                 CASE ELSE
  658.                     vgrid(ia, jb, 1) = 0
  659.                     vgrid(ia, jb, 2) = 0
  660.             END SELECT
  661.         NEXT
  662.     NEXT
  663.  
  664.     IF (SmoothFactor > 0) THEN
  665.         FOR k = 1 TO SmoothFactor
  666.             FOR ia = 1 TO wi * wa
  667.                 FOR jb = 1 TO wj * wb
  668.                     vgrid2(ia, jb) = vgrid(ia, jb, 1)
  669.                 NEXT
  670.             NEXT
  671.             FOR ia = 1 + 1 TO wi * wa - 1
  672.                 FOR jb = 1 + 1 TO wj * wb - 1
  673.                     IF (k = SmoothFactor - 5) THEN
  674.                         vgrid(ia, jb, 2) = 0
  675.                     END IF
  676.                     IF vgrid(ia, jb, 2) = 0 THEN
  677.                         vgrid(ia, jb, 1) = (1 / 4) * (vgrid2(ia - 1, jb) + vgrid2(ia + 1, jb) + vgrid2(ia, jb - 1) + vgrid2(ia, jb + 1))
  678.                     END IF
  679.                 NEXT
  680.             NEXT
  681.         NEXT
  682.     END IF
  683.  
  684.     ci = 0
  685.     cj = 0
  686.     ca = 0
  687.     cb = 0
  688.     g = 1
  689.     FOR i = -SizeX / 2 TO SizeX / 2 STEP factor1
  690.         ci = ci + 1
  691.         cj = 0
  692.         FOR j = -SizeY / 2 TO SizeY / 2 STEP factor1
  693.             cj = cj + 1
  694.             u = i
  695.             v = j
  696.             w = 0
  697.             q = LatestIdentity&(g)
  698.             vindex = Group(q).LastVector
  699.             g = CreateNewGroup&(q, PosX + u, PosY + v, PosZ + w, 0, 24)
  700.             Group(g).GroupName = TheName
  701.             Group(g).Volume.x = SizeX
  702.             Group(g).Volume.y = SizeY
  703.             Group(g).Volume.z = SQR(SizeX * SizeX + SizeY * SizeY)
  704.             Group(g).FirstVector = vindex + 1
  705.             ca = 0
  706.             FOR a = i TO i + factor1 STEP factor2
  707.                 ca = ca + 1
  708.                 cb = 0
  709.                 FOR b = j TO j + factor1 STEP factor2
  710.                     cb = cb + 1
  711.                     rr = vgrid((ci - 1) * wa + ca, (cj - 1) * wb + cb, 1)
  712.                     vindex = vindex + 1
  713.                     vec3Dpos(vindex, 1) = -u + a + BumpFactor * (RND - .5)
  714.                     vec3Dpos(vindex, 2) = -v + b + BumpFactor * (RND - .5)
  715.                     vec3Dpos(vindex, 3) = -w + rr + BumpFactor * (RND - .5)
  716.                     IF (rr > 0) THEN
  717.                         vec3Dcolor(vindex) = Gradient~&(ShadeA, ShadeB, rr / 10)
  718.                     ELSE
  719.                         vec3Dcolor(vindex) = ShadeC
  720.                     END IF
  721.                 NEXT
  722.             NEXT
  723.             Group(g).LastVector = vindex
  724.         NEXT
  725.         CALL ClusterPinch(g)
  726.     NEXT
  727.     CALL ClusterPinch(g)
  728.     NewTerrain& = g
  730.  
  731. FUNCTION NewShell& (TheName AS STRING, TheRadius AS DOUBLE, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, BumpFactor AS DOUBLE, SmoothFactor AS INTEGER, TheDynamic AS INTEGER)
  732.     DIM g AS LONG
  733.     DIM q AS LONG
  734.     DIM vindex AS LONG
  735.     DIM k AS INTEGER
  736.     DIM factor1 AS DOUBLE
  737.     DIM factor2 AS DOUBLE
  738.     DIM a AS DOUBLE
  739.     DIM b AS DOUBLE
  740.     DIM i AS DOUBLE
  741.     DIM j AS DOUBLE
  742.     DIM u AS DOUBLE
  743.     DIM v AS DOUBLE
  744.     DIM w AS DOUBLE
  745.     DIM ia AS DOUBLE
  746.     DIM jb AS DOUBLE
  747.     DIM rr AS DOUBLE
  748.     DIM wi AS LONG
  749.     DIM wj AS LONG
  750.     DIM wa AS LONG
  751.     DIM wb AS LONG
  752.     DIM ci AS LONG
  753.     DIM cj AS LONG
  754.     DIM ca AS LONG
  755.     DIM cb AS LONG
  756.  
  757.     IF (TheRadius > 200) THEN
  758.         factor1 = (2) * 2 * pi / (10 ^ (INT(LOG(TheRadius) / LOG(10))))
  759.     ELSE
  760.         factor1 = (1) * 2 * pi / (10 ^ (INT(LOG(TheRadius) / LOG(10))))
  761.     END IF
  762.     factor2 = factor1 / (10)
  763.  
  764.     wi = 0
  765.     wj = 0
  766.     wa = 0
  767.     wb = 0
  768.     FOR i = 0 TO 2 * pi STEP factor1
  769.         wi = wi + 1
  770.     NEXT
  771.     FOR j = 0 TO pi STEP factor1
  772.         wj = wj + 1
  773.     NEXT
  774.     FOR a = 0 TO factor1 STEP factor2
  775.         wa = wa + 1
  776.     NEXT
  777.     FOR b = 0 TO factor1 STEP factor2
  778.         wb = wb + 1
  779.     NEXT
  780.  
  781.     DIM vgrid(wi * wa, wj * wb, 2) AS DOUBLE
  782.     DIM vgrid2(wi * wa, wj * wb) AS DOUBLE
  783.  
  784.     FOR ia = 1 TO wi * wa
  785.         FOR jb = 1 TO wj * wb
  786.             SELECT CASE (RND)
  787.                 CASE IS < .025
  788.                     vgrid(ia, jb, 1) = TheRadius - BumpFactor * (TheRadius / 50)
  789.                     vgrid(ia, jb, 2) = 1
  790.                 CASE IS > 1 - .025
  791.                     vgrid(ia, jb, 1) = TheRadius + BumpFactor * (TheRadius / 50)
  792.                     vgrid(ia, jb, 2) = 1
  793.                 CASE ELSE
  794.                     vgrid(ia, jb, 1) = TheRadius
  795.                     vgrid(ia, jb, 2) = 0
  796.             END SELECT
  797.         NEXT
  798.     NEXT
  799.  
  800.     IF (SmoothFactor > 0) THEN
  801.         FOR k = 1 TO SmoothFactor
  802.             FOR ia = 1 TO wi * wa
  803.                 FOR jb = 1 TO wj * wb
  804.                     vgrid2(ia, jb) = vgrid(ia, jb, 1)
  805.                 NEXT
  806.             NEXT
  807.             FOR ia = 1 + 1 TO wi * wa - 1
  808.                 FOR jb = 1 + 1 TO wj * wb - 1
  809.                     IF (k = SmoothFactor - 5) THEN
  810.                         vgrid(ia, jb, 2) = 0
  811.                     END IF
  812.                     IF vgrid(ia, jb, 2) = 0 THEN
  813.                         vgrid(ia, jb, 1) = (1 / 4) * (vgrid2(ia - 1, jb) + vgrid2(ia + 1, jb) + vgrid2(ia, jb - 1) + vgrid2(ia, jb + 1))
  814.                     END IF
  815.                 NEXT
  816.             NEXT
  817.         NEXT
  818.     END IF
  819.  
  820.     ci = 0
  821.     cj = 0
  822.     ca = 0
  823.     cb = 0
  824.     g = 1
  825.     FOR i = 0 TO 2 * pi STEP factor1
  826.         ci = ci + 1
  827.         cj = 0
  828.         FOR j = 0 TO pi STEP factor1
  829.             cj = cj + 1
  830.             u = TheRadius * SIN(j) * COS(i)
  831.             v = TheRadius * SIN(j) * SIN(i)
  832.             w = TheRadius * COS(j)
  833.             q = LatestIdentity&(g)
  834.             vindex = Group(q).LastVector
  835.             g = CreateNewGroup&(q, PosX + u, PosY + v, PosZ + w, TheDynamic, 64)
  836.             Group(g).GroupName = TheName
  837.             Group(g).Volume.x = TheRadius
  838.             Group(g).Volume.y = TheRadius
  839.             Group(g).Volume.z = TheRadius
  840.             Group(g).FirstVector = vindex + 1
  841.             ca = 0
  842.             FOR a = i TO i + factor1 STEP factor2
  843.                 ca = ca + 1
  844.                 cb = 0
  845.                 FOR b = j TO j + factor1 STEP factor2
  846.                     cb = cb + 1
  847.                     rr = vgrid((ci - 1) * wa + ca, (cj - 1) * wb + cb, 1)
  848.                     vindex = vindex + 1
  849.                     vec3Dpos(vindex, 1) = -u + rr * SIN(b) * COS(a) + BumpFactor * (RND - .5) * 2
  850.                     vec3Dpos(vindex, 2) = -v + rr * SIN(b) * SIN(a) + BumpFactor * (RND - .5) * 2
  851.                     vec3Dpos(vindex, 3) = -w + rr * COS(b) + BumpFactor * (RND - .5) * 2
  852.                     IF (rr > TheRadius) THEN
  853.                         vec3Dcolor(vindex) = Gradient~&(ShadeA, ShadeB, COS(j) ^ 2)
  854.                     ELSE
  855.                         vec3Dcolor(vindex) = ShadeC
  856.                     END IF
  857.                 NEXT
  858.             NEXT
  859.             Group(g).LastVector = vindex
  860.         NEXT
  861.         CALL ClusterPinch(g)
  862.     NEXT
  863.     CALL ClusterPinch(g)
  864.  
  865.     NewShell& = g
  867.  
  868. ' Low-order primitive group(s).
  869.  
  870. FUNCTION NewCube& (StartingIdentity AS LONG, TheName AS STRING, Weight AS INTEGER, PosX AS DOUBLE, PosY AS DOUBLE, PosZ AS DOUBLE, VolX AS DOUBLE, VolY AS DOUBLE, VolZ AS DOUBLE, ShadeA AS _UNSIGNED LONG, ShadeB AS _UNSIGNED LONG, ShadeC AS _UNSIGNED LONG, TheDynamic AS INTEGER)
  871.     DIM k AS INTEGER
  872.     DIM g AS LONG
  873.     DIM q AS LONG
  874.     DIM vindex AS LONG
  875.     q = LatestIdentity&(StartingIdentity)
  876.     vindex = Group(q).LastVector
  877.     g = CreateNewGroup(q, PosX, PosY, PosZ, TheDynamic, 64)
  878.     Group(g).GroupName = TheName
  879.     Group(g).Volume.x = VolX
  880.     Group(g).Volume.y = VolY
  881.     Group(g).Volume.z = VolZ
  882.     Group(g).FirstVector = vindex + 1
  883.     FOR k = 1 TO Weight
  884.         vindex = vindex + 1
  885.         vec3Dpos(vindex, 1) = (RND - .5) * VolX
  886.         vec3Dpos(vindex, 2) = (RND - .5) * VolY
  887.         vec3Dpos(vindex, 3) = (RND - .5) * VolZ
  888.         IF (RND > .5) THEN
  889.             vec3Dcolor(vindex) = ShadeA
  890.         ELSE
  891.             IF (RND > .5) THEN
  892.                 vec3Dcolor(vindex) = ShadeB
  893.             ELSE
  894.                 vec3Dcolor(vindex) = ShadeC
  895.             END IF
  896.         END IF
  897.     NEXT
  898.     Group(g).LastVector = vindex
  899.     NewCube& = g
  901.  
  902. ' Linked list utility.
  903.  
  904. FUNCTION LatestIdentity& (StartingID AS LONG)
  905.     DIM TheReturn AS LONG
  906.     DIM p AS LONG
  907.     DIM q AS LONG
  908.     p = StartingID
  909.     DO
  910.         q = p
  911.         p = Group(q).Pointer
  912.         IF (p = -999) THEN EXIT DO
  913.     LOOP
  914.     TheReturn = q
  915.     LatestIdentity& = TheReturn
  917.  
  918. FUNCTION CreateNewGroup& (TheLaggerIn AS LONG, CenterX AS DOUBLE, CenterY AS DOUBLE, CenterZ AS DOUBLE, TheDynamic AS INTEGER, ClusterSize AS INTEGER)
  919.     GroupIdTicker = GroupIdTicker + 1
  920.     Group(GroupIdTicker).Identity = GroupIdTicker
  921.     Group(GroupIdTicker).Pointer = -999
  922.     Group(GroupIdTicker).Lagger = TheLaggerIn
  923.     Group(GroupIdTicker).Centroid.x = CenterX
  924.     Group(GroupIdTicker).Centroid.y = CenterY
  925.     Group(GroupIdTicker).Centroid.z = CenterZ
  926.     IF (TheLaggerIn <> 0) THEN
  927.         Group(TheLaggerIn).Pointer = Group(GroupIdTicker).Identity
  928.     END IF
  929.     '''
  930.     ClusterFillCounter = ClusterFillCounter + 1
  931.  
  932.     IF (ClusterFillCounter = 1) THEN
  933.         ClusterIndexTicker = ClusterIndexTicker + 1
  934.         Cluster(ClusterIndexTicker).FirstGroup = Group(GroupIdTicker).Identity
  935.         Cluster(ClusterIndexTicker).MotionType = TheDynamic
  936.     END IF
  937.  
  938.     IF (ClusterFillCounter = ClusterSize) THEN
  939.         CALL ClusterPinch(Group(GroupIdTicker).Identity)
  940.     END IF
  941.     '''
  942.     CreateNewGroup& = Group(GroupIdTicker).Identity
  944.  
  945. SUB ClusterPinch (TheLastGroup AS LONG)
  946.     ClusterFillCounter = 0
  947.     Cluster(ClusterIndexTicker).LastGroup = TheLastGroup
  948.     CALL ClusterCentroidCalc(ClusterIndexTicker)
  950.  
  951. SUB ClusterCentroidCalc (TheClusterIndex AS LONG)
  952.     DIM k AS LONG
  953.     DIM n AS INTEGER
  954.     Cluster(TheClusterIndex).Centroid.x = 0
  955.     Cluster(TheClusterIndex).Centroid.y = 0
  956.     Cluster(TheClusterIndex).Centroid.z = 0
  957.     k = Cluster(TheClusterIndex).FirstGroup
  958.     n = 0
  959.     DO
  960.         Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x + Group(k).Centroid.x
  961.         Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y + Group(k).Centroid.y
  962.         Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z + Group(k).Centroid.z
  963.         n = n + 1
  964.         IF (k = Cluster(TheClusterIndex).LastGroup) THEN EXIT DO
  965.         k = Group(k).Pointer
  966.     LOOP
  967.     Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x / n
  968.     Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y / n
  969.     Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z / n
  971.  
  972. ' Vector manipulation.
  973.  
  974. SUB SetParticleVelocity (TheGroup AS LONG, vx AS DOUBLE, vy AS DOUBLE, vz AS DOUBLE)
  975.     DIM j AS LONG
  976.     DIM m AS LONG
  977.     DIM n AS LONG
  978.     m = Group(TheGroup).FirstVector
  979.     n = Group(TheGroup).LastVector
  980.     FOR j = m TO n
  981.         vec3Dvel(j, 1) = vx
  982.         vec3Dvel(j, 2) = vy
  983.         vec3Dvel(j, 3) = vz
  984.     NEXT
  986.  
  987. ' Cluster manipulation.
  988.  
  989. SUB EvolveCluster (TheClusterIndex AS LONG)
  990.     DIM dx, dy, dz, t, u, v AS DOUBLE
  991.     IF (Cluster(TheClusterIndex).MotionType = 0) THEN
  992.         dx = Cluster(TheClusterIndex).Velocity.x
  993.         dy = Cluster(TheClusterIndex).Velocity.y
  994.         dz = Cluster(TheClusterIndex).Velocity.z
  995.     ELSE
  996.         t = TIMER
  997.         u = INT(t)
  998.         v = t - u
  999.         dx = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).x + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).x
  1000.         dy = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).y + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).y
  1001.         dz = v * FixedPath(Cluster(TheClusterIndex).MotionType, u).z + (1 - v) * FixedPath(Cluster(TheClusterIndex).MotionType, u - 1).z
  1002.     END IF
  1003.     IF ((dx <> 0) OR (dy <> 0) OR (dz <> 0)) THEN
  1004.         CALL TranslateCluster(TheClusterIndex, dx, dy, dz)
  1005.     END IF
  1007.  
  1008. SUB TranslateCluster (TheClusterIndex AS LONG, dx AS DOUBLE, dy AS DOUBLE, dz AS DOUBLE)
  1009.     DIM k AS LONG
  1010.     k = Cluster(TheClusterIndex).FirstGroup
  1011.     DO
  1012.         Group(k).Centroid.x = Group(k).Centroid.x + dx
  1013.         Group(k).Centroid.y = Group(k).Centroid.y + dy
  1014.         Group(k).Centroid.z = Group(k).Centroid.z + dz
  1015.         IF (k = Cluster(TheClusterIndex).LastGroup) THEN EXIT DO
  1016.         k = Group(k).Pointer
  1017.     LOOP
  1018.     Cluster(TheClusterIndex).Centroid.x = Cluster(TheClusterIndex).Centroid.x + dx
  1019.     Cluster(TheClusterIndex).Centroid.y = Cluster(TheClusterIndex).Centroid.y + dy
  1020.     Cluster(TheClusterIndex).Centroid.z = Cluster(TheClusterIndex).Centroid.z + dz
  1022.  
  1023. ' Particle manipulation.
  1024.  
  1025. SUB EvolveParticles (TheGroup AS LONG)
  1026.     DIM xdim AS DOUBLE
  1027.     DIM ydim AS DOUBLE
  1028.     DIM zdim AS DOUBLE
  1029.     DIM dx AS DOUBLE
  1030.     DIM dy AS DOUBLE
  1031.     DIM dz AS DOUBLE
  1032.     DIM px AS DOUBLE
  1033.     DIM py AS DOUBLE
  1034.     DIM pz AS DOUBLE
  1035.     DIM k AS LONG
  1036.  
  1037.     xdim = Group(TheGroup).Volume.x
  1038.     ydim = Group(TheGroup).Volume.y
  1039.     zdim = Group(TheGroup).Volume.z
  1040.  
  1041.     FOR k = Group(TheGroup).FirstVector TO Group(TheGroup).LastVector
  1042.  
  1043.         ' Position update with periodic boundaries inside group volume
  1044.         dx = 1 * vec3Dvel(k, 1)
  1045.         dy = 1 * vec3Dvel(k, 2)
  1046.         dz = 1 * vec3Dvel(k, 3)
  1047.         IF (dx <> 0) THEN
  1048.             px = vec3Dpos(k, 1) + dx
  1049.             IF ABS(px) > xdim / 2 THEN
  1050.                 IF (px > xdim / 2) THEN
  1051.                     px = -xdim / 2
  1052.                 ELSE
  1053.                     px = xdim / 2
  1054.                 END IF
  1055.             END IF
  1056.             vec3Dpos(k, 1) = px
  1057.         END IF
  1058.         IF (dy <> 0) THEN
  1059.             py = vec3Dpos(k, 2) + dy
  1060.             IF ABS(py) > ydim / 2 THEN
  1061.                 IF (py > ydim / 2) THEN
  1062.                     py = -ydim / 2
  1063.                 ELSE
  1064.                     py = ydim / 2
  1065.                 END IF
  1066.             END IF
  1067.             vec3Dpos(k, 2) = py
  1068.         END IF
  1069.         IF (dz <> 0) THEN
  1070.             pz = vec3Dpos(k, 3) + dz
  1071.             IF ABS(pz) > zdim / 2 THEN
  1072.                 IF (pz > zdim / 2) THEN
  1073.                     pz = -zdim / 2
  1074.                 ELSE
  1075.                     pz = zdim / 2
  1076.                 END IF
  1077.             END IF
  1078.             vec3Dpos(k, 3) = pz
  1079.         END IF
  1080.     NEXT
  1082.  
  1083. SUB CalculateScreenVectors
  1084.     DIM uhatmag AS DOUBLE
  1085.     DIM vhatmag AS DOUBLE
  1086.     DIM h2 AS DOUBLE
  1087.     DIM w2 AS DOUBLE
  1088.     DIM mag AS DOUBLE
  1089.     DIM uhatdotvhat AS DOUBLE
  1090.     uhatmag = SQR(uhat(1) * uhat(1) + uhat(2) * uhat(2) + uhat(3) * uhat(3))
  1091.     uhat(1) = uhat(1) / uhatmag: uhat(2) = uhat(2) / uhatmag: uhat(3) = uhat(3) / uhatmag
  1092.     vhatmag = SQR(vhat(1) * vhat(1) + vhat(2) * vhat(2) + vhat(3) * vhat(3))
  1093.     vhat(1) = vhat(1) / vhatmag: vhat(2) = vhat(2) / vhatmag: vhat(3) = vhat(3) / vhatmag
  1094.     uhatdotvhat = uhat(1) * vhat(1) + uhat(2) * vhat(2) + uhat(3) * vhat(3)
  1095.     nhat(1) = uhat(2) * vhat(3) - uhat(3) * vhat(2)
  1096.     nhat(2) = uhat(3) * vhat(1) - uhat(1) * vhat(3)
  1097.     nhat(3) = uhat(1) * vhat(2) - uhat(2) * vhat(1)
  1098.     h2 = _HEIGHT / 2
  1099.     w2 = _WIDTH / 2
  1100.     nearplane(1) = -nhat(1)
  1101.     nearplane(2) = -nhat(2)
  1102.     nearplane(3) = -nhat(3)
  1103.     farplane(1) = nhat(1)
  1104.     farplane(2) = nhat(2)
  1105.     farplane(3) = nhat(3)
  1106.     rightplane(1) = h2 * fovd * uhat(1) - h2 * w2 * nhat(1)
  1107.     rightplane(2) = h2 * fovd * uhat(2) - h2 * w2 * nhat(2)
  1108.     rightplane(3) = h2 * fovd * uhat(3) - h2 * w2 * nhat(3)
  1109.     mag = SQR(rightplane(1) * rightplane(1) + rightplane(2) * rightplane(2) + rightplane(3) * rightplane(3))
  1110.     rightplane(1) = rightplane(1) / mag
  1111.     rightplane(2) = rightplane(2) / mag
  1112.     rightplane(3) = rightplane(3) / mag
  1113.     leftplane(1) = -h2 * fovd * uhat(1) - h2 * w2 * nhat(1)
  1114.     leftplane(2) = -h2 * fovd * uhat(2) - h2 * w2 * nhat(2)
  1115.     leftplane(3) = -h2 * fovd * uhat(3) - h2 * w2 * nhat(3)
  1116.     mag = SQR(leftplane(1) * leftplane(1) + leftplane(2) * leftplane(2) + leftplane(3) * leftplane(3))
  1117.     leftplane(1) = leftplane(1) / mag
  1118.     leftplane(2) = leftplane(2) / mag
  1119.     leftplane(3) = leftplane(3) / mag
  1120.     topplane(1) = w2 * fovd * vhat(1) - h2 * w2 * nhat(1)
  1121.     topplane(2) = w2 * fovd * vhat(2) - h2 * w2 * nhat(2)
  1122.     topplane(3) = w2 * fovd * vhat(3) - h2 * w2 * nhat(3)
  1123.     mag = SQR(topplane(1) * topplane(1) + topplane(2) * topplane(2) + topplane(3) * topplane(3))
  1124.     topplane(1) = topplane(1) / mag
  1125.     topplane(2) = topplane(2) / mag
  1126.     topplane(3) = topplane(3) / mag
  1127.     bottomplane(1) = -w2 * fovd * vhat(1) - h2 * w2 * nhat(1)
  1128.     bottomplane(2) = -w2 * fovd * vhat(2) - h2 * w2 * nhat(2)
  1129.     bottomplane(3) = -w2 * fovd * vhat(3) - h2 * w2 * nhat(3)
  1130.     mag = SQR(bottomplane(1) * bottomplane(1) + bottomplane(2) * bottomplane(2) + bottomplane(3) * bottomplane(3))
  1131.     bottomplane(1) = bottomplane(1) / mag
  1132.     bottomplane(2) = bottomplane(2) / mag
  1133.     bottomplane(3) = bottomplane(3) / mag
  1135.  
  1136. SUB ProjectGroup (TheGroup AS LONG)
  1137.     DIM i AS LONG
  1138.     DIM f AS INTEGER
  1139.     DIM vectorinview AS INTEGER
  1140.     DIM vec3Ddotnhat AS DOUBLE
  1141.     FOR i = Group(TheGroup).FirstVector TO Group(TheGroup).LastVector
  1142.         vec(i, 1) = Group(TheGroup).Centroid.x + vec3Dpos(i, 1) - PlayerCamera.Position.x
  1143.         vec(i, 2) = Group(TheGroup).Centroid.y + vec3Dpos(i, 2) - PlayerCamera.Position.y
  1144.         vec(i, 3) = Group(TheGroup).Centroid.z + vec3Dpos(i, 3) - PlayerCamera.Position.z
  1145.         f = -1
  1146.         vec3Dvis(i) = 0
  1147.         vectorinview = 1
  1148.         IF vec(i, 1) * nearplane(1) + vec(i, 2) * nearplane(2) + vec(i, 3) * nearplane(3) - nearplane(4) < 0 THEN vectorinview = 0
  1149.         'IF vec(i, 1) * farplane(1) + vec(i, 2) * farplane(2) + vec(i, 3) * farplane(3) - farplane(4) < 0 THEN vectorinview = 0
  1150.         IF vec(i, 1) * farplane(1) + vec(i, 2) * farplane(2) + vec(i, 3) * farplane(3) - farplane(4) * .85 < 0 THEN f = 1
  1151.         'IF vec(i, 1) * rightplane(1) + vec(i, 2) * rightplane(2) + vec(i, 3) * rightplane(3) - rightplane(4) < 0 THEN vectorinview = 0
  1152.         'IF vec(i, 1) * leftplane(1) + vec(i, 2) * leftplane(2) + vec(i, 3) * leftplane(3) - leftplane(4) < 0 THEN vectorinview = 0
  1153.         'IF vec(i, 1) * topplane(1) + vec(i, 2) * topplane(2) + vec(i, 3) * topplane(3) - topplane(4) < 0 THEN vectorinview = 0
  1154.         'IF vec(i, 1) * bottomplane(1) + vec(i, 2) * bottomplane(2) + vec(i, 3) * bottomplane(3) - bottomplane(4) < 0 THEN vectorinview = 0
  1155.         IF (vectorinview = 1) THEN
  1156.             vec3Dvis(i) = 1
  1157.             vec3Ddotnhat = vec(i, 1) * nhat(1) + vec(i, 2) * nhat(2) + vec(i, 3) * nhat(3)
  1158.             vec2D(i, 1) = (vec(i, 1) * uhat(1) + vec(i, 2) * uhat(2) + vec(i, 3) * uhat(3)) * fovd / vec3Ddotnhat
  1159.             vec2D(i, 2) = (vec(i, 1) * vhat(1) + vec(i, 2) * vhat(2) + vec(i, 3) * vhat(3)) * fovd / vec3Ddotnhat
  1160.             IF (f = 1) THEN
  1161.                 vec2Dcolor(i) = Gray
  1162.             ELSE
  1163.                 vec2Dcolor(i) = vec3Dcolor(i)
  1164.             END IF
  1165.         END IF
  1166.     NEXT
  1168.  
  1169. ' TheDynamics
  1170.  
  1171. SUB ComputeVisibleScene
  1172.     DIM closestdist2 AS DOUBLE
  1173.     DIM fp42 AS DOUBLE
  1174.     DIM dist2 AS DOUBLE
  1175.     DIM dx AS DOUBLE
  1176.     DIM dy AS DOUBLE
  1177.     DIM dz AS DOUBLE
  1178.     DIM GroupInView AS INTEGER
  1179.     DIM k AS LONG
  1180.     DIM i AS LONG
  1181.     ClosestGroup = 1
  1182.     closestdist2 = 10000000
  1183.     fp42 = farplane(4) * farplane(4)
  1184.     FOR i = 1 TO ClusterIndexTicker
  1185.         dx = Cluster(i).Centroid.x - PlayerCamera.Position.x
  1186.         dy = Cluster(i).Centroid.y - PlayerCamera.Position.y
  1187.         dz = Cluster(i).Centroid.z - PlayerCamera.Position.z
  1188.         dist2 = dx * dx + dy * dy + dz * dz
  1189.         IF (dist2 > 600 * 600) THEN
  1190.             Cluster(i).Visible = 0
  1191.             IF (Cluster(i).MotionType > -1) THEN
  1192.                 CALL EvolveCluster(i)
  1193.             END IF
  1194.         ELSE
  1195.             Cluster(i).Visible = 1
  1196.             k = Cluster(i).FirstGroup
  1197.             IF ((Cluster(i).MotionType > -1) AND (ToggleAnimate = 1)) THEN
  1198.                 CALL EvolveCluster(i)
  1199.             END IF
  1200.             DO
  1201.                 dx = Group(k).Centroid.x - PlayerCamera.Position.x
  1202.                 dy = Group(k).Centroid.y - PlayerCamera.Position.y
  1203.                 dz = Group(k).Centroid.z - PlayerCamera.Position.z
  1204.                 dist2 = dx * dx + dy * dy + dz * dz
  1205.                 Group(k).Visible = 0
  1206.                 IF (dist2 < fp42) THEN
  1207.                     GroupInView = 1
  1208.                     IF dx * nearplane(1) + dy * nearplane(2) + dz * nearplane(3) - nearplane(4) < 0 THEN GroupInView = 0
  1209.                     'IF dx * farplane(1) + dy * farplane(2) + dz * farplane(3) - farplane(4) < 0 THEN groupinview = 0 ''' Redundant
  1210.                     IF dx * rightplane(1) + dy * rightplane(2) + dz * rightplane(3) - rightplane(4) < 0 THEN GroupInView = 0
  1211.                     IF dx * leftplane(1) + dy * leftplane(2) + dz * leftplane(3) - leftplane(4) < 0 THEN GroupInView = 0
  1212.                     IF dx * topplane(1) + dy * topplane(2) + dz * topplane(3) - topplane(4) < 0 THEN GroupInView = 0
  1213.                     IF dx * bottomplane(1) + dy * bottomplane(2) + dz * bottomplane(3) - bottomplane(4) < 0 THEN GroupInView = 0
  1214.                     IF (GroupInView = 1) THEN
  1215.                         Group(k).Visible = 1
  1216.                         IF (dist2 < closestdist2) THEN
  1217.                             closestdist2 = dist2
  1218.                             ClosestGroup = k
  1219.                         END IF
  1220.                         Group(k).Distance2 = dist2
  1221.                         IF (ToggleAnimate = 1) THEN CALL EvolveParticles(k)
  1222.                         CALL ProjectGroup(k)
  1223.                     END IF
  1224.                 END IF
  1225.                 IF (k = Cluster(i).LastGroup) THEN EXIT DO
  1226.                 k = Group(k).Pointer
  1227.             LOOP
  1228.         END IF
  1229.     NEXT
  1231.  
  1232. ' Graphics
  1233.  
  1234. SUB PlotWorld
  1235.     DIM a AS DOUBLE
  1236.     DIM b AS DOUBLE
  1237.     DIM c AS LONG
  1238.     DIM d AS LONG
  1239.     DIM i AS LONG
  1240.     DIM j AS INTEGER
  1241.     DIM k AS LONG
  1242.     DIM x1 AS DOUBLE
  1243.     DIM y1 AS DOUBLE
  1244.     DIM x2 AS DOUBLE
  1245.     DIM y2 AS DOUBLE
  1246.     DIM clrtmp AS _UNSIGNED LONG
  1247.     DIM SortedGroups(5000) AS LONG
  1248.     DIM SortedGroupsCount AS INTEGER
  1249.  
  1250.     NumClusterVisible = 0
  1251.     NumVectorVisible = 0
  1252.  
  1253.     SortedGroupsCount = 0
  1254.     FOR i = 1 TO ClusterIndexTicker
  1255.         IF (Cluster(i).Visible = 1) THEN
  1256.             NumClusterVisible = NumClusterVisible + 1
  1257.             k = Cluster(i).FirstGroup
  1258.             DO
  1259.                 IF (Group(k).Visible = 1) THEN
  1260.                     SortedGroupsCount = SortedGroupsCount + 1
  1261.                     SortedGroups(SortedGroupsCount) = k
  1262.                 END IF
  1263.                 IF (k = Cluster(i).LastGroup) THEN EXIT DO
  1264.                 k = Group(k).Pointer
  1265.             LOOP
  1266.         END IF
  1267.     NEXT
  1268.  
  1269.     NumGroupVisible = SortedGroupsCount
  1270.  
  1271.     ' Bubble sort might be a shitty choice but it works for now. Replace with quicksort prolly.
  1272.     FOR j = SortedGroupsCount TO 1 STEP -1
  1273.         FOR i = 2 TO SortedGroupsCount - 1
  1274.             a = Group(SortedGroups(i - 1)).Distance2
  1275.             b = Group(SortedGroups(i)).Distance2
  1276.             IF (a < b) THEN
  1277.                 c = SortedGroups(i - 1)
  1278.                 d = SortedGroups(i)
  1279.                 SortedGroups(i - 1) = d
  1280.                 SortedGroups(i) = c
  1281.             END IF
  1282.         NEXT
  1283.     NEXT
  1284.  
  1285.     CLS
  1286.     PlayerCamera.Shade = AverageShadeMix~&(vec3Dcolor(Group(ClosestGroup).FirstVector), PlayerCamera.Shade, .01)
  1287.     PAINT (_WIDTH / 2, _HEIGHT / 2), _RGBA(_RED32(PlayerCamera.Shade), _GREEN32(PlayerCamera.Shade), _BLUE32(PlayerCamera.Shade), 100)
  1288.     FOR j = 1 TO SortedGroupsCount
  1289.         k = SortedGroups(j)
  1290.         FOR i = Group(k).FirstVector TO Group(k).LastVector - 1
  1291.             IF (vec3Dvis(i) = 1) THEN
  1292.                 NumVectorVisible = NumVectorVisible + 1
  1293.                 IF (k = ClosestGroup) THEN
  1294.                     clrtmp = Yellow
  1295.                 ELSE
  1296.                     clrtmp = vec2Dcolor(i)
  1297.                 END IF
  1298.                 x1 = vec2D(i, 1)
  1299.                 y1 = vec2D(i, 2)
  1300.                 x2 = vec2D(i + 1, 1)
  1301.                 y2 = vec2D(i + 1, 2)
  1302.                 IF (((x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1)) < 225) THEN
  1303.                     CALL cline(x1, y1, x2, y2, clrtmp)
  1304.                 ELSE
  1305.                     CALL ccircle(x1, y1, 1, clrtmp)
  1306.                 END IF
  1307.             END IF
  1308.         NEXT
  1309.     NEXT
  1311.  
  1312. SUB DisplayHUD
  1313.     DIM a AS STRING
  1314.     DIM k AS INTEGER
  1315.     CALL cline(0, 0, 25 * (xhat(1) * uhat(1) + xhat(2) * uhat(2) + xhat(3) * uhat(3)), 25 * (xhat(1) * vhat(1) + xhat(2) * vhat(2) + xhat(3) * vhat(3)), _RGBA(255, 0, 0, 200))
  1316.     CALL cline(0, 0, 25 * (yhat(1) * uhat(1) + yhat(2) * uhat(2) + yhat(3) * uhat(3)), 25 * (yhat(1) * vhat(1) + yhat(2) * vhat(2) + yhat(3) * vhat(3)), _RGBA(0, 255, 0, 200))
  1317.     CALL cline(0, 0, 25 * (zhat(1) * uhat(1) + zhat(2) * uhat(2) + zhat(3) * uhat(3)), 25 * (zhat(1) * vhat(1) + zhat(2) * vhat(2) + zhat(3) * vhat(3)), _RGBA(30, 144, 255, 200))
  1318.     IF (ToggleHUD = 1) THEN
  1319.         COLOR LimeGreen
  1320.         _PRINTSTRING ((1) * 8, _HEIGHT - (10) * 16), " Position "
  1321.         COLOR Teal
  1322.         _PRINTSTRING ((1) * 8, _HEIGHT - (9) * 16), " x:       "
  1323.         _PRINTSTRING ((1) * 8, _HEIGHT - (8) * 16), " y:       "
  1324.         _PRINTSTRING ((1) * 8, _HEIGHT - (7) * 16), " z:       "
  1325.         _PRINTSTRING ((1) * 8, _HEIGHT - (9) * 16), " x: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.x))))
  1326.         _PRINTSTRING ((1) * 8, _HEIGHT - (8) * 16), " y: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.y))))
  1327.         _PRINTSTRING ((1) * 8, _HEIGHT - (7) * 16), " z: " + LTRIM$(RTRIM$(STR$(INT(PlayerCamera.Position.z))))
  1328.         COLOR LimeGreen
  1329.         _PRINTSTRING ((1) * 8, _HEIGHT - (6) * 16), " O: Reset "
  1330.         COLOR LimeGreen
  1331.         _PRINTSTRING ((1) * 8, _HEIGHT - (4) * 16), " Move  "
  1332.         COLOR DarkKhaki
  1333.         _PRINTSTRING ((1) * 8, _HEIGHT - (3) * 16), " q W e "
  1334.         _PRINTSTRING ((1) * 8, _HEIGHT - (2) * 16), " A S D "
  1335.         COLOR LimeGreen
  1336.         _PRINTSTRING ((1) * 8, (1) * 16), " Abilities "
  1337.         COLOR DarkKhaki
  1338.         _PRINTSTRING ((1) * 8, (2) * 16), "t = Pause  "
  1339.         _PRINTSTRING ((1) * 8, (3) * 16), "b = Create "
  1340.         _PRINTSTRING ((1) * 8, (4) * 16), "n = Explode"
  1341.         COLOR DarkGray
  1342.         _PRINTSTRING ((1) * 8, (5) * 16), "k = Delete "
  1343.         COLOR DarkKhaki
  1344.         _PRINTSTRING ((1) * 8, (6) * 16), "Esc = Quit "
  1345.         'COLOR LimeGreen
  1346.         '_PRINTSTRING ((1) * 8, (9) * 16), "View"
  1347.         'COLOR DarkKhaki
  1348.         '_PRINTSTRING ((1) * 8, (9) * 16), "FPS: " + LTRIM$(RTRIM$(STR$(FPSReport))) + "/30"
  1349.         '_PRINTSTRING ((1) * 8, (10) * 16), "Clusters: " + LTRIM$(RTRIM$(STR$(NumClusterVisible)))
  1350.         '_PRINTSTRING ((1) * 8, (11) * 16), "Groups: " + LTRIM$(RTRIM$(STR$(NumGroupVisible)))
  1351.         '_PRINTSTRING ((1) * 8, (12) * 16), "Particles: " + LTRIM$(RTRIM$(STR$(NumVectorVisible)))
  1352.         COLOR LimeGreen
  1353.         _PRINTSTRING (_WIDTH - (12) * 8, (1) * 16), " Locations "
  1354.         FOR k = 1 TO MissionTicker
  1355.             a = " " + Mission(k).Label + " "
  1356.             IF (Mission(k).Discovered = 0) THEN
  1357.                 COLOR DarkKhaki
  1358.             ELSE
  1359.                 COLOR DarkGray
  1360.             END IF
  1361.             _PRINTSTRING (_WIDTH - (LEN(a) + 1) * 8, (1 + k) * 16), a
  1362.         NEXT
  1363.         COLOR LimeGreen
  1364.         _PRINTSTRING (_WIDTH - (12) * 8, (k + 1) * 16), " M = Reset "
  1365.         COLOR LimeGreen
  1366.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (10) * 16), " Aim    "
  1367.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (9) * 16), " x      "
  1368.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (8) * 16), " y      "
  1369.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (7) * 16), " z      "
  1370.         COLOR Teal
  1371.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (9) * 16), " x: " + LTRIM$(RTRIM$(STR$(INT(-nhat(1) * 100))))
  1372.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (8) * 16), " y: " + LTRIM$(RTRIM$(STR$(INT(-nhat(2) * 100))))
  1373.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (7) * 16), " z: " + LTRIM$(RTRIM$(STR$(INT(-nhat(3) * 100))))
  1374.         COLOR LimeGreen
  1375.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (5) * 16), " Swivel "
  1376.         COLOR DarkKhaki
  1377.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (4) * 16), " 7 8 9  "
  1378.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (3) * 16), " 4 5 6  "
  1379.         _PRINTSTRING (_WIDTH - (9) * 8, _HEIGHT - (2) * 16), " 1 2 3  "
  1380.         a = " - Closest - "
  1381.         COLOR LimeGreen
  1382.         _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (3) * 16), a
  1383.         a = " SPACE = Hide "
  1384.         COLOR LimeGreen
  1385.         _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (1) * 16), a
  1386.     END IF
  1387.     a = " " + Group(ClosestGroup).GroupName + " "
  1388.     COLOR DarkKhaki
  1389.     _PRINTSTRING (_WIDTH / 2 - (LEN(a) / 2) * 8, _HEIGHT - (2) * 16), a
  1391.  
  1392. ' Interface
  1393.  
  1394. SUB KeyProcess
  1395.     IF (_KEYDOWN(87) = -1) OR (_KEYDOWN(119) = -1) OR (_KEYDOWN(18432) = -1) THEN ' W or w or uparrow
  1396.         CALL StrafeCameraNhatMinus
  1397.         IF (ToggleAnimate = 1) THEN
  1398.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - .05 * nhat(1)
  1399.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - .05 * nhat(2)
  1400.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - .05 * nhat(3)
  1401.         END IF
  1402.     END IF
  1403.     IF (_KEYDOWN(83) = -1) OR (_KEYDOWN(115) = -1) OR (_KEYDOWN(20480) = -1) THEN ' S or s or downarrow
  1404.         CALL StrafeCameraNhatPlus
  1405.         IF (ToggleAnimate = 1) THEN
  1406.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + .05 * nhat(1)
  1407.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + .05 * nhat(2)
  1408.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + .05 * nhat(3)
  1409.         END IF
  1410.     END IF
  1411.     IF (_KEYDOWN(65) = -1) OR (_KEYDOWN(97) = -1) THEN ' A or a
  1412.         CALL StrafeCameraUhatMinus
  1413.         IF (ToggleAnimate = 1) THEN
  1414.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - .05 * uhat(1)
  1415.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - .05 * uhat(2)
  1416.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - .05 * uhat(3)
  1417.         END IF
  1418.     END IF
  1419.     IF (_KEYDOWN(68) = -1) OR (_KEYDOWN(100) = -1) THEN ' D or d
  1420.         CALL StrafeCameraUhatPlus
  1421.         IF (ToggleAnimate = 1) THEN
  1422.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + .05 * uhat(1)
  1423.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + .05 * uhat(2)
  1424.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + .05 * uhat(3)
  1425.         END IF
  1426.     END IF
  1427.     IF (_KEYDOWN(81) = -1) OR (_KEYDOWN(113) = -1) THEN ' Q or q
  1428.         CALL StrafeCameraVhatMinus
  1429.         IF (ToggleAnimate = 1) THEN
  1430.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x - .05 * vhat(1)
  1431.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y - .05 * vhat(2)
  1432.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z - .05 * vhat(3)
  1433.         END IF
  1434.     END IF
  1435.     IF (_KEYDOWN(69) = -1) OR (_KEYDOWN(101) = -1) THEN ' E or e
  1436.         CALL StrafeCameraVhatPlus
  1437.         IF (ToggleAnimate = 1) THEN
  1438.             PlayerCamera.Velocity.x = PlayerCamera.Velocity.x + .05 * vhat(1)
  1439.             PlayerCamera.Velocity.y = PlayerCamera.Velocity.y + .05 * vhat(2)
  1440.             PlayerCamera.Velocity.z = PlayerCamera.Velocity.z + .05 * vhat(3)
  1441.         END IF
  1442.     END IF
  1443.     IF (_KEYDOWN(19200) = -1) OR (_KEYDOWN(52) = -1) THEN CALL RotateUhatMinus: CALL CalculateScreenVectors ' 4
  1444.     IF (_KEYDOWN(19712) = -1) OR (_KEYDOWN(54) = -1) THEN CALL RotateUhatPlus: CALL CalculateScreenVectors ' 6
  1445.     IF (_KEYDOWN(56) = -1) THEN CALL RotateVhatPlus: CALL CalculateScreenVectors ' 8
  1446.     IF (_KEYDOWN(50) = -1) THEN CALL RotateVhatMinus: CALL CalculateScreenVectors ' 2
  1447.     IF (_KEYDOWN(55) = -1) THEN CALL RotateClockwise ' 7
  1448.     IF (_KEYDOWN(57) = -1) THEN CALL RotateCounterclockwise ' 9
  1449.     IF (_KEYDOWN(49) = -1) THEN CALL RotateUhatMinus: CALL CalculateScreenVectors: CALL RotateClockwise ' 1
  1450.     IF (_KEYDOWN(51) = -1) THEN CALL RotateUhatPlus: CALL CalculateScreenVectors: CALL RotateCounterclockwise ' 3
  1451.     DIM k AS LONG
  1452.     DIM p AS LONG
  1453.     DIM l AS LONG
  1454.     DIM kh AS INTEGER
  1455.     kh = _KEYHIT
  1456.     IF (kh <> 0) THEN
  1457.         SELECT CASE kh
  1458.             CASE 27
  1459.                 SYSTEM
  1460.             CASE ASC(" ")
  1461.                 ToggleHUD = -ToggleHUD
  1462.             CASE ASC("b"), ASC("B")
  1463.                 DIM gtmp AS LONG
  1464.                 gtmp = NewCube&(1, "Custom block", 350, PlayerCamera.Position.x - 40 * nhat(1), PlayerCamera.Position.y - 40 * nhat(2), PlayerCamera.Position.z - 40 * nhat(3), 10, 10, 10, Lime, Purple, Teal, 0)
  1465.                 CALL ClusterPinch(gtmp)
  1466.             CASE ASC("k"), ASC("K")
  1467.                 ' set -999? delete actual vectors?
  1468.                 p = Group(ClosestGroup).Pointer
  1469.                 l = Group(ClosestGroup).Lagger
  1470.                 Group(l).Pointer = p
  1471.                 IF (p <> -999) THEN
  1472.                     Group(p).Lagger = l
  1473.                 END IF
  1474.             CASE ASC("m"), ASC("M")
  1475.                 CALL CreateMission(10)
  1476.             CASE ASC("n"), ASC("N")
  1477.                 FOR k = Group(ClosestGroup).FirstVector TO Group(ClosestGroup).LastVector
  1478.                     vec3Dvel(k, 1) = (RND - .5) * .20
  1479.                     vec3Dvel(k, 2) = (RND - .5) * .20
  1480.                     vec3Dvel(k, 3) = (RND - .5) * .20
  1481.                 NEXT
  1482.             CASE ASC("o"), ASC("O")
  1483.                 PlayerCamera.Position.x = -40
  1484.                 PlayerCamera.Position.y = 30
  1485.                 PlayerCamera.Position.z = 40
  1486.                 uhat(1) = -.2078192: uhat(2) = -.9781672: uhat(3) = 0
  1487.                 vhat(1) = 0: vhat(2) = 0: vhat(3) = 1
  1488.                 CALL CalculateScreenVectors
  1489.             CASE ASC("t"), ASC("T")
  1490.                 ToggleAnimate = -ToggleAnimate
  1491.         END SELECT
  1492.     END IF
  1493.     _KEYCLEAR
  1495.  
  1496. ' Color utility.
  1497.  
  1498. FUNCTION Gradient~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, param AS DOUBLE)
  1499.     Gradient~& = _RGB32((1 - param) * _RED32(Shade1) + param * _RED32(Shade2), (1 - param) * _GREEN32(Shade1) + param * _GREEN32(Shade2), (1 - param) * _BLUE32(Shade1) + param * _BLUE32(Shade2))
  1501.  
  1502. FUNCTION AverageShadeMix~& (Shade1 AS _UNSIGNED LONG, Shade2 AS _UNSIGNED LONG, Weight AS DOUBLE)
  1503.     AverageShadeMix~& = _RGB32(Weight * _RED32(Shade1) + (1 - Weight) * _RED32(Shade2), Weight * _GREEN32(Shade1) + (1 - Weight) * _GREEN32(Shade2), Weight * _BLUE32(Shade1) + (1 - Weight) * _BLUE32(Shade2))
  1505.  
  1506. ' Cartesian plotting.
  1507.  
  1508. SUB cline (x1 AS DOUBLE, y1 AS DOUBLE, x2 AS DOUBLE, y2 AS DOUBLE, col AS _UNSIGNED LONG)
  1509.     LINE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2)-(_WIDTH / 2 + x2, -y2 + _HEIGHT / 2), col
  1511.  
  1512. SUB ccircle (x1 AS DOUBLE, y1 AS DOUBLE, rad AS DOUBLE, col AS _UNSIGNED LONG)
  1513.     CIRCLE (_WIDTH / 2 + x1, -y1 + _HEIGHT / 2), rad, col
  1515.  
  1516. ' Camera transformation
  1517.  
  1518. SUB PlayerDynamics
  1519.  
  1520.     DIM k AS INTEGER
  1521.  
  1522.     IF (ToggleAnimate = 1) THEN
  1523.         PlayerCamera.Velocity.x = .95 * PlayerCamera.Velocity.x
  1524.         PlayerCamera.Velocity.y = .95 * PlayerCamera.Velocity.y
  1525.         PlayerCamera.Velocity.z = .95 * PlayerCamera.Velocity.z
  1526.         PlayerCamera.Position.x = PlayerCamera.Position.x + PlayerCamera.Velocity.x
  1527.         PlayerCamera.Position.y = PlayerCamera.Position.y + PlayerCamera.Velocity.y
  1528.         PlayerCamera.Position.z = PlayerCamera.Position.z + PlayerCamera.Velocity.z
  1529.     END IF
  1530.  
  1531.     FOR k = 1 TO MissionTicker
  1532.         IF (Group(ClosestGroup).GroupName = Mission(k).Label) THEN
  1533.             IF (Mission(k).Discovered = 0) THEN
  1534.                 Mission(k).Discovered = 1
  1535.                 SOUND 500, .25
  1536.             END IF
  1537.         END IF
  1538.     NEXT
  1540.  
  1541. SUB RotateUhatPlus
  1542.     uhat(1) = uhat(1) + nhat(1) * .0333
  1543.     uhat(2) = uhat(2) + nhat(2) * .0333
  1544.     uhat(3) = uhat(3) + nhat(3) * .0333
  1546.  
  1547. SUB RotateUhatMinus
  1548.     uhat(1) = uhat(1) - nhat(1) * .0333
  1549.     uhat(2) = uhat(2) - nhat(2) * .0333
  1550.     uhat(3) = uhat(3) - nhat(3) * .0333
  1552.  
  1553. SUB RotateVhatPlus
  1554.     vhat(1) = vhat(1) + nhat(1) * .0333
  1555.     vhat(2) = vhat(2) + nhat(2) * .0333
  1556.     vhat(3) = vhat(3) + nhat(3) * .0333
  1558.  
  1559. SUB RotateVhatMinus
  1560.     vhat(1) = vhat(1) - nhat(1) * .0333
  1561.     vhat(2) = vhat(2) - nhat(2) * .0333
  1562.     vhat(3) = vhat(3) - nhat(3) * .0333
  1564.  
  1565. SUB RotateCounterclockwise
  1566.     DIM v1, v2, v3 AS DOUBLE
  1567.     v1 = vhat(1)
  1568.     v2 = vhat(2)
  1569.     v3 = vhat(3)
  1570.     vhat(1) = v1 + uhat(1) * .0333
  1571.     vhat(2) = v2 + uhat(2) * .0333
  1572.     vhat(3) = v3 + uhat(3) * .0333
  1573.     uhat(1) = uhat(1) - v1 * .0333
  1574.     uhat(2) = uhat(2) - v2 * .0333
  1575.     uhat(3) = uhat(3) - v3 * .0333
  1577.  
  1578. SUB RotateClockwise
  1579.     DIM v1, v2, v3 AS DOUBLE
  1580.     v1 = vhat(1)
  1581.     v2 = vhat(2)
  1582.     v3 = vhat(3)
  1583.     vhat(1) = v1 - uhat(1) * .0333
  1584.     vhat(2) = v2 - uhat(2) * .0333
  1585.     vhat(3) = v3 - uhat(3) * .0333
  1586.     uhat(1) = uhat(1) + v1 * .0333
  1587.     uhat(2) = uhat(2) + v2 * .0333
  1588.     uhat(3) = uhat(3) + v3 * .0333
  1590.  
  1591. SUB StrafeCameraUhatPlus
  1592.     PlayerCamera.Position.x = PlayerCamera.Position.x + uhat(1)
  1593.     PlayerCamera.Position.y = PlayerCamera.Position.y + uhat(2)
  1594.     PlayerCamera.Position.z = PlayerCamera.Position.z + uhat(3)
  1596.  
  1597. SUB StrafeCameraUhatMinus
  1598.     PlayerCamera.Position.x = PlayerCamera.Position.x - uhat(1)
  1599.     PlayerCamera.Position.y = PlayerCamera.Position.y - uhat(2)
  1600.     PlayerCamera.Position.z = PlayerCamera.Position.z - uhat(3)
  1602.  
  1603. SUB StrafeCameraVhatPlus
  1604.     PlayerCamera.Position.x = PlayerCamera.Position.x + vhat(1)
  1605.     PlayerCamera.Position.y = PlayerCamera.Position.y + vhat(2)
  1606.     PlayerCamera.Position.z = PlayerCamera.Position.z + vhat(3)
  1608.  
  1609. SUB StrafeCameraVhatMinus
  1610.     PlayerCamera.Position.x = PlayerCamera.Position.x - vhat(1)
  1611.     PlayerCamera.Position.y = PlayerCamera.Position.y - vhat(2)
  1612.     PlayerCamera.Position.z = PlayerCamera.Position.z - vhat(3)
  1614.  
  1615. SUB StrafeCameraNhatPlus
  1616.     PlayerCamera.Position.x = PlayerCamera.Position.x + nhat(1)
  1617.     PlayerCamera.Position.y = PlayerCamera.Position.y + nhat(2)
  1618.     PlayerCamera.Position.z = PlayerCamera.Position.z + nhat(3)
  1620.  
  1621. SUB StrafeCameraNhatMinus
  1622.     PlayerCamera.Position.x = PlayerCamera.Position.x - nhat(1)
  1623.     PlayerCamera.Position.y = PlayerCamera.Position.y - nhat(2)
  1624.     PlayerCamera.Position.z = PlayerCamera.Position.z - nhat(3)
Logged
You're not done when it works, you're done when it's right.

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Sanctum: major overhaul to particle world
« Reply #1 on: October 04, 2020, 06:01:06 pm »
Well I discovered a pyramid!
 
Pyramid making particles.PNG

Logged

Offline SpriggsySpriggs

  • Forum Resident
  • Posts: 1145
  • Larger than life
    • View Profile
    • GitHub
Re: Sanctum: major overhaul to particle world
« Reply #2 on: October 04, 2020, 08:58:09 pm »
Wow, that's neat!
Logged
Shuwatch!

FellippeHeitor

  • Guest
Re: Sanctum: major overhaul to particle world
« Reply #3 on: October 04, 2020, 09:54:00 pm »
You never fail to impress me with Sanctum. It's mind-blowing how much is packed into less than 2k lines. I'm blown away.

Also, with every reset there are new things to see?

BTW, been to hell and back.
Logged

Offline Richard Frost

  • Seasoned Forum Regular
  • Posts: 316
  • Needle nardle noo. - Peter Sellers
    • View Profile
Re: Sanctum: major overhaul to particle world
« Reply #4 on: October 04, 2020, 10:54:52 pm »
The gradual stop is a neat effect.  I believe it's faster than a previous
version I tried.

What I like most is the coding style - meaningful variable names, single blank
lines for spacing, and all the hats (new, unusual, vampire) in KeyProcess and
elsewhere.

Doubt I'll ever understand all the fancy math.
Logged
It works better if you plug it in.

Offline SierraKen

  • Forum Resident
  • Posts: 1454
    • View Profile
Re: Sanctum: major overhaul to particle world
« Reply #5 on: October 06, 2020, 03:26:59 pm »
This is awesome Static! I found a giant graveyard.

Logged
Pages: [1]   Go Up
« previous next »