Author Topic: gl shaders in text mode... (Read 6060 times)

Petr · « **Reply #15 on:** April 29, 2019, 02:01:34 am »

Fasters, with black characters. See row 106.

Code: QB64: [Select]

'upgrade for real text mod
 
_TITLE "Bouncing Search Lights" 'started 2019-04-28 B+, continued by Petr to REAL TEXT SCREEN :-D
'continued by B+ with normal letter size :-))
 
CONST xmax = 800
CONST ymax = 600
 
DIM txt(1 TO 25) AS STRING, v(1 TO 25)
FOR i = 1 TO 25
    b$ = ""
    FOR j = 1 TO 100
        b$ = b$ + CHR$(INT(RND * 96) + 32)
    NEXT
    txt(i) = b$: v(i) = INT(RND * 3) + 1
NEXT
 
 
balls = 20
DIM x(balls), y(balls), r(balls), c(balls), dx(balls), dy(balls), a(balls), rr(balls), gg(balls), bb(balls)
FOR i = 1 TO balls
    r(i) = rand(10, 65)
    x(i) = rand(r(i), xmax - r(i))
    y(i) = rand(r(i), ymax - r(i))
    c(i) = rand(1, 15)
    dx(i) = rand(1, 5) * rdir
    dy(i) = rand(1, 5) * rdir
    rr(i) = rand(50, 255)
    gg(i) = rand(50, 255)
    bb(i) = rand(50, 255)
NEXT
 
SCREEN 0
 
 
WHILE _KEYDOWN(27) = 0
    Bplus = _NEWIMAGE(xmax, ymax, 32)
    _DEST Bplus
    _SCREENMOVE _MIDDLE
 
 
 
    ' CLS , _RGB32(0, 0, 0)
    FOR i = 1 TO balls
        'ready for collision
        a(i) = _ATAN2(dy(i), dx(i))
        power1 = (dx(i) ^ 2 + dy(i) ^ 2) ^ .5
        imoved = 0
        FOR j = i + 1 TO balls
            IF SQR((x(i) - x(j)) ^ 2 + (y(i) - y(j)) ^ 2) < r(i) + r(j) THEN
                imoved = 1
                a(i) = _ATAN2(y(i) - y(j), x(i) - x(j))
                a(j) = _ATAN2(y(j) - y(i), x(j) - x(i))
                'update new dx, dy for i and j balls
                power2 = (dx(j) ^ 2 + dy(j) ^ 2) ^ .5
                power = (power1 + power2) / 2
                dx(i) = power * COS(a(i))
                dy(i) = power * SIN(a(i))
                dx(j) = power * COS(a(j))
                dy(j) = power * SIN(a(j))
                x(i) = x(i) + dx(i)
                y(i) = y(i) + dy(i)
                x(j) = x(j) + dx(j)
                y(j) = y(j) + dy(j)
                EXIT FOR
            END IF
        NEXT
        IF imoved = 0 THEN
            x(i) = x(i) + dx(i)
            y(i) = y(i) + dy(i)
        END IF
        IF x(i) < r(i) THEN dx(i) = -dx(i): x(i) = r(i)
        IF x(i) > xmax - r(i) THEN dx(i) = -dx(i): x(i) = xmax - r(i)
        IF y(i) < r(i) THEN dy(i) = -dy(i): y(i) = r(i)
        IF y(i) > ymax - r(i) THEN dy(i) = -dy(i): y(i) = ymax - r(i)
 
 
        FOR rad = r(i) TO 0 STEP -1
            fcirc x(i), y(i), rad, _RGBA32(rr(i), gg(i), bb(i), 12)
        NEXT
    NEXT
 
    _SETALPHA 255, _RGBA32(0, 0, 0, 0), Bplus 'much better solution as previous FOR... NEXT loop
 
 
    _SOURCE 0
    _DEST 0 'redirecting to text screen
 
 
    _DEST 0
    Himage = _COPYIMAGE(Bplus, 33)
    _PUTIMAGE (0, 0)-(800, 600), Himage, 0
    Xtranslate = _WIDTH(Bplus) / 8
    Ytranslate = _HEIGHT(Bplus) / 16
 
    FOR i = 1 TO 25
        txt(i) = MID$(txt(i), v(i)) + MID$(txt(i), 1, v(i) - 1)
        FOR l = 1 TO 80
            gX = (Xtranslate + i) * 8
            gY = (-Ytranslate + l) * 16
 
            _SOURCE Bplus
            _DEST 0
            Kolor~& = POINT(gX, gY)
            COLOR 0, 0
            IF Kolor~& <> _RGB32(0, 0, 0) THEN COLOR 0, _RGB(_RED32(Kolor~&), _GREEN32(Kolor~&), _BLUE32(Kolor~&)) 'RGB background for text screen
            LOCATE i, l: PRINT MID$(txt(i), l, 1);
            LOCATE i, l: PRINT MID$(txt(i), l, 1);
 
        NEXT
    NEXT
 
    _DISPLAYORDER _SOFTWARE , _HARDWARE
    _DISPLAY
    _LIMIT 20
    _FREEIMAGE Himage
    _FREEIMAGE Bplus
