Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.

Messages - Qbee

Pages: [1] 2

Programs / Re: QB64-SDL 2020

« on: January 09, 2020, 10:08:00 am »

Quote from: SMcNeill on January 09, 2020, 09:59:45 am

Cleaned up some more of the code to remove further references to the old SDL update procedure. Back in the day, SDL used to call up [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there], see if a newer version of itself existed, and then, if so, upgrade itself for us. Now, however, [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] is a hacker's site -- Galleon no longer maintains it and nobody knows who the crap registered it and put it back up on the net -- so it's not a place that one wants to visit ever. Going there isn't going to update crap -- it'll just lock up the update process as it freezes waiting for a non-existent response to come back to it -- and there's no reason to give that bogus site your IP address, or anything else.

If it is so, then
a) the complete wiki should be searched for links to that site and those links removed; I had one some days/weeks ago
b) this complete Forum should be searched for links to that site and those links removed; I am sure, I saw some links to that site in this forum

To know here are links to hacker-site(s) is no good feeling.

QB64 Discussion / Re: QB64 Oddness at Work

« on: January 08, 2020, 12:05:24 pm »

Quote from: Qbee on January 08, 2020, 07:48:08 am

Watching the results made me think of "Weird Scenes Inside the Goldmine".
Long forgotten ... thank you for make me think of that.

Couldn't resist - went into the city and bought it - AGAIN.

QB64 Discussion / Re: QB64 Oddness at Work

« on: January 08, 2020, 07:48:08 am »

Watching the results made me think of "Weird Scenes Inside the Goldmine".
Long forgotten ... thank you for make me think of that.

Programs / Re: Northern Lights

« on: January 06, 2020, 04:27:32 pm »

I use GIF Movie Gear (Full version).
It is a little bit old, supports Windows XP, but works fine with Windows 10.

Programs / Re: Northern Lights

« on: January 06, 2020, 04:02:31 pm »

Aurora and Ribbon Candy by rfrost@mail.com and Aurora-Mod by bplus look all interesting.

To show guests, who otherwise have to imagine the beauty directly from code, I made a very short (a few seconds, but still takes nearly 14 MB after reducing from 74 MB) GIF-Animation from the Aurora-Mod.

Programs / Re: Hello physics

« on: January 05, 2020, 07:46:42 pm »

Quote from: dajan on January 05, 2020, 06:25:13 pm

Time to add some bit more advanced features. Ball-rim collisions would be nice, but it also means giving up my original code minimalism idea. Never mind, I think it is woth it.
What do you think:

Was fun :)

I added "a$ = INKEY$" as last line to make a screenshot: 10 Points isn't bad, or ?

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

« on: January 05, 2020, 03:54:49 pm »

Quote from: bplus on January 05, 2020, 03:08:06 pm

The 4th in the USA means the forth of July unless you are an obsessive Star Wars fan, then it means "may the forth be with you" :D

Ah, ok, thanks for clearing.

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

« on: January 05, 2020, 02:30:43 pm »

"Duration": Mostly the Fireworks are replaced by others too fast, in my opinion. The fireworks have not enough time to "burn down". These times should be longer, but accordiing to the actual firework.

"Replacements": It looks like the fireworks can't "burn down", because they are replaced by new fireworks. This is too obvious, I think. I assume the array for "active" fireworks is to small, so that new fireworks replaces older ones, even if they only started a short time before.

"next year or the 4th" means next year or in 4 years? I am sure I misunderstand what it really means.

[ways of] 3D-spheres sounds interesting, too.

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

« on: January 05, 2020, 01:25:16 pm »

Quote from: bplus on December 31, 2019, 04:03:44 pm

How do you top 2018's code show?

That is really a nice show!
How to top that? Only by improving, for instance:
- fullscreen (to fit my 1024px-Screen that I need for my old blue eyes)
- keyhit to escape from program
- gravity
- duration
- replacements
- some kind of parallax effects (i. e. moving visitors (?) )
- sound (yes! bombastic firework sound and pathetic music)

