How do I make collision work between the player and the level?

[Mudkip In Disguise]

I am trying to make a game where the player walks through rooms.
I can't figure out how to prevent the player from walking through the walls.
Move with WASD
if the screen is black when ran, press WASD

***Here is the code***

Code: QB64: [Select]

1. SCREEN 13
2. _FULLSCREEN
3. 'COLOR VARIBLES AND STUFF
4. MAPX = 15
5. MAPY = 15
6. PC = 7
7. SC = 8
8. FC = 6
9. CC = 4
10. x = 3
11. y = 3
12. DO
13.     'This makes the map
14.     jail:
15.     DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
16.     DATA 1,0,0,0,1,0,0,0,1,0,0,0,0,0,0,2
17.     DATA 1,0,0,0,1,0,0,0,1,0,0,0,0,0,0,1
18.     DATA 1,0,0,0,1,0,0,0,1,1,1,1,1,0,1,1
19.     DATA 1,3,0,3,1,3,3,3,1,0,0,0,0,0,0,1
20.     DATA 1,0,0,0,0,0,0,0,1,0,1,1,1,1,1,1
21.     DATA 1,0,0,0,0,0,0,0,1,0,0,0,0,0,0,1
22.     DATA 1,1,1,1,1,1,2,1,1,1,1,1,0,1,1,1
23.     DATA 1,0,0,0,0,0,0,0,1,0,0,0,0,1,0,1
24.     DATA 1,0,0,0,0,0,0,0,1,0,1,1,1,1,0,1
25.     DATA 1,0,0,0,0,0,0,0,2,0,0,0,0,0,0,1
26.     DATA 1,1,1,1,1,1,2,1,1,1,1,1,1,1,1,1
27.     DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
28.     DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
29.     DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
30.     DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
31.  
32.     'KEYPRESSES
33.     PRINT MID$(PSCANY$, y - 1, y - 1)
34.     K$ = LCASE$(INKEY$)
35.     IF K$ = "w" THEN
36.         y = y - 1: u = 1
37.         IF a = y AND u = 1 AND num = 1 THEN
38.             y = y + 1
39.         END IF
40.     END IF
41.     IF K$ = "s" THEN
42.         y = y + 1: d = 1
43.         IF a = y AND d = 1 AND num = 1 THEN
44.             y = y - 1
45.             d = 0
46.         END IF
47.     END IF
48.     IF K$ = "a" THEN x = x - 1: l = 1
49.     IF K$ = "d" THEN x = x + 1: r = 1
50.     IF K$ = "w" OR K$ = "s" OR K$ = "a" OR K$ = "d" THEN
51.         'RENDER/UPDATE ROOM WHEN MOVEMENT IS DETECTED
52.         PLAY "MB O1 GL64"
53.         RESTORE jail:
54.         DIM room(15, 15)
55.         FOR a = 0 TO MAPX
56.             FOR b = 0 TO MAPY
57.                 READ room
58.                 num = room
59.                 IF num = 0 THEN
60.                     LOCATE a + 1, b + 1
61.                     COLOR CC, FC
62.                     PRINT "_"
63.  
64.  
65.                 END IF
66.  
67.                 IF num = 1 THEN
68.                     LOCATE a + 1, b + 1
69.                     COLOR PC, SC
70.                     PRINT "°"
71.                 END IF
72.  
73.                 IF num = 2 THEN
74.                     LOCATE a + 1, b + 1
75.                     COLOR 9, 12
76.                     PRINT ""
77.  
78.  
79.                 END IF
80.                 IF num = 3 THEN
81.                     LOCATE a + 1, b + 1
82.                     COLOR 3, FC
83.                     PRINT "Ñ"
84.  
85.  
86.                 END IF
87.                 u = 0
88.  
89.  
90.                 LOCATE 20, 10
91.             NEXT b
92.  
93.         NEXT a
94.  
95.         'DRAW PLAYER
96.         LOCATE y, x
97.         COLOR 14, 0
98.         PRINT ""
99.         _DISPLAY
100.         CLS
101.  
102.  
103.     END IF
104. LOOP
105.  

[TerryRitchie]

This is just a quick hack to show you the use of using an array to hold your map level in. With the changes I made to your code everything is managed within the array.

(I had to change the code, this is the second change. You had ASCII characters embedded using the ALT123 method which was causing havoc with the code box)

Code: QB64: [Select]

