Higher/Smoother framerate movement

[Zeppelin]

Hey Guys,
Is it possible to achieve a higher/smoother framerate when moving sprites using _PUTIMAGE.
See file below.
To get to the demo go:
-Singleplayer
-Infinite
To exit the demo hit escape.

Thanks,
Zep

[bplus]

Hi Z,

I assume this is the code in question:

Code: QB64: [Select]

1. 'PRACTICE - GAMEMODE
2. SUB Infinite
3.     CLS
4.     'DEFINE LOCAL VARS
5.  
6.     DIM health
7.     DIM deltaTime
8.  
9.     playerSpeed = 500
10.     health = 100
11.     pX = _WIDTH / 2 - (playerScale * 2.5)
12.     pY = _HEIGHT / 10 * 8
13.  
14.     sTime = TIMER
15.  
16.     DO
17.         sTime = TIMER
18.  
19.         IF _KEYDOWN(100) = -1 THEN
20.             pX = pX + (deltaTime * playerSpeed)
21.         END IF
22.         IF _KEYDOWN(97) = -1 THEN
23.             pX = pX - (deltaTime * playerSpeed)
24.         END IF
25.  
26.         IF pX < 1 THEN
27.             pX = 1
28.         END IF
29.         IF pX > _WIDTH - playerScale * 5 - 1 THEN
30.             pX = _WIDTH - playerScale * 5 - 1
31.         END IF
32.  
33.         LINE (pX - (playerScale * 5) - 1, pY - (playerScale * 5) - 1)-(pX + ((playerScale * 5) * 2), pY + (playerScale * 5) + 1), _RGB(0, 0, 0), BF
34.         PUT (pX, pY), player%()
35.         _DISPLAY
36.  
37.  
38.         eTime = TIMER
39.         deltaTime = eTime - sTime
40.     LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
41.     CLS
42.     SaveGame
43.     DrawMenu
44. END SUB
45.  

I have never seen a player moved according to elapsed time.

You might try setting a character moving in a direction x amount every frame (= loop) and only stop or change direction by key press detection. It is like the snake in the Snake Game though that never stops unless it crashes into something.

Code: QB64: [Select]

1. 'PRACTICE - GAMEMODE
2. SUB Infinite
3.     CLS
4.     'DEFINE LOCAL VARS
5.  
6.     DIM health
7.     DIM deltaTime
8.  
9.     playerSpeed = 100
10.     health = 100
11.     pX = _WIDTH / 2 - (playerScale * 2.5)
12.     pY = _HEIGHT / 10 * 8
13.  
14.     sTime = TIMER
15.  
16.     DO
17.         IF _KEYDOWN(100) = -1 THEN Pdx = 1
18.         IF _KEYDOWN(97) = -1 THEN Pdx = -1
19.         pX = pX + Pdx
20.         IF pX < 1 THEN
21.             pX = 1
22.         ELSEIF pX > _WIDTH - playerScale * 5 - 1 THEN
23.             pX = _WIDTH - playerScale * 5 - 1
24.         END IF
25.         'black out character? not cls ??
26.         LINE (pX - (playerScale * 5) - 1, pY - (playerScale * 5) - 1)-(pX + ((playerScale * 5) * 2), pY + (playerScale * 5) + 1), _RGB(0, 0, 0), BF
27.         PUT (pX, pY), player%()
28.         _DISPLAY
29.         _LIMIT playerSpeed
30.     LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
31.     CLS
32.     SaveGame
33.     DrawMenu
34. END SUB
35.  

[Ashish]

Hi! You can use hardware images. It is very fast.

[SMcNeill]

I've been trying to get this thing running and so far haven't had any luck with it.  My initial feedback for the game:

1) In all those menu routines, change the SELECT CASE so that they work will upcase values as well as lower case, like so:
          SELECT CASE INKEY$
            CASE "s", "S" 'MOVE POINTER DOWN

My caps lock was on, and the game was simply unresponsive, with no indication that something was wrong with it.

2) Add a _LIMIT into each of those menu routines.  As they currently exist, they run CPU usage up to incredible levels and make the fans in my PC sound like an airplane engine as they try to keep the system cool.  Something low is more than enough in this case, as people don't type at 1000 characters per second, and the program is only actually looking for a few keypresses here to progress.  I'd go with a _LIMIT 30 or so, as that's all you really seem to need.

    DO
        _LIMIT 30
        LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
        _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER

        _DISPLAY 'REDUCE FLICKERING


