Open up another window?

[lawsonm1]

Sorry about the poorly worded subject line; but I couldn't figure out how best to fit it all in a single subject line. Basically I want to write a program to input data, store the data, retrieve the data, add to it, etc. I would like the ability to have a new window/app, run concurrently with the main window/app, but be able to display/plot the data I retrieved from the main window/app. For example, the main program would allow me to input stock price data, save, manipulate, and add to the data. Then have an option in the main program be able to open up another window/app to graph out some portion of the data in the main program. Is that possible? And if so, are there limits on how many can be opened up at one time? Thanks, Mike

[SMcNeill]

Have the first program generate and save your data, then SHELL to a second program to read and display that data. 

[bplus]

Yep, if you want 3 windows (so you can have all data visible from one while you work in 2nd), write 3 EXE's and let Windows manage which has focus and is under your mouse and getting the keypresses...

It should actually be easier to code with data structure and shared file names, subs and function in a common BI/BM include, in each program you can focus on it's one purpose as each sub or function does same.

Divide and conquer!

[Pete]

...
Divide and conquer!

I'd rather be fruitful and multiply. At least that was true up to the time QWERKY told be to go forth and multiply myself. Then I had to rethink that one...

Anyway, you can even add a Windows API library call, to keep certain windows in focus, if that ever becomes necessary. Of course if your not using a Windows system... Go multiply yourself! (Just kidding. I don't have a Linux or Mac, so I wouldn't know how to maintain focus in either of those systems.)

Some windows persistence info here:

https://www.qb64.org/forum/index.php?topic=1365.msg105588#msg105588

https://www.qb64.org/forum/index.php?topic=860.msg100590#msg100590

Pete

[Richard Frost]

Why not have your program:
1) Manage multiple viewports on the same screen, assiging TAB or some other key to switch between them?
2) Toggle between full screen data editing and graphing, again with a single key?

There are commands to help this along, VIEW PRINT, VIEW SCREEN, _DEST, _SOURCE, _DISPLAY, etc. 
With (2) the editing part can be a text screen for simplicity of programming with the graphing bit in
some high resolution mode to make pie charts look tasty.

[TempodiBasic]

Right!

Why not have your program:
1) Manage multiple viewports on the same screen, assiging TAB or some other key to switch between them?
2) Toggle between full screen data editing and graphing, again with a single key?

you can manage internally some windows in a fullscreen application.... at the time of Windows 3.1  this tecnique was called "Child Window" using windows into the Main window of the program.

[TempodiBasic]

@ Richard Frost
Hey Richard  have you some example code to demonstrate these concepts?
I have no one, would it be necessary to build some application!

[Richard Frost]

No, I didn't have a simple example of such code, so I wrote this ugly thing quick.   It's a "spreadsheet" with two editable columns that shows a bar graph at all times, a pie chart in a new screen with TAB.   Esc saves changes and quits.  Most
of the coding time was spent looking up ASCII codes of the arrows and such minor stuff. 

I hope I didn't misunderstand the initial question!

Code: QB64: [Select]