Great also the mirroring of the fireworks.

I am glad to have another year to do my very best :)
And thanks, @bplus, for sharing (again) :)

QB64 Discussion / Re: _SCREENPRINT for Mouse ?

« on: January 03, 2020, 06:49:35 am »

Thank you, @RhoSigma . That will help.

QB64 Discussion / _SCREENPRINT for Mouse ?

« on: January 03, 2020, 05:49:36 am »

Hello,

in the wiki I found some codes with which text can be entered in an external program, i. e. notepad, using _SCREENPRINT.

Moving the mouse in the local program works using _MOUSEMOVE.
What I try is
- to get the mouse position from outside the local program and
- to move the mouse in (and send mouse clicks to) an external program.

Is there a way to do that ?

Programs / Re: Pathfinder

« on: December 18, 2019, 08:41:41 pm »

Quote from: bplus on August 11, 2018, 06:31:07 pm

That is pretty cool!

Alas, I have started to reinvent the wheel. Now I have something to compare my experiments with. Thanks!

Programs / Re: Pathfinder

« on: December 18, 2019, 11:27:18 am »

Ok.
So needs 2 tasks:
- code for creating mazes
- code for running the mazes

Programs / Re: Pathfinder

« on: December 18, 2019, 07:30:35 am »

Attached it to the post.

Programs / Pathfinder

« on: December 18, 2019, 06:30:22 am »

Hello,

I managed to create a pathfinding tool, named "Pathfinder 1.0 for QB64v1.3", that finds a path from point A to point B, if there is a path. If no path exists, the tool will recognize that and give a message. Otherwise the path is shown on the map.
Actually the map has a size of 100 x 100 fields on a 800 x 600 pixel screen. The values can (slightly?) be changed to test on others mapsizes; calculations are installed in that way that they can handle variable parameters.
It's far from beeing optimal, but at least it does it's job :)

Animated GIF (Thumb)

Code: QB64: [Select]

OPTION _EXPLICIT
'$include:'CONSTANTS_Color.BI'
_TITLE "Pathfinder v1.0 for QB64v1.3"
' done 2019-12-17 to 2019-12-18
' by Myself (Karsten Maske)
'
' ESC to exit program
' any other key restarts with creating a new random map
'
 
CONST SW = 800
CONST SH = 600
CONST MAPWIDTH = 100 ' 100 on 800 * 600 => 8 pixel width
CONST MAPHEIGHT = 100 ' 100 on 800 * 600 => 6 pixel height
CONST MINX = 1
CONST MAXX = MAPWIDTH
CONST MINY = 1
CONST MAXY = MAPHEIGHT
CONST SQUAREWIDTH = SW / MAPWIDTH
CONST SQUAREHEIGHT = SH / MAPHEIGHT
CONST COST = 1 ' move cost from one square to another; horizontal/vertical = diagonal
CONST YOUSHALLNOTPASS = 32000 ' !! signed integer, stay within positive values
 
TYPE typeNode
    id AS INTEGER ' calculated as y * MAPWIDTH + x
    x AS INTEGER
    y AS INTEGER
    f AS SINGLE '   f(x) = g(x) + c + h(x)
    p AS INTEGER '  previous Node (nodeID)
    oo AS INTEGER ' 1 = on OpenList
    oc AS INTEGER ' 1 = on ClosedList
END TYPE
 
DIM SHARED Nodes(0 TO (MAXY - MINY) * MAPWIDTH + (MAXX - MINX)) AS typeNode
DIM SHARED Map(MINX TO MAXX, MINY TO MAXY) AS INTEGER
DIM SHARED startX AS INTEGER
DIM SHARED startY AS INTEGER
DIM SHARED endX AS INTEGER
DIM SHARED endY AS INTEGER
DIM SHARED bPathFound AS INTEGER
DIM SHARED bNoPathFound AS INTEGER
DIM SHARED startID AS INTEGER
DIM SHARED endID AS INTEGER
DIM id AS INTEGER
DIM a AS STRING
 
