How to stop chopping words in long strings

[lawsonm1]

Does anyone know how I can stop having words chopped up when displaying long stings? If I have a string that is longer than what will display on a single line, some words get split up when I try to PRINT them to the screen. Thanks, Mike

[SMcNeill]

You need a basic word wrapping routine for output:

Code: QB64: [Select]

1. 'SCREEN _NEWIMAGE(640, 480, 32)
2.  
3. LOCATE 1, 21 'to test a line with an offset
4. test$ = "This is a very long sentence which runs on and on and one and even contains tipos and errors and goofs and mistakes and all sorts of junk, but it is good for testing if we have word breaks working properly for us!"
5. WordWrap test$, -1
6. PRINT 'to test a line from the starting point
7. WordWrap test$, -1
8. PRINT
9. PRINT "=============="
10. PRINT
11. WordWrap test$, 0 'And this shows that we can wordwrap text without automatically moving to a new line
12. WordWrap test$, -1 'As this line picks up right where the last one left off.
13.  
14.  
15.  
16. SUB WordWrap (text AS STRING, newline)
17.     DIM BreakPoint AS STRING
18.     BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.
19.  
20.     w = _WIDTH
21.     pw = _PRINTWIDTH(text)
22.     x = POS(0): y = CSRLIN
23.     IF _PIXELSIZE <> 0 THEN x = x * _FONTWIDTH
24.     firstlinewidth = w - x + 1
25.     IF pw <= firstlinewidth THEN
26.         PRINT text;
27.         IF newline THEN PRINT
28.     ELSE
29.         'first find the natural length of the line
30.         FOR i = 1 TO LEN(text)
31.             p = _PRINTWIDTH(LEFT$(text, i))
32.             IF p > firstlinewidth THEN EXIT FOR
33.         NEXT
34.         lineend = i - 1
35.         t$ = RTRIM$(LEFT$(text, lineend)) 'at most, our line can't be any longer than what fits the screen.
36.         FOR i = lineend TO 1 STEP -1
37.             IF INSTR(BreakPoint, MID$(text, i, 1)) THEN lineend = i: EXIT FOR
38.         NEXT
39.         PRINT LEFT$(text, lineend)
40.         WordWrap LTRIM$(MID$(text, lineend + 1)), newline
41.     END IF
42. END SUB
43.  

[lawsonm1]

Thanks Steve. It works just wonderful. I have used GWBASIC in the past, but that doesn't work anymore on Windows 10. So I'm still getting used to QB64, and trying to clean up the cobwebs from using BASIC years ago. I'm using this as part of a educational program I'm writting for my two kids to help them in school. Thanks again, Mike

[bplus]

Here are a couple more wrappings:

For just printing:

Code: QB64: [Select]

1. _TITLE "wrap$ test" 'b+ 2019-12-28  a simple way
2.  
3. 'now test in graphics screen
4. 'SCREEN _NEWIMAGE(640, 600, 32) 'now test in graphics screen
5.  
6. PRINT "Here is our test string:"
7. test$ = "12345678901234567890123456789012345678901234567890123456789012345678901234567890     Here is a super long string to test with the wrap$ Function that splits a string at first space found before the maxLen limit to keep the strings at or under the maxLen length."
8. PRINT test$
9. PRINT
10. PRINT "press any for printWrap demo... "
11. SLEEP
12. CLS
13.  
14. PRINT "Here is printWrap at row = 12, col = 1, wrap length is 80:"
15. printWrap test$, 80, 12, 1
16. LOCATE 25, 20: PRINT "press any for another demo... ";
17. SLEEP
18. CLS
19.  
20. PRINT "Here is printWrap at row = 9, col = 20, wrap length is 40:"
21. printWrap test$, 40, 9, 20
22. LOCATE 25, 20: PRINT "press any for another demo... ";
23. SLEEP
24. CLS
25.  
26. PRINT "Here is printWrap at row = 5, col = 30, wrap length is 20:"
27. printWrap test$, 20, 5, 30
28. LOCATE 24, 20: PRINT "end of demos... ";
29.  
30.  
31. 'This function returns the first segment of string less than or equal to maxLen AND
32. 'the remainder of the string (if any) is returned in tail$ to be used by wrap$ again
33. FUNCTION wrap$ (s$, maxLen, tail$)
34.     IF LEN(s$) > maxLen THEN
35.         p = maxLen + 1
36.         WHILE MID$(s$, p, 1) <> " " AND p > 1
37.             p = p - 1
38.         WEND
39.         IF p = 1 THEN
40.             wrap$ = MID$(s$, 1, maxLen): tail$ = MID$(s$, maxLen + 1)
41.         ELSE
42.             wrap$ = MID$(s$, 1, p - 1): tail$ = MID$(s$, p + 1)
43.         END IF
44.     ELSE
45.         wrap$ = s$: tail$ = ""
46.     END IF
47. END FUNCTION
48.  
49. 'this sub uses the wrap$ function to print out a string with row and column offsets
50. SUB printWrap (s$, maxLen, rowOffset, colOffset)
51.     ss$ = s$ 'work with copy
52.     DO
53.         LOCATE rowOffset + i, colOffset: PRINT wrap$(ss$, maxLen, st$)
54.         ss$ = st$
55.         i = i + 1
56.     LOOP UNTIL LEN(ss$) = 0
57. END SUB
58.  

