Author Topic: redifine character set... something like on commodore64 or pcg on microbee (Read 8743 times)

PMACKAY · « **on:** August 27, 2018, 06:24:58 am »

I can make my own character set using pset, but how can i change the defaults to print using _printstring (x,y),my character so i can keep the speed and work with the system how it is

on microbee you just poke into a memory address and type pcg (user defined) and use the normal print commands
same as for commodore64, ti, sega, bbc so how can i do this. 8x8, 8x16, 16x16.

bplus · « **Reply #1 on:** August 27, 2018, 09:23:23 am »

You could make your own "print" character sub.

Setup character draw subs that use pset or lines or circles or ... that fit into a character block 8x16.

sub printChar x, y, charID
select case charID
case c1& : drawC1 x, y
case c2& : drawC2 x, y
...
end select
end sub

sub drawC1 x, y
pset (? + x, ? + y), color?
line ( ? + x, ? + y)-step(?, ?), color?
circle(? + x, ? + y), r, color?
... a bunch of drawing instructions to make the character, all offset by the x, y place to put the top left corner of block.
end sub

with such you can control the colors more than you could with with a font character. You can even make the characters scalable.
This is like making your own tiles.

bplus · « **Reply #2 on:** August 27, 2018, 09:34:03 am »

You can also draw all the characters in advance into image handles and use _putimage where you want the character.

Petr · « **Reply #3 on:** August 27, 2018, 10:38:03 am »

Code: QB64: [Select]

DIM SHARED chars(255) AS LONG
SCREEN _NEWIMAGE(800, 600, 32)
 
FOR Ascii = 0 TO 255
    chars(Ascii) = _NEWIMAGE(10, 20, 32)
    _DEST chars(Ascii)
    _PRINTSTRING (0, 0), CHR$(Ascii), chars(Ascii)
NEXT Ascii
_DEST 0
 
Prnt "What you think? Something this?", 1, 10, 10, 20, 15
SLEEP 1
Prnt "You have many options in QB64...", 2, 10, 500, 20, -15
 
 
 
SUB Prnt (text AS STRING, size AS INTEGER, StartX AS INTEGER, StartY AS INTEGER, Xspace AS INTEGER, Yspace AS INTEGER)
    x = StartX
    y = StartY
    FOR f = 1 TO LEN(text)
        ch = ASC(text, f)
        x = x + Xspace
        IF x MOD 5 = 0 THEN y = y + Yspace
        _PUTIMAGE (x, y)-(x + (size * 16), y + (size * (8 * f))), chars(ch), 0
        _DELAY .1
    NEXT
END SUB
 

Petr · « **Reply #4 on:** August 27, 2018, 10:53:47 am »

Or see here https://www.qb64.org/forum/index.php?topic=311.msg2031#msg2031. You can use _LoadFont and _Font before save points to array, then this point you can view as quads or circles or 3D objects....

Cobalt · « **Reply #5 on:** August 27, 2018, 10:57:17 am »

I would use something like Davey W Taylor's Font Editor to make a new BIOS font and then load that. Galleon set me up a way to get it to load in QB64. Just put the Charset.h in the QB64 directory.

DECLARE LIBRARY "charset"
SUB Charset_8x8 (BYVAL o AS _OFFSET)
SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE

Code: QB64: [Select]

CONST TRUE = -1, FALSE = NOT TRUE
SUB loadreapingfont
 OPEN "reaping.fnt" FOR BINARY AS #1
 FOR c% = 0 TO 255
  FOR y% = 0 TO 15
   GET #1, , charload
   FOR x% = 0 TO 7 'STEP -1
    IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
   NEXT
  NEXT
 NEXT
 CLOSE
END SUB
 
FUNCTION readbit (bit%, value%)
 IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
END FUNCTION
 

And I still use a POKE routine to display the text on screen 0 anyway. But that 'should' still work with normal PRINT or _PRINTSTRING in other screen modes as a 8x16 font. I think it will work with a 8x8 too but thats stuck on .NETs forum and until Galleon gets a backup copy to us to have here it maybe lost. Since I only use 8x16 I cut out the code for the 8x8 and don't have a copy.

PMACKAY · « **Reply #6 on:** August 27, 2018, 01:08:29 pm »