WEND
 
FUNCTION rand (lo, hi)
    rand = (RND * (hi - lo + 1)) \ 1 + lo
END FUNCTION
 
FUNCTION rdir ()
    IF RND < .5 THEN rdir = -1 ELSE rdir = 1
END FUNCTION
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
    COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
END SUB
 

Petr · « **Reply #16 on:** April 29, 2019, 02:49:57 am »

Or this...

Code: QB64: [Select]

'upgrade for real text mod
 
_TITLE "Bouncing Search Lights" 'started 2019-04-28 B+, continued by Petr to REAL TEXT SCREEN :-D
'continued by B+ with normal letter size :-))
 
CONST xmax = 800
CONST ymax = 600
 
DIM txt(1 TO 25) AS STRING, v(1 TO 25)
FOR i = 1 TO 25
    b$ = ""
    FOR j = 1 TO 100
        b$ = b$ + CHR$(INT(RND * 96) + 32)
    NEXT
    txt(i) = b$: v(i) = INT(RND * 3) + 1
NEXT
 
 
balls = 20
DIM x(balls), y(balls), r(balls), c(balls), dx(balls), dy(balls), a(balls), rr(balls), gg(balls), bb(balls)
FOR i = 1 TO balls
    r(i) = rand(10, 65)
    x(i) = rand(r(i), xmax - r(i))
    y(i) = rand(r(i), ymax - r(i))
    c(i) = rand(1, 15)
    dx(i) = rand(1, 5) * rdir
    dy(i) = rand(1, 5) * rdir
    rr(i) = rand(50, 255)
    gg(i) = rand(50, 255)
    bb(i) = rand(50, 255)
NEXT
 
SCREEN 0
 
 
WHILE _KEYDOWN(27) = 0
    Bplus = _NEWIMAGE(xmax, ymax, 32)
    _DEST Bplus
    _SCREENMOVE _MIDDLE
 
 
 
    ' CLS , _RGB32(0, 0, 0)
    FOR i = 1 TO balls
        'ready for collision
        a(i) = _ATAN2(dy(i), dx(i))
        power1 = (dx(i) ^ 2 + dy(i) ^ 2) ^ .5
        imoved = 0
        FOR j = i + 1 TO balls
            IF SQR((x(i) - x(j)) ^ 2 + (y(i) - y(j)) ^ 2) < r(i) + r(j) THEN
                imoved = 1
                a(i) = _ATAN2(y(i) - y(j), x(i) - x(j))
                a(j) = _ATAN2(y(j) - y(i), x(j) - x(i))
                'update new dx, dy for i and j balls
                power2 = (dx(j) ^ 2 + dy(j) ^ 2) ^ .5
                power = (power1 + power2) / 2
                dx(i) = power * COS(a(i))
                dy(i) = power * SIN(a(i))
                dx(j) = power * COS(a(j))
                dy(j) = power * SIN(a(j))
                x(i) = x(i) + dx(i)
                y(i) = y(i) + dy(i)
                x(j) = x(j) + dx(j)
                y(j) = y(j) + dy(j)
                EXIT FOR
            END IF
        NEXT
        IF imoved = 0 THEN
            x(i) = x(i) + dx(i)
            y(i) = y(i) + dy(i)
        END IF
        IF x(i) < r(i) THEN dx(i) = -dx(i): x(i) = r(i)
        IF x(i) > xmax - r(i) THEN dx(i) = -dx(i): x(i) = xmax - r(i)
        IF y(i) < r(i) THEN dy(i) = -dy(i): y(i) = r(i)
        IF y(i) > ymax - r(i) THEN dy(i) = -dy(i): y(i) = ymax - r(i)
 
 
        FOR rad = r(i) TO 0 STEP -1
            fcirc x(i), y(i), rad, _RGBA32(rr(i), gg(i), bb(i), 12)
        NEXT
    NEXT
 
    _SETALPHA 155, _RGBA32(0, 0, 0, 0), Bplus 'much better solution as previous FOR... NEXT loop
 
 
    _SOURCE 0
    _DEST 0 'redirecting to text screen
 
 
    _DEST 0
    Himage = _COPYIMAGE(Bplus, 33)
    _PUTIMAGE (0, 0)-(800, 600), Himage, 0
    Xtranslate = (_WIDTH(Bplus) / 80) / 8
    Ytranslate = (_HEIGHT(Bplus) / 25) / 16
 
 
    FOR B = 1 TO balls
        RadiusX = r(B) / 2 / 8
        RadiusY = r(B) / 2 / 16
        FOR i = 1 TO 25
            txt(i) = MID$(txt(i), v(i)) + MID$(txt(i), 1, v(i) - 1)
            FOR l = 1 TO 80
 
 
                gX = (Xtranslate + l - RadiusX + 1) * 8
                gY = (Ytranslate + i - RadiusY) * 16
 
                _SOURCE Bplus
                _DEST 0
                COLOR 0
                FOR fy = gY TO gY + 16
                    FOR fx = gX TO gX + 8
                        Kolor~& = POINT(gX, gY)
                        IF _ALPHA32(Kolor~&) < 255 THEN COLOR 0, _RGB(_RED32(Kolor~&), _GREEN32(Kolor~&), _BLUE32(Kolor~&)): GOTO ENDFOR 'RGB background for text screen
                    NEXT
                NEXT
                ENDFOR:
                LOCATE i, l: PRINT MID$(txt(i), l, 1);
                LOCATE i, l: PRINT MID$(txt(i), l, 1);
            NEXT
        NEXT
    NEXT
    _DISPLAYORDER _SOFTWARE , _HARDWARE
    _DISPLAY
    _LIMIT 20
    _FREEIMAGE Himage
    _FREEIMAGE Bplus
