IN/ Out triangle: Help!

[TempodiBasic]

Hi guys
I have this trouble...
I have found a geometric formula to evaluate the position of a P point towards the ABC plane of a triangle using the centroid...
here the reference  https://en.wikipedia.org/wiki/Centroid#Of_a_triangle

Let ABC be a triangle, let G be its centroid, and let D, E, and F be the midpoints of BC, CA, and AB, respectively. For any point P in the plane of ABC then PA+PB+PC <= 2*(PD+PE+PF)+3*PG

Please I am not able to catch the mistake
here the code.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. SCREEN _NEWIMAGE(800, 600, 32)
4. DO: LOOP UNTIL _SCREENEXISTS
5. _TITLE "In or Out the triangle?"
6. _SCREENMOVE 10, 10
7. RANDOMIZE TIMER
8. TYPE point
9.     x AS INTEGER
10.     y AS INTEGER
11. END TYPE
12.  
13. CONST True = -1, False = NOT True
14. DIM SHARED P(1 TO 8) AS point ' 3 vertex 3 medium points 1 centroid 1 point P to test
15. WINDOW SCREEN(0, 0)-(799, 599)
16. DIM a AS INTEGER, b AS INTEGER, c AS STRING
17. Initialize
18. DO
19.     ' it gets input
20.     DO: LOOP UNTIL NOT _MOUSEINPUT
21.     a = _MOUSEBUTTON(1)
22.     b = _MOUSEBUTTON(2)
23.     P(4).x = _MOUSEX: P(4).y = _MOUSEY
24.     c = INKEY$
25.     ' output to screen
26.     CLS
27.     makeImage
28.     ' calculations
29.     IF IsInner THEN _PRINTSTRING (10, 30), " Point is inner to triangle" ELSE _PRINTSTRING (10, 10), " Point is outer to triangle"
30.     IF c = CHR$(13) XOR a THEN Initialize
31.     ' it slows pc
32.     _DISPLAY
33.     _LIMIT 10
34. LOOP UNTIL c = " " OR b = True
35. END
36.  
37. FUNCTION IsInner
38.     'PA+PB+PC <= 2*(PD+PE+PF)+3*PG
39.     IF (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))) <= 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8))) THEN IsInner = True ELSE IsInner = False
40.  
41.     ' debug output
42.     PRINT (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))) <= 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8))); " ";
43.     PRINT (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))), 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8)))
44. END FUNCTION
45.  
46. FUNCTION Distance (P1 AS point, P2 AS point)
47.     ' in a Carthesian grid the distance between P1 and P2
48.     'is the hypotenuse of the triangle rectangle of the 2 cohordinates
49.     Distance = SQR(((P1.x - P2.x)) ^ 2 + ((P1.y - P2.y)) ^ 2)
50. END FUNCTION
51.  
52. SUB makeImage
53.     DIM a AS INTEGER
54.     COLOR _RGB32(255)
55.     ' graphic cursor starts at last vertex of triangle
56.     PSET (P(3).x, P(3).y)
57.     FOR a = 1 TO 3 STEP 1 ' vertexs
58.         LINE -(P(a).x, P(a).y)
59.     NEXT
60.  
61.     ' using little circle points are more visible
62.     ' PSET
63.     CIRCLE (P(4).x, P(4).y), 3, _RGB32(255, 0, 0) ' point to test
64.     ' PSET
65.     CIRCLE (P(5).x, P(5).y), 3, _RGB32(0, 0, 255) ' centroid
66.     'PSET
67.     CIRCLE (P(6).x, P(6).y), 3, _RGB32(0, 255, 0) 'midpoints
68.     ' PSET
69.     CIRCLE (P(7).x, P(7).y), 3, _RGB32(0, 255, 200)
70.     '    PSET
71.     CIRCLE (P(8).x, P(8).y), 3, _RGB32(200, 255, 0)
72. END SUB
73.  
74. SUB Initialize
75.     DIM a AS INTEGER
76.     ' it creates at random 3 vertex and point P to test inner/outer triangle
77.     FOR a = 1 TO 4 STEP 1
78.         P(a).x = 1 + RND * 780
79.         P(a).y = 1 + RND * 580
80.     NEXT
81.     ' it calculates centroid
82.     P(5).x = (P(1).x + P(2).x + P(3).x) / 3
83.     P(5).y = (P(1).y + P(2).y + P(3).y) / 3
84.  
85.     'it calculates midpoints DEF
86.     P(6).x = (P(1).x + P(2).x) / 2
87.     P(6).y = (P(1).y + P(2).y) / 2
88.     P(7).x = (P(3).x + P(2).x) / 2
89.     P(7).y = (P(3).y + P(2).y) / 2
90.     P(8).x = (P(1).x + P(3).x) / 2
91.     P(8).y = (P(1).y + P(3).y) / 2
92. END SUB

