double click

[bplus]

I have deployed Terry's code in my simple menu app and...

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. _TITLE "press menu number key or Double Click Menu Item" 'b+ 2020-02-17 with TerryRitchie mouse code
3. TYPE MOUSE
4.     x AS INTEGER '           actual Y location of mouse cursor
5.     y AS INTEGER '           actual X location of mouse cursor
6.     Click AS INTEGER '       TRUE if single click occurred
7.     DoubleClick AS INTEGER ' TRUE if double click occurred
8.     DCTimer AS INTEGER '     double click timer
9.     LeftDown AS INTEGER '    TRUE if left button is down
10.     ClickX AS INTEGER
11.     ClickY AS INTEGER
12. END TYPE
13.  
14. CONST FALSE = 0, TRUE = NOT FALSE
15. CONST FPS = 60
16. DIM Mouse AS MOUSE, m, ms$, ink$, oldink$, keyhit AS LONG, oldkeyhit AS LONG
17. 'SCREEN _NEWIMAGE(640, 480, 32) '<<<<<<<<<<<<<< i'm thinking mouse sub should work in any screen including default
18. DO
19.     _LIMIT FPS
20.     CLS
21.     PRINT "Press menu # key or double click menu item:"
22.     FOR m = 1 TO 8
23.         ms$ = _TRIM$(STR$(m))
24.         PRINT ms$; ") Menu item "; ms$
25.     NEXT
26.     PRINT "9) Quit this demo"
27.  
28.     UpdateMouse
29.     'IF Mouse.DoubleClick THEN SOUND 880, 1
30.     'IF Mouse.Click THEN SOUND 440, 1
31.     'PRINT "Mouse X     : "; Mouse.x
32.     'PRINT "Mouse Y     : "; Mouse.y
33.     'PRINT "Last click X: "; Mouse.ClickX
34.     'PRINT "Last click Y: "; Mouse.ClickY
35.     'PRINT "Left button is ";
36.     'IF Mouse.LeftDown THEN PRINT "DOWN" ELSE PRINT "UP"
37.     keyhit = _KEYHIT
38.     IF keyhit > 0 THEN oldkeyhit = keyhit
39.     ink$ = INKEY$
40.     IF ink$ <> "" THEN oldink$ = ink$
41.     'PRINT "Last KeyHit = "; oldkeyhit
42.     'PRINT "Last Inkey$ = "; oldink$
43.     'IF Mouse.LeftDown THEN
44.     'LINE (Mouse.ClickX, Mouse.ClickY)-(Mouse.x, Mouse.y), _RGB32(0, 0, 255), BF
45.     'END IF
46.     LOCATE 15, 1: PRINT "Mouse x, y:"; Mouse.x; ","; Mouse.y
47.     FOR m = 1 TO 9
48.         IF NOT Mouse.Click THEN
49.             IF Mouse.DoubleClick AND Mouse.ClickY = m + 1 OR ink$ = _TRIM$(STR$(m)) THEN 'for screen 0 or default my = line number
50.                 PRINT "You selected menu"; m: _DELAY 2
51.                 IF m = 9 THEN SYSTEM
52.             END IF
53.         END IF
54.     NEXT
55.  
56.     ' Demo use single click info when doesn't interfere with dbl click evaluation, ie doesn't delay 2nd click detection
57.     IF Mouse.Click AND (Mouse.ClickY > 10) THEN PRINT " You clicked outside then menu area: col"; Mouse.ClickX; ", row"; Mouse.ClickY
58.     PRINT "You pressed "; ink$
59.  
60.  
61.     '_DISPLAY
62. LOOP
63.  
64.  
65. SUB UpdateMouse ()
66.  
67.     SHARED Mouse AS MOUSE
68.  
69.     WHILE _MOUSEINPUT: WEND
70.     Mouse.x = _MOUSEX '                     actual X coordinate
71.     Mouse.y = _MOUSEY '                     actual Y coordinate
72.     Mouse.DoubleClick = FALSE
73.     Mouse.Click = FALSE
74.     SELECT CASE _MOUSEBUTTON(1) '                   current state of left button?
75.         CASE TRUE '                                 button is down
76.             IF NOT Mouse.LeftDown THEN '            already held down?
77.                 Mouse.LeftDown = TRUE '             no, remember that it is now
78.                 IF Mouse.DCTimer THEN '             was last click less than double click timer value?
79.                     IF ABS(Mouse.ClickX - Mouse.x) < 3 AND ABS(Mouse.ClickY - Mouse.y) < 3 THEN
80.                         Mouse.DoubleClick = TRUE '  yes, report a double click happened
81.                     END IF
82.                     Mouse.DCTimer = 0 '             reset the double click timer
83.                 ELSE '                              no, double click timer has run out
84.                     Mouse.DCTimer = FPS \ 3 '       reset double click timer to 1/3 second
85.                     Mouse.ClickX = Mouse.x '        remember X location of click
86.                     Mouse.ClickY = Mouse.y '        remember Y location of click
87.                     Mouse.Click = TRUE '            report that a single click occurred
88.                 END IF
89.             END IF
90.         CASE FALSE '                                button is up
91.             IF Mouse.LeftDown THEN '                was the left button previously down?
92.                 Mouse.LeftDown = FALSE '            yes, report that it's now up
93.             END IF
94.             IF Mouse.DCTimer THEN '                 time left in double click timer?
95.                 Mouse.DCTimer = Mouse.DCTimer - 1 ' yes, decrement value
96.             END IF
97.     END SELECT
98. END SUB
99.  

