Author Topic: Scrollable DOS Screen (Read 4319 times)

hotlnc · « **on:** March 15, 2019, 02:22:33 pm »

Is it possible to use/access the method a modern DOS computer uses to display large number of lines in the DOS window?

For example, in a dos window type "help" and a long help list is displayed. You can scroll up and down this list.

This would be very useful in the tools firmware I use to monitor my industrial cell phones.

FellippeHeitor · « **Reply #1 on:** March 15, 2019, 02:29:20 pm »

Start your program with:

Code: QB64: [Select]

$CONSOLE:ONLY
_DEST _CONSOLE

Pete · « **Reply #2 on:** March 15, 2019, 03:02:05 pm »

Or do you mean just to scroll say 500 lines of text through a 25 line high window? Yes, that can be coded. Something like: FOR i = 1 to 500: PRINT i: NEXT and have a way to scroll back through those numbers would require a routine similar to like this...

Code: QB64: [Select]

WIDTH 80, 25 ' Standard window.
DIM myarray(500) AS STRING * 80 ' Screen width
FOR ii% = 1 TO 500
    myarray(ii%) = LTRIM$(STR$(ii%))
    PRINT myarray(ii%)
NEXT
 
DO
    _LIMIT 30
    b$ = INKEY$
    IF LEN(b$) THEN
        IF b$ = CHR$(27) THEN SYSTEM ' Quit.
        IF b$ = CHR$(0) + "H" AND ii% > 23 THEN
            ' scroll up
            CLS
            ii% = ii% - 23: IF ii% < 24 THEN ii% = 24
            FOR j% = 23 TO 1 STEP -1
                PRINT myarray(ii% - j%)
            NEXT
        END IF
        IF b$ = CHR$(0) + "P" AND ii% < 500 THEN
            ' scroll down
            CLS
            FOR j% = 1 TO 23
                IF ii% > 500 THEN EXIT FOR
                PRINT myarray(ii%)
                ii% = ii% + 1
            NEXT
        END IF
 
    END IF
LOOP

Up and down conditions show two approaches to the math, but there are several others. You can also make routines that scroll one line at a time. In other words you could show a cursor and it would travel up and down, entry by entry, and only scroll the screen when it was going above or below the top or bottom visible line. Anyway, I wouldn't recommend this code, it's too simplistic and if using $CONSOLE:ONLY with _DEST _CONSOLE is all you need, that's even easier!

Pete

hotlnc · « **Reply #3 on:** April 01, 2019, 04:52:24 pm »

Thanks for the replies.

Well I tried the $console lines and it had no effect. I couldn't scroll up to see what scrolled off the upper part of the string.

How could I screw up two lines?

Any thoughts?

Bert22306 · « **Reply #4 on:** April 01, 2019, 07:25:38 pm »

My only thought is, how are you scrolling? Are you using the scroll bar on the right? Or are you trying to use the arrow keys?

In a DOS window, if you try to scroll using the arrow keys, you will instead see a sequence of the most recent inputs you entered into the app.

Here, try this handy little number conversion program, to see what I mean.

Code: QB64: [Select]

REM  Number Conversion - Binary-Hex-Decimal
REM ---------------------------------------
REM OPEN "c:\temp\NumberConversions.txt" FOR OUTPUT AS #1
DIM SHARED dec AS _FLOAT, decin AS _FLOAT, TotDec AS _FLOAT, MSbitVal AS _FLOAT
DIM SHARED DecVal AS _FLOAT, TotDecVal AS _FLOAT, MaxDecVal AS _FLOAT
DIM SHARED TotIntVal AS _FLOAT, IntVal AS _FLOAT, MSbitIntVal AS _FLOAT
DIM SHARED Bit(1000) AS INTEGER, i AS INTEGER, subtract(1000) AS _FLOAT
DIM SHARED Character(128)
1 CALL intro(op$)
IF op$ = "x" THEN
    CLOSE
    END