1. TYPE ROOMS '                each room in level
2.     fcolor AS INTEGER '     foreground color
3.     bcolor AS INTEGER '     background color
4.     char AS STRING * 1 '    room character
5. END TYPE
6.  
7. SCREEN 13
8. '_FULLSCREEN
9. 'COLOR VARIBLES AND STUFF
10. MAPX = 15
11. MAPY = 15
12. PC = 7
13. SC = 8
14. FC = 6
15. CC = 4
16.  
17. '** Create the level
18.  
19. DIM Map(MAPX, MAPY) AS ROOMS '              create 2D array to hold the level full of rooms
20. FOR y = 0 TO MAPY '                         cycle horizontally
21.     FOR x = 0 TO MAPX '                     cycle vertically
22.         READ room '                         read in the next room
23.         SELECT CASE room '                  which room is it?
24.             CASE 0 '                        room type 0
25.                 Map(x, y).fcolor = CC '     set characteristics of this room
26.                 Map(x, y).bcolor = FC
27.                 Map(x, y).char = "_"
28.             CASE 1 '                        room type 1
29.                 Map(x, y).fcolor = PC
30.                 Map(x, y).bcolor = SC
31.                 Map(x, y).char = CHR$(176)
32.             CASE 2 '                        room type 2
33.                 Map(x, y).fcolor = 9
34.                 Map(x, y).bcolor = 12
35.                 Map(x, y).char = CHR$(8)
36.             CASE 3 '                        room type 3
37.                 Map(x, y).fcolor = 3
38.                 Map(x, y).bcolor = FC
39.                 Map(x, y).char = CHR$(209)
40.         END SELECT
41.     NEXT x
42. NEXT y
43.  
44. x = 2 '  character location
45. y = 2
46. px = 2 ' previous character location
47. py = 2
48.  
49. DO
50.     _LIMIT 30 ' 30 frames per second (don't want to hog CPU)
51.     CLS
52.  
53.     'KEYPRESSES
54.     PRINT MID$(PSCANY$, y - 1, y - 1)
55.     K$ = LCASE$(INKEY$)
56.  
57.     px = x
58.     py = y
59.  
60.     IF K$ = "w" AND Map(x, y - 1).char = "_" THEN
61.         y = y - 1
62.     END IF
63.     IF K$ = "s" AND Map(x, y + 1).char = "_" THEN
64.         y = y + 1
65.     END IF
66.     IF K$ = "a" AND Map(x - 1, y).char = "_" THEN
67.         x = x - 1
68.     END IF
69.     IF K$ = "d" AND Map(x + 1, y).char = "_" THEN
70.         x = x + 1
71.     END IF
72.  
73.     Map(px, py).char = "_"
74.     Map(x, y).char = CHR$(2)
75.  
76.     IF K$ = "w" OR K$ = "s" OR K$ = "a" OR K$ = "d" THEN
77.         'RENDER/UPDATE ROOM WHEN MOVEMENT IS DETECTED
78.         PLAY "MB O1 GL64"
79.  
80.         '** draw the level
81.  
82.         FOR b = 0 TO MAPY
83.             FOR a = 0 TO MAPX
84.                 IF Map(a, b).char = CHR$(2) THEN
85.                     COLOR 14, 0
86.                 ELSE
87.                     COLOR Map(a, b).fcolor, Map(a, b).bcolor
88.                 END IF
89.                 PRINT Map(a, b).char;
90.             NEXT a
91.             PRINT
92.         NEXT b
93.  
94.         _DISPLAY
95.  
96.     END IF
97. LOOP
98.  
99. DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
100. DATA 1,0,0,0,1,0,0,0,1,0,0,0,0,0,0,2
101. DATA 1,0,0,0,1,0,0,0,1,0,0,0,0,0,0,1
102. DATA 1,0,0,0,1,0,0,0,1,1,1,1,1,0,1,1
103. DATA 1,3,0,3,1,3,3,3,1,0,0,0,0,0,0,1
104. DATA 1,0,0,0,0,0,0,0,1,0,1,1,1,1,1,1
105. DATA 1,0,0,0,0,0,0,0,1,0,0,0,0,0,0,1
106. DATA 1,1,1,1,1,1,2,1,1,1,1,1,0,1,1,1
107. DATA 1,0,0,0,0,0,0,0,1,0,0,0,0,1,0,1
108. DATA 1,0,0,0,0,0,0,0,1,0,1,1,1,1,0,1
109. DATA 1,0,0,0,0,0,0,0,2,0,0,0,0,0,0,1
110. DATA 1,1,1,1,1,1,2,1,1,1,1,1,1,1,1,1
111. DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
112. DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
113. DATA 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,1
114. DATA 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
115.  

[Mudkip In Disguise]

Thank you!

[TerryRitchie]

Thank you!

You're welcome :-)  If you would like a more thorough explanation of what I did I can post that. I'm busy with a home project right now and during a break saw your post and responded.

[Mudkip In Disguise]

This looks very interesting. I would like to see a bit of an in-depth explanation about how this works.