' #############################################################################################################
' <- Definitions
' -> Initialization
' #############################################################################################################
 
SCREEN _NEWIMAGE(SW, SH, 32)
 
DO
    CLS
 
    bPathFound = 0
    bNoPathFound = 0
    startX = 6
    startY = MAPHEIGHT - 6
    endX = MAPWIDTH - 6
    endY = 6
 
    InitNodes
    InitMap
    SetWall INT(MAPWIDTH / 2), INT(MAPHEIGHT / 4), INT(MAPWIDTH / 2) + 1, MAPHEIGHT - 5
    SetWall INT(MAPWIDTH / 2) + 1, MAPHEIGHT - 6, INT(MAPWIDTH / 3), MAPHEIGHT - 7
    FOR id = 1 TO 250
        RandomBlock
    NEXT
    PaintMap
    ShowCrow
 
    endID = GetIdFromXY(endX, endY)
    id = GetIdFromXY(startX, startY)
    startID = id
    Nodes(id).x = startX
    Nodes(id).y = startY
    Nodes(id).id = id
    Nodes(id).f = SQR(((startX - endX) ^ 2) + ((startY - endY) ^ 2)) ' only h(x)
    Nodes(id).p = 0
    Nodes(id).oo = 1 ' put on open list
    Nodes(id).oc = 0
 
    ' #############################################################################################################
    ' <- Initialization
    ' -> Main
    ' #############################################################################################################
 
    DO
        _LIMIT 1000
        GetNeighbours
 
    LOOP WHILE (bPathFound = 0) AND (bNoPathFound = 0)
 
    LOCATE 1, 1
    IF bPathFound = 1 THEN
        PRINT "Path found!"
        ShowPath
    ELSEIF bNoPathFound = 1 THEN
        PRINT "No path found!"
    ELSE
        PRINT "Nothing"
    END IF
 
    DO
        a = INKEY$
    LOOP WHILE a = ""
 
LOOP WHILE a <> CHR$(27)
SYSTEM
 
' #############################################################################################################
' <- Main
' -> helper
' #############################################################################################################
 
FUNCTION GetIdFromXY (x AS INTEGER, y AS INTEGER)
    GetIdFromXY = (y - MINY) * MAPWIDTH + (x - MINX)
END FUNCTION
 
' #############################################################################################################
' <- helper
' -> pathfinding SUBs
' #############################################################################################################
 
SUB GetNeighbours
 
    DIM x AS INTEGER, y AS INTEGER, x1 AS INTEGER, y1 AS INTEGER
    DIM id AS INTEGER
    DIM ooid AS INTEGER
    DIM f AS SINGLE
 
    ooid = GetMinFromOpenList
    IF ooid = 0 THEN ' nothing on open list
        bNoPathFound = 1
        EXIT SUB
    END IF
 
    x1 = Nodes(ooid).x
    y1 = Nodes(ooid).y
 
    IF ooid <> startID THEN
        PaintBlock ooid, GOLD
    END IF
 
    FOR y = y1 - 1 TO y1 + 1 STEP 1
        IF y >= MINY AND y <= MAXY THEN
            FOR x = x1 - 1 TO x1 + 1 STEP 1
                IF x >= MINX AND x <= MAXX THEN
                    id = GetIdFromXY(x, y)
                    IF id <> startID THEN
                        IF Nodes(id).oc = 0 THEN ' not yet on closed list
                            IF id <> startID THEN
                                PaintBlock id, AQUA
                            END IF
                            f = Nodes(ooid).f + Map(x, y) + SQR(((x - endX) ^ 2) + ((y - endY) ^ 2))
                            IF id <> endID THEN
                                IF Nodes(id).oo THEN ' is on open list
                                    IF Nodes(id).f > f THEN
                                        Nodes(id).p = Nodes(ooid).id
                                        Nodes(id).f = f
                                    END IF
                                ELSE ' not yet on open list
                                    Nodes(id).f = f
                                    Nodes(id).p = Nodes(ooid).id
                                    Nodes(id).oo = 1 ' put on open list
                                    IF id <> startID THEN
                                        PaintBlock id, DARKORANGE
                                    END IF
                                END IF
                            ELSE
                                Nodes(id).p = Nodes(ooid).id
                                bPathFound = 1
                                EXIT SUB
                            END IF
                        ELSE
                            IF id <> startID THEN
                                PaintBlock id, GRAY
                            END IF
                        END IF
                    END IF
                END IF
            NEXT
        END IF
    NEXT
 
    Nodes(ooid).oc = 1
    Nodes(ooid).oo = 0
    IF ooid <> startID THEN
        PaintBlock ooid, BLACK 'SILVER
    END IF