OK works nice, it can distinguish a click from a double. :) and it's not using TIMER().

Don't know why I was having trouble with INKEY$ and mouse, a day or 2 ago.

[TempodiBasic]

What plenty of wonderful codes about double click!

Thanks guys!

@krovit
my 2 cents

reading this

So it works but then, inserting it into the real program, no. Maybe it's some variable that disturbs...

In any case is this the cleanest code to monitor the double click or do you think and be another more efficient?

and this one

I can't insert double click! when I'm on the field (because I pressed a click or because I got there by scrolling through the fields with the keyboard) I can't manage the double click: it doesn't notice and during the attempts I get to the maximum that the first click is already mistaken for the second and activate - or try to activate even where it doesn't exist - the drop-down menu.

Well, no dragging action in your application!

So if less variables = less change to get a glitch

my first step is

Code: QB64: [Select]

1.   WHILE 1
2.     DO
3.         j$ = INKEY$
4.         xxw& = _KEYHIT
5.  
6.         num_click = 0
7.         the_end = 0
8.         IF _MOUSEINPUT THEN ' <-- user presses left button
9.             mb% = _MOUSEBUTTON(1) ' <-- it stores the status of left button of mouse
10.             DO WHILE mb% 'check for button release
11.                 i = _MOUSEINPUT
12.                 mb% = _MOUSEBUTTON(1)
13.                 num_click = 1
14.             LOOP
15.             IF num_click = 1 THEN 'if button was pressed and released
16.                 t = TIMER + .3
17.                 DO WHILE TIMER < t 'check for a second press within .3 seconds
18.                     i = _MOUSEINPUT
19.                     IF _MOUSEBUTTON(1) THEN num_click = 2
20.                 LOOP
21.             END IF
22.         END IF
23.     LOOP UNTIL j$ <> "" OR the_end > 0 OR num_click > 0
24.  
25.     PRINT num_click
26. WEND
27.  

and this is my second step to shrink your working code to fit well in the original application

Code: QB64: [Select]