WEND
 
FUNCTION rand (lo, hi)
    rand = (RND * (hi - lo + 1)) \ 1 + lo
END FUNCTION
 
FUNCTION rdir ()
    IF RND < .5 THEN rdir = -1 ELSE rdir = 1
END FUNCTION
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
    COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
END SUB
 

PMACKAY · « **Reply #17 on:** April 29, 2019, 05:55:08 am »

This is all great stuff.... thanks guys... :) AWESOME many thanks.....

bplus · « **Reply #18 on:** April 29, 2019, 10:54:53 am »

Here is odd variation that keeps colors but only in the letters!

Code: QB64: [Select]

_TITLE "Bouncing Search Lights" 'started 2019-04-28 B+, continued by Petr to REAL TEXT SCREEN :-D
'continued by B+ with normal letter size :-))
' 2019-04-29 another variation
 
'this really text mode??? ;-))
 
CONST xmax = 640
CONST ymax = 400
 
DIM txt(1 TO 25) AS STRING, v(1 TO 25)
FOR i = 1 TO 25
    b$ = ""
    FOR j = 1 TO 100
        b$ = b$ + CHR$(INT(RND * 96) + 32)
    NEXT
    txt(i) = b$: v(i) = INT(RND * 3) + 1
NEXT
balls = 20
DIM x(balls), y(balls), r(balls), c(balls), dx(balls), dy(balls), a(balls), rr(balls), gg(balls), bb(balls)
FOR i = 1 TO balls
    r(i) = rand(10, 65)
    x(i) = rand(r(i), xmax - r(i))
    y(i) = rand(r(i), ymax - r(i))
    c(i) = rand(1, 15)
    dx(i) = rand(1, 5) * rdir
    dy(i) = rand(1, 5) * rdir
    rr(i) = rand(50, 255)
    gg(i) = rand(50, 255)
    bb(i) = rand(50, 255)
