Show Posts

This section allows you to view all posts made by this member. Note that you can only see posts made in areas you currently have access to.

Messages - Zeppelin

Pages: [1] 2 3

Programs / Re: Intersection of two circles

« on: December 11, 2019, 04:24:45 pm »

Hey everyone,

Heres a WIP voronoi function.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
RANDOMIZE TIMER
 
cirs = 25
 
DIM cirX(cirs)
DIM cirY(cirs)
 
rad = 25
FOR n = 1 TO cirs
    cirX(n) = INT(RND * _WIDTH - 1) + 1
    cirY(n) = INT(RND * _HEIGHT - 1) + 1
    CIRCLE (cirX(n), cirY(n)), 2
    PAINT (cirX(n), cirY(n)), _RGB(255, 255, 255)
    CIRCLE (cirX(n), cirY(n)), rad
NEXT n
 
DO
    CLS
 
    FOR x = 1 TO cirs
        FOR n = 1 TO cirs
            dist = SQR(((cirX(x) - (cirX(n))) ^ 2) + ((cirY(x) - cirY(n)) ^ 2))
            IF dist <= rad * 2 THEN
                Dx = cirX(n) - cirX(x)
                Dy = cirY(n) - cirY(x)
 
                E = (Dx ^ 2 + Dy ^ 2 + r2 ^ 2 - r1 ^ 2) / (2 * rad)
                F = (-Dx ^ 2 - Dy ^ 2 + r2 ^ 2 - r1 ^ 2) / (2 * rad)
 
                a = Dx / E
                b = Dy / E
                c = Dx / F
                d = Dy / F
 
                cosbetap = (a + b * SQR(a ^ 2 + b ^ 2 - 1)) / (a ^ 2 + b ^ 2)
                sinbetap = (b + a * SQR(a ^ 2 + b ^ 2 - 1)) / (a ^ 2 + b ^ 2)
                cosbetam = (a - b * SQR(a ^ 2 + b ^ 2 - 1)) / (a ^ 2 + b ^ 2)
                sinbetam = (b - a * SQR(a ^ 2 + b ^ 2 - 1)) / (a ^ 2 + b ^ 2)
 
                cosalphap = (c + d * SQR(c ^ 2 + d ^ 2 - 1)) / (c ^ 2 + d ^ 2)
                sinalphap = (d + c * SQR(c ^ 2 + d ^ 2 - 1)) / (c ^ 2 + d ^ 2)
                cosalpham = (c - d * SQR(c ^ 2 + d ^ 2 - 1)) / (c ^ 2 + d ^ 2)
                sinalpham = (d - c * SQR(c ^ 2 + d ^ 2 - 1)) / (c ^ 2 + d ^ 2)
 
                ipX = cirX(n) + rad * cosalphap
                ipY = cirY(n) + rad * sinalpham
 
                ipX2 = cirX(x) + rad * cosbetap
                ipY2 = cirY(x) + rad * sinbetam
 
 
                LINE (ipX, ipY)-(ipX2, ipY2), _RGB(0, 0, 255)
            END IF
 
        NEXT n
    NEXT x
 
    rad = rad + 1
    _DELAY (0.1)
 
LOOP UNTIL rad = 500
 
PRINT "DONE"
DO
LOOP UNTIL INKEY$ <> ""
 

Zep

Programs / Re: _PUT Rotation Help

« on: December 06, 2019, 02:08:56 am »

Thanks bPlus,
Your method seems alot more efficient.

Zep

Programs / _PUT Rotation Help

« on: December 05, 2019, 05:51:00 pm »

Hey Everyone,
Here's a piece I've been working on for awhile now but in the Infinite sub I'm trying to get the 'sword' to make a full rotation and end up under the character during the jump, but it seems to just keep spinning and stopping at random points. Not too sure what I'm doing wrong.

Code: QB64: [Select]

'+-------------------+
'        SLAY
' ZEPPELIN GAMES 2019
'+-------------------+
 
_TITLE "SLAY" 'SET TITLE
_FULLSCREEN 'SET FULLSCREEN
SCREEN _NEWIMAGE(1200, 800, 32)
 
'DECLARE VARIABLES
'SAVE DATA VARS
DIM SHARED save.point AS INTEGER
DIM SHARED saveData$(1000)
 
'PLAYER VARS
DIM SHARED player%(100000)
DIM SHARED sword%(100000)
DIM SHARED player.name AS STRING
DIM SHARED player.health AS INTEGER
DIM SHARED player.basehealth AS INTEGER
DIM SHARED playerScale AS INTEGER
playerScale = 15
 
DIM SHARED pX
 
'PLAYER STATS
DIM SHARED stats.enemyskilled AS INTEGER
DIM SHARED stats.totaldeaths AS INTEGER
 
'SCREEN AND FORMATTING VARS
DIM SHARED w AS INTEGER
DIM SHARED h AS INTEGER
 
DIM SHARED fh AS INTEGER
DIM SHARED fw AS INTEGER
 
'GET THE SCREEN DIMSENSIONS
w = _WIDTH
h = _HEIGHT
 
'FONT DATA
fh = _FONTHEIGHT
fw = _FONTWIDTH
 
'SET THE COLOR
col = _RGBA(255, 255, 255, 255)
 
'START GAME
LoadData
 