1.  WHILE 1
2.     DO
3.         j$ = INKEY$
4.         xxw& = _KEYHIT
5.  
6.         num_click = 0
7.         the_end = 0
8.         IF _MOUSEINPUT AND _MOUSEBUTTON(1) THEN ' <-- user presses left button
9.  
10.             num_click = 1
11.             WHILE _MOUSEBUTTON(1)
12.                 dummy = _MOUSEINPUT
13.             WEND
14.  
15.             t = TIMER + .3
16.             DO WHILE TIMER < t 'check for a second press within .3 seconds
17.                 i = _MOUSEINPUT
18.                 IF _MOUSEBUTTON(1) THEN num_click = 2
19.             LOOP
20.         END IF
21.  
22.     LOOP UNTIL j$ <> "" OR the_end > 0 OR num_click > 0
23.  
24.     PRINT num_click
25. WEND
26.  
27.  

here your code in scheme
  [ You are not allowed to view this attachment ]  

[krovit]

Grazie Tempodibasic per l'ulteriore contributo (non mi ero accorto che il 3d era andato avanti!).

Scrivo in italiano per intendersi (mi pare che tu sia un connazionale) e poi in inglese (traduttore permettendo) per tutti gli altri.
Il tuo codice è stringato e funziona benissimo: è la sintesi di molti altri che fanno un po' di tutto e anche loro lo fanno molto bene.
Purtroppo quando vado ad inserirlo nelle mie routine continuo ad ottenere comportamenti incomprensibili.

Una delle chiavi sta anche nel DOVE si inserisce il codice di controllo del mouse. Alle volte vedo che va inserito dove... non diresti di doverlo mettere. D'altra parte la programmazione non è totalmente "ad oggetti", un certo flusso sequenziale il codice, di per se, lo ha, e quindi il "dove" assume la sua importanza.

Ho individuato il dove. E ci ho messo un codice primitivo (nel senso che davvero è ben poco elegante) ma funziona. Però... però, a mio parere la funzione TIMER ha qualche problema e il programma ne risente. Le pause diventano troppo lunghe aggiungendo solo 0.3 secondi a TIMER. Se se ne aggiungono meno il doppio click non viene intercettato in nessun caso.

La funzione TIMER funziona e non rallenta l'applicazione se la tolgo dal DO-LOOP e mi limito ad intercettare il primo click e poi a verificare se il secondo avviene entro .3 secondi. Purtroppo il monitoraggio inizia, ovviamente, dopo il primo click per cui viene perso e davvero il programma agisce solo dopo aver verificato il secondo. In altre parole, se mi aspettassi un certo comportamento con il primo click (ad esempio saltare su un campo) in effetti dovrei aspettare il secondo per stabilire se davvero si trattava di un doppio click o piuttosto di due click singoli.

Ho scritto grandi quantità di codice e fatto molta fatica a concepire un sistema completo... ma la gestione del secondo click sembra diventare una chimera. Che peccato!

Per esperienza so, ed immagino sappiamo bene tutti, che se dai all'utente la possibilità di sbagliare ad inserisce un dato... quello sbaglierà di sicuro. Il doppio click mi serve all'interno di un sistema che gestisce fino allo sfinimento l'immissione dei dati. Ad esempio se voglio un numero a 5 cifre con due decimali mi deve impedire qualsiasi cosa tranne che scrivere fino a 5 cifre con 2 decimali (prevedendo l'uso del mouse, delle correzioni, del salto ad altro campo, e chi più ne ha più ne metta).

E' facile capire che il sistema non è semplicissimo e prevede molti casi nei quali la routine del doppio click s'inserisce male e con i risultati di ho parlato.

Continuerò a provare... ci vorrà ancora molto tempo (accidenti!) e comunque faccio tesoro dei contributi che trovo in questi forum. Sono dietro a queste cose dai tempi del C64 e devo dire che questa comunità è la migliore di sempre. Anche dal punto di vista umano: sempre disponibili, mai supponenti e naturalmente molto competenti. Se puoi, dillo in giro...

Oro provo a postare il pezzetto di codice che ho elaborato sulla base dei vostri contributi e a scrivere qualcosa in inglese...