NEXT
Bplus = _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE _MIDDLE
WHILE _KEYDOWN(27) = 0
    _DEST Bplus
    CLS
    FOR i = 1 TO balls
        'ready for collision
        a(i) = _ATAN2(dy(i), dx(i))
        power1 = (dx(i) ^ 2 + dy(i) ^ 2) ^ .5
        imoved = 0
        FOR j = i + 1 TO balls
            IF SQR((x(i) - x(j)) ^ 2 + (y(i) - y(j)) ^ 2) < r(i) + r(j) - 20 THEN
                imoved = 1
                a(i) = _ATAN2(y(i) - y(j), x(i) - x(j))
                a(j) = _ATAN2(y(j) - y(i), x(j) - x(i))
                'update new dx, dy for i and j balls
                power2 = (dx(j) ^ 2 + dy(j) ^ 2) ^ .5
                power = (power1 + power2) / 2
                dx(i) = power * COS(a(i))
                dy(i) = power * SIN(a(i))
                dx(j) = power * COS(a(j))
                dy(j) = power * SIN(a(j))
                x(i) = x(i) + dx(i)
                y(i) = y(i) + dy(i)
                x(j) = x(j) + dx(j)
                y(j) = y(j) + dy(j)
                EXIT FOR
            END IF
        NEXT
        IF imoved = 0 THEN
            x(i) = x(i) + dx(i)
            y(i) = y(i) + dy(i)
        END IF
        IF x(i) < r(i) THEN dx(i) = -dx(i): x(i) = r(i)
        IF x(i) > xmax - r(i) THEN dx(i) = -dx(i): x(i) = xmax - r(i)
        IF y(i) < r(i) THEN dy(i) = -dy(i): y(i) = r(i)
        IF y(i) > ymax - r(i) THEN dy(i) = -dy(i): y(i) = ymax - r(i)
        FOR rad = r(i) TO 0 STEP -1
            fcirc x(i), y(i), rad, _RGBA32(rr(i), gg(i), bb(i), 10)
        NEXT
    NEXT
 
    COLOR 0 '<<< doesn't matter what color but need something?
    FOR i = 1 TO 25
        txt(i) = MID$(txt(i), v(i)) + MID$(txt(i), 1, v(i) - 1)
        LOCATE i, 1: PRINT MID$(txt(i), 1, 80);
    NEXT
 
    _DEST 0 'redirecting to text screen
 
    Himage = _COPYIMAGE(Bplus, 33)
    _PUTIMAGE (0, 0)-(xmax, ymax), Himage, 0
    _DISPLAY
    _LIMIT 15
    _FREEIMAGE Himage
WEND
 
FUNCTION rand (lo, hi)
    rand = (RND * (hi - lo + 1)) \ 1 + lo
END FUNCTION
 
FUNCTION rdir ()
    IF RND < .5 THEN rdir = -1 ELSE rdir = 1
END FUNCTION
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
 

[ You are not allowed to view this attachment ]

Petr · « **Reply #19 on:** April 29, 2019, 01:04:08 pm »

Hi Bplus (Sphere King),

It looks nice, but the text is printed on the graphics screen and uses 32-bit color. To your question on line 73 about color: Because you have a black font on a black background inside a 32-bit image, the font is not visible. Since the COLOR 0 in 32-bit mode returns the same as _RGBA32 (0,0,0,0), then the font is transparent (this cannot be achieved if you put the text on SCREEN 0) and the sphere changes his background color, so then is visible.

It's definitely very nice.

bplus · « **Reply #20 on:** April 29, 2019, 03:21:53 pm »

OHHH! The font is transparent. Yeah because in 32 bit... Same if I have COLOR 9 almost transparent... that's why it didn't make a difference but why I did need COLOR something (very low), forgot I was in 32 bit mode, got it. Thanks Petr

bplus · « **Reply #21 on:** April 29, 2019, 03:31:09 pm »

OK now it is same as graphics mode (I think):

Code: QB64: [Select]

_TITLE "Bouncing Search Lights" 'started 2019-04-28 B+, continued by Petr to REAL TEXT SCREEN :-D
'continued by B+ with normal letter size :-))
' 2019-04-29 another variation
' 2019-04-29 now same as graphics mode!!! Thanks Petr!!!
 
 
'this really text mode??? ;-))
 
CONST xmax = 640
CONST ymax = 400
 
DIM txt(1 TO 25) AS STRING, v(1 TO 25)
FOR i = 1 TO 25
    b$ = ""
    FOR j = 1 TO 100
        b$ = b$ + CHR$(INT(RND * 96) + 32)
    NEXT
    txt(i) = b$: v(i) = INT(RND * 3) + 1
NEXT
balls = 15
DIM x(balls), y(balls), r(balls), c(balls), dx(balls), dy(balls), a(balls), rr(balls), gg(balls), bb(balls)
FOR i = 1 TO balls
    r(i) = rand(10, 65)
    x(i) = rand(r(i), xmax - r(i))
    y(i) = rand(r(i), ymax - r(i))
    c(i) = rand(1, 15)
    dx(i) = rand(1, 5) * rdir
    dy(i) = rand(1, 5) * rdir
    rr(i) = rand(150, 255)
    gg(i) = rand(150, 255)
    bb(i) = rand(150, 255)
