How could thicken the compass needle line ?

[acjacques]

Hi;  How I could thicken the compass needle line ?

Code: QB64: [Select]

1. SCREEN 12
2.  
3. CX = 320: CY = 240 'Centre of circle
4. Rad = 100 'Radius
5.  
6. DO
7.    '_LIMIT 100
8.     DO WHILE _MOUSEINPUT: LOOP
9.     mX = _MOUSEX: mY = _MOUSEY
10.     ang = mX
11.   ' rad = mY
12.  
13.     IF ang = 360 THEN ang = 0
14.     IF ang > 360 THEN ang = ang - 360
15.  
16.  
17.     X = CX + COS(_D2R(ang - 90)) * Rad
18.     Y = CY + SIN(_D2R(ang - 90)) * Rad
19.  
20.     pX = CX + COS(_D2R(ang - 90)) * (Rad + 1)
21.     pY = CY + SIN(_D2R(ang - 90)) * (Rad + 1)
22.     LINE (CX, CY)-(oldX, oldY), 0 'clear the old line
23.     LINE (CX, CY)-(X, Y), 14 'yellow needle line
24.     PSET (pX, pY)
25.     oldX = X: oldY = Y
26.     LOCATE 1, 10: PRINT USING "Angle: ###.##"; ang;
27.    'PRINT " mX= "; mX
28.     CIRCLE (CX, CY), 5, 14
29.    _DISPLAY
30. LOOP
31.  
32.  
33.  

[bplus]

This code: https://www.qb64.org/forum/index.php?topic=1810.msg110567#msg110567

Demo's the thic (thick line drawing) SUB that requires the ftri SUB for filling triangles (but you don't have to know how to use that).

hmm... looks like need to switch to 32 bit graphics colors to use that.

[bplus]

Code: QB64: [Select]

1. _TITLE "Compass fix and mod B+ 2019-10-31"
2.  
3. SCREEN _NEWIMAGE(700, 700, 32)
4. _SCREENMOVE 400, 20
5. CX = 350: CY = 350 'Centre of circle
6. Radius = 100 'Radius
7.  
8. DO
9.     CLS
10.     DO WHILE _MOUSEINPUT: LOOP
11.     mX = _MOUSEX: mY = _MOUSEY
12.     ang = _ATAN2(mY - CY, mX - CX)
13.     IF ang < 0 THEN ang = ang + _PI(2)
14.     X = CX + Radius * COS(ang)
15.     Y = CY + Radius * SIN(ang)
16.     thic CX, CY, X, Y, 5, &HFFFFFF00
17.     da = _R2D(ang) + 90
18.     IF da > 360 THEN da = da - 360
19.     LOCATE 1, 10: PRINT USING "Angle: ###.##"; da
20.     CIRCLE (CX, CY), 5, &HFFFFFF00
21.     CIRCLE (CX, CY), Radius, &HFFFFFFFF
22.     _DISPLAY
23.     _LIMIT 60
24. LOOP
25.  
26. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
27.     PD2 = _PI / 2
28.     DIM t2 AS SINGLE, a AS SINGLE, x3 AS SINGLE, y3 AS SINGLE, x4 AS SINGLE, y4 AS SINGLE
29.     DIM x5 AS SINGLE, y5 AS SINGLE, x6 AS SINGLE, y6 AS SINGLE
30.     t2 = thick / 2
31.     IF t2 < 1 THEN t2 = 1
32.     a = _ATAN2(y2 - y1, x2 - x1)
33.     x3 = x1 + t2 * COS(a + PD2)
34.     y3 = y1 + t2 * SIN(a + PD2)
35.     x4 = x1 + t2 * COS(a - PD2)
36.     y4 = y1 + t2 * SIN(a - PD2)
37.     x5 = x2 + t2 * COS(a + PD2)
38.     y5 = y2 + t2 * SIN(a + PD2)
39.     x6 = x2 + t2 * COS(a - PD2)
40.     y6 = y2 + t2 * SIN(a - PD2)
41.     ftri x6, y6, x4, y4, x3, y3, K
42.     ftri x3, y3, x5, y5, x6, y6, K
43. END SUB
44.  
45. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
46.     DIM a&
47.     a& = _NEWIMAGE(1, 1, 32)
48.     _DEST a&
49.     PSET (0, 0), K
50.     _DEST 0
51.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
52.     _FREEIMAGE a& '<<< this is important!
53. END SUB
54.  

EDIT: fix the display angle for more compass like readings

[bplus]

Might look better with filled triangles:

Code: QB64: [Select]