SUB LoadData
    'LOAD SAVE DATA
 
    'LOAD PLAYER SPRITE
    LoadSprite player%(), playerScale
    LoadSprite sword%(), playerScale / 1.2
 
    IF _FILEEXISTS("SlayV4SaveData.txt") THEN 'SEE IF THE FILE EXISTS
        OPEN "SlayV4SaveData.txt" FOR INPUT AS #1
        DO UNTIL EOF(1) 'LOOP UNTIL END OF FILE
            _LIMIT 60
            filecount = filecount + 1 'COUNT AMOUNT OF LINES
            LINE INPUT #1, file$
            saveData$(filecount) = file$
        LOOP
        CLOSE #1
 
        IF filecount > 2 THEN
            'PLAYER
 
            'DECRYPT NAME
            name$ = ""
            FOR n = 1 TO LEN(saveData$(1)) STEP 2
                name$ = name$ + CHR$(ASC(MID$(saveData$(1), n, 1)) - 4)
            NEXT n
 
            'DECRYPT STATS
            'HEALTH
            health$ = ""
            FOR n = 1 TO LEN(saveData$(2)) STEP 2
                health$ = health$ + CHR$(ASC(MID$(saveData$(2), n, 1)) - 4)
            NEXT n
 
            player.name = UCASE$(name$) 'LOAD NAME
            player.basehealth = VAL(health$) 'LOAD BASE HEALTH
            player.health = player.basehealth 'SET PLAYER HEALTH
            'SAVE DATA
            save.point = VAL(saveData$(3)) 'LOAD SAVE POINT
            'STATS
            stats.enemyskilled = VAL(saveData$(4)) 'ENEMYS KILLED
            stats.totaldeaths = VAL(saveData$(5)) 'TOTAL DEATHS
        ELSE
            CreateNewSave
        END IF
    ELSE
        CreateNewSave
    END IF
 
    'START GAME
    _DELAY (1)
    DrawLogo
END SUB
 
SUB CreateNewSave
    'CREATE NEW SAVE FILE
    scaledText w / 2 - 65, h / 2 + 8, 16, _RGBA(255, 255, 255, 255), "Enter your name: "
    DO
        _LIMIT 60
        LOCATE (h / 2 - 248) / fh + hf, (w / 2 - 50) / fw + fw: INPUT "", name$
    LOOP UNTIL LEN(name$) > 1
    IF LEN(name$) > 16 THEN
        CLS
        _PRINTSTRING (w / 2 - 150, h / 2), "Name length should be less than 16 characters"
        _DELAY (2)
        CLS
        LoadData
    END IF
 
    'SET VARS
    player.name = UCASE$(name$)
    player.health = 100
 
    save.point = 0
    stats.enemyskilled = 0
    stats.totaldeaths = 0
 
    'ENCRYPT SAVE DATA
    'NAME
    DIM nameArray$(16)
    FOR n = 1 TO LEN(player.name)
        nameArray$(n) = MID$(player.name, n, 1)
    NEXT n
 
    FOR n = 1 TO LEN(player.name)
        tempName$ = tempName$ + CHR$(ASC(nameArray$(n)) + 4)
        tempName$ = tempName$ + CHR$(INT(RND * 100) + 100)
    NEXT n
 
    name$ = tempName$
 
    'ENCRYPT STATS
    'HEALTH
    DIM healthArray$(5)
    FOR n = 1 TO LEN(STR$(player.health))
        healthArray$(n) = MID$(STR$(player.health), n, 1)
    NEXT n
 
    FOR n = 1 TO LEN(STR$(player.health))
        tempHealth$ = tempHealth$ + CHR$(ASC(healthArray$(n)) + 4)
        tempHealth$ = tempHealth$ + CHR$(INT(RND * 100) + 100)
    NEXT n
 
    'SAVE VARS TO TXT
    OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
    'PLAYER
    PRINT #1, name$
    PRINT #1, tempHealth$
    'SAVE DATA
    PRINT #1, save.point
    'STATS
    PRINT #1, stats.enemyskilled
    PRINT #1, stats.totaldeaths
    CLOSE #1
    CLS
END SUB
 
SUB DrawLogo
    'FADE LOGO IN
    FOR n = 0 TO 255
        'LIMIT FPS
        _LIMIT 60
 
        LINE (w / 10 * 2, h / 10 * 7)-(w / 10 * 8, h / 10 * 8), _RGB(0, 0, 0), BF
        scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, n), "Z"
        scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, n), "ZEPPELIN GAMES"
        _DISPLAY
    NEXT n
 
    scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, 255), "Z"
    scaledText w / 2, h / 6 * 4.5, 50, _RGBA32(255, 255, 255, 255), "ZEPPELIN GAMES"
    _DISPLAY
    _DELAY (3) 'WAIT A BIT
 
    'FADE THE LOGO AND TEXT OUT
    FOR n = 0 TO 255
        'LIMIT FPS
        _LIMIT 60
 
        LINE (w / 10 * 2, h / 10 * 7)-(w / 10 * 8, h / 10 * 8), _RGB(0, 0, 0), BF
        scaledText w / 2, h / 2, 500, _RGBA32(255, 255, 255, 255 - n), "Z"
        scaledText w / 2, h / 6 * 4.5, 50, _RGBA(255, 255, 255, 255 - n), "ZEPPELIN GAMES"
        _DISPLAY
    NEXT n
    CLS
    _DISPLAY
    DrawMenu
