Seeking best ellipse fill function. (For everyone's sake.)

[bplus]

Alrighty, considering using this for the final submission. Super bare-bones as it should be (whoever wants some backstory will be able to click a link to this thread). The obvious contributors are, in ABC order, bplus, pete, smcneill, and yours truly. Anyone not in favor, speak now or forever hold your peace. (I'm interested in moving on to the next thing, as is probably everyone.)

I made an effort to unify the notation, so if you *do* have an edit to make, use what's posted below, or make sure the notation is maintained.

EDIT

Opps, didn't add the un-filled, yes-tilted ellipse yet. Luckily this is so easy even *I* can do that, as it won't be needing any newfangled underscore technology. Just my original post without the PAINT statement.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2.  
3. DIM TransRed AS _UNSIGNED LONG
4. DIM TransGreen AS _UNSIGNED LONG
5. DIM TransBlue AS _UNSIGNED LONG
6. TransRed = _RGBA(255, 0, 0, 128)
7. TransGreen = _RGBA(0, 255, 0, 128)
8. TransBlue = _RGBA(0, 0, 255, 128)
9.  
10. CALL CircleFill(100, 100, 75, TransRed)
11. CALL CircleFill(120, 120, 75, TransBlue)
12.  
13. CALL EllipseFill(550, 100, 150, 75, TransBlue)
14. CALL EllipseFill(570, 120, 150, 75, TransGreen)
15.  
16. CALL EllipseTiltFill(0, 350, 400, 150, 75, 3.14 / 6, TransGreen)
17. CALL EllipseTiltFill(0, 370, 420, 150, 75, 3.14 / 4, TransRed)
18.  
19. END
20.  
21. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
22.     ' CX = center x coordinate
23.     ' CY = center y coordinate
24.     '  R = radius
25.     '  C = fill color
26.     DIM Radius AS INTEGER, RadiusError AS INTEGER
27.     DIM X AS INTEGER, Y AS INTEGER
28.     Radius = ABS(R)
29.     RadiusError = -Radius
30.     X = Radius
31.     Y = 0
32.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
33.     LINE (CX - X, CY)-(CX + X, CY), C, BF
34.     WHILE X > Y
35.         RadiusError = RadiusError + Y * 2 + 1
36.         IF RadiusError >= 0 THEN
37.             IF X <> Y + 1 THEN
38.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
39.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
40.             END IF
41.             X = X - 1
42.             RadiusError = RadiusError - X * 2
43.         END IF
44.         Y = Y + 1
45.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
46.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
47.     WEND
48. END SUB
49.  
50. SUB EllipseFill (CX AS INTEGER, CY AS INTEGER, a AS INTEGER, b AS INTEGER, C AS _UNSIGNED LONG)
51.     ' CX = center x coordinate
52.     ' CY = center y coordinate
53.     '  a = semimajor axis
54.     '  b = semiminor axis
55.     '  C = fill color
56.     IF a = 0 OR b = 0 THEN EXIT SUB
57.     DIM h2 AS _INTEGER64
58.     DIM w2 AS _INTEGER64
59.     DIM h2w2 AS _INTEGER64
60.     DIM x AS INTEGER
61.     DIM y AS INTEGER
62.     w2 = a * a
63.     h2 = b * b
64.     h2w2 = h2 * w2
65.     LINE (CX - a, CY)-(CX + a, CY), C, BF
66.     DO WHILE y < b
67.         y = y + 1
68.         x = SQR((h2w2 - y * y * w2) \ h2)
69.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
70.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
71.     LOOP
72. END SUB
73.  
74. SUB EllipseTiltFill (destHandle&, CX, CY, a, b, ang, C AS _UNSIGNED LONG)
75.     '  destHandle& = destination handle
76.     '  CX = center x coordinate
77.     '  CY = center y coordinate
78.     '   a = semimajor axis
79.     '   b = semiminor axis
80.     ' ang = clockwise orientation of semimajor axis in radians (0 default)
81.     '   C = fill color
82.     DIM max AS INTEGER, mx2 AS INTEGER, i AS INTEGER, j AS INTEGER
83.     DIM prc AS _UNSIGNED LONG
84.     DIM D AS INTEGER, S AS INTEGER
85.     D = _DEST: S = _SOURCE
86.     prc = _RGB32(255, 255, 255, 255)
87.     IF a > b THEN max = a + 1 ELSE max = b + 1
88.     mx2 = max + max
89.     tef& = _NEWIMAGE(mx2, mx2)
90.     _DEST tef&
91.     _SOURCE tef&
92.     FOR k = 0 TO 6.283185307179586 + .025 STEP .025
93.         i = max + a * COS(k) * COS(ang) + b * SIN(k) * SIN(ang)
94.         j = max + a * COS(k) * SIN(ang) - b * SIN(k) * COS(ang)
95.         IF k <> 0 THEN
96.             LINE (lasti, lastj)-(i, j), prc
97.         ELSE
98.             PSET (i, j), prc
99.         END IF
100.         lasti = i: lastj = j
101.     NEXT
102.     DIM xleft(mx2) AS INTEGER, xright(mx2) AS INTEGER, x AS INTEGER, y AS INTEGER
103.     FOR y = 0 TO mx2
104.         x = 0
105.         WHILE POINT(x, y) <> prc AND x < mx2
106.             x = x + 1
107.         WEND
108.         xleft(y) = x
109.         WHILE POINT(x, y) = prc AND x < mx2
110.             x = x + 1
111.         WEND
112.         WHILE POINT(x, y) <> prc AND x < mx2
113.             x = x + 1
114.         WEND
115.         IF x = mx2 THEN xright(y) = xleft(y) ELSE xright(y) = x
116.     NEXT
117.     _DEST destHandle&
118.     FOR y = 0 TO mx2
119.         IF xleft(y) <> mx2 THEN LINE (xleft(y) + CX - max, y + CY - max)-(xright(y) + CX - max, y + CY - max), C, BF
120.     NEXT
121.     _DEST D: _DEST S
122.     _FREEIMAGE tef&
123. END SUB
124.  

A couple of things just from quick scan of Bill's 2nd final complete code post (above):

Bill:

Opps, didn't add the un-filled, yes-tilted ellipse yet. Luckily this is so easy even *I* can do that, as it won't be needing any newfangled underscore technology. Just my original post without the PAINT statement.

Bill that had problems using the Cartesian coordinate system with y-axis flipped and angles increasing in counter-clockwise direction. Build the Tilted Ellipse code from the TiltedEllipseFill code.

The a and b parameters represent NOT the major and minor axis respectively but the x and y axis respectively ie a is not always greater than or equal to b. And the angle of tilt when 0, would put the a radius parallel with the x-axis.

[STxAxTIC]

crap, ran out of time for this, probably for weeks to come

ask Fell or luke for librarian creds

[bplus]

... dang it, Bill had something else posted that I was replying to, now gone.

OK tested EllipseTilt and Bill did not use the original one without the PAINT because the current one fits TiltedEllipseFill and is changing angle correctly to Basic system coordinates. I still object to descriptions of a and b parameters and offer an alternate wording closer to the actual facts.

Code: QB64: [Select]

1. _TITLE "Tilted Ellipse Angle test" ' B+ 2019-02-16 check Bill's code for EllipseTilt
2.  
3. SCREEN _NEWIMAGE(1000, 700, 32)
4. _SCREENMOVE 100, 20
5. CX = 500
6. CY = 350
7. a = 100
8. b = 340
9.  
10. FOR ang = 0 TO 2 * _PI STEP _PI(2 / 12) 'draw ellipse at various heights and compare to CIRCLE with aspect i/300
11.     CLS
12.     PRINT "Angle tilt:"; INT(_R2D(ang) + .5)
13.     TiltedEllipseFill 0, CX, CY, a, b, 0, _RGBA(255, 255, 255, 40)
14.     TiltedEllipseFill 0, CX, CY, a, b, ang, _RGBA(255, 255, 255, 100)
15.     EllipseTilt CX, CY, a, b, ang, _RGBA(255, 255, 255, 100)
16.     CIRCLE (CX, CY), a
17.     CIRCLE (CX, CY), b
18.     LINE (CX, CY)-(CX + a * COS(ang), CY + a * SIN(ang))
19.     _DISPLAY
20.     IF a = _PI(2 / 12) THEN _DELAY 5 ELSE _LIMIT 1
21. NEXT
22.  
23. SUB TiltedEllipseFill (destHandle&, ox, oy, a, b, ang, col AS _UNSIGNED LONG)
24.     DIM max AS INTEGER, mx2 AS INTEGER, i AS INTEGER, j AS INTEGER
25.     DIM prc AS _UNSIGNED LONG
26.  
27.     DIM D AS INTEGER, S AS INTEGER 'to preserve old settings
28.     D = _DEST: S = _SOURCE
29.  
30.     prc = _RGB32(255, 255, 255, 255)
31.     IF a > b THEN max = a + 1 ELSE max = b + 1
32.     mx2 = max + max
33.     tef& = _NEWIMAGE(mx2, mx2)
34.     _DEST tef&
35.     _SOURCE tef& 'point wont read without this!
36.     FOR k = 0 TO 6.2832 + .05 STEP .1
37.         i = max + a * COS(k) * COS(ang) + b * SIN(k) * SIN(ang)
38.         j = max + a * COS(k) * SIN(ang) - b * SIN(k) * COS(ang)
39.         IF k <> 0 THEN
40.             LINE (lasti, lastj)-(i, j), prc
41.         ELSE
42.             PSET (i, j), prc
43.         END IF
44.         lasti = i: lastj = j
45.     NEXT
46.     DIM xleft(mx2) AS INTEGER, xright(mx2) AS INTEGER, x AS INTEGER, y AS INTEGER
47.     FOR y = 0 TO mx2
48.         x = 0
49.         WHILE POINT(x, y) <> prc AND x < mx2
50.             x = x + 1
51.         WEND
52.         xleft(y) = x
53.         WHILE POINT(x, y) = prc AND x < mx2
54.             x = x + 1
55.         WEND
56.         WHILE POINT(x, y) <> prc AND x < mx2
57.             x = x + 1
58.         WEND
59.         IF x = mx2 THEN xright(y) = xleft(y) ELSE xright(y) = x
60.     NEXT
61.     _DEST destHandle&
62.     FOR y = 0 TO mx2
63.         IF xleft(y) <> mx2 THEN LINE (xleft(y) + ox - max, y + oy - max)-(xright(y) + ox - max, y + oy - max), col, BF
64.     NEXT
65.     _DEST D: _DEST S 'restore those old settings
66.     _FREEIMAGE tef&
67. END SUB
68.  
69. SUB EllipseTilt (CX, CY, a, b, ang, C AS _UNSIGNED LONG) 'by STATIC
70.     '  CX = center x coordinate
71.     '  CY = center y coordinate
72.     '   a = Flat ellipse x-axis   '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< B+ changed comment
73.     '   b = Flat ellipse y-axis   '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< B+ changed comment
74.     ' ang = clockwise orientation of semimajor axis in radians (0 default)
75.     '   C = fill color
76.     FOR k = 0 TO 6.283185307179586 + .025 STEP .025
77.         i = a * COS(k) * COS(ang) + b * SIN(k) * SIN(ang)
78.         j = -a * COS(k) * SIN(ang) + b * SIN(k) * COS(ang)
79.         i = i + CX
80.         j = -j + CY
81.         IF k <> 0 THEN
82.             LINE -(i, j), C
83.         ELSE
84.             PSET (i, j), C
85.         END IF
86.     NEXT
87. END SUB
88.  
89.  
90.