1. DEFINT A-Z
2. DIM SHARED employee$(50), wage!(50), hours!(50), total!(50)
3. employees$ = "employees.dat"
4. SCREEN 12
5. IF NOT (_FILEEXISTS(employees$)) THEN
6.     DO
7.         READ t$
8.         IF t$ = "end" THEN EXIT DO
9.         n = n + 1
10.         employee$(n) = t$
11.     LOOP
12.     FOR i = 1 TO n
13.         CLS
14.         PRINT "FILE EMPLOYEE.DAT DOES NOT EXIST - INITIAL ENTRY MODE"
15.         PRINT
16.         PRINT "Employee "; employee$(i)
17.         PRINT
18.         d = RND * 30 + 14: c = RND * 100
19.         wage!(i) = d + c / 100 ' hey, it's a demo, just create random data
20.         hours!(i) = 40 + INT(RND * 10)
21.     NEXT i
22.     GOSUB writefile
23. END IF
24. OPEN employees$ FOR INPUT AS #1
25. n = 0
26. WHILE NOT (EOF(1))
27.     n = n + 1
28.     INPUT #1, employee$(n), wage!(n), hours!(n)
29.     total!(n) = wage!(n) * hours!(n)
30. WEND
31. CLOSE #1
32.  
33. wpos = 30
34. hpos = 40
35. tpos = 50
36. minrow = 5
37. maxrow = minrow + n - 1
38. mrow = minrow
39. mcol = hpos
40.  
41. DO
42.     GOSUB plotspread
43.     DO
44.         LOCATE mrow, mcol - 1: PRINT " ";
45.         GOSUB scankey
46.         IF LEN(i$) = 2 THEN
47.             k = ASC(RIGHT$(i$, 1))
48.             IF k = 80 THEN mrow = mrow + 1 '                        arrow down
49.             IF k = 72 THEN mrow = mrow - 1 '                        arrow up
50.             IF k = 77 THEN '                                        arrow right
51.                 IF mcol = wpos THEN mcol = hpos ELSE mcol = wpos
52.             END IF
53.             IF k = 75 THEN '                                        arrow left
54.                 IF mcol = hpos THEN mcol = wpos ELSE mcol = hpos
55.             END IF
56.             IF mrow < minrow THEN mrow = minrow
57.             IF mrow > maxrow THEN mrow = maxrow
58.         END IF
59.         LOCATE mrow, mcol - 1: PRINT ">";
60.         _DELAY .1
61.         IF i$ = CHR$(13) THEN
62.             t$ = ""
63.             DO: _LIMIT 10
64.                 GOSUB scankey
65.                 IF LEN(i$) = 1 THEN
66.                     t$ = t$ + i$
67.                     LOCATE mrow, mcol: PRINT USING "###.##"; VAL(t$);
68.                 END IF
69.             LOOP UNTIL (LEN(t$) = 6) OR (i$ = CHR$(13))
70.             z = mrow - minrow + 1
71.             IF mcol = wpos THEN wage!(z) = VAL(t$)
72.             IF mcol = hpos THEN hours!(z) = VAL(t$)
73.             total!(z) = wage!(z) * hours!(z)
74.             mrow = mrow + 1: IF mrow > maxrow THEN mrow = maxrow
75.             EXIT DO
76.         END IF
77.         IF i$ = CHR$(9) THEN GOSUB pie: EXIT DO
78.     LOOP
79. LOOP
80.  
81. done:
82. GOSUB writefile
83. SYSTEM
84. ' -----------------------------------------------------------------------------------------------
85. writefile:
86. OPEN employees$ FOR OUTPUT AS #1
87. FOR i = 1 TO n
88.     PRINT #1, employee$(i); ","; wage!(i); ","; hours!(i)
89. NEXT i
90. CLOSE #1
91. RETURN
92. ' -----------------------------------------------------------------------------------------------
93. scankey:
94. i$ = INKEY$
95. IF i$ = CHR$(27) THEN GOSUB writefile: SYSTEM
96. RETURN
97. ' -----------------------------------------------------------------------------------------------
98. pie:
99. CLS
100. gtotal! = 0
101. FOR z = 1 TO n
102.     gtotal! = gtotal! + total!(z)
103. NEXT z
104. a = 0
105. FOR z = 1 TO n
106.     q = total!(z) / gtotal! * 360
107.     FOR j = 1 TO q
108.         x = 320 + 200 * COS(_D2R(a))
109.         y = 240 + 200 * SIN(_D2R(a))
110.         LINE (320, 240)-(x, y), z
111.         _DELAY .0001
112.         a = a + 1
113.     NEXT j
114. NEXT z
115. LOCATE 29, 16: PRINT "Press spacebar to return to spreadsheet, Esc to exit";
116. DO: _LIMIT 10
117.     GOSUB scankey
118. LOOP UNTIL i$ = " "
119. RETURN
120. ' -----------------------------------------------------------------------------------------------
121. plotspread:
122. CLS
123. PRINT "                       WIDGETS COMPANY WEEKLY PAYROLL"
124. PRINT
125. PRINT "EMPLOYEE                       WAGE     HOURS         PAY"
126. LOCATE 5, 1
127. FOR i = 1 TO n
128.     c = i MOD 16
129.     COLOR c
130.     PRINT employee$(i);
131.     LOCATE CSRLIN, wpos: PRINT USING "###.##"; wage!(i);
132.     LOCATE CSRLIN, hpos: PRINT USING "###.##"; hours!(i);
133.     LOCATE CSRLIN, tpos: PRINT USING "#####.##"; total!(i)
134.     COLOR 15
135. NEXT i
136. LOCATE n + 7, 23: PRINT "Arrow keys to move, Enter to change value";
137. LOCATE n + 9, 23: PRINT "   TAB for a bigger graph, ESC to exit";
138.  
139. gtotal! = 0
140. maxt! = 0
141. FOR z = 1 TO n
142.     gtotal! = gtotal! + total!(z)
143.     IF total!(z) > maxt! THEN maxt! = total!(z)
144. NEXT z
145. x1 = 100: y1 = 370
146. x2 = 550: y2 = 470
147. LINE (x1, y1 - 10)-(x2, y2), 15, B
148. FOR z = 1 TO n
149.     tx1 = x1 + z * (x2 - x1) / (n + 1)
150.     tx2 = tx1 + 10
151.     ty1 = y2 - total!(z) / maxt! * 100
152.     ty2 = y2
153.     LINE (tx1, ty1)-(tx2, ty2), z, BF
154. NEXT z
155. RETURN
156. ' -----------------------------------------------------------------------------------------------
157. ' -----------------------------------------------------------------------------------------------
158. DATA Felicity Jones
159. DATA Saorise Ronan
160. DATA Brigitte Fonda
161. DATA Kay Lenz
162. DATA Linda Fiorentino
163. DATA Ali McGraw
164. DATA Susan Dey
165. DATA Lee Remick
166. DATA Jennifer Connelly
167. DATA Lindsey Stirling
168. DATA end
169.  
170.  