Code: QB64: [Select]

1. FUNCTION Click%
2.     DO
3.         WHILE _MOUSEINPUT: WEND
4.         mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3) ' >>>>>>>>>>>>> report mouse status
5.                 IF mb AND oldMouse = 0 THEN
6.                         if plusClick% = 2 then Click%=2 else Click%=1
7.                 end if
8.                 oldMouse = mb
9.     LOOP UNTIL Click%
10. END FUNCTION
11.  
12. FUNCTION plusClick%
13. static oldMouse2       
14.         ct=0
15.         t3#=timer(.1)+.3
16.     DO while timer(.1)<t3#
17.         WHILE _MOUSEINPUT: WEND
18.         mb2 = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3)
19.         IF mb2 AND oldMouse2 = 0 THEN
20.                 ct=ct+1
21.         end if
22.         oldMouse2 = mb2
23.     LOOP
24.    plusClick%=ct
25.    oldMouse2=0
26. END FUNCTION
27.  

First of all it seems important - or at least very useful - that the code is put in the form of a function (you are more sure not to make mistakes and the use is simple and lean).

I understand... it's not a nice code... it's primitive, inelegant maybe redundant but as I said the examples posted - lastly also that of TempodiBasic - in my application are not effective (and I do not understand because! alone work perfectly...).

The example I put works everywhere but has annoying delays that make it in fact not advisable.
In my humble opinion the TIMER function has some problems that in some cases that I can not say manifests itself. ...

An important thing is also the WHERE you insert the mouse control. The flowchart can be very complex and perhaps double-click control should not be put where you would think but elsewhere. On the other hand, QB is not a real object programming and its sequential execution and events can only partially be managed outside of this lienarity.

What a pity! I've written thousands of lines of code to create a development environment that can serve to produce applications of various kinds on the same platform... and (maybe) I'll have to do without the double click!

For a few more months (!!!) I will keep trying... a system there has to be...

[TempodiBasic]

Ciao Krovit se per te va bene continuo a risponderti in inglese in modo da non renderlo una comunicazione personale, d'altronde il tuo quesito è generalizzabile per gli interessi di tutti.

So I'm saying that IMHO the issue is the logic structure of the events that you are managing.

A click of a button of the mouse is a complex event made by detecting in sequence these 3 simple events
1 mouse button is up (not pressed/activated) --> 2 mouse button is down (pressed/activated) --> 3 mouse button is up (not pressed/activated)

A double click of a button of the mouse is a bigger complex event made by 2 mouse single click in a set range of time
  1 click of mouse button  --> 2 click of mouse button
  ^                                        ^
3 |     set interval of time         |
   ---------------------------------

Thinking about these informations it is clear that you can detect a double click only after have spent the set interval of time both if  you use a loop with TIMER both if you use a loop with flags.

About my attempt to shrink your initial code, I'm working on a detection in a single loop to make easier the use of a function that is the goal of your code posted.
In the while you confirm that you needn't a dragging function?
The Dragging event is another complex event (I say always complex because we have no native function that detect it and we must build something to manage it) in  which is detected the following events in sequence
1. mouse button up --> 2 mouse button down (activate/pressed) --> 3 mouse position changes --> 4 mouse button up (released/ not pressed)

Good luck

[krovit]

Yes, of course, detecting mouse drag is an opportunity to consider to reduce the cases in which to monitor mouse behavior.

In the event of this event it would certainly be a single click. The conditions for defining double clicks are in fact the simultaneous occurrence of two conditions: 1) the reduced time between clicks; 2) have not moved.

However, to reduce the number of cases observed, additional commands must be inserted. Perhaps we have to say how much is to be agreed.

However it really seems that TIMER within a series of nested DO-LOOPs creates a kind of redundancy, of echo... which leads to delays in execution.

Thank you for the interest and also for the interesting flowchart.