END SUB
 
FUNCTION GetMinFromOpenList% ()
    DIM i AS INTEGER, id AS INTEGER
    DIM minf AS SINGLE
 
    minf = 99999.9
    id = 0
 
    FOR i = 0 TO MAXX * MAXY - 1
        IF Nodes(i).oo = 1 THEN
            IF Nodes(i).f > 0 THEN
                IF Nodes(i).f < minf THEN
                    minf = Nodes(i).f
                    id = i
                END IF
            END IF
        END IF
    NEXT
    GetMinFromOpenList = id
END SUB
 
 
SUB InitNodes
    DIM x AS INTEGER, y AS INTEGER, id AS INTEGER
 
    FOR y = MINY TO MAXY
        FOR x = MINX TO MAXX
            id = GetIdFromXY(x, y)
            Nodes(id).id = id
            Nodes(id).x = x
            Nodes(id).y = y
            Nodes(id).f = 0
            Nodes(id).p = 0
            Nodes(id).oo = 0
            Nodes(id).oc = 0
        NEXT
    NEXT
 
END SUB
 
' #############################################################################################################
' <- pathfinding SUBs
' -> map related non graphical Subs
' #############################################################################################################
 
SUB InitMap
    DIM x AS INTEGER, x1 AS INTEGER, x2 AS INTEGER
    DIM y AS INTEGER, y1 AS INTEGER, y2 AS INTEGER
 
    FOR y = MINY TO MAXY
        y1 = (y - MINY) * SQUAREHEIGHT
        y2 = y1 + SQUAREHEIGHT - 1
        FOR x = MINX TO MAXX
            Map(x, y) = 1
            x1 = (x - MINX) * SQUAREWIDTH
            x2 = x1 + SQUAREWIDTH - 1
        NEXT
    NEXT
 
END SUB
 
SUB SetWall (x1, y1, x2, y2)
    DIM x AS INTEGER, y AS INTEGER
 
    IF x1 > x2 THEN
        x = x1
        x1 = x2
        x2 = x
    END IF
 
    IF y1 > y2 THEN
        y = y1
        y1 = y2
        y2 = y
    END IF
 
 
    FOR y = y1 TO y2
        FOR x = x1 TO x2
            Map(x, y) = YOUSHALLNOTPASS
        NEXT
    NEXT
END SUB
 
SUB RandomBlock
    DIM x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER
    DIM n AS INTEGER
 
    n = INT(RND * 5) + 1
    x1 = INT(RND * (MAPWIDTH - n - 2)) + 1
    x2 = x1 + n - 1
 
    n = INT(RND * 5) + 1
    y1 = INT(RND * (MAPHEIGHT - n - 2)) + 1
    y2 = y1 + n - 1
 
    SetWall x1, y1, x2, y2
 
END SUB
 
' #############################################################################################################
' <- map related non graphical Subs
' -> map related graphical Subs
' #############################################################################################################
 