Quote from: Cobalt on August 27, 2018, 10:57:17 am

I would use something like Davey W Taylor's Font Editor to make a new BIOS font and then load that. Galleon set me up a way to get it to load in QB64. Just put the Charset.h in the QB64 directory.

DECLARE LIBRARY "charset"
SUB Charset_8x8 (BYVAL o AS _OFFSET)
SUB Charset_8x16 (BYVAL o AS _OFFSET)
END DECLARE
DIM SHARED c16(7, 15, 255) AS _UNSIGNED _BYTE, charload AS _UNSIGNED _BYTE

Code: QB64: [Select]
CONST TRUE = -1, FALSE = NOT TRUE
SUB loadreapingfont
OPEN "reaping.fnt" FOR BINARY AS #1
FOR c% = 0 TO 255
FOR y% = 0 TO 15
GET #1, , charload
FOR x% = 0 TO 7 'STEP -1
IF readbit(x%, charload) THEN c16(7 - x%, y%, c%) = 1 'any non-0 value should work
NEXT
NEXT
NEXT
CLOSE
END SUB

FUNCTION readbit (bit%, value%)
IF value% AND 2 ^ bit% THEN readbit = TRUE ELSE readbit = FALSE
END FUNCTION

And I still use a POKE routine to display the text on screen 0 anyway. But that 'should' still work with normal PRINT or _PRINTSTRING in other screen modes as a 8x16 font. I think it will work with a 8x8 too but thats stuck on .NETs forum and until Galleon gets a backup copy to us to have here it maybe lost. Since I only use 8x16 I cut out the code for the 8x8 and don't have a copy.

thank you. this is what was looking for. as for 8 x 8 i can just double the length anyway :) cheers

PMACKAY · « **Reply #7 on:** August 27, 2018, 01:12:37 pm »

thank you guys for the kind help.... :) I will jump straight to it... when i wake up 3:12am here in australia. ZZZzzzZZzzZ me

johnno56 · « **Reply #8 on:** August 27, 2018, 04:28:36 pm »

Melbourne. Where are you?

J

johnno56 · « **Reply #9 on:** August 27, 2018, 04:58:03 pm »

I used to have an Amstrad (8bit) back in the mid to late 80's and it, like the commodore and others, could redefine characters. I think they were re definable for two reasons. 1. If you had a LOT of patience - a new character set and 2. To create 8x8 tiles. I think the idea is, it is quicker to display a 64 pixel 'text' tile than it is to plot a 64 pixel tile. After all, a 4 mhz cpu, can only do SO much... lol

The method of 'mapping' the characters was using pencil and paper... Not as easy as THIS program. Great Job! Ah the memories...

J

bplus · « **Reply #10 on:** August 28, 2018, 01:17:24 am »

Ascii Character Editor sounded interesting, here is what I came up with today:

Code: QB64: [Select]

_TITLE "Ascii Character Editor"
'started 2018-08-27 by bplus
'QB64 X 64 version 1.2 20180228/86  from git b301f92
 
'========================== Instructions: =================================
'
' Arrow keys move the highlighter around, spacebar toggles tile on/off
' or just click with mouse to do the same.
 
' Click buttons to either
' 1. Enter an ascii by number to edit.
' 2. Enter a character by pressing the key(s) from which the anscii number is taken.
' 3. Save a modified character.
' 4. Save all edits made to flie called "Character Set.DAT".
' Note: If want to work with more sets, just rename Character Set.DAT
'       If that file isn't found, this app will start from scratch.
'
'==========================================================================
 
CONST CW = 8
CONST CH = 16
CONST SQ = 25
CONST XOFF = 60
CONST YOFF = 80
CONST WW = 800
CONST WH = 600
SCREEN _NEWIMAGE(WW, WH, 32)
_SCREENMOVE (1280 - WW) / 2 + 30, (760 - WH) / 2
DIM SHARED AN%, CX, CY, BLK AS _UNSIGNED LONG, WHT AS _UNSIGNED LONG, FILE$
DIM SHARED MAP(CW + 2, CH + 2) AS STRING * 1
DIM SHARED CS(256) AS STRING * 128
WHT = _RGB32(255, 255, 255)
BLK = _RGB32(0, 0, 0)
 
