Question about text attributes in SCREEN 0

[LechU]

Two simple(?) questions:

1. Is it possible to print something on the screen (SCREEN 0) WITHOUT altering old attribytes at cursor position?
2. Is it possible to change attributes of text already displayed at screen (SCREEN 0)?

[Pete]

I suppose the attribute of color comes to mind. You could change that attribute and then rewrite the text to the screen, but a long time ago, I recall doing something with PEEK/POKE to change those attributes, and, if I remember correctly, once the new values were poked into memory, the text already on the screen changed color. Well, it has been over 20 years, so I may be mistaken. Maybe some sort of screen refresh procedure was needed as well. Anyway, it was an interesting concept, which I never needed. IS there something like it in QB64? Maybe. Again, I've never needed a way to change text attributes without rewriting the text, text line, or screen, so I wouldn't know. Rewrites are so fast, it doesn't seem necessary to do it any other way. It will be interesting to see if there is a Qb64, GL, Windows API call, or PEKK/POKE method that is still valid to do what I think you are inquiring about. If this isn't what you mean, please provide a more detailed explanation of what you are trying to achieve, or wait for additional responses.

Pete

[SMcNeill]

Sounds to me as if you're looking for the _MEM commands:

Code: QB64: [Select]

1. SCREEN 0
2.  
3. PRINT "Hello World"
4. SLEEP 'so we can see the original text
5.  
6. DIM m AS _MEM
7. m = _MEMIMAGE(0)
8.  
9. _MEMPUT m, m.OFFSET, 4 AS _UNSIGNED _BYTE 'first, to change the character at 1,1 (Top Left of screen; it should be "H")
10. SLEEP 'so we can see the change, as we changed the "H" to CHR$(4) --- ""
11.  
12. _MEMPUT m, m.OFFSET + 3 * 2 + 1, 4 AS _UNSIGNED _BYTE 'now let's try to change the "3rd" character's color to RED (color value 4)
13. 'If you notice, we actually changed the FOURTH characcter's color to red (the second "l" in "Hello World".
14. 'This makes sense once you realize that memory is mapped starting at 0,0; whereas LOCATE starts at 1,1 in SCREEN 0.
15. 'To work with any particular point for SCREEN 0 memory, we need to remember:
16.  
17. '1) Screen Information is stored in 2 bytes -- First Byte is the character.
18. '                                              Second Byte is the color code.
19.  
20. '2) To convert the screen coordinates to memory coordinates, use the simple formula:
21. '                                              CharacterMemoryPosition = ((Column -1) * _WIDTH + Row -1)) * 2
22. '                                              ColorMemoryPosition =     ((Column -1) * _WIDTH + Row -1)) * 2 + 1
23.  
24. '3) Next tip is to always remember to add the value to m.Offset which is QB64's way to track where the screen information starts in memory
25.  
26.  
27. 'So to make Row 2, Column 1 become a "W", we'd do the following:
28. CharacterMemoryPosition = ((2 - 1) * _WIDTH + 1 - 1) * 2
29. SLEEP 'so we can wait and see the W appear where we want it
30. _MEMPUT m, m.OFFSET + CharacterMemoryPosition, "W"
31. 'And to change that W to being blue, we'd do the following:
32. ColorMemoryPosition = ((2 - 1) * _WIDTH + 1 - 1) * 2 + 1
33. SLEEP 'to see the change one step at a time
34. _MEMPUT m, m.OFFSET + ColorMemoryPosition, 1 AS _UNSIGNED _BYTE
35.  
36.  

[Pete]

I think if I ever decide to look into more QB64 or GL commands, I'd start with _MEM. It's like it's not your grandma's PEEK and POKE. Careful, Steve! :D

Pete

[LechU]

Sounds to me as if you're looking for the _MEM commands:

Code: QB64: [Select]

1. SCREEN 0
2.  
3. PRINT "Hello World"
4. SLEEP 'so we can see the original text
5.  
6. DIM m AS _MEM
7. m = _MEMIMAGE(0)
8.  
9. _MEMPUT m, m.OFFSET, 4 AS _UNSIGNED _BYTE 'first, to change the character at 1,1 (Top Left of screen; it should be "H")
10. SLEEP 'so we can see the change, as we changed the "H" to CHR$(4) --- ""
11.  
12. _MEMPUT m, m.OFFSET + 3 * 2 + 1, 4 AS _UNSIGNED _BYTE 'now let's try to change the "3rd" character's color to RED (color value 4)
13. 'If you notice, we actually changed the FOURTH characcter's color to red (the second "l" in "Hello World".
14. 'This makes sense once you realize that memory is mapped starting at 0,0; whereas LOCATE starts at 1,1 in SCREEN 0.
15. 'To work with any particular point for SCREEN 0 memory, we need to remember:
16.  
17. '1) Screen Information is stored in 2 bytes -- First Byte is the character.
18. '                                              Second Byte is the color code.
19.  
20. '2) To convert the screen coordinates to memory coordinates, use the simple formula:
21. '                                              CharacterMemoryPosition = ((Column -1) * _WIDTH + Row -1)) * 2
22. '                                              ColorMemoryPosition =     ((Column -1) * _WIDTH + Row -1)) * 2 + 1
23.  
24. '3) Next tip is to always remember to add the value to m.Offset which is QB64's way to track where the screen information starts in memory
25.  
26.  
27. 'So to make Row 2, Column 1 become a "W", we'd do the following:
28. CharacterMemoryPosition = ((2 - 1) * _WIDTH + 1 - 1) * 2
29. SLEEP 'so we can wait and see the W appear where we want it
30. _MEMPUT m, m.OFFSET + CharacterMemoryPosition, "W"
31. 'And to change that W to being blue, we'd do the following:
32. ColorMemoryPosition = ((2 - 1) * _WIDTH + 1 - 1) * 2 + 1
33. SLEEP 'to see the change one step at a time
34. _MEMPUT m, m.OFFSET + ColorMemoryPosition, 1 AS _UNSIGNED _BYTE
35.  
36.  

VERY BIG THANKS.
This is exactly what I'm looking for.
THANKS AGAIN.

But. Are You raelly sure that:

        CharacterMemoryPosition = ((Column - 1) * _WIDTH + Row - 1) * 2
        ColorMemoryPosition =     ((Column - 1) * _WIDTH + Row - 1) * 2 + 1

not:

        CharacterMemoryPosition = (Column - 1 + _WIDTH * (Row - 1)) * 2
        ColorMemoryPosition =     (Column - 1 * _WIDTH * (Row - 1)) * 2 + 1


Row and Column swapped?

[SMcNeill]

In graphics, it’s ((y * _WIDTH) + x), so I’ve probably reversed column/row, as I usually work and think in graphical mode coordinates.

LOCATE (row, column) translates to graphical (y, x), so it’d actually be:

((Row * _WIDTH) + Column) * m.ELEMENTSIZE

So you’re right, I got it backwards.  ;)

[Pete]

But. Are You raelly sure that:

Woe, speaking of backwards... Raelly? Oh well, it's not as funny as a clock typo, but I'll take it!

You know before _MEM came along, I had a graphics text screen program that mapped all color and style attributes with a screen reading multi-dimensional array function. _MEM reminds me of that. Steve, I'll have a look at your code sometime soon. It looks like fun.

Pete :D

[Cobalt]

yeah its a very very simple POKE setup;
 DEF SEG = &HB800
  POKE 0 + xloc% + (yloc% * 160), Char%
  POKE 1 + xloc% + (yloc% * 160), colr%
 DEF SEG

or a little more involved, and I mean a little;

Code: QB64: [Select]

1. SUB reaprint (Layer%, x%, y%, text$, col%)
2.  DEF SEG = &HB800
3.  l% = Layer% * 4096
4.  xloc% = x% * 2
5.  yloc% = y%
6.  IF LEN(LTRIM$(RTRIM$(text$))) > 1 THEN
7.   FOR I% = 1 TO LEN(text$)
8.    t$ = MID$(text$, I%, 1)
9.    t% = ASC(t$)
10.    POKE l% + 0 + xloc% + (yloc% * 160), t%
11.    POKE l% + 1 + xloc% + (yloc% * 160), col%
12.    xloc% = xloc% + 2
13.    IF xloc% = 160 THEN xloc% = 0: yloc% = yloc% + 1
14.   NEXT I%
15.  ELSEIF LEN(text$) = 1 THEN
16.   t% = ASC(text$)
17.   POKE l% + 0 + xloc% + (yloc% * 160), t%
18.   POKE l% + 1 + xloc% + (yloc% * 160), col%
19.  END IF
20.  DEF SEG
21. END SUB

[TempodiBasic]

Hi Cobalt
fine sub but without documentation... so I have tried it and now can I write this syntax

REAPRINT (Layer%,X%,Y%, text$, col%)

this sub PRINT on the screen 0 a text with the declared color passed with col%
Parameters:
Layer% is 0 for simple print on the screen
X% starts from 0(column to start to print) , Y% starts from 0 (row to start to print) so you must substract 1 from these cohordinates
Col% is the number of the color used in Screen 0 (range 0-255)

and as a good help must be here and example code

Code: QB64: [Select]

1. SCREEN 0
2. PRINT "Hi I try reaprint,I imagine that first layer% is 0"
3. SLEEP 1
4. reaprint 0, 4, 1, "I", 14
5. SLEEP 1
6. reaprint 0, 6, 1, "t", 4
7. SLEEP 1
8. reaprint 0, 8, 1, "u", 29
9.  
10. SLEEP 3
11. CLS
12. PRINT "Hi I try reaprint with parameter -1 for x% and y%"
13. SLEEP 1
14. reaprint 0, (4 - 1), (1 - 1), "I", 14
15. SLEEP 1
16. reaprint 0, (6 - 1), (1 - 1), "t", 4
17. SLEEP 1
18. reaprint 0, (8 - 1), (1 - 1), "u", 245
19. SLEEP 3
20. CLS
21. FOR a% = 0 TO 255
22.     LOCATE 10, 5: PRINT "Col%"; a%
23.     reaprint 0, 4, 10, "W E", a%
24.     _DELAY .3
25. NEXT
26. END
27.