How to Avoid Conditional DATA line READ Errors?

[Qwerkey]

In the code given here, the first line containing a DATA statement is inside a condition which only happens the first time the code is run.  At any subsequent program run, it is required to ignore that DATA line.

However, when READing for the Parameters!() array input (the subsequent DATA lines), the first elements of Parameters!() are taken from that first DATA line, even though that is not executed.  Is there a way to skillfully avoid that?  In my case, it was easy enough to move the DATA lines for Parameters!() before the original DATA line.

Code: QB64: [Select]

1. IF _FILEEXISTS("ducks.cfg") THEN
2.     OPEN "ducks.cfg" FOR INPUT AS #1
3.     FOR N%% = 0 TO 8
4.         INPUT #1, KeyCode%(N%%)
5.     NEXT N%%
6.     CLOSE #1
7. ELSE
8.     DATA 119,122,97,100,112,46,108,39,115 ' This line is READ even when this condition is not executed
9.     FOR N%% = 0 TO 8
10.         READ KeyCode%(N%%)
11.     NEXT N%%
12. END IF
13.  
14. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
15. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
16. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
17. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
18. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0.005
19. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0.008
20. FOR N%% = 1 TO 6
21.     FOR M%% = 0 TO 15
22.         READ Parameters!(N%%, M%%)
23.     NEXT M%%
24. NEXT N%%

[Petr]

Hi. Something as this?

Code: QB64: [Select]

1. DO
2.     data_block_a$ = "": data_block_b$ = ""
3.     IF INT(TIMER) MOD 2 = 0 THEN
4.         RESTORE data_block_a
5.         READ data_block_a$
6.     ELSE
7.         RESTORE data_block_b
8.         READ data_block_b$
9.     END IF
10.     PRINT data_block_a$, data_block_b$
11. LOOP
12.  
13.  
14. data_block_a:
15. DATA "before"
16.  
17. data_block_b:
18. DATA "after"
19.  
20.  

[Petr]

so directly to your code:

Code: QB64: [Select]

1. IF _FILEEXISTS("ducks.cfg") THEN
2.     OPEN "ducks.cfg" FOR INPUT AS #1
3.     FOR N%% = 0 TO 8
4.         INPUT #1, KeyCode%(N%%)
5.     NEXT N%%
6.     CLOSE #1
7. ELSE
8.     file_not_exists:
9.     DATA 119,122,97,100,112,46,108,39,115: ' This line is READ even when this condition is not executed  ADDED COLON!
10.     RESTORE file_not_exists
11.     FOR N%% = 0 TO 8
12.         READ KeyCode%(N%%)
13.     NEXT N%%
14. END IF
15.  
16.  
17. data_block_2:
18. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
19. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
20. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
21. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0
22. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0.005
23. DATA 0.25,30,1E5,0.02,0.002,0.02,0.01,50,5,50,100,30,5,50,100,0.008
24.  
25. RESTORE data_block_2
26. FOR N%% = 1 TO 6
27.     FOR M%% = 0 TO 15
28.         READ Parameters!(N%%, M%%)
29.     NEXT M%%
30. NEXT N%%
31.  
32.  

and one warning for you. If you use DATA, then character ' must be separated by a colon. Otherwise, READ takes it as part of a DATA block.

[bplus]

Data statements are best placed after main code block - from Wiki

As I remember READ looks for first DATA line regardless of where it sits in program, unless RESTORE is used to set the next DATA READ line.

You can isolate DATA statements in a SUB or FUNCTION only to be READ inside that procedure.

[Cobalt]

Yeah, there is no such thing as 'Conditional Data' as far as I'm aware. the best way to accomplish what it looks like your trying to is use a RESTORE command within the condition to read specific data area. unless its called from within a SUB or FUNCTION as BPlus has said, data is read from top down within the main code. Perhaps a better way is to preload all the data into an array and just call upon the required array area when needed.

[Qwerkey]

Thanks guys.  Look like I should have read the wiki.