Sprite Library Revisited

[TerryRitchie]

I have a 3 dimension array that needs saved/loaded:

TYPE SL_ANGLE
    x1 AS INTEGER '                     collision box upper left x
    x2 AS INTEGER '                     collision box lower right x
    y1 AS INTEGER '                     collision box upper left y
    y2 AS INTEGER '                     collision box lower right y
    cwidth AS INTEGER '                 collision box width
    cheight AS INTEGER '                collision box height
    radius AS INTEGER '                 collision circle radius
    rwidth AS INTEGER '                 rotated sprite width
    rheight AS INTEGER '                rotated sprite height
    px0 AS INTEGER '                    rectangular rotation coordinates
    px1 AS INTEGER
    px2 AS INTEGER
    px3 AS INTEGER
    py0 AS INTEGER
    py1 AS INTEGER
    py2 AS INTEGER
    py3 AS INTEGER
END TYPE

SL_angle(x, y, 359) AS SL_ANGLE  (x = sheet#, y = cell#, rotational angle from 0 to 359

I tried saving the entire array with a single PUT command, but when I bring it back with a single GET for some reason all the data contained in the even numbered entries is set to zero.

Here is what I'm using to save the file:

Code: QB64: [Select]

1.     IF NOT _FILEEXISTS(rotfile) THEN '                                                                  does it exist?
2.         OPEN rotfile FOR BINARY AS #1 '                                                                 no, open it for writing
3.         FOR x = 1 TO cells '                                                                            cycle through all sprite cells
4.             FOR y = 0 TO 359 '                                                                          and their rotational angles
5.                 PUT #1, , SL_angle(handle, x, y) '                                                      put the data
6.             NEXT y
7.         NEXT x
8.         CLOSE #1 '                                                                                      close the file
9.     END IF
10.  

and here is what I am using to load the file:

Code: QB64: [Select]

1.     rotfile = LEFT$(filename, INSTR(filename, ".") - 1) + ".rot" '                                      the name of the rotational data file
2.     IF _FILEEXISTS(rotfile) THEN '                                                                      does it exist?
3.         preloaded = -1 '                                                                                yes, remember that data has been preloaded
4.         OPEN rotfile FOR BINARY AS #1 '                                                                 open it for reading
5.         FOR x = 1 TO cells '                                                                            cycle through all animation cells
6.             FOR y = 0 TO 359 '                                                                          and their associated rotational data
7.                 GET #1, , SL_angle(handle, x, y) '                                                      get the data
8.             NEXT y
9.         NEXT x
10.         CLOSE #1 '                                                                                      close the file
11.     END IF
12.  

[SMcNeill]

Dim a memblock, point it to your array:


DIM m AS _MEM
M = _MEM(SL_Angle())

Set a temp variable to hold it all, and put that to the file in one go.

t$ = SPACE(M.SIZE)
_MEMGET M, M.OFFSET, t$
PUT #1, , t$
......

Reverse the process to restore it in one go.

t$ = SPACE$(M.SIZE)
GET #1, , t$
_MEMPUT M, M.OFFSET, t$

****************************

I'm thinking the end result should save you some disk access time.  (And if M can be static/shared, you won't need to _MEMFREE or assign it more than once, saving some initialization time there as well.)


*****************
*****************

EDIT:   And, I see potential issues with the shared code:  Change #1 to a FREEFILE handle.  You can't be certain that a library user isn't going to already have file #1 opened for some other purpose (such as a save game file).

[TerryRitchie]

Thank you for helping me make this better/faster.

Yes! You are correct, FREEFILE should always be used in library. I'm glad you caught that.

[TempodiBasic]

Hi Terry
you have started to go on the moon and now your astroship is acrossing the rings of Saturn. Wonderful!!! Hard but great work!

about your issue about PUT#FileNumberFree, , array() and GET#FileNumberFree, , array()
using your model of code I have tried and it seems to work well saving and loading in one shot the array from/to the file.
Here my lazy mod:

Code: QB64: [Select]

1. TYPE SL_ANGLE
2.     x1 AS INTEGER '                     collision box upper left x
3.     x2 AS INTEGER '                     collision box lower right x
4.     y1 AS INTEGER '                     collision box upper left y
5.     y2 AS INTEGER '                     collision box lower right y
6.     cwidth AS INTEGER '                 collision box width
7.     cheight AS INTEGER '                collision box height
8.     radius AS INTEGER '                 collision circle radius
9.     rwidth AS INTEGER '                 rotated sprite width
10.     rheight AS INTEGER '                rotated sprite height
11.     px0 AS INTEGER '                    rectangular rotation coordinates
12.     px1 AS INTEGER
13.     px2 AS INTEGER
14.     px3 AS INTEGER
15.     py0 AS INTEGER
16.     py1 AS INTEGER
17.     py2 AS INTEGER
18.     py3 AS INTEGER
19. END TYPE
20.  
21. REDIM SL_angle(1 TO 2, 1 TO 5, 0 TO 359) AS SL_ANGLE '(x = sheet#, y = cell#, rotational angle from 0 to 359
22.  
23. 'IF NOT _FILEEXISTS("rotfile") THEN '                                                                  does it exist?
24. handle = 1: cells = 5: numfile = FREEFILE
25. VIEW PRINT 1 TO 13
26. OPEN "rotfile" FOR BINARY AS #numfile '                                                                 no, open it for writing
27. FOR x = 1 TO cells '                                                                            cycle through all sprite cells
28.     FOR y = 0 TO 359 '                                                                          and their rotational angles
29.         SL_angle(handle, x, y).x1 = x
30.         SL_angle(handle, x, y).y1 = y
31.         SL_angle(handle, x, y).radius = y
32.         PRINT SL_angle(handle, x, y).x1; " "; SL_angle(handle, x, y).y1; " "; SL_angle(handle, x, y).radius
33.  
34.     NEXT y
35. NEXT x
36. PUT #numfile, , SL_angle() '                                                      put the data
37. CLOSE #numfile '                                                                                      close the file
38. 'END IF
39.  
40. '   rotfile = LEFT$(filename, INSTR(filename, ".") - 1) + ".rot" '                                      the name of the rotational data file
41. VIEW PRINT 14 TO 24
42. IF _FILEEXISTS("rotfile") THEN '                                                                      does it exist?
43.     preloaded = -1 '                                                                                yes, remember that data has been preloaded
44.     OPEN "rotfile" FOR BINARY AS #numfile '                                                                 open it for reading
45.     GET #numfile, , SL_angle() '                                                      get the data
46.     FOR x = 1 TO cells '                                                                            cycle through all animation cells
47.         FOR y = 0 TO 359 '                                                                          and their associated rotational data
48.             PRINT SL_angle(handle, x, y).x1; " "; SL_angle(handle, x, y).y1; " "; SL_angle(handle, x, y).radius
49.         NEXT y
50.     NEXT x
51.     CLOSE #numfile '                                                                                      close the file
52. END IF
53. VIEW PRINT
54.  
55.  

I hope this can be useful for your coding.
PS here I add Steve's suggestion to use FREEFILE to be safe from conflict about number of file used to open a file.

[TerryRitchie]

Thanks for code Tempo, I'll investigate it in a little bit.

Right now I'm tracking down some layer issues I have. I needed to have a working program to track the issues down so I created this quick Roman numeral clock using some cheesy clock graphics I found on the net. It's a good example showing how powerful this little library is already becoming. You'll need the two graphic files below if you wish to run the demo.

Code: QB64: [Select]

1. '** NOTES **
2.  
3.  
4.  
5. ' Ideas to add
6. '
7. ' if SL_EVENT_TRIGGER then 'check for event that was sent (add event triggers)
8. ' - possible link sounds to events
9. ' add gravity, attraction, repulsion  SL_SET_PHYSICS
10. ' add mass, elasticity (bounciness?)   ^  ^  ^
11. ' add arc calculator for things like a swinging vine or radar scope
12. ' ability to link sprites, when one moves the other moves, break apart when collision happens SL_LINK_SPRITE
13. ' give sprites path-following ability (bezier curves?) SL_FOLLOW_PATH
14. ' divide work space into cells and detect when sprites enter/leave a cell
15. ' stand-alone program to develop sprite sheets (inform)        \
16. ' stand-alone program to develop celled work spaces (inform)   /  combine these into one program?
17. ' when sprite interact their mass, elascticity, etc. govern the way the move and fall
18. ' - I will need help from a math major for this
19.  
20. ' Planned additions
21. '
22. ' get sprite width and height (both actual and collision box) SL_GET_ACTUAL_WIDTH, SL_GET_ACTUAL_HEIGHT, SL_GET_COLLISION_WIDTH, SL_GET_COLLISION_HEIGHT
23. ' set Z depth of sprite for different planes/layers (possibly incorporate this into zoom?)
24. ' - need to figure out how to rotate collision box along with sprites, not too hard
25. ' - this will require line segment intersection algorithms for collision detection, yikes! hard, probably need help
26. ' - possibly link sounds to collisions SL_LINK_COLLIDE_SOUND
27. ' Parallaxing layers  SL_CREATE_PARALLAX, SL_UPDATE_PARALLAX
28. ' Game font printing
29. ' Sprite tiling, square for sure, isometric?
30.  
31. ' Things to improve
32. '
33. ' Naming convention of constants and their values
34. ' Use integers wherever possible
35. ' allow SINGLE value rotation angles for accuracy but convert to integer before sprite rotation
36. ' - using only integer now, may not be precise enough for future improvements
37.  
38. ' Investigate
39. '
40. ' Use of _MAPTRIANGLE for 3D rotation   SL_ROTATE_3D
41. ' _HARDWARE vs _HARDWARE1
42.  
43. ' Remember
44. '
45. ' Any code added that is OS dependant needs to detect the OS running first
46. ' - try to create routines that are OS dependant for all OS'
47.  
48.  
49.  
50. OPTION _EXPLICIT ' need to remove before publishing library!!
51.  
52. '*
53. '* constant declarations
54. '*
55.  
56. '      CONSTANT NAME                   DESCRIPTION                                                       FUNCTIONS / SUBROUTINES THAT MAY USE THIS CONSTANT
57. ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
58. CONST SL_RESET = -32767 '   reset a function or subroutine              SL_ROTATE_SPRITE, SL_FLIP_SPRITE, SL_ZOOM_SPRITE, SL_SET_ZOOM, SL_CHANGE_AUTOROTATION, SL_CHANGE_AUTOMOTION, SL_CHANGE_ROTATION_SPEED, SL_SET_COLLISION
59. CONST SL_NOFLIP = 0 '       sprite will use no flipping                 SL_FLIP_SPRITE
60. CONST SL_HORIZONTAL = 1 '   sprite will be flipped horizontally         SL_FLIP_SPRITE
61. CONST SL_VERTICAL = 2 '     sprite will be flipped vertically           SL_FLIP_SPRITE
62. CONST SL_FLIPBOTH = 3 '     sprite will be flipped both direction       SL_FLIP_SPRITE
63. CONST SL_USESHEET = -1 '    use sheet's transparency info (.PNG)        SL_NEW_SHEET
64. CONST SL_SET = 0 '          manually set transparency                   SL_NEW_SHEET
65. CONST SL_NONE = 1 '         don't use transparency with sheet           SL_NEW_SHEET
66. CONST SL_NOSAVE = 0 '       sprite will not save background             SL_NEW_SPRITE, SL_SET_SOFTWARE
67. CONST SL_SAVE = -1 '        sprite will save background                 SL_NEW_SPRITE, SL_SET_SOFTWARE
68. CONST SL_HARDWARE = 0 '     sprite in hardware mode                     SL_NEW_SPRITE, SL_update_auto_sprites
69. CONST SL_SOFTWARE = -1 '    sprite in software mode                     SL_NEW_SPRITE, SL_update_auto_sprites
70. CONST SL_START = -1 '       enable auto motion / rotation               SL_CHANGE_AUTOMOTION, SL_CHANGE_AUTOROTATION, SL_SET_AUTOANIMATION, SL_SET_ANIMATION, SL_SET_MOTION, SL_SET_ROTATION
71. CONST SL_STOP = 0 '         disable auto motion / rotation              SL_CHANGE_AUTOMOTION, SL_CHANGE_AUTOROTATION, SL_SET_AUTOANIMATION, SL_SET_ANIMATION, SL_SET_MOTION, SL_SET_ROTATION, SL_CHANGE_ROTATION_SPEED
72. CONST SL_FORWARD = 0 '      animation cells proceed forward             SL_SET_ANIMATION
73. CONST SL_BACKWARD = 1 '     animation cells proceed backwards           SL_SET_ANIMATION
74. CONST SL_BACKFORTH = 2 '    animation cells toggle forward/backward     SL_SET_ANIMATION
75. CONST SL_CURRENTCELL = -1 ' use current cell as starting cell           SL_SET_ANIMATION, SL_CHANGE_ANIMATION_CELLS
76. CONST SL_SHOW = -1 '        sprite will be shown on screen              SL_SET_SPRITE_VISIBLE, SL_SET_LAYER_VISIBLE
77. CONST SL_HIDE = 0 '         sprite will not be shown on screen          SL_SET_SPRITE_VISIBLE, SL_SET_LAYER_VISIBLE
78. CONST SL_NODETECT = 0 '     sprite uses no collision detection          SL_SET_COLLISION
79. CONST SL_BOXDETECT = 1 '    sprite uses box collision detect            SL_SET_COLLISION
80. CONST SL_ROUNDDETECT = 2 '  sprite uses round collision detect '        SL_SET_COLLISION
81. CONST SL_PIXELDETECT = 3 '  sprite uses pixel perfect collision detect  SL_SET_COLLISION
82. CONST SL_ALL = -1 '         check for all sprites                       SL_GET_COLLISION, SL_GET_MOUSE, SL_CLEAR_LAYER
83. CONST SL_NOMOUSE = 0 '      no mouse interaction with sprite            SL_GET_MOUSE
84. CONST SL_HOVER = 1 '        mouse pointer hovering over sprite          SL_GET_MOUSE
85. CONST SL_LEFTCLICK = 2 '    left mouse button clicked on sprite         SL_GET_MOUSE
86. CONST SL_RIGHTCLICK = 3 '   right mouse button clicked on sprite        SL_GET_MOUSE
87. CONST SL_CENTERCLICK = 4 '  center mouse button clicked on sprite       SL_GET_MOUSE
88.  
89. '*
90. '* type declarations
91. '*
92.  
93. TYPE SL_SHEET ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ SPRITE SHEET DATABASE ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
94.     software AS LONG '                  software sprite image
95.     mask AS LONG '                      software mask image
96.     swidth AS INTEGER '                 width of sprite
97.     sheight AS INTEGER '                height of sprite
98.     transparency AS INTEGER '           -1 (TRUE) if sheet uses transparency
99.     clearcolor AS _UNSIGNED LONG '      transparent color of image
100. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
101.  
102. TYPE SL_XY ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ X,Y LOCATIONS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
103.     real AS SINGLE '                    single values of sprite x,y center point
104.     int AS INTEGER '                    integer values of sprite x,y center point
105.     actual AS INTEGER '                 integer values of sprite upper left x,y location
106.     back AS INTEGER '                   integer values of sprite's background image x,y location
107.     dir AS SINGLE '                     single values of sprite x,y motion vectors
108. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
109.  
110. TYPE SL_IMAGE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ IMAGES ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
111.     hardware AS LONG '                  hardware sprite image
112.     software AS LONG '                  software sprite image
113.     mask AS LONG '                      software sprite mask image
114.     back AS LONG '                      software sprite saved background image
115. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
116.  
117. TYPE SL_ANIM ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ ANIMATION SETTINGS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
118.     cell AS INTEGER '                   current animation cell
119.     cellfrom AS INTEGER '               starting animation cell
120.     cellto AS INTEGER '                 ending animation cell
121.     dir AS INTEGER '                    animation direction
122.     mode AS INTEGER '                   animation mode (forward, backward, back/forth)
123.     framerate AS INTEGER '              sprite animation frame rate
124.     frame AS INTEGER '                  animation frame counter
125.     skip AS INTEGER '                   how often to skip a frame to achieve framerate
126.     auto AS INTEGER '                   auto-animation on/off
127. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
128.  
129. TYPE SL_MOTION ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ MOTION SETTINGS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
130.     auto AS INTEGER '                   -1 (TRUE) if auto-motion turned on
131.     speed AS SINGLE '                   speed of sprite during motion
132.     angle AS INTEGER '                  direction of sprite during motion (0 - 359)
133. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
134.  
135. TYPE SL_ROTATION ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ ROTATION SETTINGS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
136.     auto AS INTEGER '                   -1 (TRUE) if auto-rotation turned on
137.     speed AS INTEGER '                  spin rate in degrees of sprite (0 - 359)
138.     angle AS INTEGER '                  current rotation angle of sprite
139. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
140.  
141. TYPE SL_COLLISION ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ COLLISION SETTINGS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
142.     detect AS INTEGER '                 type of detection this sprite uses (box, round, ellipse, pixel)
143.     box AS INTEGER '                    -1 (TRUE) if a box collision detected
144.     round AS INTEGER '                  -1 (TRUE) if a round collision detected
145.     pixel AS INTEGER '                  -1 (TRUE) if a pixel perfect collision detected
146.     with AS INTEGER '                   the sprite collision happened with
147.     radius AS INTEGER '                 radius of round collision area
148.     x1 AS INTEGER '                     collision box upper left x
149.     x2 AS INTEGER '                     collision box lower right x
150.     y1 AS INTEGER '                     collision box upper left y
151.     y2 AS INTEGER '                     collision box lower right y
152.     cwidth AS INTEGER '                 width of collision box
153.     cheight AS INTEGER '                height of collision box
154.     xpoint AS INTEGER '                 x location of collision
155.     ypoint AS INTEGER '                 y location of collision
156. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
157.  
158. TYPE SL_MOUSE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ MOUSE SETTINGS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
159.     event AS INTEGER '                  last event on sprite (hover, click, etc)
160.     x AS INTEGER '                      x location of mouse on sprite
161.     y AS INTEGER '                      y location of mouse on sprite
162.     xa AS INTEGER '                     x location of mouse on screen
163.     ya AS INTEGER '                     y location of mouse on screen
164. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
165.  
166. TYPE SL_SPRITE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ SPRITE DATABASE ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
167.     inuse AS INTEGER '                  this array index in use
168.     x AS SL_XY '                        x coordinate locations
169.     y AS SL_XY '                        y coordinate locations
170.     gfx AS SL_IMAGE '                   image graphics
171.     animation AS SL_ANIM '              animation settings
172.     motion AS SL_MOTION '               motion settings
173.     rotation AS SL_ROTATION '           rotation settings
174.     collision AS SL_COLLISION '         collision settings
175.     mouse AS SL_MOUSE '                 mouse interaction settings
176.     sheet AS INTEGER '                  sheet sprite belongs to
177.     cell AS INTEGER '                   current sprite cell
178.     swidth AS INTEGER '                 width of sprite
179.     sheight AS INTEGER '                height of sprite
180.     restore AS INTEGER '                -1 (TRUE) if sprite restores background
181.     flip AS INTEGER '                   flip horizontally, vertically, or both
182.     transparency AS INTEGER '           -1 (TRUE) if sprite uses transparency
183.     zoom AS INTEGER '                   zoom level of sprite (1% - x%)
184.     software AS INTEGER '               -1 (TRUE) if sprite is to be treated as software image
185.     score AS INTEGER '                  point score of sprite
186.     visible AS INTEGER '                -1 (TRUE) if sprite visible
187.     layer AS INTEGER '                  the layer the sprite belongs to
188. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
189.  
190. TYPE SL_ANGLE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ ROTATION ANGLE & COLLISION BOX DATABASE ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
191.     x1 AS INTEGER '                     collision box upper left x
192.     x2 AS INTEGER '                     collision box lower right x
193.     y1 AS INTEGER '                     collision box upper left y
194.     y2 AS INTEGER '                     collision box lower right y
195.     cwidth AS INTEGER '                 collision box width
196.     cheight AS INTEGER '                collision box height
197.     radius AS INTEGER '                 collision circle radius
198.     rwidth AS INTEGER '                 rotated sprite width
199.     rheight AS INTEGER '                rotated sprite height
200.     px0 AS INTEGER '                    rectangular rotation coordinates
201.     px1 AS INTEGER
202.     px2 AS INTEGER
203.     px3 AS INTEGER
204.     py0 AS INTEGER
205.     py1 AS INTEGER
206.     py2 AS INTEGER
207.     py3 AS INTEGER
208. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
209.  
210. TYPE SL_LAYERS ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ LAYER DATABASE ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
211.     image AS LONG '                     software image of screen layer
212.     visible AS INTEGER '                -1 (TRUE) if layer is visible
213. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
214.  
215. TYPE SL_GLOBAL ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ GLOBALS DATABASE ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
216.     layer AS INTEGER '                  active layer
217.     swidth AS INTEGER '                 screen width
218.     sheight AS INTEGER '                screen height
219.     framerate AS INTEGER '              global frame rate
220.     source AS INTEGER '                 current source layer
221.     destination AS INTEGER '            current destination layer
222. END TYPE ' ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
223.  
224. '*
225. '* global dynamic array declarations
226. '*
227.  
228. REDIM SL_sheet(1, 1) AS SL_SHEET '      sheet#, cell# - master sheet array
229. REDIM SL_angle(1, 1, 359) AS SL_ANGLE ' sheet#, cell#, angle# - master sheet precalculated angle array
230. REDIM SL_sprite(1) AS SL_SPRITE '       master working sprite array
231. REDIM SL_layer(1) AS SL_LAYERS '        image layer array
232.  
233. '
234. '*
235. '* global variable declarations
236. '*
237.  
238. DIM SL_global AS SL_GLOBAL
239.  
240. '*
241. '* main code (for testing)
242. '*
243.  
244. DIM handsheet AS INTEGER '      clock hand sprite sheet
245. DIM hour AS INTEGER '           hour hand sprite
246. DIM minute AS INTEGER '         minute hand sprite
247. DIM second AS INTEGER '         second hand sprite
248. DIM h AS INTEGER '              current hour value
249. DIM m AS INTEGER '              current minute value
250. DIM s AS INTEGER '              current second value
251.  
252. SL_SCREEN 551, 551, 1 '                                                                                 set window size and layers
253. _TITLE "Clock Demo" '                                                                                   give window a title
254. handsheet = SL_NEW_SHEET("hands73x533.png", 73, 533, SL_SET, _RGB32(255, 0, 255)) '                     load the clock hands
255. hour = SL_NEW_SPRITE(1, handsheet, 2, SL_HARDWARE, SL_NOSAVE) '                                         get the hour hand
256. minute = SL_NEW_SPRITE(1, handsheet, 1, SL_HARDWARE, SL_NOSAVE) '                                       get the minute hand
257. second = SL_NEW_SPRITE(1, handsheet, 3, SL_HARDWARE, SL_NOSAVE) '                                       get the second hand
258. _PUTIMAGE , _LOADIMAGE("face.png", 32) '                                                                display the clock face
259. SL_SET_FRAMERATE 5 '                                                                                    set the global frame rate
260. DO
261.     _LIMIT SL_GET_FRAMERATE '                                                                           maintain global frame rate
262.     h = VAL(TIME$) '                                                                                    get current hour value
263.     IF h > 11 THEN h = h - 12 '                                                                         keep a 12 hour clock
264.     m = VAL(MID$(TIME$, 4, 2)) '                                                                        get current minute value
265.     s = VAL(MID$(TIME$, 7, 2)) '                                                                        get current second value
266.     SL_ROTATE_SPRITE hour, 30 * h + m \ 2 '                                                             rotate hour hand into position
267.     SL_ROTATE_SPRITE minute, 6 * m + s \ 10 '                                                           rotate minute hand into position
268.     SL_ROTATE_SPRITE second, 6 * s '                                                                    rotate second hand into position
269.     SL_PUT_SPRITE 276, 276, hour '                                                                      display the hour hand
270.     SL_PUT_SPRITE 276, 276, minute '                                                                    display the minute hand
271.     SL_PUT_SPRITE 276, 276, second '                                                                    display the second hand
272.     SL_DISPLAY '                                                                                        merge layers and display
273. LOOP UNTIL _KEYHIT '                                                                                    leave when key hit
274. SL_FREE_SPRITE hour '                                                                                   free sprites from memory
275. SL_FREE_SPRITE minute
276. SL_FREE_SPRITE second
277. END
278.  
279.  
280.  
281. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
282. '                                                                       ----------==========                ==========----------
283. '                                                                       ----------========== LAYER ROUTINES ==========----------
284. '                                                                       ----------==========                ==========----------
285. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
286.  
287. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
288. SUB SL_SCREEN (swidth AS INTEGER, sheight AS INTEGER, layers AS INTEGER) '                                                                                                                    SL_SCREEN
289.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
290.  
291.     ' declare global variables
292.  
293.     SHARED SL_layer() AS SL_LAYERS '    master layer array
294.     SHARED SL_global AS SL_GLOBAL '     common globals array
295.  
296.     ' declare local variables
297.  
298.     DIM layer AS INTEGER '              layer counter
299.  
300.     ' perform error checks
301.  
302.     IF layers < 1 THEN '                                                                                creating at least one layer?
303.         SL_error "SL_SCREEN", 26, "" '                                                                  no, report error to programmer
304.     END IF
305.  
306.     REDIM SL_layer(layers) AS SL_LAYERS '                                                               increase layer array to match requested number of layers
307.     SL_global.swidth = swidth '                                                                         set screen width
308.     SL_global.sheight = sheight '                                                                       set screen height
309.     layer = 0 '                                                                                         reset layer counter
310.  
311.     DO '                                                                                                cycle through layers
312.         SL_layer(layer).image = _NEWIMAGE(swidth, sheight, 32) '                                        create layer software image
313.         SL_layer(layer).visible = -1 '                                                          (TRUE)  layer is visible
314.         layer = layer + 1 '                                                                             increment layer counter
315.     LOOP UNTIL layer = UBOUND(SL_layer) + 1 '                                                           leave when all layers created
316.  
317.     SL_SET_DESTINATION_LAYER 1 '                                                                        set destination layer
318.     SL_SET_SOURCE_LAYER 1 '                                                                             set source layer
319.     SCREEN SL_layer(0).image '                                                                          initialize layer 0 working screen
320.  
321. END SUB
322.  
323. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
324. SUB SL_DISPLAY () '                                                                                                                                                                          SL_DISPLAY
325.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
326.  
327.     ' declare global variables
328.  
329.     SHARED SL_layer() AS SL_LAYERS '    master layer array
330.     SHARED SL_global AS SL_GLOBAL '     common globals array
331.  
332.     ' declare local variables
333.  
334.     DIM layer AS INTEGER '              layer counter
335.     DIM odest AS INTEGER '              original destination
336.     DIM merge AS LONG '                 software image to merge all layers onto
337.     DIM hardware AS LONG '              hardware image of merged layers to place on working screen
338.  
339.     SL_update_auto_sprites -1 '                                                          (SL_SOFTWARE)  update all software automatic sprites
340.     odest = _DEST '                                                                                     save original destination
341.     _DEST SL_layer(0).image '                                                                           working screen is destination
342.     merge = _NEWIMAGE(SL_global.swidth, SL_global.sheight, 32) '                                        create screen to merge layers
343.     layer = UBOUND(SL_layer) '                                                                          reset layer counter
344.  
345.     DO '                                                                                                cycle through layers backwards (high to low)
346.         IF SL_layer(layer).visible THEN '                                                               is this layer visible?
347.             _PUTIMAGE , SL_layer(layer).image, merge '                                                  merge this layer
348.         END IF
349.         layer = layer - 1 '                                                                             decrement layer counter
350.     LOOP UNTIL layer = 0 '                                                                              leave when all layers merged
351.  
352.     hardware = _COPYIMAGE(merge, 33) '                                                                  create hardware image of merged layers
353.     _PUTIMAGE , hardware '                                                                              place hardware image on working screen
354.     _FREEIMAGE merge '                                                                                  merged software image no longer needed
355.     _FREEIMAGE hardware '                                                                               merged hardware image no longer needed
356.     SL_update_auto_sprites 0 '                                                           (SL_HARDWARE)  update all hardware automatic sprites
357.     _DEST odest '                                                                                       restore original destination
358.     _DISPLAY '                                                                                          update display screen with changes
359.  
360. END SUB
361.  
362. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
363. SUB SL_SET_DESTINATION_LAYER (layer AS INTEGER) '                                                                                                                              SL_SET_DESTINATION_LAYER
364.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
365.  
366.     ' declare global variables
367.  
368.     SHARED SL_layer() AS SL_LAYERS '    master layer array
369.     SHARED SL_global AS SL_GLOBAL '     common globals array
370.  
371.     ' perform error checks
372.  
373.     IF layer <> -32767 THEN '                                                               (SL_RESET)  reset to working image?
374.         IF NOT SL_VALID_LAYER(layer) THEN '                                                             no, valid layer?
375.             SL_error "SL_SET_DESTINATION_LAYER", 25, "" '                                               no, report error to programmer
376.         ELSE '                                                                                          yes, valid layer
377.             _DEST SL_layer(layer).image '                                                               set destination as layer software image
378.             SL_global.destination = layer '                                                             save new destination layer
379.         END IF
380.     ELSE '                                                                                              yes, reset layer
381.         _DEST SL_layer(1).image '                                                                       set destination as layer 1 software image
382.         SL_global.destination = 1 '                                                                     save new destination layer
383.     END IF
384.  
385. END SUB
386.  
387. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
388. SUB SL_SET_SOURCE_LAYER (layer AS INTEGER) '                                                                                                                                        SL_SET_SOURCE_LAYER
389.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
390.  
391.     ' declare global variables
392.  
393.     SHARED SL_layer() AS SL_LAYERS '    master layer array
394.     SHARED SL_global AS SL_GLOBAL '     common globals array
395.  
396.     ' perform error checks
397.  
398.     IF layer <> -32767 THEN '                                                               (SL_RESET)  reset to working image?
399.         IF NOT SL_VALID_LAYER(layer) THEN '                                                             no, valid layer?
400.             SL_error "SL_SET_SOURCE_LAYER", 25, "" '                                                    no, report error to programmer
401.         ELSE '                                                                                          yes, valid layer
402.             _SOURCE SL_layer(layer).image '                                                             set source as layer software image
403.             SL_global.source = layer '                                                                  save new source layer
404.         END IF
405.     ELSE '                                                                                              yes, reset layer
406.         _SOURCE SL_layer(1).image '                                                                     set source as layer 1 software image
407.         SL_global.source = 1 '                                                                          save new source layer
408.     END IF
409.  
410. END SUB
411.  
412. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
413. FUNCTION SL_GET_DESTINATION_LAYER () '                                                                                                                                         SL_GET_DESTINATION_LAYER
414.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
415.  
416.     ' declare global variables
417.  
418.     SHARED SL_global AS SL_GLOBAL '     common globals array
419.  
420.     SL_GET_DESTINATION_LAYER = SL_global.destination '                                                  return current destination layer
421.  
422. END FUNCTION
423.  
424. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
425. FUNCTION SL_GET_SOURCE_LAYER () '                                                                                                                                                   SL_GET_SOURCE_LAYER
426.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
427.  
428.     ' declare global variables
429.  
430.     SHARED SL_global AS SL_GLOBAL '     common globals array
431.  
432.     SL_GET_SOURCE_LAYER = SL_global.source '                                                            return current source layer
433.  
434. END FUNCTION
435.  
436. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
437. SUB SL_CLEAR_LAYER (layer AS INTEGER) '                                                                                                                                                  SL_CLEAR_LAYER
438.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
439.  
440.     ' declare global variables
441.  
442.     SHARED SL_layer() AS SL_LAYERS '    master layer array
443.     SHARED SL_global AS SL_GLOBAL '     common globals array
444.  
445.     ' declare local variables
446.  
447.     DIM layers AS INTEGER '             layer counter
448.  
449.     ' perform error checks
450.  
451.     IF layer <> -1 THEN '                                                                     (SL_ALL)  clear all layers?
452.         IF NOT SL_VALID_LAYER(layer) THEN '                                                             no, valid layer?
453.             SL_error "SL_CLEAR_LAYER", 25, "" '                                                         no, report error to programmer
454.         END IF
455.         _FREEIMAGE SL_layer(layer).image '                                                              free the layer's software image from memory
456.         SL_layer(layer).image = _NEWIMAGE(SL_global.swidth, SL_global.sheight, 32) '                    create a new software layer
457.     ELSE '                                                                                              yes, clear all layers
458.         layers = 0 '                                                                                    reset layer counter
459.         DO
460.             layers = layers + 1 '                                                                       increment layer counter
461.             _FREEIMAGE SL_layer(layers).image '                                                         free the layer's software image from memory
462.             SL_layer(layers).image = _NEWIMAGE(SL_global.swidth, SL_global.sheight, 32) '               create a new software layer
463.         LOOP UNTIL layers = UBOUND(SL_layer) '                                                          leave when all layers cleared
464.     END IF
465.  
466. END SUB
467.  
468. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
469. FUNCTION SL_VALID_LAYER (layer AS INTEGER) '                                                                                                                                             SL_VALID_LAYER
470.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
471.  
472.     ' declare global variables
473.  
474.     SHARED SL_layer() AS SL_LAYERS '    master layer array
475.  
476.     IF layer < 1 OR layer > UBOUND(SL_layer) THEN '                                                     valid layer?
477.         SL_VALID_LAYER = 0 '                                                                   (FALSE)  no, return invalid
478.     ELSE '                                                                                              yes
479.         SL_VALID_LAYER = -1 '                                                                   (TRUE)  return valid
480.     END IF
481.  
482. END FUNCTION
483.  
484. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
485. FUNCTION SL_SCREEN_WIDTH () '                                                                                                                                                           SL_SCREEN_WIDTH
486.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
487.  
488.     ' declare global variables
489.  
490.     SHARED SL_global AS SL_GLOBAL '     common globals array
491.  
492.     SL_SCREEN_WIDTH = SL_global.swidth '                                                                return screen width
493.  
494. END FUNCTION
495.  
496. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
497. FUNCTION SL_SCREEN_HEIGHT () '                                                                                                                                                         SL_SCREEN_HEIGHT
498.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
499.  
500.     ' declare global variables
501.  
502.     SHARED SL_global AS SL_GLOBAL '     common globals array
503.  
504.     SL_SCREEN_HEIGHT = SL_global.sheight '                                                              return screen height
505.  
506. END FUNCTION
507.  
508. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
509. SUB SL_SET_LAYER_VISBILE (layer AS INTEGER, visible AS INTEGER) '                                                                                                                  SL_SET_LAYER_VISIBLE
510.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
511.  
512.     ' declare global variables
513.  
514.     SHARED SL_layer() AS SL_LAYERS '    master layer array
515.  
516.     ' perform error checks
517.  
518.     IF NOT SL_VALID_LAYER(layer) THEN '                                                                 no, valid layer?
519.         SL_error "SL_SET_LAYER_VISIBLE", 25, "" '                                                       no, report error to programmer
520.     END IF
521.     IF (visible < -1) OR (visible > 0) THEN '                                      (SL_SHOW & SL_HIDE)  valid visible behavior requested?
522.         SL_error "SL_SET_LAYER_VISIBLE", 20, "" '                                                       no, report error to programmer
523.     END IF
524.  
525.     SL_layer(layer).visible = visible '                                                                 set layer visibility
526.  
527. END SUB
528.  
529. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
530. '                                                                       ----------==========                ==========----------
531. '                                                                       ----------========== MOUSE ROUTINES ==========----------
532. '                                                                       ----------==========                ==========----------
533. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
534.  
535. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
536. FUNCTION SL_GET_MOUSE (handle AS INTEGER) '                                                                                                                                                SL_GET_MOUSE
537.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
538.  
539.     ' declare global variables
540.  
541.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
542.  
543.     ' declare local variables
544.  
545.     DIM sprite AS INTEGER '             sprite counter to cycle through array
546.     DIM event AS INTEGER '              -1 (TRUE) if an event was recorded
547.  
548.     ' perform error checks
549.  
550.     IF handle <> -1 THEN '                                                                    (SL_ALL)  check all sprites for mouse interaction?
551.         IF NOT SL_VALID_SPRITE(handle) THEN '                                                           no, is this a valid sprite?
552.             SL_error "SL_GET_MOUSE", 1, "" '                                                            no, report error to programmer
553.         END IF
554.         IF NOT SL_sprite(handle).visible THEN '                                                         is sprite visible?
555.             EXIT FUNCTION '                                                                             no, leave function
556.         END IF
557.     END IF
558.     IF handle = -1 THEN '                                                                     (SL_ALL)  check all sprites?
559.         sprite = 1 '                                                                                    yes, start with first index
560.     ELSE '                                                                                              no, check a single sprite
561.         sprite = handle '                                                                               start with that sprite
562.     END IF
563.  
564.     DO '                                                                                                cycle through sprite array
565.         IF SL_sprite(handle).inuse AND SL_sprite(handle).visible THEN '                                 is sprite in use and visible?
566.             SL_sprite(handle).mouse.event = 0 '                                                         yes, reset mouse settings
567.             SL_sprite(handle).mouse.x = 0
568.             SL_sprite(handle).mouse.y = 0
569.             SL_sprite(handle).mouse.xa = 0
570.             SL_sprite(handle).mouse.ya = 0
571.             WHILE _MOUSEINPUT: WEND '                                                                   get latest mouse information
572.             IF _MOUSEX >= SL_sprite(sprite).collision.x1 THEN '                                         is mouse pointer on sprite?
573.                 IF _MOUSEX <= SL_sprite(sprite).collision.x2 THEN
574.                     IF _MOUSEY >= SL_sprite(sprite).collision.y1 THEN
575.                         IF _MOUSEY <= SL_sprite(sprite).collision.y2 THEN
576.                             event = -1 '                                                                yes, remember that an event occurred
577.                             SL_sprite(sprite).mouse.xa = _MOUSEX '                                      screen location of mouse x
578.                             SL_sprite(sprite).mouse.ya = _MOUSEY '                                      screen location of mouse y
579.                             SL_sprite(sprite).mouse.x = _MOUSEX - SL_sprite(sprite).x.actual '          sprite location of mouse x
580.                             SL_sprite(sprite).mouse.y = _MOUSEY - SL_sprite(sprite).y.actual '          sprite location of mouse y
581.                             IF _MOUSEBUTTON(1) THEN '                                                   is left button clicked?
582.                                 SL_GET_MOUSE = 2 '                                      (SL_LEFTCLICK)  yes, return value
583.                                 SL_sprite(sprite).mouse.event = 2 '                     (SL_LEFTCLICK)  record mouse event
584.                             ELSEIF _MOUSEBUTTON(2) THEN '                                               no, is right button clicked?
585.                                 SL_GET_MOUSE = 3 '                                     (SL_RIGHTCLICK)  yes, return value
586.                                 SL_sprite(sprite).mouse.event = 3 '                    (SL_RIGHTCLICK)  record mouse event
587.                             ELSEIF _MOUSEBUTTON(3) THEN '                                               no, is center button clicked?
588.                                 SL_GET_MOUSE = 4 '                                    (SL_CENTERCLICK)  yes, return value
589.                                 SL_sprite(sprite).mouse.event = 4 '                   (SL_CENTERCLICK)  record mouse event
590.                             ELSE '                                                                      no, mouse is just hovering
591.                                 SL_GET_MOUSE = 1 '                                          (SL_HOVER)  return value
592.                                 SL_sprite(sprite).mouse.event = 1 '                         (SL_HOVER)  record mouse event
593.                             END IF
594.                         END IF
595.                     END IF
596.                 END IF
597.             END IF
598.         END IF
599.         sprite = sprite + 1 '                                                                           increment sprite counter
600.     LOOP UNTIL sprite = (UBOUND(SL_sprite) + 1) OR (handle = -1) '                                      leave when full array or single sprite checked
601.  
602.     IF handle = -1 THEN '                                                                     (SL_ALL)  were all sprites checked?
603.         IF event THEN '                                                                                 yes, was there an event with any of them?
604.             SL_GET_MOUSE = -1 '                                                                 (TRUE)  return that an event occurred
605.         ELSE '                                                                                          no events recorded
606.             SL_GET_MOUSE = 0 '                                                                 (FALSE)  return that no events occurred
607.         END IF
608.     END IF
609.  
610. END FUNCTION
611.  
612. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
613. FUNCTION SL_GET_MOUSE_EVENT (handle AS INTEGER) '                                                                                                                                    SL_GET_MOUSE_EVENT
614.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
615.  
616.     ' declare global variables
617.  
618.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
619.  
620.     ' perform error checks
621.  
622.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
623.         SL_error "SL_GET_MOUSE_EVENT", 1, "" '                                                          no, report error to programmer
624.     END IF
625.  
626.     SL_GET_MOUSE_EVENT = SL_sprite(handle).mouse.event '                                                return mouse event
627.     SL_sprite(handle).mouse.event = 0 '                                                                 reset now that value retrieved
628.  
629. END FUNCTION
630.  
631. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
632. FUNCTION SL_GET_MOUSE_SPRITEX (handle AS INTEGER) '                                                                                                                                SL_GET_MOUSE_SPRITEX
633.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
634.  
635.     ' declare global variables
636.  
637.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
638.  
639.     ' perform error checks
640.  
641.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
642.         SL_error "SL_GET_MOUSE_SPRITEX", 1, "" '                                                        no, report error to programmer
643.     END IF
644.  
645.     SL_GET_MOUSE_SPRITEX = SL_sprite(handle).mouse.x '                                                  return x value of mouse on sprite
646.     SL_sprite(handle).mouse.x = 0 '                                                                     reset now that value retrieved
647.  
648. END FUNCTION
649.  
650. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
651. FUNCTION SL_GET_MOUSE_SPRITEY (handle AS INTEGER) '                                                                                                                                SL_GET_MOUSE_SPRITEY
652.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
653.  
654.     ' declare global variables
655.  
656.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
657.  
658.     ' perform error checks
659.  
660.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
661.         SL_error "SL_GET_MOUSE_SPRITEY", 1, "" '                                                        no, report error to programmer
662.     END IF
663.  
664.     SL_GET_MOUSE_SPRITEY = SL_sprite(handle).mouse.y '                                                  return y value of mouse on sprite
665.     SL_sprite(handle).mouse.y = 0 '                                                                     reset now that value retrieved
666.  
667. END FUNCTION
668.  
669. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
670. FUNCTION SL_GET_MOUSE_ACTUALX (handle AS INTEGER) '                                                                                                                                SL_GET_MOUSE_ACTUALX
671.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
672.  
673.     ' declare global variables
674.  
675.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
676.  
677.     ' perform error checks
678.  
679.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
680.         SL_error "SL_GET_MOUSE_ACTUALX", 1, "" '                                                        no, report error to programmer
681.     END IF
682.  
683.     SL_GET_MOUSE_ACTUALX = SL_sprite(handle).mouse.xa '                                                 return x value of mouse on screen
684.     SL_sprite(handle).mouse.xa = 0 '                                                                    reset now that value retrieved
685.  
686. END FUNCTION
687.  
688. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
689. FUNCTION SL_GET_MOUSE_ACTUALY (handle AS INTEGER) '                                                                                                                                SL_GET_MOUSE_ACTUALY
690.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
691.  
692.     ' declare global variables
693.  
694.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
695.  
696.     ' perform error checks
697.  
698.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
699.         SL_error "SL_GET_MOUSE_ACTUALY", 1, "" '                                                        no, report error to programmer
700.     END IF
701.  
702.     SL_GET_MOUSE_ACTUALY = SL_sprite(handle).mouse.ya '                                                 return y value of mouse on screen
703.     SL_sprite(handle).mouse.ya = 0 '                                                                    reset now that value retrieved
704.  
705. END FUNCTION
706.  
707. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
708. '                                                                     ----------==========                    ==========----------
709. '                                                                     ----------========== COLLISION ROUTINES ==========----------
710. '                                                                     ----------==========                    ==========----------
711. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
712.  
713. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
714. FUNCTION SL_GET_COLLISION (handle1 AS INTEGER, handle2 AS INTEGER) '                                                                                                                   SL_GET_COLLISION
715.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
716.  
717.     ' declare global variables
718.  
719.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
720.  
721.     ' declare local variables
722.  
723.     DIM sprite AS INTEGER '             sprite counter in loop
724.  
725.     ' perform error checks
726.  
727.     IF NOT SL_VALID_SPRITE(handle1) THEN '                                                              is this a valid sprite?
728.         SL_error "SL_GET_COLLISION", 1, "" '                                                            no, report error to programmer
729.     END IF
730.     IF handle2 <> -1 THEN '                                                                   (SL_ALL)  check for collision with all sprites?
731.         IF NOT SL_VALID_SPRITE(handle2) THEN '                                                          no, is this a valid sprite?
732.             SL_error "SL_GET_COLLISION", 1, "" '                                                        no, report error to programmer
733.         END IF
734.         IF SL_sprite(handle2).collision.detect = 0 THEN '                                               collision detection turned on?
735.             SL_error "SL_GET_COLLISION", 22, "" '                                                       no, report error to programmer
736.         END IF
737.         'IF SL_sprite(handle1).collision.detect <> SL_sprite(handle2).collision.detect THEN '            both sprites use same detection method?
738.         '    SL_error "SL_GET_COLLISION", 23, "" '                                                       no, report error to programmer
739.         'END IF
740.     END IF
741.     IF SL_sprite(handle1).collision.detect = 0 THEN '                                                   collision detection turned on?
742.         SL_error "SL_GET_COLLISION", 21, "" '                                                           no, report error to programmer
743.     END IF
744.  
745.     SELECT CASE SL_sprite(handle1).collision.detect
746.         CASE 1 '                                                                              (SL_BOX)  box detection
747.             IF handle2 <> -1 THEN '                                                           (SL_ALL)  check all sprites for collision?
748.                 SL_sprite(handle1).collision.box = SL_box_collision(SL_sprite(handle1).collision.x1,_
749.                                                                     SL_sprite(handle1).collision.y1,_
750.                                                                     SL_sprite(handle1).collision.cwidth,_
751.                                                                     SL_sprite(handle1).collision.cheight,_
752.                                                                     SL_sprite(handle2).collision.x2,_
753.                                                                     SL_sprite(handle2).collision.y2,_
754.                                                                     SL_sprite(handle2).collision.cwidth,_
755.                                                                     SL_sprite(handle2).collision.cheight) ' no, check for a box collision of two sprites
756.                 IF SL_sprite(handle1).collision.box THEN '                                              was there a collision?
757.                     SL_sprite(handle1).collision.with = handle2 '                                       yes, record sprite that was collided with
758.                     SL_sprite(handle2).collision.with = handle1 '                                       tell the other sprite who it collided with
759.                     SL_GET_COLLISION = handle2 '                                                (TRUE)  return that a collision happened
760.                 END IF
761.             ELSE '                                                                                      yes, check all sprites
762.                 sprite = 0 '                                                                            reset sprite counter
763.                 DO '                                                                                    cycle through sprite array
764.                     sprite = sprite + 1 '                                                               increment sprite counter
765.                     IF SL_sprite(sprite).inuse AND SL_sprite(sprite).collision.detect THEN '            is sprite in use and using collision detection?
766.                         SL_sprite(handle1).collision.box = SL_box_collision(SL_sprite(handle1).collision.x1,_
767.                                                                             SL_sprite(handle1).collision.y1,_
768.                                                                             SL_sprite(handle1).collision.cwidth,_
769.                                                                             SL_sprite(handle1).collision.cheight,_
770.                                                                             SL_sprite(sprite).collision.x2,_
771.                                                                             SL_sprite(sprite).collision.y2,_
772.                                                                             SL_sprite(sprite).collision.cwidth,_
773.                                                                             SL_sprite(sprite).collision.cheight) ' yes, check for a box collision of two sprites
774.                         IF SL_sprite(handle1).collision.box THEN '                                      box collision detected?
775.                             SL_sprite(handle1).collision.with = sprite '                                yes, record sprite that was collided with
776.                             SL_sprite(sprite).collision.with = handle1 '                                tell the other sprite who it collided with
777.                             SL_GET_COLLISION = sprite '                                         (TRUE)  return that collision happened
778.                             sprite = UBOUND(SL_sprite) '                                                no need to check further
779.                         END IF
780.                     END IF
781.                 LOOP UNTIL sprite = UBOUND(SL_sprite) '                                                 leave when end of array reached
782.             END IF
783.         CASE 2 '                                                                            (SL_ROUND)  round collision
784.             IF handle2 <> -1 THEN '                                                           (SL_ALL)  check all sprites for collision?
785.                 SL_sprite(handle1).collision.round = sl_round_collision(SL_sprite(handle1).x.int,_
786.                                                                         SL_sprite(handle1).y.int,_
787.                                                                         SL_sprite(handle1).collision.radius,_
788.                                                                         SL_SPRITE(handle2).x.int,_
789.                                                                         SL_sprite(handle2).y.int,_
790.                                                                         SL_sprite(handle2).collision.radius) ' no, check for a round collision of two sprites
791.                 IF SL_sprite(handle1).collision.round THEN '                                            was there a collision?
792.                     SL_sprite(handle1).collision.with = handle2 '                                       yes, record sprite that was collided with
793.                     SL_sprite(handle2).collision.with = handle1 '                                       tell the other sprite who it collided with
794.                     SL_GET_COLLISION = handle2 '                                                (TRUE)  return that a collision happened
795.                 END IF
796.             ELSE '                                                                                      yes, check all sprites
797.                 sprite = 0 '                                                                            reset sprite counter
798.                 DO '                                                                                    cycle through sprite array
799.                     sprite = sprite + 1 '                                                               increment sprite counter
800.                     IF SL_sprite(sprite).inuse AND SL_sprite(sprite).collision.detect THEN '            is sprite in use and using collision detection?
801.                         SL_sprite(handle1).collision.round = sl_round_collision(SL_sprite(handle1).x.int,_
802.                                                                                 SL_sprite(handle1).y.int,_
803.                                                                                 SL_sprite(handle1).collision.radius,_
804.                                                                                 SL_sprite(sprite).x.int,_
805.                                                                                 SL_sprite(sprite).y.int,_
806.                                                                                 SL_sprite(sprite).collision.radius) ' yes, check for a round collision of two sprites
807.                         IF SL_sprite(handle1).collision.round THEN '                                    round collision detected?
808.                             SL_sprite(handle1).collision.with = sprite '                                yes, record sprite that was collided with
809.                             SL_sprite(sprite).collision.with = handle1 '                                tell the other sprite who it collided with
810.                             SL_GET_COLLISION = sprite '                                         (TRUE)  return that collision happened
811.                             sprite = UBOUND(SL_sprite) '                                                no need to check further
812.                         END IF
813.                     END IF
814.                 LOOP UNTIL sprite = UBOUND(SL_sprite) '                                                 leave when end of array reached
815.             END IF
816.         CASE 3 '                                                                            (SL_PIXEL)  pixel perfect collision
817.             IF handle2 <> -1 THEN '                                                           (SL_ALL)  check all sprites for collision?
818.                 SL_sprite(handle1).collision.pixel = SL_PIXEL_COLLISION(handle1, handle2) '             yes, check for a pixel collision of two sprites
819.                 IF SL_sprite(handle1).collision.pixel THEN '                                            pixel collision detected?
820.                     SL_sprite(handle1).collision.with = handle2 '                                       yes, record sprite that was collided with
821.                     SL_sprite(handle2).collision.with = handle1 '                                       tell the other sprite who it collided with
822.                     SL_GET_COLLISION = handle2 '                                                (TRUE)  return that collision happened
823.                 END IF
824.             ELSE '                                                                                      yes, check all sprites
825.                 sprite = 0 '                                                                            reset sprite counter
826.                 DO '                                                                                    cycle through sprite array
827.                     sprite = sprite + 1 '                                                               increment sprite counter
828.                     IF SL_sprite(sprite).inuse AND SL_sprite(sprite).collision.detect THEN '            is sprite in use and using collision detection? (may need to see if mask available too) <--------------- LOOK
829.                         SL_sprite(handle1).collision.pixel = SL_PIXEL_COLLISION(handle1, sprite) '      yes, check for a pixel collision of two sprites
830.                         IF SL_sprite(handle1).collision.pixel THEN '                                    pixel collision detected?
831.                             SL_sprite(handle1).collision.with = sprite '                                yes, record sprite that was collided with
832.                             SL_sprite(sprite).collision.with = handle1 '                                tell the other sprite who it collided with
833.                             SL_GET_COLLISION = sprite '                                         (TRUE)  return that collision happened
834.                             sprite = UBOUND(SL_sprite) '                                                no need to check further
835.                         END IF
836.                     END IF
837.                 LOOP UNTIL sprite = UBOUND(SL_sprite) '                                                 leave when end of array reached
838.             END IF
839.     END SELECT
840.  
841. END FUNCTION
842.  
843. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
844. FUNCTION SL_ROUND_COLLISION (x1 AS INTEGER, y1 AS INTEGER, r1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER, r2 AS INTEGER) '                                                             SL_ROUND_COLLISION
845.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
846.  
847.     IF SL_GET_DISTANCE_POINT_TO_POINT(x1, y1, x2, y2) < r1 + r2 THEN '                                  is distance less than both radii added together?
848.         SL_ROUND_COLLISION = -1 '                                                               (TRUE)  yes, return a collision
849.     END IF
850.  
851. END FUNCTION
852.  
853. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
854. FUNCTION SL_BOX_COLLISION (x1 AS INTEGER, y1 AS INTEGER, w1 AS INTEGER, h1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER, w2 AS INTEGER, h2 AS INTEGER) '                                   SL_BOX_COLLISION
855.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
856.  
857.     IF x1 <= x2 + w2 THEN '                                                                             is x1 within box 2's width?
858.         IF x1 + w1 >= x2 THEN '                                                                         yes, is x2 within box 1's width?
859.             IF y1 <= y2 + h2 THEN '                                                                     yes, is y1 within box 2's height?
860.                 IF y1 + h1 >= y2 THEN '                                                                 yes, is y2 within box 1's height?
861.                     SL_BOX_COLLISION = -1 '                                                     (TRUE)  yes, return a collision
862.                 END IF
863.             END IF
864.         END IF
865.     END IF
866.  
867. END FUNCTION
868.  
869. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
870. FUNCTION SL_PIXEL_COLLISION (handle1 AS INTEGER, handle2 AS INTEGER) '                                                                                                               SL_PIXEL_COLLISION
871.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
872.  
873.     ' declare global variables
874.  
875.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
876.  
877.     ' declare local variables
878.  
879.     DIM leftx AS INTEGER '              upper left x location of box collision area
880.     DIM rightx AS INTEGER '             lower right x location of box collision area
881.     DIM topy AS INTEGER '               upper left y location of box collision area
882.     DIM bottomy AS INTEGER '            lower right y location of box collision area
883.     DIM masks AS LONG '                 box collision area image to place masks
884.     DIM h1x AS INTEGER '                center point x offset for first sprite mask image
885.     DIM h2x AS INTEGER '                center point x offset for second sprite mask image
886.     DIM h1y AS INTEGER '                center point y offset for first sprite mask image
887.     DIM h2y AS INTEGER '                center point y offset for second sprite mask image
888.     DIM odest AS LONG '                 original destination
889.     DIM osource AS LONG '               original source
890.     DIM x AS INTEGER '                  counter to cycle through width of mask image
891.     DIM y AS INTEGER '                  counter to cycle throuogh height of mask image
892.  
893.     ' perform error checks
894.  
895.     IF (NOT SL_VALID_SPRITE(handle1)) OR (NOT SL_VALID_SPRITE(handle2)) THEN '                          are these valid sprites?
896.         SL_error "SL_PIXEL_COLLISION", 1, "" '                                                          no, report error to programmer
897.     END IF
898.  
899.     ' if there is no box collision then no need to check for pixel collision
900.  
901.     IF  SL_box_collision(SL_sprite(handle1).collision.x1, SL_sprite(handle1).collision.y1,_
902.                            SL_sprite(handle1).collision.cwidth, SL_sprite(handle1).collision.cheight,_
903.                            SL_sprite(handle2).collision.x2, SL_sprite(handle2).collision.y2,_
904.                            SL_sprite(handle2).collision.cwidth, SL_sprite(handle2).collision.cheight) THEN 'is there a box collision?
905.         leftx = SL_max(SL_sprite(handle1).collision.x1, SL_sprite(handle2).collision.x1) '              yes, get collision area coordinates
906.         rightx = SL_min(SL_sprite(handle1).collision.x1 + SL_sprite(handle1).collision.cwidth,_
907.                         SL_sprite(handle2).collision.x1 + SL_sprite(handle2).collision.cwidth)
908.         topy = SL_max(SL_sprite(handle1).collision.y1, SL_sprite(handle2).collision.y1)
909.         bottomy = SL_min(SL_sprite(handle1).collision.y1 + SL_sprite(handle1).collision.cheight,_
910.                          SL_sprite(handle2).collision.y1 + SL_sprite(handle2).collision.cheight)
911.  
912.         odest = _DEST '                                                                                 save original destination
913.         osource = _SOURCE '                                                                             save original source
914.         masks = _NEWIMAGE(rightx - leftx, bottomy - topy, 32) '                                         create image of same size to hold image masks
915.         h1x = SL_sprite(handle1).x.int - leftx '                                                        get image mask center point offsets from collision area upper left x,y
916.         h1y = SL_sprite(handle1).y.int - topy
917.         h2x = SL_sprite(handle2).x.int - leftx
918.         h2y = SL_sprite(handle2).y.int - topy
919.         _DEST masks '                                                                                   masks are to be drawn on new image
920.         _SOURCE masks '                                                                                 pixels are to be examined on new image
921.         _PUTIMAGE (-h1x, -h1y), SL_sprite(handle1).gfx.mask '                                           draw first sprite mask onto image
922.         _PUTIMAGE (-h2x, -h2y), SL_sprite(handle2).gfx.mask '                                           draw second sprite mask onto image
923.         x = 0 '                                                                                         reset width couonter
924.  
925.         DO '                                                                                            cycle through width of image
926.             y = 0 '                                                                                     reset height counter
927.             DO '                                                                                        cycle through height of image
928.                 IF POINT(x, y) = _RGBA32(0, 0, 0, 0) THEN '                                             is this a black pixel? <----------------------------------- used saved clearcolor instead?  LOOK
929.                     SL_sprite(handle1).collision.with = handle2 '                                       yes, record sprite that was collided with
930.                     SL_sprite(handle2).collision.with = handle1 '                                       tell the other sprite who it collided with
931.                     SL_PIXEL_COLLISION = handle2 '                                              (TRUE)  return that collision happened
932.                     y = _HEIGHT(masks) - 1 '                                                            no need to continue loop
933.                     x = _WIDTH(masks) - 1 '                                                             no need to continue loop
934.                 END IF
935.                 y = y + 1 '                                                                             increment height counter
936.             LOOP UNTIL y = _HEIGHT(masks) '                                                             leave when full height cycled
937.             x = x + 1 '                                                                                 increment width counter
938.         LOOP UNTIL x = _WIDTH(masks) '                                                                  leave when full width cycled
939.  
940.         _SOURCE osource '                                                                               restore original source
941.         _DEST odest '                                                                                   restore original destination
942.         _FREEIMAGE masks '                                                                              mask image no longer needed
943.     END IF
944.  
945. END FUNCTION
946.  
947. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
948. SUB SL_SET_COLLISION (handle AS INTEGER, method AS INTEGER) '                                                                                                                          SL_SET_COLLISION
949.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
950.  
951.     ' declare global variables
952.  
953.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
954.  
955.     ' perform error checks
956.  
957.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
958.         SL_error "SL_SET_COLLISION", 1, "" '                                                            no, report error to programmer
959.     END IF
960.     IF method = -32767 THEN '                                                               (SL_RESET)  reset collision detection?
961.         SL_sprite(handle).collision.detect = 0 '                                         (SL_NODETECT)  yes, reset detection
962.     ELSEIF method < 0 OR method > 3 THEN ' (SL_NODETECT, SL_BOXDETECT, SL_ROUNDDETECT, SL_PIXELDETECT)  invalid mode?
963.         SL_error "SL_SET_COLLISION", 24, "" '                                                           yes, report error to programmer
964.     ELSE '                                                                                              no
965.         SL_sprite(handle).collision.detect = method '                                                   set collision detection mode
966.     END IF
967.  
968. END SUB
969.  
970. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
971. '                                                                     ----------==========                    ==========----------
972. '                                                                     ----------========== ANIMATION ROUTINES ==========----------
973. '                                                                     ----------==========                    ==========----------
974. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
975.  
976. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
977. SUB SL_SET_FRAMERATE (framerate AS INTEGER) '                                                                                                                                          SL_SET_FRAMERATE
978.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
979.  
980.     ' declare global variables
981.  
982.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
983.     SHARED SL_global AS SL_GLOBAL
984.  
985.     ' declare local variables
986.  
987.     DIM handle AS INTEGER '             counter to cycle through sprite handles
988.  
989.     ' perform error checks
990.  
991.     IF framerate < 1 THEN '                                                                             valid frame rate?
992.         SL_error "SL_SET_FRAMERATE", 10, "" '                                                           no, report error to programmer
993.     END IF
994.  
995.     ' set local variables
996.  
997.     SL_global.framerate = framerate '                                                                   set global frame rate
998.     handle = 0 '                                                                                        reset handle counter
999.  
1000.     DO '                                                                                                update all available sprites
1001.         handle = handle + 1 '                                                                           increment sprite pointer
1002.         IF SL_sprite(handle).inuse THEN '                                                               is this sprite in use?
1003.             IF SL_sprite(handle).animation.framerate THEN '                                             yes, does it contain an animation frame rate?
1004.                 IF framerate < SL_sprite(handle).animation.framerate THEN '                             is new global frame rate less than sprite's frame rate?
1005.                     SL_sprite(handle).animation.framerate = framerate '                                 yes, set sprite's frame rate to global frame rate
1006.                 END IF
1007.                 IF framerate = SL_sprite(handle).animation.framerate THEN '                             animation and global frame rates the same?
1008.                     SL_sprite(handle).animation.skip = 0 '                                              yes, nothing needs to be done with frames
1009.                 ELSEIF SL_sprite(handle).animation.framerate >= framerate \ 2 THEN '                    no, sprite frame rate 1/2 or less of master frame rate?
1010.                     SL_sprite(handle).animation.skip = framerate \ (framerate - SL_sprite(handle).animation.framerate) ' yes, calculate every frame to skip
1011.                 ELSE '                                                                                  no, sprite frame rate is greater than 1/2 of master frame rate
1012.                     SL_sprite(handle).animation.skip = framerate \ SL_sprite(handle).animation.framerate ' calculate every frame to draw
1013.                 END IF
1014.             END IF
1015.         END IF
1016.     LOOP UNTIL handle = UBOUND(SL_sprite) '                                                             leave when all sprites updated
1017.  
1018. END SUB
1019.  
1020. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1021. FUNCTION SL_GET_FRAMERATE () '                                                                                                                                                         SL_GET_FRAMERATE
1022.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1023.  
1024.     ' declare global variables
1025.  
1026.     SHARED SL_global AS SL_GLOBAL
1027.  
1028.     SL_GET_FRAMERATE = SL_global.framerate '                                                            return global frame rate
1029.  
1030. END FUNCTION
1031.  
1032. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1033. SUB SL_NEXT_ANIMATION_CELL (handle AS INTEGER) '                                                                                                                                 SL_NEXT_ANIMATION_CELL
1034.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1035.  
1036.     ' declare global variables
1037.  
1038.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1039.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
1040.  
1041.     ' perform error checks
1042.  
1043.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1044.         SL_error "SL_NEXT_ANIMATION_CELL", 1, "" '                                                      no, report error to programmer
1045.     END IF
1046.     IF NOT SL_sprite(handle).animation.cellfrom THEN '                                                  has animation been assigned to this sprite?
1047.         SL_error "SL_NEXT_ANIMATION_CELL", 15, "" '                                                     no, report error to programmer
1048.     END IF
1049.     IF SL_sprite(handle).animation.auto THEN '                                                          is this sprite under auto animation control?
1050.         SL_error "SL_NEXT_ANIMATION_CELL", 18, "" '                                                     yes, report error to programmer
1051.     END IF
1052.  
1053.     SELECT CASE SL_sprite(handle).animation.mode '                                                      which animation mode is this sprite using?
1054.         CASE 0 '                                                                          (SL_FORWARD)  move forward through the cells
1055.             SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell + 1 '                   increment animation cell
1056.             IF SL_sprite(handle).animation.cell > SL_sprite(handle).animation.cellto THEN '             passed the last cell?
1057.                 SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellfrom '               yes, go back to first cell
1058.             END IF
1059.         CASE 1 '                                                                         (SL_BACKWARD)  move backward through the cells
1060.             SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell - 1 '                   decrement animation cell
1061.             IF SL_sprite(handle).animation.cell < SL_sprite(handle).animation.cellfrom THEN '           passed the first cell?
1062.                 SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellto '                 yes, go back to last cell
1063.             END IF
1064.         CASE 2 '                                                                        (SL_BACKFORTH)  ping-pong back and forth through the cells
1065.             SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell + SL_sprite(handle).animation.dir ' increment/decrement animation cell
1066.             IF SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellto OR _
1067.                SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellfrom THEN '           is this the first or last cell?
1068.                 SL_sprite(handle).animation.dir = -SL_sprite(handle).animation.dir '                    yes, reverse animation direction
1069.             END IF
1070.     END SELECT
1071.     SL_sprite(handle).cell = SL_sprite(handle).animation.cell '                                         update current sprite cell
1072.     IF SL_sprite(handle).rotation.angle AND (NOT SL_sprite(handle).rotation.auto) THEN '                is this animation currently rotated but not automatic?
1073.         SL_ROTATE_SPRITE handle, SL_sprite(handle).rotation.angle '                                     yes, this new cell will need manually rotated as well
1074.     ELSE '                                                                                              no rotation, but still needs image updated
1075.         _FREEIMAGE SL_sprite(handle).gfx.software '                                                     remove current software image from memory
1076.         SL_sprite(handle).gfx.software = _COPYIMAGE(SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).software, 32) ' get new software image
1077.         IF SL_sprite(handle).gfx.mask THEN '                                                            is there a mask with this image?
1078.             _FREEIMAGE SL_sprite(handle).gfx.mask '                                                     yes, remove the software mask image from memory
1079.             SL_sprite(handle).gfx.mask = _COPYIMAGE(SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).mask, 32) ' get new software mask image
1080.         END IF
1081.     END IF
1082.  
1083. END SUB
1084.  
1085. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1086. SUB SL_CHANGE_ANIMATION_CELLS (handle AS INTEGER, cellfrom AS INTEGER, cellto AS INTEGER) '                                                                                   SL_CHANGE_ANIMATION_CELLS
1087.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1088.  
1089.     ' declare global variables
1090.  
1091.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1092.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
1093.  
1094.     ' perform error checks
1095.  
1096.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1097.         SL_error "SL_CHANGE_ANIMATION_CELLS", 1, "" '                                                   no, report error to programmer
1098.     END IF
1099.     IF NOT SL_sprite(handle).animation.cellfrom THEN '                                                  has animation been assigned to this sprite?
1100.         SL_error "SL_CHANGE_ANIMATION_CELLS", 15, "" '                                                  no, report error to programmer
1101.     END IF
1102.     IF NOT SL_VALID_CELL(SL_sprite(handle).sheet, cellfrom) THEN '                                      no, is this a valid cell request?
1103.         SL_error "SL_CHANGE_ANIMATION_CELLS", 13, "" '                                                  no, report error to rpogrammer
1104.     END IF
1105.     IF NOT SL_VALID_CELL(SL_sprite(handle).sheet, cellto) THEN '                                        is this valid cell request?
1106.         SL_error "SL_CHANGE_ANIMATION_CELLS", 13, "" '                                                  no, report error to programmer
1107.     END IF
1108.  
1109.     SL_sprite(handle).animation.cellfrom = cellfrom '                                                   set first cell in animation
1110.     SL_sprite(handle).animation.cellto = cellto '                                                       set last cell in animation
1111.     SL_sprite(handle).animation.cell = cellfrom '                                                       set current animation cell to first cell
1112.     SL_sprite(handle).cell = cellfrom '                                                                 set current sprite cell to first cell
1113.  
1114.     IF SL_sprite(handle).animation.cellto < SL_sprite(handle).animation.cellfrom THEN '                 is cellto greater than cellfrom?
1115.         SL_error "SL_CHANGE_ANIMATION_CELLS", 19, "" '                                                  no, report error to programmer
1116.     END IF
1117.  
1118.     IF SL_sprite(handle).rotation.angle AND (NOT SL_sprite(handle).rotation.auto) THEN '                is this animation currently rotated but not automatic?
1119.         SL_ROTATE_SPRITE handle, SL_sprite(handle).rotation.angle '                                     yes, this new cell will need manually rotated as well
1120.     ELSE '                                                                                              no rotation, but still needs image updated
1121.         _FREEIMAGE SL_sprite(handle).gfx.software '                                                     remove current software image from memory
1122.         SL_sprite(handle).gfx.software = _COPYIMAGE(SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).software, 32) ' get new software image
1123.         IF SL_sprite(handle).gfx.mask THEN '                                                            is there a mask with this image?
1124.             _FREEIMAGE SL_sprite(handle).gfx.mask '                                                     yes, remove the software mask image from memory
1125.             SL_sprite(handle).gfx.mask = _COPYIMAGE(SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).mask, 32) ' get new software mask image
1126.         END IF
1127.     END IF
1128.  
1129. END SUB
1130.  
1131. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1132. SUB SL_CHANGE_ANIMATION_FRAMERATE (handle AS INTEGER, framerate AS INTEGER) '                                                                                             SL_CHANGE_ANIMATION_FRAMERATE
1133.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1134.     ' declare global variables
1135.  
1136.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1137.     SHARED SL_global AS SL_GLOBAL '     common globals array
1138.  
1139.     ' perform error checks
1140.  
1141.     IF framerate < 1 OR framerate > SL_global.framerate THEN '                                          valid frame rate supplied?
1142.         SL_error "SL_CHANGE_ANIMATION_FRAMERATE", 11, "" '                                              no, report error to programmer
1143.     END IF
1144.  
1145.     SL_sprite(handle).animation.framerate = framerate '                                                 save sprite frame rate
1146.     IF SL_global.framerate = framerate THEN '                                                           animation and global frame rates the same?
1147.         SL_sprite(handle).animation.skip = 0 '                                                          yes, nothing needs to be done with frames
1148.     ELSEIF framerate >= SL_global.framerate \ 2 THEN '                                                  no, sprite frame rate 1/2 or less of master frame rate?
1149.         SL_sprite(handle).animation.skip = SL_global.framerate \ (SL_global.framerate - framerate) '    yes, calculate every frame to skip
1150.     ELSE '                                                                                              no, sprite frame rate is greater than 1/2 of master frame rate
1151.         SL_sprite(handle).animation.skip = SL_global.framerate \ framerate '                            calculate every frame to draw
1152.     END IF
1153.  
1154. END SUB
1155.  
1156. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1157. SUB SL_CHANGE_AUTOANIMATION (handle AS INTEGER, auto AS INTEGER) '                                                                                                              SL_CHANGE_AUTOANIMATION
1158.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1159.  
1160.     ' declare global variables
1161.  
1162.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1163.  
1164.     ' perform error checks
1165.  
1166.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1167.         SL_error "SL_CHANGE_AUTOANIMATION", 1, "" '                                                     no, report error to programmer
1168.     END IF
1169.     IF auto < -1 OR auto > 0 THEN '                                                                     valid auto animation value?
1170.         SL_error "SL_CHANGE_ANIMATION", 14, "" '                                                        no, report error to programmer
1171.     END IF
1172.  
1173.     SL_sprite(handle).animation.auto = auto '                                     (SL_START & SL_STOP)  set auto-animation
1174.  
1175. END SUB
1176.  
1177. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1178. SUB SL_SET_ANIMATION (handle AS INTEGER, cellfrom AS INTEGER, cellto AS INTEGER, mode AS INTEGER, framerate AS INTEGER, auto AS INTEGER) '                                             SL_SET_ANIMATION
1179.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1180.  
1181.     ' declare global variables
1182.  
1183.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1184.     SHARED SL_global AS SL_GLOBAL '     common globals array
1185.  
1186.     ' perform error checks
1187.  
1188.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1189.         SL_error "SL_SET_ANIMATION", 1, "" '                                                            no, report error to programmer
1190.     END IF
1191.     IF framerate < 1 OR framerate > SL_global.framerate THEN '                                          valid frame rate supplied?
1192.         SL_error "SL_SET_ANIMATION", 11, "" '                                                           no, report error to programmer
1193.     END IF
1194.     IF mode < 0 OR mode > 2 THEN '                                                                      valid animation mode supplied?
1195.         SL_error "SL_SET_ANIMATION", 12, "" '                                                           no, report error to programmer
1196.     END IF
1197.     IF cellfrom <> -1 THEN '                                                          (SL_CURRENTCELL)  is the current cell being requested for cellfrom?
1198.         IF cellfrom < 1 OR (NOT SL_VALID_CELL(SL_sprite(handle).sheet, cellfrom)) THEN '                no, is this a valid cell request? <----------------------------- line need modified?   LOOK
1199.             SL_error "SL_SET_ANIMATION", 13, "" '                                                       no, report error to rpogrammer
1200.         END IF
1201.     END IF
1202.     IF cellto < 1 OR (NOT SL_VALID_CELL(SL_sprite(handle).sheet, cellto)) THEN '                        is this valid cell request?
1203.         SL_error "SL_SET_ANIMATION", 13, "" '                                                           no, report error to programmer
1204.     END IF
1205.     IF auto < -1 OR auto > 0 THEN '                                                                     valid auto animation value?
1206.         SL_error "SL_SET_ANIMATION", 14, "" '                                                           no, report error to programmer
1207.     END IF
1208.  
1209.     IF cellfrom = -1 THEN '                                                           (SL_CURRENTCELL)  use current cell as start cell?
1210.         SL_sprite(handle).animation.cellfrom = SL_sprite(handle).animation.cell '                       yes, set first cell as current cell
1211.     ELSE '                                                                                              no
1212.         SL_sprite(handle).animation.cell = cellfrom '                                                   set starting cell
1213.         SL_sprite(handle).animation.cellfrom = cellfrom '                                               set first cell in animation
1214.     END IF
1215.     SL_sprite(handle).animation.cellto = cellto '                                                       set last cell in animation
1216.  
1217.     IF cellto <= cellfrom THEN '                                                                        is cellto greater than cellfrom?
1218.         SL_error "SL_SET_ANIMATION", 19, "" '                                                           no, report error to programmer
1219.     END IF
1220.  
1221.     SL_sprite(handle).animation.framerate = framerate '                                                 save sprite frame rate
1222.     IF SL_global.framerate = framerate THEN '                                                           animation and global frame rates the same?
1223.         SL_sprite(handle).animation.skip = 0 '                                                          yes, nothing needs to be done with frames
1224.     ELSEIF framerate >= SL_global.framerate \ 2 THEN '                                                  no, sprite frame rate 1/2 or less of master frame rate?
1225.         SL_sprite(handle).animation.skip = SL_global.framerate \ (SL_global.framerate - framerate) '    yes, calculate every frame to skip
1226.     ELSE '                                                                                              no, sprite frame rate is greater than 1/2 of master frame rate
1227.         SL_sprite(handle).animation.skip = SL_global.framerate \ framerate '                            calculate every frame to draw
1228.     END IF
1229.     SL_sprite(handle).animation.frame = 0 '                                                             reset skip frame counter
1230.     SL_sprite(handle).animation.mode = mode '                (SL_FORWARD & SL_BACKWARD & SL_BACKFORTH)  set animation mode
1231.     IF mode = 0 OR mode = 2 THEN '                                        (SL_FORWARD or SL_BACKFORTH)  forward or back and forth?
1232.         SL_sprite(handle).animation.dir = 1 '                                                           yes, set animation direction forward
1233.     ELSE '                                                                               (SL_BACKWARD)  no, backward
1234.         SL_sprite(handle).animation.dir = -1 '                                                          set animation direction backward
1235.     END IF
1236.     SL_sprite(handle).animation.auto = auto '                                     (SL_START & SL_STOP)  set auto-animation
1237.  
1238. END SUB
1239.  
1240. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1241. FUNCTION SL_GET_CELL (handle AS INTEGER) '                                                                                                                                                  SL_GET_CELL
1242.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1243.  
1244.     ' declare global variables
1245.  
1246.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1247.  
1248.     ' perform error checks
1249.  
1250.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1251.         SL_error "SL_GET_CELL", 1, "" '                                                                 no, report error to programmer
1252.     END IF
1253.  
1254.     SL_GET_CELL = SL_sprite(handle).animation.cell '                                                    return animation cell of this sprite < --------------------- animation or sprite cell?   LOOK
1255.  
1256. END FUNCTION
1257.  
1258. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1259. FUNCTION SL_VALID_CELL (sheet AS INTEGER, cell AS INTEGER) '                                                                                                                              SL_VALID_CELL
1260.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1261.  
1262.     ' declare global variables
1263.  
1264.     SHARED SL_sheet() AS SL_SHEET '    master sprite sheet array
1265.  
1266.     IF NOT SL_VALID_SHEET(sheet) THEN '                                                                 is this a valid sheet?
1267.         SL_error "SL_VALID_CELL", 5, "" '                                                               no, report error to programmer
1268.     END IF
1269.  
1270.     IF (cell < 1) OR (cell > UBOUND(SL_sheet, 2)) THEN '                                                is cell withing range of cells on sheet?
1271.         SL_VALID_CELL = 0 '                                                                    (FALSE)  no, return false for invalid cell
1272.     ELSE '                                                                                              yes, within total cells
1273.         SL_VALID_CELL = -1 '                                                                    (TRUE)  return true for valid cell
1274.     END IF
1275.  
1276. END FUNCTION
1277.  
1278. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1279. '                                                                       ----------==========                 ==========----------
1280. '                                                                       ----------========== MOTION ROUTINES ==========----------
1281. '                                                                       ----------==========                 ==========----------
1282. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1283.  
1284. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1285. SUB SL_REVERSE_MOTIONX (handle AS INTEGER) '                                                                                                                                         SL_REVERSE_MOTIONX
1286.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1287.  
1288.     ' declare global variables
1289.  
1290.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1291.  
1292.     ' perform error checks
1293.  
1294.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1295.         SL_error "SL_REVERSE_MOTIONX", 1, "" '                                                          no, report error to programmer
1296.     END IF
1297.  
1298.     SL_sprite(handle).x.dir = -SL_sprite(handle).x.dir '                                                reverse x motion direction
1299.  
1300. END SUB
1301.  
1302. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1303. SUB SL_REVERSE_MOTIONY (handle AS INTEGER) '                                                                                                                                         SL_REVERSE_MOTIONY
1304.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1305.  
1306.     ' declare global variables
1307.  
1308.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1309.  
1310.     ' perform error checks
1311.  
1312.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1313.         SL_error "SL_REVERSE_MOTIONY", 1, "" '                                                          no, report error to programmer
1314.     END IF
1315.  
1316.     SL_sprite(handle).y.dir = -SL_sprite(handle).y.dir '                                                reverse y motion direction
1317.  
1318. END SUB
1319.  
1320. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1321. FUNCTION SL_GET_MOTIONX (handle AS INTEGER) '                                                                                                                                            SL_GET_MOTIONX
1322.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1323.  
1324.     ' declare global variables
1325.  
1326.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1327.  
1328.     ' perform error checks
1329.  
1330.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1331.         SL_error "SL_GET_MOTIONX", 1, "" '                                                              no, report error to programmer
1332.     END IF
1333.  
1334.     SL_GET_MOTIONX = SL_sprite(handle).x.dir '                                                          return x motion direction
1335.  
1336. END FUNCTION
1337.  
1338. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1339. FUNCTION SL_GET_MOTIONY (handle AS INTEGER) '                                                                                                                                            SL_GET_MOTIONY
1340.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1341.  
1342.     ' declare global variables
1343.  
1344.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1345.  
1346.     ' perform error checks
1347.  
1348.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1349.         SL_error "SL_GET_MOTIONY", 1, "" '                                                              no, report error to programmer
1350.     END IF
1351.  
1352.     SL_GET_MOTIONY = SL_sprite(handle).y.dir '                                                          return y motion direction
1353.  
1354. END FUNCTION
1355.  
1356. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1357. SUB SL_SET_MOTIONX (handle AS INTEGER, xdir AS SINGLE) '                                                                                                                                 SL_SET_MOTIONX
1358.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1359.     ' declare global variables
1360.  
1361.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1362.  
1363.     ' perform error checks
1364.  
1365.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1366.         SL_error "SL_SET_MOTIONX", 1, "" '                                                              no, report error to programmer
1367.     END IF
1368.  
1369.     SL_sprite(handle).x.dir = xdir '                                                                    set x motion direction
1370.  
1371. END SUB
1372.  
1373. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1374. SUB SL_SET_MOTIONY (handle AS INTEGER, ydir AS SINGLE) '                                                                                                                                 SL_SET_MOTIONY
1375.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1376.  
1377.     ' declare global variables
1378.  
1379.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1380.  
1381.     ' perform error checks
1382.  
1383.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1384.         SL_error "SL_SET_MOTIONY", 1, "" '                                                              no, report error to programmer
1385.     END IF
1386.  
1387.     SL_sprite(handle).y.dir = ydir '                                                                    set y motion direction
1388.  
1389. END SUB
1390.  
1391. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1392. SUB SL_UPDATE_MOTION (handle AS INTEGER) '                                                                                                                                             SL_UPDATE_MOTION
1393.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1394.  
1395.     ' declare global variables
1396.  
1397.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1398.  
1399.     ' perform error checks
1400.  
1401.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1402.         SL_error "SL_UPDATE_MOTION", 1, "" '                                                            no, report error to programmer
1403.     END IF
1404.     IF SL_sprite(handle).motion.auto THEN '                                                             attempt to move sprite under automatic control?
1405.         SL_error "SL_UPDATE_MOTION", 16, "" '                                                           yes, report error to programmer
1406.     END IF
1407.  
1408.     SL_sprite(handle).x.real = SL_sprite(handle).x.real + SL_sprite(handle).x.dir '                     update x location
1409.     SL_sprite(handle).y.real = SL_sprite(handle).y.real + SL_sprite(handle).y.dir '                     update y location
1410.     SL_PUT_SPRITE SL_sprite(handle).x.real, SL_sprite(handle).y.real, handle '                          update sprite location
1411.  
1412. END SUB
1413.  
1414. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1415. SUB SL_SET_MOTION (handle AS INTEGER, degrees AS INTEGER, speed AS SINGLE, auto AS INTEGER) '                                                                                            SL_SET_MOTION
1416.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1417.  
1418.     ' declare global variables
1419.  
1420.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1421.  
1422.     ' perform error checks
1423.  
1424.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1425.         SL_error "SL_SET_MOTION", 1, "" '                                                               no, report error to programmer
1426.     END IF
1427.     IF auto < -1 OR auto > 0 THEN '                                               (SL_START & SL_STOP)  valid on/off switch supplied?
1428.         SL_error "SL_SET_MOTION", 7, "" '                                                               no, report error to programmer
1429.     END IF
1430.  
1431.     SL_sprite(handle).motion.speed = speed '                                                            set motion speed of sprite
1432.     SL_CHANGE_MOTION_DIRECTION handle, SL_FIX_DEGREES(degrees) '                                        set motion angle of sprite
1433.     SL_sprite(handle).motion.auto = auto '                                        (SL_START & SL_STOP)  set auto-motion of sprite
1434.  
1435. END SUB
1436.  
1437. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1438. SUB SL_CHANGE_MOTION_DIRECTION (handle AS INTEGER, degrees AS INTEGER) '                                                                                                     SL_CHANGE_MOTION_DIRECTION
1439.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1440.  
1441.     ' declare global variables
1442.  
1443.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1444.  
1445.     ' delcare local variables
1446.  
1447.     DIM degree AS INTEGER '             degree angle passed in
1448.  
1449.     ' perform error checks
1450.  
1451.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1452.         SL_error "SL_CHANGE_MOTION_DIRECTION", 1, "" '                                                  no, report error to programmer
1453.     END IF
1454.  
1455.     degree = SL_FIX_DEGREES(degrees) '                                                                  get degree angle passed in
1456.     SL_sprite(handle).motion.angle = degree '                                                           set motion degree angle
1457.     SL_sprite(handle).x.dir = SIN(degree * .017453292) * SL_sprite(handle).motion.speed '               calculate x vector
1458.     SL_sprite(handle).y.dir = -COS(degree * .017453292) * SL_sprite(handle).motion.speed '              calculate y vector
1459.  
1460. END SUB
1461.  
1462. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1463. FUNCTION SL_GET_MOTION_DIRECTION (handle AS INTEGER) '                                                                                                                          SL_GET_MOTION_DIRECTION
1464.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1465.  
1466.     ' declare global variables
1467.  
1468.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1469.  
1470.     ' perform error checks
1471.  
1472.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1473.         SL_error "SL_GET_MOTION_DIRECTION", 1, "" '                                                     no, report error to programmer
1474.     END IF
1475.  
1476.     SL_GET_MOTION_DIRECTION = SL_sprite(handle).motion.angle '                                          return direction sprite currently set to
1477.  
1478. END FUNCTION
1479.  
1480. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1481. SUB SL_CHANGE_MOTION_SPEED (handle AS INTEGER, speed AS SINGLE) '                                                                                                                SL_CHANGE_MOTION_SPEED
1482.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1483.  
1484.     ' declare global variables
1485.  
1486.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1487.  
1488.     ' perform error checks
1489.  
1490.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1491.         SL_error "SL_CHANGE_MOTION_SPEED", 1, "" '                                                      no, report error to programmer
1492.     END IF
1493.  
1494.     SL_sprite(handle).motion.speed = speed '                                                            set sprite motion speed
1495.     SL_sprite(handle).x.dir = SIN(SL_sprite(handle).motion.angle * .017453292) * speed '                calculate x vector
1496.     SL_sprite(handle).y.dir = -COS(SL_sprite(handle).motion.angle * .017453292) * speed '               calculate y vector
1497.  
1498. END SUB
1499.  
1500. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1501. FUNCTION SL_GET_MOTION_SPEED (handle AS INTEGER) '                                                                                                                                  SL_GET_MOTION_SPEED
1502.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1503.  
1504.     ' declare global variables
1505.  
1506.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1507.  
1508.     ' perform error checks
1509.  
1510.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1511.         SL_error "SL_GET_MOTION_SPEED", 1, "" '                                                         no, report error to programmer
1512.     END IF
1513.  
1514.     SL_GET_MOTION_SPEED = SL_sprite(handle).motion.speed '                                              return current sprite motion speed
1515.  
1516. END FUNCTION
1517.  
1518. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1519. SUB SL_CHANGE_AUTOMOTION (handle AS INTEGER, auto AS INTEGER) '                                                                                                                    SL_CHANGE_AUTOMOTION
1520.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1521.  
1522.     ' declare global variables
1523.  
1524.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1525.  
1526.     ' perform error checks
1527.  
1528.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1529.         SL_error "SL_CHANGE_AUTOMOTION", 1, "" '                                                        no, report error to programmer
1530.     END IF
1531.     IF auto = -32767 THEN '                                                                 (SL_RESET)  reset auto motion?
1532.         SL_sprite(handle).motion.auto = 0 '                                                  (SL_STOP)  yes, turn auto motion off
1533.     ELSEIF auto < -1 OR auto > 0 THEN '                                           (SL_START & SL_STOP)  valid on/off switch supplied?
1534.         SL_error "SL_CHANGE_AUTOMOTION", 7, "" '                                                        no, report error to programmer
1535.     ELSE '                                                                                              yes
1536.         SL_sprite(handle).motion.auto = auto '                                          (TRUE & FALSE)  set auto motion status
1537.     END IF
1538.  
1539. END SUB
1540.  
1541. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1542. FUNCTION SL_GET_AUTOMOTION (handle AS INTEGER) '                                                                                                                                      SL_GET_AUTOMOTION
1543.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1544.  
1545.     ' declare global variables
1546.  
1547.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1548.  
1549.     ' perform error checks
1550.  
1551.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1552.         SL_error "SL_GET_AUTOMOTION", 1, "" '                                                           no, report error to programmer
1553.     END IF
1554.  
1555.     SL_GET_AUTOMOTION = SL_sprite(handle).motion.auto '                                 (TRUE & FALSE)  return auto motion status
1556.  
1557. END FUNCTION
1558.  
1559. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1560. '                                                                      ----------==========                   ==========----------
1561. '                                                                      ----------========== ROTATION ROUTINES ==========----------
1562. '                                                                      ----------==========                   ==========----------
1563. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1564.  
1565. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1566. SUB SL_UPDATE_ROTATION (handle AS INTEGER) '                                                                                                                                         SL_UPDATE_ROTATION
1567.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1568.  
1569.     ' declare global variables
1570.  
1571.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1572.  
1573.     ' perform error checks
1574.  
1575.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1576.         SL_error "SL_UPDATE_ROTATION", 1, "" '                                                          no, report error to programmer
1577.     END IF
1578.     IF SL_sprite(handle).rotation.auto THEN '                                                           attempt to rotate sprite under automatic control?
1579.         SL_error "SL_UPDATE_ROTATION", 17, "" '                                                         yes, report error to programmer
1580.     END IF
1581.  
1582.     SL_ROTATE_SPRITE handle, SL_sprite(handle).rotation.angle + SL_sprite(handle).rotation.speed '      rotate sprite to next degree angle
1583.     SL_PUT_SPRITE SL_sprite(handle).x.real, SL_sprite(handle).y.real, handle '                          update sprite rotation
1584.  
1585. END SUB
1586.  
1587.  
1588. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1589. SUB SL_SET_ROTATION (handle AS INTEGER, degrees AS INTEGER, speed AS INTEGER, auto AS INTEGER) '                                                                                        SL_SET_ROTATION
1590.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1591.  
1592.     ' declare global variables
1593.  
1594.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1595.  
1596.     ' perform error checks
1597.  
1598.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1599.         SL_error "SL_SET_ROTATION", 1, "" '                                                             no, report error to programmer
1600.     END IF
1601.     IF auto < -1 OR auto > 0 THEN '                                               (SL_START & SL_STOP)  valid on/off switch supplied?
1602.         SL_error "SL_SET_ROTATION", 8, "" '                                                             no, report error to programmer
1603.     END IF
1604.     IF ABS(degrees) > 359 THEN '                                                                        degree requested between -359 and 359?
1605.         SL_error "SL_SET_ROTATION", 9, "" '                                                             no, report error to programmer
1606.     END IF
1607.  
1608.     SL_sprite(handle).rotation.speed = speed '                                                          set rotation speed
1609.     SL_ROTATE_SPRITE handle, degrees '                                                                  set start angle
1610.     SL_sprite(handle).rotation.auto = auto '                                                            set auto-rotation
1611.  
1612. END SUB
1613.  
1614. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1615. SUB SL_CHANGE_AUTOROTATION (handle AS INTEGER, auto AS INTEGER) '                                                                                                                SL_CHANGE_AUTOROTATION
1616.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1617.  
1618.     ' declare global variables
1619.  
1620.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1621.  
1622.     ' perform error checks
1623.  
1624.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1625.         SL_error "SL_CHANGE_AUTOROTATION", 1, "" '                                                      no, report error to programmer
1626.     END IF
1627.     IF auto = -32767 THEN '                                                                 (SL_RESET)  reset auto rotate?
1628.         SL_sprite(handle).rotation.auto = 0 '                                                  (FALSE)  yes, turn auto rotation off
1629.     ELSEIF auto < -1 OR auto > 0 THEN '                                           (SL_START & SL_STOP)  valid on/off switch supplied?
1630.         SL_error "SL_CHANGE_AUTOROTATION", 8, "" '                                                      no, report error to programmer
1631.     ELSE '                                                                                              yes
1632.         SL_sprite(handle).rotation.auto = auto '                                        (TRUE & FALSE)  set auto rotation status
1633.     END IF
1634.  
1635. END SUB
1636.  
1637. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1638. FUNCTION SL_GET_AUTOROTATION (handle AS INTEGER) '                                                                                                                                  SL_GET_AUTOROTATION
1639.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1640.  
1641.     ' declare global variables
1642.  
1643.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1644.  
1645.     ' perform error checks
1646.  
1647.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1648.         SL_error "SL_GET_AUTOROTATION", 1, "" '                                                         no, report error to programmer
1649.     END IF
1650.  
1651.     SL_GET_AUTOROTATION = SL_sprite(handle).rotation.auto '                             (TRUE & FALSE)  return auto rotation status
1652.  
1653. END FUNCTION
1654.  
1655. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1656. SUB SL_CHANGE_ROTATION_SPEED (handle AS INTEGER, degrees AS INTEGER) '                                                                                                         SL_CHANGE_ROTATION_SPEED
1657.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1658.  
1659.     ' declare global variables
1660.  
1661.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1662.  
1663.     ' perform error checks
1664.  
1665.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1666.         SL_error "SL_CHANGE_ROTATION_SPEED", 1, "" '                                                    no, report error to programmer
1667.     END IF
1668.     IF degrees = -32767 THEN '                                                              (SL_RESET)  reset requested?
1669.         SL_sprite(handle).rotation.speed = 0 '                                               (SL_STOP)  turn auto spin off
1670.     ELSEIF ABS(degrees) > 359 THEN '                                                                    degree requested between -359 and 359?
1671.         SL_error "SL_CHANGE_ROTATION_SPEED", 9, "" '                                                    no, report error to programmer
1672.     ELSE '                                                                                              yes
1673.         SL_sprite(handle).rotation.speed = degrees '                                                    set sprite spin rate
1674.     END IF
1675.  
1676. END SUB
1677.  
1678. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1679. FUNCTION SL_GET_ROTATION_SPEED (handle AS INTEGER) '                                                                                                                              SL_GET_ROTATION_SPEED
1680.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1681.  
1682.     ' declare global variables
1683.  
1684.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1685.  
1686.     ' perform error checks
1687.  
1688.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1689.         SL_error "SL_GET_ROTATION_SPEED", 1, "" '                                                       no, report error to programmer
1690.     END IF
1691.  
1692.     SL_GET_ROTATION_SPEED = SL_sprite(handle).rotation.speed '                                          return current sprite spin rate
1693.  
1694. END FUNCTION
1695.  
1696. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1697. SUB SL_ROTATE_SPRITE (handle AS INTEGER, degrees AS INTEGER) '                                                                                                                         SL_ROTATE_SPRITE
1698.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1699.  
1700.     ' declare global variables
1701.  
1702.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
1703.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1704.     SHARED SL_angle() AS SL_ANGLE '     master rotation array
1705.  
1706.     ' declare local variables
1707.  
1708.     DIM sw AS INTEGER '                 width of sprite to be drawn
1709.     DIM sh AS INTEGER '                 height of sprite to be drawn
1710.     DIM rw AS INTEGER '                 precalculated rotated sprite width
1711.     DIM rh AS INTEGER '                 precalculated rotated sprite height
1712.     DIM px0 AS INTEGER '                precalculated triangular coordinates
1713.     DIM px1 AS INTEGER
1714.     DIM px2 AS INTEGER
1715.     DIM px3 AS INTEGER
1716.     DIM py0 AS INTEGER
1717.     DIM py1 AS INTEGER
1718.     DIM py2 AS INTEGER
1719.     DIM py3 AS INTEGER
1720.     DIM image AS LONG '                 software sprite image
1721.     DIM mask AS LONG '                  software sprite image mask
1722.     DIM degree AS INTEGER '             angle of rotation
1723.  
1724.     ' perform error checks
1725.  
1726.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1727.         SL_error "SL_ROTATE_SPRITE", 1, "" '                                                            no, report error to programmer
1728.     END IF
1729.  
1730.     ' check if rotation necessary
1731.  
1732.     degree = SL_FIX_DEGREES(degrees) '                                                                  correct degree angle if needed
1733.  
1734.     ' get default images and dimensions from sprite sheet
1735.  
1736.     image = SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).software '                        get image from sprite sheet
1737.     mask = SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).mask '                             get mask from sprite sheet
1738.     sw = SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).swidth '                             get default sprite width from sprite sheet
1739.     sh = SL_sheet(SL_sprite(handle).sheet, SL_sprite(handle).cell).sheight '                            get default sprite height from sprite sheet
1740.  
1741.     ' free existing images from memory
1742.  
1743.     _FREEIMAGE SL_sprite(handle).gfx.software '                                                         free software sprite image
1744.     IF SL_sprite(handle).gfx.mask THEN _FREEIMAGE SL_sprite(handle).gfx.mask '                          free software mask image
1745.  
1746.     ' remove rotation (reset) if requested
1747.  
1748.     IF degrees = -32767 OR degree = 0 THEN '                                                (SL_RESET)  reset sprite rotation?
1749.         SL_sprite(handle).rotation.angle = 0 '                                                          yes, reset rotation angle
1750.         SL_sprite(handle).swidth = sw '                                                                 save sprite's width
1751.         SL_sprite(handle).sheight = sh '                                                                save prite's height
1752.         SL_sprite(handle).gfx.software = _COPYIMAGE(image, 32) '                                        copy software image from sprite sheet
1753.         IF SL_sprite(handle).transparency THEN '                                                        does this sprite have a mask?
1754.             SL_sprite(handle).gfx.mask = _COPYIMAGE(mask, 32) '                                         yes, copy software mask from sprite sheet
1755.         END IF
1756.         EXIT SUB '                                                                                      no rotation needed, leave subroutine
1757.     END IF
1758.  
1759.     ' rotate sprite
1760.  
1761.     rw = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).rwidth '                     get precalculated rotated sprite width
1762.     rh = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).rheight '                    get precalculated rotated sprite height
1763.     px0 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).px0 '                       get precalculated triangular coordinates
1764.     px1 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).px1
1765.     px2 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).px2
1766.     px3 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).px3
1767.     py0 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).py0
1768.     py1 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).py1
1769.     py2 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).py2
1770.     py3 = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, degree).py3
1771.  
1772.     SL_sprite(handle).gfx.software = _NEWIMAGE(rw, rh, 32) '                                            create new software sprite image
1773.     _MAPTRIANGLE (0, 0)-(0, sh - 1)-(sw - 1, sh - 1), image TO(px0, py0)-(px1, py1)-(px2, py2), SL_sprite(handle).gfx.software ' map rotated sprite onto image
1774.     _MAPTRIANGLE (0, 0)-(sw - 1, 0)-(sw - 1, sh - 1), image TO(px0, py0)-(px3, py3)-(px2, py2), SL_sprite(handle).gfx.software
1775.     IF SL_sprite(handle).transparency THEN '                                                            does this sprite have a mask?
1776.         SL_sprite(handle).gfx.mask = _NEWIMAGE(rw, rh, 32) '                                            yes, create new software mask image
1777.         _MAPTRIANGLE (0, 0)-(0, sh - 1)-(sw - 1, sh - 1), mask TO(px0, py0)-(px1, py1)-(px2, py2), SL_sprite(handle).gfx.mask '  map rotated mask onto image
1778.         _MAPTRIANGLE (0, 0)-(sw - 1, 0)-(sw - 1, sh - 1), mask TO(px0, py0)-(px3, py3)-(px2, py2), SL_sprite(handle).gfx.mask
1779.     END IF
1780.     SL_sprite(handle).swidth = rw '                                                                     save sprite's rotated width
1781.     SL_sprite(handle).sheight = rh '                                                                    save sprite's rotated height
1782.     SL_sprite(handle).rotation.angle = degree '                                                         save sprite's degree of rotation
1783.  
1784.  
1785. END SUB
1786.  
1787. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1788. FUNCTION SL_GET_ROTATION_ANGLE (handle AS INTEGER) '                                                                                                                              SL_GET_ROTATION_ANGLE
1789.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1790.  
1791.     ' declare global variables
1792.  
1793.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1794.  
1795.     ' perform error checks
1796.  
1797.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1798.         SL_error "SL_GET_ROTATION_ANGLE", 1, "" '                                                       no, report error to programmer
1799.     END IF
1800.  
1801.     SL_GET_ROTATION_ANGLE = SL_sprite(handle).rotation.angle '                                          return current angle of rotation
1802.  
1803. END FUNCTION
1804.  
1805. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1806. FUNCTION SL_FIX_DEGREES (degrees AS INTEGER) '                                                                                                                                           SL_FIX_DEGREES
1807.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1808.  
1809.     ' Credits: this function uses code contriibuted by codeguy
1810.     '          https://www.qb64.org/forum/index.php?topic=537.15
1811.  
1812.     'declare local variables
1813.  
1814.     DIM degree AS INTEGER '             degree angle passed in
1815.  
1816.     ' set local variables
1817.  
1818.     degree = degrees MOD 360 '                                                                          get -359 to 359
1819.     IF degree < 0 THEN '                                                                                need to make positive?
1820.         SL_FIX_DEGREES = degree + 360 '                                                                 yes, correct value and return degree angle
1821.     ELSE
1822.         SL_FIX_DEGREES = degree '                                                                       no correction needed, return degree angle
1823.     END IF
1824.  
1825. END FUNCTION
1826.  
1827.  
1828. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1829. '                                                                      ----------==========                   ==========----------
1830. '                                                                      ----------========== LOCATION ROUTINES ==========----------
1831. '                                                                      ----------==========                   ==========----------
1832. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
1833.  
1834.  
1835. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1836. FUNCTION SL_GET_REALX (handle AS INTEGER) '                                                                                                                                                SL_GET_REALX
1837.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1838.  
1839.     ' declare global variables
1840.  
1841.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1842.  
1843.     ' perform error checks
1844.  
1845.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1846.         SL_error "SL_GET_REALX", 1, "" '                                                                no, report error to programmer
1847.     END IF
1848.  
1849.     SL_GET_REALX = SL_sprite(handle).x.real '                                                           return real number center point x
1850.  
1851. END FUNCTION
1852.  
1853. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1854. FUNCTION SL_GET_REALY (handle AS INTEGER) '                                                                                                                                                SL_GET_REALY
1855.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1856.  
1857.     ' declare global variables
1858.  
1859.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1860.  
1861.     ' perform error checks
1862.  
1863.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1864.         SL_error "SL_GET_REALY", 1, "" '                                                                no, report error to programmer
1865.     END IF
1866.  
1867.     SL_GET_REALY = SL_sprite(handle).y.real '                                                           return real number center point y
1868.  
1869. END FUNCTION
1870.  
1871. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1872. FUNCTION SL_GET_INTX (handle AS INTEGER) '                                                                                                                                                  SL_GET_INTX
1873.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1874.  
1875.     ' declare global variables
1876.  
1877.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1878.  
1879.     ' perform error checks
1880.  
1881.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1882.         SL_error "SL_GET_INTX", 1, "" '                                                                 no, report error to programmer
1883.     END IF
1884.  
1885.     SL_GET_INTX = SL_sprite(handle).x.int '                                                             return integer number center point x
1886.  
1887. END FUNCTION
1888.  
1889. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1890. FUNCTION SL_GET_INTY (handle AS INTEGER) '                                                                                                                                                  SL_GET_INTY
1891.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1892.  
1893.     ' declare global variables
1894.  
1895.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1896.  
1897.     ' perform error checks
1898.  
1899.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1900.         SL_error "SL_GET_INTY", 1, "" '                                                                 no, report error to programmer
1901.     END IF
1902.  
1903.     SL_GET_INTY = SL_sprite(handle).y.int '                                                             return integer number center point x
1904.  
1905. END FUNCTION
1906.  
1907. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1908. FUNCTION SL_GET_ACTUALX (handle AS INTEGER) '                                                                                                                                            SL_GET_ACTUALX
1909.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1910.  
1911.     ' declare global variables
1912.  
1913.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1914.  
1915.     ' perform error checks
1916.  
1917.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1918.         SL_error "SL_GET_ACTUALX", 1, "" '                                                              no, report error to programmer
1919.     END IF
1920.  
1921.     SL_GET_ACTUALX = SL_sprite(handle).x.actual '                                                       return integer number upper left point x
1922.  
1923. END FUNCTION
1924.  
1925. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1926. FUNCTION SL_GET_ACTUALY (handle AS INTEGER) '                                                                                                                                            SL_GET_ACTUALY
1927.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1928.  
1929.     ' declare global variables
1930.  
1931.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1932.  
1933.     ' perform error checks
1934.  
1935.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1936.         SL_error "SL_GET_ACTUALY", 1, "" '                                                              no, report error to programmer
1937.     END IF
1938.  
1939.     SL_GET_ACTUALY = SL_sprite(handle).y.actual '                                                       return integer number upper left point y
1940.  
1941. END FUNCTION
1942.  
1943. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1944. FUNCTION SL_GET_DISTANCE_POINT_TO_POINT (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER) '                                                                   SL_GET_DISTANCE_POINT_TO_POINT
1945.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1946.  
1947.     'declare local variables
1948.  
1949.     DIM a AS INTEGER '                  side a of triangle
1950.     DIM b AS INTEGER '                  side b of triangle
1951.  
1952.     'solve for c (hypotenuse)
1953.  
1954.     a = x1 - x2 '                                                                                       get length of side a
1955.     b = y1 = y2 '                                                                                       get length of side b
1956.  
1957.     SL_GET_DISTANCE_POINT_TO_POINT = INT(SQR(a * a + b * b)) '                                          return length of side c
1958.  
1959. END FUNCTION
1960.  
1961. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1962. FUNCTION SL_GET_DISTANCE_TO_SPRITE (handle1 AS INTEGER, handle2 AS INTEGER) '                                                                                                 SL_GET_DISTANCE_TO_SPRITE
1963.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1964.  
1965.     ' declare global variables
1966.  
1967.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1968.  
1969.     'perform error checks
1970.  
1971.     IF (NOT SL_VALID_SPRITE(handle1)) OR (NOT SL_VALID_SPRITE(handle2)) THEN '                          are these valid sprites?
1972.         SL_error "SL_GET_DISTANCE_TO_SPRITE", 1, "" '                                                   no, report error to programmer
1973.     END IF
1974.  
1975.     SL_GET_DISTANCE_TO_SPRITE = SL_GET_DISTANCE_POINT_TO_POINT(SL_sprite(handle1).x.int, SL_sprite(handle1).y.int, _
1976.                                                                SL_sprite(handle2).x.int, SL_sprite(handle2).y.int) '  return distance to sprite 2
1977.  
1978. END FUNCTION
1979.  
1980. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1981. FUNCTION SL_GET_DISTANCE_TO_POINT (handle AS INTEGER, x AS INTEGER, y AS INTEGER) '                                                                                            SL_GET_DISTANCE_TO_POINT
1982.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1983.  
1984.     ' declare global variables
1985.  
1986.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
1987.  
1988.     'perform error checks
1989.  
1990.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
1991.         SL_error "SL_GET_DISTANCE_TO_POINT", 1, "" '                                                    no, report error to programmer
1992.     END IF
1993.  
1994.     SL_GET_DISTANCE_TO_POINT = SL_GET_DISTANCE_POINT_TO_POINT(SL_sprite(handle).x.int, SL_sprite(handle).y.int, x, y) ' return distance to point
1995.  
1996. END FUNCTION
1997.  
1998. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
1999. FUNCTION SL_GET_ANGLE_POINT_TO_POINT (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER) '                                                                         SL_GET_ANGLE_POINT_TO_POINT
2000.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2001.  
2002.     'declare local variables
2003.  
2004.     DIM angle AS INTEGER '              angle from first x,y location to second x,y location
2005.  
2006.     IF y1 = y2 THEN '                                                                                   both y values same?
2007.         IF x1 = x2 THEN '                                                                               yes, both x values same?
2008.             EXIT FUNCTION '                                                                             yes, there is no angle (0), leave
2009.         END IF
2010.         IF x2 > x1 THEN '                                                                               is second x to the right of first x?
2011.             SL_GET_ANGLE_POINT_TO_POINT = 90 '                                                          yes, the angle must be 90 degrees
2012.         ELSE '                                                                                          no, second x is to the left of first x
2013.             SL_GET_ANGLE_POINT_TO_POINT = 270 '                                                         the angle must be 270 degrees
2014.         END IF
2015.         EXIT FUNCTION '                                                                                 leave function, angle computed
2016.     END IF
2017.     IF x1 = x2 THEN '                                                                                   both x values same?
2018.         IF y2 > y1 THEN '                                                                               yes, is second y lower than first y?
2019.             SL_GET_ANGLE_POINT_TO_POINT = 180 '                                                         yes, the angle must be 180
2020.         END IF
2021.         EXIT FUNCTION '                                                                                 leave function, angle computed (angle is 0 if no calculation done)
2022.     END IF
2023.     angle = ATN((x2 - x1) / (y2 - y1)) * -57.2957795131 '                                               calculate initial angle
2024.     IF y2 < y1 THEN '                                                                                   is second y higher than first y?
2025.         IF x2 > x1 THEN '                                                                               yes, is second x to right of first x?
2026.             SL_GET_ANGLE_POINT_TO_POINT = angle '                                                       yes, angle needs no adjustment
2027.         ELSE '                                                                                          no, second x is to left of first x
2028.             SL_GET_ANGLE_POINT_TO_POINT = angle + 360 '                                                 adjust angle accordingly
2029.         END IF
2030.     ELSE '                                                                                              no, second y is lower than first y
2031.         SL_GET_ANGLE_POINT_TO_POINT = angle + 180 '                                                     adjust angle accordingly
2032.     END IF
2033.  
2034. END FUNCTION
2035.  
2036. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2037. FUNCTION SL_GET_ANGLE_TO_SPRITE (handle1 AS INTEGER, handle2 AS INTEGER) '                                                                                                       SL_GET_ANGLE_TO_SPRITE
2038.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2039.  
2040.     ' declare global variables
2041.  
2042.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2043.  
2044.     'perform error checks
2045.  
2046.     IF (NOT SL_VALID_SPRITE(handle1)) OR (NOT SL_VALID_SPRITE(handle2)) THEN '                          are these valid sprites?
2047.         SL_error "SL_GET_ANGLE_TO_SPRITE", 1, "" '                                                      no, report error to programmer
2048.     END IF
2049.  
2050.     SL_GET_ANGLE_TO_SPRITE = SL_GET_ANGLE_POINT_TO_POINT(SL_sprite(handle1).x.int, SL_sprite(handle1).y.int, _
2051.                                                          SL_sprite(handle2).x.int, SL_sprite(handle2).y.int) ' return angle to sprite 2
2052.  
2053. END FUNCTION
2054.  
2055. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2056. FUNCTION SL_GET_ANGLE_FROM_SPRITE (handle1 AS INTEGER, handle2 AS INTEGER) '                                                                                                   SL_GET_ANGLE_FROM_SPRITE
2057.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2058.  
2059.     ' declare global variables
2060.  
2061.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2062.  
2063.     'perform error checks
2064.  
2065.     IF (NOT SL_VALID_SPRITE(handle1)) OR (NOT SL_VALID_SPRITE(handle2)) THEN '                          are these valid sprites?
2066.         SL_error "SL_GET_ANGLE_FROM_SPRITE", 1, "" '                                                    no, report error to programmer
2067.     END IF
2068.  
2069.     SL_GET_ANGLE_FROM_SPRITE = SL_GET_ANGLE_POINT_TO_POINT(SL_sprite(handle2).x.int, SL_sprite(handle2).y.int, _
2070.                                                            SL_sprite(handle1).x.int, SL_sprite(handle1).y.int) '  return angle from sprite 2
2071.  
2072. END FUNCTION
2073.  
2074. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2075. FUNCTION SL_GET_ANGLE_TO_POINT (handle AS INTEGER, x AS INTEGER, y AS INTEGER) '                                                                                                  SL_GET_ANGLE_TO_POINT
2076.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2077.  
2078.     ' declare global variables
2079.  
2080.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2081.  
2082.     'perform error checks
2083.  
2084.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2085.         SL_error "SL_GET_ANGLE_TO_POINT", 1, "" '                                                       no, report error to programmer
2086.     END IF
2087.  
2088.     SL_GET_ANGLE_TO_POINT = SL_GET_ANGLE_POINT_TO_POINT(SL_sprite(handle).x.int, SL_sprite(handle).y.int, x, y) ' return angle to point x,y
2089.  
2090. END FUNCTION
2091.  
2092. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2093. FUNCTION SL_GET_ANGLE_FROM_POINT (handle AS INTEGER, x AS INTEGER, y AS INTEGER) '                                                                                              SL_GET_ANGLE_FROM_POINT
2094.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2095.  
2096.     ' declare global variables
2097.  
2098.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2099.  
2100.     'perform error checks
2101.  
2102.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2103.         SL_error "SL_GET_ANGLE_FROM_POINT", 1, "" '                                                     no, report error to programmer
2104.     END IF
2105.  
2106.     SL_GET_ANGLE_FROM_POINT = SL_GET_ANGLE_POINT_TO_POINT(x, y, SL_sprite(handle).x.int, SL_sprite(handle).y.int) 'return angle from point x,y
2107.  
2108. END FUNCTION
2109.  
2110. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
2111. '                                                                       ----------==========                 ==========----------
2112. '                                                                       ----------========== SPRITE ROUTINES ==========----------
2113. '                                                                       ----------==========                 ==========----------
2114. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
2115.  
2116. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2117. SUB SL_SET_SPRITE_VISIBLE (handle AS INTEGER, visible AS INTEGER) '                                                                                                               SL_SET_SPRITE_VISIBLE
2118.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2119.  
2120.     ' declare global variables
2121.  
2122.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2123.  
2124.     ' perform error checks
2125.  
2126.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2127.         SL_error "SL_SET_SPRITE_VISIBLE", 1, "" '                                                       no, report error to programmer
2128.     END IF
2129.     IF (visible < -1) OR (visible > 0) THEN '                                      (SL_SHOW & SL_HIDE)  valid visible behavior requested?
2130.         SL_error "SL_SET_SPRITE_VISIBLE", 20, "" '                                                      no, report error to programmer
2131.     END IF
2132.  
2133.     SL_sprite(handle).visible = visible '                                          (SL_SHOW & SL_HIDE)  set visible mode
2134.  
2135. END SUB
2136.  
2137. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2138. FUNCTION SL_COPY_SPRITE (handle AS INTEGER) '                                                                                                                                            SL_COPY_SPRITE
2139.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2140.  
2141.     ' declare global variables
2142.  
2143.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2144.  
2145.     ' declare local variables
2146.  
2147.     DIM newhandle AS INTEGER '          handle of copied sprite
2148.  
2149.     ' perform error checks
2150.  
2151.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2152.         SL_error "SL_COPY_SPRITE", 1, "" '                                                              no, report error to programmer
2153.     END IF
2154.  
2155.     newhandle = 0 '                                                                                     initialize new handle counter
2156.  
2157.     ' increase sprite array's size if needed
2158.  
2159.     DO '                                                                                                look for next available handle
2160.         newhandle = newhandle + 1 '                                                                     increment to next handle value
2161.     LOOP UNTIL (NOT SL_sprite(newhandle).inuse) OR newhandle = UBOUND(SL_sprite) '                      stop looking when valid handle found
2162.     IF SL_sprite(newhandle).inuse THEN '                                                                is the last array element in use?
2163.         newhandle = newhandle + 1 '                                                                     yes, increment to next handle value
2164.         REDIM _PRESERVE SL_sprite(newhandle) AS SL_SPRITE '                                             increase the size of the sprite array
2165.     END IF
2166.  
2167.     ' copy new sprite
2168.  
2169.     SL_sprite(newhandle) = SL_sprite(handle) '                                                          copy entire sprite contents
2170.     SL_sprite(newhandle).gfx.hardware = _COPYIMAGE(SL_sprite(handle).gfx.hardware, 33) '                create an actual copy of the hardware sprite
2171.     SL_sprite(newhandle).gfx.software = _COPYIMAGE(SL_sprite(handle).gfx.software, 32) '                create an actual copy of the software image
2172.     IF SL_sprite(handle).gfx.mask THEN '                                                                does the original contain a mask image?
2173.         SL_sprite(newhandle).gfx.mask = _COPYIMAGE(SL_sprite(handle).gfx.mask, 32) '                    yes, create an actual copy of the software mask image
2174.     END IF
2175.  
2176.     SL_COPY_SPRITE = newhandle '                                                                        return new sprite's handle pointer
2177.  
2178. END FUNCTION
2179.  
2180. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2181. SUB SL_STAMP_SPRITE (layer AS INTEGER, x AS INTEGER, y AS INTEGER, sheet AS INTEGER, cell AS INTEGER, degrees AS INTEGER, flip AS INTEGER, zoom AS INTEGER) '                           SL_STAMP_SPRITE
2182.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2183.  
2184.     ' declare global variables
2185.  
2186.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
2187.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2188.  
2189.     ' declare local variables
2190.  
2191.     DIM tempsprite AS LONG '            temporary sprite to stamp
2192.  
2193.     ' perform error checks
2194.  
2195.     IF NOT SL_VALID_SHEET(sheet) THEN '                                                                 is this a valid sheet?
2196.         SL_error "SL_STAMP_SPRITE", 5, "" '                                                             no, report error to programmer
2197.     END IF
2198.     IF NOT SL_VALID_CELL(sheet, cell) THEN '                                                            valid cell?
2199.         SL_error "SL_STAMP_SPRITE", 13, "" '                                                            no, report error to programmer
2200.     END IF
2201.     IF flip < 0 OR flip > 3 THEN '                                                                      valid flip behavior requested?
2202.         SL_error "SL_STAMP_SPRITE", 3, "" '                                                             no, report error to programmer
2203.     END IF
2204.     IF zoom < 1 THEN '                                                                                  valid zoom level requested?
2205.         SL_error "SL_STAMP_SPRITE", 4, "" '                                                             no, report error to programmer
2206.     END IF
2207.     IF NOT SL_VALID_LAYER(layer) THEN '                                                                 valid layer?
2208.         SL_error "SL_STAMP_SPRITE", 25, "" '                                                            no, report error to programmer
2209.     END IF
2210.  
2211.     tempsprite = SL_NEW_SPRITE(layer, sheet, cell, 0, 0) '                                              create new temporary software sprite
2212.     SL_sprite(tempsprite).rotation.speed = SL_FIX_DEGREES(degrees) '                                    set speed of rotation
2213.     SL_sprite(tempsprite).flip = flip '                                                                 set flipping behavior
2214.     SL_sprite(tempsprite).zoom = zoom '                                                                 set zoom level
2215.     SL_PUT_SPRITE x, y, tempsprite '                                                                    place sprite on current destination
2216.     SL_FREE_SPRITE tempsprite '                                                                         temporary sprite no longer needed
2217.  
2218. END SUB
2219.  
2220.  
2221. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2222. SUB SL_SET_SOFTWARE (handle AS INTEGER, restores AS INTEGER) '                                                                                                                          SL_SET_SOFTWARE
2223.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2224.  
2225.     ' declare global variables
2226.  
2227.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2228.  
2229.     'perform error checks
2230.  
2231.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2232.         SL_error "SL_SET_SOFTWARE", 1, "" '                                                             no, report error to programmer
2233.     END IF
2234.     IF restores < -1 OR restores > 0 THEN '                                                             valid background restoration behavior requested?
2235.         SL_error "SL_SET_SOFTWARE", 2, "" '                                                             no, report error to programmer
2236.     END IF
2237.  
2238.     SL_sprite(handle).software = -1 '                                                    (SL_SOFTWARE)  set sprite to software mode
2239.     SL_sprite(handle).restore = restores '                                       (SL_SAVE & SL_NOSAVE)  set background saving behavior
2240.  
2241. END SUB
2242.  
2243. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2244. SUB SL_SET_HARDWARE (handle AS INTEGER) '                                                                                                                                               SL_SET_HARDWARE
2245.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2246.  
2247.     ' declare global variables
2248.  
2249.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2250.  
2251.     'perform error checks
2252.  
2253.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2254.         SL_error "SL_SET_HARDWARE", 1, "" '                                                             no, report error to programmer
2255.     END IF
2256.  
2257.     SL_sprite(handle).software = 0 '                                                     (SL_HARDWARE)  set sprite to hardware mode
2258.  
2259. END SUB
2260.  
2261. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2262. SUB SL_SET_ZOOM (handle AS INTEGER, zoom AS INTEGER) '                                                                                                                                      SL_SET_ZOOM
2263.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2264.  
2265.     ' declare global variables
2266.  
2267.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2268.  
2269.     ' perform error checks
2270.  
2271.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2272.         SL_error "SL_SET_ZOOM", 1, "" '                                                                 no, report error to programmer
2273.     END IF
2274.     IF zoom = -32767 THEN '                                                                 (SL_RESET)  reset zoom level?
2275.         SL_sprite(handle).zoom = 100 '                                                                  yes, reset level to normal
2276.     ELSEIF zoom < 1 THEN '                                                                              valid zoom level requested?
2277.         SL_error "SL_SET_ZOOM", 4, "" '                                                                 no, report error to programmer
2278.     ELSE '                                                                                              yes
2279.         SL_sprite(handle).zoom = zoom '                                                                 set zoom level
2280.     END IF
2281.  
2282. END SUB
2283.  
2284. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2285. SUB SL_FLIP_SPRITE (handle AS INTEGER, flip AS INTEGER) '                                                                                                                                SL_FLIP_SPRITE
2286.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2287.  
2288.     ' declare global variables
2289.  
2290.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2291.  
2292.     ' perform error checks
2293.  
2294.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2295.         SL_error "SL_FLIP_SPRITE", 1, "" '                                                              no, report error to programmer
2296.     END IF
2297.     IF flip = -32767 THEN '                                                                 (SL_RESET)  reset flipping behavior?
2298.         SL_sprite(handle).flip = 0 '                                                       (SL_NOFLIP)  yes, reset flip value
2299.     ELSEIF flip < 0 OR flip > 3 THEN '                                                                  valid flip behavior requested?
2300.         SL_error "SL_FLIP_SPRITE", 3, "" '                                                              no, report error to programmer
2301.     ELSE '                                                                                              yes
2302.         SL_sprite(handle).flip = flip '           (SL_NOFLIP, SL_HORIZONTAL, SL_VERTICAL, SL_FLIPBOTH)  set flipping behavior
2303.     END IF
2304.  
2305. END SUB
2306.  
2307. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2308. SUB SL_PUT_SPRITE (x AS SINGLE, y AS SINGLE, handle AS INTEGER) '                                                                                                                         SL_PUT_SPRITE
2309.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2310.  
2311.     ' declare global variables
2312.  
2313.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2314.     SHARED SL_angle() AS SL_ANGLE '     master rotation array
2315.  
2316.     ' declare local variables
2317.  
2318.     DIM xa AS INTEGER '                 actual x location of sprite on screen
2319.     DIM ya AS INTEGER '                 actual y location of sprite on screen
2320.     DIM sw AS INTEGER '                 width of sprite to be drawn
2321.     DIM sh AS INTEGER '                 height of sprite to be drawn
2322.     DIM rw AS INTEGER '                 precalculated rotated sprite width
2323.     DIM rh AS INTEGER '                 precalculated rotated sprite height
2324.     DIM px0 AS INTEGER '                precalculated triangular coordinates
2325.     DIM px1 AS INTEGER
2326.     DIM px2 AS INTEGER
2327.     DIM px3 AS INTEGER
2328.     DIM py0 AS INTEGER
2329.     DIM py1 AS INTEGER
2330.     DIM py2 AS INTEGER
2331.     DIM py3 AS INTEGER
2332.     DIM image AS LONG '                 software sprite image
2333.     DIM mask AS LONG '                  software sprite image mask
2334.     DIM sprite AS LONG '                hardware sprite image
2335.     DIM odest AS LONG '                 original destination layer
2336.     DIM osource AS LONG '               original source layer
2337.     DIM zoomfactor AS SINGLE '          zoom multiplication factor
2338.     ' perform error checks
2339.  
2340.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2341.         SL_error "SL_PUT_SPRITE", 1, "" '                                                               no, report error to programmer
2342.     END IF
2343.  
2344.     'local variable setup
2345.  
2346.     'odest = _DEST '                                                                                     save original destination
2347.     'osource = _SOURCE '                                                                                 save original source
2348.     odest = SL_GET_DESTINATION_LAYER
2349.     osource = SL_GET_SOURCE_LAYER
2350.  
2351.     SL_sprite(handle).x.real = x '                                                            (SINGLE)  save requested x center location
2352.     SL_sprite(handle).y.real = y '                                                            (SINGLE)  save requested y center location
2353.     SL_sprite(handle).x.int = INT(x) '                                                       (INTEGER)  save screen x center location
2354.     SL_sprite(handle).y.int = INT(y) '                                                       (INTEGER)  save screen y center location
2355.     sw = SL_sprite(handle).swidth '                                                                     get current sprite width
2356.     sh = SL_sprite(handle).sheight '                                                                    get current sprite height
2357.  
2358.     'update hardware image
2359.  
2360.     _FREEIMAGE SL_sprite(handle).gfx.hardware '                                                         free previous hardware sprite image
2361.     SL_sprite(handle).gfx.hardware = _COPYIMAGE(SL_sprite(handle).gfx.software, 33) '                   create new hardware sprite of image
2362.  
2363.     IF SL_sprite(handle).restore THEN '                                                                 is sprite holding a background image?
2364.         IF SL_sprite(handle).gfx.back THEN '                                                            yes, has a background image been saved yet?
2365.             SL_SET_DESTINATION_LAYER SL_sprite(handle).layer '                                          yes, set destination layer
2366.             _PUTIMAGE (SL_sprite(handle).x.back, SL_sprite(handle).y.back), SL_sprite(handle).gfx.back 'replace background with image
2367.             _FREEIMAGE SL_sprite(handle).gfx.back '                                                     free hardware background image
2368.         END IF
2369.         IF NOT SL_sprite(handle).software THEN '                                                        was the sprite type changed?
2370.             SL_sprite(handle).restore = 0 '                                                (SL_NOSAVE)  yes, stop saving background
2371.         END IF
2372.     END IF
2373.  
2374.     'adjust zoom level if needed
2375.  
2376.     IF SL_sprite(handle).zoom <> 100 THEN '                                                             zoom sprite in/out?
2377.         zoomfactor = SL_sprite(handle).zoom / 100
2378.         'sw = sw * SL_sprite(handle).zoom * .01 '\ 100 '                                                        yes, calculate new zoom width
2379.         'sh = sh * SL_sprite(handle).zoom * .01 '\ 100 '                                                        calculate new zoom height
2380.         sw = sw * zoomfactor '                                                                          yes, calculate new zoom width
2381.         sh = sh * zoomfactor '                                                                          calculate new zoom height
2382.     ELSE
2383.         zoomfactor = 1
2384.     END IF
2385.  
2386.     'calculate actual sprite screen coordinates
2387.  
2388.     xa = SL_sprite(handle).x.int - sw \ 2 '                                                             calculate actual screen x location from center
2389.     ya = SL_sprite(handle).y.int - sh \ 2 '                                                             calculate actual screen y location from center
2390.     SL_sprite(handle).x.actual = xa '                                                        (INTEGER)  save actual screen x location
2391.     SL_sprite(handle).y.actual = ya '                                                        (INTEGER)  save actual screen y location
2392.  
2393.     ' update collision box location based on actual x,y location, radius, and zoom factor
2394.  
2395.     SL_sprite(handle).collision.x1 = xa + SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, SL_sprite(handle).rotation.angle).x1 * zoomfactor
2396.     SL_sprite(handle).collision.x2 = xa + SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, SL_sprite(handle).rotation.angle).x2 * zoomfactor
2397.     SL_sprite(handle).collision.y1 = ya + SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, SL_sprite(handle).rotation.angle).y1 * zoomfactor
2398.     SL_sprite(handle).collision.y2 = ya + SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, SL_sprite(handle).rotation.angle).y2 * zoomfactor
2399.     SL_sprite(handle).collision.radius = SL_angle(SL_sprite(handle).sheet, SL_sprite(handle).cell, SL_sprite(handle).rotation.angle).radius * zoomfactor
2400.  
2401.     'get background image before placing sprite if necessary
2402.  
2403.     IF SL_sprite(handle).restore THEN '                                                                 is this sprite storing background images?
2404.         SL_sprite(handle).gfx.back = _NEWIMAGE(sw, sh, 32) '                                            yes, create background image
2405.         SL_SET_SOURCE_LAYER SL_sprite(handle).layer '                                                   set the source layer
2406.         _PUTIMAGE , _SOURCE, SL_sprite(handle).gfx.back, (xa, ya)-(xa + sw - 1, ya + sh - 1) '          get background area from current source layer
2407.         SL_sprite(handle).x.back = xa '                                                                 record background x location
2408.         SL_sprite(handle).y.back = ya '                                                                 record background y location
2409.     END IF
2410.  
2411.     'use hardware or software image
2412.  
2413.     IF SL_sprite(handle).software THEN '                                                                is this a software sprite?
2414.         sprite = SL_sprite(handle).gfx.software '                                                       yes, use the software image
2415.         SL_SET_DESTINATION_LAYER SL_sprite(handle).layer '                                              set the destination layer
2416.     ELSE '                                                                                              no
2417.         sprite = SL_sprite(handle).gfx.hardware '                                                       use the hardware image
2418.         SL_SET_DESTINATION_LAYER 1 '                                                                    set the destination layer to first as default
2419.     END IF
2420.  
2421.     ' place sprite on the current destination with desired flip method
2422.  
2423.     IF SL_sprite(handle).visible THEN '                                            (SL_SHOW & SL_HIDE)  show this sprite?
2424.         SELECT CASE SL_sprite(handle).flip '                                                            yes, which flipping style is selected?
2425.             CASE 0 '                                                                       (SL_NOFLIP)  normal, no flipping
2426.                 _PUTIMAGE (xa, ya)-(xa + sw - 1, ya + sh - 1), sprite '                                 draw normal sprite
2427.             CASE 1 '                                                                   (SL_HORIZONTAL)  flip horizontally
2428.                 _PUTIMAGE (xa + sw - 1, ya)-(xa, ya + sh - 1), sprite '                                 draw horizontally flipped sprite
2429.             CASE 2 '                                                                     (SL_VERTICAL)  flip vertically
2430.                 _PUTIMAGE (xa, ya + sh - 1)-(xa + sw - 1, ya), sprite '                                 draw vertically flipped sprite
2431.             CASE 3 '                                                                     (SL_FLIPBOTH)  flip vertically and horizontally
2432.                 _PUTIMAGE (xa + sw - 1, ya + sh - 1)-(xa, ya), sprite '                                 draw horizontally and vertically flipped sprite
2433.         END SELECT
2434.     END IF
2435.  
2436.     '_SOURCE osource '                                                                                   restore original source
2437.     '_DEST odest '                                                                                       restore original destination
2438.     SL_SET_SOURCE_LAYER osource
2439.     SL_SET_DESTINATION_LAYER odest
2440.  
2441. END SUB
2442.  
2443. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2444. FUNCTION SL_NEW_SPRITE (layer AS INTEGER, sheet AS INTEGER, cell AS INTEGER, software AS INTEGER, restores AS INTEGER) '                                                                  SL_NEW_SPRITE
2445.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2446.  
2447.     ' declare global variables
2448.  
2449.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
2450.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2451.  
2452.     ' declare local variables
2453.  
2454.     DIM handle AS INTEGER '             handle (pointer) number of new sprite
2455.  
2456.     ' perform error checks
2457.  
2458.     IF NOT SL_VALID_SHEET(sheet) THEN '                                                                 is this a valid sprite sheet?
2459.         SL_error "SL_NEW_SPRITE", 5, "" '                                                               no, report error to programmer
2460.     END IF
2461.     IF NOT SL_VALID_CELL(sheet, cell) THEN '                                                            valid cell?
2462.         SL_error "SL_NEW_SPRITE", 13, "" '                                                              no, report error to programmer
2463.     END IF
2464.     IF NOT SL_VALID_LAYER(layer) THEN '                                                                 valid layer?
2465.         SL_error "SL_NEW_SPRITE", 25, "" '                                                              no, report error to programmer
2466.     END IF
2467.     IF restores < -1 OR restores > 0 THEN '                                                             valid background restoration behavior requested?
2468.         SL_error "SL_NEW_SPRITE", 2, "" '                                                               no, report error to programmer
2469.     END IF
2470.     IF software < -1 OR software > 0 THEN '                                                             valid hardware / software setting requested?
2471.         SL_error "SL_NEW_SPRITE", 112, "" '                                                             no, report error to programmer
2472.     END IF
2473.     IF (NOT software) AND restores THEN '                                                               hardware image that restores background?
2474.         SL_error "SL_NEW_SPRITE", 113, "" '                                                             yes, report error to programmer
2475.     END IF
2476.  
2477.     ' local variable setup
2478.  
2479.     handle = 0 '                                                                                        initialize handle value
2480.  
2481.     ' increase sprite array's size if needed
2482.  
2483.     DO '                                                                                                look for next available handle
2484.         handle = handle + 1 '                                                                           increment to next handle value
2485.     LOOP UNTIL (NOT SL_sprite(handle).inuse) OR handle = UBOUND(SL_sprite) '                            stop looking when valid handle found
2486.     IF SL_sprite(handle).inuse THEN '                                                                   is the last array element in use?
2487.         handle = handle + 1 '                                                                           yes, increment to next handle value
2488.         REDIM _PRESERVE SL_sprite(handle) AS SL_SPRITE '                                                increase the size of the sprite array
2489.     END IF
2490.  
2491.     ' populate sprite array, general settings
2492.  
2493.     SL_sprite(handle).inuse = -1 '                                                              (TRUE)  mark array index as in use
2494.     SL_sprite(handle).sheet = sheet '                                                                   point to sheet where sprite resides
2495.     SL_sprite(handle).cell = cell '                                                                     cell sprite is located in on sheet
2496.     SL_sprite(handle).software = software '                                (SL_SOFTWARE & SL_HARDWARE)  sprite treated as software or hardware image
2497.     SL_sprite(handle).restore = restores '                                       (SL_SAVE & SL_NOSAVE)  background restore behavior of sprite
2498.     SL_sprite(handle).swidth = SL_sheet(sheet, cell).swidth '                                           get width of sprite
2499.     SL_sprite(handle).sheight = SL_sheet(sheet, cell).sheight '                                         get height of sprite
2500.     SL_sprite(handle).flip = 0 '                                                                        no sprite flipping
2501.     SL_sprite(handle).zoom = 100 '                                                                      zoom normal at 100%
2502.     SL_sprite(handle).score = 0 '                                                                       no point score
2503.     SL_sprite(handle).visible = -1 '                                                            (TRUE)  sprite visible on screen
2504.     SL_sprite(handle).layer = layer '                                                                   set sprite's layer
2505.  
2506.  
2507.     ' mouse settings
2508.  
2509.     SL_sprite(handle).mouse.event = 0 '(SL_NOMOUSE, SL_HOVER, SL_LEFTCLICK, SL_RIGHTCLICK, SL_CENTERCLICK) reset mouse interaction
2510.     SL_sprite(handle).mouse.x = 0 '                                                                     reset mouse pointer locations
2511.     SL_sprite(handle).mouse.y = 0
2512.     SL_sprite(handle).mouse.xa = 0
2513.     SL_sprite(handle).mouse.ya = 0
2514.  
2515.     ' collision settings
2516.  
2517.     SL_sprite(handle).collision.detect = 0 '                                                            reset collision detection method selected
2518.     SL_sprite(handle).collision.box = 0 '                                                      (FALSE)  reset box collision detected
2519.     SL_sprite(handle).collision.round = 0 '                                                    (FALSE)  reset round collision detected
2520.     SL_sprite(handle).collision.pixel = 0 '                                                    (FALSE)  reset pixel perfect collision detected
2521.     SL_sprite(handle).collision.with = 0 '                                                              reset collision detected
2522.     SL_sprite(handle).collision.xpoint = 0 '                                                            reset collision x point
2523.     SL_sprite(handle).collision.ypoint = 0 '                                                            reset collision y point
2524.     SL_sprite(handle).collision.radius = 0 '                                                            reset round collision radius
2525.     SL_sprite(handle).collision.x1 = 0 '                                                                reset sprite's collision box boundaries
2526.     SL_sprite(handle).collision.y1 = 0
2527.     SL_sprite(handle).collision.x2 = 0
2528.     SL_sprite(handle).collision.y2 = 0
2529.     SL_sprite(handle).collision.cwidth = 0 '                                                            reset collision box width
2530.     SL_sprite(handle).collision.cheight = 0 '                                                           reset collision box height
2531.  
2532.     ' animation settings
2533.  
2534.     SL_sprite(handle).animation.cell = cell '                                                           the animation cell this sprite is in
2535.     SL_sprite(handle).animation.cellfrom = 0 '                                                          reset sprite beginning animation cell
2536.     SL_sprite(handle).animation.cellto = 0 '                                                            reset sprite ending animation cell
2537.     SL_sprite(handle).animation.dir = 0 '                      (SL_FORWARD, SL_BACKWARD & SLBACKFORTH)  reset sprite animation direction
2538.     SL_sprite(handle).animation.mode = 0 '                                                              reset sprite animation mode
2539.     SL_sprite(handle).animation.frame = 0 '                                                             reset sprite animation frame counter
2540.     SL_sprite(handle).animation.skip = 0 '                                                              reset sprite animation skip rate
2541.     SL_sprite(handle).animation.auto = 0 '                                                     (FALSE)  sprite has no auto animation
2542.  
2543.     ' x,y location settings
2544.  
2545.     SL_sprite(handle).x.real = 0 '                                                                      reset x location of sprite (center x)
2546.     SL_sprite(handle).y.real = 0 '                                                                      reset y location of sprite (center y)
2547.     SL_sprite(handle).x.int = 0 '                                                                       reset x location of sprite on screen INT(xreal) (center x)
2548.     SL_sprite(handle).y.int = 0 '                                                                       reset y location of sprite on screen INT(yreal) (center y)
2549.     SL_sprite(handle).x.actual = 0 '                                                                    reset x location of sprite on screen (upper left x)
2550.     SL_sprite(handle).y.actual = 0 '                                                                    reset y location of sprite on screen (upper left y)
2551.     SL_sprite(handle).x.dir = 0 '                                                                       x direction during motion
2552.     SL_sprite(handle).y.dir = 0 '                                                                       y direction during motion
2553.  
2554.     ' graphics image settings
2555.  
2556.     SL_sprite(handle).gfx.back = 0 '                                                                    no background image saved yet
2557.     SL_sprite(handle).gfx.hardware = _COPYIMAGE(SL_sheet(sheet, cell).software, 33) '                   create hardware sprite image
2558.     SL_sprite(handle).gfx.software = _COPYIMAGE(SL_sheet(sheet, cell).software, 32) '                   copy software sprite image from sheet
2559.     IF SL_sheet(sheet, cell).transparency THEN '                                                        does this sprite use transparency?
2560.         SL_sprite(handle).gfx.mask = _COPYIMAGE(SL_sheet(sheet, cell).mask, 32) '                       yes, copy software sprite mask image from sheet
2561.         SL_sprite(handle).transparency = -1 '                                                   (TRUE)  remember this sprite has a transparency layer
2562.     ELSE '                                                                                              no transparency
2563.         SL_sprite(handle).gfx.mask = 0 '                                                                no mask will be brought in
2564.         SL_sprite(handle).transparency = 0 '                                                   (FALSE)  remember this sprite has no transparency layer
2565.     END IF
2566.  
2567.     ' rotation settings
2568.  
2569.     SL_sprite(handle).rotation.angle = 0 '                                                              no sprite rotation angle
2570.     SL_sprite(handle).rotation.speed = 0 '                                                              no spin rate
2571.     SL_sprite(handle).rotation.auto = 0 '                                                      (FALSE)  auto rotation disabled
2572.  
2573.     ' motion settings
2574.  
2575.     SL_sprite(handle).motion.speed = 0 '                                                                speed during motion
2576.     SL_sprite(handle).motion.angle = 0 '                                                                direction during motion (0 - 359)
2577.     SL_sprite(handle).motion.auto = 0 '                                                        (FALSE)  auto motion disabled
2578.  
2579.     SL_NEW_SPRITE = handle '                                                                            return pointer value of new sprite
2580.  
2581. END FUNCTION
2582.  
2583. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2584. SUB SL_FREE_SPRITE (handle AS INTEGER) '                                                                                                                                                 SL_FREE_SPRITE
2585.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2586.  
2587.     ' declare global variables
2588.  
2589.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2590.  
2591.     ' check for errors
2592.  
2593.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2594.         SL_error "SL_FREE_SPRITE", 1, "" '                                                              no, report error to programmer
2595.     END IF
2596.  
2597.     ' restore background if this sprite saving background
2598.  
2599.     IF SL_sprite(handle).restore THEN '                                                                 is there a background image to restore?
2600.         _PUTIMAGE (SL_sprite(handle).x.back, SL_sprite(handle).y.back), SL_sprite(handle).gfx.back '    yes, restore the image
2601.         _FREEIMAGE SL_sprite(handle).gfx.back '                                                         free background image
2602.     END IF
2603.  
2604.     ' free all image data associated with sprite
2605.  
2606.     IF SL_sprite(handle).gfx.back THEN _FREEIMAGE SL_sprite(handle).gfx.back '                          free background image if present
2607.     IF SL_sprite(handle).gfx.mask THEN _FREEIMAGE SL_sprite(handle).gfx.mask '                          free sprite mask image if present
2608.     _FREEIMAGE SL_sprite(handle).gfx.hardware '                                                         free hardware sprite image
2609.     _FREEIMAGE SL_sprite(handle).gfx.software '                                                         free software sprite image
2610.  
2611.     IF (handle = UBOUND(sl_sprite)) AND (handle <> 1) THEN '                                            is handle the last element in array?
2612.         REDIM _PRESERVE SL_sprite(handle - 1) AS SL_SPRITE '                                            yes, remove index and resize array
2613.     ELSE '                                                                                              no, index somewhere else
2614.         SL_sprite(handle).inuse = 0 '                                                          (FALSE)  mark index as usable later
2615.     END IF
2616.  
2617. END SUB
2618.  
2619. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2620. FUNCTION SL_VALID_SPRITE (handle AS INTEGER) '                                                                                                                                         SL_VALID_SPRITE
2621.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2622.  
2623.     ' declare global variables
2624.  
2625.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2626.  
2627.     IF (handle > UBOUND(SL_SPRITE)) OR (NOT SL_sprite(handle).inuse) OR (handle < 1) THEN '              is this a valid sprite handle?
2628.         SL_VALID_SPRITE = 0 '                                                                   (FALSE)  no, return 0
2629.     ELSE '                                                                                               yes, it is valid
2630.         SL_VALID_SPRITE = -1 '                                                                   (TRUE)  return -1
2631.     END IF
2632.  
2633. END FUNCTION
2634.  
2635. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2636. SUB SL_SET_SCORE (handle AS INTEGER, score AS INTEGER) '                                                                                                                                   SL_SET_SCORE
2637.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2638.  
2639.     ' declare global variables
2640.  
2641.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2642.  
2643.     ' perform error checks
2644.  
2645.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2646.         SL_error "SL_SET_SCORE", 1, "" '                                                                no, report error to programmer
2647.     END IF
2648.  
2649.     SL_sprite(handle).score = score '                                                                   set sprite score
2650.  
2651. END SUB
2652.  
2653. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2654. FUNCTION SL_GET_SCORE (handle AS INTEGER) '                                                                                                                                                SL_GET_SCORE
2655.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2656.  
2657.     ' declare global variables
2658.  
2659.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
2660.  
2661.     ' perform error checks
2662.  
2663.     IF NOT SL_VALID_SPRITE(handle) THEN '                                                               is this a valid sprite?
2664.         SL_error "SL_GET_SCORE", 1, "" '                                                                no, report error to programmer
2665.     END IF
2666.  
2667.     SL_GET_SCORE = SL_sprite(handle).score '                                                            return sprite score
2668.  
2669. END FUNCTION
2670.  
2671.  
2672. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
2673. '                                                                       ----------==========                ==========----------
2674. '                                                                       ----------========== SHEET ROUTINES ==========----------
2675. '                                                                       ----------==========                ==========----------
2676. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
2677.  
2678.  
2679. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2680. FUNCTION SL_NEW_SHEET (filename AS STRING, swidth AS INTEGER, sheight AS INTEGER, transparency AS INTEGER, transcolor AS _UNSIGNED LONG) '                                                 SL_NEW_SHEET
2681.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
2682.  
2683.     ' The saving/loading of rotational data file added from an idea by Bplus
2684.     ' https://www.qb64.org/forum/index.php?topic=537.30
2685.  
2686.     ' declare global variables
2687.  
2688.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
2689.     SHARED SL_angle() AS SL_ANGLE '     precalculated rotation table
2690.  
2691.     ' declare local variables
2692.  
2693.     DIM handle AS INTEGER '             handle (pointer) number of new sprite sheet
2694.     DIM x AS INTEGER '                  generic counter to cycle through sheet sprite columns
2695.     DIM y AS INTEGER '                  generic counter to cycle through sheet sprite rows
2696.     DIM osource AS LONG '               original source image before this function was called
2697.     DIM odest AS LONG '                 original destination image before this function was called
2698.     DIM pixel AS _UNSIGNED LONG '       pixel color at each coordinate in sprite sheet
2699.     DIM alpha AS _UNSIGNED LONG '       alpha level of current pixel
2700.     DIM top AS INTEGER '                upper boundary of sprite image
2701.     DIM bottom AS INTEGER '             lower boundary of sprite image
2702.     DIM left AS INTEGER '               left boundary of sprite image
2703.     DIM right AS INTEGER '              right boundary of sprite image
2704.     DIM sheetimage AS LONG '            sprite sheet image
2705.     DIM sheetwidth AS INTEGER '         width of sprite sheet in pixels
2706.     DIM sheetheight AS INTEGER '        height of sprite sheet in pixels
2707.     DIM rows AS INTEGER '               number of sprite rows contained on sheet
2708.     DIM columns AS INTEGER '            number of sprite columns contained on sheet
2709.     DIM clearcolor AS _UNSIGNED LONG '  transcolor passed in will be modified
2710.     DIM tempsprite AS LONG '            temporary sprite image
2711.     DIM px(3) AS SINGLE '               polar x coordinates of maptriangle
2712.     DIM py(3) AS SINGLE '               polar y coordinates of maptriangle
2713.     DIM sinr AS SINGLE '                sin rotation calculation
2714.     DIM cosr AS SINGLE '                cosine rotation calculation
2715.     DIM bx1 AS SINGLE '                 boundaries of collision box
2716.     DIM bx2 AS SINGLE
2717.     DIM by1 AS SINGLE
2718.     DIM by2 AS SINGLE
2719.     DIM x2 AS SINGLE '                  new computed polar coordinates
2720.     DIM y2 AS SINGLE
2721.     DIM cells AS INTEGER '              total number of cells on sheet
2722.     DIM cell AS INTEGER '               cell counter
2723.     DIM degree AS INTEGER '             degree counter
2724.     DIM polar AS INTEGER '              polar coordinate counter
2725.     DIM xoffset AS INTEGER '            x offset to rotated center
2726.     DIM yoffset AS INTEGER '            y offset to rotated center
2727.     DIM xwidth AS INTEGER '             sprite width counter
2728.     DIM yheight AS INTEGER '            sprite height counter
2729.     DIM rotfile AS STRING '             name of rotation data file
2730.     DIM preloaded AS INTEGER '          -1 (TRUE) if rotation data preloaded
2731.     DIM filenum AS INTEGER '            FREEFILE number
2732.  
2733.     ' perform error checks
2734.  
2735.     IF NOT _FILEEXISTS(filename) THEN '                                                                 does the sprite sheet exist?
2736.         SL_error "SL_NEW_SHEET", 100, filename '                                                        no, report error to programmer
2737.     END IF
2738.     IF ABS(transparency) > 1 THEN '                                                                     valid transparency setting?
2739.         SL_error "SL_NEW_SHEET", 101, "" '                                                              no, report error to programmer
2740.     END IF
2741.     IF swidth < 1 OR sheight < 1 THEN '                                                                 valid sprite width/height supplied?
2742.         SL_error "SL_NEW_SHEET", 102, "" '                                                              no, report error to programmer
2743.     END IF
2744.     IF transparency = -1 AND UCASE$(RIGHT$(filename, 4)) <> ".PNG" THEN '                               wrong file type for transparency?
2745.         SL_error "SL_NEW_SHEET", 103, UCASE$(RIGHT$(filename, 4)) '                                     yes, report error to programmer
2746.     END IF
2747.  
2748.     ' local variable setup
2749.  
2750.     sheetimage = _LOADIMAGE(filename, 32) '                                                             load sprite sheet file
2751.     sheetwidth = _WIDTH(sheetimage) '                                                                   get width of sheet
2752.     sheetheight = _HEIGHT(sheetimage) '                                                                 get height of sheet
2753.     columns = sheetwidth \ swidth '                                                                     get number of whole columns of sprites
2754.     rows = sheetheight \ sheight '                                                                      get number of whole rows of sprites
2755.     cells = rows * columns '                                                                            calculate total number of cells on sheet
2756.  
2757.     IF columns < 1 OR rows < 1 THEN '                                                                   at least one sprite column and row on sheet?
2758.         SL_error "SL_NEW_SHEET", 104, "" '                                                              no, report error to programmer
2759.     END IF
2760.  
2761.     osource = _SOURCE '                                                                                 remember current source image
2762.     odest = _DEST '                                                                                     remember current destination image
2763.     handle = 0 '                                                                                        initialize handle value
2764.     clearcolor = transcolor '                                                                           get background/transparent color passed in
2765.  
2766.     ' increase sheet array's 1st dimension if needed to create a new sprite sheet
2767.  
2768.     DO '                                                                                                look for the next available handle
2769.         handle = handle + 1 '                                                                           increment the handle value
2770.     LOOP UNTIL (NOT SL_sheet(handle, 0).software) OR handle = UBOUND(SL_sheet) '                        stop looking when valid handle value found
2771.     IF SL_sheet(handle, 0).software = -1 THEN '                                                 (TRUE)  is the last array element in use?
2772.         handle = handle + 1 '                                                                           yes, increment the handle value
2773.         REDIM _PRESERVE SL_sheet(handle, UBOUND(SL_sheet, 2)) AS SL_SHEET '                             create new sheet in sprite array
2774.         REDIM _PRESERVE SL_angle(handle, UBOUND(SL_angle, 2), 359) AS SL_ANGLE '                        increase rotation array to match
2775.     END IF
2776.  
2777.     ' increase sheet array's 2nd dimension if needed to match number of cells
2778.  
2779.     IF cells > UBOUND(SL_sheet, 2) THEN '                                                               more cells in this sheet than others?
2780.         REDIM _PRESERVE SL_sheet(handle, cells) AS SL_SHEET '                                           yes, increase the array's 2nd dimension to match
2781.         REDIM _PRESERVE SL_angle(handle, cells, 359) AS SL_ANGLE '                                      increase rotation array to match
2782.     END IF
2783.  
2784.     ' the variables in SL_sheet(x, 0) will serve a dual purpose
2785.     ' SL_sheet(x, 0).image will contain either -1 (true) or 0 (false) to indicate the first dimension of the array is in use.
2786.  
2787.     SL_sheet(handle, 0).software = -1 '                                                         (TRUE)  mark as in use
2788.  
2789.     ' identify transparency of sprite sheet if requested
2790.  
2791.     IF transparency = -1 THEN '                                                          (SL_USESHEET)  sheet have alpha channel?
2792.         x = 0 '                                                                                         yes, start at upper left x of sheet
2793.         y = 0 '                                                                                         start at upper left y of sheet
2794.         alpha = 255 '                                                                                   assume no alpha channel
2795.         _SOURCE sheetimage '                                                                            set sprite sheet image as source image
2796.         DO '                                                                                            start looping through the sheet's pixels
2797.             pixel = POINT(x, y) '                                                                       get the pixel's color attributes
2798.             alpha = _ALPHA32(pixel) '                                                                   get the alpha level (0 - 255)
2799.             IF alpha = 0 THEN EXIT DO '                                                                 if it is transparent then leave the loop
2800.             x = x + 1 '                                                                                 move right one pixel
2801.             IF x > sheetwidth THEN '                                                                    have we gone off the sheet?
2802.                 x = 0 '                                                                                 yes, reset back to the left beginning
2803.                 y = y + 1 '                                                                             move down one pixel
2804.             END IF
2805.         LOOP UNTIL y > sheetheight '                                                                    don't stop until the entire sheet has been checked
2806.         IF alpha = 0 THEN '                                                                             did we find a transparent pixel?
2807.             tempsprite = _NEWIMAGE(1, 1, 32) '                                                          yes, create a temporary image         * why did I have to do
2808.             _CLEARCOLOR pixel, tempsprite '                                                             set pixel found as transparent        * this hack to get
2809.             clearcolor = _CLEARCOLOR(tempsprite) '                                                      get the transparent color from image  * clearcolor to come out
2810.             _FREEIMAGE tempsprite '                                                                     temporary image no longer needed      * to the right value?
2811.         ELSE '                                                                                          no transparency found within sheet
2812.             transparency = 1 '                                                                          set sheet to having no alpha channel
2813.         END IF
2814.     ELSEIF transparency = 0 THEN '                                                            (SL_SET)  manually set alpha channel?
2815.         _CLEARCOLOR clearcolor, sheetimage '                                                            yes, set color as transparent
2816.         clearcolor = _CLEARCOLOR(sheetimage) '                                                          get the transparent color ************* again, why this hack?
2817.     END IF
2818.  
2819.     ' preload rotational data if it exists
2820.  
2821.     rotfile = LEFT$(filename, INSTR(filename, ".") - 1) + ".rot" '                                      the name of the rotational data file
2822.     IF _FILEEXISTS(rotfile) THEN '                                                                      does it exist?
2823.         preloaded = -1 '                                                                                yes, remember that data has been preloaded
2824.         filenum = FREEFILE
2825.         OPEN rotfile FOR BINARY AS filenum '                                                            open it for reading
2826.         FOR x = 1 TO cells '                                                                            cycle through all animation cells
2827.             FOR y = 0 TO 359 '                                                                          and their associated rotational data
2828.                 GET #1, , SL_angle(handle, x, y) '                                                      get the data
2829.             NEXT y
2830.         NEXT x
2831.         CLOSE filenum '                                                                                 close the file
2832.     END IF
2833.  
2834.     ' load sprites from sheet and place into sprite array
2835.  
2836.     x = 0 '                                                                                             reset column counter
2837.     DO '                                                                                                cycle through sheet's columns
2838.         x = x + 1 '                                                                                     increment column counter
2839.         y = 0 '                                                                                         reset row counter
2840.         DO '                                                                                            cycle through sheet's rows
2841.             y = y + 1 '                                                                                 increment row counter
2842.             cell = (y - 1) * columns + x '                                                              calculate current cell number
2843.             SL_sheet(handle, cell).software = _NEWIMAGE(swidth, sheight, 32) '                          create software sprite image
2844.  
2845.             SL_sheet(handle, cell).swidth = swidth
2846.             SL_sheet(handle, cell).sheight = sheight
2847.  
2848.  
2849.             IF transparency < 1 THEN '                                                                  should a mask be created?
2850.                 SL_sheet(handle, cell).mask = _NEWIMAGE(swidth, sheight, 32) '                          yes, create software sprite mask image
2851.                 _DEST SL_sheet(handle, cell).mask '                                                     write to the mask image
2852.             ELSE '                                                                                      no software mask image
2853.                 SL_sheet(handle, cell).transparency = 0 '                                      (FALSE)  set sprite as having no transparency
2854.             END IF
2855.             _PUTIMAGE , sheetimage, SL_sheet(handle, cell).software,_
2856.                 ((x - 1) * swidth, (y - 1) * sheight)-_
2857.                 ((x - 1) * swidth + swidth - 1, (y - 1) * sheight + sheight - 1) '                      copy sprite from sheet and place in sprite image
2858.  
2859.             ' precalculate collision boundaries and update sprite mask if needed
2860.  
2861.             _SOURCE SL_sheet(handle, cell).software '                                                   work from the software sprite image
2862.             top = sheight - 1 '                                                                         set initial collision boundary markers
2863.             left = swidth - 1
2864.             bottom = 0
2865.             right = 0
2866.  
2867.             xwidth = 0 '                                                                                reset width counter
2868.             DO '                                                                                        cycle through width of sprite
2869.                 yheight = 0 '                                                                           reset height counter
2870.                 DO '                                                                                    cycle through height of sprite
2871.                     IF POINT(xwidth, yheight) <> clearcolor THEN '                                      is this pixel a transparent/background color?
2872.                         IF xwidth < left THEN left = xwidth '                                           no, save position if left-most pixel
2873.                         IF yheight < top THEN top = yheight '                                           save position if top-most pixel
2874.                         IF xwidth > right THEN right = xwidth '                                         save position if right-most pixel
2875.                         IF yheight > bottom THEN bottom = yheight '                                     save position if bbottom-most pixel
2876.                     END IF
2877.                     IF transparency < 1 THEN '                                                          update software sprite mask?
2878.                         IF POINT(xwidth, yheight) = clearcolor THEN '                                   yes, is this pixel a transparent/background color?
2879.                             PSET (xwidth, yheight), _RGB32(255, 255, 255) '                             yes, set as white on the mask image
2880.                         END IF
2881.                     END IF
2882.                     yheight = yheight + 1 '                                                             increment height counter
2883.                 LOOP UNTIL yheight = sheight '                                                          leave when height of sprite reached (-1)
2884.                 xwidth = xwidth + 1 '                                                                   increment width counter
2885.             LOOP UNTIL xwidth = swidth '                                                                leave when width of sprite reached (-1)
2886.  
2887.             SL_angle(handle, cell, 0).x1 = left '                                                       collision box top left x
2888.             SL_angle(handle, cell, 0).y1 = top '                                                        collision box top left y
2889.             SL_angle(handle, cell, 0).x2 = right '                                                      collision box bottom right x
2890.             SL_angle(handle, cell, 0).y2 = bottom '                                                     collision box bottom right y
2891.             SL_angle(handle, cell, 0).cwidth = right - left '                                           remember collision box width
2892.             SL_angle(handle, cell, 0).cheight = bottom - top '                                          remember collision box height
2893.             SL_angle(handle, cell, 0).radius = (SL_angle(handle, cell, 0).cwidth + SL_angle(handle, cell, 0).cheight) \ 4 ' calculate round collision radius
2894.  
2895.             IF NOT preloaded THEN
2896.  
2897.                 degree = 0 '                                                                            reset degree counter
2898.                 DO '                                                                                    cycle from 1 to 359 degrees
2899.                     degree = degree + 1 '                                                               increment degree counter
2900.                     'px(0) = (-swidth + 1) / 2 '                                                         upper left  x polar coordinate of sprite
2901.                     'py(0) = (-sheight + 1) / 2 '                                                        upper left  y polar coordinate of sprite
2902.                     px(0) = -swidth / 2 '                                                               upper left  x polar coordinate of sprite
2903.                     py(0) = -sheight / 2 '                                                              upper left  y polar coordinate of sprite
2904.                     px(1) = px(0) '                                                                     lower left  x polar coordinate of sprite
2905.                     'py(1) = (sheight -1) / 2 '                                                          lower left  y polar coordinate of sprite
2906.                     'px(2) = (swidth - 1) / 2 '                                                          lower right x polar coordinate of sprite
2907.                     py(1) = sheight / 2 '                                                               lower left  y polar coordinate of sprite
2908.                     px(2) = swidth / 2 '                                                                lower right x polar coordinate of sprite
2909.                     py(2) = py(1) '                                                                     lower right y polar coordinate of sprite
2910.                     px(3) = px(2) '                                                                     upper right x polar coordinate of sprite
2911.                     py(3) = py(0) '                                                                     upper right y polar coordinate of sprite
2912.                     sinr = SIN(-degree / 57.2957795131) '                                               calculate the sin of rotation
2913.                     cosr = COS(-degree / 57.2957795131) '                                               calculate the cosine of rotation
2914.                     bx1 = 0 '                                                                           upper left x boundary of sprite
2915.                     by1 = 0 '                                                                           upper left y boundary of sprite
2916.                     bx2 = 0 '                                                                           lower right x boundary of sprite
2917.                     by2 = 0 '                                                                           lower right y boundary of sprite
2918.  
2919.                     polar = 0 '                                                                         reset counter
2920.                     DO '                                                                                cycle through all four polar coordinates (0 to 3)
2921.                         x2 = (px(polar) * cosr + sinr * py(polar)) '                                    compute new polar coordinate location
2922.                         y2 = (py(polar) * cosr - px(polar) * sinr) '                                    compute new polar coordinate location
2923.                         px(polar) = x2 '                                                                save the new polar coordinate
2924.                         py(polar) = y2 '                                                                save the new polar coordinate
2925.                         IF px(polar) < bx1 THEN bx1 = px(polar) '                                       save lowest  x value seen \  NOTE: use for
2926.                         IF px(polar) > bx2 THEN bx2 = px(polar) '                                       save highest x value seen  \ background image         <--------------------- LOOK
2927.                         IF py(polar) < by1 THEN by1 = py(polar) '                                       save lowest  y value seen  / rectangle coordinates
2928.                         IF py(polar) > by2 THEN by2 = py(polar) '                                       save highest y value seen /
2929.                         polar = polar + 1 '                                                             increment counter
2930.                     LOOP UNTIL polar = 4 '                                                              leave when all coordinates calculated
2931.  
2932.                     SL_angle(handle, cell, degree).rwidth = bx2 - bx1 + 1 '                             calculate width of rotated sprite
2933.                     SL_angle(handle, cell, degree).rheight = by2 - by1 + 1 '                            calculate height of rotated sprite
2934.                     xoffset = SL_angle(handle, cell, degree).rwidth \ 2 '                               calculate x offset
2935.                     yoffset = SL_angle(handle, cell, degree).rheight \ 2 '                              calculate y offset
2936.                     SL_angle(handle, cell, degree).px0 = px(0) + xoffset '                              add offsets to coordinates
2937.                     SL_angle(handle, cell, degree).px1 = px(1) + xoffset
2938.                     SL_angle(handle, cell, degree).px2 = px(2) + xoffset
2939.                     SL_angle(handle, cell, degree).px3 = px(3) + xoffset
2940.                     SL_angle(handle, cell, degree).py0 = py(0) + yoffset
2941.                     SL_angle(handle, cell, degree).py1 = py(1) + yoffset
2942.                     SL_angle(handle, cell, degree).py2 = py(2) + yoffset
2943.                     SL_angle(handle, cell, degree).py3 = py(3) + yoffset
2944.  
2945.                     ' rotate image here to get rotated collision box info
2946.  
2947.                     tempsprite = _NEWIMAGE(SL_angle(handle, cell, degree).rwidth, SL_angle(handle, cell, degree).rheight, 32) ' create temp image using precalculated width/height
2948.                 _MAPTRIANGLE (0, 0)-(0, sheight - 1)-(swidth - 1, sheight - 1), SL_sheet(handle, cell).software TO _
2949.                              (SL_angle(handle, cell, degree).px0, SL_angle(handle, cell, degree).py0)-(SL_angle(handle, cell, degree).px1,_
2950.                               SL_angle(handle, cell, degree).py1)-(SL_angle(handle, cell, degree).px2, SL_angle(handle, cell, degree).py2), tempsprite ' map rotated sprite onto temp image
2951.                 _MAPTRIANGLE (0, 0)-(swidth - 1, 0)-(swidth - 1, sheight - 1), SL_sheet(handle, cell).software TO _
2952.                              (SL_angle(handle, cell, degree).px0, SL_angle(handle, cell, degree).py0)-(SL_angle(handle, cell, degree).px3,_
2953.                               SL_angle(handle, cell, degree).py3)-(SL_angle(handle, cell, degree).px2, SL_angle(handle, cell, degree).py2), tempsprite
2954.  
2955.                     ' precalculate rotated collision boundaries
2956.  
2957.                     _SOURCE tempsprite '                                                                work from the temp image
2958.                     top = SL_angle(handle, cell, degree).rheight - 1 '                                  set initial collision boundary markers
2959.                     left = SL_angle(handle, cell, degree).rwidth - 1
2960.                     bottom = 0
2961.                     right = 0
2962.  
2963.                     xwidth = 0 '                                                                        reset width counter
2964.                     DO '                                                                                cycle through width of rotated sprite
2965.                         yheight = 0 '                                                                   reset height counter
2966.                         DO '                                                                            cycle through height of rotated sprite
2967.                             IF POINT(xwidth, yheight) <> clearcolor THEN '                              is this pixel a transparent/background color?
2968.                                 IF xwidth < left THEN left = xwidth '                                   no, save position if left-most pixel
2969.                                 IF yheight < top THEN top = yheight '                                   save position if top-most pixel
2970.                                 IF xwidth > right THEN right = xwidth '                                 save position if right-most pixel
2971.                                 IF yheight > bottom THEN bottom = yheight '                             save position if bbottom-most pixel
2972.                             END IF
2973.                             yheight = yheight + 1 '                                                     increment height counter
2974.                         LOOP UNTIL yheight = SL_angle(handle, cell, degree).rheight '                   leave when height of rotated sprite reached (-1)
2975.                         xwidth = xwidth + 1 '                                                           increment width counter
2976.                     LOOP UNTIL xwidth = SL_angle(handle, cell, degree).rwidth '                         leave when width of rotated sprite reached (-1)
2977.  
2978.                     _FREEIMAGE tempsprite '                                                             temp image no longer needed
2979.                     SL_angle(handle, cell, degree).x1 = left '                                          collision box top left x
2980.                     SL_angle(handle, cell, degree).y1 = top '                                           collision box top left y
2981.                     SL_angle(handle, cell, degree).x2 = right '                                         collision box bottom right x
2982.                     SL_angle(handle, cell, degree).y2 = bottom '                                        collision box bottom right y
2983.                     SL_angle(handle, cell, degree).cwidth = right - left '                              remember collision box width
2984.                     SL_angle(handle, cell, degree).cheight = bottom - top '                             remember collision box height
2985.                     SL_angle(handle, cell, degree).radius = (SL_angle(handle, cell, degree).cwidth + SL_angle(handle, cell, degree).cheight) \ 4 ' calculate round collision radius
2986.                 LOOP UNTIL degree = 359 '                                                               leave when all degree angles calculated
2987.  
2988.             END IF ' preloaded
2989.  
2990.         LOOP UNTIL y = rows '                                                                           leave when all rows processed
2991.     LOOP UNTIL x = columns '                                                                            leave when all columns processed
2992.  
2993.     _FREEIMAGE sheetimage '                                                                             sprite sheet image no longer needed
2994.  
2995.     _SOURCE osource '                                                                                   return source to current
2996.     _DEST odest '                                                                                       return destination to current
2997.  
2998.     IF NOT _FILEEXISTS(rotfile) THEN '                                                                  does it exist?
2999.         filenum = FREEFILE
3000.         OPEN rotfile FOR BINARY AS filenum '                                                            no, open it for writing
3001.         FOR x = 1 TO cells '                                                                            cycle through all sprite cells
3002.             FOR y = 0 TO 359 '                                                                          and their rotational angles
3003.                 PUT #1, , SL_angle(handle, x, y) '                                                      put the data
3004.             NEXT y
3005.         NEXT x
3006.         CLOSE filenum '                                                                                 close the file
3007.     END IF
3008.  
3009.     SL_NEW_SHEET = handle '                                                                             return the handle number pointing to this sheet
3010.  
3011. END FUNCTION
3012.  
3013. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3014. FUNCTION SL_VALID_SHEET (sheet AS INTEGER) '                                                                                                                                             SL_VALID_SHEET
3015.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3016.  
3017.     ' declare global variables
3018.  
3019.     SHARED SL_sheet() AS SL_SHEET '    master sprite sheet array
3020.  
3021.     IF (sheet > UBOUND(SL_sheet)) OR (sheet < 1) THEN '                                                 is this a valid sheet?
3022.         SL_VALID_SHEET = 0 '                                                                   (FALSE)  no, return false
3023.     ELSEIF NOT SL_sheet(sheet, 0).software THEN '                                                       is sprite sheet in use?
3024.         SL_VALID_SHEET = 0 '                                                                   (FALSE)  no, return false
3025.     ELSE '                                                                                              everything checks out
3026.         SL_VALID_SHEET = -1 '                                                                   (TRUE)  return true
3027.     END IF
3028.  
3029. END FUNCTION
3030.  
3031.  
3032. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
3033. '                                                                      ----------==========                   ==========----------
3034. '                                                                      ----------========== INTERNAL USE ONLY ==========----------
3035. '                                                                      ----------==========                   ==========----------
3036. 'ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
3037.  
3038.  
3039. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3040. SUB SL_update_auto_sprites (software AS INTEGER) '                                                                                                                               SL_update_auto_sprites
3041.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3042.  
3043.     ' declare global variables
3044.  
3045.     SHARED SL_sprite() AS SL_SPRITE '   master working sprite array
3046.     SHARED SL_global AS SL_GLOBAL '     common globals array
3047.  
3048.     ' declare local variables
3049.  
3050.     DIM handle AS INTEGER '             handle of sprite
3051.     DIM nextcell AS SINGLE '            draw (-1 TRUE) or skip (0 FALSE) next animation cell
3052.  
3053.     ' local variable setup
3054.  
3055.     handle = 0 '                                                                                        initialize handle counter
3056.  
3057.     DO '                                                                                                cycle through all sprite indexes
3058.         handle = handle + 1 '                                                                           increment to next sprite handle
3059.         IF SL_sprite(handle).software = software THEN '                                                 hardware or software type equal to requested type?
3060.             IF SL_sprite(handle).inuse AND (SL_sprite(handle).motion.auto OR _
3061.                                             SL_sprite(handle).rotation.auto OR _
3062.                                             SL_sprite(handle).animation.auto) THEN '                    yes, is this sprite being used and automagically controlled?
3063.  
3064.                 ' auto motion
3065.  
3066.                 IF SL_sprite(handle).motion.auto THEN '                                                 yes, is auto motion enabled?
3067.                     SL_sprite(handle).x.real = SL_sprite(handle).x.real + SL_sprite(handle).x.dir '     yes, update x location
3068.                     SL_sprite(handle).y.real = SL_sprite(handle).y.real + SL_sprite(handle).y.dir '     update y location
3069.                 END IF
3070.  
3071.  
3072.                 ' auto animation
3073.  
3074.                 IF SL_sprite(handle).animation.auto THEN '                                              is auto animation enabled?
3075.                     IF SL_sprite(handle).animation.skip = 0 THEN '                                      yes, always go to next cell?
3076.                         nextcell = -1 '                                                         (TRUE)  yes, draw next cell
3077.                     ELSE '                                                                              no
3078.  
3079.                         ' decide to draw or skip next cell
3080.  
3081.                         SL_sprite(handle).animation.frame = SL_sprite(handle).animation.frame + 1 '     increment frame counter
3082.                         IF SL_sprite(handle).animation.skip = SL_sprite(handle).animation.frame THEN '  time to skip or go to next cell?
3083.                             SL_sprite(handle).animation.frame = 0 '                                     yes, reset the frame counter
3084.                             IF SL_sprite(handle).animation.framerate >= SL_global.framerate \ 2 THEN '  should this cell be skipped?
3085.                                 nextcell = 0 '                                                 (FALSE)  yes, skip next cell
3086.                             ELSE '                                                                      no
3087.                                 nextcell = -1 '                                                 (TRUE)  go to next cell
3088.                             END IF
3089.                         ELSEIF SL_sprite(handle).animation.framerate >= SL_global.framerate \ 2 THEN '  no, is sprite frame rate equal or greater than half global frame rate?
3090.                             nextcell = -1 '                                                             yes, go to next cell
3091.                         END IF
3092.                     END IF
3093.  
3094.                     ' draw next cell
3095.  
3096.                     IF nextcell THEN '                                                                  update animation cell?
3097.                         SELECT CASE SL_sprite(handle).animation.mode '                                  which animation mode is this sprite using?
3098.                             CASE 0 '                                                      (SL_FORWARD)  move forward through the cells
3099.                                 SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell + 1 ' increment animation cell
3100.                                 IF SL_sprite(handle).animation.cell > SL_sprite(handle).animation.cellto THEN ' passed the last cell?
3101.                                     SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellfrom ' yes, go back to first cell
3102.                                 END IF
3103.                             CASE 1 '                                                     (SL_BACKWARD)  move backward through the cells
3104.                                 SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell - 1 ' decrement animation cell
3105.                                 IF SL_sprite(handle).animation.cell < SL_sprite(handle).animation.cellfrom THEN ' passed the first cell?
3106.                                     SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellto ' yes, go back to last cell
3107.                                 END IF
3108.                             CASE 2 '                                                    (SL_BACKFORTH)  ping-pong back and forth through the cells
3109.                                 SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cell + SL_sprite(handle).animation.dir ' increment/decrement animation cell
3110.                                 IF SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellto OR _
3111.                                     SL_sprite(handle).animation.cell = SL_sprite(handle).animation.cellfrom THEN ' is this the first or last cell?
3112.                                     SL_sprite(handle).animation.dir = -SL_sprite(handle).animation.dir 'yes, reverse animation direction
3113.                                 END IF
3114.                         END SELECT
3115.                         SL_sprite(handle).cell = SL_sprite(handle).animation.cell '                     update current sprite cell
3116.                         IF SL_sprite(handle).rotation.angle AND (NOT SL_sprite(handle).rotation.auto) THEN ' is this animation currently rotated but not automatic?
3117.                             SL_ROTATE_SPRITE handle, SL_sprite(handle).rotation.angle '                 yes, this new cell will need manually rotated as well
3118.                         END IF
3119.                     END IF
3120.                 END IF
3121.  
3122.                 ' auto rotation
3123.  
3124.                 IF SL_sprite(handle).rotation.auto THEN '                                               is auto rotation enabled?
3125.                     SL_ROTATE_SPRITE handle, SL_sprite(handle).rotation.angle + SL_sprite(handle).rotation.speed ' yes, rotate sprite to next degree angle
3126.                 END IF
3127.  
3128.                 SL_PUT_SPRITE SL_sprite(handle).x.real, SL_sprite(handle).y.real, handle '              update sprite motion location, rotation, and animation
3129.             END IF
3130.         END IF
3131.     LOOP UNTIL handle = UBOUND(SL_sprite) '                                                             leave when all indexes checked
3132.  
3133. END SUB
3134.  
3135. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3136. FUNCTION SL_min (a AS INTEGER, b AS INTEGER) '                                                                                                                                                   SL_min
3137.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3138.  
3139.     IF a < b THEN '                                                                                     is a the smaller number?
3140.         SL_min = a '                                                                                    yes, return a
3141.     ELSE '                                                                                              no, b is smaller number
3142.         SL_min = b '                                                                                    return b (or a = b)
3143.     END IF
3144.  
3145. END FUNCTION
3146.  
3147. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3148. FUNCTION SL_max (a AS INTEGER, b AS INTEGER) '                                                                                                                                                   SL_max
3149.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3150.  
3151.     IF a > b THEN '                                                                                     is a the larger number?
3152.         SL_max = a '                                                                                    yes, return a
3153.     ELSE '                                                                                              no, b is the larger number
3154.         SL_max = b '                                                                                    return b (or a = b)
3155.     END IF
3156.  
3157. END FUNCTION
3158.  
3159. '    ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3160. SUB SL_error (routine AS STRING, errno AS INTEGER, info AS STRING) '                                                                                                                           SL_error
3161.     'ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
3162.  
3163.     SCREEN 0, 0, 0, 0 '                                                                                 go to a pure text screen
3164.     _FONT 16 '                                                                                          set the standard screen 0 font
3165.     IF _FULLSCREEN THEN _FULLSCREEN _OFF '                                                              turn off full screen if on
3166.     _AUTODISPLAY '                                                                                      auto update the display
3167.     CLS '                                                                                               clear the screen
3168.     COLOR 10, 0
3169.     PRINT "                   **************************************" '                                 print error header
3170.     PRINT "                   ** Sprite Library Error Encountered **"
3171.     PRINT "                   **************************************"
3172.     PRINT
3173.     COLOR 15, 0
3174.     PRINT " "; routine;
3175.     COLOR 7, 0
3176.     PRINT " has reported error";
3177.     COLOR 30, 0
3178.     PRINT STR$(errno)
3179.     COLOR 7, 0
3180.     PRINT
3181.     SELECT CASE errno '                                                                                 which error number is being reported?
3182.  
3183.         ' general purpose errors for all subs/functions
3184.  
3185.         CASE 1
3186.             PRINT "- the requested sprite does not exist"
3187.         CASE 2
3188.             PRINT "- invalid background restore setting supplied - valid settings are"
3189.             PRINT "- : -1 (constant SL_SAVE)"
3190.             PRINT "- :  0 (constant SL_NOSAVE)"
3191.         CASE 3
3192.             PRINT "- invalid flip setting supplied - valid settings are"
3193.             PRINT "- : 0 (constant SL_NOFLIP or SL_RESET)"
3194.             PRINT "- : 1 (constant SL_HORIZONTAL)"
3195.             PRINT "- : 2 (constant SL_VERTICAL)"
3196.             PRINT "- : 3 (constant SL_FLIPBOTH)"
3197.         CASE 4
3198.             PRINT "- invalid zoom level setting supplied"
3199.             PRINT "- zoom level must be greater than zero (0)"
3200.         CASE 5
3201.             PRINT "- the specified sprite sheet is not in use or does not exist"
3202.         CASE 6
3203.             PRINT "- invalid row or column selected for specified sprite sheet"
3204.         CASE 7
3205.             PRINT "- invalid auto motion behavior requested - valid settings are"
3206.             PRINT "- : -1 (constant SL_START)"
3207.             PRINT "- :  0 (constant SL_STOP)"
3208.         CASE 8
3209.             PRINT "- invalid auto rotation behavior requested - valid settings are"
3210.             PRINT "- : -1 (constant SL_START)"
3211.             PRINT "- :  0 (constant SL_STOP)"
3212.         CASE 9
3213.             PRINT "- rotation speed must be between -359 and 359 degrees"
3214.         CASE 10
3215.             PRINT "- frame rate must be greater than zero (0)"
3216.         CASE 11
3217.             PRINT "- frame rate must be greater than zero (0) and less than or equal"
3218.             PRINT "- to the global frame rate"
3219.         CASE 12
3220.             PRINT "- incorrect animation direction mode setting - valid settings are"
3221.             PRINT "- : 0 (constant SL_FORWARD)"
3222.             PRINT "- : 1 (constant SL_BACKWARD)"
3223.             PRINT "- : 2 (constant CL_BACKFORTH"
3224.         CASE 13
3225.             PRINT "- invalid cell value given - it must be greater than 0 and less"
3226.             PRINT "- than or equal to the total number of animation cells on a sheet"
3227.         CASE 14
3228.             PRINT "- invalid auto animation behavior requested - valid settings are"
3229.             PRINT "- : -1 (constant SL_START)"
3230.             PRINT "- :  0 (constant SL_STOP)"
3231.         CASE 15
3232.             PRINT "- animation has not been assigned to this sprite - use"
3233.             PRINT "- SL_SET_ANIMATION to assign animation to this sprite"
3234.         CASE 16
3235.             PRINT "- this srpite is already under auto motion control"
3236.             PRINT "- use SL_CHANGE_AUTOMOTION to disable auto motion control"
3237.         CASE 17
3238.             PRINT "- this sprite is already under auto rotation control"
3239.             PRINT "- use SL_CHANGE_AUTOROTATION to disable auto rotation control"
3240.         CASE 18
3241.             PRINT "- this sprite is already under auto animation control"
3242.             PRINT "- use SL_CHNAGE_AUTOANIMATION to disable auto animation control"
3243.         CASE 19
3244.             PRINT "- the destination cell must be greater than the starting cell"
3245.         CASE 20
3246.             PRINT "- invalid visible setting reguested - valid setting are"
3247.             PRINT "- : -1 (constant SL_SHOW)"
3248.             PRINT "- :  0 (constant SL_HIDE)"
3249.         CASE 21
3250.             PRINT "- the sprite being checked for collisions has no collision detection"
3251.             PRINT "- enabled - use SL_XXXXXXXXXX to turn on collision detection for"
3252.             PRINT "- the sprite"
3253.         CASE 22
3254.             PRINT "- the sprite being checked for a collision with has no collision"
3255.             PRINT "- detection enabled - use SL_XXXXXXX to turn on collision detection"
3256.             PRINT "- for the sprite"
3257.         CASE 23
3258.             PRINT "- both sprites must have the same collision detection method"
3259.         CASE 24
3260.             PRINT "- invalid collision detection mode requested - valid settings are"
3261.             PRINT "- : 0 (constant SL_NODETECT or SL_RESET)"
3262.             PRINT "- : 1 (constant SL_BOXDETECT)"
3263.             PRINT "- : 2 (constant SL_ROUNDDETECT)"
3264.             PRINT "- : 3 (constant SL_PIXELDETECT)"
3265.         CASE 25
3266.             PRINT "- invalid layer requested - the layer does not exist"
3267.         CASE 26
3268.             PRINT "- you must create at least one (1) layer"
3269.  
3270.             ' errors belonging to SL_NEW_SHEET (100 - 109)
3271.  
3272.         CASE 100
3273.             PRINT "- "; CHR$(34); info; CHR$(34); " sprite sheet does not exist"
3274.             PRINT "- check path or spelling"
3275.         CASE 101
3276.             PRINT "- invalid transparency setting supplied - valid settings are"
3277.             PRINT "- : -1 (constant SL_USESHEET)"
3278.             PRINT "- :  0 (constant SL_SET)"
3279.             PRINT "- :  1 (constant SL_NONE)"
3280.         CASE 102
3281.             PRINT "- sprite width and/or height must be greater than zero"
3282.         CASE 103
3283.             PRINT "- selecting to use a sheet's transparency only works with .PNG files"
3284.             PRINT "- the function was passed a "; info; " file."
3285.         CASE 104
3286.             PRINT "- there must be at least one column and one row of sprites on sheet"
3287.             PRINT "- the sheet being loaded does not meet these minimums"
3288.  
3289.             'errors belonging to SL_NEW_SPRITE (110 - 119)
3290.  
3291.             'CASE 110
3292.             '    PRINT "- the specified sprite sheet is not in use or does not exist"
3293.             'CASE 111
3294.             '    PRINT "- invalid row or column selected for specified sprite sheet"
3295.         CASE 112
3296.             PRINT "- invalid hardware / software setting supplied - valid settings are"
3297.             PRINT "- : -1 (constant SL_SOFTWARE)"
3298.             PRINT "- :  0 (constant SL_HARDWARE)"
3299.         CASE 113
3300.             PRINT "- there is no need to restore the background with hardware sprites"
3301.             PRINT "- change background restore setting to zero (0) (constant SL_NOSAVE)"
3302.  
3303.     END SELECT
3304.     COLOR 12, 0
3305.     PRINT
3306.     PRINT " See sprite library doumentation for further explanation."
3307.     COLOR 7, 0
3308.     DO: LOOP UNTIL INKEY$ = "" '                                                                        clear the keyboard buffer
3309.     END '                                                                                               end the program
3310.  
3311. END SUB
3312.  
3313.  

[TerryRitchie]

I've taken the clock demo code from above and added screen resizing to show how sprite zooming works in conjunction with it. If you resize the screen it will stay square and the clock continues to operate like nothing happens, only bigger or smaller depending on the resize.

Update: I smoothed the second hand out as well. It now uses all 360 degrees when spinning.

Code: QB64: [Select]

1. $RESIZE:ON
2.  
3. DIM handsheet AS INTEGER '      clock hand sprite sheet
4. DIM hour AS INTEGER '           hour hand sprite
5. DIM minute AS INTEGER '         minute hand sprite
6. DIM second AS INTEGER '         second hand sprite
7. DIM h AS INTEGER '              current hour value
8. DIM m AS INTEGER '              current minute value
9. DIM s AS INTEGER '              current second value
10. DIM currentscreen AS LONG '     current SL_SCREEN
11. DIM tempscreen AS LONG '        a temporary screen needed for resizing
12. DIM swidth AS INTEGER '         original width of screen
13. DIM sheight AS INTEGER '        original height of screen
14. DIM center AS INTEGER '         x and y center point of screen
15. DIM frame AS INTEGER '          frame counter
16. DIM olds AS INTEGER '           the previous second
17.  
18. swidth = 551 '                                                                                          set screen variables
19. sheight = 551
20. center = 276
21. SL_SCREEN swidth, sheight, 1 '                                                                          set window size and layers
22. _DELAY .1 '                                                                                             need to wait for _RESIZE below
23. tempscreen = _RESIZE '                                                                                  clear resize flag
24.  
25. _TITLE "Clock Demo" '                                                                                   give window a title
26. handsheet = SL_NEW_SHEET("hands73x533.png", 73, 533, SL_SET, _RGB32(255, 0, 255)) '                     load the clock hands
27. hour = SL_NEW_SPRITE(1, handsheet, 2, SL_HARDWARE, SL_NOSAVE) '                                         get the hour hand
28. minute = SL_NEW_SPRITE(1, handsheet, 1, SL_HARDWARE, SL_NOSAVE) '                                       get the minute hand
29. second = SL_NEW_SPRITE(1, handsheet, 3, SL_HARDWARE, SL_NOSAVE) '                                       get the second hand
30. _PUTIMAGE , _LOADIMAGE("face.png", 32) '                                                                display the clock face
31. SL_SET_FRAMERATE 6 '                                                                                    set the global frame rate
32. DO
33.     _LIMIT SL_GET_FRAMERATE '                                                                           maintain global frame rate
34.     h = VAL(TIME$) '                                                                                    get current hour value
35.     IF h > 11 THEN h = h - 12 '                                                                         keep a 12 hour clock
36.     m = VAL(MID$(TIME$, 4, 2)) '                                                                        get current minute value
37.     s = VAL(MID$(TIME$, 7, 2)) '                                                                        get current second value
38.     frame = frame + 1 '                                                                                 increment frame counter
39.     IF s <> olds THEN '                                                                                 new second?
40.         frame = 0 '                                                                                     yes, reset frame counter
41.         olds = s '                                                                                      remember this second value
42.     END IF
43.     SL_ROTATE_SPRITE hour, 30 * h + m \ 2 '                                                             rotate hour hand into position
44.     SL_ROTATE_SPRITE minute, 6 * m + s \ 10 '                                                           rotate minute hand into position
45.     SL_ROTATE_SPRITE second, 6 * s + frame '                                                                    rotate second hand into position
46.     SL_PUT_SPRITE center, center, hour '                                                                display the hour hand
47.     SL_PUT_SPRITE center, center, minute '                                                              display the minute hand
48.     SL_PUT_SPRITE center, center, second '                                                              display the second hand
49.     IF _RESIZE THEN '                                                                                   did user resize screen?
50.         currentscreen = _SOURCE '                                                                       yes, get the current screen pointer
51.         tempscreen = _COPYIMAGE(_SOURCE, 32) '                                                          make a copy of the current screen
52.         SCREEN tempscreen '                                                                             make the copy active
53.         _FREEIMAGE currentscreen '                                                                      free the old current screen
54.         SL_SCREEN _RESIZEWIDTH, _RESIZEWIDTH, 1 '                                                       create the new current screen (square _RESIZEWIDTH)
55.         _PUTIMAGE (0, 0)-(_WIDTH(_SOURCE) - 1, _HEIGHT(_SOURCE) - 1), _LOADIMAGE("face.png", 32) '      stretch the clock face onto it
56.         _FREEIMAGE tempscreen '                                                                         no longer need copy of old current screen
57.         SL_SET_ZOOM hour, _WIDTH(_SOURCE) / swidth * 100 '                                              zoom the sprites to match new dimensions
58.         SL_SET_ZOOM minute, _WIDTH(_SOURCE) / swidth * 100
59.         SL_SET_ZOOM second, _WIDTH(_SOURCE) / swidth * 100
60.         center = _WIDTH(_SOURCE) \ 2 '                                                                  new center point for clock hands
61.     END IF
62.     SL_DISPLAY '                                                                                        merge layers and display
63. LOOP UNTIL _KEYHIT '                                                                                    leave when key hit
64. SL_FREE_SPRITE hour '                                                                                   free sprites from memory
65. SL_FREE_SPRITE minute
66. SL_FREE_SPRITE second
67. END

[TempodiBasic]

Hi Terry
your clock demo is very fine
like you can see from the attachment file image...

it remember me the old fashion clock of the ancient time :-)

Waiting the evolution of your creature Sprite Library I'll take open eyes

[TerryRitchie]

It's been a while since I posted an update. I am still working on the new library. I have most of the pieces I want in place, it's now time to go through those pieces and optimize the code. I purchased a wide carriage dot matrix printer because the code is getting LONG. At last count I was over 4000 lines. To this end during the optimization I am keeping code to 132 characters per line to match the printer.

Some additions I made since the last update:
- SIN and COSINE tables are now precalculated and used to speed up math routines.
- Sprite rotation table saving/loading is now done with one GET and PUT statement speeding it up drastically.
- Took a page from Python and designed data types to use RECT (rectangular) structures for easier manipulation (TOP, LEFT, RIGHT, BOTTOM).
- The programmer now has the option to have the sprite rotation file built during a sprite sheet load or have sprites done individually as needed.
- Saving of _SOURCE and _DEST throughout the code is now performed using a FILO stack structure.

Here is the newly designed code I have completed so far. Much leaner and cleaner. Much, much more to come.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST SL_NOTRANSPARENCY = _RGB32(2, 4, 6) ' the chance of a sheet using this as a transparent color are 16 million to 1
4. CONST SL_WHITE = _RGB32(255, 255, 255)
5.  
6. CONST SL_FALSE = 0 '                    boolean truth test
7. CONST SL_TRUE = -1 '                    boolean truth test
8. CONST SL_PUSH = -1 '                    push _DEST and _SOURCE into stack
9. CONST SL_POP = 0 '                      pop _DEST and _SOURCE out of stack
10.  
11.  
12. TYPE SL_RECTANGLE '---------------- A RECTANGULAR STRUCTURE -----------------------------------------------------------------------
13.     left AS INTEGER '               the left x coordinate       *  This structure should ALWAYS be used to describe any           *
14.     right AS INTEGER '              the right x coordinate      *  rectangular object contained within the library. The screen,   *
15.     top AS INTEGER '                the top y coordinate        *  layers, sprites, and objects are examples of rectangular       *
16.     bottom AS INTEGER '             the bottom y coordinate     *  structures.                                                    *
17.     centerx AS INTEGER '            the center x coordinate     *                                                                 *
18.     centery AS INTEGER '            the center y coordinate     *                                                                 *
19.     width AS INTEGER '              the width of rectangle      *                                                                 *
20.     height AS INTEGER '             the height of rectangle     *                                                                 *
21. END TYPE '-------------------------------------------------------------------------------------------------------------------------
22.  
23. TYPE SL_COLLISION '---------------- COLLISION BOX STRUCTURE -----------------------------------------------------------------------
24.     collision AS SL_RECTANGLE '     collision box offsets
25. END TYPE '-------------------------------------------------------------------------------------------------------------------------
26.  
27. TYPE SL_RECT '--------------------- RECTANGULAR STRUCTURES ------------------------------------------------------------------------
28.     '                                                           *  -------------------------------------------------------------  *
29.     offset AS SL_RECTANGLE '        rectangular offset values   *  These should be considered STATIC values. Once they have been  *
30.     '                                                           *  set they should not be changed. These are used as offsets to   *
31.     '                                                           *  rectangular objects placed on the screen. TOP and LEFT will    *
32.     '                                                           *  ALWAYS be zero (0). RIGHT and BOTTOM will ALWAYS equal         *
33.     '                                                           *  WIDTH - 1 and HEIGHT - 1 respectively.                         *
34.     '                                                           *  WIDTH and HEIGHT respectively.                                 *
35.     '                                                           *  -------------------------------------------------------------  *
36.     '                                                           *  -------------------------------------------------------------  *
37.     screen AS SL_RECTANGLE '        rectangular screen values   *  These should be considered as DYNAMIC values. The values       *
38.     '                                                           *  contained here will be computed from the offsets above to      *
39.     '                                                           *  obtain screen coordinates. These will change every time an     *
40.     '                                                           *  object is moved based on the CENTERX and CENTERY values        *
41.     '                                                           *  passed in.                                                     *
42.     '                                                           *  -------------------------------------------------------------  *
43.     '                                                           *  -------------------------------------------------------------  *
44.     collision AS SL_RECTANGLE '     collision box offsets       *  These should be considered STATIC values. Once they have been  *
45.     '                                                           *  set they should not be changed. These are used as offsets to   *
46.     '                                                           *  rectangular object collision boxes within the sprite itself.   *
47.     '                                                           *  Add these offsets to 'screen' above to identify the collision  *
48.     '                                                           *  rectangular area within the sprite.                            *
49.     '                                                           *  -------------------------------------------------------------  *
50. END TYPE '-------------------------------------------------------------------------------------------------------------------------
51.  
52. TYPE SL_ANGLE '-------------------- PRECALCULATED SPRITE ROTATION ANGLE DATABASE --------------------------------------------------
53.     inuse AS _BYTE '                -1 if array index in use
54.     rect AS SL_COLLISION '          collision box offsets
55.     px0 AS INTEGER '                rotation coordinates
56.     px1 AS INTEGER '                (used by _MAPTRIANGLE)
57.     px2 AS INTEGER
58.     px3 AS INTEGER
59.     py0 AS INTEGER
60.     py1 AS INTEGER
61.     py2 AS INTEGER
62.     py3 AS INTEGER
63. END TYPE '-------------------------------------------------------------------------------------------------------------------------
64.  
65. TYPE SL_DEGREE '------------------- PRECALCULATED ROTATION DEGREE TABLE -----------------------------------------------------------
66.     sin AS SINGLE '                 rotating sprites
67.     cos AS SINGLE '                 rotating sprites
68.     sinmap AS SINGLE '              maptriangle rotation
69.     cosmap AS SINGLE '              maptriangle rotation
70. END TYPE '-------------------------------------------------------------------------------------------------------------------------
71.  
72. TYPE SL_SHEET '-------------------- SPRITE SHEET DATABASE -------------------------------------------------------------------------
73.     rect AS SL_COLLISION '          collision box offsets
74.     image AS LONG '                 default sprite image
75.     mask AS LONG '                  default sprite mask
76.     anglekey AS INTEGER '           pointer to SL_angle
77. END TYPE '-------------------------------------------------------------------------------------------------------------------------
78.  
79. TYPE SL_SPRITE
80.     rect AS SL_RECT '               rectangular structures
81.     zoom AS INTEGER
82. END TYPE
83.  
84. ' define arrays
85.  
86. REDIM SL_sheet(0, 0) AS SL_SHEET '      sprite sheet sprite database
87. REDIM SL_angle(1, 359) AS SL_ANGLE '    precalculated rotation table
88. DIM SL_degree(359) AS SL_DEGREE '       precalculated SIN/COS table
89.  
90.  
91. ' main code (for testing)
92.  
93. DIM sprite AS SL_SPRITE
94. DIM rect AS SL_RECTANGLE
95. DIM dkong AS INTEGER
96.  
97. SL_START '                                                                  initialize library
98. dkong = SL_LOAD_SHEET("dkong.png", 64, 64, _RGB32(255, 0, 255), SL_TRUE) '  load a sprite sheet
99. SCREEN _NEWIMAGE(640, 480, 32) '                                            set up a screen
100. _PUTIMAGE (100, 100), SL_sheet(dkong, 1).image '                            make sure SL_SHEET is getting images
101. LINE (SL_sheet(dkong, 1).rect.collision.left + 100, SL_sheet(dkong, 1).rect.collision.top + 100)-_
102.      (SL_sheet(dkong, 1).rect.collision.right + 100, SL_sheet(dkong, 1).rect.collision.bottom + 100),_
103.      _RGB32(255, 255, 255), B '                                             draw the collision box
104. END
105.  
106.  
107. '----------------------------------------------------------------------------------------------------------------------------------
108. SUB SL_START ()
109.     '------------------------------------------------------------------------------------------------------------------------------
110.  
111.     SHARED SL_degree() AS SL_DEGREE '   precalculated SIN/COS table
112.     DIM degree AS INTEGER '             degree counter
113.  
114.     ' precalculate SIN/COS values and place in table
115.  
116.     DO '                                                                                    cycle 0 to 359 degrees
117.         SL_degree(degree).sin = SIN(degree * .017453292) '                                  SIN of angle
118.         SL_degree(degree).cos = -COS(degree * .017453292) '                                 COS of angle
119.         'SL_degree(degree).sinmap = SIN(-degree / 57.2957795131) '                           MAPTRIANGLE SIN of angle
120.         'SL_degree(degree).cosmap = COS(-degree / 57.2957795131) '                           MAPTRIANGLE COS of angle
121.         SL_degree(degree).sinmap = SIN(-degree * .017453292) '                              MAPTRIANGLE SIN of angle
122.         SL_degree(degree).cosmap = COS(-degree * .017453292) '                              MAPTRIANGLE COS of angle
123.         degree = degree + 1 '                                                               increment degree counter
124.     LOOP UNTIL degree = 360 '                                                               leave when all degrees calculated
125.  
126. END SUB
127.  
128. '----------------------------------------------------------------------------------------------------------------------------------
129. FUNCTION SL_LOAD_SHEET (filename AS STRING, swidth AS INTEGER, sheight AS INTEGER, colour AS _UNSIGNED LONG, rotate AS INTEGER)
130.     '------------------------------------------------------------------------------------------------------------------------------
131.  
132.     SHARED SL_sheet() AS SL_SHEET '     master sheet array
133.     SHARED SL_angle() AS SL_ANGLE '     precalculated rotation angle array
134.     REDIM SL_temp(0, 0) AS SL_ANGLE '   temporary rotation angle array
135.     DIM clearcolor AS _UNSIGNED LONG '  transparency color of sprite sheet
136.     DIM bounds AS SL_RECTANGLE '        rectangle boundaries
137.     DIM transparent AS INTEGER '        -1 (TRUE) if sprite sheet contains transparency
138.     DIM celltotal AS INTEGER '          total number of cells on sheet
139.     DIM colcount AS INTEGER '           column counter
140.     DIM rowcount AS INTEGER '           row counter
141.     DIM anglekey AS INTEGER '           key index pointer to angle array
142.     DIM filenum AS INTEGER '            the next free file handle
143.     DIM preload AS INTEGER '            -1 (SL_TRUE) if rotation data file was loaded
144.     DIM columns AS INTEGER '            number of columns on sheet
145.     DIM rows AS INTEGER '               number of rows on sheet
146.     DIM handle AS INTEGER '             next available sheet handle pointer
147.     DIM rotfile AS STRING '             rotation data file name
148.     DIM degree AS INTEGER '             degree counter
149.     DIM cell AS INTEGER '               number of cells currently assigned in SL_sheet, and a cell counter
150.     DIM sheet AS LONG '                 sheet image
151.  
152.     ' load sheet, determine rows / columns / cells, create an index in sheet array
153.  
154.     sheet = _LOADIMAGE(filename, 32) '                                                      load sprite sheet
155.     columns = _WIDTH(sheet) \ swidth: rows = _HEIGHT(sheet) \ sheight '                     calculate number of columns and rows
156.     celltotal = rows * columns '                                                            calculate number of cells
157.     cell = UBOUND(SL_sheet, 2) '                                                            current number of cells in sheet array
158.     IF celltotal > cell THEN cell = celltotal '                                             increase cells in sheet array
159.     handle = UBOUND(SL_sheet) + 1 '                                                         get new sheet's handle pointer value
160.     REDIM _PRESERVE SL_sheet(handle, cell) AS SL_SHEET '                                    create a new sheet entry in array
161.  
162.     ' load rotation data file if it exists
163.  
164.     IF rotate THEN '                                                                        precalculate rotations?
165.         rotfile = LEFT$(filename, INSTR(filename, ".")) + "rot" '                           yes, create name of rotation file
166.         filenum = FREEFILE '                                                                get next free file handle
167.         REDIM SL_temp(celltotal, 359) AS SL_ANGLE '                                         increase array size to match sheet size
168.         IF _FILEEXISTS(rotfile) THEN '                                                      does the rotation file exist?
169.             OPEN rotfile FOR BINARY AS #filenum '                                           open the rotation file
170.             GET #filenum, , SL_temp() '                                                     get the rotation data
171.             CLOSE #filenum '                                                                close the file
172.             anglekey = UBOUND(SL_angle) + 1 '                                               beginning index in array
173.             REDIM _PRESERVE SL_angle(UBOUND(SL_angle) + UBOUND(sl_temp), 359) AS SL_ANGLE ' increase angle array to hold ne data
174.             preload = SL_TRUE '                                                             remember that is has been loaded
175.         END IF
176.     END IF
177.  
178.     ' get or apply transparency to the sprite sheet
179.  
180.     IF colour <> SL_NOTRANSPARENCY THEN '                                                   use transparency?
181.         transparent = SL_GetTransparentColor(sheet, clearcolor) '                           yes, get transparent layer of image
182.         IF NOT transparent THEN '                                                           was a transparent color found?
183.             _CLEARCOLOR colour, sheet '                                                     no, apply the supplied color
184.             clearcolor = _CLEARCOLOR(sheet) '                                               get the transparent value from sheet
185.             transparent = SL_TRUE '                                                         sheet now contains transparency
186.         END IF
187.     END IF
188.  
189.     ' cycle through the sheet and create related data
190.  
191.     DO '                                                                                    cycle through sheet's columns
192.         colcount = colcount + 1 '                                                           increment column counter
193.         rowcount = 0 '                                                                      reset row counter
194.         DO '                                                                                cycle through sheet's rows
195.  
196.             ' get image from sheet and place in array
197.  
198.             rowcount = rowcount + 1 '                                                       increment row counter
199.             cell = (rowcount - 1) * columns + colcount '                                    calculate current sprite's cell number
200.             SL_sheet(handle, cell).image = _NEWIMAGE(swidth, sheight, 32) '                 create sprite image holder
201.             bounds.left = (colcount - 1) * swidth '                                         calculate left x sprite location
202.             bounds.top = (rowcount - 1) * sheight '                                         calculate top y sprite location
203.             bounds.right = bounds.left + swidth - 1 '                                       calculate right x sprite location
204.             bounds.bottom = bounds.top + sheight - 1 '                                      calculate bottom y sprite location
205.             _PUTIMAGE , sheet, SL_sheet(handle, cell).image, (bounds.left, bounds.top)-_
206.                                                              (bounds.right, bounds.bottom) 'get image from sheet
207.  
208.             ' create image mask and determine collision boundaries if necessary
209.  
210.             IF transparent THEN '                                                           sprite contain transparent color?
211.                 SL_sheet(handle, cell).mask = _NEWIMAGE(swidth, sheight, 32) '              yes, create sprite mask image
212.                 bounds.left = swidth - 1
213.                 bounds.top = sheight - 1
214.                 bounds.right = 0
215.                 bounds.left = 0
216.                 bounds.width = swidth
217.                 bounds.height = sheight
218.                 SL_GetBounds SL_sheet(handle, cell).image, SL_sheet(handle, cell).mask, clearcolor, bounds ' get collision bounds
219.                 '                                                                           collide with boundaries only
220.                 SL_sheet(handle, cell).rect.collision.left = bounds.left '                  * ----------------------------
221.                 SL_sheet(handle, cell).rect.collision.top = bounds.top '                    *
222.                 SL_sheet(handle, cell).rect.collision.right = bounds.right '                *
223.                 SL_sheet(handle, cell).rect.collision.bottom = bounds.bottom '              * NOTE: These are OFFSETS
224.                 SL_sheet(handle, cell).rect.collision.width = bounds.right - bounds.left '  *       NOT actual coordinates
225.                 SL_sheet(handle, cell).rect.collision.height = bounds.bottom - bounds.top ' *
226.                 SL_sheet(handle, cell).rect.collision.centerx = bounds.left + (bounds.right - bounds.left) / 2 '*
227.                 SL_sheet(handle, cell).rect.collision.centery = bounds.top + (bounds.bottom - bounds.top) / 2 ' * --------
228.             ELSE '                                                                          collide with entire sprite
229.                 SL_sheet(handle, cell).rect.collision.left = 0 '                            * ----------------------------
230.                 SL_sheet(handle, cell).rect.collision.top = 0 '                             *
231.                 SL_sheet(handle, cell).rect.collision.right = swidth - 1 '                  *
232.                 SL_sheet(handle, cell).rect.collision.bottom = sheight - 1 '                * NOTE: These are OFFSETS
233.                 SL_sheet(handle, cell).rect.collision.width = swidth '                      *       NOT actual coordinates
234.                 SL_sheet(handle, cell).rect.collision.height = sheight '                    *
235.                 SL_sheet(handle, cell).rect.collision.centerx = bounds.left + swidth / 2 '  *
236.                 SL_sheet(handle, cell).rect.collision.centery = bounds.top + sheight / 2 '  * ----------------------------
237.             END IF
238.  
239.             ' create / insert precalculated rotation data
240.  
241.             IF rotate THEN '                                                                precalculate rotation data?
242.                 IF preload THEN '                                                           yes, has it already been loaded?
243.                     degree = 0 '                                                            reset degree counter
244.                     DO '                                                                    cycle through 360 degrees
245.                         SL_angle(anglekey, degree) = SL_temp(cell, degree) '                insert loaded information into array
246.                         degree = degree + 1 '                                               increment degree counter
247.                     LOOP UNTIL degree = 360 '                                               leave when all degrees processed
248.                     SL_sheet(handle, cell).anglekey = anglekey '                            record the array index key
249.                     anglekey = anglekey + 1 '                                               increment array index key
250.                 ELSE '                                                                      no file was preloaded
251.                     SL_sheet(handle, cell).anglekey = SL_RotationPrecalc(handle, cell, clearcolor) 'calculate rotation information
252.                     degree = 0 '                                                            reset degree counter
253.                     DO '                                                                    cycle through 360 degrees
254.                         SL_temp(cell, degree) = SL_angle(anglekey, degree) '                save the rotation data to temp array
255.                         degree = degree + 1 '                                               increment degree counter
256.                     LOOP UNTIL degree = 360 '                                               leave when all degrees processed
257.                 END IF
258.             END IF
259.         LOOP UNTIL rowcount = rows '                                                        leave when all rows checked
260.     LOOP UNTIL colcount = columns '                                                         leave when all columns checked
261.  
262.     ' save precalculated rotation data to a file
263.  
264.     IF rotate AND (NOT preload) THEN '                                                      rotation data need saved?
265.         OPEN rotfile FOR BINARY AS #filenum '                                               yes, open the file
266.         PUT #filenum, , SL_temp() '                                                         write the rotation data
267.         CLOSE #filenum '                                                                    close the file
268.         REDIM SL_temp(0, 0) AS SL_ANGLE '                                                   clear temporary array
269.     END IF
270.     _FREEIMAGE sheet '                                                                      remove sprite sheet image from memory
271.     SL_LOAD_SHEET = handle '                                                                return handle pointing to this sheet
272.  
273. END FUNCTION
274.  
275. '----------------------------------------------------------------------------------------------------------------------------------
276. FUNCTION SL_RotationPrecalc (sheet AS INTEGER, cell AS INTEGER, clearcolor AS _UNSIGNED LONG)
277.     '------------------------------------------------------------------------------------------------------------------------------
278.  
279.     SHARED SL_sheet() AS SL_SHEET '     master sprite sheet array
280.     SHARED SL_angle() AS SL_ANGLE '     master sprite angle array
281.     SHARED SL_degree() AS SL_DEGREE '   precalculated SIN/COS table
282.     DIM bounds AS SL_RECTANGLE '        rectangle boundries
283.     DIM rotatedsprite AS LONG '         rotated sprite image
284.     DIM anglekey AS INTEGER '           angle array index pointer
285.     DIM swidth AS INTEGER '             width of sprite
286.     DIM sheight AS INTEGER '            height of sprite
287.     DIM xoffset AS INTEGER '            used to center sprite on rotated image
288.     DIM yoffset AS INTEGER
289.     DIM degree AS INTEGER '             degree counter
290.     DIM polar AS INTEGER '              polar coordinate counter
291.     DIM px(3) AS SINGLE '               _MAPTRIANGLE coordinates
292.     DIM py(3) AS SINGLE
293.     DIM sinr AS SINGLE, cosr AS SINGLE 'coordinate rotation calculations
294.     DIM x2 AS SINGLE, y2 AS SINGLE '    rotated polar coordinate positions
295.     DIM px0 AS SINGLE, px1 AS SINGLE '  polar coordinates
296.     DIM px2 AS SINGLE, px3 AS SINGLE
297.     DIM py0 AS SINGLE, py1 AS SINGLE
298.     DIM py2 AS SINGLE, py3 AS SINGLE
299.  
300.     DO '                                                                                    cycle through angle array
301.         anglekey = anglekey + 1 '                                                           increment index key pointer
302.     LOOP UNTIL (SL_angle(anglekey, 0).inuse = SL_FALSE) OR (anglekey = UBOUND(SL_angle)) '  leave when available index found
303.     IF SL_angle(anglekey, 0).inuse = SL_TRUE THEN '                                         is there no available index?
304.         anglekey = anglekey + 1 '                                                           yes, increment index key pointer
305.         REDIM _PRESERVE SL_angle(anglekey, 359) AS SL_ANGLE '                               increase size of angle array by one
306.     END IF
307.     SL_angle(anglekey, 0).inuse = SL_TRUE '                                                 mark this array index as in use
308.     swidth = _WIDTH(SL_sheet(sheet, cell).image) '                                          get width of sprite image
309.     sheight = _HEIGHT(SL_sheet(sheet, cell).image) '                                        get height of sprite image
310.  
311.     ' calculate _MAPTRIANGLE rotated coordinates
312.  
313.     DO
314.         px(0) = -swidth / 2: py(0) = -sheight / 2: px(1) = px(0): py(1) = sheight / 2 '     specifiy _MAPTRIANGLE coordinates
315.         px(2) = swidth / 2: py(2) = py(1): px(3) = px(2): py(3) = py(0)
316.         sinr = SL_degree(degree).sinmap '                                                   get coordinate rotation angles
317.         cosr = SL_degree(degree).cosmap '                                                   from precalculated COS/SIN table
318.         bounds.left = 0: bounds.top = 0: bounds.right = 0: bounds.bottom = 0: polar = 0 '   set initial boundary markers
319.         DO '                                                                                cycle through polar coordinates
320.             x2 = (px(polar) * cosr + sinr * py(polar)) '                                    compute new polar coordinate location
321.             y2 = (py(polar) * cosr - px(polar) * sinr) '                                    compute new polar coordinate location
322.             px(polar) = x2 '                                                                save the new polar coordinate
323.             py(polar) = y2 '                                                                save the new polar coordinate
324.             IF px(polar) < bounds.left THEN bounds.left = px(polar) '                       get left x value
325.             IF px(polar) > bounds.right THEN bounds.right = px(polar) '                     get right x value
326.             IF py(polar) < bounds.top THEN bounds.top = py(polar) '                         get top y value
327.             IF py(polar) > bounds.bottom THEN bounds.bottom = py(polar) '                   get bottom y value
328.             polar = polar + 1 '                                                             increment counter
329.         LOOP UNTIL polar = 4 '                                                              leave when all coordinates calculated
330.         bounds.width = bounds.right - bounds.left + 1 '                                     calculate rotated width
331.         bounds.height = bounds.bottom - bounds.top + 1 '                                    calculate rotated height
332.         xoffset = bounds.width \ 2 '                                                        calculate x offset
333.         yoffset = bounds.height \ 2 '                                                       calculate y offset
334.         px0 = px(0) + xoffset: px1 = px(1) + xoffset '                                      add offsets to rotated sprite
335.         px2 = px(2) + xoffset: px3 = px(3) + xoffset '                                      to center sprite onto the rotated
336.         py0 = py(0) + yoffset: py1 = py(1) + yoffset '                                      image
337.         py2 = py(2) + yoffset: py3 = py(3) + yoffset
338.         rotatedsprite = _NEWIMAGE(bounds.width, bounds.height, 32) '                        create rotated sprite image holder
339.  
340.         ' map image onto rotated sprite
341.  
342.         _MAPTRIANGLE (0, 0)-(0, sheight - 1)-(swidth - 1, sheight - 1), SL_sheet(sheet, cell).image_
343.                      TO(px0, py0)-(px1, py1)-(px2, py2), rotatedsprite
344.         _MAPTRIANGLE (0, 0)-(swidth - 1, 0)-(swidth - 1, sheight - 1), SL_sheet(sheet, cell).image_
345.                      TO(px0, py0)-(px3, py3)-(px2, py2), rotatedsprite
346.  
347.         ' get rotated collision boundaries
348.  
349.         bounds.left = bounds.width - 1: bounds.top = bounds.height - 1 '                    set intitial boundary markers
350.         bounds.right = 0: bounds.bottom = 0
351.         SL_GetBounds rotatedsprite, 0, clearcolor, bounds '                                 get collision boundaries
352.         SL_angle(anglekey, degree).rect.collision.left = bounds.left '                      * ----------------------------
353.         SL_angle(anglekey, degree).rect.collision.top = bounds.top '                        *
354.         SL_angle(anglekey, degree).rect.collision.right = bounds.right '                    *
355.         SL_angle(anglekey, degree).rect.collision.bottom = bounds.bottom '                  * NOTE: These are OFFSETS
356.         SL_angle(anglekey, degree).rect.collision.width = bounds.right - bounds.left '      *       NOT actual coordinates
357.         SL_angle(anglekey, degree).rect.collision.height = bounds.bottom - bounds.top '     *
358.         SL_angle(anglekey, degree).rect.collision.centerx = bounds.left + (bounds.right - bounds.left) / 2 '*
359.         SL_angle(anglekey, degree).rect.collision.centery = bounds.top + (bounds.bottom - bounds.top) / 2 ' * -------------
360.         SL_angle(anglekey, degree).px0 = px0 '                                              save _MAPTRIANGLE coordinates
361.         SL_angle(anglekey, degree).px1 = px1
362.         SL_angle(anglekey, degree).px2 = px2
363.         SL_angle(anglekey, degree).px3 = px3
364.         SL_angle(anglekey, degree).py0 = py0
365.         SL_angle(anglekey, degree).py1 = py1
366.         SL_angle(anglekey, degree).py2 = py2
367.         SL_angle(anglekey, degree).py3 = py3
368.         degree = degree + 1 '                                                               increment degree counter
369.     LOOP UNTIL degree = 360 '                                                               leave when all degrees processed
370.     SL_RotationPrecalc = anglekey '                                                         return array index pointer
371.  
372. END FUNCTION
373.  
374. '----------------------------------------------------------------------------------------------------------------------------------
375. FUNCTION SL_GetTransparentColor (image AS LONG, clearcolor AS _UNSIGNED LONG)
376.     '------------------------------------------------------------------------------------------------------------------------------
377.  
378.     ' usage  : exists = SL_GetTransparentColor(image, clearcolor)
379.     '
380.     ' returns: exists     =  0 (SL_FALSE) if no transparent color found, -1 (SL_TRUE) if a transparent color found
381.     '          clearcolor =  unchanged if no transparent color found or the transparent color if one is found
382.  
383.     DIM pixel AS _UNSIGNED LONG '       color of pixel
384.     DIM x AS INTEGER, y AS INTEGER '    column and row counters
385.     DIM tempimage AS LONG '             temporary image used to identify transparent color
386.  
387.     SL_DestSource SL_PUSH '                                                                 save current _DEST and _SOURCE
388.     _SOURCE image '                                                                         read from image
389.     DO '                                                                                    cycle through image
390.         pixel = POINT(x, y) '                                                               get the next pixel
391.         IF _ALPHA32(pixel) = 0 THEN '                                                       is it transparent?
392.             tempimage = _NEWIMAGE(1, 1, 32) '                                               yes, create a temp image
393.             _CLEARCOLOR pixel, tempimage '                                                  apply the transparent value to it
394.             clearcolor = _CLEARCOLOR(tempimage) '                                           get transparent value from temp image
395.             _FREEIMAGE tempimage '                                                          remove temp image from memory
396.             EXIT DO '                                                                       leave the loop, no reason to continue
397.         END IF
398.         x = x + 1 '                                                                         move to the next column
399.         IF x > _WIDTH(image) THEN x = 0: y = y + 1 '                                        move to the next row if necessary
400.     LOOP UNTIL y > _HEIGHT(image) '                                                         leave when entire sheet checked
401.     IF _ALPHA32(pixel) = 0 THEN SL_GetTransparentColor = SL_TRUE '                          return -1 if transparent color found
402.     SL_DestSource SL_POP '                                                                  restore previous _DEST and _SOURCE
403.  
404. END FUNCTION
405.  
406. '----------------------------------------------------------------------------------------------------------------------------------
407. SUB SL_GetBounds (image AS LONG, mask AS LONG, clearcolor AS _UNSIGNED LONG, bounds AS SL_RECTANGLE)
408.     '------------------------------------------------------------------------------------------------------------------------------
409.  
410.     ' NOTE: bounds will be modified with new boundary coordinates
411.  
412.     DIM x AS INTEGER, y AS INTEGER '    column and row counters
413.  
414.     SL_DestSource SL_PUSH '                                                                 save current _DEST and _SOURCE
415.     _SOURCE image '                                                                         read from image
416.     IF mask THEN _DEST mask '                                                               write to mask if present
417.     DO '                                                                                    cycle through columns
418.         y = 0 '                                                                             reset row counter
419.         DO '                                                                                cycle through rows
420.             IF POINT(x, y) <> clearcolor THEN '                                             is this pixel transparent?
421.                 IF x < bounds.left THEN bounds.left = x '                                   no, set left-most image pixel seen
422.                 IF y < bounds.top THEN bounds.top = y '                                     set top-most image pixel seen
423.                 IF x > bounds.right THEN bounds.right = x '                                 set right-most image pixel seen
424.                 IF y > bounds.bottom THEN bounds.bottom = y '                               set bottom-most image pixel seen
425.             ELSE '                                                                          yes, this is a transparent pixel
426.                 IF mask THEN PSET (x, y), SL_WHITE '                                        draw as white on the image mask
427.             END IF
428.             y = y + 1 '                                                                     increment row counter
429.         LOOP UNTIL y = bounds.height '                                                      leave when all rows scanned
430.         x = x + 1 '                                                                         increment column counter
431.     LOOP UNTIL x = bounds.width '                                                           leave when all columns scanned
432.     SL_DestSource SL_POP '                                                                  restore previous _DEST and _SOURCE
433.  
434. END SUB
435.  
436. '----------------------------------------------------------------------------------------------------------------------------------
437. SUB SL_DestSource (action AS INTEGER)
438.     '------------------------------------------------------------------------------------------------------------------------------
439.  
440.     ' creates a FILO (First In Last Out) stack for storing source and destination values
441.  
442.     STATIC stack(0) AS LONG '           FILO stack (values retained between calls)
443.  
444.     SELECT CASE action '                                                                    push or pop stack?
445.         CASE SL_PUSH '                                                                      pushing
446.             REDIM _PRESERVE stack(UBOUND(stack) + 2) AS LONG '                              increase stack size
447.             stack(UBOUND(stack) - 1) = _SOURCE '                                            save current source
448.             stack(UBOUND(stack)) = _DEST '                                                  save current destination
449.         CASE SL_POP '                                                                       popping in reverse order
450.             _DEST stack(UBOUND(stack)) '                                                    restore destination
451.             _SOURCE stack(UBOUND(stack) - 1) '                                              restore source
452.             REDIM _PRESERVE stack(UBOUND(stack) - 2) AS LONG '                              decrease stack size
453.     END SELECT
454.  
455. END SUB
456.  
457.  
458.  
459.  
460.  
461.  
462.  
463.  
464. ' subs and functions below ideas for now
465.  
466.  
467. SUB SL_ComputeRectScreen (rect AS SL_RECT, centerx AS INTEGER, centery AS INTEGER)
468.  
469.     ' Calculates a RECT structures onscreen values using offset values
470.     ' CENTERX and CENTERY always assumed to be the only values used
471.     ' Any RECT structure supplied will be MODIFIED and sent back
472.  
473.     rect.screen.left = centerx - rect.offset.centerx
474.     rect.screen.right = rect.screen.left + rect.offset.width
475.     rect.screen.top = centery - rect.offset.centery
476.     rect.screen.bottom = rect.screen.top + rect.offset.height
477.     rect.screen.width = rect.screen.right - rect.screen.left
478.     rect.screen.height = rect.screen.bottom - rect.screen.top
479.     rect.screen.centerx = centerx
480.     rect.screen.centery = centery
481.  
482. END SUB
483.  
484.  
485. SUB SL_ComputeRectOffset (rect AS SL_RECTANGLE)
486.  
487.     ' Calculates a RECT structure's offset values
488.     ' LEFT and TOP always assumed to be zero (0)
489.     ' Any RECT structure supplied will be MODIFIED and sent back
490.  
491.     IF rect.left + rect.top THEN BEEP: END '                        left and top must be zero
492.  
493.     IF rect.width THEN '                                            if width is supplied
494.         rect.right = rect.width '                                   then calculate right
495.         rect.centerx = rect.width / 2 '                             and center x
496.     ELSEIF rect.centerx THEN '                                      if center x is supplied
497.         rect.right = rect.centerx * 2 '                             then calculate right
498.         rect.width = rect.right '                                   and width
499.     ELSE '                                                          if right and left supplied
500.         rect.width = rect.right '                                   then calculate width
501.         rect.centerx = rect.width / 2 '                             and center x
502.     END IF
503.  
504.     IF rect.height THEN '                                           if height is supplied
505.         rect.bottom = rect.height '                                 then calculate bottom
506.         rect.centery = rect.height / 2 '                            and center y
507.     ELSEIF rect.centery THEN '                                      if center y is suplied
508.         rect.bottom = rect.centery * 2 '                            then calculate bottom
509.         rect.height = rect.bottom '                                 and height
510.     ELSE '                                                          if top and bottom supplied
511.         rect.height = rect.bottom '                                 then calculate height
512.         rect.centery = rect.height / 2 '                            and center y
513.     END IF
514.  
515. END SUB
516.  

[TerryRitchie]

Just an update to state I'm still working on the library. Here is the current state of the code:

Code: QB64: [Select]

1. '
2. ' Sprite Library v2.0
3. ' Terry Ritchie
4. ' QuickBASIC64@gmail.com
5. '
6.  
7. OPTION _EXPLICIT '                  NOTE: Remove before publishing library
8.  
9. '                                                                                            _____________________________________
10. CONST SLFALSE = 0 '                 logical false (0)                                       | Constants are used throughout the   |
11. CONST SLTRUE = NOT SLFALSE '        logical true (-1)                                       | library code. Changing, deleting,   |
12. CONST SLNONE = 0 '                  used to null a setting                                  | or altering CONSTant values will    |
13. CONST SLFORWARD = 1 '               used for animation cell direction                       | result in errors.                   |
14. CONST SLBACKWARD = 2 '              used for animation cell direction                       |                                     |
15. CONST SLBACKFORTH = 3 '             used for animation cell direction                       |                                     |
16. CONST SLRECTANGLE = 1 '             used for collision detection method                     |                                     |
17. CONST SLCIRCLE = 2 '                used for collision detection method                     |                                     |
18. CONST SLPIXEL = 3 '                 used for collision detection method                     |                                     |
19. CONST SLHORIZONTAL = 1 '            used for object flipping                                |                                     |
20. CONST SLVERTICAL = 2 '              used for object flipping                                |                                     |
21. CONST SLBOTH = 3 '                  used for object flipping                                |                                     |
22. CONST SLNOTRANSPARENCY = 1 '        used to disable sheet/sprite transparency               |                                     |
23. CONST SLLEFTCLICK = 1
24. CONST SLRIGHTCLICK = 2
25. CONST SLMIDDLECLICK = 3
26. CONST SLHOVER = 4
27. CONST SLWHEELUP = 5
28. CONST SLWHEELDOWN = 6
29. CONST SLZOOM = -32767
30. CONST SLFLIP = -32766
31. CONST SLVISIBLE = -32765
32. CONST SLLAYER = -32764
33. CONST SLSCORE = -32763
34. CONST SLAUTOANIMATE = -32762
35. CONST SLFROMCELL = -32761
36. CONST SLTOCELL = -32760
37. CONST SLANIMATEDIR = -32759
38. CONST SLFRAMERATE = -32758
39. CONST SLAUTOMOTION = -32757
40. CONST SLMOTIONANGLE = -32756
41. CONST SLXDIR = -32755
42. CONST SLYDIR = -32754
43. CONST SLAUTOROTATE = -32753
44. CONST SLROTATEANGLE = -32752
45. CONST SLROTATESPEED = -32751
46. CONST SLDETECTION = -32750
47. CONST SLLEFT = -32749
48. CONST SLTOP = -32748
49. CONST SLRIGHT = -32747
50. CONST SLBOTTOM = -32746
51. CONST SLWIDTH = -32745
52. CONST SLHEIGHT = -32744
53. CONST SLCENTERX = -32743
54. CONST SLCENTERY = -32742
55. CONST SLCOLLISION = -32741
56. CONST SLCOLLIDEWITH = -32740
57. CONST SLCOLLIDEX = -32739
58. CONST SLCOLLIDEY = -32738
59. CONST SLMOUSE = -32737
60. CONST SLMOUSEX = -32736
61. CONST SLMOUSEY = -32735
62. CONST SLSPRITEMOUSEX = -32734
63. CONST SLSPRITEMOUSEY = -32733
64. '                                                                                            ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
65.  
66. TYPE SLRECT '---------------------- RECTANGULAR STRUCTURE ---------------------------------  _____________________________________
67.     Width AS INTEGER '              width  of rectangular object                            | This structure should ALWAYS be     |
68.     Height AS INTEGER '             height of rectangular object                            | used to describe any rectangular    |
69.     Left AS INTEGER '               left x coordinate   (or offset) of rectangular object   | object used within the library.     |
70.     Top AS INTEGER '                top y coordinate    (or offset) of rectangular object   | Items such as layers, main screen,  |
71.     Right AS INTEGER '              right x coordinate  (or offset) of rectangular object   | sprites, and collision areas are    |
72.     Bottom AS INTEGER '             bottom y coordinate (or offset) of rectangular object   | examples of rectangular structures. |
73. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
74.  
75. TYPE SLANIMATION '----------------- OBJECT ANIMATION SETTINGS -----------------------------  _____________________________________
76.     Auto AS _BYTE '                 auto animation (SLTRUE / SLFALSE)                       | Notes                               |
77.     Cell AS INTEGER '               current animation cell                                  |                                     |
78.     FromCell AS INTEGER '           animation start cell number                             |                                     |
79.     ToCell AS INTEGER '             animation end cell number                               |                                     |
80.     FrameRate AS INTEGER '          animation independent frame rate                        |                                     |
81.     Direction AS _BYTE '            animation direction (1 to 3)                            |                                     |
82. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
83.  
84. TYPE SLMOTION '-------------------- OBJECT MOTION SETTINGS --------------------------------  _____________________________________
85.     Auto AS _BYTE '                 auto motion (SLTRUE / SLFALSE)                          | Notes                               |
86.     Degree AS INTEGER '             angle direction of motion (-359 to 359)                 |                                     |
87.     Xdir AS INTEGER '               x motion vector                                         |                                     |
88.     Ydir AS INTEGER '               y motion vector                                         |                                     |
89. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
90.  
91. TYPE SLROTATION '------------------ OBJECT ROTATION SETTINGS ------------------------------  _____________________________________
92.     Auto AS _BYTE '                 auto rotation (SLTRUE / SLFALSE)                        | Notes                               |
93.     Rotates AS _BYTE '              rotation enabled/disabled for sprite (SLTRUE / SLFALSE) |                                     |
94.     Degree AS INTEGER '             angle of rotation (0 to 359)                            |                                     |
95.     Rate AS INTEGER '               rotation spin rate (speed)                              |                                     |
96.     key AS INTEGER '                index key to map and rotation arrays                    |                                     |
97. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
98.  
99. TYPE SLCOLLISIONS '---------------- OBJECT COLLISION SETTINGS -----------------------------  _____________________________________
100.     Detect AS _BYTE '               collision detection method (0 to 3)                     | Notes                               |
101.     Event AS _BYTE '                collision occurance (SLTRUE / SLFALSE)                  |                                     |
102.     With AS INTEGER '               the object collision happend with                       |                                     |
103.     Xloc AS INTEGER '               x location of collision (pixel)                         |                                     |
104.     Yloc AS INTEGER '               y location of collision (pixel)                         |                                     |
105.     Mask AS LONG '                  sprite mask image for pixel detection                   |                                     |
106. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
107.  
108. TYPE SLMOUSES '-------------------- MOUSE INTERACTION SETTINGS ----------------------------  _____________________________________
109.     Event AS _BYTE '                most recent mouse event                                 | Notes                               |
110.     Xloc AS INTEGER '               x coordinate location of mouse on object                |                                     |
111.     Yloc AS INTEGER '               y coordinate location of mouse on object                |                                     |
112.     SXloc AS INTEGER '              x coordinate of mouse on screen in relation to object   |                                     |
113.     SYloc AS INTEGER '              y coordinate of mouse on screen in relation to object   |                                     |
114. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
115.  
116. TYPE SLSHEET '--------------------- SPRITE SHEET SETTINGS ---------------------------------  _____________________________________
117.     InUse AS _BYTE '                array index in use (SLTRUE / SLFASLE)                   | Notes                               |
118.     Image AS LONG '                 sprite sheet image                                      |                                     |
119.     ClearColor AS _UNSIGNED LONG '  transparent color of sheet                              |                                     |
120.     CellWidth AS INTEGER '          width of each sprite cell                               |                                     |
121.     CellHeight AS INTEGER '         height of each sprite cell                              |                                     |
122.     Columns AS INTEGER '            number of cell columns                                  |                                     |
123.     Rows AS INTEGER '               number of cell rows                                     |                                     |
124.     TotalCells AS INTEGER '         total number of cells on sheet                          |                                     |
125. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
126.  
127. TYPE SLSPRITE '-------------------- SPRITE SETTINGS ---------------------------------------
128.     '                                                                                        _____________________________________
129.     OrigSheet AS INTEGER '          original sprite sheet location                          | These values are to be considered   |
130.     OrigCell AS INTEGER '           original sprite sheet cell location                     | STATIC in nature. Once they are set |
131.     OrigImage AS LONG '             original sprite image                                   | they should never be changed.       |
132.     OrigMask AS LONG '              original sprite mask image                              |                                     |
133.     OrigWidth AS INTEGER '          original sprite width                                   |                                     |
134.     OrigHeight AS INTEGER '         original sprite height                                  |                                     |
135.     '                                                                                        ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
136.     OrigColl AS SLRECT '            original NON_ROTATED sprite collision area coordinates
137.     '  _________________________________________________________________________________     _____________________________________
138.     ' | .Width  - original collision area width                                         |   | These values are to be considered   |
139.     ' | .Height - original collision area height                                        |   | STATIC in nature. Once they are set |
140.     ' | .Left   - original collision area left   x offset (from screen left x)          |   | they should never be changed. These |
141.     ' | .Top    - original collision area top    y offset (from screen top  y)          |   | values are used to calculate the    |
142.     ' | .Right  - original collision area right  x offset (from screen left x)          |   | on-screen sprite collision area     |
143.     ' | .Bottom - original collision area bottom y offset (from screen top  y)          |   | coordinates.                        |
144.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
145.     ScrnImage AS LONG '             on-screen sprite software image
146.     ScrnHardware AS LONG '          on-screen sprite hardware image
147.     ScrnMask AS LONG '              on-screen sprite mask image
148.  
149.     Scrn AS SLRECT '                on-screen sprite location coordinates
150.     '  _________________________________________________________________________________     _____________________________________
151.     ' | .Width  - on-screen sprite width                                                |   | These values are to be considered   |
152.     ' | .Height - on-screen sprite height                                               |   | DYNAMIC in nature. These values     |
153.     ' | .Left   - on-screen sprite left   x location                                    |   | will be calculated every time a     |
154.     ' | .Top    - on-screen sprite top    y location                                    |   | sprite is to be drawn on-screen     |
155.     ' | .Right  - on-screen sprite right  x location                                    |   | taking into account rotation,       |
156.     ' | .Bottom - on-screen sprite bottom y location                                    |   | animation, motion, etc..            |
157.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
158.  
159.     ScrnColl AS SLRECT '            on-screen sprite collision area coordinates
160.     '  _________________________________________________________________________________     _____________________________________
161.     ' | .Width  - on-screen sprite collision area width                                 |   | These values are to be considered   |
162.     ' | .Height - on-screen sprite collision area height                                |   | DYNAMIC in nature. These values     |
163.     ' | .Left   - on-screen sprite collision area left   x location                     |   | will be calculated by adding the    |
164.     ' | .Top    - on-screen sprite collision area top    y location                     |   | original collision offsets to the   |
165.     ' | .Right  - on-screen sprite collision area right  x location                     |   | on-screen sprite location           |
166.     ' | .Bottom - on-screen sprite collision area bottom y location                     |   | coordinates.                        |
167.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
168.  
169.     Anim AS SLANIMATION '           sprite animation settings
170.     '  _________________________________________________________________________________     _____________________________________
171.     ' | .Auto      - enable or disable sprite auto-animation (SLTRUE / SLFALSE)         |   | Notes                               |
172.     ' | .Cell      - the current cell in the animation sequence                         |   |                                     |
173.     ' | .FromCell  - the beginning cell number of the animation sequence                |   |                                     |
174.     ' | .ToCell    - the ending cell number of the animation sequence                   |   |                                     |
175.     ' | .FrameRate - the independent animation frame rate                               |   |                                     |
176.     ' | .Direction - the animation cell direction (1 forward, 2 backward, 3 back/forth) |   |                                     |
177.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
178.  
179.     Move AS SLMOTION '              sprite motion settings
180.     '  _________________________________________________________________________________     _____________________________________
181.     ' | .Auto   - enable or disable sprite auto-motion (SLTRUE / SLFALSE)               |   | Notes                               |
182.     ' | .Degree - direction of motion movement in degrees (0 to 359)                    |   |                                     |
183.     ' | .Xdir   - x direction vector of sprite motion                                   |   |                                     |
184.     ' | .Ydir   - y direction vector of sprite motion                                   |   |                                     |
185.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
186.  
187.     Spin AS SLROTATION '            sprite rotation settings
188.     '  _________________________________________________________________________________     _____________________________________
189.     ' | .Auto    - enable or disable sprite auto-rotation (SLTRUE / SLFALSE)            |   | Notes                               |
190.     ' | .Rotates - sprite has been configured for rotation (SLTRUE / SLFALSE)           |   |                                     |
191.     ' | .Degree  - sprite degree of rotation (0 to 359)                                 |   |                                     |
192.     ' | .Rate    - spin rate (speed) of rotation (-359 to 359)                          |   |                                     |
193.     ' | .Key     - index pointer to map and rotation arrays                             |   |                                     |
194.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
195.  
196.     Mouse AS SLMOUSES '             sprite/mouse interaction settings
197.     '  _________________________________________________________________________________     _____________________________________
198.     ' | .Event - the most recent mouse/sprite interaction event that occurred           |   | Notes                               |
199.     ' | .Xloc  - the x coordinate location of the mouse pointer on the sprite           |   |                                     |
200.     ' | .Yloc  - the y coordinate location of the mouse pointer on the sprite           |   |                                     |
201.     ' | .SXloc - the x coordinate of the mouse pointer on the screen                    |   |                                     |
202.     ' | .SYloc - the y coordinate of the mouse pointer on the screen                    |   |                                     |
203.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
204.  
205.     Coll AS SLCOLLISIONS '          sprite collision settings
206.     '  _________________________________________________________________________________     _____________________________________
207.     ' | .Detect - collision detection method (0 none, 1 rectangle, 2 circle, 3 pixel)   |   | These collision settings have       |
208.     ' | .Event  - set when a collision event occurs (SLTRUE / SLFALSE)                  |   | nothing to do with collision area   |
209.     ' | .With   - the object handle the sprite has collided with                        |   | structures used for collision       |
210.     ' | .Xloc   - x coordinate location of where the collision occurred (pixel)         |   | detection itself. Theese values are |
211.     ' | .Yloc   - y coordinate location of where the collision occurred (pixel)         |   | created in direct result of a       |
212.     ' | .Mask   - sprite mask image for use in pixel detection                          |   | collision happening between objects.|
213.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
214.  
215.     InUse AS _BYTE '                array index in use (SLTRUE / SLFALSE)
216.     Flipped AS _BYTE '              sprite flipping method (0 None, 1 Horiz, 2 Vert, 3 Both)
217.     Zoom AS INTEGER '               sprite zoom level (100 = 100%)
218.     Visible AS _BYTE '              sprite is currently visible (SLTRUE / SLFALSE)
219.     Layer AS INTEGER '              the layer a sprite belongs to
220.     Score AS SINGLE '               the score value associated with a sprite
221.     ClearColor AS _UNSIGNED LONG '  transparent color of sprite
222.     Centerx AS INTEGER
223.     Centery AS INTEGER
224. END TYPE '---------------------------------------------------------------------------------
225.  
226. TYPE SLLAYERS '-------------------- LAYER DATABASE ----------------------------------------  _____________________________________
227.     image AS LONG '                 the layer surface software image                        | Notes                               |
228.     Hardware AS LONG '              the layer surface hardware image                        |                                     |
229.     visible AS _BYTE '              layer visibility (SLTRUE / SLFALSE)                     |                                     |
230. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
231.  
232. TYPE SLMAP '----------------------- _MAPTRIANGLE COORDINATES ------------------------------  _____________________________________
233.     width AS INTEGER '              width of  _MAPTRIANGLE rotated sprite                   | Notes                               |
234.     height AS INTEGER '             height of _MAPTRIANGLE rotated sprite                   |                                     |
235.     px0 AS INTEGER '                upper left  x _MAPTRIANGLE coordinate                   |                                     |
236.     py0 AS INTEGER '                upper left  y _MAPTRIANGLE coordinate                   |                                     |
237.     px1 AS INTEGER '                lower left  x _MAPTRIANGLE coordinate                   |                                     |
238.     py1 AS INTEGER '                lower left  y _MAPTRIANGLE coordinate                   |                                     |
239.     px2 AS INTEGER '                lower right x _MAPTRIANGLE coordinate                   |                                     |
240.     py2 AS INTEGER '                lower right y _MAPTRIANGLE coordinate                   |                                     |
241.     px3 AS INTEGER '                upper right x _MAPTRIANGLE coordinate                   |                                     |
242.     py3 AS INTEGER '                upper right y _MAPTRIANGLE coordinate                   |                                     |
243. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
244.  
245. TYPE SLROT '----------------------- ROTATED COLLISION AREA COORDINATES --------------------
246.     InUse AS _BYTE '                array index in use (SLTRUE / SLFALSE)
247.     Coll AS SLRECT '                ROTATED collision area coordinates
248.     '  _________________________________________________________________________________     _____________________________________
249.     ' | .Width  - rotated collision area width                                          |   | These values are to be considered   |
250.     ' | .Height - rotated collision area height                                         |   | STATIC in nature. Once they are set |
251.     ' | .Left   - rotated collision area left   x offset (from screen left x)           |   | they should never be changed. These |
252.     ' | .Top    - rotated collision area top    y offset (from screen top  y)           |   | values are used to calculate the    |
253.     ' | .Right  - rotated collision area right  x offset (from screen left x)           |   | on-screen ROTATED sprite collision  |
254.     ' | .Bottom - rotated collision area bottom y offset (from screen top  y)           |   | area coordinates.                   |
255.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
256. END TYPE '---------------------------------------------------------------------------------
257.  
258. TYPE SLDEGREE '-------------------- PRECALCULATED SIN/COS TABLE ---------------------------  _____________________________________
259.     SIN AS SINGLE '                 SIN of rotation                                         | The file degrees.deg will be        |
260.     COS AS SINGLE '                 COS of rotation                                         | created to hold this table.         |
261. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
262.  
263. TYPE SLGLOBAL '-------------------- GLOBAL SETTINGS ---------------------------------------  _____________________________________
264.     Scrn AS SLRECT '                main screen coordinate values                           | Any single variables that need to   |
265.     Start AS _BYTE '                SLStart initialization trigger (SLTRUE / SLFALSE)       | be shared globally throughout the   |
266.     FrameRate AS INTEGER '          global library frame rate                               | library should be placed in this    |
267.     Layers AS INTEGER '             number of layers requested by programmer                | data type.                          |
268.     Subroutine AS STRING * 15 '     current subroutine for error processing                 |                                     |
269. END TYPE '---------------------------------------------------------------------------------  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
270.  
271.  
272. REDIM SLSheet(0) AS SLSHEET '       master sprite sheet array
273. REDIM SLSprite(0) AS SLSPRITE '     master sprite array
274. REDIM SLMap(0, 359) AS SLMAP '      master sprite sheet _MAPTRIANGLE coordinate array
275. REDIM SLRot(0, 359) AS SLROT '      master sprite rotated collision area array
276. REDIM SLLayers(0) AS SLLAYERS '      master layer array
277. DIM SLDegree(359) AS SLDEGREE '     precalculated SIN/COS table
278. DIM SLGlobal AS SLGLOBAL '          global variables
279.  
280.  
281. DIM dkong AS INTEGER
282. DIM i AS INTEGER
283. DIM rect AS SLRECT
284. DIM mario AS INTEGER
285.  
286. SL_Start
287. SL_Window 640, 480, 5
288. dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
289. mario = SL_MakeSprite(0, dkong, 6, SLTRUE)
290. 'SL_SpriteSet mario, SLZOOM, 500
291. SL_PutSprite mario, 200, 200
292. _PUTIMAGE (SLSprite(mario).Scrn.Left, SLSprite(mario).Scrn.Top)-(SLSprite(mario).Scrn.Right, SLSprite(mario).Scrn.Bottom), SLSprite(mario).OrigImage
293. CIRCLE (100, 100), 50, _RGB32(255, 255, 255)
294. LINE (SLSprite(mario).ScrnColl.Left, SLSprite(mario).ScrnColl.Top)-(SLSprite(mario).ScrnColl.Right, SLSprite(mario).ScrnColl.Bottom), _RGB32(255, 255, 255), B
295. SL_FreeSprite mario
296.  
297.  
298. ' Verified SLRot() is being created correctly
299. '--------------------------------------------
300. 'SCREEN _NEWIMAGE(640, 480, 32)
301. 'dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
302. 'mario = SL_MakeSprite(0, dkong, 1, SLTRUE)
303. 'FOR i = 0 TO 359
304. '    PRINT SLRot(0, i).Coll.Width; SLRot(0, i).Coll.Height
305. '    PRINT SLRot(0, i).Coll.Left; SLRot(0, i).Coll.Top; SLRot(0, i).Coll.Right; SLRot(0, i).Coll.Bottom
306. 'NEXT i
307.  
308.  
309. ' Verified SL_MakeSprite is working properly
310. '-------------------------------------------
311. 'SCREEN _NEWIMAGE(640, 480, 32)
312. 'dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
313. 'mario = SL_MakeSprite(0, dkong, 1, SLTRUE)
314. '_PUTIMAGE (0, 0), SLSprite(dkong).OrigImage
315. 'LINE (SLSprite(mario).OrigColl.Left, SLSprite(mario).OrigColl.Top)-(SLSprite(mario).OrigColl.Right, SLSprite(mario).OrigColl.Bottom), _RGB32(255, 255, 255), B
316.  
317.  
318. ' Verified SL_GetCellCoordinates is working properly
319. '---------------------------------------------------
320. 'SCREEN _NEWIMAGE(640, 480, 32)
321. 'dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
322. 'SL_GetCellCoordinates dkong, 1, rect
323. 'PRINT rect.left, rect.top
324. 'PRINT rect.right, rect.bottom
325. 'PRINT rect.width, rect.height
326.  
327.  
328. ' Verified sheet is loading and clearcolor being applied
329. '-------------------------------------------------------
330. 'SCREEN _NEWIMAGE(640, 480, 32)
331. 'dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
332. '_PUTIMAGE (100, 100), SLSheet(dkong).Image
333.  
334.  
335. ' Verified SLMAP() is being created and reloaded properly
336. '--------------------------------------------------------
337. 'SCREEN _NEWIMAGE(640, 480, 32)
338. 'dkong = SL_LoadSheet("dkong.png", 64, 64, _RGB32(255, 0, 255))
339. 'FOR i = 0 TO 359
340. '    PRINT i; SLMap(dkong, i).width; SLMap(dkong, i).height
341. '    DO: LOOP UNTIL _KEYHIT
342. 'NEXT i
343.  
344.  
345.  
346. '----------------------------------------------------------------------------------------------------------------------------------
347. SUB SL_Start () '                                                                                                          SL_Start
348.     '  ___________________________________________________________________________________________________________________________
349.     ' | Initializes the sprite library                                                                                            |
350.     ' |---------------------------------------------------------------------------------------------------------------------------|
351.     ' | Usage : SL_Start                                                                                                          |
352.     ' |                                                                                                                           |
353.     ' | Output: A file named 'degrees.deg' will be created after executing this subroutine.                                       |
354.     ' | Note  : This MUST be the first command issued before using the sprite library. Any setup procedures that need to be       |
355.     ' |         performed in support of functions and subroutines should be placed in this subroutine.                            |
356.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
357.     SHARED SLDegree() AS SLDEGREE ' precalculated SIN/COS table
358.     SHARED SLGlobal AS SLGLOBAL '   global variables
359.     DIM Degree AS INTEGER '         degree counter
360.     DIM FileNumber AS INTEGER '     next available file handle
361.     '  ________________________________________________________________________________
362.     ' | Load or create precalculated degree rotation array                             |
363.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
364.     FileNumber = FREEFILE '                                                                 get the next free file handle
365.     IF _FILEEXISTS("degrees.deg") THEN '                                                    does the degree file exist?
366.         '  ____________________________________________________________________________
367.         ' | Load the array since the file already exists                               |
368.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
369.         OPEN "degrees.deg" FOR BINARY AS #FileNumber '                                      yes, open the file for reading
370.         GET #FileNumber, , SLDegree() '                                                     get the rotational degree data
371.         CLOSE #FileNumber '                                                                 close the file
372.     ELSE '                                                                                  no, the file does not exist
373.         '  ____________________________________________________________________________
374.         ' | Create the precalculated degree rotation array                             |
375.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
376.         DO '                                                                                cycle through 360 degrees
377.             SLDegree(Degree).SIN = SIN(Degree * .017453292) '                               calculate the SIN of angle
378.             SLDegree(Degree).COS = -COS(Degree * .017453292) '                              calculate the COSINE of angle
379.             Degree = Degree + 1 '                                                           increment degree counter
380.         LOOP UNTIL Degree = 360 '                                                           leave when all degrees cycled
381.         '  ____________________________________________________________________________
382.         ' | The file must be created since it did not exist                            |
383.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
384.         OPEN "degrees.deg" FOR BINARY AS #FileNumber '                                      open the file for writing
385.         PUT #FileNumber, , SLDegree() '                                                     write the rotational degree data
386.         CLOSE #FileNumber '                                                                 close the file
387.     END IF
388.     SLGlobal.Start = SLTRUE '                                                               record that library was initialized
389.  
390. END SUB
391.  
392. '----------------------------------------------------------------------------------------------------------------------------------
393. SUB SL_Window (ScreenWidth AS INTEGER, ScreenHeight AS INTEGER, Layers AS INTEGER) '                                      SL_Window
394.     '  ___________________________________________________________________________________________________________________________
395.     ' | Creates the main working screen and number of requested layers.                                                           |
396.     ' |---------------------------------------------------------------------------------------------------------------------------|
397.     ' | Usage : SL_Window 640, 480, 4                                                                                             |
398.     ' |                                                                                                                           |
399.     ' | Input : ScreenWidth  = the width of the main working screen and requested layers                                          |
400.     ' |         ScreenHeight = the height of the main working screen and requested layers                                         |
401.     ' |         Layers       = the requested number fo layers to create (zero (0) for no layers)                                  |
402.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
403.     SHARED SLLayers() AS SLLAYERS ' master layer array
404.     SHARED SLGlobal AS SLGLOBAL '   global variables
405.     DIM layer AS INTEGER
406.  
407.     SLGlobal.Scrn.Width = ScreenWidth '                                                     set screen/layer rectangular values
408.     SLGlobal.Scrn.Height = ScreenHeight
409.     SLGlobal.Scrn.Left = 0
410.     SLGlobal.Scrn.Top = 0
411.     SLGlobal.Scrn.Right = ScreenWidth - 1
412.     SLGlobal.Scrn.Bottom = ScreenHeight - 1
413.     '  _________________________________________________________________________________
414.     ' | Create the number of requested layers                                           |
415.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
416.     IF Layers > SLNONE THEN '                                                               have layers been requested?
417.         SLGlobal.Layers = Layers '                                                          yes, record number of layers requested
418.         REDIM SLLayers(Layers) AS SLLAYERS '                                                increase size of layer array
419.         DO '                                                                                cycle through requested layers
420.             layer = layer + 1 '                                                             increment layer counter
421.             SLLayers(layer).image = _NEWIMAGE(ScreenWidth, ScreenHeight, 32) '              create software layer image
422.             SLLayers(Layers).visible = SLTRUE '                                             layers are visible by default
423.         LOOP UNTIL layer = UBOUND(SLLayers) '                                               leave when all layers created
424.     END IF
425.     '  _________________________________________________________________________________
426.     ' | Create the main working screen (_DEST 0)                                        |
427.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
428.     SCREEN _NEWIMAGE(ScreenWidth, ScreenHeight, 32) '                                       initialize main screen
429.  
430. END SUB
431.  
432. '----------------------------------------------------------------------------------------------------------------------------------
433. SUB SL_PutSprite (Handle AS INTEGER, Centerx AS INTEGER, Centery AS INTEGER) '                                         SL_PutSprite
434.     '  ___________________________________________________________________________________________________________________________
435.     ' | Calculates the actual screen and collision area coordinates for sprite screen placement.                                  |
436.     ' |---------------------------------------------------------------------------------------------------------------------------|
437.     ' | Usage : SL_PutSprite Mysprite, 100, 100                                                                                   |
438.     ' |                                                                                                                           |
439.     ' | Input : Handle  = the handle pointer name of the sprite to have screen placement calculated                               |
440.     ' |         Centerx = the x coordinate location to horizontally center the sprite                                             |
441.     ' |         Centery = the y coordinate location to vertically center the sprite                                               |
442.     ' | Note  : The sprite will be centered on the supplied Centerx and Centery coordinate pair.                                  |
443.     ' |         The sprite zoom level will be taken into account to adjust the screen and collision coordinates accordingly.      |
444.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
445.     SHARED SLSprite() AS SLSPRITE ' master sprite array
446.     SHARED SLMap() AS SLMAP '       master sprite sheet _MAPTRIANGLE coordinate array
447.     SHARED SLRot() AS SLROT '       master sprite rotated collision area array
448.     DIM Zoom AS INTEGER '           zoom level of sprite
449.     DIM Sheet AS INTEGER '          the sprite sheet the sprite belongs to
450.     DIM Degree AS INTEGER '         the sprite's dgree of rotation
451.     DIM RotKey AS INTEGER '         the sprite's key index pointer to the SLRot array
452.  
453.     Zoom = SLSprite(Handle).Zoom \ 100 '                                                    get and calculate the zoom level
454.     Sheet = SLSprite(Handle).OrigSheet '                                                    get the sheet that owns this sprite
455.     Degree = SLSprite(Handle).Spin.Degree '                                                 get the sprite's degree of rotation
456.     RotKey = SLSprite(Handle).Spin.key '                                                    get the sprite's SLRot index pointer
457.     SLSprite(Handle).Centerx = Centerx '                                                    record current x coordinate of sprite
458.     SLSprite(Handle).Centery = Centery '                                                    record current y coordinate of sprite
459.     '  _________________________________________________________________________________
460.     ' |                                                                                 |
461.     ' | Calculate the sprite's on-screen rectangular structure coordinate values        |
462.     ' |                                                                                 |
463.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
464.     IF SLSprite(Handle).Spin.Rotates THEN '                                                 has sprite been configured to rotate?
465.         '  _____________________________________________________________________________
466.         ' | Use SLMap width and height values since the sprite uses ROTATION            |
467.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
468.         SLSprite(Handle).Scrn.Width = SLMap(Sheet, Degree).width '                          yes, get the rotated width of sprite
469.         SLSprite(Handle).Scrn.Height = SLMap(Sheet, Degree).height '                        get the rotated height of sprite
470.     ELSE '                                                                                  no, this sprite does not rotate
471.         '  _____________________________________________________________________________
472.         ' | Use original width and height values since the sprite uses NO ROTATION      |
473.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
474.         SLSprite(Handle).Scrn.Width = SLSprite(Handle).OrigWidth '                          get the original width of sprite
475.         SLSprite(Handle).Scrn.Height = SLSprite(Handle).OrigHeight '                        get the original height of sprite
476.     END IF
477.     '  _________________________________________________________________________________
478.     ' | Complete the calculations for the on-screen sprite rectangular structure        |
479.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
480.     SLSprite(Handle).Scrn.Left = Centerx - (SLSprite(Handle).Scrn.Width \ 2) * Zoom '       calculate sprite's left x coordinate
481.     SLSprite(Handle).Scrn.Top = Centery - (SLSprite(Handle).Scrn.Height \ 2) * Zoom '       calculate sprite's top y coordinate
482.     SLSprite(Handle).Scrn.Right = SLSprite(Handle).Scrn.Left +_
483.                                   (SLSprite(Handle).Scrn.Width - 1) * Zoom '                calculate sprite's right x coordinate
484.     SLSprite(Handle).Scrn.Bottom = SLSprite(Handle).Scrn.Top +_
485.                                   (SLSprite(Handle).Scrn.Height - 1) * Zoom '               calculate sprite's bottom y coordinate
486.     '  _________________________________________________________________________________
487.     ' |                                                                                 |
488.     ' | Calculate the sprite's on-screen collision area rectangular coordinate values   |
489.     ' |                                                                                 |
490.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
491.     IF SLSprite(Handle).ClearColor = SLNOTRANSPARENCY THEN '                                does sprite have transparent color?
492.         '  _____________________________________________________________________________
493.         ' | Since sprite is not transparent the collision area will be the entire sprite|
494.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
495.         SLSprite(Handle).ScrnColl = SLSprite(Handle).Scrn '                                 no, use entire sprite as collision
496.     ELSE '                                                                                  yes, this sprite uses transparency
497.         IF SLSprite(Handle).Spin.Rotates THEN '                                             has sprite been configured to rotate?
498.             '  _________________________________________________________________________
499.             ' | Since the sprite is transparent and it rotates the collision area       |
500.             ' | coordinates must come from the SLRot array.                             |
501.             ' |-------------------------------------------------------------------------|
502.             ' |                                Sprite Top Y                             |
503.             ' |          +--------------------------------------------------------+     |
504.             ' |          |TRANSPARENT          SLRot        ^   ^        SLRot    |     |
505.             ' |          |   SPRITE          Collision      |   |      Collision  |     |
506.             ' |          |                   Area Top Y --->|   |<--- Area Bottom |     |
507.             ' |          |                    (offset)      |   |     Y (offset)  |     |
508.             ' |          |                                  |   |                 |     |
509.             ' |          |  SLRot ~~~~~~~~~~\               V   |                 |     |
510.             ' |  Sprite  |  Collision Area   |    +-------------+--------+        |     |
511.             ' |  Left X  |  Lext X (offset)  V    |COLLISION    |        |        |     |
512.             ' |          |<---------------------->|   AREA      |        |        |     |
513.             ' |          |                        |             |        |        |     |
514.             ' |          |<-----------------------+-------------+------->|        |     |
515.             ' |          |   Collision Area  ^    |             |        |        |     |
516.             ' |          |  Right X (offset) |    |             V        |        |     |
517.             ' |          |  SLRot __________/     +----------------------+        |     |
518.             ' |          |                                                        |     |
519.             ' |          +--------------------------------------------------------+     |
520.             ' | The collsion area for a transparent sprite comes from taking the left x |
521.             ' | and top y offset values from SLRot and adding them to the left x and    |
522.             ' | top y sprite coordinate values as shown above. The collision area can   |
523.             ' | wildy vary in size depending on the actual non-transparent image        |
524.             ' | contained within the sprite. Note as well that the collision does not   |
525.             ' | necessarily need to be centered within the sprite, again depending on   |
526.             ' | the actual non-transparent image contained within the sprite.           |
527.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
528.             SLSprite(Handle).ScrnColl.Width = SLRot(RotKey, Degree).Coll.Width '            get the sprite's rotated width
529.             SLSprite(Handle).ScrnColl.Height = SLRot(RotKey, Degree).Coll.Height '          get the sprite's rotated height
530.             SLSprite(Handle).ScrnColl.Left = SLSprite(Handle).Scrn.Left +_
531.                                              SLRot(RotKey, Degree).Coll.Left * Zoom '       calculate sprite's left x coordinate
532.             SLSprite(Handle).ScrnColl.Top = SLSprite(Handle).Scrn.Top +_
533.                                             SLRot(RotKey, Degree).Coll.Top * Zoom '         calculate sprite's top y coordinate
534.             SLSprite(Handle).ScrnColl.Right = SLSprite(Handle).Scrn.Left +_
535.                                               SLRot(RotKey, Degree).Coll.Right * Zoom '     calculate sprite's right x coordinate
536.             SLSprite(Handle).ScrnColl.Bottom = SLSprite(Handle).Scrn.Top +_
537.                                                SLRot(RotKey, Degree).Coll.Bottom * Zoom '   calculate sprite's bottom y coordinate
538.         ELSE '                                                                              no, this sprite does not rotate
539.             '  _________________________________________________________________________
540.             ' | The sprite does not rotate so use the original collision area instead   |
541.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
542.             SLSprite(Handle).ScrnColl.Width = SLSprite(Handle).OrigColl.Width '             get sprite's original collision width
543.             SLSprite(Handle).ScrnColl.Height = SLSprite(Handle).OrigColl.Height '           get sprite's original collision height
544.             SLSprite(Handle).ScrnColl.Left = SLSprite(Handle).Scrn.Left +_
545.                                              SLSprite(Handle).OrigColl.Left * Zoom '        calculate sprite's left x coordinate
546.             SLSprite(Handle).ScrnColl.Top = SLSprite(Handle).Scrn.Top +_
547.                                             SLSprite(Handle).OrigColl.Top * Zoom '          calculate sprite's top y coordinate
548.             SLSprite(Handle).ScrnColl.Right = SLSprite(Handle).Scrn.Left +_
549.                                               SLSprite(Handle).OrigColl.Right * Zoom '      calculate sprite's right x coordinate
550.             SLSprite(Handle).ScrnColl.Bottom = SLSprite(Handle).Scrn.Top +_
551.                                                SLSprite(Handle).OrigColl.Bottom * Zoom '    calculate sprite's bottom y coordinate
552.         END IF
553.     END IF
554.  
555. END SUB
556.  
557. '----------------------------------------------------------------------------------------------------------------------------------
558. FUNCTION SL_MakeSprite (Layer AS INTEGER, Sheet AS INTEGER, Cell AS INTEGER, Rotates AS INTEGER) '                    SL_MakeSprite
559.     '  ___________________________________________________________________________________________________________________________
560.     ' | Create a new sprite from a previously loaded sprite sheet.                                                                |
561.     ' |---------------------------------------------------------------------------------------------------------------------------|
562.     ' | Usage : Sprite = SL_MakeSprite(LayerNumber, MySheet, CellNumber, SLTRUE)                                                  |
563.     ' |                                                                                                                           |
564.     ' | Input : Layer   = the layer this sprite resides on (use zero (0) for a pure hardware sprite)                              |
565.     ' |         Sheet   = the previously loaded sheet where the sprite is located                                                 |
566.     ' |         Cell    = the cell number on the previously loaded sheet where the sprite resides                                 |
567.     ' |         Rotates = sprite rotation characteristics (SLTRUE = the sprite will rotate, SLFALSE = the sprite will not rotate) |
568.     ' | Output: An array index that acts as a handle pointer to the newly created sprite                                          |
569.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
570.     SHARED SLSprite() AS SLSPRITE ' master sprite array
571.     SHARED SLSheet() AS SLSHEET '   master sprite sheet array
572.     SHARED SLMap() AS SLMAP '       master sprite sheet _MAPTRIANGLE coordinate array
573.     SHARED SLRot() AS SLROT '       master sprite rotated collision area array
574.     DIM Handle AS INTEGER '         sprite array index pointer
575.     DIM Rect AS SLRECT '            general use rectangular structure
576.     DIM odest AS LONG '             current _DEST
577.     DIM osource AS LONG '           current _SOURCE
578.     DIM x AS INTEGER '              x axis (width) counter
579.     DIM y AS INTEGER '              y axis (height) counter
580.     DIM RotKey AS INTEGER '         rotated collsion array index key used by sprite
581.     DIM rotatedsprite AS LONG '     each sprite rotated 360 degrees
582.     DIM degree AS INTEGER '         degree counter
583.     '  _________________________________________________________________________________
584.     ' | Create a new or use existing unused index in sprite array to hold sprite.       |
585.     ' |---------------------------------------------------------------------------------|
586.     ' | When a sprite is removed (SL_RemoveSprite) the array index is marked as unused  |
587.     ' | and can be later reused by another sprite being created. If no unused array     |
588.     ' | positions exist then a new array index will be created to hold the new sprite's |
589.     ' | information.                                                                    |
590.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
591.     Handle = -1 '                                                                           reset handle array index pointer
592.     DO '                                                                                    cycle through sprite array
593.         Handle = Handle + 1 '                                                               increment handle array index pointer
594.     LOOP UNTIL SLSprite(Handle).InUse = SLFALSE OR Handle = UBOUND(SLSprite) '              leave when suitable array index found
595.     IF SLSprite(Handle).InUse THEN '                                                        is this array index currently in use?
596.         Handle = Handle + 1 '                                                               yes, increase the array index size
597.         REDIM _PRESERVE SLSprite(Handle) AS SLSPRITE '                                      create new index in sprite array
598.     END IF
599.     '  _________________________________________________________________________________
600.     ' | Record basic information about the sprite                                       |
601.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
602.     SLSprite(Handle).InUse = SLTRUE '                                                       mark this array index as in use
603.     SLSprite(Handle).OrigSheet = Sheet '                                                    get the sheet sprite belongs to
604.     SLSprite(Handle).OrigCell = Cell '                                                      get the cell sprite resides in on sheet
605.     SLSprite(Handle).OrigWidth = SLSheet(Sheet).CellWidth '                                 get original width of sprite
606.     SLSprite(Handle).OrigHeight = SLSheet(Sheet).CellHeight '                               get original height of sprite
607.     SLSprite(Handle).OrigImage = _NEWIMAGE(SLSprite(Handle).OrigWidth,_
608.                                            SLSprite(Handle).OrigHeight, 32) '               create original image surface
609.     SLSprite(Handle).OrigMask = _COPYIMAGE(SLSprite(Handle).OrigImage, 32) '                create original image mask surface
610.     SL_GetCellCoordinates Sheet, Cell, Rect '                                               get original image sheet coordinates
611.     _PUTIMAGE , SLSheet(Sheet).Image, SLSprite(Handle).OrigImage,_
612.                 (Rect.Left, Rect.Top)-(Rect.Right, Rect.Bottom) '                           get original copy of image from sheet
613.     SLSprite(Handle).Flipped = SLNONE '                                                     reset sprite flipping behavior
614.     SLSprite(Handle).Zoom = 100 '                                                           reset zoom to normal (100%)
615.     SLSprite(Handle).Visible = SLTRUE '                                                     all new sprites visible by default
616.     SLSprite(Handle).Layer = Layer '                                                        the layer that sprite belongs to
617.     SLSprite(Handle).Score = 0 '                                                            reset sprite's score
618.     SLSprite(Handle).ClearColor = SLSheet(Sheet).ClearColor '                               get sprite's transparenct color
619.     '  _________________________________________________________________________________
620.     ' | Create original collision area information and original sprite mask image       |
621.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
622.     odest = _DEST '                                                                         save current destination surface
623.     osource = _SOURCE '                                                                     save current source surface
624.     _SOURCE SLSprite(Handle).OrigImage '                                                    set original image as source surface
625.     _DEST SLSprite(Handle).OrigMask '                                                       set original image mask as destination
626.     Rect.Width = SLSprite(Handle).OrigWidth '                                               use original width in rect structure
627.     Rect.Height = SLSprite(Handle).OrigHeight '                                             use original height in rect structure
628.     Rect.Left = Rect.Width '                                                                start at opposite side of left
629.     Rect.Top = Rect.Height '                                                                start at opposite side of top
630.     Rect.Right = 0 '                                                                        start at opposite side of right
631.     Rect.Bottom = 0 '                                                                       start at opposite side of bottom
632.     '  _________________________________________________________________________________
633.     ' | Scan every pixel of the image to obtain collision area characteristics          |
634.     ' |---------------------------------------------------------------------------------|
635.     ' | If a pixel location within the image is not a transparent color then test to    |
636.     ' | see if that pixel is one of the outer boundaries of the collision area. The     |
637.     ' | collison area will encompass any pixel that is not a transparent one. If the    |
638.     ' | pixel is transparent however draw a pixel on the sprite mask image in the same  |
639.     ' | spot as white. This will create a negative mask, white being where a tranparent |
640.     ' | pixel is and black being where the image is located.                            |
641.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
642.     DO '                                                                                    cycle through the width of the image
643.         y = 0 '                                                                             reset height counter
644.         DO '                                                                                cycle through the height of the image
645.             IF POINT(x, y) <> SLSprite(Handle).ClearColor THEN '                            is this pixel transparent?
646.                 '  _____________________________________________________________________
647.                 ' | pixel is part of image so look for outer boundary                   |
648.                 '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
649.                 IF x < Rect.Left THEN Rect.Left = x '                                       no, if left-most so far record it
650.                 IF y < Rect.Top THEN Rect.Top = y '                                         if top-most so far record it
651.                 IF x > Rect.Right THEN Rect.Right = x '                                     if right-most so far record it
652.                 IF y > Rect.Bottom THEN Rect.Bottom = y '                                   if bottom-most so far record it
653.             ELSE '                                                                          yes, the pixel is transparent
654.                 '  _____________________________________________________________________
655.                 ' | pixel is part of the transparent area so create mask instead        |
656.                 '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
657.                 PSET (x, y), _RGB32(255, 255, 255) '                                        draw white pixel on mask in same spot
658.             END IF
659.             y = y + 1 '                                                                     increment height counter
660.         LOOP UNTIL y = Rect.Height '                                                        leave when height of image reached
661.         x = x + 1 '                                                                         increment width counter
662.     LOOP UNTIL x = Rect.Width '                                                             leave when width of image reached
663.     _DEST odest '                                                                           restore current destination surface
664.     _SOURCE osource '                                                                       restore current source surface
665.     SLSprite(Handle).OrigColl = Rect '                                                      record original collision area values
666.     '  _________________________________________________________________________________
667.     ' | Reset on-screen sprite and collision area coordinates                           |
668.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
669.     Rect.Width = 0 '                                                                        create empty rectangular structure
670.     Rect.Height = 0
671.     Rect.Left = 0
672.     Rect.Top = 0
673.     Rect.Right = 0
674.     Rect.Bottom = 0
675.     SLSprite(Handle).Scrn = Rect '                                                          reset on-screen location coordinates
676.     SLSprite(Handle).ScrnColl = Rect '                                                      reset on-screen collision area coords
677.     '  _________________________________________________________________________________
678.     ' | Reset sprite animation settings                                                 |
679.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
680.     SLSprite(Handle).Anim.Auto = SLFALSE
681.     SLSprite(Handle).Anim.Cell = 0
682.     SLSprite(Handle).Anim.FromCell = 0
683.     SLSprite(Handle).Anim.ToCell = 0
684.     SLSprite(Handle).Anim.FrameRate = 0
685.     SLSprite(Handle).Anim.Direction = 0
686.     '  _________________________________________________________________________________
687.     ' | Reset sprite motion settings                                                    |
688.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
689.     SLSprite(Handle).Move.Auto = SLFALSE
690.     SLSprite(Handle).Move.Degree = 0
691.     SLSprite(Handle).Move.Xdir = 0
692.     SLSprite(Handle).Move.Ydir = 0
693.     '  _________________________________________________________________________________
694.     ' | Reset sprite rotation settings                                                  |
695.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
696.     IF Rotates THEN '                                                                       will this sprite be able to rotate?
697.         '  _____________________________________________________________________________
698.         ' | Create a new or use existing unused index in collision rotation array       |
699.         ' |-----------------------------------------------------------------------------|
700.         ' | When a sprite is set as being allowed to rotate its image is rotated 360    |
701.         ' | degrees to obtain collision area coordinates for every angle. This          |
702.         ' | information is stored in the collision rotation array at either a new index |
703.         ' | created to hold the information or an unused one freed up by a sprite being |
704.         ' | removed. A key is used as an index pointer by the sprite to find its        |
705.         ' | information in the collision rotation array.                                |
706.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
707.         RotKey = -1 '                                                                       yes, reset handle array index pointer
708.         DO '                                                                                cycle through rotated collision array
709.             RotKey = RotKey + 1 '                                                           increment handle array index pointer
710.         LOOP UNTIL SLRot(RotKey, 0).InUse = SLFALSE OR RotKey = UBOUND(SLrot, 1) '          leave when suitable array index found
711.         IF SLRot(RotKey, 0).InUse THEN '                                                    is this array index currently in use?
712.             RotKey = RotKey + 1 '                                                           yes, increase the array index size
713.             REDIM _PRESERVE SLRot(RotKey, 359) AS SLROT '                                   create new index in rotated coll array
714.         END IF
715.         SLSprite(Handle).Spin.key = RotKey '                                                mark this array index as in use
716.         DO '                                                                                cycle through 360 degrees
717.             IF SLSprite(Handle).ClearColor = SLNOTRANSPARENCY THEN '                        does this sprite contain transparency?
718.                 '  _____________________________________________________________________
719.                 ' | The sprite not transparent so use the full rotated width and height |
720.                 '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
721.                 SLRot(RotKey, degree).Coll.Width = SLMap(Sheet, degree).width '             no, record rotated collision area width
722.                 SLRot(RotKey, degree).Coll.Height = SLMap(Sheet, degree).height '           record rotated collision area height
723.                 SLRot(RotKey, degree).Coll.Left = 0 '                                       record rotated collision left offset
724.                 SLRot(RotKey, degree).Coll.Top = 0 '                                        record rotated collision top offset
725.                 SLRot(RotKey, degree).Coll.Right = SLMap(Sheet, degree).width - 1 '         record rotated collision right offset
726.                 SLRot(RotKey, degree).Coll.Bottom = SLMap(Sheet, degree).height - 1 '       record rotated collision bottom offset
727.             ELSE '                                                                          yes, this sprite contains transparency
728.                 '  _____________________________________________________________________     _____________________________________
729.                 ' | Map original sprite onto rotated image using SLMap data made before |   | These rotated sprite images could   |
730.                 ' |---------------------------------------------------------------------|   | be saved into an array in a later   |
731.                 ' | The precalculated values        px(0),py(0)           px(3),py(3)   |   | version of the sprite library       |
732.                 ' | created when the sheet was           +---------------------+        |   | eleviating the need to once again   |
733.                 ' | loaded and placed in SLMap       ,>  |~\_     _MAPTRIANGLE |  >,    |   | rotate them in SLPutSprite later.   |
734.                 ' | are now used by _MAPTRIANGLE    /    |   ~\_       #2      |    \   |   | This would take a considerable      |
735.                 ' | to rotate the image onto       |     |      ~\_            |     |  |   | amount of memory to store however   |
736.                 ' | the rotated sprite image      |      |         ~\_         |      | |   | depending on the number of sprites  |
737.                 ' | surface. SLMap also contains   |     |            ~\_      |     |  |   | that require rotating in a given    |
738.                 ' | the rotated width and height    \    | _MAPTRIANGLE  ~\_   |    /   |   | game/program. This will need to be  |
739.                 ' | needed to create the rotated     `<  |      #1          ~\_|  <'    |   | investigated at a later date.       |
740.                 ' | sprite image surface.                +---------------------+        |   |                                     |
741.                 ' |                                 px(1),py(1)           px(2),py(2)   |   |                       tr 10/30/18   |
742.                 '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
743.                 rotatedsprite = _NEWIMAGE(SLMap(Sheet, degree).width,_
744.                                           SLMap(Sheet, degree).height, 32) '                create rotated sprite image surface
745.  
746.                 _MAPTRIANGLE (0, 0)-(0, SLSprite(Handle).OrigHeight - 1)-_
747.                     (SLSprite(Handle).OrigWidth - 1, SLSprite(Handle).OrigHeight - 1),_
748.                     SLSprite(Handle).OrigImage TO _
749.                     (SLMap(Sheet, degree).px0, SLMap(Sheet, degree).py0)-_
750.                     (SLMap(Sheet, degree).px1, SLMap(Sheet, degree).py1)-_
751.                     (SLMap(Sheet, degree).px2, SLMap(Sheet, degree).py2), rotatedsprite '   map triangle #1 to rotated sprite image
752.                 _MAPTRIANGLE (0, 0)-(SLSprite(Handle).OrigWidth - 1, 0)-_
753.                     (SLSprite(Handle).OrigWidth - 1, SLSprite(Handle).OrigHeight - 1),_
754.                     SLSprite(Handle).OrigImage TO _
755.                     (SLMap(Sheet, degree).px0, SLMap(Sheet, degree).py0)-_
756.                     (SLMap(Sheet, degree).px3, SLMap(Sheet, degree).py3)-_
757.                     (SLMap(Sheet, degree).px2, SLMap(Sheet, degree).py2), rotatedsprite '   map triangle #2 to rotated sprite image
758.                 '  _____________________________________________________________________
759.                 ' | The sprite is transparent so the rotated image will need scanned    |
760.                 ' |---------------------------------------------------------------------|
761.                 ' | If a pixel location within the image is not a transparent color     |
762.                 ' | then test to see if that pixel is one of the outer boundaries of    |
763.                 ' | the collision area. The collision area will encompass any pixel     |
764.                 ' | that is not a transparent one.                                      |
765.                 '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
766.                 Rect.Width = SLMap(Sheet, degree).width '                                   use rotated width in rect structure
767.                 Rect.Height = SLMap(Sheet, degree).height '                                 use rotated height in rect structure
768.                 Rect.Left = Rect.Width '                                                    start at opposite side of left
769.                 Rect.Top = Rect.Height '                                                    start at opposite side of top
770.                 Rect.Right = 0 '                                                            start at opposite side of right
771.                 Rect.Bottom = 0 '                                                           start at opposite side of bottom
772.                 osource = _SOURCE '                                                         save current source surface
773.                 _SOURCE rotatedsprite '                                                     set rotated image as source surface
774.                 x = 0 '                                                                     reset width counter
775.                 DO '                                                                        cycle through the width of the image
776.                     y = 0 '                                                                 reset height counter
777.                     DO '                                                                    cycle through the height of the image
778.                         IF POINT(x, y) <> SLSprite(Handle).ClearColor THEN '                is this pixel transparent?
779.                             '  _________________________________________________________
780.                             ' | pixel is part of image so look for outer boundary       |
781.                             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
782.                             IF x < Rect.Left THEN Rect.Left = x '                           no, if left-most so far record it
783.                             IF y < Rect.Top THEN Rect.Top = y '                             if top-most so far record it
784.                             IF x > Rect.Right THEN Rect.Right = x '                         if right-most so far record it
785.                             IF y > Rect.Bottom THEN Rect.Bottom = y '                       if bottom-most so far record it
786.                         END IF
787.                         y = y + 1 '                                                         increment height counter
788.                     LOOP UNTIL y = Rect.Height '                                            leave when height of image reached
789.                     x = x + 1 '                                                             increment width counter
790.                 LOOP UNTIL x = Rect.Width '                                                 leave when width of image reached
791.                 _SOURCE osource '                                                           restore current source surface
792.                 Rect.Width = Rect.Right - Rect.Left '                                       record width of rotated collision area
793.                 Rect.Height = Rect.Bottom - Rect.Top '                                      record height of rotated collision area
794.                 SLRot(RotKey, degree).Coll = Rect '                                         record rotated collision area values
795.                 _FREEIMAGE rotatedsprite '                                                  remove rotated image from memory
796.             END IF
797.             degree = degree + 1 '                                                           increment degree counter
798.         LOOP UNTIL degree = 360 '                                                           leave when 360 degrees processed
799.     ELSE '                                                                                  no, this sprite will not rotate
800.         SLSprite(Handle).Spin.key = 0 '                                                     reset rotation file index pointer
801.     END IF
802.     SLSprite(Handle).Spin.Auto = SLFALSE '                                                  disable auto rotation
803.     SLSprite(Handle).Spin.Rotates = Rotates '                                               enable/disable sprite rotation status
804.     SLSprite(Handle).Spin.Degree = 0 '                                                      reset rotation degree angle
805.     SLSprite(Handle).Spin.Rate = 0 '                                                        reset rotation spin rate (speed)
806.     '  _________________________________________________________________________________
807.     ' | Reset sprite/mouse interaction settings                                         |
808.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
809.     SLSprite(Handle).Mouse.Event = SLNONE '                                                 reset most recent mouse interaction
810.     SLSprite(Handle).Mouse.Xloc = 0 '                                                       reset mouse x coordinate location
811.     SLSprite(Handle).Mouse.Yloc = 0 '                                                       reset mouse y coordinate location
812.     SLSprite(Handle).Mouse.SXloc = 0 '                                                      reset mouse on screen x coordinate
813.     SLSprite(Handle).Mouse.SYloc = 0 '                                                      reset mouse on screen y coordinate
814.     '  _________________________________________________________________________________
815.     ' | Reset sprite collision settings                                                 |
816.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
817.     SLSprite(Handle).Coll.Detect = SLNONE '                                                 reset sprite collision detection method
818.     SLSprite(Handle).Coll.Event = 0 '                                                       reset collision event trigger
819.     SLSprite(Handle).Coll.With = 0 '                                                        reset collision with object identifier
820.     SLSprite(Handle).Coll.Xloc = 0 '                                                        reset collision x coordinate location
821.     SLSprite(Handle).Coll.Yloc = 0 '                                                        reset collision y coordinate location
822.     SLSprite(Handle).Coll.Mask = 0 '                                                        reset mask image surface
823.     SL_MakeSprite = Handle '                                                                return the sprite handle index pointer
824.  
825. END FUNCTION
826.  
827. '----------------------------------------------------------------------------------------------------------------------------------
828. FUNCTION SL_CopySprite (Handle AS INTEGER) '                                                                          SL_CopySprite
829.     '  ___________________________________________________________________________________________________________________________
830.     ' | Creates an identical copy of a sprite and assigns a new handle pointer value.                                             |
831.     ' |---------------------------------------------------------------------------------------------------------------------------|
832.     ' | Usage : NewSprite = SL_CopySPrite(MySPrite)                                                                               |
833.     ' |                                                                                                                           |
834.     ' | Input : Handle = the handle pointer of the sprite being copied                                                            |
835.     ' | Output: a handle pointer value of the new sprite created                                                                  |
836.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
837.     SHARED SLSprite() AS SLSPRITE ' master sprite array
838.     DIM CopyHandle AS INTEGER
839.  
840.     CopyHandle = -1 '                                                                       reset handle array index pointer
841.     DO '                                                                                    cycle through sprite array
842.         CopyHandle = CopyHandle + 1 '                                                       increment handle array index pointer
843.     LOOP UNTIL SLSprite(CopyHandle).InUse = SLFALSE OR CopyHandle = UBOUND(SLSprite) '      leave when suitable array index found
844.     IF SLSprite(CopyHandle).InUse THEN '                                                    is this array index currently in use?
845.         CopyHandle = CopyHandle + 1 '                                                       yes, increase the array index size
846.         REDIM _PRESERVE SLSprite(CopyHandle) AS SLSPRITE '                                  create new index in sprite array
847.     END IF
848.     SLSprite(CopyHandle) = SLSprite(Handle) '                                               copy the entire contents of sprite
849.     SLSprite(CopyHandle).OrigImage = _COPYIMAGE(SLSprite(Handle).OrigImage, 32) '           copy the sprite's original image
850.     IF SLSprite(Handle).OrigMask THEN '                                                     does the sprite being copied have mask?
851.         SLSprite(CopyHandle).OrigMask = _COPYIMAGE(SLSprite(Handle).OrigMask, 32) '         yes, copy sprite's original image mask
852.     END IF
853.     SL_CopySprite = CopyHandle '                                                            return the new sprite's handle pointer
854.  
855. END FUNCTION
856.  
857. '----------------------------------------------------------------------------------------------------------------------------------
858. SUB SL_FreeSprite (Handle AS INTEGER)
859.     '  ___________________________________________________________________________________________________________________________
860.     ' | Removes a sprite from the sprite array and all associated images from memory.                                             |
861.     ' |---------------------------------------------------------------------------------------------------------------------------|
862.     ' | Usage : SL_FreeSprite(MySprite)                                                                                           |
863.     ' |                                                                                                                           |
864.     ' | Input : Handle = the handle pointer of the sprite being removed                                                           |
865.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
866.     SHARED SLSprite() AS SLSPRITE ' master sprite array
867.  
868.     IF SL_ValidSprite(Handle) = SLFALSE THEN SL_Error 1, "SL_FreeSprite" '                  report error if invalid sprite
869.     IF SLSprite(Handle).OrigMask THEN _FREEIMAGE SLSprite(Handle).OrigMask '                free mask image if present
870.     IF SLSprite(Handle).ScrnHardware THEN _FREEIMAGE SLSprite(Handle).ScrnHardware '        free screen hardware image if present
871.     IF SLSprite(Handle).ScrnImage THEN _FREEIMAGE SLSprite(Handle).ScrnImage '              free screen software image if present
872.     _FREEIMAGE SLSprite(Handle).OrigImage '                                                 free original sprite image
873.     IF (Handle = UBOUND(slsprite)) AND (Handle <> 0) THEN '                                 is this the last sprite in array?
874.         REDIM _PRESERVE SLSprite(Handle - 1) AS SLSPRITE '                                  yes, remove last element in array
875.     ELSE '                                                                                  no, this sprite resides somewhere else
876.         SLSprite(Handle).InUse = SLFALSE '                                                  mark the index in array as reusable
877.     END IF
878.  
879. END SUB
880.  
881. '----------------------------------------------------------------------------------------------------------------------------------
882. FUNCTION SL_LoadSheet (Filename AS STRING, CellWidth AS INTEGER, CellHeight AS INTEGER, ClearColor AS _UNSIGNED LONG) 'SL_LoadSheet
883.     '  ___________________________________________________________________________________________________________________________
884.     ' | Load a sprite sheet image and create a _MAPTRIANGLE rotation array to be used for sprite rotation.                        |
885.     ' |---------------------------------------------------------------------------------------------------------------------------|
886.     ' | Usage : SheetName = ("spritesheet.png", 32, 48, _RGB32(255, 0, 255))                                                      |
887.     ' |                                                                                                                           |
888.     ' | Input : filename   = the name of the image file to load as a sprite sheet                                                 |
889.     ' |         CellWidth  = the width of each sprite on the sheet                                                                |
890.     ' |         CellHeight = the height of each sprite on the sheet                                                               |
891.     ' |         ClearColor = the color to use as the transparent layer of the sprite sheet                                        |
892.     ' | Output: An array index that acts as a handle pointer to the newly loaded sprite sheet                                     |
893.     ' |                                                                                                                           |
894.     ' | A .map file will be created with the same name as the image filename provided, "filename.map", that holds precalculated   |
895.     ' | coordinates that _MAPTRIANGLE will use for sprite rotation.                                                               |
896.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
897.     SHARED SLSheet() AS SLSHEET '   master sprite sheet array
898.     SHARED SLMap() AS SLMAP '       master sprite sheet _MAPTRIANGLE coordinate array
899.     DIM Handle AS INTEGER '         index pointer to new sheet
900.     DIM MapFileName AS STRING '     name of .map file where _MAPTRIANGLE coordinates are stored
901.     DIM Degree AS INTEGER '         0 through 359 degree counter
902.     DIM FileNumber AS INTEGER '     next free file handle
903.     DIM Polar AS INTEGER '          counter used for calculating _MAPTRIANGLE x,y coordinate pairs
904.     DIM px(3) AS SINGLE '           _MAPTRIANGLE x coordinates
905.     DIM py(3) AS SINGLE '           _MAPTRIANGLE y coordinates
906.     DIM Xoffset AS INTEGER '        _MAPTRIANGLE x coordinate offset to center image
907.     DIM Yoffset AS INTEGER '        _MAPTRIANGLE y coordinate offset to center image
908.     DIM x AS SINGLE '               rotated x location of a image corner
909.     DIM y AS SINGLE '               rotated y location of a image corner
910.     DIM SINr AS SINGLE '            SIN of image corner rotation
911.     DIM COSr AS SINGLE '            COSINE of image corner rotation
912.     DIM Left AS INTEGER '           new left x coordinate of rotated cell image
913.     DIM Top AS INTEGER '            new top y coordinate of rotated cell image
914.     DIM Right AS INTEGER '          new right x coordinate of rotated cell image
915.     DIM Bottom AS INTEGER '         new bottom y coordinate of rotated cell image
916.     '  _________________________________________________________________________________
917.     ' | Create a new or use existing unused index in sprite sheet array to hold sheet.  |
918.     ' |---------------------------------------------------------------------------------|
919.     ' | When a sprite sheet is removed (SL_RemoveSheet) the array index is marked as    |
920.     ' | unused and can be later reused by another sprite sheet being loaded. If no      |
921.     ' | unused array positions exist then a new array index will be created to hold the |
922.     ' | new sprite sheet's information.                                                 |
923.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
924.     Handle = -1 '                                                                           reset handle array index pointer
925.     DO '                                                                                    cycle through sprite sheet array
926.         Handle = Handle + 1 '                                                               increment handle array index pointer
927.     LOOP UNTIL SLSheet(Handle).InUse = SLFALSE OR Handle = UBOUND(SLSheet) '                leave when suitable array index found
928.     IF SLSheet(Handle).InUse THEN '                                                         is this array index currently in use?
929.         Handle = Handle + 1 '                                                               yes, increase the array index size
930.         REDIM _PRESERVE SLSheet(Handle) AS SLSHEET '                                        create new index in sprite sheet array
931.         REDIM _PRESERVE SLMap(Handle, 359) AS SLMAP '                                       create new index in coordinate array
932.     END IF
933.     '  _________________________________________________________________________________
934.     ' | Load sprite sheet and record basic information about the sheet                  |
935.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
936.     SLSheet(Handle).InUse = SLTRUE '                                                        mark this array index as being used
937.     SLSheet(Handle).Image = _LOADIMAGE(Filename, 32) '                                      load the sprite sheet image
938.     SLSheet(Handle).CellWidth = CellWidth '                                                 record each cell's width
939.     SLSheet(Handle).CellHeight = CellHeight '                                               record each cell's height
940.     IF ClearColor = SLNOTRANSPARENCY THEN '                                                 has sheet transparency been disabled?
941.         SLSheet(Handle).ClearColor = SLNOTRANSPARENCY '                                     yes, record this setting
942.     ELSE '                                                                                  no, set the transparent color of sheet
943.         _CLEARCOLOR ClearColor, SLSheet(Handle).Image '                                     set the sheet's transparent color
944.         SLSheet(Handle).ClearColor = _CLEARCOLOR(SLSheet(Handle).Image) '                   record the sheet's transparent color
945.     END IF
946.     SLSheet(Handle).Columns = _WIDTH(SLSheet(Handle).Image) \ CellWidth '                   record number of cell columns on sheet
947.     SLSheet(Handle).Rows = _HEIGHT(SLSheet(Handle).Image) \ CellHeight '                    record number of cell rows on sheet
948.     SLSheet(Handle).TotalCells = SLSheet(Handle).Columns * SLSheet(Handle).Rows '           record total number of cells on sheet
949.     '  _________________________________________________________________________________
950.     ' | Create or retrieve the _MAPTRIANGLE rotational map file for sprite rotation     |
951.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
952.     MapFileName = LEFT$(Filename, INSTR(Filename, ".")) + "map" '                           create the map file's file name
953.     FileNumber = FREEFILE '                                                                 get the next free file handle
954.     IF _FILEEXISTS(MapFileName) THEN '                                                      does the map file already exist?
955.         '  _____________________________________________________________________________
956.         ' | The file has been previously created. Open it and load its contents.        |
957.         ' |-----------------------------------------------------------------------------|
958.         ' | This is done for speed. Calculations will only need to be performed once    |
959.         ' | per sprite sheet. However, if the sprite sheet's characteristics are ever   |
960.         ' | changed the .map file will need to be deleted to have the new coordinate    |
961.         ' | information calculated and saved. This will be in the documentation.        |
962.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
963.         OPEN MapFileName FOR BINARY AS #FileNumber '                                        yes, open the map file for reading
964.         DO '                                                                                cycle through 360 degrees
965.             GET #FileNumber, , SLMap(Handle, Degree) '                                      get the rotational data for this degree
966.             Degree = Degree + 1 '                                                           increment degree counter
967.         LOOP UNTIL Degree = 360 '                                                           leave when 360 degrees cycled through
968.         CLOSE #FileNumber '                                                                 close the map file
969.     ELSE '                                                                                  no, the map file does not exist
970.         '  _____________________________________________________________________________     _____________________________________
971.         ' | The file must be created. This is the first time the sheet has been loaded. |   | If the .map file were to somehow    |
972.         ' |-----------------------------------------------------------------------------|   | get deleted from the user's drive   |
973.         ' | The original cell width and height        px(0),py(0)           px(3),py(3) |   | it will simply get recreated the    |
974.         ' | are used to calculate the four         ....... +---------------------+      |   | next time the program is executed.  |
975.         ' | corners of the image. These four          ^    |~\_     _MAPTRIANGLE |      |    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
976.         ' | corners are then rotated through 360      |    |   ~\_       #2      |      |
977.         ' | degrees to the new corner locations      cell  |      ~\_            |      |
978.         ' | for _MAPTRIANGLE, and also to           height |         ~\_         |      |
979.         ' | calculate the new width and height        |    |            ~\_      |      |
980.         ' | of the rotated image. These values        |    | _MAPTRIANGLE  ~\_   |      |
981.         ' | are then saved to a .map file for         V    |      #1          ~\_|      |
982.         ' | later retrieval to speed up the        ....... +---------------------+      |
983.         ' | process of _MAPTRIANGLE coordinate        px(1),py(1)           px(2),py(2) |
984.         ' | calculations. This process will only           :                     :      |
985.         ' | need to be performed once per sprite           :<--- cell width ---->:      |
986.         ' | sheet unless the physical character-           :                     :      |
987.         ' | istics of the sprite sheet change.                                          |
988.         '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
989.         OPEN MapFileName FOR BINARY AS #FileNumber '                                        open the map file for writing
990.         Degree = 0 '                                                                        reset the degree counter
991.         DO '                                                                                cycle through 360 degrees
992.             px(0) = -CellWidth / 2 '                                                        reset image corner coordinates
993.             py(0) = -CellHeight / 2
994.             px(1) = px(0)
995.             py(1) = CellHeight / 2
996.             px(2) = CellWidth / 2
997.             py(2) = py(1)
998.             px(3) = px(2)
999.             py(3) = py(0)
1000.             SINr = SIN(-Degree / 57.2957795131) '                                           calculate the SIN of rotation
1001.             COSr = COS(-Degree / 57.2957795131) '                                           calculate the COSINE of rotation
1002.             Left = 0 '                                                                      reset rotated image boundaries
1003.             Top = 0
1004.             Right = 0
1005.             Bottom = 0
1006.             Polar = 0 '                                                                     reset polar coordinate counter
1007.             DO '                                                                            cycle through the 4 polar coordinates
1008.                 x = (px(Polar) * COSr + SINr * py(Polar)) '                                 calculate rotated image x corner
1009.                 y = (py(Polar) * COSr - px(Polar) * SINr) '                                 calculate rotated image y corner
1010.                 px(Polar) = x '                                                             record new corner x location
1011.                 py(Polar) = y '                                                             record new corner y location
1012.                 IF px(Polar) < Left THEN Left = px(Polar) '                                 get smallest left x value seen so far
1013.                 IF px(Polar) > Right THEN Right = px(Polar) '                               get greatest right x value seen so far
1014.                 IF py(Polar) < Top THEN Top = py(Polar) '                                   get smallest top y value seen so far
1015.                 IF py(Polar) > Bottom THEN Bottom = py(Polar) '                             get greatest bottom y value seen so far
1016.                 Polar = Polar + 1 '                                                         increment to next polar coordinate pair
1017.             LOOP UNTIL Polar = 4 '                                                          leave when all four corners processed
1018.             SLMap(Handle, Degree).width = Right - Left + 1 '                                record the width of the rotated image
1019.             SLMap(Handle, Degree).height = Bottom - Top + 1 '                               record the height of the rotated image
1020.             Xoffset = SLMap(Handle, Degree).width \ 2 '                                     calculate x offset to center image
1021.             Yoffset = SLMap(Handle, Degree).height \ 2 '                                    calculate y offset to center image
1022.             SLMap(Handle, Degree).px0 = INT(px(0)) + Xoffset '                              record all 4 centered coordinate pairs
1023.             SLMap(Handle, Degree).px1 = INT(px(1)) + Xoffset
1024.             SLMap(Handle, Degree).px2 = INT(px(2)) + Xoffset
1025.             SLMap(Handle, Degree).px3 = INT(px(3)) + Xoffset
1026.             SLMap(Handle, Degree).py0 = INT(py(0)) + Yoffset
1027.             SLMap(Handle, Degree).py1 = INT(py(1)) + Yoffset
1028.             SLMap(Handle, Degree).py2 = INT(py(2)) + Yoffset
1029.             SLMap(Handle, Degree).py3 = INT(py(3)) + Yoffset
1030.             PUT #1, , SLMap(Handle, Degree) '                                               save the rotational data for the degree
1031.             Degree = Degree + 1 '                                                           increment the degree counter
1032.         LOOP UNTIL Degree = 360 '                                                           leave when 360 degrees cycled through
1033.         CLOSE #FileNumber '                                                                 close the map file
1034.     END IF
1035.     '  _________________________________________________________________________________
1036.     ' | Return the array index as a pointer to this new sprite sheet                    |
1037.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1038.     SL_LoadSheet = Handle '                                                                 return array index pointer to new sheet
1039.  
1040. END FUNCTION
1041.  
1042. '----------------------------------------------------------------------------------------------------------------------------------
1043. SUB SL_GetCellCoordinates (Sheet AS INTEGER, Cell AS INTEGER, Rect AS SLRECT) '                               SL_GetCellCoordinates
1044.     '  ___________________________________________________________________________________________________________________________
1045.     ' | Returns the rectangular coordinates of a cell given the sprite sheet that it belongs to.                                  |
1046.     ' |---------------------------------------------------------------------------------------------------------------------------|
1047.     ' | Usage : SL_GetCellCoordinates MySheet, CellNumber, RectStructure                                                          |
1048.     ' |                                                                                                                           |
1049.     ' | Input : Sheet = the handle pointer of the sheet the cell resides in                                                       |
1050.     ' |         Cell  = the cell number to return the coordinates of                                                              |
1051.     ' |         Rect  = the rectangular structure (SLRECT) that the resuls are returned in                                        |
1052.     ' |                                                                                                                           |
1053.     ' | Output: the values in Rect will be modified with the coordinate information:                                              |
1054.     ' |         Rect.left   = left   x coordinate of cell                                                                         |
1055.     ' |         Rect.top    = top    y coordinate of cell                                                                         |
1056.     ' |         Rect.right  = right  x coordinate of cell                                                                         |
1057.     ' |         Rect.bottom = bottom y coordinate of cell                                                                         |
1058.     ' |         Rect.width  = width of cell                                                                                       |
1059.     ' |         Rect.height = height of cell                                                                                      |
1060.     ' |          _________________________________________________________                                                        |
1061.     ' | Note  : | ** INTERNAL USE ONLY ** not to be used by programmer ** |                                                       |
1062.     ' |          ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~                                                        |
1063.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1064.     SHARED SLSheet() AS SLSHEET '   master sprite sheet array
1065.     DIM Column AS INTEGER '         the column the cell resides in
1066.     DIM Row AS INTEGER '            the row the cell resides in
1067.     '  _________________________________________________________________________________
1068.     ' | Calculate the row and column the sheet's cell reside in                         |
1069.     ' |---------------------------------------------------------------------------------|
1070.     ' | Sprite images within a sprite sheet are seen as cells with equal widths and     |
1071.     ' | heights. The cells are numbered beginning at the top left corner and counting   |
1072.     ' | to the right, beginning again at the next row down when the end of the current  |
1073.     ' | row has been reached.                                                           |
1074.     ' |                              <----- COLUMNS ----->                              |
1075.     ' |                    1         2         3         4         5 ....               |
1076.     ' |               +-------------------------------------------------+               |
1077.     ' |               |         |         |         |         |         |               |
1078.     ' |        ^    1 | cell 01 | cell 02 | cell 03 | cell 04 | cell 05 |               |
1079.     ' |        |      |         |         |         |         |         |               |
1080.     ' |        |      +-------------------------------------------------+               |
1081.     ' |        |      |         |         |         |         |         |               |
1082.     ' |      ROWS   2 | cell 06 | cell 07 | cell 08 | cell 09 | cell 10 |               |
1083.     ' |        |      |         |         |         |         |         |               |
1084.     ' |        |      +-------------------------------------------------+               |
1085.     ' |        |      |         |         |         |         |         |               |
1086.     ' |        V    3 | cell 11 | cell 12 | cell 13 | cell 14 | cell 15 |               |
1087.     ' |             : |         |         |         |         |         |               |
1088.     ' |             : +-------------------------------------------------+               |
1089.     ' |                                                                                 |
1090.     ' | Modulus division using the cell number will yield the current column a cell     |
1091.     ' | resides in, execpt for the far right column. The result of a modulus division   |
1092.     ' | with a cell in the far right column will produce 0 (zero). A result of zero can |
1093.     ' | then be interpreted as the cell being in the column farthest to the right.      |
1094.     ' |                                                                                 |
1095.     ' | Once you have the column a cell resides in you can then subract that value from |
1096.     ' | the cell, divide that result by the total number of columns and add 1 to get    |
1097.     ' | the row a cell resides in.                                                      |
1098.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1099.     Column = Cell MOD SLSheet(Sheet).Columns '                                              MOD remainder equals the column number
1100.     IF Column = 0 THEN Column = SLSheet(Sheet).Columns '                                    unless it's 0, then column is greatest
1101.     Row = (Cell - Column) / SLSheet(Sheet).Columns + 1 '                                    calculate the row number from column
1102.     '  _________________________________________________________________________________
1103.     ' | Calculate and return the rectangular coordinates of the sheet's cell            |
1104.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1105.     Rect.Left = (Column - 1) * SLSheet(Sheet).CellWidth '                                   calculate left x coordinate of cell
1106.     Rect.Top = (Row - 1) * SLSheet(Sheet).CellHeight '                                      calculate top y coordinate of cell
1107.     Rect.Right = Rect.Left + SLSheet(Sheet).CellWidth - 1 '                                 calculate right x coordinate of cell
1108.     Rect.Bottom = Rect.Top + SLSheet(Sheet).CellHeight - 1 '                                calculate bottom y coordinate of cell
1109.     Rect.Width = SLSheet(Sheet).CellWidth '                                                 report cell width
1110.     Rect.Height = SLSheet(Sheet).CellHeight '                                               report cell height
1111.  
1112. END SUB
1113.  
1114. '----------------------------------------------------------------------------------------------------------------------------------
1115. FUNCTION SL_FixDegree (Degree AS INTEGER) '                                                                            SL_FixDegree
1116.     '  ___________________________________________________________________________________________________________________________
1117.     ' | Returns a corrected degree value of 0 to 359 given the value passed in.                                                   |
1118.     ' |---------------------------------------------------------------------------------------------------------------------------|
1119.     ' | Usage : ValidDegree = SL_FixDegree(720)                                                                                   |
1120.     ' |                                                                                                                           |
1121.     ' | Input : Degree = the degree value to correct                                                                              |
1122.     ' | Output: the corrected degree value between 0 and 359 degrees                                                              |
1123.     ' | Credit: This function uses code contributed by CodeGuy - https://www.qb64.org/forum/index.php?topic=537.15                |
1124.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1125.     DIM Deg AS INTEGER '            degree value supplied
1126.  
1127.     Deg = Degree MOD 360 '                                                                  get -359 to 359
1128.     IF Deg < 0 THEN '                                                                       need to make positive?
1129.         SL_FixDegree = Deg + 360 '                                                          yes, correct value and return degree
1130.     ELSE '                                                                                  no correction needed
1131.         SL_FixDegree = Deg '                                                                return degree
1132.     END IF
1133.  
1134. END FUNCTION
1135.  
1136. '----------------------------------------------------------------------------------------------------------------------------------
1137. FUNCTION SL_PPDistance (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER) '                                 SL_PPDistance
1138.     '  ___________________________________________________________________________________________________________________________
1139.     ' | Calculates the distance in pixels between any two coordinate pair points.                                                 |
1140.     ' |---------------------------------------------------------------------------------------------------------------------------|
1141.     ' | Usage : Distance = SL_PPDistance(100, 100, 200, 200)                                                                      |
1142.     ' |                                                                                                                           |
1143.     ' | Input : x1 = x coordinate location of first point                                                                         |
1144.     ' |         y1 = y coordinate location of first point                                                                         |
1145.     ' |         x2 = x coordinate location of second point                                                                        |
1146.     ' |         y2 = y coordinate location of second point                                                                        |
1147.     ' | Output: the distance in pixels between the two coordinate pair points                                                     |
1148.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1149.     DIM SideA AS INTEGER '          side A of right triangle
1150.     DIM SideB AS INTEGER '          side B of right triangle
1151.     '  _________________________________________________________________________________
1152.     ' | Use Pythagoras to calculate the distance between the two points.                |
1153.     ' |---------------------------------------------------------------------------------|
1154.     ' | By using the Pythagorean Theorum                               x1,y1            |
1155.     ' | Aý + Bý = Cý the distance between any                           /|              |
1156.     ' | two points can be calculated by                               /  |              |
1157.     ' | creating a right triangle between the                       /    |              |
1158.     ' | two points, solving for sides A and B,        hypotenuse  /      |              |
1159.     ' | and then solving for side C, the                SIDE C  /        | SIDE B       |
1160.     ' | hypotenuse. The following formula can                 /          |              |
1161.     ' | be utilized:                                        /            |              |
1162.     ' |       _________                                   /              |              |
1163.     ' |  C = û Aý + Bý                                  /               _|              |
1164.     ' |                                               /________________I_|              |
1165.     ' |                                            x2,y2     SIDE A                     |
1166.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1167.     SideA = x1 - x2 '                                                                       calculate length of side A
1168.     SideB = y1 - y2 '                                                                       calculate length of side B
1169.     SL_PPDistance = INT(SQR(SideA * SideA + SideB * SideB)) '                               return length of side C (hypotenuse)
1170.  
1171. END FUNCTION
1172.  
1173. '----------------------------------------------------------------------------------------------------------------------------------
1174. FUNCTION SL_SSDistance (Handle1 AS INTEGER, Handle2 AS INTEGER) '                                                     SL_SSDistance
1175.     '  ___________________________________________________________________________________________________________________________
1176.     ' | Calculates the distance in pixels between any two supplied sprites.                                                       |
1177.     ' |---------------------------------------------------------------------------------------------------------------------------|
1178.     ' | Usage : Distance = SL_SSDistance(Sprite1, Sprite2)                                                                        |
1179.     ' |                                                                                                                           |
1180.     ' | Input : Handle1 = the handle pointer name of first sprite                                                                 |
1181.     ' |         Handle2 = the handle pointer name of second sprite                                                                |
1182.     ' | Output: the distance in pixels between the two supplied sprites                                                           |
1183.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1184.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1185.     '  _________________________________________________________________________________
1186.     ' | Pass the sprite coordinates to SL_PPDistance to use Pythagoras to calculate.    |
1187.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1188.     SL_SSDistance = SL_PPDistance(SLSprite(Handle1).Centerx, SLSprite(Handle1).Centery,_
1189.                                   SLSprite(Handle2).Centerx, SLSprite(Handle2).Centery) '   return distance between the sprites
1190.  
1191. END FUNCTION
1192.  
1193. '----------------------------------------------------------------------------------------------------------------------------------
1194. FUNCTION SL_SPDistance (Handle AS INTEGER, x AS INTEGER, y AS INTEGER) '                                              SL_SPDistance
1195.     '  ___________________________________________________________________________________________________________________________
1196.     ' | Calculates the distance in pixels between a sprite and a coordinate point.                                                |
1197.     ' |---------------------------------------------------------------------------------------------------------------------------|
1198.     ' | Usage : Distance = SL_SPDistance(Sprite, 100, 100)                                                                        |
1199.     ' |                                                                                                                           |
1200.     ' | Input : Handle = the handle pointer name of the sprite                                                                    |
1201.     ' |         x      = the x coordinate value of the point                                                                      |
1202.     ' |         y      = the y coordinate value of the point                                                                      |
1203.     ' | Output: the distance in pixels between the sprite and the supplied coordinate point                                       |
1204.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1205.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1206.     '  _________________________________________________________________________________
1207.     ' | Pass the sprite coordinates and supplied coordinate to SL_PPDistance to use     |
1208.     ' | Pythagoras to calculate.                                                        |
1209.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1210.     SL_SPDistance = SL_PPDistance(SLSprite(Handle).Centerx, SLSprite(Handle).Centery, x, y) 'return distance to point from sprite
1211.  
1212. END FUNCTION
1213.  
1214. '----------------------------------------------------------------------------------------------------------------------------------
1215. FUNCTION SL_PPAngle (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER) '                                       SL_PPAngle
1216.     '  ___________________________________________________________________________________________________________________________
1217.     ' | Calculates the angle (0 to 359) between two coordinate pairs.                                                             |
1218.     ' |---------------------------------------------------------------------------------------------------------------------------|
1219.     ' | Usage : Angle = SL_PPAngle(100, 100, 200, 200)                                                                            |
1220.     ' |                                                                                                                           |
1221.     ' | Input : x1 = x coordinate location of first point                                                                         |
1222.     ' |         y1 = y coordinate location of first point                                                                         |
1223.     ' |         x2 = x coordinate location of second point                                                                        |
1224.     ' |         y2 = y coordinate location of second point                                                                        |
1225.     ' | Output: the angle from x1,y1 to x2,y2.                                                                                    |
1226.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1227.     DIM angle AS INTEGER '          angle from x1,y1 to x2,y2
1228.  
1229.     IF y1 = y2 THEN '                                                                       both y values same?
1230.         IF x1 = x2 THEN '                                                                   yes, both x values same?
1231.             EXIT FUNCTION '                                                                 yes, there is no angle (0), leave
1232.         END IF
1233.         IF x2 > x1 THEN '                                                                   is second x to the right of first x?
1234.             SL_PPAngle = 90 '                                                               yes, the angle must be 90 degrees
1235.         ELSE '                                                                              no, second x is to the left of first x
1236.             SL_PPAngle = 270 '                                                              the angle must be 270 degrees
1237.         END IF
1238.         EXIT FUNCTION '                                                                     leave function, angle computed
1239.     END IF
1240.     IF x1 = x2 THEN '                                                                       both x values same?
1241.         IF y2 > y1 THEN '                                                                   yes, is second y lower than first y?
1242.             SL_PPAngle = 180 '                                                              yes, the angle must be 180
1243.         END IF
1244.         EXIT FUNCTION '                                                                     leave function, angle computed
1245.     END IF
1246.     angle = ATN((x2 - x1) / (y2 - y1)) * -57.2957795131 '                                   calculate initial angle
1247.     IF y2 < y1 THEN '                                                                       is second y higher than first y?
1248.         IF x2 > x1 THEN '                                                                   yes, is second x to right of first x?
1249.             SL_PPAngle = angle '                                                            yes, angle needs no adjustment
1250.         ELSE '                                                                              no, second x is to left of first x
1251.             SL_PPAngle = angle + 360 '                                                      adjust angle accordingly
1252.         END IF
1253.     ELSE '                                                                                  no, second y is lower than first y
1254.         SL_PPAngle = angle + 180 '                                                          adjust angle accordingly
1255.     END IF
1256.  
1257. END FUNCTION
1258.  
1259. '----------------------------------------------------------------------------------------------------------------------------------
1260. FUNCTION SL_SSAngle (Handle1 AS INTEGER, Handle2 AS INTEGER) '                                                           SL_SSAngle
1261.     '  ___________________________________________________________________________________________________________________________
1262.     ' | Calculates the angle between any two supplied sprites.                                                                    |
1263.     ' |---------------------------------------------------------------------------------------------------------------------------|
1264.     ' | Usage : Angle = SL_SSAngle(Sprite1, Sprite2)                                                                              |
1265.     ' |                                                                                                                           |
1266.     ' | Input : Handle1 = the handle pointer name of first sprite                                                                 |
1267.     ' |         Handle2 = the handle pointer name of second sprite                                                                |
1268.     ' | Output: the angle from sprite1 to sprite2                                                                                 |
1269.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1270.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1271.     '  _________________________________________________________________________________
1272.     ' | Pass the sprite coordinates to SL_PPAngle to calculate the angle.               |
1273.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1274.     SL_SSAngle = SL_PPAngle(SLSprite(Handle1).Centerx, SLSprite(Handle1).Centery,_
1275.                             SLSprite(Handle2).Centerx, SLSprite(Handle2).Centery) '         return the angle between the sprites
1276.  
1277. END FUNCTION
1278.  
1279. '----------------------------------------------------------------------------------------------------------------------------------
1280. FUNCTION SL_SPAngle (Handle AS INTEGER, x AS INTEGER, y AS INTEGER) '                                                    SL_SPAngle
1281.     '  ___________________________________________________________________________________________________________________________
1282.     ' | Calculates the angle between a sprite an a supplied coordinate pair.                                                      |
1283.     ' |---------------------------------------------------------------------------------------------------------------------------|
1284.     ' | Usage : Angle = SL_SPAngle(Sprite, 100, 100)                                                                              |
1285.     ' |                                                                                                                           |
1286.     ' | Input : Handle = the handle pointer name of the sprite                                                                    |
1287.     ' |         x      = the x coordinate value of the point                                                                      |
1288.     ' |         y      = the y coordinate value of the point                                                                      |
1289.     ' | Output: the angle from the sprite to the supplied coordinate pair.                                                        |
1290.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1291.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1292.     '  _________________________________________________________________________________
1293.     ' | Pass the sprite coordinates to SL_PPAngle to calculate the angle.               |
1294.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1295.     SL_SPAngle = SL_PPAngle(SLSprite(Handle).Centerx, SLSprite(Handle).Centery, x, y) '     return the angle from sprite to point
1296.  
1297. END FUNCTION
1298.  
1299. '----------------------------------------------------------------------------------------------------------------------------------
1300. SUB SL_SpriteSet (Handle AS INTEGER, Action AS INTEGER, Value AS LONG) ' (MULTI-FUNCTION COMMAND)                      SL_SpriteSet
1301.     '  ___________________________________________________________________________________________________________________________
1302.     ' | Sets various aspects of sprite depending on action and value provided.                                                    |
1303.     ' |---------------------------------------------------------------------------------------------------------------------------|
1304.     ' | Usage : SL_SpriteSet MySPrite, SLZOOM, 150                                                                                |
1305.     ' |                                                                                                                           |
1306.     ' | Input : Handle = the handle pointer name of the sprite                                                                    |
1307.     ' |         Action = the setting to be acted upon                                                                             |
1308.     ' |         Value  = the new setting value                                                                                    |
1309.     ' |                                                                                                                           |
1310.     ' | Valid Action and Value combinations:                                                                                      |
1311.     ' |                                                                                                                           |
1312.     ' |     Action           Value(s)                                   Description                                               |
1313.     ' | --------------  ------------------  ------------------------------------------------------------------------------------- |
1314.     ' | SLZOOM          1 - 32767           Sets the zoom level for a sprite (100 = 100%, 200 = 200%, etc..)                      |
1315.     ' | SLFLIP          SLNONE              reset sprite's orientation to normal (no flipping)                                    |
1316.     ' |                 SLVERTICAL          flips a sprite vertically                                                             |
1317.     ' |                 SLHORIZONTAL        flips a sprite horizontally                                                           |
1318.     ' |                 SLBOTH              flips a sprite both horizontally and vertically                                       |
1319.     ' | SLVISIBLE       SLTRUE              sets the sprite as visible on screen                                                  |
1320.     ' |                 SLFALSE             sets the sprite as invisible (will not be shown on screen)                            |
1321.     ' | SLLAYER         0 - max layers      sets the layer associated with the sprite                                             |
1322.     ' | SLSCORE         any LONG INT        sets the score associated with a sprite                                               |
1323.     ' | SLAUTOANIMATE   SLTRUE              enables sprite auto-animation                                                         |
1324.     ' |                 SLFALSE             disables sprite auto-animation                                                        |
1325.     ' | SLFROMCELL      1 - max cells       sets the sprite's animation sequence starting cell number (must be less than ending)  |
1326.     ' | SLTOCELL        1 - max cells       sets the sprite's animation sequence ending cell number (must be greater than start)  |
1327.     ' | SLANIMATEDIR    SLFORWARD           animation sequence will proceed from start to end then recylce back to start          |
1328.     ' |                 SLBACKWARD          animation sequence will proceed from end to start then recycle back to end            |
1329.     ' |                 SLBACKFORTH         animation sequence will proceed SLFORWARD, then SLBACKWARD, then recyle to SLFORWARD  |
1330.     ' | SLFRAMERATE     1 - global rate     sets the local independent frame rate of the sprite                                   |
1331.     ' | SLAUTOMOTION    SLTRUE              enables sprite auto-motion                                                            |
1332.     ' |                 SLFALSE             disables sprite auto-motion                                                           |
1333.     ' | SLMOTIONANGLE   -359 to 359         sets the sprite's direction of motion (SLXDIR and SLYDIR computed from this)          |
1334.     ' | SLXDIR          -32768 - 32767      sets the sprite's x motion vextor (used to over-ride SLMOTIONANGLE if desired)        |
1335.     ' | SLYDIR          -32768 - 32767      sets the sprite's y motion vector (used to over-ride SLMOTIONANGLE if desired)        |
1336.     ' | SLAUTOROTATE    SLTRUE              enables sprite auto-rotation                                                          |
1337.     ' |                 SLFALSE             disables sprite auto-rotation                                                         |
1338.     ' | SLROTATEANGLE   -359 to 359         set rotation angle of sprite                                                          |
1339.     ' | SLROTATESPEED   -359 to 359         set the rotation rate (or spin) of a sprite                                           |
1340.     ' | SLDETECTION     SLNONE              disable sprite collision detection                                                    |
1341.     ' |                 SLRECTANGLE         enable rectangular sprite collision detection                                         |
1342.     ' |                 SLCIRCLE            enable circular sprite collision detection                                            |
1343.     ' |                 SLPIXEL             enable pixel-perfect sprite collision detection                                       |
1344.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1345.     SHARED SLSheet() AS SLSHEET '   master sprite sheet array
1346.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1347.     SHARED SLGlobal AS SLGLOBAL '   global variables
1348.  
1349.     IF SL_ValidSprite(Handle) = SLFALSE THEN SL_Error 1, "SL_SpriteSet" '                   report error if invalid sprite
1350.     SELECT CASE Action '                                                                    which value will be set?
1351.         CASE SLZOOM '                                                                       set sprite zoom level
1352.             '  _________________________________________________________________________
1353.             ' | Valid values: 1 through 32767                                           |
1354.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1355.             IF (Value < 1) OR (Value > 32767) THEN SL_Error 2, "SL_SpriteSet" '             report error if invalid zoom level
1356.             SLSprite(Handle).Zoom = Value '                                                 set sprite's zoom level
1357.         CASE SLFLIP '                                                                       set sprite flipping behavior
1358.             '  _________________________________________________________________________
1359.             ' | Valid values: SLNONE, SLVERTICAL, SLHORIZONTAL, SLBOTH                  |
1360.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1361.             IF (Value < SLNONE) OR (Value > SLBOTH) THEN SL_Error 3, "SL_SpriteSet" '       report error if invalid flip setting
1362.             SLSprite(Handle).Flipped = Value '                                              set sprite's flipping behavior
1363.         CASE SLVISIBLE '                                                                    set sprite visibility
1364.             '  _________________________________________________________________________
1365.             ' | Valid values: SLTRUE, SLFALSE                                           |
1366.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1367.             IF (Value <> SLFALSE) AND (Value <> SLTRUE) THEN SL_Error 4, "SL_SpriteSet" '   reprt error if invalid visible setting
1368.             SLSprite(Handle).Visible = Value '                                              set sprite's visibility
1369.         CASE SLLAYER '                                                                      set layer sprite belongs to
1370.             '  _________________________________________________________________________
1371.             ' | Valid values: 0 through UBOUND(SLLayers)                                |
1372.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1373.             IF (Value < 0) OR (Value > SLGlobal.Layers) THEN SL_Error 5, "SL_SpriteSet" '   report error if invalid layer requested
1374.             SLSprite(Handle).Layer = Value '                                                set sprite's layer
1375.         CASE SLSCORE '                                                                      set score value of sprite
1376.             '  _________________________________________________________________________
1377.             ' | Valid values: any number in LONG integer range                          |
1378.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1379.             SLSprite(Handle).Score = Value '                                                set sprite's score
1380.         CASE SLAUTOANIMATE '                                                                enable or disable auto animation
1381.             '  _________________________________________________________________________
1382.             ' | Valid values: SLTRUE, SLFALSE                                           |
1383.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1384.             IF (Value <> SLFALSE) AND (Value <> SLTRUE) THEN SL_Error 6, "SL_SpriteSet" '   report error if invalid auto-motion
1385.             SLSprite(Handle).Anim.Auto = Value '                                            set sprite's auto-motion
1386.         CASE SLFROMCELL '                                                                   set animation starting cell
1387.             '  _________________________________________________________________________
1388.             ' | Valid values: 1 through total number of cells on sheet                  |
1389.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1390.             IF (Value < 1) OR (Value > SLSheet(SLSprite(Handle).OrigSheet).TotalCells) THEN 'invalid cell requested?
1391.                 SL_Error 7, "SL_SpriteSet" '                                                yes, report error
1392.             END IF
1393.             SLSprite(Handle).Anim.FromCell = Value '                                        set sprite's animation start cell
1394.         CASE SLTOCELL '                                                                     set animation ending cell
1395.             '  _________________________________________________________________________
1396.             ' | Valid values: 1 through total number of cells on sheet                  |
1397.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1398.             IF (Value < 1) OR (Value > SLSheet(SLSprite(Handle).OrigSheet).TotalCells) OR _
1399.                (Value <= SLSprite(Handle).Anim.FromCell) THEN '                             invalid cell requested?
1400.                 SL_Error 7, "SL_SpriteSet" '                                                yes, report error
1401.             END IF
1402.             SLSprite(Handle).Anim.ToCell = Value '                                          set sprite's animation end cell
1403.         CASE SLANIMATEDIR '                                                                 set direction of animation sequence
1404.             '  _________________________________________________________________________
1405.             ' | Valid values: SLFORWARD, SLBACKWARD, SLBACKFORTH                        |
1406.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1407.             IF (Value < SLFORWARD) OR (Value > SLBACKFORTH) THEN SL_Error 8, "SL_SpriteSet" 'report error if invalid direction
1408.             SLSprite(Handle).Anim.Direction = Value '                                       set sprite's animation direction
1409.         CASE SLFRAMERATE '                                                                  set local animation frame rate
1410.             '  _________________________________________________________________________
1411.             ' | Valid values: 1 through global frame rate                               |
1412.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1413.             IF (Value < 1) OR (Value > SLGlobal.FrameRate) THEN SL_Error 9, "SL_SpriteSet" 'report error if invalid frame rate
1414.             SLSprite(Handle).Anim.FrameRate = Value '                                       set sprite's local frame rate
1415.         CASE SLAUTOMOTION '                                                                 enable or disable auto motion
1416.             '  _________________________________________________________________________
1417.             ' | Valid values: SLTRUE, SLFALSE                                           |
1418.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1419.             IF (Value <> SLFALSE) AND (Value <> SLTRUE) THEN SL_Error 10, "SL_SpriteSet" '  report error if invalid auto motion
1420.             SLSprite(Handle).Move.Auto = Value '                                            set sprite's auto motion
1421.         CASE SLMOTIONANGLE '                                                                set angle in degrees of motion
1422.             '  _________________________________________________________________________
1423.             ' | Valid values: -359 through 359                                          |
1424.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1425.             SLSprite(Handle).Move.Degree = SL_FixDegree(Value) '                            set sprite's angle of motion
1426.         CASE SLXDIR '                                                                       set x motion direction vector
1427.             '  _________________________________________________________________________
1428.             ' | Valid values: -32768 through 32767                                      |
1429.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1430.             IF (Value < -32768) OR (Value > 32767) THEN SL_Error 11, "SL_SpriteSet" '       report error if invalid x vector value
1431.             SLSprite(Handle).Move.Xdir = Value '                                            set sprite's x vector
1432.         CASE SLYDIR '                                                                       set y motion direction vector
1433.             '  _________________________________________________________________________
1434.             ' | Valid values: -32768 through 32767                                      |
1435.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1436.             IF (Value < -32768) OR (Value > 32767) THEN SL_Error 12, "SL_SpriteSet" '       report error if invalid y vector value
1437.             SLSprite(Handle).Move.Ydir = Value '                                            set sprite's y vector
1438.         CASE SLAUTOROTATE '                                                                 enable or disable auto rotation
1439.             '  _________________________________________________________________________
1440.             ' | Valid values: SLTRUE, SLFALSE                                           |
1441.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1442.             IF (Value <> SLFALSE) AND (Value <> SLTRUE) THEN SL_Error 13, "SL_SpriteSet" '  report error if invalid auto rotation
1443.             SLSprite(Handle).Spin.Auto = Value '                                            set sprite's auto rotation
1444.         CASE SLROTATEANGLE '                                                                set angle in degrees of rotation
1445.             '  _________________________________________________________________________
1446.             ' | Valid values: -359 through 359                                          |
1447.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1448.             SLSprite(Handle).Spin.Degree = SL_FixDegree(Value) '                            set sprite's angle of rotation
1449.         CASE SLROTATESPEED '                                                                set spin speed of rotation
1450.             '  _________________________________________________________________________
1451.             ' | Valid values: -359 through 359                                          |
1452.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1453.             IF ABS(Value) > 359 THEN SL_Error 14, "SL_SpriteSet" '                          report error if invalid rotate speed
1454.             SLSprite(Handle).Spin.Rate = Value '                                            set sprite's spin rate
1455.         CASE SLDETECTION '                                                                  set sprite collision detection method
1456.             '  _________________________________________________________________________
1457.             ' | Valid values: SLNONE, SLRECTANGLE, SLCIRCLE, SLPIXEL                    |
1458.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1459.             IF (Value < SLNONE) OR (Value > SLPIXEL) THEN SL_Error 15, "SL_SpriteSet" '     report error if invalid detection
1460.             SLSprite(Handle).Coll.Detect = Value '                                          set sprite's collision detection method
1461.         CASE ELSE
1462.             SL_Error 16, "SL_SpriteSet" '                                                   report invalid use of command
1463.     END SELECT
1464.  
1465. END SUB
1466.  
1467. '----------------------------------------------------------------------------------------------------------------------------------
1468. FUNCTION SL_SpriteGet (Handle AS INTEGER, Action AS INTEGER) ' (MULTI-FUNCTION COMMAND)                                SL_SpriteGet
1469.     '  ___________________________________________________________________________________________________________________________
1470.     ' | Gets various aspects of a sprite depending on the action provided.                                                        |
1471.     ' |---------------------------------------------------------------------------------------------------------------------------|
1472.     ' | Usage : Setting = SL_SpriteGet(MySprite, SLZOOM)                                                                          |
1473.     ' |                                                                                                                           |
1474.     ' | Input : Handle = the handle pointer name of the sprite                                                                    |
1475.     ' |         Action = the setting to be acted upon                                                                             |
1476.     ' | Output: A return value based on the setting to obtain a value from                                                        |
1477.     ' |                                                                                                                           |
1478.     ' | Valid Actions and their return value(s):                                                                                  |
1479.     ' |                                                                                                                           |
1480.     ' |     Action       Return Value(s)                                Description                                               |
1481.     ' | --------------  ------------------  ------------------------------------------------------------------------------------- |
1482.     ' | SLZOOM          1 - 32767           retrieve the current zoom level of the sprite (100 = 100%, 200 = 200%, etc..)         |
1483.     ' | SLFLIP          SLNONE              sprite flipping disabled                                                              |
1484.     ' |                 SLVERTICAL          sprite set to flip vertically                                                         |
1485.     ' |                 SLHORIZONTAL        sprite set to flip horizontally                                                       |
1486.     ' |                 SLBOTH              sprite set to flip vertically and horizontally                                        |
1487.     ' | SLVISIBLE       SLTRUE              sprite is set to be visible on screen                                                 |
1488.     ' |                 SLFALSE             sprite is set to be invisible                                                         |
1489.     ' | SLLAYER         1 to max layers     the layer a sprite belongs to                                                         |
1490.     ' | SLSCORE         Any LONG integer    the score associated with the sprite                                                  |
1491.     ' | SLLEFT          -32768 to 32767     the left x coordinate of the sprite                                                   |
1492.     ' | SLTOP           -32768 to 32767     the top y coordinate of the sprite                                                    |
1493.     ' | SLRIGHT         -32768 to 32767     the right x coordinate of the sprite                                                  |
1494.     ' | SLBOTTOM        -32768 to 32767     the bottom y coordinate of the sprite                                                 |
1495.     ' | SLWIDTH         1 to 32767          the width of the sprite                                                               |
1496.     ' | SLHEIGHT        1 to 32767          the height of the sprite                                                              |
1497.     ' | SLCENTERX       1 to 16382          the center x coordinate of the sprite                                                 |
1498.     ' | SLCENTERY       1 to 16382          the center y coordinate of the sprite                                                 |
1499.     ' | SLFRAMERATE     1 to global rate    the current independent animation frame rate of the sprite                            |
1500.     ' | SLAUTOANIMATE   SLTRUE              auto-animation is enabled for the sprite                                              |
1501.     ' |                 SLFALSE             auto-animation is disabled for the sprite                                             |
1502.     ' | SLFROMCELL      1 to max cells      the sprite's animation start cell (must be less than SLTOCELL)                        |
1503.     ' | SLTOCELL        1 to max cells      the sprite's animation end cell (must be greater than SLFROMCELL)                     |
1504.     ' | SLANIMATEDIR    SLFORWARD           the sprite's animation will proceed from start to end cell then back to start         |
1505.     ' |                 SLBACKWARD          the sprite's animation will proceed from end to start cell then back to end           |
1506.     ' |                 SLBACKFORTH         the sprite's animation will proceed from start to end then end to start               |
1507.     ' | SLAUTOMOTION    SLTRUE              auto-motion is enabled for the sprite                                                 |
1508.     ' |                 SLFALSE             auto-motion is disabled for the sprite                                                |
1509.     ' | SLMOTIONANGLE   0 to 359            the sprite's current angle of motion                                                  |
1510.     ' | SLXDIR          -32768 to 32767     the sprite's current x motion vector                                                  |
1511.     ' | SLYDIR          -32768 to 32767     the sprite's current y motion vector                                                  |
1512.     ' | SLAUTOROTATE    SLTRUE              auto-rotation is enabled for the sprite                                               |
1513.     ' |                 SLFALSE             auto-rotation is disabled for the sprite                                              |
1514.     ' | SLROTATEANGLE   0 to 359            the sprite's current rotation angle                                                   |
1515.     ' | SLROTATESPEED   0 to 359            the sprite's current spin rate                                                        |
1516.     ' | SLDETECTION     SLNONE              collision detection for the sprite is disabled                                        |
1517.     ' |                 SLRECTANGLE         collision detection is set to rectangle collsiion                                     |
1518.     ' |                 SLCIRCLE            collision detection is set for circular collision                                     |
1519.     ' |                 SLPIXEL             collsiion detection is set for pixel-perfect collision                                |
1520.     ' | SLCOLLISION     SLTRUE              this sprite has collided with another object                                          |
1521.     ' |                 SLFALSE             no collisions have been detected with this sprite                                     |
1522.     ' | SLCOLLIDEWITH   1 to max sprites    the sprite has collided with this sprite                                              |
1523.     ' |                 SLNONE              no other sprite has been collided with                                                |
1524.     ' | SLCOLLIDEX      -32768 to 32767     the x coordinate location of sprite collision                                         |
1525.     ' | SLCOLLIDEY      -32768 to 32767     the y coordinate location of sprite collision                                         |
1526.     ' | SLMOUSE         SLNONE              no interaction with the mouse pointer has been recorded                               |
1527.     ' |                 SLLEFTCLICK         the left mouse button was clicked while on the sprite                                 |
1528.     ' |                 SLRIGHTCLICK        the right mouse button was clicked while on the sprite                                |
1529.     ' |                 SLMIDDLECLICK       the middle mouse button was clicked while on the sprite                               |
1530.     ' |                 SLHOVER             the mouse pointer is currently hovering over the sprite                               |
1531.     ' | SLMOUSEX        0 - screen width-1  the current mouse x location on the screen in relation to the sprite                  |
1532.     ' | SLMOUSEY        0 - screen height-1 the current mouse y location on the screen in relation to the sprite                  |
1533.     ' | SLSPRITEMOUSEX  sprite left - right the current mouse x location on the sprite                                            |
1534.     ' | SLSPRITEMOUSEY  sprite top - bottom the current mouse y location on the sprite                                            |
1535.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1536.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1537.  
1538.     IF SL_ValidSprite(Handle) = SLFALSE THEN SL_Error 1, "SL_SpriteGet" '                   report error if invalid sprite
1539.     SELECT CASE Action
1540.         CASE SLZOOM
1541.             '  _________________________________________________________________________
1542.             ' | Valid returns: 1 - 32767                                                |
1543.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1544.             SL_SpriteGet = SLSprite(Handle).Zoom
1545.         CASE SLFLIP
1546.             '  _________________________________________________________________________
1547.             ' | Valid returns: SLNONE, SLVERTICAL, SLHORIZONTAL, SLBOTH                 |
1548.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1549.             SL_SpriteGet = SLSprite(Handle).Flipped
1550.         CASE SLVISIBLE
1551.             '  _________________________________________________________________________
1552.             ' | Valid returns: SLTRUE, SLFALSE                                          |
1553.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1554.             SL_SpriteGet = SLSprite(Handle).Visible
1555.         CASE SLLAYER
1556.             '  _________________________________________________________________________
1557.             ' | Valid returns: 0 - UBOUND(SLLayers)                                     |
1558.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1559.             SL_SpriteGet = SLSprite(Handle).Layer
1560.         CASE SLSCORE
1561.             '  _________________________________________________________________________
1562.             ' | Valid returns: any number in LONG integer range                         |
1563.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1564.             SL_SpriteGet = SLSprite(Handle).Score
1565.         CASE SLLEFT
1566.             '  _________________________________________________________________________
1567.             ' | Valid returns: -32768 through 32767                                     |
1568.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1569.             SL_SpriteGet = SLSprite(Handle).Scrn.Left
1570.         CASE SLTOP
1571.             '  _________________________________________________________________________
1572.             ' | Valid returns: -32768 through 32767                                     |
1573.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1574.             SL_SpriteGet = SLSprite(Handle).Scrn.Top
1575.         CASE SLRIGHT
1576.             '  _________________________________________________________________________
1577.             ' | Valid returns: -32768 through 32767                                     |
1578.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1579.             SL_SpriteGet = SLSprite(Handle).Scrn.Right
1580.         CASE SLBOTTOM
1581.             '  _________________________________________________________________________
1582.             ' | Valid returns: -32768 through 32767                                     |
1583.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1584.             SL_SpriteGet = SLSprite(Handle).Scrn.Bottom
1585.         CASE SLWIDTH
1586.             '  _________________________________________________________________________
1587.             ' | Valid returns: -32768 through 32767                                     |
1588.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1589.             SL_SpriteGet = SLSprite(Handle).Scrn.Width
1590.         CASE SLHEIGHT
1591.             '  _________________________________________________________________________
1592.             ' | Valid returns: -32768 through 32767                                     |
1593.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1594.             SL_SpriteGet = SLSprite(Handle).Scrn.Height
1595.         CASE SLCENTERX
1596.             '  _________________________________________________________________________
1597.             ' | Valid returns: -32768 through 32767                                     |
1598.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1599.             SL_SpriteGet = SLSprite(Handle).Centerx
1600.         CASE SLCENTERY
1601.             '  _________________________________________________________________________
1602.             ' | Valid returns: -32768 through 32767                                     |
1603.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1604.             SL_SpriteGet = SLSprite(Handle).Centery
1605.         CASE SLFRAMERATE
1606.             '  _________________________________________________________________________
1607.             ' | Valid returns: 1 through global frame rate                              |
1608.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1609.             SL_SpriteGet = SLSprite(Handle).Anim.FrameRate
1610.         CASE SLAUTOANIMATE
1611.             '  _________________________________________________________________________
1612.             ' | Valid returns: SLTRUE, SLFALSE                                          |
1613.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1614.             SL_SpriteGet = SLSprite(Handle).Anim.Auto
1615.         CASE SLFROMCELL
1616.             '  _________________________________________________________________________
1617.             ' | Valid returns: 1 through total number of cells on sheet                 |
1618.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1619.             SL_SpriteGet = SLSprite(Handle).Anim.FromCell
1620.         CASE SLTOCELL
1621.             '  _________________________________________________________________________
1622.             ' | Valid returns: 1 through total number of cells on sheet                 |
1623.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1624.             SL_SpriteGet = SLSprite(Handle).Anim.ToCell
1625.         CASE SLANIMATEDIR
1626.             '  _________________________________________________________________________
1627.             ' | Valid returns: SLFORWARD, SLBACKWARD, SLBACKFORTH                       |
1628.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1629.             SL_SpriteGet = SLSprite(Handle).Anim.Direction
1630.         CASE SLAUTOMOTION
1631.             '  _________________________________________________________________________
1632.             ' | Valid returns: SLTRUE, SLFALSE                                          |
1633.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1634.             SL_SpriteGet = SLSprite(Handle).Move.Auto
1635.         CASE SLMOTIONANGLE
1636.             '  _________________________________________________________________________
1637.             ' | Valid returns: 0 through 359                                            |
1638.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1639.             SL_SpriteGet = SLSprite(Handle).Move.Degree
1640.         CASE SLXDIR
1641.             '  _________________________________________________________________________
1642.             ' | Valid returns: -32768 through 32767                                     |
1643.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1644.             SL_SpriteGet = SLSprite(Handle).Move.Xdir
1645.         CASE SLYDIR
1646.             '  _________________________________________________________________________
1647.             ' | Valid returns: -32768 through 32767                                     |
1648.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1649.             SL_SpriteGet = SLSprite(Handle).Move.Ydir
1650.         CASE SLAUTOROTATE
1651.             '  _________________________________________________________________________
1652.             ' | Valid returns: SLTRUE, SLFALSE                                          |
1653.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1654.             SL_SpriteGet = SLSprite(Handle).Spin.Auto
1655.         CASE SLROTATEANGLE
1656.             '  _________________________________________________________________________
1657.             ' | Valid returns: 0 through 359                                            |
1658.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1659.             SL_SpriteGet = SLSprite(Handle).Spin.Degree
1660.         CASE SLROTATESPEED
1661.             '  _________________________________________________________________________
1662.             ' | Valid returns: -359 through 359                                         |
1663.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1664.             SL_SpriteGet = SLSprite(Handle).Spin.Rate
1665.         CASE SLDETECTION
1666.             '  _________________________________________________________________________
1667.             ' | Valid returns: SLNONE, SLRECTANGLE, SLCIRCLE, SLPIXEL                   |
1668.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1669.             SL_SpriteGet = SLSprite(Handle).Coll.Detect
1670.         CASE SLCOLLISION
1671.             '  _________________________________________________________________________
1672.             ' | Valid returns: SLTRUE, SLFALSE                                          |
1673.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1674.             SL_SpriteGet = SLSprite(Handle).Coll.Event
1675.         CASE SLCOLLIDEWITH
1676.             '  _________________________________________________________________________
1677.             ' | Valid returns: 1 through maximum number of sprite handles               |
1678.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1679.             SL_SpriteGet = SLSprite(Handle).Coll.With
1680.         CASE SLCOLLIDEX
1681.             '  _________________________________________________________________________
1682.             ' | Valid returns: -32768 through 32767                                     |
1683.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1684.             SL_SpriteGet = SLSprite(Handle).Coll.Xloc
1685.         CASE SLCOLLIDEY
1686.             '  _________________________________________________________________________
1687.             ' | Valid returns: -32768 through 32767                                     |
1688.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1689.             SL_SpriteGet = SLSprite(Handle).Coll.Yloc
1690.         CASE SLMOUSE
1691.             '  _________________________________________________________________________
1692.             ' | Valid returns: SLNONE, SLLEFTCLICK, SLRIGHTCLICK, SLMIDDLECLICK, SLHOVER|
1693.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1694.             SL_SpriteGet = SLSprite(Handle).Mouse.Event
1695.         CASE SLMOUSEX
1696.             '  _________________________________________________________________________
1697.             ' | Valid returns: 0 through screen width - 1                               |
1698.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1699.             SL_SpriteGet = SLSprite(Handle).Mouse.SXloc
1700.         CASE SLMOUSEY
1701.             '  _________________________________________________________________________
1702.             ' | Valid returns: 0 through screen height - 1                              |
1703.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1704.             SL_SpriteGet = SLSprite(Handle).Mouse.SYloc
1705.         CASE SLSPRITEMOUSEX
1706.             '  _________________________________________________________________________
1707.             ' | Valid returns: sprite.left through sprite.right                         |
1708.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1709.             SL_SpriteGet = SLSprite(Handle).Mouse.Xloc
1710.         CASE SLSPRITEMOUSEY
1711.             '  _________________________________________________________________________
1712.             ' | Valid returns: sprite.top through sprite.bottom                         |
1713.             '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1714.             SL_SpriteGet = SLSprite(Handle).Mouse.Yloc
1715.         CASE ELSE
1716.             SL_Error 17, "SL_SpriteGet" '                                                   report invalid use of command
1717.     END SELECT
1718.  
1719. END FUNCTION
1720.  
1721. '----------------------------------------------------------------------------------------------------------------------------------
1722. FUNCTION SL_ValidSprite (Handle AS INTEGER) '                                                                        SL_ValidSprite
1723.     '  ___________________________________________________________________________________________________________________________
1724.     ' | Checks that the supplied sprite handle points to a valid sprite.                                                          |
1725.     ' |---------------------------------------------------------------------------------------------------------------------------|
1726.     ' | Usage : Valid = SL_ValidSprite(MySprite)                                                                                  |
1727.     ' |                                                                                                                           |
1728.     ' | Input : Handle = the handle pointer name of the sprite                                                                    |
1729.     ' | Output: SLTRUE if the sprite handle is valid, SLFALSE otherwise.                                                          |
1730.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1731.     SHARED SLSprite() AS SLSPRITE ' master sprite array
1732.  
1733.     IF Handle > UBOUND(SLSprite) OR Handle < 0 THEN '                                       is this a valid handle pointer?
1734.         SL_ValidSprite = SLFALSE '                                                          no, return SLFALSE
1735.     ELSEIF SLSprite(Handle).InUse THEN '                                                    yes, is the sprite currently in use?
1736.         SL_ValidSprite = SLTRUE '                                                           yes, return SLTRUE
1737.     END IF
1738.     '  _________________________________________________________________________________
1739.     ' | If the handle was not in use the function will return 0 (SLFALSE)               |
1740.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1741. END FUNCTION
1742.  
1743. '----------------------------------------------------------------------------------------------------------------------------------
1744. FUNCTION SL_Min (Num1 AS INTEGER, Num2 AS INTEGER) '                                                                         SL_Min
1745.     '  ___________________________________________________________________________________________________________________________
1746.     ' | Returns the smaller of the two numbers supplied.                                                                          |
1747.     ' |---------------------------------------------------------------------------------------------------------------------------|
1748.     ' | Usage : Smallest = SL_Min(Number1, Number2)                                                                               |
1749.     ' |                                                                                                                           |
1750.     ' | Input : Num1, Num2 = the two numbers to be compared                                                                       |
1751.     ' | Output: The smaller of the two numbers (if equal then Num2 will always be returned)                                       |
1752.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1753.     IF Num1 < Num2 THEN SL_Min = Num1 ELSE SL_Min = Num2 '                                  return the smallest of the two numbers
1754.  
1755. END FUNCTION
1756.  
1757. '----------------------------------------------------------------------------------------------------------------------------------
1758. FUNCTION SL_Max (Num1 AS INTEGER, Num2 AS INTEGER) '                                                                         SL_Max
1759.     '  ___________________________________________________________________________________________________________________________
1760.     ' | Returns the larger of the two numbers supplied.                                                                           |
1761.     ' |---------------------------------------------------------------------------------------------------------------------------|
1762.     ' | Usage : Largest = SL_Max(Number1, Number2)                                                                                |
1763.     ' |                                                                                                                           |
1764.     ' | Input : Num1, Num2 = the two numbers to be compared                                                                       |
1765.     ' | Output: The larger of the two numbers (if equal then Num2 will always be returned)                                        |
1766.     '  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1767.     IF Num1 > Num2 THEN SL_Max = Num1 ELSE SL_Max = Num2 '                                  return the largest of the two numbers
1768.  
1769. END FUNCTION
1770.  
1771. '----------------------------------------------------------------------------------------------------------------------------------
1772. SUB SL_Error (ErrNo AS INTEGER, Routine AS STRING)
1773.     '  ___________________________________________________________________________________________________________________________
1774.     ' |                                                                                                                           |
1775.     ' |---------------------------------------------------------------------------------------------------------------------------|
1776.     ' | Usage :                                                                                                                   |
1777.     ' |                                                                                                                           |
1778.     ' | Input :                                                                                                                   |
1779.     ' |                                                                                                                           |
1780.     ' | Output:                                                                                                                   |
1781.  
1782.     BEEP
1783.  
1784.     SCREEN 0, 0, 0, 0
1785.     PRINT ErrNo, Routine
1786.  
1787.     SELECT CASE ErrNo
1788.         CASE 1 ' invalid sprite
1789.         CASE 2 ' invalid sprite zoom level
1790.         CASE 3 ' invalid sprite flpping behavior
1791.         CASE 4 ' invalid sprite visibility setting
1792.         CASE 5 ' invalid layer requested
1793.         CASE 6 ' invalid auto-animation setting
1794.         CASE 7 ' invalid cell requested
1795.         CASE 8 ' invalid animation direction requested
1796.         CASE 9 ' invalid sprite frame rate requested
1797.         CASE 10 ' invalid auto-motion setting
1798.         CASE 11 ' invalid x direction vector
1799.         CASE 12 ' invalid y direction vector
1800.         CASE 13 ' invalid auto-rotation setting
1801.         CASE 14 ' invalid rotation speed
1802.         CASE 15 ' invalid colllsion detection method
1803.         CASE 16 ' invalid use of SL_SpriteSet
1804.         CASE 17 ' invalid use of SL_SpriteGet
1805.  
1806.     END SELECT
1807.  
1808.     END
1809.  
1810. END SUB
1811.  
1812.  

[TempodiBasic]

Hi Terry

while you are working in progress with your library
you raccomande us to use old library or the new in progress because only news are in evolution and the rest part is done and it will not change?

[madscijr]

Just an update to state I'm still working on the library. Here is the current state of the code:

I'm new to QB64 and just learning by making some simple games.
This library seems really useful - have you updated it since this post?
Does this have a home on git hub?
A tutorial and especially example programs (such as simple basic games) that illustrate how to utilize it would be very helpful.

[bplus]

I'm new to QB64 and just learning by making some simple games.
This library seems really useful - have you updated it since this post?
Does this have a home on git hub?
A tutorial and especially example programs (such as simple basic games) that illustrate how to utilize it would be very helpful.

Welcome madscijr!  Mad Scientist Jr?

Terry hasn't been around for awhile at least with public posts here but you can find links to his wonderful tutorial from this .org Home page or the Wiki for QB64 or maybe it's in his signature or maybe someone can paste one up here directly, I can't find mine at moment.

Here is Wiki which you might bookmark anyway on your browser (if you hadn't already), very handy!
https://www.qb64.org/wiki/Main_Page

[TempodiBasic]

Hi Madscijr
welcome to the forum
here a link to the tutorial for game programming of Terry
https://www.qb64.org/forum/index.php?topic=3204.0
here one of the last post of Terry
https://www.qb64.org/forum/index.php?topic=2264.msg114989#msg114989

[bplus]

Found it! Terry's Tutorial: https://www.qb64sourcecode.com

? I thought it was on Home page and at Wiki but couldn't find at either.

[FellippeHeitor]

Found it! Terry's Tutorial: https://www.qb64sourcecode.com

? I thought it was on Home page and at Wiki but couldn't find at either.

Link to Terry's tutorial is in the wiki's landing page.