all point are at the right place but the function always returns true nevertheless the P point is put by mouse.

you can change triangle with enter key or left click of mouse, you can quit with space key or right click of mouse

Thanks to help

[bplus]

Looks like it is set up OK but

Let ABC be a triangle, let G be its centroid, and let D, E, and F be the midpoints of BC, CA, and AB, respectively. For any point P in the plane of ABC then PA+PB+PC <= 2*(PD+PE+PF)+3*PG

I could not find this quote in the Wiki you referenced to judge the context. The quote comes at very end.

This looks more like finding points on the same plane, "in the plane of ABC", as the triangle NOT in the interior of the triangle. In which case your exercise being all on same plane to start would return true always.

[STxAxTIC]

Wait, didn't we just spend a week on this question and solve it multiple ways?

[bplus]

Wait, didn't we just spend a week on this question and solve it multiple ways?

Slightly different if this test is for Coplanar points to triangle.

Yes I was going to test 3D version of this with your problem code but I don't know if the 2 points not Interior might still be coplanar, what are the odds? Oh just points of cube that contains the triangle we know those arent coplanar.

[STxAxTIC]

Meh you guys aren't reading my pdf, I solved both

[bplus]

Meh you guys aren't reading my pdf, I solved both

So does your PDF say if this:
PA+PB+PC <= 2*(PD+PE+PF)+3*PG

is a test for Coplanar Points of Triangle ABC with DEF midpoints of ABC segments and G the Centroid Pt

or is it a test for points Interior (and Coplanar) of triangle ABC?

[STxAxTIC]

It's not news that I use vector notation, so no, the thing you cite isn't part of my write-up on the grounds that I didn't need it. I have two explicit calculations for coplanarity and containment as separate concerns. Obviously one encloses the other...

If I could use the proper notation on forums I would just 'splain it but no freebie this time

[TempodiBasic]

Thanks Bplus
for the perspective that you bring. Rightly you stress that it talks about the plane of ABC... but with a 2D entities (the points: vertexs of triangles, centroid, middlepoints of sides of triangle and P poit to test) how can I  produce a P point external to the 2D plane in which the triangle is already?
This is the thought that let me use that formula to test if P point is out o in to the triangle.
 

So I'll give a try with the other formula

PA^2+PB^2+PC^2 = GA^2+GB^2+GC^2+3(PG^2)

Waiting more info I thank you for your time spent to answer me

[bplus]

Waiting more info I thank you for your time spent to answer me

Just a little more wait, just got back from lunch and testing Spriggsy's help for FileDialog.

I have reworked your code a little to make it easier to read and hope to use it with code I worked on yesterday for STx 3D problem.

If I say, "It shouldn't take long", I will curse myself! ;-))  Excellent drawing BTW!

[bplus]

@TempodiBasic

Well in 3D there is still no relief from returning -1 for True

Code: QB64: [Select]