____
Being human - that is, belonging to mankind - is really a mysterious, fascinating and wonderful condition, even truly supernatural. And also unmanageable (there is no "code" that can predict all behaviors and all reactions...): we are here to talk about mouse and right around and near us the covid19 reaps real victims...

[krovit]

It took me days but maybe, I say maybe, I solved my problem (with the double click mouse...  to the rest of my life I'm still working on it)

I think the solution is useful for everyone.

This function provides the following result:
1) intercepts a single click isolated;
2) intercepts a click and deems it single if the next is pressed beyond the allowed time;
3) intercept one click, and check if you perform another one within the allotted time;
4) If the second click is within the allotted time then it's a double click!

The function does not cause delays in the execution of the application that remains fluid and you don't appreciate any slowing or jumping or momentary interruption.
 
The function intercepts the first click and places the cursor on the chosen field (of course you have to have a field to jump on).
On the field where you jumped intercept the possible second click.

Ultimately the routine handles clicks as naturally as on any other windows application.

Can it be improved?

Yes, Of course. For example, a first improvement would be to check whether the variables it carries with it and continuously monitors are really all indispensable.

I'm not going to try any change, at the moment ... ;) it took me too many days to get to this point and it only takes a nothing to destroy everything!

Code: QB64: [Select]

1. do
2.    while _mouseinput: wend
3.   print Click%
4. loop until inkey$=chr$(27)
5.  
6. end
7.  
8.  
9.  
10. FUNCTION Click%
11.         DO
12.                 WHILE _MOUSEINPUT: WEND
13.         mb = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3)
14.                         IF mb AND oldMouse = 0 THEN
15.                                 passato=0
16.                                 IF plusClick%(timer) = 2 THEN
17.                                         Click%=2
18.                                 else
19.                                         Click%=1
20.                                 end if
21.                         END IF
22.                         oldMouse = mb
23.     LOOP UNTIL Click%
24. END FUNCTION
25. FUNCTION plusClick%(t1#)
26. static passato,t2#
27.         DO
28.         WHILE _MOUSEINPUT: WEND
29.         mb2 = _MOUSEBUTTON(1) OR _MOUSEBUTTON(2) OR _MOUSEBUTTON(3)
30.         IF mb2=0 THEN  'mouse up
31.                         if timer-t2# <.3 then
32.                                 t2#=timer
33.                                 t1#=timer
34.                                 passato=0
35.                                 plusClick%=2
36.                                 exit FUNCTION
37.                         end     if
38.                         if timer-t1#<.3 then
39.                                 if passato=0 then  'first mouse in time
40.                                         passato=38
41.                                         t1#=timer
42.                                         t2#=timer
43.                                         plusClick%=1
44.                                 elseif passato=38 then  'mouse up ignored
45.                                         passato=0
46.                                         t1#=timer
47.                                         t2#=timer
48.                                         plusClick%=1
49.                                 end if
50.                         else  'useless to monitor yet because time has passed
51.                                 t1#=timer
52.                                 t2#=timer
53.                                 passato=0
54.                                 plusClick%=1
55.                         end if
56.                 END IF
57.     LOOP until plusClick%
58. END FUNCTION
59.  
60.  
61.  

[TempodiBasic]

Good Krovit, it seems that you have found your way to solve the issue.
Well done.

[bplus]

Yes congratulations krovit.

I am glad to find Terry's system thank's to this thread.

[Pete]

Hmm, this reminded me of the code I posted in Bill's program thread.

https://www.qb64.org/forum/index.php?topic=2226.msg114708#msg114708

[krovit]

Thank you all!

There is no perfect algorithm, there are only those that work better than others in certain contexts.
The real trick is to predict the predictable and try to manage it better writing a code that is as adaptable to any situation without too upheavals... but it's not always possible.
The greater the needs and the greater the difficulty in solving them.

Everyone's contribution is important: where one does not arrive another and vice versa.
And it applies to anything in life...