3D Double Pendulum

[Ashish]

My previous Double Pendulum now comes in 3D!
Press Space for new Pattern.
I've fixed some bugs in the code. Code updated.

Code: QB64: [Select]

1. 'Coded By Ashish on 4 March, 2018
2.  
3. _TITLE "3D Double Pendulum [Press Space for new settings]"
4. SCREEN _NEWIMAGE(800, 600, 32)
5.  
6. TYPE vec3
7.     x AS DOUBLE
8.     y AS DOUBLE
9.     z AS DOUBLE
10. END TYPE
11.  
12. TYPE pendlm
13.     pos AS vec3
14.     r AS DOUBLE
15.     ang AS DOUBLE
16.     angInc AS DOUBLE
17.     angSize AS DOUBLE
18. END TYPE
19.  
20. DECLARE LIBRARY
21.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#)
22.     SUB glutSolidSphere (BYVAL radius AS DOUBLE, BYVAL slices AS LONG, BYVAL stack AS LONG)
23. END DECLARE
24.  
25. DIM SHARED glAllow AS _BYTE
26. DIM SHARED pendulum(1) AS pendlm, t1 AS vec3, t2 AS vec3
27. DIM SHARED tracer(3000) AS vec3, tracerSize AS _UNSIGNED LONG
28. RANDOMIZE TIMER
29.  
30. settings:
31. tracerSize = 0
32. g = 0
33.  
34. pendulum(0).pos.x = 0
35. pendulum(0).pos.y = 0
36. pendulum(0).pos.z = 0
37. pendulum(0).r = p5random(.7, 1.1)
38. pendulum(0).angInc = p5random(0, _PI(2))
39. pendulum(0).angSize = p5random(_PI(.3), _PI(.6))
40.  
41. pendulum(1).r = p5random(.25, .5)
42. pendulum(1).angInc = p5random(0, _PI(2))
43. pendulum(1).angSize = p5random(_PI(.3), _PI(1.1))
44.  
45. glAllow = -1
46. _GLRENDER _BEHIND
47. DO
48.     k& = _KEYHIT
49.     IF k& = ASC(" ") THEN GOTO settings
50.     pendulum(0).ang = SIN(pendulum(0).angInc) * pendulum(0).angSize + _PI(.5)
51.  
52.     t1.x = COS(pendulum(0).ang) * pendulum(0).r + pendulum(0).pos.x
53.     t1.y = SIN(pendulum(0).ang) * pendulum(0).r + pendulum(0).pos.y
54.     t1.z = COS(pendulum(0).ang) * pendulum(0).r + pendulum(0).pos.z
55.  
56.     pendulum(1).pos = t1
57.  
58.     pendulum(1).ang = SIN(pendulum(1).angInc) * pendulum(1).angSize + pendulum(0).ang
59.  
60.     t2.x = COS(pendulum(1).ang) * pendulum(1).r + pendulum(1).pos.x
61.     t2.y = SIN(pendulum(1).ang) * pendulum(1).r + pendulum(1).pos.y
62.     t2.z = SIN(pendulum(1).ang) * pendulum(1).r + pendulum(1).pos.z
63.  
64.     pendulum(0).angInc = pendulum(0).angInc + .02
65.     pendulum(1).angInc = pendulum(1).angInc + .043
66.  
67.     IF tracerSize < UBOUND(tracer) - 1 AND g > 40 THEN tracer(tracerSize) = t2
68.     IF g > 40 AND tracerSize < UBOUND(tracer) - 1 THEN tracerSize = tracerSize + 1
69.  
70.     g = g + 1
71.     _LIMIT 60
72. LOOP
73.  
74. SUB _GL () STATIC
75.     IF NOT glAllow THEN EXIT SUB
76.  
77.     IF NOT glInit THEN
78.         glInit = -1
79.         aspect# = _WIDTH / _HEIGHT
80.         _glViewport 0, 0, _WIDTH, _HEIGHT
81.     END IF
82.  
83.     _glEnable _GL_BLEND
84.     _glEnable _GL_DEPTH_TEST
85.  
86.  
87.     _glShadeModel _GL_SMOOTH
88.  
89.     _glMatrixMode _GL_PROJECTION
90.     _glLoadIdentity
91.     _gluPerspective 45.0, aspect#, 1.0, 1000.0
92.  
93.     _glMatrixMode _GL_MODELVIEW
94.     _glLoadIdentity
95.  
96.     gluLookAt 0, 0, -4, 0, 1, 0, 0, -1, 0
97.  
98.     _glRotatef clock# * 90, 0, 1, 0
99.     _glLineWidth 3.0
100.  
101.     _glPushMatrix
102.  
103.     _glColor4f 1, 1, 1, .7
104.  
105.     _glBegin _GL_LINES
106.     _glVertex3f pendulum(0).pos.x, pendulum(0).pos.y, pendulum(0).pos.z
107.     _glVertex3f t1.x, t1.y, t1.z
108.     _glEnd
109.     _glPopMatrix
110.  
111.     _glPushMatrix
112.  
113.     _glBegin _GL_LINES
114.     _glVertex3f t1.x, t1.y, t1.z
115.     _glVertex3f t2.x, t2.y, t2.z
116.     _glEnd
117.  
118.     IF tracerSize > 3 THEN
119.         _glBegin _GL_LINES
120.         FOR i = 0 TO tracerSize - 2
121.             _glColor3f 0, map(tracer(i).x, -1, 1, .5, 1), map(tracer(i).y, -1, 1, .5, 1)
122.             _glVertex3f tracer(i).x, tracer(i).y, tracer(i).z
123.             _glColor3f 0, map(tracer(i + 1).x, -1, 1, .5, 1), map(tracer(i + 1).y, -1, 1, .5, 1)
124.             _glVertex3f tracer(i + 1).x, tracer(i + 1).y, tracer(i + 1).z
125.         NEXT
126.         _glEnd
127.     END IF
128.     _glPopMatrix
129.  
130.     _glEnable _GL_LIGHTING
131.     _glEnable _GL_LIGHT0
132.     _glPushMatrix
133.     _glTranslatef t1.x, t1.y, t1.z
134.  
135.     _glColor3f .8, .8, .8
136.     glutSolidSphere .1, 15, 15
137.     _glPopMatrix
138.  
139.     _glPushMatrix
140.     _glTranslatef t2.x, t2.y, t2.z
141.  
142.     _glColor3f .8, .8, .8
143.     glutSolidSphere .1, 15, 15
144.     _glPopMatrix
145.  
146.     clock# = clock# + .01
147.  
148.     _glFlush
149. END SUB
150.  
151.  
152.  
153. 'taken from p5js.bas
154. 'https://bit.y/p5jsbas
155. FUNCTION p5random! (mn!, mx!)
156.     IF mn! > mx! THEN
157.         SWAP mn!, mx!
158.     END IF
159.     p5random! = RND * (mx! - mn!) + mn!
160. END FUNCTION
161.  
162. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
163.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
164. END FUNCTION
165.  