END IF
IF op$ = "b" THEN CALL BinTo
IF op$ = "i" THEN CALL IntTo(op$)
IF op$ = "d" THEN CALL DecTo(op$)
IF op$ = "h" THEN CALL IntTo(op$)
GOTO 1
END
 
SUB intro (op$)
    $CONSOLE:ONLY
    _DEST _CONSOLE
    $SCREENHIDE
    PRINT "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
    PRINT "NUMBERICAL DEC-BIN-HEX CONVERSIONS"
    PRINT
    PRINT "Binary to decimal and hex = b"
    PRINT "Non-neg integer decimal to binary and hex = i"
    PRINT "Decimal to binary and hex = d"
    PRINT "Hex to decimal and binary = h"
    PRINT
    INPUT "Enter conversion operation (x exits) -> ", op$
END SUB
 
SUB BinTo
    i = 0
    imax = 0
    2 CLS
    INPUT "Enter binary number, MSbit entered first -> ", binnum$
    imax = LEN(binnum$)
    warn = 0
    FOR i = 1 TO imax
        Bit(i) = ASC(binnum$, i)
        IF Bit(i) < 48 OR Bit(i) > 49 THEN warn = 1
        IF Bit(i) = 48 THEN Bit(i) = 0
        IF Bit(i) = 49 THEN Bit(i) = 1
        IF warn = 1 THEN
            PRINT
            COLOR 4, 7
            BEEP
            PRINT "Entered one or more non-binary bits."
            PRINT
            COLOR 1, 7
            INPUT "Continue"; cont$
            EXIT SUB
        END IF
    NEXT i
    CLS
    PRINT "Entered"; imax; "-bit binary value (MSbit left) ="
    FOR i = 1 TO imax
        REM LOCATE 2, 2 * i
        PRINT Bit(i)
    NEXT i
    PRINT
    INPUT "Is this value correct (y/n)"; ans$
    IF ans$ = "n" GOTO 2
    dec = 0
    TotDec = 0
    FOR i = 1 TO imax
        dec = Bit(i) * 2 ^ (imax - i)
        TotDec = TotDec + dec
    NEXT i
    HexNum$ = HEX$(TotDec)
    PRINT
    PRINT "Value as if integer ="; TotDec, "Hex value = "; HexNum$
    PRINT
    REM PRINT #1, "Entered"; imax; "-bit binary value (MSbit top) ="
    FOR i = 1 TO imax
        REM  PRINT #1, Bit(i)
    NEXT i
    REM PRINT #1,
    REM PRINT #1, "Value as if integer ="; TotDec, , "Hex value = "; HexNum$
    INPUT "Enter value of MSbit (negative to indicate 2's complement) -> ", MSbitVal
    TotDecVal = 0
    FOR i = 1 TO imax
        DecVal = ABS(MSbitVal) * Bit(i) / 2 ^ (i - 1)
        TotDecVal = TotDecVal + DecVal
    NEXT i
    IF MSbitVal < 0 AND Bit(1) = 1 THEN TotDecVal = TotDecVal - 2 * ABS(MSbitVal)
    PRINT "Value of binary number = "; TotDecVal
    REM PRINT #1,
    REM PRINT #1, "MSbit (- for 2's complement) = "; MSbitVal, "Value of binary number = "; TotDecVal
    REM PRINT #1, "----------------------------------------"
    REM PRINT #1,
    PRINT
    INPUT "Continue"; cont$
END SUB
 
