3d_model_viewer by Galleon

[Qwerkey]

3d_model_viewer

Author: @Galleon
Source: QB64 Folder (/programs/samples/open_gl/3d_model_viewer.bas)
URL: N/A
Version: 1
Tags: [3D], [Graphics], [Open_GL], [Demonstration]

Description:
Librarian's note: This demonstration by Galleon comes with the QB64 install, but is given here as an excellent demonstration of what Open_GL can do.

Note: If you have the Run Option “Output Exe to Source Folder” checked, you will need to comment out the first line.  The code given here is for reference only.  Load the .bas file from the given folder.

Controls:
Mouse and wheel
1 / 2 / 3 to change rendering order
A / B / C to change displayed image

Source Code:

Code: QB64: [Select]

1. CHDIR "programs\samples\open_gl"
2.  
3. ' This example shows how models with textures or materials can be displayed with OpenGL using QB64
4. '
5. 'IMPORTANT:
6. ' Whilst the .X file loader is optimized for speed, it is very incomplete:
7. '  -only .X files in text file format
8. '  -only one object, not a cluster of objects
9. '  -if using a texture, use a single texture which will be applied to all materials
10. '  -all the 3D models in this example were exported from Blender, a free 3D creation tool
11. '   Blender tips: CTRL+J to amalgamate objects, select object to export first, in the UV/image-editor
12. '                 window you can export the textures built into your .blend file, apply the decimate
13. '                 modifier to reduce your polygon count to below 10000, preferably ~3000 or less
14. ' This program is not a definitive guide to OpenGL in any way
15. ' The GLH functions are something I threw together to stop people crashing their code by making
16. '  calls to OpenGL with incorrectly sized memory regions. The GLH... prefixed commands are not mandatory or
17. '  part of QB64, nor do they represent a complete library of helper commands.
18. ' Lighting is not this example's strongest point, there's probably some work to do on light positioning
19. '  and vertex normals
20. '
21. 'Finally, I hope you enjoy this program as much as I enjoyed piecing it together,
22. ' Galleon
23.  
24. '###################################### GLH SETUP #############################################
25.  
26. 'Used to manage textures
27. TYPE DONT_USE_GLH_Handle_TYPE
28.     in_use AS _BYTE
29.     handle AS LONG
30. END TYPE
31.  
32. 'Used by GLH RGB/etc helper functions
33. DIM SHARED DONT_USE_GLH_COL_RGBA(1 TO 4) AS SINGLE
34.  
35. REDIM SHARED DONT_USE_GLH_Handle(1000) AS DONT_USE_GLH_Handle_TYPE
36.  
37. '.X Format Model Loading Data
38. TYPE VERTEX_TYPE
39.     X AS DOUBLE
40.     Y AS DOUBLE
41.     Z AS DOUBLE
42.     NX AS DOUBLE
43.     NY AS DOUBLE
44.     NZ AS DOUBLE
45. END TYPE
46. REDIM SHARED VERTEX(1) AS VERTEX_TYPE
47. DIM SHARED VERTICES AS LONG
48. TYPE FACE_CORNER_TYPE
49.     V AS LONG 'the vertex index
50.     TX AS SINGLE 'texture X coordinate
51.     TY AS SINGLE 'texture Y coordinate
52. END TYPE
53. TYPE FACE_TYPE
54.     V1 AS FACE_CORNER_TYPE
55.     V2 AS FACE_CORNER_TYPE
56.     V3 AS FACE_CORNER_TYPE
57.     Material AS LONG
58.     Index AS LONG
59. END TYPE
60. REDIM SHARED FACE(1) AS FACE_TYPE
61. DIM SHARED FACES AS LONG
62. TYPE MATERIAL_RGBAI_TYPE
63.     R AS SINGLE
64.     G AS SINGLE
65.     B AS SINGLE
66.     A AS SINGLE
67.     Intensity AS SINGLE
68. END TYPE
69. TYPE MATERIAL_TYPE
70.     Diffuse AS MATERIAL_RGBAI_TYPE 'regular col
71.     Specular AS MATERIAL_RGBAI_TYPE 'hightlight/shine col
72.     Texture_Image AS LONG 'both an image and a texture handle are held
73.     Texture AS LONG 'if 0, there is no texture
74. END TYPE
75. REDIM SHARED MATERIAL(1) AS MATERIAL_TYPE
76. DIM SHARED MATERIALS AS LONG
77.  
78. '##############################################################################################
79.  
80. DIM SHARED AllowSubGL
81.  
82. SCREEN _NEWIMAGE(1024, 768, 32)
83.  
84. backdrop = _LOADIMAGE("backdrop_tron.png")
85.  
86. DIM SHARED rot1
87. DIM SHARED rot2, rot3
88. DIM SHARED scale: scale = 1
89.  
90. 'Load (default) model
91. GLH_Load_Model_Format_X "marty.x", "marty_tmap.png"
92. 'draw backdrop
93. _PUTIMAGE , backdrop: _DONTBLEND: LINE (200, 200)-(500, 500), _RGBA(0, 255, 255, 0), BF: _BLEND
94.  
95. AllowSubGL = 1
96.  
97. DO
98.     'This is our program's main loop
99.     _LIMIT 100
100.     LOCATE 1, 1
101.     PRINT "Mouse Input:"
102.     PRINT "{Horizonal Movement}Spin"
103.     PRINT "{Vertical Movement}Flip"
104.     PRINT "{Wheel}Scale"
105.     PRINT
106.     PRINT "Keyboard comands:"
107.     PRINT "Switch rendering order: {1}GL behind, {2}GL on top, {3}GL only, good for speed"
108.     PRINT "Switch/Load model: {A}Zebra, {B}Pig, {C}Car"
109.  
110.     k$ = INKEY$
111.     IF k$ = "1" THEN _GLRENDER _BEHIND
112.     IF k$ = "2" THEN _GLRENDER _ONTOP
113.     IF k$ = "3" THEN _GLRENDER _ONLY
114.  
115.  
116.     PRINT "Angles:"; rot1, rot2, rot3
117.  
118.  
119.     IF UCASE$(k$) = "A" THEN
120.         AllowSubGL = 0
121.         GLH_Load_Model_Format_X "marty.x", "marty_tmap.png"
122.         _PUTIMAGE , backdrop: _DONTBLEND: LINE (200, 200)-(500, 500), _RGBA(0, 255, 255, 0), BF: _BLEND
123.         AllowSubGL = 1
124.     END IF
125.  
126.     IF UCASE$(k$) = "B" THEN
127.         AllowSubGL = 0
128.         GLH_Load_Model_Format_X "piggy_mini3.x", ""
129.         _PUTIMAGE , backdrop: _DONTBLEND: LINE (200, 200)-(500, 500), _RGBA(0, 255, 255, 0), BF: _BLEND
130.         AllowSubGL = 1
131.     END IF
132.  
133.     IF UCASE$(k$) = "C" THEN
134.         AllowSubGL = 0
135.         GLH_Load_Model_Format_X "gasprin.x", "gasprin_tmap.png"
136.         _PUTIMAGE , backdrop: _DONTBLEND: LINE (200, 200)-(500, 500), _RGBA(0, 255, 255, 0), BF: _BLEND
137.         AllowSubGL = 1
138.     END IF
139.  
140.     DO WHILE _MOUSEINPUT
141.         scale = scale * (1 - (_MOUSEWHEEL * .1))
142.         rot1 = _MOUSEX
143.         rot2 = _MOUSEY
144.     LOOP
145.  
146.     IF k$ = "." THEN rot3 = rot3 + 1
147.     IF k$ = "," THEN rot3 = rot3 - 1
148.  
149.  
150.  
151.  
152. LOOP UNTIL k$ = CHR$(27)
153. END
154.  
155. 'this specially named sub "_GL" is detected by QB64 and adds support for OpenGL commands
156. 'it is called automatically whenever the underlying software deems an update is possible
157. 'usually/ideally, this is in sync with your monitor's refresh rate
158. SUB _GL STATIC
159.     'STATIC was used above to make all variables in this sub maintain their values between calls to this sub
160.  
161.     IF AllowSubGL = 0 THEN EXIT SUB 'we aren't ready yet!
162.  
163.     'timing is everything, we don't know how fast the 3D renderer will call this sub to we use timers to smooth things out
164.     T# = TIMER(0.001)
165.     IF ETT# = 0 THEN ETT# = T#
166.     ET# = T# - ETT#
167.     ETT# = T#
168.  
169.     IF sub_gl_called = 0 THEN
170.         sub_gl_called = 1 'we only need to perform the following code once
171.         '...
172.     END IF
173.  
174.     'These settings affect how OpenGL will render our content
175.     '!!! THESE SETTINGS ARE TO SHOW HOW ALPHA CAN WORK, BUT IT IS 10x FASTER WHEN ALPHA OPTIONS ARE DISABLED !!!
176.     '*** every setting must be reset because SUB _GL cannot guarantee settings have not changed since last time ***
177.     _glMatrixMode _GL_PROJECTION 'Select The Projection Matrix
178.     _glLoadIdentity 'Reset The Projection Matrix
179.     _gluPerspective 45, _WIDTH(0) / _HEIGHT(0), 1, 100 'QB64 internally supports this GLU command for convenience sake, but does not support GLU
180.     _glEnable _GL_TEXTURE_2D
181.     _glEnable _GL_BLEND
182.     _glBlendFunc _GL_SRC_ALPHA, _GL_ONE_MINUS_SRC_ALPHA 'how alpha values are interpretted
183.     _glEnable _GL_DEPTH_TEST 'use the zbuffer
184.     _glDepthMask _GL_TRUE
185.     _glAlphaFunc _GL_GREATER, 0.5 'dont do anything if alpha isn't greater than 0.5 (or 128)
186.     _glEnable _GL_ALPHA_TEST
187.     _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_LINEAR
188.     _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_LINEAR
189.     '**************************************************************************************************************
190.  
191.     _glMatrixMode _GL_MODELVIEW 'Select The Modelview Matrix
192.     _glLoadIdentity 'Reset The Modelview Matrix
193.  
194.  
195.  
196.     'setup our light
197.     _glEnable _GL_LIGHTING
198.     _glEnable _GL_LIGHT0
199.     _glLightfv _GL_LIGHT0, _GL_DIFFUSE, GLH_RGB(.8, .8, .8)
200.     _glLightfv _GL_LIGHT0, _GL_AMBIENT, GLH_RGB(0.1, 0.1, 0.1)
201.     _glLightfv _GL_LIGHT0, _GL_SPECULAR, GLH_RGB(0.3, 0.3, 0.3)
202.  
203.     light_rot = light_rot + ET#
204.     _glLightfv _GL_LIGHT0, _GL_POSITION, GLH_RGBA(SIN(light_rot) * 20, COS(light_rot) * 20, 20, 1)
205.  
206.  
207.     _glTranslatef 0, 0, -20 'Translate Into The Screen
208.     _glRotatef rot1, 0, 1, 0
209.     _glRotatef rot2, 1, 0, 0
210.     _glRotatef rot3, 0, 0, 1
211.  
212.  
213.  
214.     current_m = -1
215.     FOR F = 1 TO FACES
216.  
217.         m = FACE(F).Material
218.         IF m <> current_m THEN 'we don't switch materials unless we have to
219.             IF current_m <> -1 THEN _glEnd 'stop rendering triangles so we can change some settings
220.             current_m = m
221.             IF MATERIAL(m).Texture_Image THEN
222.  
223.                 _glEnable _GL_TEXTURE_2D
224.                 _glDisable _GL_COLOR_MATERIAL
225.                 _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_LINEAR 'seems these need to be respecified
226.                 _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_LINEAR
227.  
228.  
229.                 IF MATERIAL(m).Texture = 0 THEN
230.                     MATERIAL(m).Texture = GLH_Image_to_Texture(MATERIAL(m).Texture_Image)
231.                 END IF
232.                 GLH_Select_Texture MATERIAL(m).Texture
233.  
234.                 _glMaterialfv _GL_FRONT, _GL_DIFFUSE, GLH_RGBA(1, 1, 1, 1)
235.  
236.             ELSE
237.                 'use materials, disable textures
238.                 _glDisable _GL_TEXTURE_2D
239.                 _glDisable _GL_COLOR_MATERIAL
240.  
241.                 mult = MATERIAL(m).Diffuse.Intensity 'otherwise known as "power"
242.                 r = MATERIAL(m).Diffuse.R * mult
243.                 g = MATERIAL(m).Diffuse.G * mult
244.                 b = MATERIAL(m).Diffuse.B * mult
245.                 '            _glColor3f r, g, b
246.                 _glMaterialfv _GL_FRONT, _GL_DIFFUSE, GLH_RGBA(r, g, b, 1)
247.  
248.                 mult = MATERIAL(m).Specular.Intensity
249.                 r = MATERIAL(m).Specular.R * mult
250.                 g = MATERIAL(m).Specular.G * mult
251.                 b = MATERIAL(m).Specular.B * mult
252.                 _glMaterialfv _GL_FRONT, _GL_SPECULAR, GLH_RGBA(r, g, b, 1)
253.  
254.             END IF
255.  
256.             _glBegin _GL_TRIANGLES
257.  
258.         END IF
259.  
260.         FOR s = 1 TO 3
261.  
262.             IF s = 1 THEN v = FACE(F).V1.V
263.             IF s = 2 THEN v = FACE(F).V2.V
264.             IF s = 3 THEN v = FACE(F).V3.V
265.             v = v + 1
266.  
267.             'vertex
268.             x = (VERTEX(v).X + 0) * scale
269.             y = (VERTEX(v).Y + 0) * scale
270.             z = (VERTEX(v).Z + 0) * scale
271.             'normal direction from vertex
272.             nx = VERTEX(v).NX: ny = VERTEX(v).NY: nz = VERTEX(v).NZ
273.  
274.  
275.             'corner's texture coordinates
276.             IF MATERIAL(m).Texture THEN
277.                 IF s = 1 THEN tx = FACE(F).V1.TX: ty = FACE(F).V1.TY
278.                 IF s = 2 THEN tx = FACE(F).V2.TX: ty = FACE(F).V2.TY
279.                 IF s = 3 THEN tx = FACE(F).V3.TX: ty = FACE(F).V3.TY
280.                 _glTexCoord2f tx, ty
281.             END IF
282.  
283.             _glNormal3d nx, my, nz
284.             _glVertex3f x, y, z
285.  
286.         NEXT
287.  
288.     NEXT
289.     _glEnd
290.  
291. END SUB
292.  
293.  
294.  
295. 'QB64 OPEN-GL HELPER MACROS (aka. GLH macros) #######################################################################
296.  
297. SUB GLH_Select_Texture (texture_handle AS LONG) 'turn an image handle into a texture handle
298.     IF texture_handle < 1 OR texture_handle > UBOUND(DONT_USE_GLH_HANDLE) THEN ERROR 258: EXIT FUNCTION
299.     IF DONT_USE_GLH_Handle(texture_handle).in_use = 0 THEN ERROR 258: EXIT FUNCTION
300.     _glBindTexture _GL_TEXTURE_2D, DONT_USE_GLH_Handle(texture_handle).handle
301. END SUB
302.  
303. FUNCTION GLH_Image_to_Texture (image_handle AS LONG) 'turn an image handle into a texture handle
304.     IF image_handle >= 0 THEN ERROR 258: EXIT FUNCTION 'don't allow screen pages
305.     DIM m AS _MEM
306.     m = _MEMIMAGE(image_handle)
307.     DIM h AS LONG
308.     h = DONT_USE_GLH_New_Texture_Handle
309.     GLH_Image_to_Texture = h
310.     _glBindTexture _GL_TEXTURE_2D, DONT_USE_GLH_Handle(h).handle
311.     _glTexImage2D _GL_TEXTURE_2D, 0, _GL_RGBA, _WIDTH(image_handle), _HEIGHT(image_handle), 0, &H80E1&&, _GL_UNSIGNED_BYTE, m.OFFSET
312.     _MEMFREE m
313. END FUNCTION
314.  
315. FUNCTION DONT_USE_GLH_New_Texture_Handle
316.     handle&& = 0
317.     _glGenTextures 1, _OFFSET(handle&&)
318.     DONT_USE_GLH_New_Texture_Handle = handle&&
319.     FOR h = 1 TO UBOUND(DONT_USE_GLH_Handle)
320.         IF DONT_USE_GLH_Handle(h).in_use = 0 THEN
321.             DONT_USE_GLH_Handle(h).in_use = 1
322.             DONT_USE_GLH_Handle(h).handle = handle&&
323.             DONT_USE_GLH_New_Texture_Handle = h
324.             EXIT FUNCTION
325.         END IF
326.     NEXT
327.     REDIM _PRESERVE DONT_USE_GLH_Handle(UBOUND(DONT_USE_GLH_HANDLE) * 2) AS DONT_USE_GLH_Handle_TYPE
328.     DONT_USE_GLH_Handle(h).in_use = 1
329.     DONT_USE_GLH_Handle(h).handle = handle&&
330.     DONT_USE_GLH_New_Texture_Handle = h
331. END FUNCTION
332.  
333.  
334.  
335.  
336. SUB GLH_Load_Model_Format_X (Filename$, Optional_Texture_Filename$)
337.  
338.     _AUTODISPLAY 'so loading messages can be seen
339.  
340.     DEFLNG A-Z
341.  
342.     IF LEN(Optional_Texture_Filename$) THEN
343.         texture_image = _LOADIMAGE(Optional_Texture_Filename$, 32)
344.         IF texure_image = -1 THEN texure_image = 0
345.     END IF
346.  
347.     'temporary arrays
348.     DIM SIDE_LIST(10000) AS LONG 'used for wrangling triangle-fans/triangle-strips
349.     REDIM TEXCO_TX(1) AS SINGLE
350.     REDIM TEXCO_TY(1) AS SINGLE
351.     REDIM POLY_FACE_INDEX_FIRST(1) AS LONG
352.     REDIM POLY_FACE_INDEX_LAST(1) AS LONG
353.  
354.     'buffer file
355.     fh = FREEFILE: OPEN Filename$ FOR BINARY AS #fh: file_data$ = SPACE$(LOF(fh)): GET #fh, , file_data$: CLOSE #fh
356.  
357.     file_x = 1
358.     file_data$ = UCASE$(file_data$)
359.  
360.     ASC_COMMA = 44
361.     ASC_SEMICOLON = 59
362.     ASC_LBRAC = 123
363.     ASC_RBRAC = 125
364.     ASC_SPACE = 32
365.     ASC_TAB = 9
366.     ASC_CR = 13
367.     ASC_LF = 10
368.     ASC_FSLASH = 47
369.     ASC_DOT = 46
370.     ASC_MINUS = 45
371.  
372.     DIM WhiteSpace(255) AS LONG
373.     WhiteSpace(ASC_LF) = -1
374.     WhiteSpace(ASC_CR) = -1
375.     WhiteSpace(ASC_SPACE) = -1
376.     WhiteSpace(ASC_TAB) = -1
377.  
378.     DIM FormattingCharacter(255) AS LONG
379.     FormattingCharacter(ASC_COMMA) = -1
380.     FormattingCharacter(ASC_SEMICOLON) = -1
381.     FormattingCharacter(ASC_LBRAC) = -1
382.     FormattingCharacter(ASC_RBRAC) = -1
383.  
384.     DIM Numeric(255) AS LONG
385.     FOR a = 48 TO 57
386.         Numeric(a) = -1
387.     NEXT
388.     Numeric(ASC_DOT) = -1
389.     Numeric(ASC_MINUS) = -1
390.  
391.     PRINT "Loading model:"
392.  
393.     DO
394.  
395.         skip_comment:
396.  
397.         'find start of element
398.         x1 = -1
399.         FOR x = file_x TO LEN(file_data$)
400.             IF WhiteSpace(ASC(file_data$, x)) = 0 THEN x1 = x: EXIT FOR
401.         NEXT
402.         IF x1 = -1 THEN EXIT DO 'no more data
403.  
404.         a = ASC(file_data$, x1)
405.         IF a = ASC_FSLASH THEN 'commend
406.             IF ASC(file_data$, x1 + 1) = ASC_FSLASH THEN
407.                 FOR x = x1 TO LEN(file_data$)
408.                     a = ASC(file_data$, x)
409.                     IF a = ASC_CR OR a = ASC_LF THEN file_x = x + 1: GOTO skip_comment '//.....
410.                 NEXT
411.             END IF
412.         END IF
413.  
414.         'find end of element
415.         x2 = x1
416.         FOR x = x1 TO LEN(file_data$)
417.             a = ASC(file_data$, x)
418.             IF WhiteSpace(a) THEN
419.                 IF a = ASC_CR OR a = ASC_LF THEN EXIT FOR 'it is the end
420.             ELSE
421.                 'not whitespace
422.                 IF FormattingCharacter(a) THEN EXIT FOR
423.                 x2 = x
424.             END IF
425.         NEXT
426.         file_x = x2 + 1
427.  
428.         a2$ = MID$(file_data$, x1, x2 - x1 + 1)
429.  
430.         IF LEN(skip_until$) THEN
431.             IF a2$ <> skip_until$ THEN GOTO skip_comment
432.             skip_until$ = ""
433.         END IF
434.  
435.  
436.  
437.         a = ASC(a2$)
438.  
439.         IF Numeric(a) AND a <> ASC_DOT THEN 'faster than VAL, value conversion
440.             v = 0
441.             dp = 0
442.             div = 1
443.             IF a = ASC_MINUS THEN neg = 1: x1 = 2 ELSE neg = 0: x1 = 1
444.             FOR x = x1 TO LEN(a2$)
445.                 a2 = ASC(a2$, x)
446.                 IF a2 = ASC_DOT THEN
447.                     dp = 1
448.                 ELSE
449.                     v = v * 10 + (a2 - 48)
450.                     IF dp THEN div = div * 10
451.                 END IF
452.             NEXT
453.  
454.             IF dp = 1 THEN
455.                 v# = v
456.                 div# = div
457.                 IF neg THEN value# = (-v#) / div# ELSE value# = v# / div#
458.             ELSE
459.                 IF neg THEN value# = -v ELSE value# = v
460.             END IF
461.  
462.         END IF
463.  
464.         IF face_input THEN
465.             IF face_input = 3 THEN
466.                 IF a2$ = ";" THEN
467.                     IF last_a2$ = ";" THEN face_input = 0
468.                     SLI = SLI + 1
469.                 ELSEIF a2$ = "," THEN
470.                     face_input = 2
471.                     polygon = polygon + 1
472.                 ELSE
473.                     SIDE_LIST(SLI) = value#
474.                     IF SLI >= 3 THEN
475.                         FACES = FACES + 1
476.                         IF FACES > UBOUND(FACE) THEN REDIM _PRESERVE FACE(UBOUND(FACE) * 2) AS FACE_TYPE
477.                         FACE(FACES).V1.V = SIDE_LIST(1)
478.                         FACE(FACES).V2.V = SIDE_LIST(SLI - 1)
479.                         FACE(FACES).V3.V = SIDE_LIST(SLI)
480.                         IF POLY_FACE_INDEX_FIRST(polygon) = 0 THEN POLY_FACE_INDEX_FIRST(polygon) = FACES
481.                         POLY_FACE_INDEX_LAST(polygon) = FACES
482.                         FACE(FACES).Index = polygon
483.                     END IF
484.  
485.                     file_x = file_x + 1: a2$ = ";": a = ASC_SEMICOLON: SLI = SLI + 1
486.  
487.  
488.                 END IF
489.                 GOTO done
490.             END IF
491.             IF face_input = 2 THEN
492.                 SIDES = value#
493.                 SLI = 0
494.                 face_input = 3
495.                 GOTO done
496.             END IF
497.             IF face_input = 1 THEN
498.                 POLYGONS = value#
499.                 REDIM _PRESERVE FACE(POLYGONS * 4) AS FACE_TYPE 'estimate triangles in polygons
500.                 REDIM POLY_FACE_INDEX_FIRST(POLYGONS) AS LONG
501.                 REDIM POLY_FACE_INDEX_LAST(POLYGONS) AS LONG
502.                 polygon = 1
503.                 face_input = 2
504.                 FACES = 0
505.                 GOTO done
506.             END IF
507.         END IF
508.  
509.         IF mesh_input THEN
510.             IF mesh_input = 5 THEN
511.                 IF a = ASC_SEMICOLON THEN
512.                     mesh_input = 0: face_input = 1
513.                     IF normals_input = 1 THEN
514.                         face_input = 0 'face input is unrequired on 2nd pass
515.                         skip_until$ = "MESHMATERIALLIST"
516.                     END IF
517.                 END IF
518.                 GOTO done
519.             END IF
520.             IF mesh_input = 4 THEN
521.                 IF a = ASC_SEMICOLON THEN
522.                     'ignore
523.                 ELSEIF a = ASC_COMMA THEN
524.                     vertex = vertex + 1
525.                 ELSE
526.                     IF normals_input = 1 THEN
527.                         IF plane = 1 THEN VERTEX(vertex).NX = value#
528.                         IF plane = 2 THEN VERTEX(vertex).NY = value#
529.                         IF plane = 3 THEN VERTEX(vertex).NZ = value#
530.                     ELSE
531.                         IF plane = 1 THEN VERTEX(vertex).X = value#
532.                         IF plane = 2 THEN VERTEX(vertex).Y = value#
533.                         IF plane = 3 THEN VERTEX(vertex).Z = value#
534.                     END IF
535.  
536.                     plane = plane + 1
537.                     IF plane = 4 THEN
538.                         plane = 1
539.                         IF vertex = VERTICES THEN mesh_input = 5
540.                     END IF
541.  
542.                     file_x = file_x + 1 'skip next character (semicolon)
543.  
544.                 END IF
545.                 GOTO done
546.             END IF
547.             IF mesh_input = 3 THEN
548.                 IF a2$ = ";" THEN mesh_input = 4
549.                 GOTO done
550.             END IF
551.             IF mesh_input = 2 THEN
552.                 VERTICES = value#
553.                 IF normals_input = 0 THEN
554.                     REDIM VERTEX(VERTICES) AS VERTEX_TYPE
555.                     REDIM TEXCO_TX(VERTICES) AS SINGLE
556.                     REDIM TEXCO_TY(VERTICES) AS SINGLE
557.                 END IF
558.                 mesh_input = 3
559.                 GOTO done
560.             END IF
561.             IF mesh_input = 1 THEN
562.                 IF a2$ = "{" THEN mesh_input = 2: plane = 1: vertex = 1
563.                 GOTO done
564.             END IF
565.             GOTO done
566.         END IF
567.  
568.         IF matlist_input THEN
569.             IF matlist_input = 6 THEN
570.                 IF a2$ = "," THEN
571.                     'do nothing
572.                 ELSEIF a2$ = ";" THEN
573.                     matlist_input = 0
574.                 ELSE
575.                     polygon = polygon + 1: m = value#
576.                     FOR f = POLY_FACE_INDEX_FIRST(polygon) TO POLY_FACE_INDEX_LAST(polygon)
577.                         FACE(f).Material = m + 1
578.                     NEXT
579.                 END IF
580.                 GOTO done
581.             END IF
582.             IF matlist_input = 5 AND a2$ = ";" THEN matlist_input = 6: polygon = 0: face_search_start = 1: GOTO done
583.             IF matlist_input = 4 THEN matlist_input = 5: GOTO done
584.             IF matlist_input = 3 AND a2$ = ";" THEN matlist_input = 4: GOTO done
585.             IF matlist_input = 2 THEN MATERIALS = value#: REDIM MATERIAL(MATERIALS) AS MATERIAL_TYPE: matlist_input = 3: GOTO done
586.             IF matlist_input = 1 AND a2$ = "{" THEN matlist_input = 2: GOTO done
587.             GOTO done
588.         END IF
589.  
590.         IF material_input THEN
591.             IF material_input = 2 THEN
592.                 IF a2$ = ";" THEN
593.                     'do nothing
594.                 ELSEIF a2$ = "}" THEN
595.                     material_input = 0
596.                 ELSE
597.                     N = material_n
598.                     IF N = 1 THEN MATERIAL(MATERIAL).Diffuse.R = value#
599.                     IF N = 2 THEN MATERIAL(MATERIAL).Diffuse.G = value#
600.                     IF N = 3 THEN MATERIAL(MATERIAL).Diffuse.B = value#
601.                     IF N = 4 THEN MATERIAL(MATERIAL).Diffuse.A = value#
602.                     IF N = 5 THEN MATERIAL(MATERIAL).Diffuse.Intensity = value# / 100
603.                     IF N = 6 THEN MATERIAL(MATERIAL).Specular.R = value#
604.                     IF N = 7 THEN MATERIAL(MATERIAL).Specular.G = value#
605.                     IF N = 8 THEN MATERIAL(MATERIAL).Specular.B = value#
606.                     IF N = 9 THEN MATERIAL(MATERIAL).Specular.A = value#
607.                     IF N = 10 THEN MATERIAL(MATERIAL).Specular.Intensity = MATERIAL(MATERIAL).Diffuse.Intensity
608.  
609.                     'if texture_image
610.                     material_n = N + 1
611.  
612.                 END IF
613.                 GOTO done
614.             END IF
615.             IF material_input = 1 AND a2$ = "{" THEN material_input = 2: material_n = 1: GOTO done
616.             GOTO done
617.         END IF
618.  
619.         IF texco_input THEN
620.             IF texco_input = 4 THEN
621.                 IF a2$ = ";" THEN
622.                     IF last_a2$ = ";" THEN
623.                         texco_input = 0
624.                         GOTO finished
625.                     END IF
626.                     plane = plane + 1: IF plane = 3 THEN plane = 1
627.                 ELSEIF a2$ = "," THEN
628.                     vertex = vertex + 1
629.                 ELSE
630.                     IF plane = 1 THEN
631.                         TEXCO_TX(vertex) = value#
632.                     ELSE
633.                         TEXCO_TY(vertex) = value#
634.                     END IF
635.                 END IF
636.                 GOTO done
637.             END IF
638.             IF texco_input = 3 THEN
639.                 IF a2$ = ";" THEN texco_input = 4: plane = 1: vertex = 1
640.                 GOTO done
641.             END IF
642.             IF texco_input = 2 THEN
643.                 'vertices already known
644.                 texco_input = 3
645.                 GOTO done
646.             END IF
647.             IF texco_input = 1 THEN
648.                 IF a2$ = "{" THEN texco_input = 2
649.                 GOTO done
650.             END IF
651.  
652.             GOTO done
653.         END IF
654.  
655.         'mode switch?
656.         IF a2$ = "MESHTEXTURECOORDS" THEN texco_input = 1: PRINT "[Texture Coordinates]";: GOTO done
657.         IF a2$ = "MESHNORMALS" THEN normals_input = 1: mesh_input = 1: face_input = 0: PRINT "[Normals]";: GOTO done
658.         IF a2$ = "MESH" THEN mesh_input = 1: PRINT "[Mesh Vertices & Faces]";: GOTO done
659.         IF a2$ = "MESHMATERIALLIST" THEN matlist_input = 1: PRINT "[Face Material Indexes]";: GOTO done
660.         IF LEFT$(a2$, 9) = "MATERIAL " THEN
661.             material_input = 1: MATERIAL = MATERIAL + 1
662.             MATERIAL(MATERIAL).Texture = 0: MATERIAL(MATERIAL).Texture_Image = texture_image
663.             PRINT "[Material]";: GOTO done
664.         END IF
665.         done:
666.  
667.         progress = progress + 1: IF progress > 5000 THEN PRINT ".";: progress = 0
668.  
669.         IF a = ASC_SEMICOLON THEN
670.             last_a2$ = a2$
671.         ELSE
672.             IF LEN(last_a2$) THEN last_a2$ = ""
673.         END IF
674.  
675.     LOOP
676.     finished:
677.     'change texture coords (with are organised per vertex to be organised by face side
678.     'that way one vertex can share multiple materials without duplicating the vertex
679.     PRINT "[Attaching Texture Coordinates to Face Cornders]";
680.     f = 1
681.     DO UNTIL f > FACES
682.         v = FACE(f).V1.V + 1: FACE(f).V1.TX = TEXCO_TX(v): FACE(f).V1.TY = TEXCO_TY(v)
683.         v = FACE(f).V2.V + 1: FACE(f).V2.TX = TEXCO_TX(v): FACE(f).V2.TY = TEXCO_TY(v)
684.         v = FACE(f).V3.V + 1: FACE(f).V3.TX = TEXCO_TX(v): FACE(f).V3.TY = TEXCO_TY(v)
685.         f = f + 1
686.     LOOP
687.     PRINT
688.     PRINT "Model loaded!"
689.  
690.     DEFSNG A-Z
691.  
692. END SUB
693.  
694. FUNCTION GLH_RGB%& (r AS SINGLE, g AS SINGLE, b AS SINGLE)
695.     DONT_USE_GLH_COL_RGBA(1) = r
696.     DONT_USE_GLH_COL_RGBA(2) = g
697.     DONT_USE_GLH_COL_RGBA(3) = b
698.     DONT_USE_GLH_COL_RGBA(4) = 1
699.     GLH_RGB = _OFFSET(DONT_USE_GLH_COL_RGBA())
700. END FUNCTION
701.  
702. FUNCTION GLH_RGBA%& (r AS SINGLE, g AS SINGLE, b AS SINGLE, a AS SINGLE)
703.     DONT_USE_GLH_COL_RGBA(1) = r
704.     DONT_USE_GLH_COL_RGBA(2) = g
705.     DONT_USE_GLH_COL_RGBA(3) = b
706.     DONT_USE_GLH_COL_RGBA(4) = a
707.     GLH_RGBA = _OFFSET(DONT_USE_GLH_COL_RGBA())
708. END FUNCTION
709.