[FellippeHeitor]

That looks really good, Ashish!

[Ashish]

That looks really good, Ashish!

Thanks ;D

[Pete]

Admittedly, I'm not a fan of graphics programs, especially geometric ones.  I'm more of a practical math type. I do get the fascination factor, which in my opinion is a prime component of learning. I'm just blabbering on because I think I recall this poster is 14. I'm too old to be in touch with the programming skills that will be needed in the next decade but I'd feel pretty safe in stating if a 14yr old can put something like this together, it might be worth it for him to investigate what the future in computer programming holds.

Pete

PS I wasn't wild about the trail, but the pure 3-d pendulums were very professional looking. It certainly could be a modern screen saver app.

[Ashish]

Admittedly, I'm not a fan of graphics programs, especially geometric ones.  I'm more of a practical math type. I do get the fascination factor, which in my opinion is a prime component of learning. I'm just blabbering on because I think I recall this poster is 14. I'm too old to be in touch with the programming skills that will be needed in the next decade but I'd feel pretty safe in stating if a 14yr old can put something like this together, it might be worth it for him to investigate what the future in computer programming holds.

Pete

PS I wasn't wild about the trail, but the pure 3-d pendulums were very professional looking. It certainly could be a modern screen saver app.

Glad you like it. I've came to knew earlier that future programming is Artificial Intelligence. I have tried to learn it a year ago, but it was very complex and the video I watched was above my head. ;D
BTW, I will be able to learn AI before 18.

[Pete]

I prefer natural intelligence over the artificial variety. When I come back, I want my brain taken out of the jar and re-installed. Yep, all original parts in this bad boy. You know this type of science keeps getting more and more expensive as it gets closer to reality but me being the astute businessman I am, well,  I was smart enough to get in on it before the price started increasing. That's right, in 2008 I had my brain removed and put in a jar. The only ill effects I noted that year were taking over the N54 QBasic Forum and voting for Obama. You know what, you may have something there with the whole AI concept after all.

Pete :D   

[keybone]

Reminds me of an old Windows 3.x screensaver or Windows 9x for that matter.

Well done.

[Ashish]

Reminds me of an old Windows 3.x screensaver or Windows 9x for that matter.

Well done.

Thanks Keybone! ;D

[Qwerkey]

Ashish, this is a remarkable achievement.  I may want to ask you some questions on this, if you are agreeable.

[Ashish]

Ashish, this is a remarkable achievement.  I may want to ask you some questions on this, if you are agreeable.

You don't need to take permission for asking any thing related to this topic. What are your questions?