Comma delimited numbers with decimal len

[xra7en]

Love QB64 (I put it 1 step higher than pascal, only because QB64 can do full screen pascal cannot)
OK I digress,
I am sure this code I made is an over kill, however, It works, but sometimes it is putting a "," in front of the  number

example instead of
295,559.00
it does
,295,559.00

If there is a better method that would be great

I do not want to use a print using "###.##" etc... I need a return string

thanks for looking

Code: QB64: [Select]

1. FUNCTION NUM2STR$ (x AS DOUBLE, PRECISION AS INTEGER)
2.     DIM I, J AS INTEGER
3.     '// x           = number to convert
4.     '// precision   = how many decimals places to the right
5.    
6.  
7.     DIM STR_X AS STRING
8.     DIM DECPOS AS INTEGER
9.     DIM DEC_STR AS STRING
10.     DIM INT_STR AS STRING
11.     DIM COMMA AS STRING
12.  
13.     '// If less than 1,000 then no comma needed
14.     '// exit sub
15.     STR_X = STR$(x)
16.     IF x < 1000 THEN
17.         NUM2STR = STR_X
18.         EXIT SUB
19.     END IF
20.  
21.     '// FIND A DECIMAL
22.     DECPOS = INSTR(STR_X, ".")
23.  
24.     '// WORK ON DECIMAL SECTION
25.     IF DECPOS = 0 THEN '                        // NO DECIMAL?
26.         DEC_STR = ".00"
27.     ELSE
28.         DEC_STR = MID$(STR_X, DECPOS, PRECISION + 1)
29.     END IF
30.  
31.     '// If there is a decimal, calc string, otherwise the int_str = the string
32.     IF DECPOS = 0 THEN
33.         INT_STR = STR_X
34.     ELSE
35.         INT_STR = LEFT$(STR_X, DECPOS - 1)
36.     END IF
37.  
38.  
39.     COMMA = ""
40.     J = 0
41.     FOR I = LEN(INT_STR) TO 0 STEP -1
42.         J = J + 1
43.         IF J = 4 THEN
44.             COMMA = MID$(INT_STR, I, 1) + "," + COMMA
45.             J = 0
46.         ELSE
47.             COMMA = MID$(INT_STR, I, 1) + COMMA
48.         END IF
49.     NEXT
50.     NUM2STR$ = COMMA + DEC_STR
51.  
52. END FUNCTION

[SMcNeill]

Isn't it a case of you manually adding the comma with:

NUM2STR$ = COMMA + DEC_STR

[Pete]

That's not it. The variable isn't necessarily a comma. Try some numbers. The algorithms are just off. 100 doesn't add .00, but 1000 does. 1000 outputs 1,000.00 but 234567 outputs , 234,567 and 2345678 outputs , 2345,678.

Added input code so others could try numbers...

Code: QB64: [Select]

1. INPUT "Number: "; x
2. y$ = NUM2STR$(x, 0)
3. PRINT y$
4. DO: SLEEP: LOOP UNTIL INKEY$ <> ""
5. RUN
6.  
7. FUNCTION NUM2STR$ (x AS DOUBLE, PRECISION AS INTEGER)
8. DIM I, J AS INTEGER
9. '// x           = number to convert
10. '// precision   = how many decimals places to the right
11.  
12.  
13. DIM STR_X AS STRING
14. DIM DECPOS AS INTEGER
15. DIM DEC_STR AS STRING
16. DIM INT_STR AS STRING
17. DIM COMMA AS STRING
18.  
19. '// If less than 1,000 then no comma needed
20. '// exit sub
21. STR_X = STR$(x)
22. IF x < 1000 THEN
23.     NUM2STR = STR_X
24.     EXIT SUB
25. END IF
26.  
27. '// FIND A DECIMAL
28. DECPOS = INSTR(STR_X, ".")
29.  
30. '// WORK ON DECIMAL SECTION
31. IF DECPOS = 0 THEN '                        // NO DECIMAL?
32.     DEC_STR = ".00"
33. ELSE
34.     DEC_STR = MID$(STR_X, DECPOS, PRECISION + 1)
35. END IF
36.  
37. '// If there is a decimal, calc string, otherwise the int_str = the string
38. IF DECPOS = 0 THEN
39.     INT_STR = STR_X
40. ELSE
41.     INT_STR = LEFT$(STR_X, DECPOS - 1)
42. END IF
43.  
44.  
45. COMMA = ""
46. J = 0
47. FOR I = LEN(INT_STR) TO 0 STEP -1
48.     J = J + 1
49.     IF J = 4 THEN
50.         COMMA = MID$(INT_STR, I, 1) + "," + COMMA
51.         J = 0
52.     ELSE
53.         COMMA = MID$(INT_STR, I, 1) + COMMA
54.     END IF
55. NEXT
56. NUM2STR$ = COMMA + DEC_STR
57.  
58. END FUNCTION
59.  