1. _TITLE "Checking TempodiBasic formula for Coplanar Points"
2. ' 2020-06-23 ref:  https://www.qb64.org/forum/index.php?topic=2745.0
3.  
4. SCREEN _NEWIMAGE(1000, 600, 32)
5. _DELAY .25 'allow time to load before moving
6. _SCREENMOVE _MIDDLE
7.  
8. DEFDBL A-Z
9. TYPE xyz
10.     x AS DOUBLE
11.     y AS DOUBLE
12.     z AS DOUBLE
13. END TYPE
14.  
15. 'given 3d tri
16. '(1,1,0)
17. '(1,0,1)
18. '(0,1,1)
19. DIM SHARED tri(2) AS xyz ' This turns out to be Equilateral triangle from my experiments of getting 3D angles
20. tri(0).x = 1: tri(0).y = 1: tri(0).z = 0
21. tri(1).x = 1: tri(1).y = 0: tri(1).z = 1
22. tri(2).x = 0: tri(2).y = 1: tri(2).z = 1
23.  
24. 'given test cases   6 points in 3d tri or not? 2 are made up the remaider are in which is which?
25. '(.66,.66,.66)
26. '(.46,.66,.86)
27. '(.83,.89,.26)
28. '(.55,.55,.55)
29. '(.75,.79,.46)
30. '(.79,.89,.66)
31. DIM test(5) AS xyz
32. test(0).x = .66: test(0).y = .66: test(0).z = .66 'on/in
33. test(1).x = .46: test(1).y = .66: test(1).z = .86
34. test(2).x = .83: test(2).y = .89: test(2).z = .26
35. test(3).x = 100: test(3).y = -100: test(3).z = 100 '
36. test(4).x = .75: test(4).y = .79: test(4).z = .46
37. test(5).x = 0: test(5).y = 0: test(5).z = 0 '
38.  
39. DIM SHARED P(1 TO 8) AS xyz, TF
40. Initialize
41. FOR i = 0 TO 5 'test points to Stx triangle, we know 4 are inside of triangle so MUST also be Coplanar
42.     P(4).x = test(i).x: P(4).y = test(i).y: P(4).z = test(i).z
43.     TF = IsInner
44.     PRINT "For test point"; i; " IsInner test returned"; TF
45.     PRINT
46. NEXT
47. PRINT "Number 3 and 5 should not be true"
48. FUNCTION dist3D (p1 AS xyz, p2 AS xyz)
49.     dist3D = SQR((p1.x - p2.x) ^ 2 + (p1.y - p2.y) ^ 2 + (p1.z - p2.z) ^ 2)
50. END FUNCTION
51.  
52.  
53. SUB Initialize
54.     DIM i AS INTEGER
55.     PRINT "Initializing"
56.     ' using STx known triangle and test points already tested
57.     FOR i = 1 TO 3 STEP 1
58.         P(i).x = tri(i - 1).x
59.         P(i).y = tri(i - 1).y
60.         P(i).z = tri(i - 1).z
61.         PRINT P(i).x, P(i).y, P(i).z
62.     NEXT
63.     PRINT "Centroid"
64.  
65.     ' it calculates centroid
66.     P(5).x = (P(1).x + P(2).x + P(3).x) / 3
67.     P(5).y = (P(1).y + P(2).y + P(3).y) / 3
68.     P(5).z = (P(1).z + P(2).z + P(3).z) / 3
69.     PRINT P(5).x, P(5).y, P(5).z
70.     PRINT "Mid-points"
71.     'it calculates midpoints DEF
72.     P(6).x = (P(1).x + P(2).x) / 2
73.     P(6).y = (P(1).y + P(2).y) / 2
74.     P(6).z = (P(1).z + P(2).z) / 2
75.     PRINT P(6).x, P(6).y, P(6).z
76.  
77.     P(7).x = (P(3).x + P(2).x) / 2
78.     P(7).y = (P(3).y + P(2).y) / 2
79.     P(7).z = (P(3).z + P(2).z) / 2
80.     PRINT P(7).x, P(7).y, P(7).z
81.  
82.     P(8).x = (P(1).x + P(3).x) / 2
83.     P(8).y = (P(1).y + P(3).y) / 2
84.     P(8).z = (P(1).z + P(3).z) / 2
85.     PRINT P(8).x, P(8).y, P(8).z
86.     PRINT
87. END SUB
88.  
89. FUNCTION IsInner
90.     'PA+PB+PC <= 2*(PD+PE+PF)+3*PG
91.     DIM PA, PB, PC, PD, PE, PF, PG
92.     PA = dist3D(P(4), P(1)): PB = dist3D(P(4), P(2)): PC = dist3D(P(4), P(3))
93.     PD = dist3D(P(4), P(6)): PE = dist3D(P(4), P(7)): PF = dist3D(P(4), P(8))
94.     PG = dist3D(P(4), P(5))
95.     IF PA + PB + PC <= 2 * (PD + PE + PF) + 3 * PG THEN IsInner = -1
96.     PRINT PA + PB + PC, 2 * (PD + PE + PF) + 3 * PG
97.  
98.     'IF (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))) <= 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8))) THEN IsInner = True ELSE IsInner = False
99.  
100.     ' debug output
101.     'PRINT (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))) <= 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8))); " ";
102.     'PRINT (Distance(P(4), P(1)) + Distance(P(4), P(2)) + Distance(P(4), P(3))), 3 * Distance(P(4), P(5)) + 2 * (Distance(P(4), P(6)) + Distance(P(4), P(7)) + Distance(P(4), P(8)))
103. END FUNCTION
104.  
105.  
106.  

