Shadow over Mars

[bplus]

[banned user]'s spinning planet now with shadow added to make look spherical.

Code: QB64: [Select]

1. _TITLE "Planet Maker - Mars"
2. SCREEN _NEWIMAGE(500, 500, 32)
3.  
4. ' \/\/\/\/\/\/\/\/\/
5. ' Load texture image
6. ' /\/\/\/\/\/\/\/\/\
7. Texture = _LOADIMAGE(".\images\mars.png")
8.  
9. ' \/\/\/\/\/\/\/\/\/\/
10. ' Center of the screen
11. ' /\/\/\/\/\/\/\/\/\/\
12. DIM SHARED cw AS INTEGER
13. DIM SHARED ch AS INTEGER
14. cw = 250
15. ch = 250
16.  
17. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
18. ' Width and Height of the texture
19. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
20. w = 480
21. h = 480
22.  
23. ' \/\/\/\/\/\/\/\/\/\/\/\/\/
24. ' Location to put the images
25. ' /\/\/\/\/\/\/\/\/\/\/\/\/\
26. tx = cw - w \ 2
27. ty = ch - h \ 2
28.  
29. shaddow& = _NEWIMAGE(w, h)
30. _DEST shaddow&
31. COLOR _RGBA(10, 10, 10, 8)
32. FOR dx = 1 TO 200
33.     fcirc 250 + 200 + dx, 250, 250 + 2 * dx
34. NEXT
35.  
36. DIM Text AS STRING
37. Text = "Creating Mars planet.... "
38. lenText = LEN(Text)
39.  
40. ' \/\/\/\/\/\/
41. ' Mars images
42. ' /\/\/\/\/\/\
43. DIM SHARED Mars(w) AS LONG
44. FOR f = 1 TO w
45.     Mars(f) = _NEWIMAGE(w, h)
46. NEXT
47. ' \/\/\/\/\/\/\/\/\/
48. ' Start with frame 1
49. ' /\/\/\/\/\/\/\/\/\
50. frames = 1
51.  
52. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
53. ' Scroll the texture the width of the texture
54. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
55. FOR x = 0 TO w - 1
56.     _DEST 0
57.     _PRINTSTRING (cw - 4 * lenText, ch - 8), Text
58.     Text = RIGHT$(Text, lenText - 1) + LEFT$(Text, 1)
59.  
60.     ' \/\/\/\/\/\/\/\/\/\/\/
61.     ' Draw to the Mars image
62.     ' /\/\/\/\/\/\/\/\/\/\/\
63.     _DEST Mars(frames)
64.  
65.     '_PUTIMAGE (tx, ty), Texture, , (x, 0)-(w, h)
66.     '_PUTIMAGE (tx + w - x, ty), Texture, , (1, 0)-(x, h)
67.     _PUTIMAGE (0, 0), Texture, , (x, 0)-(w, h)
68.     _PUTIMAGE (w - x, 0), Texture, , (1, 0)-(x, h)
69.     _PUTIMAGE , shaddow&, Mars(frames)
70.     ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/
71.     ' Remove all extra image data from outside the circle
72.     ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\/\
73.     FOR r = 241 TO 341 STEP 0.05
74.         CIRCLE (240, 240), r, _RGB(0, 0, 0)
75.     NEXT
76.  
77.     ' \/\/\/\/\/\/\/\/\/\/
78.     ' Increase frame count
79.     ' /\/\/\/\/\/\/\/\/\/\
80.     frames = frames + 1
81. NEXT
82.  
83. ' \/\/\/\/\/\/\/\/\/\/\/\/\/
84. ' Set destination to screen
85. ' /\/\/\/\/\/\/\/\/\/\/\/\/\
86. _DEST 0
87.  
88. ' \/\/\/\/\/\/\/\/
89. ' Erase the screen
90. ' /\/\/\/\/\/\/\/\
91. LINE (0, 0)-(800, 600), _RGB(0, 0, 0), BF
92.  
93. ' \/\/\/\/\/\/\/\/\/\/\/\/\/\/
94. ' Repeat until ESC is pressed
95. ' /\/\/\/\/\/\/\/\/\/\/\/\/\/\
96. WHILE INKEY$ <> CHR$(27)
97.  
98.     ' \/\/\/\/\/\/\/\/\/\/
99.     ' Show the planet Mars
100.     ' /\/\/\/\/\/\/\/\/\/\
101.     FOR f = 1 TO frames - 1
102.         _PUTIMAGE (tx, ty), Mars(f), 0
103.         _DISPLAY
104.         _LIMIT 30
105.     NEXT
106. WEND
107.  
108. 'Steve McNeil's  copied from his forum   note: Radius is too common a name
109. SUB fcirc (CX AS LONG, CY AS LONG, R AS LONG)
110.     DIM subRadius AS LONG, RadiusError AS LONG
111.     DIM X AS LONG, Y AS LONG
112.  
113.     subRadius = ABS(R)
114.     RadiusError = -subRadius
115.     X = subRadius
116.     Y = 0
117.  
118.     IF subRadius = 0 THEN PSET (CX, CY): EXIT SUB
119.  
120.     ' Draw the middle span here so we don't draw it twice in the main loop,
121.     ' which would be a problem with blending turned on.
122.     LINE (CX - X, CY)-(CX + X, CY), , BF
123.  
124.     WHILE X > Y
125.         RadiusError = RadiusError + Y * 2 + 1
126.         IF RadiusError >= 0 THEN
127.             IF X <> Y + 1 THEN
128.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), , BF
129.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), , BF
130.             END IF
131.             X = X - 1
132.             RadiusError = RadiusError - X * 2
133.         END IF
134.         Y = Y + 1
135.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), , BF
136.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), , BF
137.     WEND
138. END SUB
139.  
140.