For storing and appending fixed lengths in a array and using when and where needed:

Code: QB64: [Select]

1. _TITLE "wrapAppend test" 'b+ 2019-12-28  a less simple way
2.  
3. test$ = "1234567890123456789012345678901234567890     Here is a rather long string to test with the wrap$ SUB that splits a string at first space found before the maxLen limit to keep the strings at or under the maxLen length and appends these segments to an Dynamic Array which is handy to track number of rows."
4. test2$ = "     And here is a 2nd very long line to see how well it appends to the first long line in the dynamic array holding all the segments at maxLen or less."
5. PRINT "Here is our first test string:"
6. PRINT test$
7. PRINT
8. PRINT "Here is 2nd string for our test of appending fixed length string to an array:"
9. PRINT test2$
10. PRINT: PRINT "press any for first demo... "
11. SLEEP
12. CLS
13.  
14. REDIM testArr$(1 TO 1) '<<< dynamic array
15. wrapAppend test$, 40, testArr$()
16. wrapAppend "     Hey! add this short line too.", 40, testArr$()
17. wrapAppend test2$, 40, testArr$()
18. PRINT "Here are the 2 strings split at max lengths of 40 and stored in an array:"
19. PRINT
20. FOR i = LBOUND(testArr$) TO UBOUND(testArr$)
21.     PRINT "Row"; i, testArr$(i)
22. NEXT
23. PRINT
24. PRINT "Press any to see a centered display..."
25. SLEEP
26. CLS
27.  
28. ub = UBOUND(testArr$)
29. sRow = (_HEIGHT - ub) \ 2
30. sCol = 20
31. FOR i = LBOUND(testArr$) TO ub
32.     LOCATE sRow + i, sCol: PRINT testArr$(i);
33. NEXT
34.  
35. 'this sub splits a string at first spaces less than maxlen + 1
36. SUB wrapAppend (s$, maxLen AS INTEGER, dynamicArr$()) 'appends strings from s$ to arr$()at lengths of maxLen and under
37.     ss$ = s$ 'copy s$ because going to change it
38.     ub = UBOUND(dynamicArr$)
39.     lb = LBOUND(dynamicArr$)
40.     WHILE LEN(ss$) > maxLen
41.         p = maxLen + 1
42.         WHILE MID$(ss$, p, 1) <> " " AND p > 1
43.             p = p - 1
44.         WEND
45.         IF ub = lb AND LEN(dynamicArr$(lb)) = 0 THEN ELSE ub = ub + 1: REDIM _PRESERVE dynamicArr$(lb TO ub)
46.         IF p = 1 THEN
47.             dynamicArr$(ub) = MID$(ss$, 1, maxLen)
48.             ss$ = MID$(ss$, maxLen + 1)
49.         ELSE
50.             dynamicArr$(ub) = MID$(ss$, 1, p - 1)
51.             ss$ = MID$(ss$, p + 1)
52.         END IF
53.     WEND
54.     IF LEN(ss$) THEN
55.         IF ub = lb AND LEN(dynamicArr$(lb)) = 0 THEN ELSE ub = ub + 1: REDIM _PRESERVE dynamicArr$(lb TO ub)
56.         dynamicArr$(ub) = ss$
57.     END IF
58. END SUB
59.  
60.  
61.  

[Pete]

Let's not forget about our new exciting keyword _INSTRREV...

Code: QB64: [Select]