END SUB
 
SUB DrawMenu
    'FADE IN MENU SCREEN
    DIM col AS LONG
    col = _RGBA(255, 255, 255, 255)
    'S
    LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3.5, h / 10 * 1.75), col, BF '1ST ACROSS
    LINE (w / 10 * 2.75, h / 10 * 1.5)-(w / 10 * 3, h / 10 * 2.5), col, BF '1ST DOWN
    LINE (w / 10 * 2.75, h / 10 * 2.5)-(w / 10 * 3.45, h / 10 * 2.75), col, BF '2ND ACROSS
    LINE (w / 10 * 3.2, h / 10 * 2.75)-(w / 10 * 3.45, h / 10 * 2.9), col, BF '2ND DOWN
    LINE (w / 10 * 3.2, h / 10 * 3.35)-(w / 10 * 3.45, h / 10 * 3.75), col, BF 'EXTENDED 2ND DOWN
    LINE (w / 10 * 2.65, h / 10 * 3.75)-(w / 10 * 3.45, h / 10 * 4.1), col, BF '3RD ACROSS
 
    'L
    LINE (w / 10 * 3.8, h / 10 * 1.5)-(w / 10 * 4.05, h / 10 * 2.65), col, BF '1ST DOWN
    LINE (w / 10 * 3.8, h / 10 * 3.6)-(w / 10 * 4.05, h / 10 * 3.75), col, BF 'EXTENDED 1ST DOWN
    LINE (w / 10 * 3.8, h / 10 * 3.75)-(w / 10 * 4.6, h / 10 * 4.1), col, BF '1ST ACROSS
 
    'A
    LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.1, h / 10 * 2.7), col, BF 'LEFT DOWN
    LINE (w / 10 * 4.85, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 1.8), col, BF 'TOP LINE
    LINE (w / 10 * 5.5, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.7), col, BF 'RIGHT DOWN
    LINE (w / 10 * 5.55, h / 10 * 1.5)-(w / 10 * 5.75, h / 10 * 2.9), col, BF 'RIGHT DOWN EDGE
    LINE (w / 10 * 4.85, h / 10 * 2.4)-(w / 10 * 5.75, h / 10 * 2.65), col, BF 'MIDDLE LINE
    LINE (w / 10 * 4.85, h / 10 * 3.5)-(w / 10 * 5.1, h / 10 * 4.1), col, BF 'EXTENDED LEFT DOWN
    LINE (w / 10 * 5.5, h / 10 * 3.5)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
    LINE (w / 10 * 5.55, h / 10 * 3.35)-(w / 10 * 5.75, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN EDGE
 
    'Y
    LINE (w / 10 * 6, h / 10 * 1.5)-(w / 10 * 6.25, h / 10 * 2.75), col, BF 'LEFT DOWN
    LINE (w / 10 * 6.75, h / 10 * 1.5)-(w / 10 * 7, h / 10 * 3), col, BF 'RIGHT DOWN
    LINE (w / 10 * 6, h / 10 * 2.5)-(w / 10 * 7, h / 10 * 2.85), col, BF '1ST ACROSS
    LINE (w / 10 * 6.75, h / 10 * 3.25)-(w / 10 * 7, h / 10 * 4.1), col, BF 'EXTENDED RIGHT DOWN
    LINE (w / 10 * 6, h / 10 * 3.8)-(w / 10 * 7, h / 10 * 4.1), col, BF 'BOTTOM LINE
 
    'SWORD
    LINE (w / 10 * 3, h / 10 * 3)-(w / 10 * 6.5, h / 10 * 3.25), col, BF 'HILT
    LINE (w / 10 * 3.5, h / 10 * 2.5)-(w / 10 * 3.75, h / 10 * 3.75), col, BF 'Hand Guard
    LINE (w / 10 * 3.75, h / 10 * 2.75)-(w / 10 * 4.75, h / 10 * 3.50), col, BF 'Blade First Layer
    LINE (w / 10 * 4.75, h / 10 * 2.85)-(w / 10 * 5.5, h / 10 * 3.4), col, BF 'Blade 2nd Layer
    LINE (w / 10 * 5.5, h / 10 * 3.10)-(w / 10 * 7, h / 10 * 3.15), col, BF 'Tip of Blade
 
    col = _RGBA(0, 0, 0, 255)
    LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
 
    'SHOW ACCOUNT
    _PRINTSTRING (5, 5), player.name
 
    'PRINT MENU OPTIONS
    scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "SINGLE-PLAYER"
    scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "MULTI-PLAYER"
    scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "OPTIONS"
    scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "QUIT"
    scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
 
    'PICK MENU OPTION
    opt = 0
    col = _RGBA(0, 0, 0, 255)
    DO
        _LIMIT 60
        LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
        _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
        _DISPLAY 'REDUCE FLICKERING
 
        SELECT CASE INKEY$
            CASE "s", "S" 'MOVE POINTER DOWN
                IF opt + 1 = 4 THEN
                    opt = 0
                ELSE
                    opt = opt + 1
                END IF
 
            CASE "w", "W" 'MOVE POINTER UP
                IF opt - 1 = -1 THEN
                    opt = 3
                ELSE
                    opt = opt - 1
                END IF
 
            CASE CHR$(13) 'ENTER KEY
                'SINGLE-PLAYER SELECTED
                IF opt = 0 THEN
                    SinglePlayerMenu
                END IF
 
                'MULTI-PLAYER SELECTED
                IF opt = 1 THEN
                    MultiplayerGameMenu
                END IF
 
                'OPTIONS SELETED
                IF opt = 2 THEN
                    OptionsMenu
                END IF
 
                'QUIT SELECTED
                IF opt = 3 THEN
                    SYSTEM
                END IF
        END SELECT
    LOOP
END SUB
 
 
SUB OptionsMenu
    LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
    scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "INFO"
    scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "RESET GAME"
    scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
    scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
 
    opt = 0
    DO
        _LIMIT 60
        LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
        _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
 
        _DISPLAY 'REDUCE FLICKERING
 
        SELECT CASE INKEY$
            CASE "s", "S" 'MOVE POINTER DOWN
                IF opt + 1 = 3 THEN
                    opt = 0
                ELSE
                    opt = opt + 1
                END IF
 
            CASE "w", "W" 'MOVE POINTER UP
                IF opt - 1 = -1 THEN
                    opt = 2
                ELSE
                    opt = opt - 1
                END IF
            CASE CHR$(13) 'ENTER PRESSED
                IF opt = 0 THEN 'GAME INFO
                    LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
                    scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "ZEPPELIN GAMES 2018"
                    scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "SLAY V4"
                    scaledText w / 2, h / 10 * 6.25, 25, _RGBA(255, 255, 255, 255), "ENEMIES KILLED: " + STR$(stats.enemyskilled)
                    scaledText w / 2, h / 10 * 6.75, 25, _RGBA(255, 255, 255, 255), "TOTAL DEATHS: " + STR$(stats.totaldeaths)
                    scaledText w / 2, h / 10 * 9.25, 14, _RGBA(255, 255, 255, 255), "PRESS ANY KEY TO CONTINUE"
 
                    _DISPLAY
                    DO WHILE INKEY$ = ""
                    LOOP
                    LINE (0, h / 10 * 4.7)-(w, h), col, BF 'CLEAR OPTIONS
                    OptionsMenu
                END IF
                IF opt = 1 THEN 'RESET GAME
                    OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
                    PRINT #1, ""
                    CLOSE #1
                    CLS
                    RUN "SLAY V4.exe"
                END IF
                IF opt = 2 THEN 'BACK
                    DrawMenu
                END IF
        END SELECT
    LOOP
END SUB
 
SUB SinglePlayerMenu
    col = _RGBA(0, 0, 0, 255)
    LINE (w / 10, h / 10 * 4.5)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
    scaledText w / 2, h / 10 * 4.75, 25, _RGBA(255, 255, 255, 255), "CAMPAIGN"
    scaledText w / 2, h / 10 * 5.25, 25, _RGBA(255, 255, 255, 255), "INFINITE"
    scaledText w / 2, h / 10 * 5.75, 25, _RGBA(255, 255, 255, 255), "BACK"
    scaledText w / 2, h / 10 * 9.5, 14, _RGBA(255, 255, 255, 255), "TIP: USE 'w' AND 's' TO NAVIGATE. PRESS 'ENTER' TO SELCT"
 
    opt = 0
    DO
        _LIMIT 60
        LINE (w / 2 - 90, h / 10 * 4.5)-(w / 2 - 110, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
        _PRINTSTRING (w / 2 - 100, h / 10 * (4.6 + (0.52 * opt))), ">" 'DISPLAY POINTER
 
        _DISPLAY 'REDUCE FLICKERING
 
        SELECT CASE INKEY$
            CASE "s", "S" 'MOVE POINTER DOWN
                IF opt + 1 = 3 THEN
                    opt = 0
                ELSE
                    opt = opt + 1
                END IF
 
            CASE "w", "W" 'MOVE POINTER UP
                IF opt - 1 = -1 THEN
                    opt = 2
                ELSE
                    opt = opt - 1
                END IF
            CASE CHR$(13) 'ENTER PRESSED
                IF opt = 0 THEN
                    Campaign
                END IF
                IF opt = 1 THEN
                    Infinite
                END IF
                IF opt = 2 THEN
                    DrawMenu
                END IF
        END SELECT
    LOOP
END SUB
 
'CAMPAIGN - STORY
SUB Campaign
 
END SUB
 
'PRACTICE - GAMEMODE
SUB Infinite
    CLS
    'DEFINE LOCAL VARS
 
    DIM health
    DIM deltaTime
 
    DIM swordX
    DIM swordY
 
    DIM swing
    DIM angle
 
    playerSpeed = 500
    jumpHeight = 150
    health = 100
    jump = 0
    pX = _WIDTH / 2 - (playerScale * 2.5)
    pY = _HEIGHT / 10 * 8
 
    swordX = pX
    swordY = pY + (playerScale * 5)
 
    sTime = TIMER
 
    DO
        _LIMIT 120
        sTime = TIMER(0.001)
        IF _KEYDOWN(100) THEN
            pX = pX + playerSpeed / 100
            IF pX > _WIDTH - (playerScale * 12) - 1 THEN pX = _WIDTH - (playerScale * 12) - 1
        END IF
        IF _KEYDOWN(97) THEN
            pX = pX - playerSpeed / 100
            IF pX < (playerScale * 12) THEN pX = (playerScale * 12)
        END IF
        IF _KEYDOWN(32) THEN
            IF jump = 0 THEN
                jump = 1
            END IF
        END IF
 
        IF jump >= 1 THEN
            IF pY > ((_HEIGHT / 10) * 8) - jumpHeight AND NOT jump = 2 THEN
                pY = pY - playerSpeed / 100
 
                'Spin Sword
                swing = 1
                swordX = pX + ((playerScale * 6) * COS(_D2R(angle)))
                swordY = pY + ((playerScale * 6) * SIN(_D2R(angle)))
            ELSE
 
                IF pY <= (_HEIGHT / 10) * 8 THEN
                    jump = 2
                    pY = pY + playerSpeed / 100
 
                    'Spin Sword
                    swing = 1
                    swordX = pX + ((playerScale * 6) * COS(_D2R(angle)))
                    swordY = pY + ((playerScale * 6) * SIN(_D2R(angle)))
 
                ELSE
                    jump = 0
                    swing = 0
                    pY = (_HEIGHT / 10) * 8
                END IF
            END IF
        END IF
 
        IF swing = 1 THEN
            angle = angle + (jumpHeight / 100)
        END IF
 
        LINE (pX - (playerScale * 10) - 10, pY - (playerScale * 12) - 10)-(pX + ((playerScale * 10) * 2) + 10, pY + (playerScale * 10) + 10), _RGB(0, 0, 0), BF
 
        PUT (pX, pY), player%()
        PUT (swordX, swordY), sword%()
        _DISPLAY
 
        eTime = TIMER(0.001)
        deltaTime = eTime - sTime
 
    LOOP UNTIL health <= 0 OR INKEY$ = CHR$(27)
    CLS
    SaveGame
    DrawMenu
END SUB
 
'MULTIPLAYER GAME MENU
SUB MultiplayerGameMenu
    LINE (w / 10, h / 10 * 4.7)-(w, h / 10 * 7), col, BF 'CLEAR OPTIONS
    _PRINTSTRING (w / 2 - 40, h / 10 * 4.75), "LOCAL"
    _PRINTSTRING (w / 2 - 34, h / 10 * 5.25), "LAN"
    _PRINTSTRING (w / 2 - 37, h / 10 * 5.75), "BACK"
 
    opt = 0
    DO
        LINE (w / 2 - 58, h / 10 * 4.7)-(w / 2 - 70, h / 10 * 7), col, BF 'CLEAR PAST POINTERS
        _PRINTSTRING (w / 2 - 65, h / 10 * (4.75 + (0.5 * opt))), ">" 'DISPLAY POINTER
 
        _DISPLAY 'REDUCE FLICKERING
 
        SELECT CASE INKEY$
            CASE "s" 'MOVE POINTER DOWN
                IF opt + 1 = 3 THEN
                    opt = 0
                ELSE
                    opt = opt + 1
                END IF
 
            CASE "w" 'MOVE POINTER UP
                IF opt - 1 = -1 THEN
                    opt = 2
                ELSE
                    opt = opt - 1
                END IF
            CASE CHR$(13) 'ENTER KEY
                IF opt = 0 THEN
                    LocalMultiplayer
                ELSEIF opt = 1 THEN
                    LANMultiplayer
                ELSEIF opt = 2 THEN
                    DrawMenu
                END IF
        END SELECT
    LOOP UNTIL INKEY$ = CHR$(13)
END SUB
 
 
'MULTIPLAYER ON SAME DEVICE
SUB LocalMultiplayer
 
END SUB
 
'MULTIPLAYER OVER WIFI CONNECTION
SUB LANMultiplayer
 
 
END SUB
 
SUB SaveGame
    'SAVE VARS TO TXT
    OPEN "SlayV4SaveData.txt" FOR OUTPUT AS #1
    'PLAYER
    PRINT #1, name$
    PRINT #1, player.health
    'SAVE DATA
    PRINT #1, save.point
    'STATS
    PRINT #1, stats.enemyskilled
    PRINT #1, stats.totaldeaths
    CLOSE #1
END SUB
 
SUB LoadSprite (sp%(), scale)
    DIM sprite(4, 4)
    FOR y = 0 TO 4
        FOR x = 0 TO 4
            READ sprite(x, y) 'Read the data
        NEXT x
    NEXT y
 
    FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
        FOR x = 0 TO 4 * scale STEP scale
            spriteCol = sprite(x / scale, y / scale)
            LINE (x, y)-(x + scale, y + scale), _RGB(spriteCol * 255, spriteCol * 255, spriteCol * 255), BF 'Draw each pixel
        NEXT x
    NEXT y
 
    GET (0, 0)-(scale * 5, scale * 5), sp%()
    CLS
 
    'Player Data
    DATA 0,1,1,1,0
    DATA 0,1,1,1,0
    DATA 1,1,1,1,1
    DATA 0,1,1,1,0
    DATA 0,1,0,1,0
 
    'Sword Data
    DATA 0,0,1,0,0
    DATA 1,1,1,1,1
    DATA 0,1,1,1,0
    DATA 0,1,1,1,0
    DATA 0,0,1,0,0
END SUB
 
SUB scaledText (x, y, textHeight, K AS _UNSIGNED LONG, txt$)
    fg = _DEFAULTCOLOR
    'screen snapshot
    cur& = _DEST
    I& = _NEWIMAGE(8 * LEN(txt$), 16, 32)
    _DEST I&
    COLOR K, _RGBA32(0, 0, 0, 0)
    _PRINTSTRING (0, 0), txt$
    mult = textHeight / 16
    xlen = LEN(txt$) * 8 * mult
    _PUTIMAGE (x - .5 * xlen, y - .5 * textHeight)-STEP(xlen, textHeight), I&, cur&
    COLOR fg
    _FREEIMAGE I&
END SUB

Thanks,
Zep

Programs / Re: Drawing Polygons

« on: November 26, 2019, 04:47:45 am »

Thanks bPlus,
It's always a small issue that underpins what could've been :D

Zep

Programs / Drawing Polygons

« on: November 25, 2019, 11:11:36 pm »

Hey all,
I've been trying to make a program that can draw any polygon (pentagon, octagon, pentacontagon, etc...), although I can't get it to work.

Code: QB64: [Select]

SCREEN _NEWIMAGE(800, 600, 32)
l = 100
s = 8
 
angle = (360 / s)
lx = (_WIDTH / 2) + ((COS(angle)) * l)
ly = (_HEIGHT / 2) + ((SIN(angle)) * l)
 
FOR n = 1 TO s
    x = (_WIDTH / 2) + ((COS(angle)) * l)
    y = (_HEIGHT / 2) + ((SIN(angle)) * l)
 
    LINE (lx, ly)-(x, y), _RGB(255, 255, 255)
 
    lx = x
    ly = y
 
    angle = (360 / s) * n
    PRINT angle
NEXT n
 

l is the length of each line
s is the amount of sides i want.

No matter what I do either the shape doesnt line up or it overlaps.

Thanks,
Zep

Programs / Re: Mini Messenger

« on: November 18, 2019, 05:55:15 pm »

SMcNeill,
First off just wanna say thanks for actually getting TCP/IP to work. I've tried many times with the examples on the wiki.

Code: QB64: [Select]

DIM SHARED Users(1 TO 1000) ' array to hold other client info
DIM SHARED NumClients
DIM SHARED OUT$
 
 
PRINT "[Steve's Mini Messenger]"
host = _OPENHOST("TCP/IP:7319") ' no host found, so begin new host
IF host THEN
    PRINT "[Beginning new host chat session!]"
    NumClients = 0
    client = _OPENCLIENT("TCP/IP:7319:localhost")
    IF client = 0 THEN PRINT "ERROR: could not attach host's personal client to host!"
    INPUT "Enter your name:", myname$
    'PRINT #client, myname$ + " connected!"
    PRINT "[Chat session active!]"
ELSE
    PRINT "ERROR: Could not begin new host!"
    PRINT "JOINING as CLIENT"
 
    'Join as client
    client = _OPENCLIENT("TCP/IP:7319:localhost") ' Attempt to connect to local host as a client
END IF ' host
 
IF host THEN
    _TITLE "HOST"
    DO ' host main loop
        newclient = _OPENCONNECTION(host) ' receive any new connection
        IF newclient THEN
            NumClients = NumClients + 1
            Users(NumClients) = newclient
            PRINT "Welcome to Steve's Mini Messenger!"
        END IF
        FOR i = 1 TO NumClients
            GetMessage Users(i) 'check all clients for a message
            IF OUT$ <> "" THEN
                l = LEN(OUT$)
                FOR j = 1 TO NumClients ' distribute incoming messages to all clients
                    PUT #Users(j), , l
                    PUT #Users(j), , OUT$
                NEXT
            END IF
        NEXT i
 
        SendMessage myname$, mymessage$, client
        _LIMIT 30
    LOOP
END IF
 
IF client THEN
    INPUT "Enter your name: ", myname$
    OUT$ = myname$ + " connected!"
    l = LEN(OUT$)
    PUT #client, , l
    PUT #client, , OUT$
 
    _TITLE "CLIENT"
    DO
        GetMessage client
        SendMessage myname$, mymessage$, client ' display current input on screen
        _LIMIT 30
    LOOP
END IF
 
 
SUB GetMessage (client) ' get & display any new message
    GET #client, , l
    IF l > 0 THEN
        OUT$ = SPACE$(l)
        GET #client, , OUT$
        VIEW PRINT 1 TO 20
        LOCATE 20, 1
        PRINT OUT$
        VIEW PRINT 1 TO 24
    ELSE
        OUT$ = ""
    END IF
END SUB
 
SUB SendMessage (myname$, mymessage$, client) ' simple input handler
    k$ = INKEY$
    IF LEN(k$) THEN
        IF k$ = CHR$(8) AND LEN(mymessage$) <> 0 THEN
            mymessage$ = LEFT$(mymessage$, LEN(mymessage$) - 1)
        ELSE
            IF LEN(k$) = 1 AND ASC(k$) >= 32 THEN mymessage$ = mymessage$ + k$
        END IF
    END IF
    VIEW PRINT 1 TO 24
    LOCATE 22, 1: PRINT SPACE$(80); ' erase previous message displayed
    LOCATE 22, 1: PRINT myname$ + ": "; mymessage$;
    IF k$ = CHR$(13) THEN ' [Enter] sends the message
        IF mymessage$ = "" THEN SYSTEM ' [Enter] with no message ends program
        mymessage$ = myname$ + ":" + mymessage$
        l = LEN(mymessage$)
        PUT #client, , l
        PUT #client, , mymessage$
        mymessage$ = ""
    END IF
    IF k$ = CHR$(27) THEN SYSTEM ' [Esc] key ends program
END SUB
 

Here's a version of your program that can run both client and/or host. Checks if a host is already open, then connects as client. Its just easier than having two separate programs.

Zep

QB64 Discussion / Re: Rotating Sprites

« on: November 06, 2019, 07:40:58 pm »

RhoSigma,
MAPTRIANGLE doesnt seem to be working for me. Whenever I try to display the sprite, nothing appears (its just black).
Could this be that I'm not using an actual image?

Zep

QB64 Discussion / Rotating Sprites

« on: November 06, 2019, 03:04:14 am »

Hey everyone,
Is it possible to rotate sprites with PUT, e.g. rotating an image to a specific degree.
Or am I going to have to calculate each corner of the images coordinates?

Thanks,
Zep

Programs / Re: Higher/Smoother framerate movement

« on: November 05, 2019, 05:20:21 pm »

Quote from: SMcNeill on November 05, 2019, 04:55:23 am

Like this, you can set the speed of the program so that it'll have a maximum movement with _LIMIT on very fast computers, and you can increase the playerSpeed as necessary to keep game flow steady if it's ever ran on very old/slow computers. (Just add a condition to check for your FPS, which should always be within 1 of your limit, and then you can adjust the player and opponent speed to skip a few frames if the values get too low, to keep the game moving at the same rate, which is what I think you were wanting to do with deltatime as you implemented it.)

I usually program in c# with Unity, so the deltatime was to try keep a consistent movement speed disregarding framerate (to some degree).
I will add limits to all loops (completely forgot, sorry about the egg-cooking CPU).

Thanks,
Zep

Programs / Higher/Smoother framerate movement

« on: November 04, 2019, 08:55:58 pm »

Hey Guys,
Is it possible to achieve a higher/smoother framerate when moving sprites using _PUTIMAGE.
See file below.
To get to the demo go:
-Singleplayer
-Infinite
To exit the demo hit escape.

Thanks,
Zep

QB64 Discussion / _PRINTSTRING For INPUT

« on: November 01, 2019, 04:11:23 am »

Hey,
Is there a command like _PRINTSTRING that allows coordinate placement of text but for INPUT?
I am aware of LOCATE, but it doesnt use screen coordinates. If there isnt a way to do this, is there a way to convert LOCATE coords to _PRINTSCREEN coords?

Thanks,
Zep

Programs / Re: GUESS MY NUMBER GAME

« on: September 10, 2019, 02:53:34 am »

Well done bPlus. I don't think we can get it much smaller than that.

Programs / Re: GUESS MY NUMBER GAME

« on: September 09, 2019, 11:07:11 pm »

Ron,
How short can you make it though ;)

Code: QB64: [Select]

RANDOMIZE TIMER: num = INT(RND * 100)
FOR n = 1 TO 10
    INPUT ">> ", in
    IF in < num THEN PRINT "Higher"
    IF in > num  THEN PRINT "Lower" ELSE
    IF in = num THEN PRINT "Correct. You Win": END
NEXT n: PRINT "Game-over. 10 turns passed"

7 lines

Zep.

Programs / Smooth Sprite Movement

« on: August 04, 2019, 08:52:10 pm »

Hey everyone,
Heres a good starting point or example for anyone having problems with slow or jerky sprite movement.

Code: QB64: [Select]

[/cod_TITLE "Space Invaders"
_SCREENMOVE _MIDDLE
SCREEN 13 '320x200
 
'LOAD SPRITES
DIM SHARED alien1%(1000)
DIM SHARED alien2%(1000)
DIM SHARED alien3%(1000)
 
DIM SHARED shield%(1000)
DIM SHARED player%(1000)
 
TYPE Bullet
    xPos AS INTEGER
    yPos AS INTEGER
    alive AS INTEGER
END TYPE
 
DIM SHARED bullets(100) AS Bullet
 
DIM SHARED deltaTime
DIM SHARED playerSpeed
DIM SHARED bulletSpeed
DIM SHARED lastBulletTime
 
DIM SHARED pX
 
CALL LoadSprite(alien1%())
CALL LoadSprite(alien2%())
CALL LoadSprite(alien3%())
 
CALL LoadSprite(shield%())
CALL LoadSprite(player%())
 
playerSpeed = 100
bulletSpeed = 100
 
FOR n = 1 TO 100
    bullets(n).alive = 0
NEXT n
 
CALL DrawShields
 
DO
    sTime = TIMER
 
    CALL MovePlayer
    CALL SpawnBullet
    CALL UpdateBullets
 
 
    eTime = TIMER
    deltaTime = eTime - sTime
LOOP UNTIL INKEY$ = CHR$(27)
 
SUB UpdateBullets
    FOR n = 1 TO 100
        IF bullets(n).alive = 1 THEN
            LINE (bullets(n).xPos, bullets(n).yPos)-(bullets(n).xPos + 2, bullets(n).yPos + 4), _RGB(0, 0, 0), BF
            bullets(n).yPos = bullets(n).yPos - (deltaTime * bulletSpeed)
            LINE (bullets(n).xPos, bullets(n).yPos)-(bullets(n).xPos + 2, bullets(n).yPos + 4), _RGB(255, 0, 0), BF
            _DISPLAY
 
            IF bullets(n).yPos < 0 THEN
                bullets(n).alive = 0
                LINE (bullets(n).xPos, bullets(n).yPos)-(bullets(n).xPos + 3, bullets(n).yPos + 5), _RGB(0, 0, 0), BF
            END IF
 
        END IF
    NEXT n
END SUB
 
SUB SpawnBullet
    IF _KEYDOWN(32) = -1 THEN
        IF TIMER - lastBulletTime > 0.1 THEN
            first = 101
            FOR n = 100 TO 1 STEP -1
                IF NOT bullets(n).alive = 1 THEN
                    IF n < first THEN
                        first = n
                    END IF
                END IF
            NEXT n
 
            IF first < 101 THEN
                lastBulletTime = TIMER
                bullets(first).alive = 1
                bullets(first).xPos = pX + 5
                bullets(first).yPos = 170
                LINE (bullets(first).xPos, bullets(first).yPos)-(bullets(first).xPos + 2, bullets(first).yPos + 4), _RGB(255, 255, 255), BF
            END IF
        END IF
    END IF
END SUB
 
SUB MovePlayer
    IF _KEYDOWN(100) = -1 THEN
        pX = pX + (deltaTime * playerSpeed)
    END IF
    IF _KEYDOWN(97) = -1 THEN
        pX = pX - (deltaTime * playerSpeed)
    END IF
 
    IF pX < 20 THEN
        pX = 20
    END IF
    IF pX > 300 THEN
        pX = 300
    END IF
 
    LINE (pX - 10, 175)-(pX + 100, 201), _RGB(0, 0, 0), BF
    PUT (pX, 175), player%()
    _DISPLAY
END SUB
 
SUB DrawShields
    FOR x = 0 TO 3
        PUT (x * (320 / 4) + 30, 150), shield%()
    NEXT x
END SUB
 
SUB LoadSprite (sp%())
    DIM sprite(4, 4)
    scale = 2
    FOR y = 0 TO 4
        FOR x = 0 TO 4
            READ sprite(x, y) 'Read the data
        NEXT x
    NEXT y
 
    FOR y = 0 TO 4 * scale STEP scale 'Factor in the scale
        FOR x = 0 TO 4 * scale STEP scale
            LINE (x, y)-(x + scale, y + scale), sprite(x / scale, y / scale), BF 'Draw each pixel
        NEXT x
    NEXT y
 
    GET (0, 0)-(10, 10), sp%()
    CLS
END SUB
 
'Alien 1 Data
DATA 0,0,15,0,0
DATA 0,15,15,15,0
DATA 0,15,15,15,0
DATA 15,0,15,0,15
DATA 0,15,0,15,0
 
'Alien 2 Data
DATA 0,0,15,0,0
DATA 0,15,15,15,0
DATA 0,15,0,15,0
DATA 15,0,0,0,15
DATA 15,0,0,0,15
 
'Alien 3 Data
DATA 15,0,0,0,15
DATA 15,0,15,0,15
DATA 0,15,0,15,0
DATA 0,15,0,15,0
DATA 0,0,15,0,0
 
'Shield Data
DATA 0,15,15,15,0
DATA 15,15,15,15,15
DATA 15,15,0,15,15
DATA 15,0,0,0,15
DATA 15,0,0,0,15
 
'Player Data
DATA 0,0,0,0,0
DATA 0,0,15,0,0
DATA 0,15,15,15,0
DATA 15,15,15,15,15
DATA 15,15,15,15,15
 
e]
 
Yes. It is for a space invaders clone im making. 
 
Zep

QB64 Discussion / Re: Discord

« on: June 26, 2019, 04:31:53 am »

Quote

September 16, 2018, 09:02:01 PM »
Great to hear that everyone is ok.
Just an idea, but someone make a discord so that we can chat and not disturb the forum?
I think it will help people with small problems and you get notified when someone needs help.
Pretty good I think

Zeppelin

So now we have one ;)

Pages: [1] 2 3

News:

Show Posts

Messages - Zeppelin

Programs / Re: Intersection of two circles

Programs / Re: _PUT Rotation Help

Programs / _PUT Rotation Help

Programs / Re: Drawing Polygons

Programs / Drawing Polygons

Programs / Re: Mini Messenger

QB64 Discussion / Re: Rotating Sprites

QB64 Discussion / Rotating Sprites

Programs / Re: Higher/Smoother framerate movement

Programs / Higher/Smoother framerate movement

QB64 Discussion / _PRINTSTRING For INPUT

Programs / Re: GUESS MY NUMBER GAME

Programs / Re: GUESS MY NUMBER GAME

Programs / Smooth Sprite Movement

QB64 Discussion / Re: Discord