Pete

[bplus]

6 of 1, h,alf do,zen of a,not,her:

Code: QB64: [Select]

1. _TITLE "Commatose Test" 'B+  2018-12-03
2. COLOR 2, 0
3. DIM test AS DOUBLE
4. FOR i = 1 TO 20
5.     test = .123456789123456789123456789 * 10 ^ i
6.     PRINT Commatose$(test, 2)
7. NEXT
8. DO
9.     INPUT "Enter a number to test Commatose ", test
10.     PRINT Commatose$(test, 4)
11. LOOP UNTIL test = 0
12.  
13.  
14. FUNCTION Commatose$ (v AS DOUBLE, precision AS INTEGER)
15.     sv$ = LTRIM$(STR$(v)) '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ltrim$ remove leading space!
16.     dot = INSTR(sv$, ".")
17.     IF dot THEN
18.         i$ = MID$(sv$, 1, dot - 1)
19.         d$ = LEFT$(MID$(sv$, dot + 1) + STRING$(precision, "0"), precision)
20.     ELSE
21.         i$ = sv$
22.         d$ = STRING$(precision, "0")
23.     END IF
24.     FOR i = LEN(i$) TO 1 STEP -1
25.         c = c + 1
26.         IF c = 4 THEN c = 1: b$ = "," + b$
27.         b$ = MID$(i$, i, 1) + b$
28.     NEXT
29.     Commatose$ = b$ + "." + d$
30. END FUNCTION
31.  
32.  

Yes sir, that IS half of a Christmas tree! ;-))

[xra7en]

6 of 1, h,alf do,zen of a,not,her:

Code: QB64: [Select]

1.  
2.     sv$ = LTRIM$(STR$(v)) '<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ltrim$ remove leading space!
3.    
4.  
5.  

Yes sir, that IS half of a Christmas tree! ;-))

Yup the guilty line! Thanks!!!

[bplus]

Thanks, I forget that leading space more times than I care to remember. :)

[xra7en]

Thanks, I forget that leading space more times than I care to remember. :)

its funny the qb64 did not add a trim function, they have left/righ but nothing for all
strings they do, left/right and mid meh simple function to solve that :-)

Code: QB64: [Select]

1. function trim(txt as string)
2.     trim = ltrim$(rtrim$(txt))
3. end function

I think that does it :P

[FellippeHeitor]

The development build has _TRIM$(), which is a macro for LTRIM$(RTRIM$()), and it'll be available in the next version yet to be released.

[xra7en]

The development build has _TRIM$(), which is a macro for LTRIM$(RTRIM$()), and it'll be available in the next version yet to be released.

suweet!! I downloaded the latest today from git, not much changed in this version - still seems to be at 1.2 (the last one I had was 2/2/2018)

[FellippeHeitor]

You probably grabbed from the master branch instead of the development branch. Get it from qb64.org instead.