Sorry I don't understand the "Inner" formula better to say what our difficulty is.

EDIT: Dang forgot to call Initialize! still didn't help :(

[bplus]

@TempodiBasic

If you start with your drawing here:
https://www.qb64.org/forum/index.php?topic=2727.msg119597#msg119597
and remove all the mid points and lines to them, you will have a tetrahedron (3 sided pyramid). If the areas of the 3 triangles from P = the area of the base triangle then the tetrahedron is flat and P is Coplanar to ABC and inside or on triangle ABC.


Compare the Sum of the areas of 3 triangles from point P to the area of Triangle ABC, will check if P is is inside on same plane as ABC, if P were higher or lower or outside Triangle ABC then the Sum of the areas of 3 Triangles from P to the 3 sides of Triangle ABC would be greater than the area of ABC.
 
We did this here on Father's Day:
https://www.qb64.org/forum/index.php?topic=2727.msg119597#msg119597

[bplus]

Bing Search from new Edge: (that my browser couldn't find using Google)
https://www.mat.uniroma2.it/~tauraso/AMM/AMM12015.pdf

This IS the article referenced in Wiki about the formula.

I don't know any other way to interpret |AB| other than always positive distance between 2 Points.

Maybe the paper is wrong, TempodiBasic you are good at finding bugs, are you an entomologist? ;-))

[codeguy]

if the slope is the same between any two points of the triangle and a point of the triangle and the point in question, it's coplanar. You may need a tolerance of .001 or so because digital division isn't always precise.

[TempodiBasic]

@bplus

yes your research is very accurate.  So in the original article there is the 3rd dimension! And it solves the question of why the author says plane of triangle ABC!

about the other formula this is the reference: https://www.isinj.com/mt-usamo/An%20Introduction%20to%20the%20Modern%20Geometry%20of%20the%20Triangle%20and%20the%20Circle%20-%20Altshiller-Court%20N.%20College%20Geometry%20(Dover%202007).pdf
at page 70 of book (89 of pdf file) theorem 109.

Let P be any point in the plane of a triangle with vertices A, B, and C and centroid G. Then the sum of the squared distances of P from the three vertices exceeds the sum of the squared distances of the centroid G from the vertices by three times the squared distance between P and G:

....Nope  it seems that the 3rd dimension comes out always!

now I'll try with this assumption

A triangle's centroid is the point that maximizes the product of the directed distances of a point from the triangle's sidelines

reference: triangle's centroid is the point that maximizes the product of the directed distances of a point from the triangle's sidelines
see later

[bplus]

Yes it looks like we are talking about 2D Triangles on same plane in both references.

The equation you point to in Geometry book is talking about Centroids alright, but they are not talking inside / outside of triangle let alone a plane.

That book looks interesting though, I will skim through it.