SUB IntTo (op$)
    CLS
    warn = 0
    IF op$ = "i" THEN
        INPUT "Enter decimal (non-negative integer) -> ", dec
        IF dec < 0 OR dec <> INT(dec) THEN
            PRINT
            COLOR 4, 7
            BEEP
            PRINT "Must enter a non-negative integer."
            PRINT
            COLOR 1, 7
            INPUT "Continue"; cont$
            EXIT SUB
        END IF
        hexnum$ = HEX$(dec)
    ELSE
        INPUT "Enter hex value (0-9, A-F) -> ", hexnum$
        NumChar = LEN(hexnum$)
        FOR i = 1 TO NumChar
            Character(i) = ASC(hexnum$, i)
            IF Character(i) < 48 THEN warn = 1
            IF Character(i) > 57 AND Character(i) < 65 THEN warn = 1
            IF Character(i) > 70 AND Character(i) < 97 THEN warn = 1
            IF Character(i) > 102 THEN warn = 1
        NEXT i
        IF warn = 1 THEN
            PRINT
            COLOR 4, 7
            BEEP
            PRINT "Entered one or more non-hex characters."
            PRINT
            COLOR 1, 7
            INPUT "Continue"; cont$
            EXIT SUB
        END IF
        dec = VAL("&h" + hexnum$)
    END IF
    imax = 0
    n = 0
    DO
        numbits = dec / 2 ^ n
        IF numbits < 1 THEN EXIT DO
        n = n + 1
    LOOP
    IF n - 1 >= 0 THEN
        imax = n - 1
    ELSE imax = 0
    END IF
    PRINT
    PRINT "Decimal value ="; dec, "Hex value = "; UCASE$(hexnum$)
    PRINT
    REM PRINT #1, "Decimal value ="; dec, "Hex value = "; UCASE$(hexnum$)
    REM PRINT #1,
    PRINT "Requires"; imax + 1; "-bit binary value (MSbit left) ="
    REM PRINT #1, "Requires"; imax + 1; "-bit binary value (MSbit top) ="
    FOR i = imax TO 0 STEP -1
        remainder = dec / 2 ^ i
        IF remainder >= 1 THEN
            Bit(i) = 1
            dec = dec - 2 ^ i
        ELSE
            Bit(i) = 0
        END IF
        REM LOCATE 6, 1 + 2 * (imax - i)
        PRINT Bit(i)
        REM  PRINT #1, Bit(i)
    NEXT i
    IF n > 0 THEN
        PRINT
        REM PRINT #1,
        PRINT "MSbit value if non-negative integer ="; 2 ^ imax
        REM PRINT #1, "MSbit value if non-negative integer ="; 2 ^ imax
    END IF
    IF op$ = "h" THEN
        PRINT
        INPUT "Enter value of MSbit (negative to indicate 2's complement) -> ", MSbitVal
        TotDecVal = 0
        FOR i = 0 TO imax
            DecVal = ABS(MSbitVal) * Bit(imax - i) / 2 ^ i
            TotDecVal = TotDecVal + DecVal
        NEXT i
        IF MSbitVal < 0 THEN TotDecVal = TotDecVal - 2 * ABS(MSbitVal)
        PRINT "Value of binary number = "; TotDecVal
        REM PRINT #1,
        REM PRINT #1, "MSbit (- for 2's complement) = "; MSbitVal, "Value of binary number = "; TotDecVal
    END IF
    PRINT
    REM PRINT #1, "----------------------------------------"
    REM PRINT #1,
    INPUT "Continue"; cont$
END SUB
 