SUB PaintMap
    DIM x AS INTEGER, x1 AS INTEGER, x2 AS INTEGER
    DIM y AS INTEGER, y1 AS INTEGER, y2 AS INTEGER
    DIM col AS LONG
 
    CLS
    FOR y = MINY TO MAXY
        y1 = (y - MINY) * SQUAREHEIGHT
        y2 = y1 + SQUAREHEIGHT - 1
        FOR x = MINX TO MAXX
            x1 = (x - MINX) * SQUAREWIDTH
            x2 = x1 + SQUAREWIDTH - 1
            IF Map(x, y) < YOUSHALLNOTPASS THEN
                col = FERN
            ELSE
                col = BLACK
            END IF
            LINE (x1, y1)-(x2, y2), col, BF
            LINE (x1, y1)-(x2, y2), BLACK, B
        NEXT
    NEXT
 
    PlaceStartEnd startX, startY, MAROON
    PlaceStartEnd endX, endY, LAWNGREEN
 
END SUB
 
SUB PlaceStartEnd (x AS INTEGER, y AS INTEGER, col AS LONG)
    DIM x1 AS INTEGER, x2 AS INTEGER, y1 AS INTEGER, y2 AS INTEGER
 
    x1 = (x - MINX) * SQUAREWIDTH
    x2 = x1 + SQUAREWIDTH - 1
    y1 = (y - MINY) * SQUAREHEIGHT
    y2 = y1 + SQUAREHEIGHT - 1
    LINE (x1, y1)-(x2, y2), col, BF
 
END SUB
 
SUB ShowCrow
    LINE ((startX - MINX) * SQUAREWIDTH, (startY - MINY) * SQUAREHEIGHT)-((endX - MINX) * SQUAREWIDTH, (endY - MINY) * SQUAREHEIGHT), WHITE
END SUB
 
SUB ShowPath
    DIM x AS INTEGER, x1 AS INTEGER, x2 AS INTEGER
    DIM y AS INTEGER, y1 AS INTEGER, y2 AS INTEGER
    DIM id AS INTEGER, zid AS INTEGER
 
    PaintMap
 
    zid = GetIdFromXY(startX, startY)
    id = GetIdFromXY(endX, endY)
 
    IF Nodes(id).p THEN
 
        WHILE id <> zid
            x = Nodes(Nodes(id).p).x
            y = Nodes(Nodes(id).p).y
            y1 = (y - MINY) * SQUAREHEIGHT
            y2 = y1 + SQUAREHEIGHT - 1
            x1 = (x - MINX) * SQUAREWIDTH
            x2 = x1 + SQUAREWIDTH - 1
 
            LINE (x1, y1)-(x2, y2), CORNFLOWERBLUE, BF
 
            id = Nodes(id).p
        WEND
    END IF
 
    PlaceStartEnd startX, startY, MAROON
    PlaceStartEnd endX, endY, LAWNGREEN
 
END SUB
 
SUB PaintBlock (id AS INTEGER, col AS LONG)
    DIM x AS INTEGER, y AS INTEGER
    DIM x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER
 
    x = Nodes(id).x
    y = Nodes(id).y
 
    y1 = (y - MINY) * SQUAREHEIGHT
    y2 = y1 + SQUAREHEIGHT - 1
    x1 = (x - MINX) * SQUAREWIDTH
    x2 = x1 + SQUAREWIDTH - 1
 
    LINE (x1, y1)-(x2, y2), col, BF
 
END SUB
 

Pages: [1] 2

News:

Show Posts

Messages - Qbee

Programs / Re: QB64-SDL 2020

QB64 Discussion / Re: QB64 Oddness at Work

QB64 Discussion / Re: QB64 Oddness at Work

Programs / Re: Northern Lights

Programs / Re: Northern Lights

Programs / Re: Hello physics

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

QB64 Discussion / Re: It's already 2020 in Australia! Where are the fireworks, folks?

QB64 Discussion / Re: _SCREENPRINT for Mouse ?

QB64 Discussion / _SCREENPRINT for Mouse ?

Programs / Re: Pathfinder

Programs / Re: Pathfinder

Programs / Re: Pathfinder

Programs / Pathfinder