Edit:

Like bplus, I also think that a _LIMIT of some sort should be set inside the loop, rather than trying to base movement upon elapsed time.

However, I think that the limit should be a set amount, with the ability to modify the movement as needed via the playerSpeed variable, rather than messing with the limit as his code would. 

Code: QB64: [Select]

1. SUB Infinite
2.     CLS
3.     'DEFINE LOCAL VARS
4.  
5.     DIM health
6.     DIM deltaTime
7.  
8.     playerSpeed = 500
9.     health = 100
10.     pX = _WIDTH / 2 - (playerScale * 2.5)
11.     pY = _HEIGHT / 10 * 8
12.  
13.     sTime = TIMER
14.  
15.     DO
16.         _LIMIT 120
17.  
18.         sTime = TIMER(0.001)
19.         IF _KEYDOWN(ASC("+")) OR _KEYDOWN(ASC("=")) THEN 'plus key
20.             playerSpeed = playerSpeed + 50 'adjustable speed for testing with the player
21.             IF playerSpeed > 1000 THEN playerSpeed = 1000
22.             _DELAY .1 ' small pause to register/release the key
23.         END IF
24.         IF _KEYDOWN(ASC("-")) OR _KEYDOWN(ASC("_")) THEN 'minus key
25.             playerSpeed = playerSpeed - 50
26.             IF playerSpeed < 100 THEN playerSpeed = 100
27.             _DELAY .1
28.         END IF
29.         IF _KEYDOWN(100) THEN
30.             pX = pX + playerSpeed / 100
31.             IF pX > _WIDTH - playerScale * 5 - 1 THEN pX = _WIDTH - playerScale * 5 - 1
32.         END IF
33.         IF _KEYDOWN(97) THEN
34.             pX = pX - playerSpeed / 100
35.             IF pX < 1 THEN pX = 1
36.         END IF
37.  
38.  
39.         LOCATE 1, 1: PRINT playerSpeed
40.         LINE (pX - (playerScale * 5) - 1, pY - (playerScale * 5) - 1)-(pX + ((playerScale * 5) * 2), pY + (playerScale * 5) + 1), _RGB(0, 0, 0), BF
41.         PUT (pX, pY), player%()
42.         _DISPLAY
43.  
44.  
45.         eTime = TIMER(0.001)
46.         deltaTime = eTime - sTime
47.     LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
48.     CLS
49.     SaveGame
50.     DrawMenu
51. END SUB

Like this, you can set the speed of the program so that it'll have a maximum movement with _LIMIT on very fast computers, and you can increase the playerSpeed as necessary to keep game flow steady if it's ever ran on very old/slow computers.  (Just add a condition to check for your FPS, which should always be within 1 of your limit, and then you can adjust the player and opponent speed to skip a few frames if the values get too low,  to keep the game moving at the same rate, which is what I think you were wanting to do with deltatime as you implemented it.)

[Zeppelin]

Like this, you can set the speed of the program so that it'll have a maximum movement with _LIMIT on very fast computers, and you can increase the playerSpeed as necessary to keep game flow steady if it's ever ran on very old/slow computers.  (Just add a condition to check for your FPS, which should always be within 1 of your limit, and then you can adjust the player and opponent speed to skip a few frames if the values get too low,  to keep the game moving at the same rate, which is what I think you were wanting to do with deltatime as you implemented it.)

I usually program in c# with Unity, so the deltatime was to try keep a consistent movement speed disregarding framerate (to some degree).
I will add limits to all loops (completely forgot, sorry about the egg-cooking CPU).

Thanks,
Zep

[MrFreyer]

...something smooth like this?

Code: QB64: [Select]