1. _TITLE "Compass 2 fix and mod B+ 2019-10-31"
2.  
3. SCREEN _NEWIMAGE(500, 500, 32)
4. _SCREENMOVE 400, 20
5. CX = 250: CY = 250 'Centre of circle
6. Radius = 200 'Radius
7.  
8. DO
9.     CLS
10.     DO WHILE _MOUSEINPUT: LOOP
11.     mX = _MOUSEX: mY = _MOUSEY
12.     ang = _ATAN2(mY - CY, mX - CX)
13.     IF ang < 0 THEN ang = ang + 2 * _PI
14.     X = CX + Radius * COS(ang)
15.     Y = CY + Radius * SIN(ang)
16.     x1 = CX + 20 * COS(ang + _PI / 2)
17.     y1 = CY + 20 * SIN(ang + _PI / 2)
18.     x2 = CX + 20 * COS(ang - _PI / 2)
19.     y2 = CY + 20 * SIN(ang - _PI / 2)
20.     x3 = CX + Radius * COS(ang - _PI)
21.     y3 = CY + Radius * SIN(ang - _PI)
22.     ftri x1, y1, x2, y2, X, Y, &HFFFFFFFF
23.     ftri x1, y1, x2, y2, x3, y3, &HFF444444
24.     da = _R2D(ang) + 90
25.     IF da >= 360 THEN da = da - 360
26.     LOCATE 1, 10: PRINT USING "Angle: ###.##"; da ' usually want o degrees pointing North
27.     CIRCLE (CX, CY), 5, &HFF000000
28.     i = 0
29.     FOR a = 0 TO _PI(2) STEP _PI(1 / 18)
30.         X = CX + Radius * COS(a)
31.         Y = CY + Radius * SIN(a)
32.         i = i + 1
33.         IF (i - 10) MOD 9 = 0 THEN
34.             CIRCLE (X, Y), 4, &HFFFFFFFF
35.         ELSE
36.             CIRCLE (X, Y), 1, &HFFFFFFFF
37.         END IF
38.     NEXT
39.     _DISPLAY
40.     _LIMIT 60
41. LOOP
42.  
43.  
44. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
45.     DIM a&
46.     a& = _NEWIMAGE(1, 1, 32)
47.     _DEST a&
48.     PSET (0, 0), K
49.     _DEST 0
50.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
51.     _FREEIMAGE a& '<<< this is important!
52. END SUB
53.  
54.  
55.  

[TempodiBasic]

Cool Bplus!
  [ You are not allowed to view this attachment ]  

a fine evolution of compass of acJacques.
Fine idea to share acjacques!

[acjacques]

I made some mods :  Resizeable screen
Visual changes
Text fixed at center

Code: QB64: [Select]

1. $RESIZE:ON
2. 'RESIZE:STRETCH
3. $RESIZE:SMOOTH
4. size = 300 'enter size of window
5. iwidth = size
6. iheight = size
7.  
8. _TITLE "Compass fix and mod B+ 2019-10-31"
9. 'MODIFIED by ACJACQUES 2019-11-02
10.  
11. SCREEN _NEWIMAGE(iwidth, iheight, 32)
12. _SCREENMOVE 400, 20
13. CX = iwidth / 2: CY = iheight / 2 'Centre of circle
14. Radius = size / 3 'Radius
15.  
16.  
17. DO
18.     CLS
19.     _MOUSESHOW "CROSSHAIR" ' will display a crosshair cursor
20.     DO WHILE _MOUSEINPUT: LOOP 'wait for mouse
21.     mX = _MOUSEX: mY = _MOUSEY 'get mouse xy
22.  
23.     ang = _ATAN2(mY - CY, mX - CX)
24.     IF ang < 0 THEN ang = ang + _PI(2)
25.  
26.     X = CX + Radius * COS(ang)
27.     Y = CY + Radius * SIN(ang)
28.     thic CX, CY, X, Y, 3, &HFFFFFF00
29.     da = _R2D(ang) + 90
30.     'IF ang = 360 THEN ang = 0
31.     IF da > 359.99 THEN da = da - 360
32.  
33.  
34.     CIRCLE (CX, CY), 38, &HFFFFFFFF 'white center circle
35.     PAINT (CX, CY), &HFFFFFFFF, &HFFFFFFFF 'filling
36.  
37.     CIRCLE (CX, CY), 37, &HFF000000 'black center circle
38.     PAINT (CX, CY), &HFF000000, &HFF000000 'filling
39.  
40.     CIRCLE (CX, CY), Radius + 3, &HFFFFFFFF 'external white circle
41.  
42.     'LOCATE 10, 10:
43.     'PRINT USING "Angle: ###.##"; da
44.  
45.     da = INT(da) 'make only integer
46.     chrstr$ = STR$(da) 'convert to string
47.  
48.     chrstr$ = RIGHT$("00" + LTRIM$(chrstr$), 3) 'to include leading zeros
49.     COLOR _RGB(255, 255, 0) 'color for text
50.     _PRINTSTRING (CX - 12, CY - 6), chrstr$ ' set position relativve graphic screen with  offsets to be centered
51.     _DISPLAY
52.     _LIMIT 60
53. LOOP
54.  
55. SUB thic (x1, y1, x2, y2, thick, K AS _UNSIGNED LONG)
56.     PD2 = _PI / 3
57.     DIM t2 AS SINGLE, a AS SINGLE, x3 AS SINGLE, y3 AS SINGLE, x4 AS SINGLE, y4 AS SINGLE
58.     DIM x5 AS SINGLE, y5 AS SINGLE, x6 AS SINGLE, y6 AS SINGLE
59.     t2 = thick / 2
60.     IF t2 < 1 THEN t2 = 1
61.     a = _ATAN2(y2 - y1, x2 - x1)
62.     x3 = x1 + t2 * COS(a + PD2)
63.     y3 = y1 + t2 * SIN(a + PD2)
64.     x4 = x1 + t2 * COS(a - PD2)
65.     y4 = y1 + t2 * SIN(a - PD2)
66.     x5 = x2 + t2 * COS(a + PD2)
67.     y5 = y2 + t2 * SIN(a + PD2)
68.     x6 = x2 + t2 * COS(a - PD2)
69.     y6 = y2 + t2 * SIN(a - PD2)
70.     ftri x6, y6, x4, y4, x3, y3, K
71.     ftri x3, y3, x5, y5, x6, y6, K
72. END SUB
73.  
74. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
75.     DIM a&
76.     a& = _NEWIMAGE(1, 1, 32)
77.     _DEST a&
78.     PSET (0, 0), K
79.     _DEST 0
80.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
81.     _FREEIMAGE a& '<<< this is important!
82. END SUB

 [ You are not allowed to view this attachment ]