'==============================   main
 
'see if there is a file in the works to load else start from scratch
IF _FILEEXISTS("Character Set.DAT") THEN
    OPEN "Character Set.DAT" FOR INPUT AS #1
    FOR i = 1 TO 256
        INPUT #1, CS(i - 1)
    NEXT
    CLOSE #1
    FILE$ = "Character Set.DAT"
ELSE
    FOR a = 0 TO 255
        CLS
        _PRINTSTRING (0, 0), CHR$(a)
        b$ = ""
        FOR y = 0 TO CH - 1
            FOR x = 0 TO CW - 1
                IF POINT(x, y) <> BLK THEN b$ = b$ + "1" ELSE b$ = b$ + "0"
            NEXT
        NEXT
        CS(a) = b$
    NEXT
    FILE$ = "Nothing saved yet."
END IF
 
FOR i = 1 TO 128
    PRINT MID$(CS(1), i, 1);
    IF i MOD CW = 0 THEN PRINT
NEXT
'END
'sample B for starters
AN% = 66
load AN%
CX = 1: CY = 1
DO
    WHILE _MOUSEINPUT: WEND
    IF _MOUSEBUTTON(1) THEN
        mx = _MOUSEX
        my = _MOUSEY
        _DELAY .2
        'ascii #  to edit
        IF mx > 500 AND mx < 700 AND my > 50 AND my < 100 THEN
            COLOR WHT, 0
            LINE (500, 50)-(700, 100), BLK, BF
            LOCATE 5, 67: INPUT "Ascii # "; a%
            IF a% >= 0 AND a% <= 255 THEN AN% = a%: load AN%
        END IF
        'chr$  to edit
        IF mx > 500 AND mx < 700 AND my > 110 AND my < 160 THEN
            COLOR WHT, 0
            LINE (500, 110)-(700, 160), BLK, BF
            LOCATE 9, 67: INPUT "Enter Chr$ "; char$
            a% = ASC(char$)
            IF a% >= 0 AND a% <= 255 THEN AN% = a%: load AN%
        END IF
        'save character edit
        IF mx > 500 AND mx < 700 AND my > 170 AND my < 220 THEN
            b$ = ""
            FOR y = 1 TO CH
                FOR x = 1 TO CW
                    b$ = b$ + MAP(x, y)
                NEXT
            NEXT
            CS(AN%) = b$
            COLOR WHT, 0
            LINE (500, 170)-(700, 220), BLK, BF
            LOCATE 13, 67: PRINT " Character recorded. "
            _DISPLAY
            _DELAY 1.5
        END IF
        'file character set
        IF mx > 500 AND mx < 700 AND my > 230 AND my < 280 THEN
            COLOR WHT, 0
            LINE (500, 230)-(700, 280), BLK, BF
            OPEN "Character Set.DAT" FOR OUTPUT AS #1
            FOR a = 0 TO 255
                PRINT #1, CS(a)
            NEXT
            CLOSE #1
            LOCATE 16, 65: PRINT "Filed Character Set.DAT"
            _DISPLAY
            _DELAY 1.5
        END IF
 
        'mouse over edit box, toggle tiles and update cursor
        tx = (mx - XOFF) \ SQ: ty = (my - YOFF) \ SQ
        IF tx >= 1 AND tx <= CW AND ty >= 1 AND ty <= CH THEN
            CX = tx: CY = ty
            IF MAP(CX, CY) = "1" THEN MAP(CX, CY) = "0" ELSE MAP(CX, CY) = "1"
        END IF
    END IF
    KH& = _KEYHIT
    SELECT CASE KH&
        CASE 32 'space bar
            IF MAP(CX, CY) = "1" THEN MAP(CX, CY) = "0" ELSE MAP(CX, CY) = "1"
        CASE 18432 'up
            IF CY - 1 >= 1 THEN CY = CY - 1
        CASE 20480 'down
            IF CY + 1 <= CH THEN CY = CY + 1
        CASE 19200 'left
            IF CX - 1 >= 1 THEN CX = CX - 1
        CASE 19712 'right
            IF CX + 1 <= CW THEN CX = CX + 1
    END SELECT
 
    IF _KEYDOWN(27) THEN END
    update
    _DISPLAY
    _LIMIT 60