SUB DecTo (op$)
    CLS
    4 INPUT "Enter decimal value (negative for 2's complement) -> ", decin
    INPUT "Enter number of bits in binary value (positive integer) -> ", imax
    IF imax = 0 THEN EXIT SUB
    IF imax < 1 OR imax <> INT(imax) THEN
        PRINT
        GOTO 4
    END IF
    INPUT "Enter value of the MSbit (positive number) -> ", MSbitVal
    IF MSbitVal <= 0 THEN
        PRINT
        GOTO 4
    END IF
    IF decin < 0 THEN
        dec = MSbitVal * 2 + decin
    ELSE dec = decin
    END IF
    n = 0
    PRINT
    PRINT "Decimal value = "; decin, "Decimal as positive number ="; dec
    PRINT "MSbit value ="; MSbitVal; "of the"; imax; "-bit binary number"
    PRINT
    REM PRINT #1, "Decimal value = "; decin, "Decimal as positive number ="; dec
    REM PRINT #1, "MSbit value ="; MSbitVal; "of the"; imax; "-bit binary number"
    REM PRINT #1,
    PRINT "Binary value (MSbit left) ="
    REM PRINT #1, "Binary value (MSbit top) ="
    FOR i = 0 TO imax - 1
        subtract(i) = MSbitVal / 2 ^ i
        IF dec - subtract(i) >= 0 THEN
            Bit(i) = 1
            dec = dec - subtract(i)
        ELSE Bit(i) = 0
        END IF
        REM LOCATE 9, 1 + 2 * i
        PRINT Bit(i)
        REM  PRINT #1, Bit(i)
    NEXT i
    REM -------
    REM  Now calculate the actual value produced by the binary number
    REM -------
    TotDecVal = 0
    FOR i = 0 TO imax - 1
        DecVal = MSbitVal * Bit(i) / 2 ^ i
        TotDecVal = TotDecVal + DecVal
    NEXT i
    IF decin < 0 THEN TotDecVal = TotDecVal - 2 * MSbitVal
    REM -------
    REM  Now calculate the positive integer value and hex equivalent
    REM -------
    MSbitIntVal = 2 ^ (imax - 1)
    TotIntVal = 0
    FOR i = 0 TO imax - 1
        IntVal = MSbitIntVal * Bit(i) / 2 ^ i
        TotIntVal = TotIntVal + IntVal
    NEXT i
    PRINT
    PRINT "Actual decimal equivalent = "; TotDecVal, "Positive Integer ="; TotIntVal, "Hex = "; HEX$(TotIntVal)
    PRINT
    REM PRINT #1,
    REM PRINT #1, "Actual decimal equivalent = "; TotDecVal, "Positive Integer ="; TotIntVal, "Hex = "; HEX$(TotIntVal)
    REM PRINT #1, "----------------------------------------"
    REM PRINT #1,
    INPUT "Continue"; cont$
END SUB
 

hotlnc · « **Reply #5 on:** April 01, 2019, 07:51:52 pm »

Thanks for the reply.

I'd like to use the scroll bar on the right. Your program worked great. That's the way I'd like my program to look.

I guess i need to analyze your program and figure out what I'm doing differently.

Compared to your program, my program looks like I wrote it when I was first using a TRS-80 Model 1 to teach myself Basic!

Bert22306 · « **Reply #6 on:** April 01, 2019, 08:18:50 pm »

Thanks, hotInc, but I didn't do anything subtle, wrt your question. So, here's a much shorter program which seems to work for me. See if it works for you. You can just keep the <enter> key pressed, to enter a bunch of zeroes. The you can try scrolling up and down, with the scrool bar on the right.

Code: QB64: [Select]

$CONSOLE:ONLY
_DEST _CONSOLE
$SCREENHIDE
DO
    INPUT "Enter any number (if you enter 100 you exit this loop)"; num
    IF num = 100 THEN EXIT DO
    PRINT "Number entered = "; num
    PRINT
LOOP
END
 

hotlnc · « **Reply #7 on:** April 02, 2019, 10:56:49 am »

That small program worked great.

I moved the three screen format statements below my DIM and shared statements and my screen now is scrollable.

Thanks for all the help guys.

News:

Author Topic: Scrollable DOS Screen (Read 4319 times)

hotlnc

Scrollable DOS Screen

FellippeHeitor

Re: Scrollable DOS Screen

Pete

Re: Scrollable DOS Screen

hotlnc

Re: Scrollable DOS Screen

Bert22306

Re: Scrollable DOS Screen

hotlnc

Re: Scrollable DOS Screen

Bert22306

Re: Scrollable DOS Screen

hotlnc

Re: Scrollable DOS Screen