1. WIDTH 80, 43
2. a$ = "The quick brown fox ran through the dense forrest."
3. lmargin = 1
4. rmargin = 50
5. IF RIGHT$(a$, 1) <> " " THEN a$ = a$ + " "
6. DO UNTIL rmargin = 0
7.     LOCATE 1, lmargin - 1 + rmargin + 1
8.     FOR i = 1 TO 42
9.         LOCATE , rmargin + 1
10.         PRINT "|"
11.     NEXT
12.     seed = 1
13.     LOCATE 1, lmargin
14.     DO UNTIL INSTR(seed, a$, " ") = 0
15.         z$ = MID$(a$, seed, rmargin - lmargin + 2)
16.         IF lmargin = rmargin THEN z$ = MID$(z$, 1, LEN(z$) - 1)
17.         IF RIGHT$(z$, 1) = " " THEN
18.             x = LEN(z$)
19.         ELSE
20.             x = _INSTRREV(z$, " ")
21.         END IF
22.         IF x = 0 THEN x = rmargin - lmargin + 1
23.         PRINT RTRIM$(MID$(a$, seed, x))
24.         IF rmargin = lmargin AND x = 0 THEN SYSTEM
25.         seed = seed + x
26.     LOOP
27.     DO
28.         _LIMIT 30
29.         b$ = INKEY$
30.         IF LEN(b$) THEN
31.             SELECT CASE b$ ' Use left / right arrow keys to decrease / increase page width.
32.                 CASE CHR$(27)
33.                     SYSTEM
34.                 CASE CHR$(0) + "M"
35.                     IF rmargin < 80 - 1 THEN rmargin = rmargin + 1: EXIT DO
36.                 CASE CHR$(0) + "K"
37.                     IF rmargin > lmargin THEN rmargin = rmargin - 1: EXIT DO
38.             END SELECT
39.         END IF
40.     LOOP
41.     CLS
42. LOOP

... These are the things I think about at work.

Pete

[lawsonm1]

Steve, I have noticed that if there are single quotes in the text string, then they get displayed as some other character, as in from a completely different font. I'm sure I am missing something... Thanks, Mike

[SMcNeill]

Steve, I have noticed that if there are single quotes in the text string, then they get displayed as some other character, as in from a completely different font. I'm sure I am missing something... Thanks, Mike

We don't do anything to the character values with the little routine I posted, except just choose a suitable breakpoint and stop printing the text at that point, before moving to the next line to start again.

Testing with the following code, I don't generate any odd characters with the program, that I can see:

Code: [Select]

SCREEN _NEWIMAGE(640, 480, 32)

LOCATE 1, 21 'to test a line with an offset
test$ = "This is a '''' " + CHR$(34) + " ```` very long sentence which runs on and on and one and even contains tipos and errors and goofs and mistakes and all sorts of junk, but it is good for testing if we have word breaks working properly for us!"
WordWrap test$, -1
PRINT 'to test a line from the starting point
WordWrap test$, -1
PRINT
PRINT "=============="
PRINT
WordWrap test$, 0 'And this shows that we can wordwrap text without automatically moving to a new line
WordWrap test$, -1 'As this line picks up right where the last one left off.



SUB WordWrap (text AS STRING, newline)
    DIM BreakPoint AS STRING
    BreakPoint = ",./- ;:!" 'I consider all these to be valid breakpoints.  If you want something else, change them.

    w = _WIDTH
    pw = _PRINTWIDTH(text)
    x = POS(0): y = CSRLIN
    IF _PIXELSIZE <> 0 THEN x = x * _FONTWIDTH
    firstlinewidth = w - x + 1
    IF pw <= firstlinewidth THEN
        PRINT text;
        IF newline THEN PRINT
    ELSE
        'first find the natural length of the line
        FOR i = 1 TO LEN(text)
            p = _PRINTWIDTH(LEFT$(text, i))
            IF p > firstlinewidth THEN EXIT FOR
        NEXT
        lineend = i - 1
        t$ = RTRIM$(LEFT$(text, lineend)) 'at most, our line can't be any longer than what fits the screen.
        FOR i = lineend TO 1 STEP -1
            IF INSTR(BreakPoint, MID$(text, i, 1)) THEN lineend = i: EXIT FOR
        NEXT
        PRINT LEFT$(text, lineend)
        WordWrap LTRIM$(MID$(text, lineend + 1)), newline
    END IF
END SUB
Can you provide an example of the code which is displaying character substitutions?  I'll be happy to help with debugging it for you, if I can.  ;)

[lawsonm1]

Thanks. I did a little bit of testing some things, but I'm thinking it may be more related to the application I use for creating the text file I load that gets parsed. The computer I run QB64 on is a Windows10 machine and I generated the text file using LibreOffice 6.1. But I was editing the file on my laptop, which is Windows 8.1 and running Excel 2010. The text file is a comma separated .csv file. I'll fiddle some more tomorrow to see if I can get the error to come back. I'll let you know one way or another. Thanks again, Mike

[lawsonm1]

Steve, I did some more testing, and so far it appears that the file is changed when I use LibreOffice Calc. It works fine when I use Microsoft Excel to create and modify the .csv file. Thanks again for your help, Mike