[TempodiBasic]

Fine Richard!

But please do this:
OR  at line 168  DATA end
OR  at line 8     IF t$ = "END"   <--- I've made this  [ You are not allowed to view this attachment ]  
OR at line 8      IF LTRIM$(t$) = "end"
to avoid  line 7 OUT of DATA

[TempodiBasic]

moreover adding

Code: QB64: [Select]

1.             COLOR 15, 0
2.             LOCATE mrow, mcol: PRINT USING "###.##"; VAL(t$);

after line 61 IF i$ = CHR$(13) THEN 
I find more clear that I must input a data... I do this feedback only because your demonstration is very fine and I didn't like this neo on it.

[lawsonm1]

Holy Moly; now my brain has been overloaded. For now, I'm probably going to stick to something reasonably simple; like SHELL. I don't mind additional windows open. But this has got me thinking about how to pass variables to the program I am SHELLing to. Maybe a string, or two, that I could use to set the window title to. I have always just used GWBASIC, so this new world of QB64 is really new. Thanks, Mike

[Pete]

I like to just use a file to pass variables. This was an old trick I used to run my office software, when QBasic was around. Just take all the variables that the SHELL program needs, and write them to a file before the SHELL call is made. Have the SHELL program open that file to load the variables. Redo the process in reverse, if the SHELL program will be making any changes to these variables, that the main program calling it would need updated.

Pete

[Richard Frost]

Here's a simpler and shorter example that actually restores the previous screen rather than regenerate it,
and the screens are different - one text and one graphics.

I couldn't get the F1 key trap to work with INPUT, so I grab one character at a time with INKEY$.  Not handling
backspace and whatnot isn't very nice, but hey, this is a demo for a specific purpose, and proper input ain't it.

Code: QB64: [Select]

1. ON KEY(1) GOSUB GraphicsScreen
2. KEY(1) ON
3.  
4. LOCATE 12, 27: PRINT "SCREEN 0 page, F1 for graphics";
5.  
6. DO
7.     LOCATE 15, 30: PRINT SPACE$(30);
8.     LOCATE 15, 30: PRINT "Enter name: ";
9.     name$ = ""
10.     DO: _LIMIT 10
11.         i$ = INKEY$
12.         IF i$ = CHR$(13) THEN EXIT DO
13.         IF LEN(i$) = 1 THEN
14.             PRINT i$;
15.             name$ = name$ + i$
16.         END IF
17.     LOOP
18. LOOP UNTIL name$ = ""
19. END
20.  
21. GraphicsScreen:
22. i& = _COPYIMAGE(0)
23. SCREEN _NEWIMAGE(800, 600, 32)
24. CIRCLE (400, 300), 200, _RGB32(255, 0, 0)
25. SLEEP
26. SCREEN i&
27. RETURN
28.  

[TempodiBasic]

Hi lawsomn1

here you can see a demo of multiple windows into your main window program https://www.qb64.org/forum/index.php?topic=2124.msg113618#msg113618

this is an alternative answer to your question versus multiple static windows/Areas of the window of your program by Richard Frost.
Moreover you can merge the idea of multiple child windows with that of Richard Frost (navigation by TAB among the windows and keyboard input)

When I started to write code in Qbasic (in the old time of DOS) I was fascinated of the possibility to write different modules (programs) and to pass data among them... the way was  or COMMON variables or files with data.
Today with QB64 there is no matter to write different modules, because having no RAM limitation except that for  RAM being on the machine that runs the program, you can do very huge programs with little problems.
Moreover if your will is to build two programs that interact between them you can use as newer method TCP protocol.

Good luck with your project...
and write down it before as pseudocode!
I have done the mistake to not do so and in the empowerement from 1 child window to multiple child window I waste 4-6h because I have moved of 1 raw an instruction. (in the one child window it doesn't make difference, but in that with multiple child windows it make so difference!)

[lawsonm1]

Well, as I was getting more involved in this program I'm writing, I came across something else I could use the "SHELL and passing data in a file" concept (thanks Pete); getting a list of the data files my program creates in order to be able to figure out which one to load for update. So I decided to SHELL out to get a directory re-directed to a data file, then INPUT the data file into strings, parse the strings for the dates, and then display them for eventual selection. Hey, it isn't the fanciest way I'm sure, but it works.

I guess the more things I want to do with this program, the more I dig around trying to find new things, and ways, to do them. For me that is hard if you don't have a goal in what you want to create, so you can best create it. Thanks all, Mike