NEXT
Bplus = _NEWIMAGE(xmax, ymax, 32)
_SCREENMOVE _MIDDLE
WHILE _KEYDOWN(27) = 0
    _DEST Bplus
    CLS
    FOR i = 1 TO balls
        'ready for collision
        a(i) = _ATAN2(dy(i), dx(i))
        power1 = (dx(i) ^ 2 + dy(i) ^ 2) ^ .5
        imoved = 0
        FOR j = i + 1 TO balls
            IF SQR((x(i) - x(j)) ^ 2 + (y(i) - y(j)) ^ 2) < r(i) + r(j) THEN
                imoved = 1
                a(i) = _ATAN2(y(i) - y(j), x(i) - x(j))
                a(j) = _ATAN2(y(j) - y(i), x(j) - x(i))
                'update new dx, dy for i and j balls
                power2 = (dx(j) ^ 2 + dy(j) ^ 2) ^ .5
                power = (power1 + power2) / 2
                dx(i) = power * COS(a(i))
                dy(i) = power * SIN(a(i))
                dx(j) = power * COS(a(j))
                dy(j) = power * SIN(a(j))
                x(i) = x(i) + dx(i)
                y(i) = y(i) + dy(i)
                x(j) = x(j) + dx(j)
                y(j) = y(j) + dy(j)
                EXIT FOR
            END IF
        NEXT
        IF imoved = 0 THEN
            x(i) = x(i) + dx(i)
            y(i) = y(i) + dy(i)
        END IF
        IF x(i) < r(i) THEN dx(i) = -dx(i): x(i) = r(i)
        IF x(i) > xmax - r(i) THEN dx(i) = -dx(i): x(i) = xmax - r(i)
        IF y(i) < r(i) THEN dy(i) = -dy(i): y(i) = r(i)
        IF y(i) > ymax - r(i) THEN dy(i) = -dy(i): y(i) = ymax - r(i)
        FOR rad = r(i) TO 0 STEP -1
            fcirc x(i), y(i), rad, _RGBA32(rr(i), gg(i), bb(i), 20)
        NEXT
    NEXT
 
    COLOR , _RGBA(0, 0, 0, 0)
    FOR i = 1 TO 25
        txt(i) = MID$(txt(i), v(i)) + MID$(txt(i), 1, v(i) - 1)
        FOR l = 1 TO 80
            IF i MOD 2 THEN midInk 60, 0, 0, 0, 0, 60, l / 80 ELSE midInk 0, 0, 60, 60, 0, 0, l / 80
            LOCATE i, l: PRINT MID$(txt(i), l, 1);
        NEXT
    NEXT
 
    _DEST 0 'redirecting to text screen
 
    Himage = _COPYIMAGE(Bplus, 33)
    _PUTIMAGE (0, 0)-(xmax, ymax), Himage, 0
    _DISPLAY
    _LIMIT 10
    _FREEIMAGE Himage
WEND
 
FUNCTION rand (lo, hi)
    rand = (RND * (hi - lo + 1)) \ 1 + lo
END FUNCTION
 
FUNCTION rdir ()
    IF RND < .5 THEN rdir = -1 ELSE rdir = 1
END FUNCTION
 
SUB fcirc (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
    DIM Radius AS INTEGER, RadiusError AS INTEGER
    DIM X AS INTEGER, Y AS INTEGER
    Radius = ABS(R): RadiusError = -Radius: X = Radius: Y = 0
    IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
    LINE (CX - X, CY)-(CX + X, CY), C, BF
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
    WEND
END SUB
 
SUB midInk (r1%, g1%, b1%, r2%, g2%, b2%, fr##)
    COLOR _RGB32(r1% + (r2% - r1%) * fr##, g1% + (g2% - g1%) * fr##, b1% + (b2% - b1%) * fr##)
END SUB
 
 

EDIT: added the midInk effect with barely seen letters

Petr · « **Reply #22 on:** April 30, 2019, 04:04:35 pm »

Hi. This is again 32bit mode, copyed to SCREEN 0 as background image when done :-D (none _DEST to text screen before print with LOCATE.) MidInk is maybe possible using also on text screen, but not with _RGB32, but _RGB. :-D

PMACKAY · « **Reply #23 on:** May 03, 2019, 01:34:49 am »

My fav bplus is « Last Edit: April 29, 2019, 10:56:23 AM »

Awesome stuff (love the way it looks)

News:

Author Topic: gl shaders in text mode... (Read 6060 times)

Petr

Re: gl shaders in text mode...

Petr

Re: gl shaders in text mode...

PMACKAY

Re: gl shaders in text mode...

bplus

Re: gl shaders in text mode...

Petr

Re: gl shaders in text mode...

bplus

Re: gl shaders in text mode...

bplus

Re: gl shaders in text mode...

Petr

Re: gl shaders in text mode...

PMACKAY

Re: gl shaders in text mode...