1. '+-------------------+
2. '        SLAY
3. ' ZEPPELIN GAMES 2019
4. '+-------------------+
5.  
6. _TITLE "SLAY" 'SET TITLE
7. _FULLSCREEN 'SET FULLSCREEN
8. SCREEN _NEWIMAGE(1200, 800, 256)
9.  
10. DIM sTime AS DOUBLE 'NEW NEW NEW ####################################
11. DIM eTime AS DOUBLE 'NEW NEW NEW ####################################
12. DIM deltaTime AS SINGLE 'NEW NEW NEW ####################################
13.  
14. 'DECLARE VARIABLES
15. 'SAVE DATA VARS
16. DIM SHARED save.point AS INTEGER
17. DIM SHARED saveData$(1000)
18.  
19. 'PLAYER VARS
20. DIM SHARED player%(10000)
21. DIM SHARED player.name AS STRING
22. DIM SHARED player.health AS INTEGER
23. DIM SHARED player.basehealth AS INTEGER
24. DIM SHARED playerScale AS INTEGER
25. playerScale = 15
26.  
27. DIM SHARED pX
28.  
29. 'PLAYER STATS
30. DIM SHARED stats.enemyskilled AS INTEGER
31. DIM SHARED stats.totaldeaths AS INTEGER
32.  
33. 'SCREEN AND FORMATTING VARS
34. DIM SHARED w AS INTEGER
35. DIM SHARED h AS INTEGER
36.  
37. DIM SHARED fh AS INTEGER
38. DIM SHARED fw AS INTEGER
39.  
40. 'GET THE SCREEN DIMSENSIONS
41. w = _WIDTH
42. h = _HEIGHT
43.  
44. 'FONT DATA
45. fh = _FONTHEIGHT
46. fw = _FONTWIDTH
47.  
48. 'SET THE COLOR
49. col = _RGBA(255, 255, 255, 255)
50.  
51. 'START GAME
52. LoadData
53.  
54. SUB LoadData
55.     'LOAD SAVE DATA
56.  
57.     'LOAD PLAYER SPRITE
58.     LoadSprite player%(), playerScale
59.  
60.     IF _FILEEXISTS("SlayV4SaveData.txt") THEN 'SEE IF THE FILE EXISTS
61.         OPEN "SlayV4SaveData.txt" FOR INPUT AS #1
62.         DO UNTIL EOF(1) 'LOOP UNTIL END OF FILE
63.             filecount = filecount + 1 'COUNT AMOUNT OF LINES
64.             LINE INPUT #1, file$
65.             saveData$(filecount) = file$
66.         LOOP
67.         CLOSE #1
68.  
69.         IF filecount > 2 THEN
70.             'PLAYER
71.  
72.             'DECRYPT NAME
73.             name$ = ""
74.             FOR n = 1 TO LEN(saveData$(1)) STEP 2
75.                 name$ = name$ + CHR$(ASC(MID$(saveData$(1), n, 1)) - 4)
76.             NEXT n
77.  
78.             'DECRYPT STATS
79.             'HEALTH
80.             health$ = ""
81.             FOR n = 1 TO LEN(saveData$(2)) STEP 2
82.                 health$ = health$ + CHR$(ASC(MID$(saveData$(2), n, 1)) - 4)
83.             NEXT n
84.  
85.             player.name = UCASE$(name$) 'LOAD NAME
86.             player.basehealth = VAL(health$) 'LOAD BASE HEALTH
87.             player.health = player.basehealth 'SET PLAYER HEALTH
88.             'SAVE DATA
89.             save.point = VAL(saveData$(3)) 'LOAD SAVE POINT
90.             'STATS
91.             stats.enemyskilled = VAL(saveData$(4)) 'ENEMYS KILLED
92.             stats.totaldeaths = VAL(saveData$(5)) 'TOTAL DEATHS
93.         ELSE
94.             CreateNewSave
95.         END IF
96.     ELSE
97.         CreateNewSave
98.     END IF
99.  
100.     'START GAME
101.     _DELAY (1)
102.     DrawLogo
103. END SUB
104.  
105. SUB CreateNewSave
106.     'CREATE NEW SAVE FILE
107.     scaledText w / 2 - 65, h / 2 + 8, 16, _RGBA(255, 255, 255, 255), "Enter your name: "
108.     DO
109.         LOCATE (h / 2 - 248) / fh + hf, (w / 2 - 50) / fw + fw: INPUT "", name$
110.     LOOP UNTIL LEN(name$) > 1
111.     IF LEN(name$) > 16 THEN
112.         CLS
113.         _PRINTSTRING (w / 2 - 150, h / 2), "Name length should be less than 16 characters"
114.         _DELAY (2)
115.         CLS
116.         LoadData
117.     END IF
118.  
119.     'SET VARS
120.     player.name = UCASE$(name$)
121.     player.health = 100
122.  
123.     save.point = 0
124.     stats.enemyskilled = 0
125.     stats.totaldeaths = 0
126.  
127.     'ENCRYPT SAVE DATA
128.     'NAME
129.     DIM nameArray$(16)
130.     FOR n = 1 TO LEN(player.name)
131.         nameArray$(n) = MID$(player.name, n, 1)
132.     NEXT n
133.  
134.     FOR n = 1 TO LEN(player.name)
135.         tempName$ = tempName$ + CHR$(ASC(nameArray$(n)) + 4)
136.         tempName$ = tempName$ + CHR$(INT(RND * 100) + 100)
137.     NEXT n
138.  
139.     name$ = tempName$
140.  
141.     'ENCRYPT STATS
142.     'HEALTH
143.     DIM healthArray$(5)
144.     FOR n = 1 TO LEN(STR$(player.health))
145.         healthArray$(n) = MID$(STR$(player.health), n, 1)
146.     NEXT n
147.  
148.     FOR n = 1 TO LEN(STR$(player.health))
149.         tempHealth$ = tempHealth$ + CHR$(ASC(healthArray$(n)) + 4)
150.         tempHealth$ = tempHealth$ + CHR$(INT(RND * 100) + 100)
151.     NEXT n
152.  
153.     'SAVE VARS TO TXT
154.     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
155.     'PLAYER
156.     PRINT #1, name$
157.     PRINT #1, tempHealth$
158.     'SAVE DATA
159.     PRINT #1, save.point
160.     'STATS
161.     PRINT #1, stats.enemyskilled
162.     PRINT #1, stats.totaldeaths
163.     CLOSE #1
164.     CLS
165. END SUB
166.  
167. SUB DrawLogo
168.     'FADE LOGO IN
169.     FOR n = 0 TO 255
170.         'LIMIT FPS
171.         _LIMIT 1000
172.         'TOP LINE
173.         LINE (w / 6 * 2, h / 6 * 1.5)-(w / 6 * 4, h / 6 * 2), col, BF
174.         LINE (w / 6 * 1.8, h / 6 * 1.5)-(w / 6 * 4.25, h / 6 * 1.75), col, BF
175.  
176.         'MIDDLE
177.         LINE (w / 6 * 3.5, h / 6 * 2)-(w / 6 * 4, h / 6 * 2.5), col, BF
178.         LINE (w / 6 * 3.25, h / 6 * 2.25)-(w / 6 * 3.75, h / 6 * 3), col, BF
179.         LINE (w / 6 * 2.75, h / 6 * 2.75)-(w / 6 * 3.5, h / 6 * 3.25), col, BF
180.         LINE (w / 6 * 2.25, h / 6 * 3)-(w / 6 * 3.25, h / 6 * 3.5), col, BF
181.         LINE (w / 6 * 2, h / 6 * 3.25)-(w / 6 * 2.5, h / 6 * 3.75), col, BF
182.  
183.         'BOTTOM LINE
184.         LINE (w / 6 * 1.75, h / 6 * 3.75)-(w / 6 * 4.25, h / 6 * 4.25), col, BF
185.         LINE (w / 6 * 1.5, h / 6 * 4)-(w / 6 * 4.5, h / 6 * 4.25), col, BF
186.         col = _RGB(n, n, n)
187.         _DISPLAY
188.     NEXT n
189.  
190.  
191.     'DRAW LOGO
192.     LINE (w / 6 * 2, h / 6 * 1.5)-(w / 6 * 4, h / 6 * 2), col, BF
193.     LINE (w / 6 * 1.8, h / 6 * 1.5)-(w / 6 * 4.25, h / 6 * 1.75), col, BF
194.  
195.     'MIDDLE
196.     LINE (w / 6 * 3.5, h / 6 * 2)-(w / 6 * 4, h / 6 * 2.5), col, BF
197.     LINE (w / 6 * 3.25, h / 6 * 2.25)-(w / 6 * 3.75, h / 6 * 3), col, BF
198.     LINE (w / 6 * 2.75, h / 6 * 2.75)-(w / 6 * 3.5, h / 6 * 3.25), col, BF
199.     LINE (w / 6 * 2.25, h / 6 * 3)-(w / 6 * 3.25, h / 6 * 3.5), col, BF
200.     LINE (w / 6 * 2, h / 6 * 3.25)-(w / 6 * 2.5, h / 6 * 3.75), col, BF
201.  
202.     'BOTTOM LINE
203.     LINE (w / 6 * 1.75, h / 6 * 3.75)-(w / 6 * 4.25, h / 6 * 4.25), col, BF
204.     LINE (w / 6 * 1.5, h / 6 * 4)-(w / 6 * 4.5, h / 6 * 4.25), col, BF
205.  
206.     scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, 255), "ZEPPELIN GAMES"
207.     _DISPLAY
208.     _DELAY (3) 'WAIT A BIT
209.  
210.     'FADE THE LOGO AND TEXT OUT
211.     FOR n = 0 TO 255
212.         'LIMIT FPS
213.         _LIMIT 1000
214.         'TOP LINE
215.         LINE (w / 6 * 2, h / 6 * 1.5)-(w / 6 * 4, h / 6 * 2), col, BF
216.         LINE (w / 6 * 1.8, h / 6 * 1.5)-(w / 6 * 4.25, h / 6 * 1.75), col, BF
217.  
218.         'MIDDLE
219.         LINE (w / 6 * 3.5, h / 6 * 2)-(w / 6 * 4, h / 6 * 2.5), col, BF
220.         LINE (w / 6 * 3.25, h / 6 * 2.25)-(w / 6 * 3.75, h / 6 * 3), col, BF
221.         LINE (w / 6 * 2.75, h / 6 * 2.75)-(w / 6 * 3.5, h / 6 * 3.25), col, BF
222.         LINE (w / 6 * 2.25, h / 6 * 3)-(w / 6 * 3.25, h / 6 * 3.5), col, BF
223.         LINE (w / 6 * 2, h / 6 * 3.25)-(w / 6 * 2.5, h / 6 * 3.75), col, BF
224.  
225.         'BOTTOM LINE
226.         LINE (w / 6 * 1.75, h / 6 * 3.75)-(w / 6 * 4.25, h / 6 * 4.25), col, BF
227.         LINE (w / 6 * 1.5, h / 6 * 4)-(w / 6 * 4.5, h / 6 * 4.25), col, BF
228.         col = _RGB(255 - n, 255 - n, 255 - n)
229.  
230.         LINE (w / 10 * 2, h / 10 * 7)-(w / 10 * 8, h / 10 * 8), _RGB(0, 0, 0), BF
231.         scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, 255 - n), "ZEPPELIN GAMES"
232.         _DISPLAY
233.     NEXT n
234.     CLS
235.     _DISPLAY
236.     _DELAY (2)
237.     DrawMenu
238. END SUB
239.  
240. SUB DrawMenu
241.     'FADE IN MENU SCREEN
242.     FOR n = 0 TO 255
243.         _LIMIT 1000
244.         'S
245.         LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3.5, h / 10 * 1.75), col, BF '1ST ACROSS
246.         LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3, h / 10 * 2.5), col, BF '1ST DOWN
247.         LINE (w / 10 * 2.75, h / 10 * 2.5)-(w / 10 * 3.45, h / 10 * 2.75), col, BF '2ND ACROSS
248.         LINE (w / 10 * 3.2, h / 10 * 2.75)-(w / 10 * 3.45, h / 10 * 2.9), col, BF '2ND DOWN
249.         LINE (w / 10 * 3.2, h / 10 * 3.35)-(w / 10 * 3.45, h / 10 * 3.75), col, BF 'EXTENDED 2ND DOWN
250.         LINE (w / 10 * 2.65, h / 10 * 3.75)-(w / 10 * 3.45, h / 10 * 4.1), col, BF '3RD ACROSS
251.  
252.         'L
253.         LINE (w / 10 * 3.8, h / 10 * 1.5)-(w / 10 * 4.05, h / 10 * 2.65), col, BF '1ST DOWN
254.         LINE (w / 10 * 3.8, h / 10 * 3.6)-(w / 10 * 4.05, h / 10 * 3.75), col, BF 'EXTENDED 1ST DOWN
255.         LINE (w / 10 * 3.8, h / 10 * 3.75)-(w / 10 * 4.6, h / 10 * 4.1), col, BF '1ST ACROSS
256.  
257.         'A
258.         LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.1, h / 10 * 2.7), col, BF 'LEFT DOWN
259.         LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 1.8), col, BF 'TOP LINE
260.         LINE (w / 10 * 5.5, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.7), col, BF 'RIGHT DOWN
261.         LINE (w / 10 * 5.55, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.9), col, BF 'RIGHT DOWN EDGE
262.         LINE (w / 10 * 4.85, h / 10 * 2.4)-(w / 10 * 5.75, h / 10 * 2.65), col, BF 'MIDDLE LINE
263.         LINE (w / 10 * 4.85, h / 10 * 3.5)-(w / 10 * 5.1, h / 10 * 4.1), col, BF 'EXTENDED LEFT DOWN
264.         LINE (w / 10 * 5.5, h / 10 * 3.5)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
265.         LINE (w / 10 * 5.55, h / 10 * 3.35)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN EDGE
266.  
267.         'Y
268.         LINE (w / 10 * 6, h / 10 * 1.5)-(w / 10 * 6.25, h / 10 * 2.75), col, BF 'LEFT DOWN
269.         LINE (w / 10 * 6.75, h / 10 * 1.5)-(w / 10 * 7, h / 10 * 3), col, BF 'RIGHT DOWN
270.         LINE (w / 10 * 6, h / 10 * 2.5)-(w / 10 * 7, h / 10 * 2.85), col, BF '1ST ACROSS
271.         LINE (w / 10 * 6.75, h / 10 * 3.25)-(w / 10 * 7, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
272.         LINE (w / 10 * 6, h / 10 * 3.8)-(w / 10 * 7, h / 10 * 4.1), col, BF 'BOTTOM LINE
273.  
274.         'SWORD
275.         LINE (w / 10 * 3, h / 10 * 3)-(w / 10 * 6.5, h / 10 * 3.25), col, BF 'HILT
276.         LINE (w / 10 * 3.5, h / 10 * 2.5)-(w / 10 * 3.75, h / 10 * 3.75), col, BF 'Hand Guard
277.         LINE (w / 10 * 3.75, h / 10 * 2.75)-(w / 10 * 4.75, h / 10 * 3.50), col, BF 'Blade First Layer
278.         LINE (w / 10 * 4.75, h / 10 * 2.85)-(w / 10 * 5.5, h / 10 * 3.4), col, BF 'Blade 2nd Layer
279.         LINE (w / 10 * 5.5, h / 10 * 3.10)-(w / 10 * 7, h / 10 * 3.15), col, BF 'Tip of Blade
280.  
281.         col = _RGB(n, n, n)
282.     NEXT n
283.  
284.     col = _RGB(0, 0, 0)
285.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
286.  
287.     'SHOW ACCOUNT
288.     _PRINTSTRING (5, 5), player.name
289.  
290.     'PRINT MENU OPTIONS
291.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "SINGLE-PLAYER"
292.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "MULTI-PLAYER"
293.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "OPTIONS"
294.     scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "QUIT"
295.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
296.  
297.     'PICK MENU OPTION
298.     opt = 0
299.     col = _RGB(0, 0, 0)
300.     DO
301.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
302.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
303.         _DISPLAY 'REDUCE FLICKERING
304.  
305.         SELECT CASE INKEY$
306.             CASE "s" 'MOVE POINTER DOWN
307.                 IF opt + 1 = 4 THEN
308.                     opt = 0
309.                 ELSE
310.                     opt = opt + 1
311.                 END IF
312.  
313.             CASE "w" 'MOVE POINTER UP
314.                 IF opt - 1 = -1 THEN
315.                     opt = 3
316.                 ELSE
317.                     opt = opt - 1
318.                 END IF
319.  
320.             CASE CHR$(13) 'ENTER KEY
321.                 'SINGLE-PLAYER SELECTED
322.                 IF opt = 0 THEN
323.                     SinglePlayerMenu
324.                 END IF
325.  
326.                 'MULTI-PLAYER SELECTED
327.                 IF opt = 1 THEN
328.                     MultiplayerGameMenu
329.                 END IF
330.  
331.                 'OPTIONS SELETED
332.                 IF opt = 2 THEN
333.                     OptionsMenu
334.                 END IF
335.  
336.                 'QUIT SELECTED
337.                 IF opt = 3 THEN
338.                     SYSTEM
339.                 END IF
340.         END SELECT
341.     LOOP
342. END SUB
343.  
344.  
345. SUB OptionsMenu
346.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
347.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "INFO"
348.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "RESET GAME"
349.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
350.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
351.  
352.     opt = 0
353.     DO
354.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
355.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
356.  
357.         _DISPLAY 'REDUCE FLICKERING
358.  
359.         SELECT CASE INKEY$
360.             CASE "s" 'MOVE POINTER DOWN
361.                 IF opt + 1 = 3 THEN
362.                     opt = 0
363.                 ELSE
364.                     opt = opt + 1
365.                 END IF
366.  
367.             CASE "w" 'MOVE POINTER UP
368.                 IF opt - 1 = -1 THEN
369.                     opt = 2
370.                 ELSE
371.                     opt = opt - 1
372.                 END IF
373.             CASE CHR$(13) 'ENTER PRESSED
374.                 IF opt = 0 THEN 'GAME INFO
375.                     LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
376.                     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "ZEPPELIN GAMES 2018"
377.                     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "SLAY V4"
378.                     scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "ENEMIES KILLED: " + STR$(stats.enemyskilled)
379.                     scaledText w / 2, h / 10 * 6.75, 25, _RGBA(255, 255, 255, 255), "TOTAL DEATHS: " + STR$(stats.totaldeaths)
380.                     scaledText w / 2, h / 10 * 9.25, 14, _RGBA(255, 255, 255, 255), "PRESS ANY KEY TO CONTINUE"
381.  
382.                     _DISPLAY
383.                     DO WHILE INKEY$ = ""
384.                     LOOP
385.                     LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
386.                     OptionsMenu
387.                 END IF
388.                 IF opt = 1 THEN 'RESET GAME
389.                     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
390.                     PRINT #1, ""
391.                     CLOSE #1
392.                     CLS
393.                     RUN "SLAY V4.exe"
394.                 END IF
395.                 IF opt = 2 THEN 'BACK
396.                     DrawMenu
397.                 END IF
398.         END SELECT
399.     LOOP
400. END SUB
401.  
402. SUB SinglePlayerMenu
403.     LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
404.     scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "CAMPAIGN"
405.     scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "INFINITE"
406.     scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
407.     scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
408.  
409.     opt = 0
410.     DO
411.         LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
412.         _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
413.  
414.         _DISPLAY 'REDUCE FLICKERING
415.  
416.         SELECT CASE INKEY$
417.             CASE "s" 'MOVE POINTER DOWN
418.                 IF opt + 1 = 3 THEN
419.                     opt = 0
420.                 ELSE
421.                     opt = opt + 1
422.                 END IF
423.  
424.             CASE "w" 'MOVE POINTER UP
425.                 IF opt - 1 = -1 THEN
426.                     opt = 2
427.                 ELSE
428.                     opt = opt - 1
429.                 END IF
430.             CASE CHR$(13) 'ENTER PRESSED
431.                 IF opt = 0 THEN
432.                     Campaign
433.                 END IF
434.                 IF opt = 1 THEN
435.                     Infinite
436.                 END IF
437.                 IF opt = 2 THEN
438.                     DrawMenu
439.                 END IF
440.         END SELECT
441.     LOOP
442. END SUB
443.  
444. 'CAMPAIGN - STORY
445. SUB Campaign
446.  
447. END SUB
448.  
449. 'PRACTICE - GAMEMODE
450. SUB Infinite
451.     CLS
452.     'DEFINE LOCAL VARS
453.  
454.     DIM health
455.     DIM deltaTime
456.  
457.     playerSpeed = 500
458.     health = 100
459.     pX = _WIDTH / 2 - (playerScale * 2.5)
460.     pY = _HEIGHT / 10 * 8
461.  
462.     sTime = TIMER(.001) 'NEW NEW NEW ####################################
463.  
464.     DO
465.         sTime = TIMER(.001) 'NEW NEW NEW ####################################
466.  
467.         IF _KEYDOWN(100) = -1 THEN
468.             pX = pX + (deltaTime * playerSpeed)
469.         END IF
470.         IF _KEYDOWN(97) = -1 THEN
471.             pX = pX - (deltaTime * playerSpeed)
472.         END IF
473.  
474.         IF pX < 1 THEN
475.             pX = 1
476.         END IF
477.         IF pX > _WIDTH - playerScale * 5 - 1 THEN
478.             pX = _WIDTH - playerScale * 5 - 1
479.         END IF
480.  
481.         LINE (pX - (playerScale * 5) - 1, pY - (playerScale * 5) - 1)-(pX + ((playerScale * 5) * 2), pY + (playerScale * 5) + 1), _RGB(0, 0, 0), BF
482.         PUT (pX, pY), player%()
483.         _DISPLAY
484.  
485.  
486.         eTime = TIMER(.001) 'NEW NEW NEW ####################################
487.         deltaTime = eTime - sTime
488.     LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
489.     CLS
490.     SaveGame
491.     DrawMenu
492. END SUB
493.  
494. 'MULTIPLAYER GAME MENU
495. SUB MultiplayerGameMenu
496.     LINE (w / 10, h / 10 * 4.7)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
497.     _PRINTSTRING (w / 2 - 40, h / 10 * 4.75), "LOCAL"
498.     _PRINTSTRING (w / 2 - 34, h / 10 * 5.25), "LAN"
499.     _PRINTSTRING (w / 2 - 37, h / 10 * 5.75), "BACK"
500.  
501.     opt = 0
502.     DO
503.         LINE (w / 2 - 58, h / 10 * 4.7)-(w / 2 - 70, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
504.         _PRINTSTRING (w / 2 - 65, h / 10 * (4.75 + (0.5 * opt))), ">" 'DISPLAY POINTER
505.  
506.         _DISPLAY 'REDUCE FLICKERING
507.  
508.         SELECT CASE INKEY$
509.             CASE "s" 'MOVE POINTER DOWN
510.                 IF opt + 1 = 3 THEN
511.                     opt = 0
512.                 ELSE
513.                     opt = opt + 1
514.                 END IF
515.  
516.             CASE "w" 'MOVE POINTER UP
517.                 IF opt - 1 = -1 THEN
518.                     opt = 2
519.                 ELSE
520.                     opt = opt - 1
521.                 END IF
522.             CASE CHR$(13) 'ENTER KEY
523.                 IF opt = 0 THEN
524.                     LocalMultiplayer
525.                 ELSEIF opt = 1 THEN
526.                     LANMultiplayer
527.                 ELSEIF opt = 2 THEN
528.                     DrawMenu
529.                 END IF
530.         END SELECT
531.     LOOP UNTIL INKEY$ = CHR$(13)
532. END SUB
533.  
534.  
535. 'MULTIPLAYER ON SAME DEVICE
536. SUB LocalMultiplayer
537.  
538. END SUB
539.  
540. 'MULTIPLAYER OVER WIFI CONNECTION
541. SUB LANMultiplayer
542.  
543.  
544. END SUB
545.  
546. SUB SaveGame
547.     'SAVE VARS TO TXT
548.     OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
549.     'PLAYER
550.     PRINT #1, name$
551.     PRINT #1, player.health
552.     'SAVE DATA
553.     PRINT #1, save.point
554.     'STATS
555.     PRINT #1, stats.enemyskilled
556.     PRINT #1, stats.totaldeaths
557.     CLOSE #1
558. END SUB
559.  
560. SUB LoadSprite (sp%(), scale)
561.     DIM sprite(4, 4)
562.     FOR y = 0 TO 4
563.         FOR x = 0 TO 4
564.             READ sprite(x, y) 'Read the data
565.         NEXT x
566.     NEXT y
567.  
568.     FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
569.         FOR x = 0 TO 4 * scale STEP scale
570.             spriteCol = sprite(x / scale, y / scale)
571.             LINE (x, y)-(x + scale, y + scale), _RGB(spriteCol * 255, spriteCol * 255, spriteCol * 255), BF 'Draw each pixel
572.         NEXT x
573.     NEXT y
574.  
575.     GET (0, 0)-(scale * 5, scale * 5), sp%()
576.     CLS
577.  
578.     'Player Data
579.     DATA 0,1,1,1,0
580.     DATA 0,1,1,1,0
581.     DATA 1,1,1,1,1
582.     DATA 0,1,1,1,0
583.     DATA 0,1,0,1,0
584.  
585. END SUB
586.  
587. SUB scaledText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
588.     fg = _DEFAULTCOLOR
589.     'screen snapshot
590.     cur& = _DEST
591.     I& = _NEWIMAGE(8 * LEN(txt$), 16, 256)
592.     _DEST I&
593.     COLOR K, _RGBA(0, 0, 0, 0)
594.     _PRINTSTRING (0, 0), txt$
595.     mult = textHeight / 16
596.     xlen = LEN(txt$) * 8 * mult
597.     _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
598.     COLOR fg
599.     _FREEIMAGE I&
600. END SUB
601.  

(all changes marked with  'NEW NEW NEW ####################################) :D

EDIT: some other were faster, sorry