LOOP
 
SUB load (asci)
    FOR i = 1 TO 128
        y = i \ CW + 1
        x = i MOD CW: IF x = 0 THEN x = 8: y = y - 1
        MAP(x, y) = MID$(CS(asci), i, 1)
    NEXT
END SUB
 
SUB update
    COLOR WHT, _RGB32(100, 110, 100): CLS
    drwBtn 500, 50, "Load map with Ascii"
    drwBtn 500, 110, "Load map with Chr$"
    drwBtn 500, 170, "Save Character Edit"
    drwBtn 500, 230, "File Character Set"
    COLOR _RGB32(250, 225, 255), _RGB32(100, 110, 100)
    _PRINTSTRING (398, 400), "Current Ascii% =" + STR$(AN%) + " or CHR$(" + LTRIM$(STR$(AN%)) + ") = " + CHR$(AN%)
    _PRINTSTRING (398, 440), "File: " + FILE$
    LINE (XOFF - 1, YOFF - 1)-STEP((CW + 2) * SQ + 2, (CH + 2) * SQ + 2), _RGB32(255, 255, 0), B
    LINE (XOFF + 1, YOFF + 1)-STEP((CW + 2) * SQ, (CH + 2) * SQ), BLK, B
    LINE (XOFF, YOFF)-STEP((CW + 2) * SQ, (CH + 2) * SQ), _RGB32(255, 80, 0), BF
    FOR y = 1 TO CH
        FOR x = 1 TO CW
            IF MAP(x, y) = "1" THEN c& = _RGB32(200, 200, 200) ELSE c& = _RGB32(0, 0, 0)
            LINE ((x) * SQ + XOFF, (y) * SQ + YOFF)-STEP(SQ - 2, SQ - 2), c&, BF
        NEXT
    NEXT
    ' let's see actual size!
    COLOR _RGB32(255, 255, 0), _RGB32(100, 110, 100)
    FOR i = 1 TO 4
        drwChar XOFF + 16 * (i * 2), .5 * YOFF - (16 * i) / 2, AN%, i
    NEXT
    'highlight sqr
    LINE (CX * SQ - 1 + XOFF, CY * SQ - 1 + YOFF)-STEP(SQ, SQ), WHT, B
 
END SUB
 
SUB drwBtn (x, y, s$)
    th = 16: tw = 8 * LEN(s$): gray& = _RGB32(190, 190, 190)
    LINE (x, y)-STEP(200, 50), _RGB32(0, 0, 0), BF
    LINE (x, y)-STEP(197, 47), _RGB32(255, 255, 255), BF
    LINE (x + 1, y + 1)-STEP(197, 47), gray&, BF
    COLOR _RGB32(0, 0, 0), gray&
    _PRINTSTRING (x + 100 - 4 * LEN(s$), y + 17), s$
END SUB
 
SUB drwChar (x0, y0, ascn, size) 'what ever the present color is set at
    FOR y = 0 TO CH - 1
        FOR x = 0 TO CW - 1
            i = i + 1
            IF MID$(CS(ascn), i, 1) = "1" THEN LINE (x0 + x * size, y0 + y * size)-STEP(size - 1, size - 1), , BF
        NEXT
    NEXT
END SUB
 

[ You are not allowed to view this attachment ]

Then a quick little demo, showing table:

Code: QB64: [Select]

_TITLE "Using custom characters"
'started 2018-08-27 by bplus
'QB64 X 64 version 1.2 20180228/86  from git b301f92
 
 
CONST CW = 8
CONST CH = 16
CONST WW = 800
CONST WH = 600
CONST MAPW = 30
CONST MAPH = 20
CONST sq = 20
SCREEN _NEWIMAGE(WW, WH, 32)
_SCREENMOVE (1280 - WW) / 2 + 30, (760 - WH) / 2
DIM SHARED AN%, CX, CY, BLK AS _UNSIGNED LONG, WHT AS _UNSIGNED LONG, FILE$
DIM SHARED MAP(CW + 2, CH + 2) AS STRING * 1
DIM SHARED CS(256) AS STRING * 128
WHT = _RGB32(255, 255, 255)
BLK = _RGB32(0, 0, 0)
 
'==============================   main
 
i = 0
FOR y = 10 TO 500 STEP 40
    FOR x = 10 TO 700 STEP 40
        drwChar x, y, i, 2
        i = i + 1
        IF i > 155 THEN END
    NEXT
NEXT
 
SUB drwChar (x0, y0, ascn, size) 'what ever the present color is set at
    'CS() DIM SHARED in starting setup
    STATIC beenHere
    IF beenHere = 0 THEN
        'see if there is a file in the works to load else start from scratch
        IF _FILEEXISTS("Character Set.DAT") THEN
            OPEN "Character Set.DAT" FOR INPUT AS #1
            FOR i = 1 TO 256
                INPUT #1, CS(i - 1)
            NEXT
            CLOSE #1
            FILE$ = "Character Set.DAT"
        ELSE
            PRINT "Can't find Character Set.DAT file, goodbye!"
            END
        END IF
        beenHere = -1
    END IF
    FOR y = 0 TO CH - 1
        FOR x = 0 TO CW - 1
            i = i + 1
            IF MID$(CS(ascn), i, 1) = "1" THEN LINE (x0 + x * size, y0 + y * size)-STEP(size - 1, size - 1), , BF
        NEXT
    NEXT
END SUB
 

[ You are not allowed to view this attachment ]

FellippeHeitor · « **Reply #11 on:** August 28, 2018, 01:38:49 am »

Now that was quick, bplus! And it does look good too!

johnno56 · « **Reply #12 on:** August 28, 2018, 04:24:47 am »

Just curious. Why are the characters 8x16? The old characters were 8x8...

J

bplus · « **Reply #13 on:** August 28, 2018, 08:43:07 am »

I was using QB64 default font. BTW, these characters can't be printed in normal PRINT statement, they are copied so all original characters remain intact and you make your own print statements by stringing the 8x16 tiles together or resize them and draw bigger!

If QB64 is not fast enough (it usually is), draw the characters to image handles as Petr has shown and make your own _printstring sub.

PMACKAY · « **Reply #14 on:** August 28, 2018, 09:20:44 am »

Quote from: johnno56 on August 27, 2018, 04:58:03 pm

I used to have an Amstrad (8bit) back in the mid to late 80's and it, like the commodore and others, could redefine characters. I think they were re definable for two reasons. 1. If you had a LOT of patience - a new character set and 2. To create 8x8 tiles. I think the idea is, it is quicker to display a 64 pixel 'text' tile than it is to plot a 64 pixel tile. After all, a 4 mhz cpu, can only do SO much... lol

The method of 'mapping' the characters was using pencil and paper... Not as easy as THIS program. Great Job! Ah the memories...

J

this is what i want, not to make a new sub or thing, just straight out replacement of the character. redifine it.... the routine is faster to just print rather then slow the computer down using pset (x,y): i am able to rip character roms from original roms, but i just want to change a few not the whole set. its really to make my game more appealing... a monster as a monster. brick as bricks and so on. the ascii is great but now i want to be more creative.

News:

Author Topic: redifine character set... something like on commodore64 or pcg on microbee (Read 8743 times)

PMACKAY

redifine character set... something like on commodore64 or pcg on microbee

bplus

Re: redifine character set... something like on commodore64 or pcg on microbee

bplus

Re: redifine character set... something like on commodore64 or pcg on microbee

Petr

Re: redifine character set... something like on commodore64 or pcg on microbee

Petr

Re: redifine character set... something like on commodore64 or pcg on microbee

Cobalt

Re: redifine character set... something like on commodore64 or pcg on microbee

PMACKAY

Re: redifine character set... something like on commodore64 or pcg on microbee

PMACKAY

Re: redifine character set... something like on commodore64 or pcg on microbee

johnno56

Re: redifine character set... something like on commodore64 or pcg on microbee

johnno56

Re: redifine character set... something like on commodore64 or pcg on microbee

bplus

Re: redifine character set... something like on commodore64 or pcg on microbee

FellippeHeitor

Re: redifine character set... something like on commodore64 or pcg on microbee

johnno56

Re: redifine character set... something like on commodore64 or pcg on microbee

bplus

Re: redifine character set... something like on commodore64 or pcg on microbee

PMACKAY

Re: redifine character set... something like on commodore64 or pcg on microbee